lisp/vc-svn.el

   1 ;;; vc-svn.el --- non-resident support for Subversion version-control
   2
   3 ;; Copyright (C) 2003, 2004, 2005, 2006, 2007, 2008, 2009
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author:      FSF (see vc.el for full credits)
   7 ;; Maintainer:  Stefan Monnier <monnier@gnu.org>
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Sync'd with Subversion's vc-svn.el as of revision 5801. but this version
  27 ;; has been extensively modified since to handle filesets.
  28
  29 ;;; Code:
  30
  31 (eval-when-compile
  32   (require 'vc))
  33
  34 ;;;
  35 ;;; Customization options
  36 ;;;
  37
  38 ;; FIXME there is also svnadmin.
  39 (defcustom vc-svn-program "svn"
  40   "Name of the SVN executable."
  41   :type 'string
  42   :group 'vc)
  43
  44 (defcustom vc-svn-global-switches nil
  45   "Global switches to pass to any SVN command."
  46   :type '(choice (const :tag "None" nil)
  47                  (string :tag "Argument String")
  48                  (repeat :tag "Argument List"
  49                          :value ("")
  50                          string))
  51   :version "22.1"
  52   :group 'vc)
  53
  54 (defcustom vc-svn-register-switches nil
  55   "Switches for registering a file into SVN.
  56 A string or list of strings passed to the checkin program by
  57 \\[vc-register].  If nil, use the value of `vc-register-switches'.
  58 If t, use no switches."
  59   :type '(choice (const :tag "Unspecified" nil)
  60                  (const :tag "None" t)
  61                  (string :tag "Argument String")
  62                  (repeat :tag "Argument List" :value ("") string))
  63   :version "22.1"
  64   :group 'vc)
  65
  66 (defcustom vc-svn-diff-switches
  67   t                        ;`svn' doesn't support common args like -c or -b.
  68   "String or list of strings specifying extra switches for svn diff under VC.
  69 If nil, use the value of `vc-diff-switches' (or `diff-switches'),
  70 together with \"-x --diff-cmd=diff\" (since svn diff does not
  71 support the default \"-c\" value of `diff-switches').  If you
  72 want to force an empty list of arguments, use t."
  73   :type '(choice (const :tag "Unspecified" nil)
  74                  (const :tag "None" t)
  75                  (string :tag "Argument String")
  76                  (repeat :tag "Argument List"
  77                          :value ("")
  78                          string))
  79   :version "22.1"
  80   :group 'vc)
  81
  82 (defcustom vc-svn-header (or (cdr (assoc 'SVN vc-header-alist)) '("\$Id\$"))
  83   "Header keywords to be inserted by `vc-insert-headers'."
  84   :version "22.1"
  85   :type '(repeat string)
  86   :group 'vc)
  87
  88 ;; We want to autoload it for use by the autoloaded version of
  89 ;; vc-svn-registered, but we want the value to be compiled at startup, not
  90 ;; at dump time.
  91 ;; ;;;###autoload
  92 (defconst vc-svn-admin-directory
  93   (cond ((and (memq system-type '(cygwin windows-nt ms-dos))
  94               (getenv "SVN_ASP_DOT_NET_HACK"))
  95          "_svn")
  96         (t ".svn"))
  97   "The name of the \".svn\" subdirectory or its equivalent.")
  98
  99 ;;; Properties of the backend
 100
 101 (defun vc-svn-revision-granularity () 'repository)
 102 (defun vc-svn-checkout-model (files) 'implicit)
 103
 104 ;;;
 105 ;;; State-querying functions
 106 ;;;
 107
 108 ;;; vc-svn-admin-directory is generally not defined when the
 109 ;;; autoloaded function is called.
 110
 111 ;;;###autoload (defun vc-svn-registered (f)
 112 ;;;###autoload   (let ((admin-dir (cond ((and (eq system-type 'windows-nt)
 113 ;;;###autoload                                (getenv "SVN_ASP_DOT_NET_HACK"))
 114 ;;;###autoload                           "_svn")
 115 ;;;###autoload                          (t ".svn"))))
 116 ;;;###autoload     (when (file-readable-p (expand-file-name
 117 ;;;###autoload                             (concat admin-dir "/entries")
 118 ;;;###autoload                             (file-name-directory f)))
 119 ;;;###autoload       (load "vc-svn")
 120 ;;;###autoload       (vc-svn-registered f))))
 121
 122 (defun vc-svn-registered (file)
 123   "Check if FILE is SVN registered."
 124   (when (file-readable-p (expand-file-name (concat vc-svn-admin-directory
 125                                                    "/entries")
 126                                            (file-name-directory file)))
 127     (with-temp-buffer
 128       (cd (file-name-directory file))
 129       (let ((status
 130              (condition-case nil
 131                  ;; Ignore all errors.
 132                  (vc-svn-command t t file "status" "-v")
 133                ;; Some problem happened.  E.g. We can't find an `svn'
 134                ;; executable.  We used to only catch `file-error' but when
 135                ;; the process is run on a remote host via Tramp, the error
 136                ;; is only reported via the exit status which is turned into
 137                ;; an `error' by vc-do-command.
 138                (error nil))))
 139         (when (eq 0 status)
 140           (let ((parsed (vc-svn-parse-status file)))
 141             (and parsed (not (memq parsed '(ignored unregistered))))))))))
 142
 143 (defun vc-svn-state (file &optional localp)
 144   "SVN-specific version of `vc-state'."
 145   (setq localp (or localp (vc-stay-local-p file)))
 146   (with-temp-buffer
 147     (cd (file-name-directory file))
 148     (vc-svn-command t 0 file "status" (if localp "-v" "-u"))
 149     (vc-svn-parse-status file)))
 150
 151 (defun vc-svn-state-heuristic (file)
 152   "SVN-specific state heuristic."
 153   (vc-svn-state file 'local))
 154
 155 ;; FIXME it would be better not to have the "remote" argument,
 156 ;; but to distinguish the two output formats based on content.
 157 (defun vc-svn-after-dir-status (callback &optional remote)
 158   (let ((state-map '((?A . added)
 159                      (?C . conflict)
 160                      (?I . ignored)
 161                      (?M . edited)
 162                      (?D . removed)
 163                      (?R . removed)
 164                      (?? . unregistered)
 165                      ;; This is what vc-svn-parse-status does.
 166                      (?~ . edited)))
 167         (re (if remote "^\\(.\\)..... \\([ *]\\) +\\(?:[-0-9]+\\)?   \\(.*\\)$"
 168               ;; Subexp 2 is a dummy in this case, so the numbers match.
 169               "^\\(.\\)....\\(.\\) \\(.*\\)$"))
 170        result)
 171     (goto-char (point-min))
 172     (while (re-search-forward re nil t)
 173       (let ((state (cdr (assq (aref (match-string 1) 0) state-map)))
 174             (filename (match-string 3)))
 175         (and remote (string-equal (match-string 2) "*")
 176              ;; FIXME are there other possible combinations?
 177              (cond ((eq state 'edited) (setq state 'needs-merge))
 178                    ((not state) (setq state 'needs-update))))
 179         (when (and state (not (string= "." filename)))
 180          (setq result (cons (list filename state) result)))))
 181     (funcall callback result)))
 182
 183 (defun vc-svn-dir-status (dir callback)
 184   "Run 'svn status' for DIR and update BUFFER via CALLBACK.
 185 CALLBACK is called as (CALLBACK RESULT BUFFER), where
 186 RESULT is a list of conses (FILE . STATE) for directory DIR."
 187   ;; FIXME should this rather be all the files in dir?
 188   ;; FIXME: the vc-stay-local-p logic below is disabled, it ends up
 189   ;; calling synchronously (vc-svn-registered DIR) => calling svn status -v DIR
 190   ;; which is VERY SLOW for big trees and it makes emacs
 191   ;; completely unresponsive during that time.
 192   (let* ((local (and nil (vc-stay-local-p dir)))
 193          (remote (or t (not local) (eq local 'only-file))))
 194     (vc-svn-command (current-buffer) 'async nil "status"
 195                     (if remote "-u"))
 196   (vc-exec-after
 197      `(vc-svn-after-dir-status (quote ,callback) ,remote))))
 198
 199 (defun vc-svn-dir-status-files (dir files default-state callback)
 200   (apply 'vc-svn-command (current-buffer) 'async nil "status" files)
 201   (vc-exec-after
 202    `(vc-svn-after-dir-status (quote ,callback))))
 203
 204 (defun vc-svn-dir-extra-headers (dir)
 205   "Generate extra status headers for a Subversion working copy."
 206   (vc-svn-command "*vc*" 0 nil "info")
 207   (let ((repo
 208          (save-excursion
 209            (and (progn
 210                   (set-buffer "*vc*")
 211                   (goto-char (point-min))
 212                   (re-search-forward "Repository Root: *\\(.*\\)" nil t))
 213                 (match-string 1)))))
 214     (concat
 215      (cond (repo
 216             (concat
 217              (propertize "Repository : " 'face 'font-lock-type-face)
 218              (propertize repo 'face 'font-lock-variable-name-face)))
 219            (t "")))))
 220
 221 (defun vc-svn-working-revision (file)
 222   "SVN-specific version of `vc-working-revision'."
 223   ;; There is no need to consult RCS headers under SVN, because we
 224   ;; get the workfile version for free when we recognize that a file
 225   ;; is registered in SVN.
 226   (vc-svn-registered file)
 227   (vc-file-getprop file 'vc-working-revision))
 228
 229 ;; vc-svn-mode-line-string doesn't exist because the default implementation
 230 ;; works just fine.
 231
 232 (defun vc-svn-previous-revision (file rev)
 233   (let ((newrev (1- (string-to-number rev))))
 234     (when (< 0 newrev)
 235       (number-to-string newrev))))
 236
 237 (defun vc-svn-next-revision (file rev)
 238   (let ((newrev (1+ (string-to-number rev))))
 239     ;; The "working revision" is an uneasy conceptual fit under Subversion;
 240     ;; we use it as the upper bound until a better idea comes along.  If the
 241     ;; workfile version W coincides with the tree's latest revision R, then
 242     ;; this check prevents a "no such revision: R+1" error.  Otherwise, it
 243     ;; inhibits showing of W+1 through R, which could be considered anywhere
 244     ;; from gracious to impolite.
 245     (unless (< (string-to-number (vc-file-getprop file 'vc-working-revision))
 246                newrev)
 247       (number-to-string newrev))))
 248
 249
 250 ;;;
 251 ;;; State-changing functions
 252 ;;;
 253
 254 (defun vc-svn-create-repo ()
 255   "Create a new SVN repository."
 256   (vc-do-command "*vc*" 0 "svnadmin" '("create" "SVN"))
 257   (vc-do-command "*vc*" 0 vc-svn-program '(".")
 258                  "checkout" (concat "file://" default-directory "SVN")))
 259
 260 (defun vc-svn-register (files &optional rev comment)
 261   "Register FILES into the SVN version-control system.
 262 The COMMENT argument is ignored  This does an add but not a commit.
 263 Passes either `vc-svn-register-switches' or `vc-register-switches'
 264 to the SVN command."
 265   (apply 'vc-svn-command nil 0 files "add" (vc-switches 'SVN 'register)))
 266
 267 (defun vc-svn-responsible-p (file)
 268   "Return non-nil if SVN thinks it is responsible for FILE."
 269   (file-directory-p (expand-file-name vc-svn-admin-directory
 270                                       (if (file-directory-p file)
 271                                           file
 272                                         (file-name-directory file)))))
 273
 274 (defalias 'vc-svn-could-register 'vc-svn-responsible-p
 275   "Return non-nil if FILE could be registered in SVN.
 276 This is only possible if SVN is responsible for FILE's directory.")
 277
 278 (defun vc-svn-checkin (files rev comment)
 279   "SVN-specific version of `vc-backend-checkin'."
 280   (if rev (error "Committing to a specific revision is unsupported in SVN"))
 281   (let ((status (apply
 282                  'vc-svn-command nil 1 files "ci"
 283                  (nconc (list "-m" comment) (vc-switches 'SVN 'checkin)))))
 284     (set-buffer "*vc*")
 285     (goto-char (point-min))
 286     (unless (equal status 0)
 287       ;; Check checkin problem.
 288       (cond
 289        ((search-forward "Transaction is out of date" nil t)
 290         (mapc (lambda (file) (vc-file-setprop file 'vc-state 'needs-merge))
 291               files)
 292         (error (substitute-command-keys
 293                 (concat "Up-to-date check failed: "
 294                         "type \\[vc-next-action] to merge in changes"))))
 295        (t
 296         (pop-to-buffer (current-buffer))
 297         (goto-char (point-min))
 298         (shrink-window-if-larger-than-buffer)
 299         (error "Check-in failed"))))
 300     ;; Update file properties
 301     ;; (vc-file-setprop
 302     ;;  file 'vc-working-revision
 303     ;;  (vc-parse-buffer "^\\(new\\|initial\\) revision: \\([0-9.]+\\)" 2))
 304     ))
 305
 306 (defun vc-svn-find-revision (file rev buffer)
 307   "SVN-specific retrieval of a specified version into a buffer."
 308   (apply 'vc-svn-command
 309          buffer 0 file
 310          "cat"
 311          (and rev (not (string= rev ""))
 312               (concat "-r" rev))
 313          (vc-switches 'SVN 'checkout)))
 314
 315 (defun vc-svn-checkout (file &optional editable rev)
 316   (message "Checking out %s..." file)
 317   (with-current-buffer (or (get-file-buffer file) (current-buffer))
 318     (vc-svn-update file editable rev (vc-switches 'SVN 'checkout)))
 319   (vc-mode-line file)
 320   (message "Checking out %s...done" file))
 321
 322 (defun vc-svn-update (file editable rev switches)
 323   (if (and (file-exists-p file) (not rev))
 324       ;; If no revision was specified, there's nothing to do.
 325       nil
 326     ;; Check out a particular version (or recreate the file).
 327     (vc-file-setprop file 'vc-working-revision nil)
 328     (apply 'vc-svn-command nil 0 file
 329            "update"
 330            (cond
 331             ((null rev) "-rBASE")
 332             ((or (eq rev t) (equal rev "")) nil)
 333             (t (concat "-r" rev)))
 334            switches)))
 335
 336 (defun vc-svn-delete-file (file)
 337   (vc-svn-command nil 0 file "remove"))
 338
 339 (defun vc-svn-rename-file (old new)
 340   (vc-svn-command nil 0 new "move" (file-relative-name old)))
 341
 342 (defun vc-svn-revert (file &optional contents-done)
 343   "Revert FILE to the version it was based on."
 344   (unless contents-done
 345     (vc-svn-command nil 0 file "revert")))
 346
 347 (defun vc-svn-merge (file first-version &optional second-version)
 348   "Merge changes into current working copy of FILE.
 349 The changes are between FIRST-VERSION and SECOND-VERSION."
 350   (vc-svn-command nil 0 file
 351                  "merge"
 352                  "-r" (if second-version
 353                         (concat first-version ":" second-version)
 354                       first-version))
 355   (vc-file-setprop file 'vc-state 'edited)
 356   (with-current-buffer (get-buffer "*vc*")
 357     (goto-char (point-min))
 358     (if (looking-at "C  ")
 359         1                               ; signal conflict
 360       0)))                              ; signal success
 361
 362 (defun vc-svn-merge-news (file)
 363   "Merge in any new changes made to FILE."
 364   (message "Merging changes into %s..." file)
 365   ;; (vc-file-setprop file 'vc-working-revision nil)
 366   (vc-file-setprop file 'vc-checkout-time 0)
 367   (vc-svn-command nil 0 file "update")
 368   ;; Analyze the merge result reported by SVN, and set
 369   ;; file properties accordingly.
 370   (with-current-buffer (get-buffer "*vc*")
 371     (goto-char (point-min))
 372     ;; get new working revision
 373     (if (re-search-forward
 374          "^\\(Updated to\\|At\\) revision \\([0-9]+\\)" nil t)
 375         (vc-file-setprop file 'vc-working-revision (match-string 2))
 376       (vc-file-setprop file 'vc-working-revision nil))
 377     ;; get file status
 378     (goto-char (point-min))
 379     (prog1
 380         (if (looking-at "At revision")
 381             0 ;; there were no news; indicate success
 382           (if (re-search-forward
 383                ;; Newer SVN clients have 3 columns of chars (one for the
 384                ;; file's contents, then second for its properties, and the
 385                ;; third for lock-grabbing info), before the 2 spaces.
 386                ;; We also used to match the filename in column 0 without any
 387                ;; meta-info before it, but I believe this can never happen.
 388                (concat "^\\(\\([ACGDU]\\)\\(.[B ]\\)?  \\)"
 389                        (regexp-quote (file-name-nondirectory file)))
 390                nil t)
 391               (cond
 392                ;; Merge successful, we are in sync with repository now
 393                ((string= (match-string 2) "U")
 394                 (vc-file-setprop file 'vc-state 'up-to-date)
 395                 (vc-file-setprop file 'vc-checkout-time
 396                                  (nth 5 (file-attributes file)))
 397                 0);; indicate success to the caller
 398                ;; Merge successful, but our own changes are still in the file
 399                ((string= (match-string 2) "G")
 400                 (vc-file-setprop file 'vc-state 'edited)
 401                 0);; indicate success to the caller
 402                ;; Conflicts detected!
 403                (t
 404                 (vc-file-setprop file 'vc-state 'edited)
 405                 1);; signal the error to the caller
 406                )
 407             (pop-to-buffer "*vc*")
 408             (error "Couldn't analyze svn update result")))
 409       (message "Merging changes into %s...done" file))))
 410
 411 (defun vc-svn-modify-change-comment (files rev comment)
 412   "Modify the change comments for a specified REV.
 413 You must have ssh access to the repository host, and the directory Emacs
 414 uses locally for temp files must also be writable by you on that host.
 415 This is only supported if the repository access method is either file://
 416 or svn+ssh://."
 417   (let (tempfile host remotefile directory fileurl-p)
 418     (with-temp-buffer
 419       (vc-do-command (current-buffer) 0 vc-svn-program nil "info")
 420       (goto-char (point-min))
 421       (unless (re-search-forward "Repository Root: \\(file://\\(/.*\\)\\)\\|\\(svn\\+ssh://\\([^/]+\\)\\(/.*\\)\\)" nil t)
 422         (error "Repository information is unavailable"))
 423       (if (match-string 1)
 424           (progn
 425             (setq fileurl-p t)
 426             (setq directory (match-string 2)))
 427         (setq host (match-string 4))
 428         (setq directory (match-string 5))
 429         (setq remotefile (concat host ":" tempfile))))
 430     (with-temp-file (setq tempfile (make-temp-file user-mail-address))
 431       (insert comment))
 432     (if fileurl-p
 433         ;; Repository Root is a local file.
 434         (progn
 435           (unless (vc-do-command
 436                    "*vc*" 0 "svnadmin" nil
 437                    "setlog" "--bypass-hooks" directory
 438                    "-r" rev (format "%s" tempfile))
 439             (error "Log edit failed"))
 440           (delete-file tempfile))
 441
 442       ;; Remote repository, using svn+ssh.
 443       (unless (vc-do-command "*vc*" 0 "scp" nil "-q" tempfile remotefile)
 444         (error "Copy of comment to %s failed" remotefile))
 445       (unless (vc-do-command
 446                "*vc*" 0 "ssh" nil "-q" host
 447                (format "svnadmin setlog --bypass-hooks %s -r %s %s; rm %s"
 448                        directory rev tempfile tempfile))
 449         (error "Log edit failed")))))
 450
 451 ;;;
 452 ;;; History functions
 453 ;;;
 454
 455 (defvar log-view-per-file-logs)
 456
 457 (define-derived-mode vc-svn-log-view-mode log-view-mode "SVN-Log-View"
 458   (require 'add-log)
 459   (set (make-local-variable 'log-view-per-file-logs) nil))
 460
 461 (defun vc-svn-print-log (files &optional buffer)
 462   "Get change log(s) associated with FILES."
 463   (save-current-buffer
 464     (vc-setup-buffer buffer)
 465     (let ((inhibit-read-only t))
 466       (goto-char (point-min))
 467       (if files
 468           (dolist (file files)
 469                   (insert "Working file: " file "\n")
 470                   (vc-svn-command
 471                    buffer
 472                    'async
 473                    ;; (if (and (= (length files) 1) (vc-stay-local-p file)) 'async 0)
 474                    (list file)
 475                    "log"
 476                    ;; By default Subversion only shows the log up to the
 477                    ;; working revision, whereas we also want the log of the
 478                    ;; subsequent commits.  At least that's what the
 479                    ;; vc-cvs.el code does.
 480                    "-rHEAD:0"))
 481         ;; Dump log for the entire directory.
 482         (vc-svn-command buffer 0 nil "log" "-rHEAD:0")))))
 483
 484 (defun vc-svn-diff (files &optional oldvers newvers buffer)
 485   "Get a difference report using SVN between two revisions of fileset FILES."
 486   (and oldvers
 487        (not newvers)
 488        files
 489        (catch 'no
 490          (dolist (f files)
 491            (or (equal oldvers (vc-working-revision f))
 492                (throw 'no nil)))
 493          t)
 494        ;; Use nil rather than the current revision because svn handles
 495        ;; it better (i.e. locally).  Note that if _any_ of the files
 496        ;; has a different revision, we fetch the lot, which is
 497        ;; obviously sub-optimal.
 498        (setq oldvers nil))
 499   (let* ((switches
 500             (if vc-svn-diff-switches
 501                 (vc-switches 'SVN 'diff)
 502               (list "--diff-cmd=diff" "-x"
 503                     (mapconcat 'identity (vc-switches nil 'diff) " "))))
 504            (async (and (not vc-disable-async-diff)
 505                        (vc-stay-local-p files)
 506                        (or oldvers newvers)))) ; Svn diffs those locally.
 507       (apply 'vc-svn-command buffer
 508              (if async 'async 0)
 509              files "diff"
 510              (append
 511               switches
 512               (when oldvers
 513                 (list "-r" (if newvers (concat oldvers ":" newvers)
 514                              oldvers)))))
 515       (if async 1                     ; async diff => pessimistic assumption
 516         ;; For some reason `svn diff' does not return a useful
 517         ;; status w.r.t whether the diff was empty or not.
 518         (buffer-size (get-buffer buffer)))))
 519
 520 ;;;
 521 ;;; Tag system
 522 ;;;
 523
 524 (defun vc-svn-create-tag (dir name branchp)
 525   "Assign to DIR's current revision a given NAME.
 526 If BRANCHP is non-nil, the name is created as a branch (and the current
 527 workspace is immediately moved to that new branch).
 528 NAME is assumed to be a URL."
 529   (vc-svn-command nil 0 dir "copy" name)
 530   (when branchp (vc-svn-retrieve-tag dir name nil)))
 531
 532 (defun vc-svn-retrieve-tag (dir name update)
 533   "Retrieve a tag at and below DIR.
 534 NAME is the name of the tag; if it is empty, do a `svn update'.
 535 If UPDATE is non-nil, then update (resynch) any affected buffers.
 536 NAME is assumed to be a URL."
 537   (vc-svn-command nil 0 dir "switch" name)
 538   ;; FIXME: parse the output and obey `update'.
 539   )
 540
 541 ;;;
 542 ;;; Miscellaneous
 543 ;;;
 544
 545 ;; Subversion makes backups for us, so don't bother.
 546 ;; (defalias 'vc-svn-make-version-backups-p 'vc-stay-local-p
 547 ;;   "Return non-nil if version backups should be made for FILE.")
 548
 549 (defun vc-svn-check-headers ()
 550   "Check if the current file has any headers in it."
 551   (save-excursion
 552     (goto-char (point-min))
 553     (re-search-forward "\\$[A-Za-z\300-\326\330-\366\370-\377]+\
 554 \\(: [\t -#%-\176\240-\377]*\\)?\\$" nil t)))
 555
 556
 557 ;;;
 558 ;;; Internal functions
 559 ;;;
 560
 561 (defun vc-svn-command (buffer okstatus file-or-list &rest flags)
 562   "A wrapper around `vc-do-command' for use in vc-svn.el.
 563 The difference to vc-do-command is that this function always invokes `svn',
 564 and that it passes `vc-svn-global-switches' to it before FLAGS."
 565   (apply 'vc-do-command (or buffer "*vc*") okstatus vc-svn-program file-or-list
 566          (if (stringp vc-svn-global-switches)
 567              (cons vc-svn-global-switches flags)
 568            (append vc-svn-global-switches
 569                    flags))))
 570
 571 (defun vc-svn-repository-hostname (dirname)
 572   (with-temp-buffer
 573     (let ((coding-system-for-read
 574            (or file-name-coding-system
 575                default-file-name-coding-system)))
 576       (vc-insert-file (expand-file-name (concat vc-svn-admin-directory
 577                                                 "/entries")
 578                                         dirname)))
 579     (goto-char (point-min))
 580     (when (re-search-forward
 581            ;; Old `svn' used name="svn:this_dir", newer use just name="".
 582            (concat "name=\"\\(?:svn:this_dir\\)?\"[\n\t ]*"
 583                    "\\(?:[-a-z]+=\"[^\"]*\"[\n\t ]*\\)*?"
 584                    "url=\"\\(?1:[^\"]+\\)\""
 585                    ;; Yet newer ones don't use XML any more.
 586                    "\\|^\ndir\n[0-9]+\n\\(?1:.*\\)") nil t)
 587       ;; This is not a hostname but a URL.  This may actually be considered
 588       ;; as a feature since it allows vc-svn-stay-local to specify different
 589       ;; behavior for different modules on the same server.
 590       (match-string 1))))
 591
 592 (defun vc-svn-resolve-when-done ()
 593   "Call \"svn resolved\" if the conflict markers have been removed."
 594   (save-excursion
 595     (goto-char (point-min))
 596     (unless (re-search-forward "^<<<<<<< " nil t)
 597       (vc-svn-command nil 0 buffer-file-name "resolved")
 598       ;; Remove the hook so that it is not called multiple times.
 599       (remove-hook 'after-save-hook 'vc-svn-resolve-when-done t))))
 600
 601 ;; Inspired by vc-arch-find-file-hook.
 602 (defun vc-svn-find-file-hook ()
 603   (when (eq ?C (vc-file-getprop buffer-file-name 'vc-svn-status))
 604     ;; If the file is marked as "conflicted", then we should try and call
 605     ;; "svn resolved" when applicable.
 606     (if (save-excursion
 607           (goto-char (point-min))
 608           (re-search-forward "^<<<<<<< " nil t))
 609         ;; There are conflict markers.
 610         (progn
 611           (smerge-start-session)
 612           (add-hook 'after-save-hook 'vc-svn-resolve-when-done nil t))
 613       ;; There are no conflict markers.  This is problematic: maybe it means
 614       ;; the conflict has been resolved and we should immediately call "svn
 615       ;; resolved", or it means that the file's type does not allow Svn to
 616       ;; use conflict markers in which case we don't really know what to do.
 617       ;; So let's just punt for now.
 618       nil)
 619     (message "There are unresolved conflicts in this file")))
 620
 621 (defun vc-svn-parse-status (&optional filename)
 622   "Parse output of \"svn status\" command in the current buffer.
 623 Set file properties accordingly.  Unless FILENAME is non-nil, parse only
 624 information about FILENAME and return its status."
 625   (let (file status)
 626     (goto-char (point-min))
 627     (while (re-search-forward
 628             ;; Ignore the files with status X.
 629             "^\\(?:\\?\\|[ ACDGIMR!~][ MC][ L][ +][ S]..\\([ *]\\) +\\([-0-9]+\\) +\\([0-9?]+\\) +\\([^ ]+\\)\\) +" nil t)
 630       ;; If the username contains spaces, the output format is ambiguous,
 631       ;; so don't trust the output's filename unless we have to.
 632       (setq file (or filename
 633                      (expand-file-name
 634                       (buffer-substring (point) (line-end-position)))))
 635       (setq status (char-after (line-beginning-position)))
 636       (if (eq status ??)
 637           (vc-file-setprop file 'vc-state 'unregistered)
 638         ;; Use the last-modified revision, so that searching in vc-print-log
 639         ;; output works.
 640         (vc-file-setprop file 'vc-working-revision (match-string 3))
 641         ;; Remember Svn's own status.
 642         (vc-file-setprop file 'vc-svn-status status)
 643         (vc-file-setprop
 644          file 'vc-state
 645          (cond
 646           ((eq status ?\ )
 647            (if (eq (char-after (match-beginning 1)) ?*)
 648                'needs-update
 649              (vc-file-setprop file 'vc-checkout-time
 650                               (nth 5 (file-attributes file)))
 651              'up-to-date))
 652           ((eq status ?A)
 653            ;; If the file was actually copied, (match-string 2) is "-".
 654            (vc-file-setprop file 'vc-working-revision "0")
 655            (vc-file-setprop file 'vc-checkout-time 0)
 656            'added)
 657           ((eq status ?C)
 658            (vc-file-setprop file 'vc-state 'conflict))
 659           ((eq status '?M)
 660            (if (eq (char-after (match-beginning 1)) ?*)
 661                'needs-merge
 662              'edited))
 663           ((eq status ?I)
 664            (vc-file-setprop file 'vc-state 'ignored))
 665           ((memq status '(?D ?R))
 666            (vc-file-setprop file 'vc-state 'removed))
 667           (t 'edited)))))
 668     (when filename (vc-file-getprop filename 'vc-state))))
 669
 670 (defun vc-svn-valid-symbolic-tag-name-p (tag)
 671   "Return non-nil if TAG is a valid symbolic tag name."
 672   ;; According to the SVN manual, a valid symbolic tag must start with
 673   ;; an uppercase or lowercase letter and can contain uppercase and
 674   ;; lowercase letters, digits, `-', and `_'.
 675   (and (string-match "^[a-zA-Z]" tag)
 676        (not (string-match "[^a-z0-9A-Z-_]" tag))))
 677
 678 (defun vc-svn-valid-revision-number-p (tag)
 679   "Return non-nil if TAG is a valid revision number."
 680   (and (string-match "^[0-9]" tag)
 681        (not (string-match "[^0-9]" tag))))
 682
 683 ;; Support for `svn annotate'
 684
 685 (defun vc-svn-annotate-command (file buf &optional rev)
 686   (vc-svn-command buf 0 file "annotate" (if rev (concat "-r" rev))))
 687
 688 (defun vc-svn-annotate-time-of-rev (rev)
 689   ;; Arbitrarily assume 10 commmits per day.
 690   (/ (string-to-number rev) 10.0))
 691
 692 (defvar vc-annotate-parent-rev)
 693
 694 (defun vc-svn-annotate-current-time ()
 695   (vc-svn-annotate-time-of-rev vc-annotate-parent-rev))
 696
 697 (defconst vc-svn-annotate-re "[ \t]*\\([0-9]+\\)[ \t]+[^\t ]+ ")
 698
 699 (defun vc-svn-annotate-time ()
 700   (when (looking-at vc-svn-annotate-re)
 701     (goto-char (match-end 0))
 702     (vc-svn-annotate-time-of-rev (match-string 1))))
 703
 704 (defun vc-svn-annotate-extract-revision-at-line ()
 705   (save-excursion
 706     (beginning-of-line)
 707     (if (looking-at vc-svn-annotate-re) (match-string 1))))
 708
 709 (provide 'vc-svn)
 710
 711 ;; arch-tag: 02f10c68-2b4d-453a-90fc-1eee6cfb268d
 712 ;;; vc-svn.el ends here