lisp/mail/mail-utils.el

   1 ;;; mail-utils.el --- utility functions used both by rmail and rnews
   2
   3 ;; Copyright (C) 1985, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: mail, news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Utility functions for mail and netnews handling.  These handle fine
  27 ;; points of header parsing.
  28
  29 ;;; Code:
  30
  31 ;;; We require lisp-mode to make sure that lisp-mode-syntax-table has
  32 ;;; been initialized.
  33 (require 'lisp-mode)
  34
  35 ;;;###autoload
  36 (defcustom mail-use-rfc822 nil "\
  37 *If non-nil, use a full, hairy RFC822 parser on mail addresses.
  38 Otherwise, (the default) use a smaller, somewhat faster, and
  39 often correct parser."
  40   :type 'boolean
  41   :group 'mail)
  42
  43 ;; Returns t if file FILE is an Rmail file.
  44 ;;;###autoload
  45 (defun mail-file-babyl-p (file)
  46   (let ((buf (generate-new-buffer " *rmail-file-p*")))
  47     (unwind-protect
  48         (save-excursion
  49           (set-buffer buf)
  50           (insert-file-contents file nil 0 100)
  51           (looking-at "BABYL OPTIONS:"))
  52       (kill-buffer buf))))
  53
  54 (defun mail-string-delete (string start end)
  55   "Returns a string containing all of STRING except the part
  56 from START (inclusive) to END (exclusive)."
  57   (if (null end) (substring string 0 start)
  58     (concat (substring string 0 start)
  59             (substring string end nil))))
  60
  61 ;;;###autoload
  62 (defun mail-quote-printable (string &optional wrapper)
  63   "Convert a string to the \"quoted printable\" Q encoding.
  64 If the optional argument WRAPPER is non-nil,
  65 we add the wrapper characters =?ISO-8859-1?Q?....?=."
  66   (let ((i 0) (result ""))
  67     (save-match-data
  68       (while (string-match "[?=\"\200-\377]" string i)
  69         (setq result
  70               (concat result (substring string i (match-beginning 0))
  71                       (upcase (format "=%02x"
  72                                       (aref string (match-beginning 0))))))
  73         (setq i (match-end 0)))
  74       (if wrapper
  75           (concat "=?ISO-8859-1?Q?"
  76                   result (substring string i)
  77                   "?=")
  78         (concat result (substring string i))))))
  79
  80 (defun mail-unquote-printable-hexdigit (char)
  81   (setq char (upcase char))
  82   (if (>= char ?A)
  83       (+ (- char ?A) 10)
  84     (- char ?0)))
  85
  86 ;;;###autoload
  87 (defun mail-unquote-printable (string &optional wrapper)
  88   "Undo the \"quoted printable\" encoding.
  89 If the optional argument WRAPPER is non-nil,
  90 we expect to find and remove the wrapper characters =?ISO-8859-1?Q?....?=."
  91   (save-match-data
  92     (and wrapper
  93          (string-match "\\`=\\?ISO-8859-1\\?Q\\?\\([^?]*\\)\\?" string)
  94          (setq string (match-string 1 string)))
  95     (let ((i 0) strings)
  96       (while (string-match "=\\(..\\|\n\\)" string i)
  97         (setq strings (cons (substring string i (match-beginning 0)) strings))
  98         (unless (= (aref string (match-beginning 1)) ?\n)
  99           (setq strings
 100                 (cons (make-string 1
 101                                    (+ (* 16 (mail-unquote-printable-hexdigit
 102                                              (aref string (match-beginning 1))))
 103                                       (mail-unquote-printable-hexdigit
 104                                        (aref string (1+ (match-beginning 1))))))
 105                       strings)))
 106         (setq i (match-end 0)))
 107       (apply 'concat (nreverse (cons (substring string i) strings))))))
 108
 109 ;;;###autoload
 110 (defun mail-unquote-printable-region (beg end &optional wrapper noerror
 111                                           unibyte)
 112   "Undo the \"quoted printable\" encoding in buffer from BEG to END.
 113 If the optional argument WRAPPER is non-nil,
 114 we expect to find and remove the wrapper characters =?ISO-8859-1?Q?....?=.
 115 If NOERROR is non-nil, return t if successful.
 116 If UNIBYTE is non-nil, insert converted characters as unibyte.
 117 That is useful if you are going to character code decoding afterward,
 118 as Rmail does."
 119   (interactive "r\nP")
 120   (let (failed)
 121     (save-match-data
 122       (save-excursion
 123         (save-restriction
 124           (narrow-to-region beg end)
 125           (goto-char (point-min))
 126           (when (and wrapper
 127                      (looking-at "\\`=\\?ISO-8859-1\\?Q\\?\\([^?]*\\)\\?"))
 128             (delete-region (match-end 1) end)
 129             (delete-region (point) (match-beginning 1)))
 130           (while (re-search-forward "=\\(\\([0-9A-F][0-9A-F]\\)\\|[=\n]\\|..\\)" nil t)
 131             (goto-char (match-end 0))
 132             (cond ((= (char-after (match-beginning 1)) ?\n)
 133                    (replace-match ""))
 134                   ((= (char-after (match-beginning 1)) ?=)
 135                    (replace-match "="))
 136                   ((match-beginning 2)
 137                    (let ((char (+ (* 16 (mail-unquote-printable-hexdigit
 138                                          (char-after (match-beginning 2))))
 139                                   (mail-unquote-printable-hexdigit
 140                                    (char-after (1+ (match-beginning 2)))))))
 141                      (if unibyte
 142                          (progn
 143                            (replace-match "")
 144                            ;; insert-byte will insert this as a
 145                            ;; corresponding eight-bit character.
 146                            (insert-byte char 1))
 147                        (replace-match (make-string 1 char) t t))))
 148                   (noerror
 149                    (setq failed t))
 150                   (t
 151                    (error "Malformed MIME quoted-printable message"))))
 152           (not failed))))))
 153
 154 (eval-when-compile (require 'rfc822))
 155
 156 (defun mail-strip-quoted-names (address)
 157   "Delete comments and quoted strings in an address list ADDRESS.
 158 Also delete leading/trailing whitespace and replace FOO <BAR> with just BAR.
 159 Return a modified address list."
 160   (if (null address)
 161       nil
 162     (if mail-use-rfc822
 163         (progn (require 'rfc822)
 164                (mapconcat 'identity (rfc822-addresses address) ", "))
 165       (let (pos)
 166
 167        ;; Detect nested comments.
 168        (if (string-match "[ \t]*(\\([^)\\]\\|\\\\.\\|\\\\\n\\)*(" address)
 169            ;; Strip nested comments.
 170            (with-current-buffer (get-buffer-create " *temp*")
 171              (erase-buffer)
 172              (insert address)
 173              (set-syntax-table lisp-mode-syntax-table)
 174              (goto-char 1)
 175              (while (search-forward "(" nil t)
 176                (forward-char -1)
 177                (skip-chars-backward " \t")
 178                (delete-region (point)
 179                               (save-excursion
 180                                 (condition-case ()
 181                                     (forward-sexp 1)
 182                                   (error (goto-char (point-max))))
 183                                   (point))))
 184              (setq address (buffer-string))
 185              (erase-buffer))
 186          ;; Strip non-nested comments an easier way.
 187          (while (setq pos (string-match
 188                             ;; This doesn't hack rfc822 nested comments
 189                             ;;  `(xyzzy (foo) whinge)' properly.  Big deal.
 190                             "[ \t]*(\\([^)\\]\\|\\\\.\\|\\\\\n\\)*)"
 191                             address))
 192            (setq address (replace-match "" nil nil address 0))))
 193
 194        ;; strip surrounding whitespace
 195        (string-match "\\`[ \t\n]*" address)
 196        (setq address (substring address
 197                                 (match-end 0)
 198                                 (string-match "[ \t\n]*\\'" address
 199                                               (match-end 0))))
 200
 201        ;; strip `quoted' names (This is supposed to hack `"Foo Bar" <bar@host>')
 202        (setq pos 0)
 203        (while (setq pos (string-match
 204                           "\\([ \t]?\\)\\([ \t]*\"\\([^\"\\]\\|\\\\.\\|\\\\\n\\)*\"[ \t\n]*\\)"
 205                           address pos))
 206          ;; If the next thing is "@", we have "foo bar"@host.  Leave it.
 207          (if (and (> (length address) (match-end 0))
 208                   (= (aref address (match-end 0)) ?@))
 209              (setq pos (match-end 0))
 210            ;; Otherwise discard the "..." part.
 211            (setq address (replace-match "" nil nil address 2))))
 212        ;; If this address contains <...>, replace it with just
 213        ;; the part between the <...>.
 214        (while (setq pos (string-match "\\(,\\s-*\\|\\`\\)\\([^,]*<\\([^>,:]*\\)>[^,]*\\)\\(\\s-*,\\|\\'\\)"
 215                                       address))
 216          (setq address (replace-match (match-string 3 address)
 217                                       nil 'literal address 2)))
 218        address))))
 219
 220 ;;; The following piece of ugliness is legacy code.  The name was an
 221 ;;; unfortunate choice --- a flagrant violation of the Emacs Lisp
 222 ;;; coding conventions.  `mail-dont-reply-to' would have been
 223 ;;; infinitely better.  Also, `rmail-dont-reply-to-names' might have
 224 ;;; been better named `mail-dont-reply-to-names' and sourced from this
 225 ;;; file instead of in rmail.el.  Yuck.  -pmr
 226 (defun rmail-dont-reply-to (destinations)
 227   "Prune addresses from DESTINATIONS, a list of recipient addresses.
 228 All addresses matching `rmail-dont-reply-to-names' are removed from
 229 the comma-separated list.  The pruned list is returned."
 230   (if (null rmail-dont-reply-to-names)
 231       (setq rmail-dont-reply-to-names
 232             (concat (if rmail-default-dont-reply-to-names
 233                         (concat rmail-default-dont-reply-to-names "\\|")
 234                       "")
 235                     (if (and user-mail-address
 236                              (not (equal user-mail-address user-login-name)))
 237                         ;; Anchor the login name and email address so
 238                         ;; that we don't match substrings: if the
 239                         ;; login name is "foo", we shouldn't match
 240                         ;; "barfoo@baz.com".
 241                         (concat "\\`"
 242                                 (regexp-quote user-mail-address)
 243                                 "\\'\\|")
 244                       "")
 245                     (concat "\\`" (regexp-quote user-login-name) "@"))))
 246   ;; Split up DESTINATIONS and match each element separately.
 247   (let ((start-pos 0) (cur-pos 0)
 248         (case-fold-search t))
 249     (while start-pos
 250       (setq cur-pos (string-match "[,\"]" destinations cur-pos))
 251       (if (and cur-pos (equal (match-string 0 destinations) "\""))
 252           ;; Search for matching quote.
 253           (let ((next-pos (string-match "\"" destinations (1+ cur-pos))))
 254             (if next-pos
 255                 (setq cur-pos (1+ next-pos))
 256               ;; If the open-quote has no close-quote,
 257               ;; delete the open-quote to get something well-defined.
 258               ;; This case is not valid, but it can happen if things
 259               ;; are weird elsewhere.
 260               (setq destinations (concat (substring destinations 0 cur-pos)
 261                                     (substring destinations (1+ cur-pos))))
 262               (setq cur-pos start-pos)))
 263         (let* ((address (substring destinations start-pos cur-pos))
 264                (naked-address (mail-strip-quoted-names address)))
 265           (if (string-match rmail-dont-reply-to-names naked-address)
 266               (setq destinations (concat (substring destinations 0 start-pos)
 267                                     (and cur-pos (substring destinations
 268                                                             (1+ cur-pos))))
 269                     cur-pos start-pos)
 270             (setq cur-pos (and cur-pos (1+ cur-pos))
 271                   start-pos cur-pos))))))
 272   ;; get rid of any trailing commas
 273   (let ((pos (string-match "[ ,\t\n]*\\'" destinations)))
 274     (if pos
 275         (setq destinations (substring destinations 0 pos))))
 276   ;; remove leading spaces. they bother me.
 277   (if (string-match "\\(\\s \\|,\\)*" destinations)
 278       (substring destinations (match-end 0))
 279     destinations))
 280
 281 \f
 282 ;;;###autoload
 283 (defun mail-fetch-field (field-name &optional last all list)
 284   "Return the value of the header field whose type is FIELD-NAME.
 285 The buffer is expected to be narrowed to just the header of the message.
 286 If second arg LAST is non-nil, use the last field of type FIELD-NAME.
 287 If third arg ALL is non-nil, concatenate all such fields with commas between.
 288 If 4th arg LIST is non-nil, return a list of all such fields."
 289   (save-excursion
 290     (goto-char (point-min))
 291     (let ((case-fold-search t)
 292           (name (concat "^" (regexp-quote field-name) "[ \t]*:[ \t]*")))
 293       (if (or all list)
 294           (let ((value (if all "")))
 295             (while (re-search-forward name nil t)
 296               (let ((opoint (point)))
 297                 (while (progn (forward-line 1)
 298                               (looking-at "[ \t]")))
 299                 ;; Back up over newline, then trailing spaces or tabs
 300                 (forward-char -1)
 301                 (skip-chars-backward " \t" opoint)
 302                 (if list
 303                     (setq value (cons (buffer-substring-no-properties
 304                                        opoint (point))
 305                                       value))
 306                   (setq value (concat value
 307                                       (if (string= value "") "" ", ")
 308                                       (buffer-substring-no-properties
 309                                        opoint (point)))))))
 310             (if list
 311                 value
 312               (and (not (string= value "")) value)))
 313         (if (re-search-forward name nil t)
 314             (progn
 315               (if last (while (re-search-forward name nil t)))
 316               (let ((opoint (point)))
 317                 (while (progn (forward-line 1)
 318                               (looking-at "[ \t]")))
 319                 ;; Back up over newline, then trailing spaces or tabs
 320                 (forward-char -1)
 321                 (skip-chars-backward " \t" opoint)
 322                 (buffer-substring-no-properties opoint (point)))))))))
 323 \f
 324 ;; Parse a list of tokens separated by commas.
 325 ;; It runs from point to the end of the visible part of the buffer.
 326 ;; Whitespace before or after tokens is ignored,
 327 ;; but whitespace within tokens is kept.
 328 (defun mail-parse-comma-list ()
 329   (let (accumulated
 330         beg)
 331     (skip-chars-forward " \t\n")
 332     (while (not (eobp))
 333       (setq beg (point))
 334       (skip-chars-forward "^,")
 335       (skip-chars-backward " \t\n")
 336       (setq accumulated
 337             (cons (buffer-substring-no-properties beg (point))
 338                   accumulated))
 339       (skip-chars-forward "^,")
 340       (skip-chars-forward ", \t\n"))
 341     accumulated))
 342
 343 (defun mail-comma-list-regexp (labels)
 344   (let (pos)
 345     (setq pos (or (string-match "[^ \t]" labels) 0))
 346     ;; Remove leading and trailing whitespace.
 347     (setq labels (substring labels pos (string-match "[ \t]*$" labels pos)))
 348     ;; Change each comma to \|, and flush surrounding whitespace.
 349     (while (setq pos (string-match "[ \t]*,[ \t]*" labels))
 350       (setq labels
 351             (concat (substring labels 0 pos)
 352                     "\\|"
 353                     (substring labels (match-end 0))))))
 354   labels)
 355 \f
 356 (defun mail-rfc822-time-zone (time)
 357   (let* ((sec (or (car (current-time-zone time)) 0))
 358          (absmin (/ (abs sec) 60)))
 359     (format "%c%02d%02d" (if (< sec 0) ?- ?+) (/ absmin 60) (% absmin 60))))
 360
 361 (defun mail-rfc822-date ()
 362   (let* ((time (current-time))
 363          (s (current-time-string time)))
 364     (string-match "[^ ]+ +\\([^ ]+\\) +\\([^ ]+\\) \\([^ ]+\\) \\([^ ]+\\)" s)
 365     (concat (substring s (match-beginning 2) (match-end 2)) " "
 366             (substring s (match-beginning 1) (match-end 1)) " "
 367             (substring s (match-beginning 4) (match-end 4)) " "
 368             (substring s (match-beginning 3) (match-end 3)) " "
 369             (mail-rfc822-time-zone time))))
 370
 371 (provide 'mail-utils)
 372
 373 ;; arch-tag: b24aec2f-fd65-4ceb-9e39-3cc2827036fd
 374 ;;; mail-utils.el ends here