lisp/autorevert.el

   1 ;;; autorevert.el --- revert buffers when files on disk change
   2
   3 ;; Copyright (C) 1997-1999, 2001-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Anders Lindgren <andersl@andersl.com>
   6 ;; Keywords: convenience
   7 ;; Created: 1997-06-01
   8 ;; Date: 1999-11-30
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Introduction:
  28 ;;
  29 ;; Whenever a file that Emacs is editing has been changed by another
  30 ;; program the user normally has to execute the command `revert-buffer'
  31 ;; to load the new content of the file into Emacs.
  32 ;;
  33 ;; This package contains two minor modes: Global Auto-Revert Mode and
  34 ;; Auto-Revert Mode.  Both modes automatically revert buffers
  35 ;; whenever the corresponding files have been changed on disk and the
  36 ;; buffer contains no unsaved changes.
  37 ;;
  38 ;; Auto-Revert Mode can be activated for individual buffers.  Global
  39 ;; Auto-Revert Mode applies to all file buffers. (If the user option
  40 ;; `global-auto-revert-non-file-buffers' is non-nil, it also applies
  41 ;; to some non-file buffers.  This option is disabled by default.)
  42 ;; Since checking a remote file is too slow, these modes do not check
  43 ;; or revert remote files.
  44 ;;
  45 ;; Both modes operate by checking the time stamp of all files at
  46 ;; intervals of `auto-revert-interval'.  The default is every five
  47 ;; seconds.  The check is aborted whenever the user actually uses
  48 ;; Emacs.  You should never even notice that this package is active
  49 ;; (except that your buffers will be reverted, of course).
  50 ;;
  51 ;; After reverting a file buffer, Auto Revert Mode normally puts point
  52 ;; at the same position that a regular manual revert would.  However,
  53 ;; there is one exception to this rule.  If point is at the end of the
  54 ;; buffer before reverting, it stays at the end.  Similarly if point
  55 ;; is displayed at the end of a file buffer in any window, it will stay
  56 ;; at the end of the buffer in that window, even if the window is not
  57 ;; selected.  This way, you can use Auto Revert Mode to `tail' a file.
  58 ;; Just put point at the end of the buffer and it will stay there.
  59 ;; These rules apply to file buffers. For non-file buffers, the
  60 ;; behavior may be mode dependent.
  61 ;;
  62 ;; While you can use Auto Revert Mode to tail a file, this package
  63 ;; contains a third minor mode, Auto Revert Tail Mode, which does so
  64 ;; more efficiently, as long as you are sure that the file will only
  65 ;; change by growing at the end.  It only appends the new output,
  66 ;; instead of reverting the entire buffer.  It does so even if the
  67 ;; buffer contains unsaved changes.  (Because they will not be lost.)
  68 ;; Auto Revert Tail Mode works also for remote files.
  69
  70 ;; Usage:
  71 ;;
  72 ;; Go to the appropriate buffer and press either of:
  73 ;;   M-x auto-revert-mode RET
  74 ;;   M-x auto-revert-tail-mode RET
  75 ;;
  76 ;; To activate Global Auto-Revert Mode, press:
  77 ;;   M-x global-auto-revert-mode RET
  78 ;;
  79 ;; To activate Global Auto-Revert Mode every time Emacs is started
  80 ;; customize the option `global-auto-revert-mode' or the following
  81 ;; line could be added to your ~/.emacs:
  82 ;;   (global-auto-revert-mode 1)
  83 ;;
  84 ;; The function `turn-on-auto-revert-mode' could be added to any major
  85 ;; mode hook to activate Auto-Revert Mode for all buffers in that
  86 ;; mode.  For example, the following line will activate Auto-Revert
  87 ;; Mode in all C mode buffers:
  88 ;;
  89 ;; (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)
  90
  91 ;;; Code:
  92
  93 ;; Dependencies:
  94
  95 (require 'timer)
  96
  97 ;; Custom Group:
  98 ;;
  99 ;; The two modes will be placed next to Auto Save Mode under the
 100 ;; Files group under Emacs.
 101
 102 (defgroup auto-revert nil
 103   "Revert individual buffers when files on disk change.
 104 Auto-Revert mode enables auto-revert in individual buffers.
 105 Global Auto-Revert mode does so in all buffers."
 106   :group 'files
 107   :group 'convenience)
 108
 109
 110 ;; Variables:
 111
 112 ;;; What's this?: ;; Autoload for the benefit of `make-mode-line-mouse-sensitive'.
 113 ;;; What's this?: ;;;###autoload
 114 (defvar auto-revert-mode nil
 115   "Non-nil when Auto-Revert Mode is active.
 116 Never set this variable directly, use the command `auto-revert-mode' instead.")
 117 (put 'auto-revert-mode 'permanent-local t)
 118
 119 (defvar auto-revert-tail-mode nil
 120   "Non-nil when Auto-Revert Tail Mode is active.
 121 Never set this variable directly, use the command
 122 `auto-revert-tail-mode' instead.")
 123 (put 'auto-revert-tail-mode 'permanent-local t)
 124
 125 (defvar auto-revert-timer nil
 126   "Timer used by Auto-Revert Mode.")
 127
 128 (defcustom auto-revert-interval 5
 129   "Time, in seconds, between Auto-Revert Mode file checks.
 130 The value may be an integer or floating point number.
 131
 132 If a timer is already active, there are two ways to make sure
 133 that the new value will take effect immediately.  You can set
 134 this variable through Custom or you can call the command
 135 `auto-revert-set-timer' after setting the variable.  Otherwise,
 136 the new value will take effect the first time Auto Revert Mode
 137 calls `auto-revert-set-timer' for internal reasons or in your
 138 next editing session."
 139   :group 'auto-revert
 140   :type 'number
 141   :set (lambda (variable value)
 142          (set-default variable value)
 143          (and (boundp 'auto-revert-timer)
 144               auto-revert-timer
 145               (auto-revert-set-timer))))
 146
 147 (defcustom auto-revert-stop-on-user-input t
 148   "When non-nil, user input temporarily interrupts Auto-Revert Mode.
 149 With this setting, Auto-Revert Mode checks for user input after
 150 handling each buffer and does not process any further buffers
 151 \(until the next run of the timer) if user input is available.
 152 When nil, Auto-Revert Mode checks files and reverts buffers,
 153 with quitting disabled, without paying attention to user input.
 154 Thus, with this setting, Emacs might be non-responsive at times."
 155   :group 'auto-revert
 156   :type 'boolean)
 157
 158 (defcustom auto-revert-verbose t
 159   "When nil, Auto-Revert Mode does not generate any messages.
 160 When non-nil, a message is generated whenever a file is reverted."
 161   :group 'auto-revert
 162   :type 'boolean)
 163
 164 (defcustom auto-revert-mode-text " ARev"
 165   "String to display in the mode line when Auto-Revert Mode is active.
 166
 167 \(When the string is not empty, make sure that it has a leading space.)"
 168   :tag "Auto Revert Mode Text"          ; To separate it from `global-...'
 169   :group 'auto-revert
 170   :type 'string)
 171
 172 (defcustom auto-revert-tail-mode-text " Tail"
 173   "String to display in the mode line when Auto-Revert Tail Mode is active.
 174
 175 \(When the string is not empty, make sure that it has a leading space.)"
 176   :group 'auto-revert
 177   :type 'string
 178   :version "22.1")
 179
 180 (defcustom auto-revert-mode-hook nil
 181   "Functions to run when Auto-Revert Mode is activated."
 182   :tag "Auto Revert Mode Hook"          ; To separate it from `global-...'
 183   :group 'auto-revert
 184   :type 'hook)
 185
 186 (defcustom global-auto-revert-mode-text ""
 187   "String to display when Global Auto-Revert Mode is active.
 188
 189 The default is nothing since when this mode is active this text doesn't
 190 vary over time, or between buffers.  Hence mode line text
 191 would only waste precious space."
 192   :group 'auto-revert
 193   :type 'string)
 194
 195 (defcustom global-auto-revert-mode-hook nil
 196   "Hook called when Global Auto-Revert Mode is activated."
 197   :group 'auto-revert
 198   :type 'hook)
 199
 200 (defcustom global-auto-revert-non-file-buffers nil
 201   "When nil, Global Auto-Revert mode operates only on file-visiting buffers.
 202
 203 When non-nil, both file buffers and buffers with a custom
 204 `revert-buffer-function' and a `buffer-stale-function' are
 205 reverted by Global Auto-Revert mode.  These include the Buffer
 206 List buffer displayed by `buffer-menu', and Dired buffers showing
 207 complete local directories.  The Buffer List buffer reverts every
 208 `auto-revert-interval' seconds; Dired buffers when the file list of
 209 the main directory changes.  Dired buffers do not auto-revert as
 210 a result of changes in subdirectories, or in the contents, size,
 211 modes, etc., of files.  You may still sometimes want to revert
 212 them manually.
 213
 214 Use this option with care since it could lead to excessive auto-reverts.
 215 For more information, see Info node `(emacs)Autorevert'."
 216   :group 'auto-revert
 217   :type 'boolean
 218   :link '(info-link "(emacs)Autorevert"))
 219
 220 (defcustom global-auto-revert-ignore-modes ()
 221   "List of major modes Global Auto-Revert Mode should not check."
 222   :group 'auto-revert
 223   :type '(repeat sexp))
 224
 225 (defcustom auto-revert-load-hook nil
 226   "Functions to run when Auto-Revert Mode is first loaded."
 227   :tag "Load Hook"
 228   :group 'auto-revert
 229   :type 'hook)
 230
 231 (defcustom auto-revert-check-vc-info nil
 232   "If non-nil Auto Revert Mode reliably updates version control info.
 233 Auto Revert Mode updates version control info whenever the buffer
 234 needs reverting, regardless of the value of this variable.
 235 However, the version control state can change without changes to
 236 the work file.  If the change is made from the current Emacs
 237 session, all info is updated.  But if, for instance, a new
 238 version is checked in from outside the current Emacs session, the
 239 version control number in the mode line, as well as other version
 240 control related information, may not be properly updated.  If you
 241 are worried about this, set this variable to a non-nil value.
 242
 243 This currently works by automatically updating the version
 244 control info every `auto-revert-interval' seconds.  Nevertheless,
 245 it should not cause excessive CPU usage on a reasonably fast
 246 machine, if it does not apply to too many version controlled
 247 buffers.  CPU usage depends on the version control system."
 248   :group 'auto-revert
 249   :type 'boolean
 250   :version "22.1")
 251
 252 (defvar global-auto-revert-ignore-buffer nil
 253   "When non-nil, Global Auto-Revert Mode will not revert this buffer.
 254 This variable becomes buffer local when set in any fashion.")
 255 (make-variable-buffer-local 'global-auto-revert-ignore-buffer)
 256
 257 ;; Internal variables:
 258
 259 (defvar auto-revert-buffer-list ()
 260   "List of buffers in Auto-Revert Mode.
 261
 262 Note that only Auto-Revert Mode, never Global Auto-Revert Mode, adds
 263 buffers to this list.
 264
 265 The timer function `auto-revert-buffers' is responsible for purging
 266 the list of old buffers.")
 267
 268 (defvar auto-revert-remaining-buffers ()
 269   "Buffers not checked when user input stopped execution.")
 270
 271 (defvar auto-revert-tail-pos 0
 272   "Position of last known end of file.")
 273
 274 (add-hook 'find-file-hook
 275           (lambda ()
 276             (set (make-local-variable 'auto-revert-tail-pos)
 277                  (nth 7 (file-attributes buffer-file-name)))))
 278
 279 ;; Functions:
 280
 281 ;;;###autoload
 282 (define-minor-mode auto-revert-mode
 283   "Toggle reverting buffer when the file changes (Auto Revert mode).
 284 With a prefix argument ARG, enable Auto Revert mode if ARG is
 285 positive, and disable it otherwise.  If called from Lisp, enable
 286 the mode if ARG is omitted or nil.
 287
 288 Auto Revert mode is a minor mode that affects only the current
 289 buffer.  When enabled, it reverts the buffer when the file on
 290 disk changes.
 291
 292 Use `global-auto-revert-mode' to automatically revert all buffers.
 293 Use `auto-revert-tail-mode' if you know that the file will only grow
 294 without being changed in the part that is already in the buffer."
 295   :group 'auto-revert :lighter auto-revert-mode-text
 296   (if auto-revert-mode
 297       (if (not (memq (current-buffer) auto-revert-buffer-list))
 298           (push (current-buffer) auto-revert-buffer-list))
 299     (setq auto-revert-buffer-list
 300           (delq (current-buffer) auto-revert-buffer-list)))
 301   (auto-revert-set-timer)
 302   (when auto-revert-mode
 303     (auto-revert-buffers)
 304     (setq auto-revert-tail-mode nil)))
 305
 306
 307 ;;;###autoload
 308 (defun turn-on-auto-revert-mode ()
 309   "Turn on Auto-Revert Mode.
 310
 311 This function is designed to be added to hooks, for example:
 312   (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)"
 313   (auto-revert-mode 1))
 314
 315
 316 ;;;###autoload
 317 (define-minor-mode auto-revert-tail-mode
 318   "Toggle reverting tail of buffer when the file grows.
 319 With a prefix argument ARG, enable Auto-Revert Tail mode if ARG
 320 is positive, and disable it otherwise.  If called from Lisp,
 321 enable the mode if ARG is omitted or nil.
 322
 323 When Auto Revert Tail mode is enabled, the tail of the file is
 324 constantly followed, as with the shell command `tail -f'.  This
 325 means that whenever the file grows on disk (presumably because
 326 some background process is appending to it from time to time),
 327 this is reflected in the current buffer.
 328
 329 You can edit the buffer and turn this mode off and on again as
 330 you please.  But make sure the background process has stopped
 331 writing before you save the file!
 332
 333 Use `auto-revert-mode' for changes other than appends!"
 334   :group 'find-file :lighter auto-revert-tail-mode-text
 335   (when auto-revert-tail-mode
 336     (unless buffer-file-name
 337       (auto-revert-tail-mode 0)
 338       (error "This buffer is not visiting a file"))
 339     (if (and (buffer-modified-p)
 340              (zerop auto-revert-tail-pos) ; library was loaded only after finding file
 341              (not (y-or-n-p "Buffer is modified, so tail offset may be wrong.  Proceed? ")))
 342         (auto-revert-tail-mode 0)
 343       ;; a-r-tail-pos stores the size of the file at the time of the
 344       ;; last revert. After this package loads, it adds a
 345       ;; find-file-hook to set this variable every time a file is
 346       ;; loaded.  If the package is loaded only _after_ visiting the
 347       ;; file to be reverted, then we have no idea what the value of
 348       ;; a-r-tail-pos should have been when the file was visited.  If
 349       ;; the file has changed on disk in the meantime, all we can do
 350       ;; is offer to revert the whole thing. If you choose not to
 351       ;; revert, then you might miss some output then happened
 352       ;; between visiting the file and activating a-r-t-mode.
 353       (and (zerop auto-revert-tail-pos)
 354            (not (verify-visited-file-modtime (current-buffer)))
 355            (y-or-n-p "File changed on disk, content may be missing.  \
 356 Perform a full revert? ")
 357            ;; Use this (not just revert-buffer) for point-preservation.
 358            (auto-revert-handler))
 359       ;; else we might reappend our own end when we save
 360       (add-hook 'before-save-hook (lambda () (auto-revert-tail-mode 0)) nil t)
 361       (or (local-variable-p 'auto-revert-tail-pos) ; don't lose prior position
 362           (set (make-local-variable 'auto-revert-tail-pos)
 363                (nth 7 (file-attributes buffer-file-name))))
 364       ;; let auto-revert-mode set up the mechanism for us if it isn't already
 365       (or auto-revert-mode
 366           (let ((auto-revert-tail-mode t))
 367             (auto-revert-mode 1)))
 368       (setq auto-revert-mode nil))))
 369
 370
 371 ;;;###autoload
 372 (defun turn-on-auto-revert-tail-mode ()
 373   "Turn on Auto-Revert Tail mode.
 374
 375 This function is designed to be added to hooks, for example:
 376   (add-hook 'my-logfile-mode-hook 'turn-on-auto-revert-tail-mode)"
 377   (auto-revert-tail-mode 1))
 378
 379
 380 ;;;###autoload
 381 (define-minor-mode global-auto-revert-mode
 382   "Toggle Global Auto Revert mode.
 383 With a prefix argument ARG, enable Global Auto Revert mode if ARG
 384 is positive, and disable it otherwise.  If called from Lisp,
 385 enable the mode if ARG is omitted or nil.
 386
 387 Global Auto Revert mode is a global minor mode that reverts any
 388 buffer associated with a file when the file changes on disk.  Use
 389 `auto-revert-mode' to revert a particular buffer.
 390
 391 If `global-auto-revert-non-file-buffers' is non-nil, this mode
 392 may also revert some non-file buffers, as described in the
 393 documentation of that variable.  It ignores buffers with modes
 394 matching `global-auto-revert-ignore-modes', and buffers with a
 395 non-nil vale of `global-auto-revert-ignore-buffer'.
 396
 397 This function calls the hook `global-auto-revert-mode-hook'.
 398 It displays the text that `global-auto-revert-mode-text'
 399 specifies in the mode line."
 400   :global t :group 'auto-revert :lighter global-auto-revert-mode-text
 401   (auto-revert-set-timer)
 402   (when global-auto-revert-mode
 403     (auto-revert-buffers)))
 404
 405
 406 (defun auto-revert-set-timer ()
 407   "Restart or cancel the timer used by Auto-Revert Mode.
 408 If such a timer is active, cancel it.  Start a new timer if
 409 Global Auto-Revert Mode is active or if Auto-Revert Mode is active
 410 in some buffer.  Restarting the timer ensures that Auto-Revert Mode
 411 will use an up-to-date value of `auto-revert-interval'"
 412   (interactive)
 413   (if (timerp auto-revert-timer)
 414       (cancel-timer auto-revert-timer))
 415   (setq auto-revert-timer
 416         (if (or global-auto-revert-mode auto-revert-buffer-list)
 417             (run-with-timer auto-revert-interval
 418                             auto-revert-interval
 419                             'auto-revert-buffers))))
 420
 421 (defun auto-revert-active-p ()
 422   "Check if auto-revert is active (in current buffer or globally)."
 423   (or auto-revert-mode
 424       auto-revert-tail-mode
 425       (and
 426        global-auto-revert-mode
 427        (not global-auto-revert-ignore-buffer)
 428        (not (memq major-mode
 429                   global-auto-revert-ignore-modes)))))
 430
 431 (defun auto-revert-handler ()
 432   "Revert current buffer, if appropriate.
 433 This is an internal function used by Auto-Revert Mode."
 434   (when (or auto-revert-tail-mode (not (buffer-modified-p)))
 435     (let* ((buffer (current-buffer)) size
 436            (revert
 437             (or (and buffer-file-name
 438                      (if auto-revert-tail-mode
 439                          ;; Tramp caches the file attributes.  Setting
 440                          ;; `remote-file-name-inhibit-cache' forces Tramp
 441                          ;; to reread the values.
 442                          (let ((remote-file-name-inhibit-cache t))
 443                            (and (file-readable-p buffer-file-name)
 444                                 (/= auto-revert-tail-pos
 445                                     (setq size
 446                                           (nth 7 (file-attributes
 447                                                   buffer-file-name))))))
 448                        (and (not (file-remote-p buffer-file-name))
 449                             (file-readable-p buffer-file-name)
 450                             (not (verify-visited-file-modtime buffer)))))
 451                 (and (or auto-revert-mode
 452                          global-auto-revert-non-file-buffers)
 453                      revert-buffer-function
 454                      (boundp 'buffer-stale-function)
 455                      (functionp buffer-stale-function)
 456                      (funcall buffer-stale-function t))))
 457            eob eoblist)
 458       (when revert
 459         (when (and auto-revert-verbose
 460                    (not (eq revert 'fast)))
 461           (message "Reverting buffer `%s'." (buffer-name)))
 462         ;; If point (or a window point) is at the end of the buffer,
 463         ;; we want to keep it at the end after reverting.  This allows
 464         ;; to tail a file.
 465         (when buffer-file-name
 466           (setq eob (eobp))
 467           (walk-windows
 468            (lambda (window)
 469              (and (eq (window-buffer window) buffer)
 470                   (= (window-point window) (point-max))
 471                   (push window eoblist)))
 472            'no-mini t))
 473         (if auto-revert-tail-mode
 474             (auto-revert-tail-handler size)
 475           ;; Bind buffer-read-only in case user has done C-x C-q,
 476           ;; so as not to forget that.  This gives undesirable results
 477           ;; when the file's mode changes, but that is less common.
 478           (let ((buffer-read-only buffer-read-only))
 479             (revert-buffer 'ignore-auto 'dont-ask 'preserve-modes)))
 480         (when buffer-file-name
 481           (when eob (goto-char (point-max)))
 482           (dolist (window eoblist)
 483             (set-window-point window (point-max)))))
 484       ;; `preserve-modes' avoids changing the (minor) modes.  But we
 485       ;; do want to reset the mode for VC, so we do it manually.
 486       (when (or revert auto-revert-check-vc-info)
 487         (vc-find-file-hook)))))
 488
 489 (defun auto-revert-tail-handler (size)
 490   (let ((modified (buffer-modified-p))
 491         (inhibit-read-only t)           ; Ignore.
 492         (file buffer-file-name)
 493         (buffer-file-name nil))         ; Ignore that file has changed.
 494     (when (/= auto-revert-tail-pos size)
 495       (run-hooks 'before-revert-hook)
 496       (undo-boundary)
 497       (save-restriction
 498         (widen)
 499         (save-excursion
 500           (goto-char (point-max))
 501           (insert-file-contents file nil
 502                                 (and (< auto-revert-tail-pos size)
 503                                      auto-revert-tail-pos)
 504                                 size)))
 505       (run-hooks 'after-revert-hook)
 506       (undo-boundary)
 507       (setq auto-revert-tail-pos size)
 508       (restore-buffer-modified-p modified)))
 509   (set-visited-file-modtime))
 510
 511 (defun auto-revert-buffers ()
 512   "Revert buffers as specified by Auto-Revert and Global Auto-Revert Mode.
 513
 514 Should `global-auto-revert-mode' be active all file buffers are checked.
 515
 516 Should `auto-revert-mode' be active in some buffers, those buffers
 517 are checked.
 518
 519 Non-file buffers that have a custom `revert-buffer-function' and
 520 a `buffer-stale-function' are reverted either when Auto-Revert
 521 Mode is active in that buffer, or when the variable
 522 `global-auto-revert-non-file-buffers' is non-nil and Global
 523 Auto-Revert Mode is active.
 524
 525 This function stops whenever there is user input.  The buffers not
 526 checked are stored in the variable `auto-revert-remaining-buffers'.
 527
 528 To avoid starvation, the buffers in `auto-revert-remaining-buffers'
 529 are checked first the next time this function is called.
 530
 531 This function is also responsible for removing buffers no longer in
 532 Auto-Revert mode from `auto-revert-buffer-list', and for canceling
 533 the timer when no buffers need to be checked."
 534   (save-match-data
 535     (let ((bufs (if global-auto-revert-mode
 536                     (buffer-list)
 537                   auto-revert-buffer-list))
 538           (remaining ())
 539           (new ()))
 540       ;; Partition `bufs' into two halves depending on whether or not
 541       ;; the buffers are in `auto-revert-remaining-buffers'.  The two
 542       ;; halves are then re-joined with the "remaining" buffers at the
 543       ;; head of the list.
 544       (dolist (buf auto-revert-remaining-buffers)
 545         (if (memq buf bufs)
 546             (push buf remaining)))
 547       (dolist (buf bufs)
 548         (if (not (memq buf remaining))
 549             (push buf new)))
 550       (setq bufs (nreverse (nconc new remaining)))
 551       (while (and bufs
 552                   (not (and auto-revert-stop-on-user-input
 553                             (input-pending-p))))
 554         (let ((buf (car bufs)))
 555           (if (buffer-live-p buf)
 556               (with-current-buffer buf
 557                 ;; Test if someone has turned off Auto-Revert Mode in a
 558                 ;; non-standard way, for example by changing major mode.
 559                 (if (and (not auto-revert-mode)
 560                          (not auto-revert-tail-mode)
 561                          (memq buf auto-revert-buffer-list))
 562                     (setq auto-revert-buffer-list
 563                           (delq buf auto-revert-buffer-list)))
 564                 (when (auto-revert-active-p) (auto-revert-handler)))
 565             ;; Remove dead buffer from `auto-revert-buffer-list'.
 566             (setq auto-revert-buffer-list
 567                   (delq buf auto-revert-buffer-list))))
 568         (setq bufs (cdr bufs)))
 569       (setq auto-revert-remaining-buffers bufs)
 570       ;; Check if we should cancel the timer.
 571       (when (and (not global-auto-revert-mode)
 572                  (null auto-revert-buffer-list))
 573         (cancel-timer auto-revert-timer)
 574         (setq auto-revert-timer nil)))))
 575
 576
 577 ;; The end:
 578 (provide 'autorevert)
 579
 580 (run-hooks 'auto-revert-load-hook)
 581
 582 ;;; autorevert.el ends here