lisp/eshell/em-ls.el

   1 ;;; em-ls.el --- implementation of ls in Lisp  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 1999-2017 Free Software Foundation, Inc.
   4
   5 ;; Author: John Wiegley <johnw@gnu.org>
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
  21
  22 ;;; Commentary:
  23
  24 ;; Most of the command switches recognized by GNU's ls utility are
  25 ;; supported ([(fileutils)ls invocation]).
  26
  27 ;;; Code:
  28
  29 (require 'cl-lib)
  30 (require 'esh-util)
  31 (require 'esh-opt)
  32 (eval-when-compile (require 'eshell))
  33
  34 ;;;###autoload
  35 (progn
  36 (defgroup eshell-ls nil
  37   "This module implements the \"ls\" utility fully in Lisp.  If it is
  38 passed any unrecognized command switches, it will revert to the
  39 operating system's version.  This version of \"ls\" uses text
  40 properties to colorize its output based on the setting of
  41 `eshell-ls-use-colors'."
  42   :tag "Implementation of `ls' in Lisp"
  43   :group 'eshell-module))
  44
  45 ;;; User Variables:
  46
  47 (defcustom eshell-ls-date-format "%Y-%m-%d"
  48   "How to display time information in `eshell-ls-file'.
  49 This is passed to `format-time-string' as a format string.
  50 To display the date using the current locale, use \"%b \ %e\"."
  51   :version "24.1"
  52   :type 'string)
  53
  54 (defcustom eshell-ls-initial-args nil
  55   "If non-nil, this list of args is included before any call to `ls'.
  56 This is useful for enabling human-readable format (-h), for example."
  57   :type '(repeat :tag "Arguments" string))
  58
  59 (defcustom eshell-ls-dired-initial-args nil
  60   "If non-nil, args is included before any call to `ls' in Dired.
  61 This is useful for enabling human-readable format (-h), for example."
  62   :type '(repeat :tag "Arguments" string))
  63
  64 (defcustom eshell-ls-use-in-dired nil
  65   "If non-nil, use `eshell-ls' to read directories in Dired.
  66 Changing this without using customize has no effect."
  67   :set (lambda (symbol value)
  68          (cond (value
  69                 (require 'dired)
  70                 (advice-add 'insert-directory :around
  71                             #'eshell-ls--insert-directory)
  72                 (advice-add 'dired :around #'eshell-ls--dired))
  73                (t
  74                 (advice-remove 'insert-directory
  75                                #'eshell-ls--insert-directory)
  76                 (advice-remove 'dired #'eshell-ls--dired)))
  77          (set symbol value))
  78   :type 'boolean
  79   :require 'em-ls)
  80 (add-hook 'eshell-ls-unload-hook #'eshell-ls-unload-function)
  81
  82
  83 (defcustom eshell-ls-default-blocksize 1024
  84   "The default blocksize to use when display file sizes with -s."
  85   :type 'integer)
  86
  87 (defcustom eshell-ls-exclude-regexp nil
  88   "Unless -a is specified, files matching this regexp will not be shown."
  89   :type '(choice regexp (const nil)))
  90
  91 (defcustom eshell-ls-exclude-hidden t
  92   "Unless -a is specified, files beginning with . will not be shown.
  93 Using this boolean, instead of `eshell-ls-exclude-regexp', is both
  94 faster and conserves more memory."
  95   :type 'boolean)
  96
  97 (defcustom eshell-ls-use-colors t
  98   "If non-nil, use colors in file listings."
  99   :type 'boolean)
 100
 101 (defface eshell-ls-directory
 102   '((((class color) (background light)) (:foreground "Blue" :weight bold))
 103     (((class color) (background dark)) (:foreground "SkyBlue" :weight bold))
 104     (t (:weight bold)))
 105   "The face used for highlighting directories.")
 106
 107 (defface eshell-ls-symlink
 108   '((((class color) (background light)) (:foreground "Dark Cyan" :weight bold))
 109     (((class color) (background dark)) (:foreground "Cyan" :weight bold)))
 110   "The face used for highlighting symbolic links.")
 111
 112 (defface eshell-ls-executable
 113   '((((class color) (background light)) (:foreground "ForestGreen" :weight bold))
 114     (((class color) (background dark)) (:foreground "Green" :weight bold)))
 115   "The face used for highlighting executables (not directories, though).")
 116
 117 (defface eshell-ls-readonly
 118   '((((class color) (background light)) (:foreground "Brown"))
 119     (((class color) (background dark)) (:foreground "Pink")))
 120   "The face used for highlighting read-only files.")
 121
 122 (defface eshell-ls-unreadable
 123   '((((class color) (background light)) (:foreground "Grey30"))
 124     (((class color) (background dark)) (:foreground "DarkGrey")))
 125   "The face used for highlighting unreadable files.")
 126
 127 (defface eshell-ls-special
 128   '((((class color) (background light)) (:foreground "Magenta" :weight bold))
 129     (((class color) (background dark)) (:foreground "Magenta" :weight bold)))
 130   "The face used for highlighting non-regular files.")
 131
 132 (defface eshell-ls-missing
 133   '((((class color) (background light)) (:foreground "Red" :weight bold))
 134     (((class color) (background dark)) (:foreground "Red" :weight bold)))
 135   "The face used for highlighting non-existent file names.")
 136
 137 (defcustom eshell-ls-archive-regexp
 138   (concat "\\.\\(t\\(a[rz]\\|gz\\)\\|arj\\|lzh\\|"
 139           "zip\\|[zZ]\\|gz\\|bz2\\|xz\\|deb\\|rpm\\)\\'")
 140   "A regular expression that matches names of file archives.
 141 This typically includes both traditional archives and compressed
 142 files."
 143   :version "24.1"                       ; added xz
 144   :type 'regexp)
 145
 146 (defface eshell-ls-archive
 147   '((((class color) (background light)) (:foreground "Orchid" :weight bold))
 148     (((class color) (background dark)) (:foreground "Orchid" :weight bold)))
 149   "The face used for highlighting archived and compressed file names.")
 150
 151 (defcustom eshell-ls-backup-regexp
 152   "\\(\\`\\.?#\\|\\(\\.bak\\|~\\)\\'\\)"
 153   "A regular expression that matches names of backup files."
 154   :type 'regexp)
 155
 156 (defface eshell-ls-backup
 157   '((((class color) (background light)) (:foreground "OrangeRed"))
 158     (((class color) (background dark)) (:foreground "LightSalmon")))
 159   "The face used for highlighting backup file names.")
 160
 161 (defcustom eshell-ls-product-regexp
 162   "\\.\\(elc\\|o\\(bj\\)?\\|a\\|lib\\|res\\)\\'"
 163   "A regular expression that matches names of product files.
 164 Products are files that get generated from a source file, and hence
 165 ought to be recreatable if they are deleted."
 166   :type 'regexp)
 167
 168 (defface eshell-ls-product
 169   '((((class color) (background light)) (:foreground "OrangeRed"))
 170     (((class color) (background dark)) (:foreground "LightSalmon")))
 171   "The face used for highlighting files that are build products.")
 172
 173 (defcustom eshell-ls-clutter-regexp
 174   "\\(^texput\\.log\\|^core\\)\\'"
 175   "A regular expression that matches names of junk files.
 176 These are mainly files that get created for various reasons, but don't
 177 really need to stick around for very long."
 178   :type 'regexp)
 179
 180 (defface eshell-ls-clutter
 181   '((((class color) (background light)) (:foreground "OrangeRed" :weight bold))
 182     (((class color) (background dark)) (:foreground "OrangeRed" :weight bold)))
 183   "The face used for highlighting junk file names.")
 184
 185 (defsubst eshell-ls-filetype-p (attrs type)
 186   "Test whether ATTRS specifies a directory."
 187   (if (nth 8 attrs)
 188       (eq (aref (nth 8 attrs) 0) type)))
 189
 190 (defmacro eshell-ls-applicable (attrs index func file)
 191   "Test whether, for ATTRS, the user can do what corresponds to INDEX.
 192 ATTRS is a string of file modes.  See `file-attributes'.
 193 If we cannot determine the answer using ATTRS (e.g., if we need
 194 to know what group the user is in), compute the return value by
 195 calling FUNC with FILE as an argument."
 196   `(let ((owner (nth 2 ,attrs))
 197          (modes (nth 8 ,attrs)))
 198      (cond ((cond ((numberp owner)
 199                    (= owner (user-uid)))
 200                   ((stringp owner)
 201                    (or (string-equal owner (user-login-name))
 202                        (member owner (eshell-current-ange-uids)))))
 203             ;; The user owns this file.
 204             (not (eq (aref modes ,index) ?-)))
 205            ((eq (aref modes (+ ,index 3))
 206                 (aref modes (+ ,index 6)))
 207             ;; If the "group" and "other" fields give identical
 208             ;; results, use that.
 209             (not (eq (aref modes (+ ,index 3)) ?-)))
 210            (t
 211             ;; Otherwise call FUNC.
 212             (,(eval func) ,file)))))
 213
 214 (defcustom eshell-ls-highlight-alist nil
 215   "This alist correlates test functions to color.
 216 The format of the members of this alist is
 217
 218   (TEST-SEXP . FACE)
 219
 220 If TEST-SEXP evals to non-nil, that face will be used to highlight the
 221 name of the file.  The first match wins.  `file' and `attrs' are in
 222 scope during the evaluation of TEST-SEXP."
 223   :type '(repeat (cons function face)))
 224
 225 (defvar block-size)
 226 (defvar dereference-links)
 227 (defvar dir-literal)
 228 (defvar error-func)
 229 (defvar flush-func)
 230 (defvar human-readable)
 231 (defvar ignore-pattern)
 232 (defvar insert-func)
 233 (defvar listing-style)
 234 (defvar numeric-uid-gid)
 235 (defvar reverse-list)
 236 (defvar show-all)
 237 (defvar show-almost-all)
 238 (defvar show-recursive)
 239 (defvar show-size)
 240 (defvar sort-method)
 241 (defvar ange-cache)
 242 (defvar dired-flag)
 243
 244 ;;; Functions:
 245
 246 (declare-function eshell-extended-glob "em-glob" (glob))
 247 (defvar eshell-error-if-no-glob)
 248
 249 (defun eshell-ls--insert-directory
 250   (orig-fun file switches &optional wildcard full-directory-p)
 251   "Insert directory listing for FILE, formatted according to SWITCHES.
 252 Leaves point after the inserted text.
 253 SWITCHES may be a string of options, or a list of strings.
 254 Optional third arg WILDCARD means treat FILE as shell wildcard.
 255 Optional fourth arg FULL-DIRECTORY-P means file is a directory and
 256 switches do not contain `d', so that a full listing is expected.
 257
 258 This version of the function uses `eshell/ls'.  If any of the switches
 259 passed are not recognized, the operating system's version will be used
 260 instead."
 261   (if (not eshell-ls-use-in-dired)
 262       (funcall orig-fun file switches wildcard full-directory-p)
 263     (let ((handler (find-file-name-handler file 'insert-directory)))
 264       (if handler
 265           (funcall handler 'insert-directory file switches
 266                    wildcard full-directory-p)
 267         (if (stringp switches)
 268             (setq switches (split-string switches)))
 269         (let (eshell-current-handles
 270               eshell-current-subjob-p
 271               font-lock-mode)
 272           ;; use the fancy highlighting in `eshell-ls' rather than font-lock
 273           (when (and eshell-ls-use-colors
 274                      (featurep 'font-lock))
 275             (font-lock-mode -1)
 276             (setq font-lock-defaults nil)
 277             (if (boundp 'font-lock-buffers)
 278                 (set 'font-lock-buffers
 279                      (delq (current-buffer)
 280                            (symbol-value 'font-lock-buffers)))))
 281           (require 'em-glob)
 282           (let* ((insert-func 'insert)
 283                  (error-func 'insert)
 284                  (flush-func 'ignore)
 285                  (eshell-error-if-no-glob t)
 286                  (target ; Expand the shell wildcards if any.
 287                   (if (and (atom file)
 288                            (string-match "[[?*]" file)
 289                            (not (file-exists-p file)))
 290                       (mapcar #'file-relative-name (eshell-extended-glob file))
 291                     (file-relative-name file)))
 292                  (switches
 293                   (append eshell-ls-dired-initial-args
 294                           (and (or (consp dired-directory) wildcard) (list "-d"))
 295                           switches)))
 296             (eshell-do-ls (nconc switches (list target)))))))))
 297
 298
 299 (declare-function eshell-extended-glob "em-glob" (glob))
 300 (declare-function dired-read-dir-and-switches "dired" (str))
 301 (declare-function dired-goto-next-file "dired" ())
 302
 303 (defun eshell-ls--dired (orig-fun dir-or-list &optional switches)
 304   (interactive (dired-read-dir-and-switches ""))
 305   (require 'em-glob)
 306   (if (consp dir-or-list)
 307       (funcall orig-fun dir-or-list switches)
 308     (let ((dir-wildcard (insert-directory-wildcard-in-dir-p
 309                          (expand-file-name dir-or-list))))
 310       (if (not dir-wildcard)
 311           (funcall orig-fun dir-or-list switches)
 312         (let* ((default-directory (car dir-wildcard))
 313                (files (eshell-extended-glob (cdr dir-wildcard)))
 314                (dir (car dir-wildcard)))
 315           (if files
 316               (let ((inhibit-read-only t)
 317                     (buf
 318                      (apply orig-fun
 319                             (nconc (list dir) files)
 320                             (and switches (list switches)))))
 321                 (with-current-buffer buf
 322                   (save-excursion
 323                     (goto-char (point-min))
 324                     (dired-goto-next-file)
 325                     (forward-line 0)
 326                     (insert "  wildcard " (cdr dir-wildcard) "\n"))))
 327             (user-error "No files matching regexp")))))))
 328
 329 (defsubst eshell/ls (&rest args)
 330   "An alias version of `eshell-do-ls'."
 331   (let ((insert-func 'eshell-buffered-print)
 332         (error-func 'eshell-error)
 333         (flush-func 'eshell-flush))
 334     (apply 'eshell-do-ls args)))
 335
 336 (put 'eshell/ls 'eshell-no-numeric-conversions t)
 337
 338 (declare-function eshell-glob-regexp "em-glob" (pattern))
 339
 340 (defun eshell-do-ls (&rest args)
 341   "Implementation of \"ls\" in Lisp, passing ARGS."
 342   (funcall flush-func -1)
 343   ;; Process the command arguments, and begin listing files.
 344   (eshell-eval-using-options
 345    "ls" (if eshell-ls-initial-args
 346             (list eshell-ls-initial-args args)
 347           args)
 348    `((?a "all" nil show-all
 349          "do not ignore entries starting with .")
 350      (?A "almost-all" nil show-almost-all
 351          "do not list implied . and ..")
 352      (?c nil by-ctime sort-method
 353          "sort by last status change time")
 354      (?d "directory" nil dir-literal
 355          "list directory entries instead of contents")
 356      (?k "kilobytes" 1024 block-size
 357          "using 1024 as the block size")
 358      (?h "human-readable" 1024 human-readable
 359          "print sizes in human readable format")
 360      (?H "si" 1000 human-readable
 361          "likewise, but use powers of 1000 not 1024")
 362      (?I "ignore" t ignore-pattern
 363          "do not list implied entries matching pattern")
 364      (?l nil long-listing listing-style
 365          "use a long listing format")
 366      (?n "numeric-uid-gid" nil numeric-uid-gid
 367          "list numeric UIDs and GIDs instead of names")
 368      (?r "reverse" nil reverse-list
 369          "reverse order while sorting")
 370      (?s "size" nil show-size
 371          "print size of each file, in blocks")
 372      (?t nil by-mtime sort-method
 373          "sort by modification time")
 374      (?u nil by-atime sort-method
 375          "sort by last access time")
 376      (?x nil by-lines listing-style
 377          "list entries by lines instead of by columns")
 378      (?C nil by-columns listing-style
 379          "list entries by columns")
 380      (?L "dereference" nil dereference-links
 381          "list entries pointed to by symbolic links")
 382      (?R "recursive" nil show-recursive
 383          "list subdirectories recursively")
 384      (?S nil by-size sort-method
 385          "sort by file size")
 386      (?U nil unsorted sort-method
 387          "do not sort; list entries in directory order")
 388      (?X nil by-extension sort-method
 389          "sort alphabetically by entry extension")
 390      (?1 nil single-column listing-style
 391          "list one file per line")
 392      (nil "dired" nil dired-flag
 393           "Here for compatibility with GNU ls.")
 394      (nil "help" nil nil
 395           "show this usage display")
 396      :external "ls"
 397      :usage "[OPTION]... [FILE]...
 398 List information about the FILEs (the current directory by default).
 399 Sort entries alphabetically across.")
 400    ;; setup some defaults, based on what the user selected
 401    (unless block-size
 402      (setq block-size eshell-ls-default-blocksize))
 403    (unless listing-style
 404      (setq listing-style 'by-columns))
 405    (unless args
 406      (setq args (list ".")))
 407    (let ((eshell-ls-exclude-regexp eshell-ls-exclude-regexp) ange-cache)
 408      (when ignore-pattern
 409        (unless (eshell-using-module 'eshell-glob)
 410          (error (concat "-I option requires that `eshell-glob'"
 411                         " be a member of `eshell-modules-list'")))
 412        (set-text-properties 0 (length ignore-pattern) nil ignore-pattern)
 413        (setq eshell-ls-exclude-regexp
 414              (if eshell-ls-exclude-regexp
 415                  (concat "\\(" eshell-ls-exclude-regexp "\\|"
 416                          (eshell-glob-regexp ignore-pattern) "\\)")
 417                (eshell-glob-regexp ignore-pattern))))
 418      ;; list the files!
 419      (eshell-ls-entries
 420       (mapcar (lambda (arg)
 421                 (cons (if (and (eshell-under-windows-p)
 422                                (file-name-absolute-p arg))
 423                           (expand-file-name arg)
 424                         arg)
 425                       (eshell-file-attributes
 426                        arg (if numeric-uid-gid 'integer 'string))))
 427               args)
 428       t (expand-file-name default-directory)))
 429    (funcall flush-func)))
 430
 431 (defsubst eshell-ls-printable-size (filesize &optional by-blocksize)
 432   "Return a printable FILESIZE."
 433   (eshell-printable-size filesize human-readable
 434                          (and by-blocksize block-size)
 435                          eshell-ls-use-colors))
 436
 437 (defsubst eshell-ls-size-string (attrs size-width)
 438   "Return the size string for ATTRS length, using SIZE-WIDTH."
 439   (let* ((str (eshell-ls-printable-size (nth 7 attrs) t))
 440          (len (length str)))
 441     (if (< len size-width)
 442         (concat (make-string (- size-width len) ? ) str)
 443       str)))
 444
 445 (defun eshell-ls-annotate (fileinfo)
 446   "Given a FILEINFO object, return a resolved, decorated FILEINFO.
 447 This means resolving any symbolic links, determining what face the
 448 name should be displayed as, etc.  Think of it as cooking a FILEINFO."
 449   (if (not (and (stringp (cadr fileinfo))
 450                 (or dereference-links
 451                     (eq listing-style 'long-listing))))
 452       (setcar fileinfo (eshell-ls-decorated-name fileinfo))
 453     (let (dir attr)
 454       (unless (file-name-absolute-p (cadr fileinfo))
 455         (setq dir (file-truename
 456                    (file-name-directory
 457                     (expand-file-name (car fileinfo))))))
 458       (setq attr
 459             (eshell-file-attributes
 460              (let ((target (if dir
 461                                (expand-file-name (cadr fileinfo) dir)
 462                              (cadr fileinfo))))
 463                (if dereference-links
 464                    (file-truename target)
 465                  target))))
 466       (if (or dereference-links
 467               (string-match "^\\.\\.?$" (car fileinfo)))
 468           (progn
 469             (setcdr fileinfo attr)
 470             (setcar fileinfo (eshell-ls-decorated-name fileinfo)))
 471         (cl-assert (eq listing-style 'long-listing))
 472         (setcar fileinfo
 473                 (concat (eshell-ls-decorated-name fileinfo) " -> "
 474                         (eshell-ls-decorated-name
 475                          (cons (cadr fileinfo) attr)))))))
 476   fileinfo)
 477
 478 (defun eshell-ls-file (fileinfo &optional size-width copy-fileinfo)
 479   "Output FILE in long format.
 480 FILE may be a string, or a cons cell whose car is the filename and
 481 whose cdr is the list of file attributes."
 482   (if (not (cdr fileinfo))
 483       (funcall error-func (format "%s: No such file or directory\n"
 484                                   (car fileinfo)))
 485     (setq fileinfo
 486           (eshell-ls-annotate (if copy-fileinfo
 487                                   (cons (car fileinfo)
 488                                         (cdr fileinfo))
 489                                 fileinfo)))
 490     (let ((file (car fileinfo))
 491           (attrs (cdr fileinfo)))
 492       (if (not (eq listing-style 'long-listing))
 493           (if show-size
 494               (funcall insert-func (eshell-ls-size-string attrs size-width)
 495                        " " file "\n")
 496             (funcall insert-func file "\n"))
 497         (let ((line
 498                (concat
 499                 (if show-size
 500                     (concat (eshell-ls-size-string attrs size-width) " "))
 501                 (format
 502                  (if numeric-uid-gid
 503                      "%s%4d %-8s %-8s "
 504                    "%s%4d %-14s %-8s ")
 505                  (or (nth 8 attrs) "??????????")
 506                  (or (nth 1 attrs) 0)
 507                  (or (let ((user (nth 2 attrs)))
 508                        (and (stringp user)
 509                             (eshell-substring user 14)))
 510                      (nth 2 attrs)
 511                      "")
 512                  (or (let ((group (nth 3 attrs)))
 513                        (and (stringp group)
 514                             (eshell-substring group 8)))
 515                      (nth 3 attrs)
 516                      ""))
 517                 (let* ((str (eshell-ls-printable-size (nth 7 attrs)))
 518                        (len (length str)))
 519                   ;; Let file sizes shorter than 9 align neatly.
 520                   (if (< len (or size-width 8))
 521                       (concat (make-string (- (or size-width 8) len) ? ) str)
 522                     str))
 523                 " " (format-time-string
 524                      (concat
 525                       eshell-ls-date-format " "
 526                       (if (= (nth 5 (decode-time))
 527                              (nth 5 (decode-time
 528                                      (nth (cond
 529                                            ((eq sort-method 'by-atime) 4)
 530                                            ((eq sort-method 'by-ctime) 6)
 531                                            (t 5)) attrs))))
 532                           "%H:%M"
 533                         " %Y")) (nth (cond
 534                         ((eq sort-method 'by-atime) 4)
 535                         ((eq sort-method 'by-ctime) 6)
 536                         (t 5)) attrs)) " ")))
 537           (funcall insert-func line file "\n"))))))
 538
 539 (defun eshell-ls-dir (dirinfo &optional insert-name root-dir size-width)
 540   "Output the entries in DIRINFO.
 541 If INSERT-NAME is non-nil, the name of DIRINFO will be output.  If
 542 ROOT-DIR is also non-nil, and a directory name, DIRINFO will be output
 543 relative to that directory."
 544   (let ((dir (car dirinfo)))
 545     (if (not (cdr dirinfo))
 546         (funcall error-func (format "%s: No such file or directory\n" dir))
 547       (if dir-literal
 548           (eshell-ls-file dirinfo size-width)
 549         (if insert-name
 550             (funcall insert-func
 551                      (eshell-ls-decorated-name
 552                       (cons (concat
 553                              (if root-dir
 554                                  (file-relative-name dir root-dir)
 555                                (expand-file-name dir)))
 556                             (cdr dirinfo))) ":\n"))
 557         (let ((entries (eshell-directory-files-and-attributes
 558                         dir nil (and (not (or show-all show-almost-all))
 559                                      eshell-ls-exclude-hidden
 560                                      "\\`[^.]") t
 561                                      ;; Asking for UID and GID as
 562                                      ;; strings saves another syscall
 563                                      ;; later when we are going to
 564                                      ;; display user and group names.
 565                                      (if numeric-uid-gid 'integer 'string))))
 566           (when (and show-almost-all
 567                      (not show-all))
 568             (setq entries
 569                   (cl-remove-if
 570                    (lambda (entry)
 571                      (member (car entry) '("." "..")))
 572                    entries)))
 573           (when (and (not (or show-all show-almost-all))
 574                      eshell-ls-exclude-regexp)
 575             (while (and entries (string-match eshell-ls-exclude-regexp
 576                                               (caar entries)))
 577               (setq entries (cdr entries)))
 578             (let ((e entries))
 579               (while (cdr e)
 580                 (if (string-match eshell-ls-exclude-regexp (car (cadr e)))
 581                     (setcdr e (cddr e))
 582                   (setq e (cdr e))))))
 583           (when (or (eq listing-style 'long-listing) show-size)
 584             (let ((total 0.0))
 585               (setq size-width 0)
 586               (dolist (e entries)
 587                 (if (nth 7 (cdr e))
 588                     (setq total (+ total (nth 7 (cdr e)))
 589                           size-width
 590                           (max size-width
 591                                (length (eshell-ls-printable-size
 592                                         (nth 7 (cdr e))
 593                                         (not
 594                                          ;; If we are under -l, count length
 595                                          ;; of sizes in bytes, not in blocks.
 596                                          (eq listing-style 'long-listing))))))))
 597               (funcall insert-func "total "
 598                        (eshell-ls-printable-size total t) "\n")))
 599           (let ((default-directory (expand-file-name dir)))
 600             (if show-recursive
 601                 (eshell-ls-entries
 602                  (let ((e entries) (good-entries (list t)))
 603                    (while e
 604                      (unless (let ((len (length (caar e))))
 605                                (and (eq (aref (caar e) 0) ?.)
 606                                     (or (= len 1)
 607                                         (and (= len 2)
 608                                              (eq (aref (caar e) 1) ?.)))))
 609                        (nconc good-entries (list (car e))))
 610                      (setq e (cdr e)))
 611                    (cdr good-entries))
 612                  nil root-dir)
 613               (eshell-ls-files (eshell-ls-sort-entries entries)
 614                                size-width))))))))
 615
 616 (defsubst eshell-ls-compare-entries (l r inx func)
 617   "Compare the time of two files, L and R, the attribute indexed by INX."
 618   (let ((lt (nth inx (cdr l)))
 619         (rt (nth inx (cdr r))))
 620     (if (equal lt rt)
 621         (string-lessp (directory-file-name (car l))
 622                       (directory-file-name (car r)))
 623       (funcall func rt lt))))
 624
 625 (defun eshell-ls-sort-entries (entries)
 626   "Sort the given ENTRIES, which may be files, directories or both.
 627 In Eshell's implementation of ls, ENTRIES is always reversed."
 628   (if (eq sort-method 'unsorted)
 629       (nreverse entries)
 630     (sort entries
 631           (function
 632            (lambda (l r)
 633              (let ((result
 634                     (cond
 635                      ((eq sort-method 'by-atime)
 636                       (eshell-ls-compare-entries l r 4 'time-less-p))
 637                      ((eq sort-method 'by-mtime)
 638                       (eshell-ls-compare-entries l r 5 'time-less-p))
 639                      ((eq sort-method 'by-ctime)
 640                       (eshell-ls-compare-entries l r 6 'time-less-p))
 641                      ((eq sort-method 'by-size)
 642                       (eshell-ls-compare-entries l r 7 '<))
 643                      ((eq sort-method 'by-extension)
 644                       (let ((lx (file-name-extension
 645                                  (directory-file-name (car l))))
 646                             (rx (file-name-extension
 647                                  (directory-file-name (car r)))))
 648                         (cond
 649                          ((or (and (not lx) (not rx))
 650                               (equal lx rx))
 651                           (string-lessp (directory-file-name (car l))
 652                                         (directory-file-name (car r))))
 653                          ((not lx) t)
 654                          ((not rx) nil)
 655                          (t
 656                           (string-lessp lx rx)))))
 657                      (t
 658                       (string-lessp (directory-file-name (car l))
 659                                     (directory-file-name (car r)))))))
 660                (if reverse-list
 661                    (not result)
 662                  result)))))))
 663
 664 (defun eshell-ls-files (files &optional size-width copy-fileinfo)
 665   "Output a list of FILES.
 666 Each member of FILES is either a string or a cons cell of the form
 667 \(FILE .  ATTRS)."
 668   ;; Mimic behavior of coreutils ls, which lists a single file per
 669   ;; line when output is not a tty.  Exceptions: if -x was supplied,
 670   ;; or if we are the _last_ command in a pipeline.
 671   ;; FIXME Not really the same since not testing output destination.
 672   (if (or (and eshell-in-pipeline-p
 673                (not (eq eshell-in-pipeline-p 'last))
 674                (not (eq listing-style 'by-lines)))
 675           (memq listing-style '(long-listing single-column)))
 676       (dolist (file files)
 677         (if file
 678             (eshell-ls-file file size-width copy-fileinfo)))
 679     (let ((f files)
 680           last-f
 681           display-files
 682           ignore)
 683       (while f
 684         (if (cdar f)
 685             (setq last-f f
 686                   f (cdr f))
 687           (unless ignore
 688             (funcall error-func
 689                      (format "%s: No such file or directory\n" (caar f))))
 690           (if (eq f files)
 691               (setq files (cdr files)
 692                     f files)
 693             (if (not (cdr f))
 694                 (progn
 695                   (setcdr last-f nil)
 696                   (setq f nil))
 697               (setcar f (cadr f))
 698               (setcdr f (cddr f))))))
 699       (if (not show-size)
 700           (setq display-files (mapcar 'eshell-ls-annotate files))
 701         (dolist (file files)
 702           (let* ((str (eshell-ls-printable-size (nth 7 (cdr file)) t))
 703                  (len (length str)))
 704             (if (< len size-width)
 705                 (setq str (concat (make-string (- size-width len) ? ) str)))
 706             (setq file (eshell-ls-annotate file)
 707                   display-files (cons (cons (concat str " " (car file))
 708                                             (cdr file))
 709                                       display-files))))
 710         (setq display-files (nreverse display-files)))
 711       (let* ((col-vals
 712               (if (eq listing-style 'by-columns)
 713                   (eshell-ls-find-column-lengths display-files)
 714                 (cl-assert (eq listing-style 'by-lines))
 715                 (eshell-ls-find-column-widths display-files)))
 716              (col-widths (car col-vals))
 717              (display-files (cdr col-vals))
 718              (columns (length col-widths))
 719              (col-index 1)
 720              need-return)
 721         (dolist (file display-files)
 722           (let ((name
 723                  (if (car file)
 724                      (if show-size
 725                          (concat (substring (car file) 0 size-width)
 726                                  (eshell-ls-decorated-name
 727                                   (cons (substring (car file) size-width)
 728                                         (cdr file))))
 729                        (eshell-ls-decorated-name file))
 730                    "")))
 731             (if (< col-index columns)
 732                 (setq need-return
 733                       (concat need-return name
 734                               (make-string
 735                                (max 0 (- (aref col-widths
 736                                                (1- col-index))
 737                                          (length name))) ? ))
 738                       col-index (1+ col-index))
 739               (funcall insert-func need-return name "\n")
 740               (setq col-index 1 need-return nil))))
 741         (if need-return
 742             (funcall insert-func need-return "\n"))))))
 743
 744 (defun eshell-ls-entries (entries &optional separate root-dir)
 745   "Output PATH's directory ENTRIES.
 746 Each member of ENTRIES may either be a string or a cons cell, the car
 747 of which is the file name, and the cdr of which is the list of
 748 attributes.
 749 If SEPARATE is non-nil, directories name will be entirely separated
 750 from the filenames.  This is the normal behavior, except when doing a
 751 recursive listing.
 752 ROOT-DIR, if non-nil, specifies the root directory of the listing, to
 753 which non-absolute directory names will be made relative if ever they
 754 need to be printed."
 755   (let (dirs files show-names need-return (size-width 0))
 756     (dolist (entry entries)
 757       (if (and (not dir-literal)
 758                (or (eshell-ls-filetype-p (cdr entry) ?d)
 759                    (and (eshell-ls-filetype-p (cdr entry) ?l)
 760                         (file-directory-p (car entry)))))
 761           (progn
 762             (unless separate
 763               (setq files (cons entry files)
 764                     size-width
 765                     (if show-size
 766                         (max size-width
 767                              (length (eshell-ls-printable-size
 768                                       (nth 7 (cdr entry)) t))))))
 769             (setq dirs (cons entry dirs)))
 770         (setq files (cons entry files)
 771               size-width
 772               (if show-size
 773                   (max size-width
 774                        (length (eshell-ls-printable-size
 775                                 (nth 7 (cdr entry)) t)))))))
 776     (when files
 777       (eshell-ls-files (eshell-ls-sort-entries files)
 778                        size-width show-recursive)
 779       (setq need-return t))
 780     (setq show-names (or show-recursive
 781                          (> (+ (length files) (length dirs)) 1)))
 782     (dolist (dir (eshell-ls-sort-entries dirs))
 783       (if (and need-return (not dir-literal))
 784           (funcall insert-func "\n"))
 785       (eshell-ls-dir dir show-names
 786                      (unless (file-name-absolute-p (car dir)) root-dir)
 787                      size-width)
 788       (setq need-return t))))
 789
 790 (defun eshell-ls-find-column-widths (files)
 791   "Find the best fitting column widths for FILES.
 792 It will be returned as a vector, whose length is the number of columns
 793 to use, and each member of which is the width of that column
 794 \(including spacing)."
 795   (let* ((numcols 0)
 796          (width 0)
 797          (widths
 798           (mapcar
 799            (function
 800             (lambda (file)
 801               (+ 2 (length (car file)))))
 802            files))
 803          ;; must account for the added space...
 804          (max-width (+ (window-width) 2))
 805          (best-width 0)
 806          col-widths)
 807
 808     ;; determine the largest number of columns in the first row
 809     (let ((w widths))
 810       (while (and w (< width max-width))
 811         (setq width (+ width (car w))
 812               numcols (1+ numcols)
 813               w (cdr w))))
 814
 815     ;; refine it based on the following rows
 816     (while (> numcols 0)
 817       (let ((i 0)
 818             (colw (make-vector numcols 0))
 819             (w widths))
 820         (while w
 821           (if (= i numcols)
 822               (setq i 0))
 823           (aset colw i (max (aref colw i) (car w)))
 824           (setq w (cdr w) i (1+ i)))
 825         (setq i 0 width 0)
 826         (while (< i numcols)
 827           (setq width (+ width (aref colw i))
 828                 i (1+ i)))
 829         (if (and (< width max-width)
 830                  (> width best-width))
 831             (setq col-widths colw
 832                   best-width width)))
 833       (setq numcols (1- numcols)))
 834
 835     (cons (or col-widths (vector max-width)) files)))
 836
 837 (defun eshell-ls-find-column-lengths (files)
 838   "Find the best fitting column lengths for FILES.
 839 It will be returned as a vector, whose length is the number of columns
 840 to use, and each member of which is the width of that column
 841 \(including spacing)."
 842   (let* ((numcols 1)
 843          (width 0)
 844          (widths
 845           (mapcar
 846            (function
 847             (lambda (file)
 848               (+ 2 (length (car file)))))
 849            files))
 850          (max-width (+ (window-width) 2))
 851          col-widths
 852          colw)
 853
 854     ;; refine it based on the following rows
 855     (while numcols
 856       (let* ((rows (ceiling (/ (length widths)
 857                                (float numcols))))
 858              (w widths)
 859              (len (* rows numcols))
 860              (index 0)
 861              (i 0))
 862         (setq width 0)
 863         (unless (or (= rows 0)
 864                     (<= (/ (length widths) (float rows))
 865                         (float (1- numcols))))
 866           (setq colw (make-vector numcols 0))
 867           (while (> len 0)
 868             (if (= i numcols)
 869                 (setq i 0 index (1+ index)))
 870             (aset colw i
 871                   (max (aref colw i)
 872                        (or (nth (+ (* i rows) index) w) 0)))
 873             (setq len (1- len) i (1+ i)))
 874           (setq i 0)
 875           (while (< i numcols)
 876             (setq width (+ width (aref colw i))
 877                   i (1+ i))))
 878         (if (>= width max-width)
 879             (setq numcols nil)
 880           (if colw
 881               (setq col-widths colw))
 882           (if (>= numcols (length widths))
 883               (setq numcols nil)
 884             (setq numcols (1+ numcols))))))
 885
 886     (if (not col-widths)
 887         (cons (vector max-width) files)
 888       (setq numcols (length col-widths))
 889       (let* ((rows (ceiling (/ (length widths)
 890                                (float numcols))))
 891              (len (* rows numcols))
 892              (newfiles (make-list len nil))
 893              (index 0)
 894              (i 0)
 895              (j 0))
 896         (while (< j len)
 897           (if (= i numcols)
 898               (setq i 0 index (1+ index)))
 899           (setcar (nthcdr j newfiles)
 900                   (nth (+ (* i rows) index) files))
 901           (setq j (1+ j) i (1+ i)))
 902         (cons col-widths newfiles)))))
 903
 904 (defun eshell-ls-decorated-name (file)
 905   "Return FILE, possibly decorated."
 906   (if eshell-ls-use-colors
 907       (let ((face
 908              (cond
 909               ((not (cdr file))
 910                'eshell-ls-missing)
 911
 912               ((stringp (cadr file))
 913                'eshell-ls-symlink)
 914
 915               ((eq (cadr file) t)
 916                'eshell-ls-directory)
 917
 918               ((not (eshell-ls-filetype-p (cdr file) ?-))
 919                'eshell-ls-special)
 920
 921               ((and (/= (user-uid) 0) ; root can execute anything
 922                     (eshell-ls-applicable (cdr file) 3
 923                                           'file-executable-p (car file)))
 924                'eshell-ls-executable)
 925
 926               ((not (eshell-ls-applicable (cdr file) 1
 927                                           'file-readable-p (car file)))
 928                'eshell-ls-unreadable)
 929
 930               ((string-match eshell-ls-archive-regexp (car file))
 931                'eshell-ls-archive)
 932
 933               ((string-match eshell-ls-backup-regexp (car file))
 934                'eshell-ls-backup)
 935
 936               ((string-match eshell-ls-product-regexp (car file))
 937                'eshell-ls-product)
 938
 939               ((string-match eshell-ls-clutter-regexp (car file))
 940                'eshell-ls-clutter)
 941
 942               ((not (eshell-ls-applicable (cdr file) 2
 943                                           'file-writable-p (car file)))
 944                'eshell-ls-readonly)
 945               (eshell-ls-highlight-alist
 946                (let ((tests eshell-ls-highlight-alist)
 947                      value)
 948                  (while tests
 949                    (if (funcall (caar tests) (car file) (cdr file))
 950                        (setq value (cdar tests) tests nil)
 951                      (setq tests (cdr tests))))
 952                  value)))))
 953         (if face
 954             (add-text-properties 0 (length (car file))
 955                                  (list 'font-lock-face face)
 956                                  (car file)))))
 957   (car file))
 958
 959 (defun eshell-ls-unload-function ()
 960   (advice-remove 'insert-directory #'eshell-ls--insert-directory)
 961   (advice-remove 'dired #'eshell-ls--dired)
 962   nil)
 963
 964 (provide 'em-ls)
 965
 966 ;; Local Variables:
 967 ;; generated-autoload-file: "esh-groups.el"
 968 ;; End:
 969
 970 ;;; em-ls.el ends here