admin/admin.el

   1 ;;; admin.el --- utilities for Emacs administration
   2
   3 ;; Copyright (C) 2001, 2005 Free Software Foundation, Inc.
   4
   5 ;; This file is part of GNU Emacs.
   6
   7 ;; GNU Emacs is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation; either version 2, or (at your option)
  10 ;; any later version.
  11
  12 ;; GNU Emacs is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  20 ;; Boston, MA 02111-1307, USA.
  21
  22 ;;; Commentary:
  23
  24 ;; add-release-logs     Add ``Version X released'' change log entries.
  25 ;; set-version          Change Emacs version number in source tree.
  26
  27 ;;; Code:
  28
  29 (defun process-lines (program &rest args)
  30   "Execute PROGRAM with ARGS, returning its output as a list of lines.
  31 Signal an error if the program returns with a non-zero exit status."
  32   (with-temp-buffer
  33     (let ((status (apply 'call-process program nil (current-buffer) nil args)))
  34       (unless (eq status 0)
  35         (error "%s exited with status %s" program status))
  36       (goto-char (point-min))
  37       (let (lines)
  38         (while (not (eobp))
  39           (setq lines (cons (buffer-substring-no-properties
  40                              (line-beginning-position)
  41                              (line-end-position))
  42                             lines))
  43           (forward-line 1))
  44         (nreverse lines)))))
  45
  46 (defun add-release-logs (root version)
  47   "Add \"Version VERSION released.\" change log entries in ROOT.
  48 Root must be the root of an Emacs source tree."
  49   (interactive "DEmacs root directory: \nNVersion number: ")
  50   (setq root (expand-file-name root))
  51   (unless (file-exists-p (expand-file-name "src/emacs.c" root))
  52     (error "%s doesn't seem to be the root of an Emacs source tree" root))
  53   (require 'add-log)
  54   (let* ((logs (process-lines "find" root "-name" "ChangeLog"))
  55          (entry (format "%s  %s  <%s>\n\n\t* Version %s released.\n\n"
  56                         (funcall add-log-time-format)
  57                         (or add-log-full-name (user-full-name))
  58                         (or add-log-mailing-address user-mail-address)
  59                         version)))
  60     (dolist (log logs)
  61       (unless (string-match "/gnus/" log)
  62         (find-file log)
  63         (goto-char (point-min))
  64         (insert entry)))))
  65
  66 (defun set-version-in-file (root file version rx)
  67   (find-file (expand-file-name file root))
  68   (goto-char (point-min))
  69   (unless (re-search-forward rx nil t)
  70     (error "Version not found in %s" file))
  71   (replace-match (format "%s" version) nil nil nil 1))
  72
  73 (defun set-version (root version)
  74   "Set Emacs version to VERSION in relevant files under ROOT.
  75 Root must be the root of an Emacs source tree."
  76   (interactive "DEmacs root directory: \nsVersion number: ")
  77   (unless (file-exists-p (expand-file-name "src/emacs.c" root))
  78     (error "%s doesn't seem to be the root of an Emacs source tree" root))
  79   (set-version-in-file root "lisp/version.el" version
  80                        (rx (and "emacs-version" (0+ space)
  81                                 ?\" (submatch (1+ (not (in ?\")))) ?\")))
  82   (set-version-in-file root "README" version
  83                        (rx (and "version" (1+ space)
  84                                 (submatch (1+ (in "0-9."))))))
  85   (set-version-in-file root "man/emacs.texi" version
  86                        (rx (and "EMACSVER" (1+ space)
  87                                 (submatch (1+ (in "0-9.")))))))
  88
  89 ;;; arch-tag: 4ea83636-2293-408b-884e-ad64f22a3bf5
  90 ;; admin.el ends here.