lisp/version.el

   1 ;;; version.el --- record version number of Emacs
   2
   3 ;; Copyright (C) 1985, 1992, 1994-1995, 1999-2012
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal
   8 ;; Package: emacs
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (defconst emacs-major-version
  30   (progn (string-match "^[0-9]+" emacs-version)
  31          (string-to-number (match-string 0 emacs-version)))
  32   "Major version number of this version of Emacs.
  33 This variable first existed in version 19.23.")
  34
  35 (defconst emacs-minor-version
  36   (progn (string-match "^[0-9]+\\.\\([0-9]+\\)" emacs-version)
  37          (string-to-number (match-string 1 emacs-version)))
  38   "Minor version number of this version of Emacs.
  39 This variable first existed in version 19.23.")
  40
  41 (defconst emacs-build-time (current-time)
  42   "Time at which Emacs was dumped out.")
  43
  44 (defconst emacs-build-system (system-name)
  45   "Name of the system on which Emacs was built.")
  46
  47 (defvar motif-version-string)
  48 (defvar gtk-version-string)
  49 (defvar ns-version-string)
  50
  51 (defun emacs-version (&optional here)
  52   "Return string describing the version of Emacs that is running.
  53 If optional argument HERE is non-nil, insert string at point.
  54 Don't use this function in programs to choose actions according
  55 to the system configuration; look at `system-configuration' instead."
  56   (interactive "P")
  57   (let ((version-string
  58          (format (if (not (called-interactively-p 'interactive))
  59                      "GNU Emacs %s (%s%s%s)\n of %s on %s"
  60                    "GNU Emacs %s (%s%s%s) of %s on %s")
  61                  emacs-version
  62                  system-configuration
  63                  (cond ((featurep 'motif)
  64                         (concat ", " (substring motif-version-string 4)))
  65                        ((featurep 'gtk)
  66                         (concat ", GTK+ Version " gtk-version-string))
  67                        ((featurep 'x-toolkit) ", X toolkit")
  68                        ((featurep 'ns)
  69                         (format ", NS %s" ns-version-string))
  70                        (t ""))
  71                  (if (and (boundp 'x-toolkit-scroll-bars)
  72                           (memq x-toolkit-scroll-bars '(xaw xaw3d)))
  73                      (format ", %s scroll bars"
  74                              (capitalize (symbol-name x-toolkit-scroll-bars)))
  75                    "")
  76                  (format-time-string "%Y-%m-%d" emacs-build-time)
  77                  emacs-build-system)))
  78     (if here
  79         (insert version-string)
  80       (if (called-interactively-p 'interactive)
  81           (message "%s" version-string)
  82         version-string))))
  83
  84 ;; We hope that this alias is easier for people to find.
  85 (defalias 'version 'emacs-version)
  86
  87 ;; Set during dumping, this is a defvar so that it can be setq'd.
  88 (defvar emacs-bzr-version nil
  89   "String giving the bzr revision from which this Emacs was built.
  90 The format is: [revno] revision_id, where revno may be absent.
  91 Value is nil if Emacs was not built from a bzr checkout, or if we could
  92 not determine the revision.")
  93
  94 (defun emacs-bzr-version-dirstate (dir)
  95   "Try to return as a string the bzr revision ID of directory DIR.
  96 This uses the dirstate file's parent revision entry.
  97 Returns nil if unable to find this information."
  98   (let ((file (expand-file-name ".bzr/checkout/dirstate" dir)))
  99     (when (file-readable-p file)
 100       (with-temp-buffer
 101         (insert-file-contents file)
 102         (and (looking-at "#bazaar dirstate flat format 3")
 103              (forward-line 3)
 104              (looking-at "[0-9]+\0\\([^\0\n]+\\)\0")
 105              (match-string 1))))))
 106
 107 (defun emacs-bzr-version-bzr (dir)
 108   "Ask bzr itself for the version information for directory DIR."
 109   ;; Comments on `bzr version-info':
 110   ;; i) Unknown files also cause clean != 1.
 111   ;; ii) It can be slow, contacting the upstream repo to get the
 112   ;; branch nick if one is not set locally, even with a custom
 113   ;; template that is not asking for the nick (as used here).  You'd
 114   ;; think the latter part would be trivial to fix:
 115   ;; https://bugs.launchpad.net/bzr/+bug/882541/comments/3
 116   ;; https://bugs.launchpad.net/bzr/+bug/629150
 117   ;; You can set the nick locally with `bzr nick ...', which speeds
 118   ;; things up enormously.  `bzr revno' does not have this issue, but
 119   ;; has no way to print the revision_id AFAICS.
 120   (message "Waiting for bzr...")
 121   (with-temp-buffer
 122     (if (zerop
 123          (call-process "bzr" nil '(t nil) nil "version-info"
 124                        "--custom"
 125                        "--template={revno} {revision_id} (clean = {clean})"
 126                        "dir"))
 127         (buffer-string))))
 128
 129 (defun emacs-bzr-get-version (&optional dir external)
 130   "Try to return as a string the bzr revision of the Emacs sources.
 131 The format is: [revno] revision_id, where revno may be absent.
 132 Value is nil if the sources do not seem to be under bzr, or if we could
 133 not determine the revision.  Note that this reports on the current state
 134 of the sources, which may not correspond to the running Emacs.
 135
 136 Optional argument DIR is a directory to use instead of `source-directory'.
 137 Optional argument EXTERNAL non-nil means to maybe ask `bzr' itself,
 138 if the sources appear to be under bzr.  If `force', always ask bzr.
 139 Otherwise only ask bzr if we cannot find any information ourselves."
 140   (or dir (setq dir source-directory))
 141   (when (file-directory-p (expand-file-name ".bzr/branch" dir))
 142     (if (eq external 'force)
 143         (emacs-bzr-version-bzr dir)
 144       (let (file loc rev)
 145         (cond ((file-readable-p
 146                 (setq file (expand-file-name ".bzr/branch/last-revision" dir)))
 147                (with-temp-buffer
 148                  (insert-file-contents file)
 149                  (goto-char (point-max))
 150                  (if (looking-back "\n")
 151                      (delete-char -1))
 152                  (buffer-string)))
 153               ;; OK, no last-revision.  Is it a lightweight checkout?
 154               ((file-readable-p
 155                 (setq file (expand-file-name ".bzr/branch/location" dir)))
 156                (setq rev (emacs-bzr-version-dirstate dir))
 157                ;; If the parent branch is local, try looking there for the rev.
 158                ;; Note: there is no guarantee that the parent branch's rev
 159                ;; corresponds to this branch.  This branch could have
 160                ;; been made with a specific -r revno argument, or the
 161                ;; parent could have been updated since this branch was created.
 162                ;; To try and detect this, we check the dirstate revids
 163                ;; to see if they match.
 164                (if (and (setq loc (with-temp-buffer
 165                                     (insert-file-contents file)
 166                                     (if (looking-at "file://\\(.*\\)")
 167                                         (match-string 1))))
 168                         (equal rev (emacs-bzr-version-dirstate loc)))
 169                    (emacs-bzr-get-version loc)
 170                  ;; If parent does not match, the best we can do without
 171                  ;; calling external commands is to use the dirstate rev.
 172                  rev))
 173               (external
 174                (emacs-bzr-version-bzr dir)))))))
 175
 176 ;; We put version info into the executable in the form that `ident' uses.
 177 (purecopy (concat "\n$Id: " (subst-char-in-string ?\n ?\s (emacs-version))
 178                   " $\n"))
 179
 180 ;;; version.el ends here