lisp/wid-edit.el

   1 ;;; wid-edit.el --- Functions for creating and using widgets -*-byte-compile-dynamic: t;-*-
   2 ;;
   3 ;; Copyright (C) 1996,97,1999,2000,01,02,2003  Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   6 ;; Maintainer: FSF
   7 ;; Keywords: extensions
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Wishlist items (from widget.texi):
  27
  28 ;; * The `menu-choice' tag should be prettier, something like the
  29 ;;   abbreviated menus in Open Look.
  30
  31 ;; * Finish `:tab-order'.
  32
  33 ;; * Make indentation work with glyphs and proportional fonts.
  34
  35 ;; * Add commands to show overview of object and class hierarchies to
  36 ;;   the browser.
  37
  38 ;; * Find a way to disable mouse highlight for inactive widgets.
  39
  40 ;; * Find a way to make glyphs look inactive.
  41
  42 ;; * Add `key-binding' widget.
  43
  44 ;; * Add `widget' widget for editing widget specifications.
  45
  46 ;; * Find clean way to implement variable length list.  See
  47 ;;   `TeX-printer-list' for an explanation.
  48
  49 ;; * `C-h' in `widget-prompt-value' should give type specific help.
  50
  51 ;; * A mailto widget. [This should work OK as a url-link if with
  52 ;;   browse-url-browser-function' set up appropriately.]
  53
  54 ;;; Commentary:
  55 ;;
  56 ;; See `widget.el'.
  57
  58 ;;; Code:
  59
  60 ;;; Compatibility.
  61
  62 (defun widget-event-point (event)
  63   "Character position of the end of event if that exists, or nil."
  64   (posn-point (event-end event)))
  65
  66 (defun widget-button-release-event-p (event)
  67   "Non-nil if EVENT is a mouse-button-release event object."
  68   (and (eventp event)
  69        (memq (event-basic-type event) '(mouse-1 mouse-2 mouse-3))
  70        (or (memq 'click (event-modifiers event))
  71            (memq  'drag (event-modifiers event)))))
  72
  73 ;;; Customization.
  74
  75 (defgroup widgets nil
  76   "Customization support for the Widget Library."
  77   :link '(custom-manual "(widget)Top")
  78   :link '(emacs-library-link :tag "Lisp File" "widget.el")
  79   :prefix "widget-"
  80   :group 'extensions
  81   :group 'hypermedia)
  82
  83 (defgroup widget-documentation nil
  84   "Options controling the display of documentation strings."
  85   :group 'widgets)
  86
  87 (defgroup widget-faces nil
  88   "Faces used by the widget library."
  89   :group 'widgets
  90   :group 'faces)
  91
  92 (defvar widget-documentation-face 'widget-documentation-face
  93   "Face used for documentation strings in widgets.
  94 This exists as a variable so it can be set locally in certain buffers.")
  95
  96 (defface widget-documentation-face '((((class color)
  97                                        (background dark))
  98                                       (:foreground "lime green"))
  99                                      (((class color)
 100                                        (background light))
 101                                       (:foreground "dark green"))
 102                                      (t nil))
 103   "Face used for documentation text."
 104   :group 'widget-documentation
 105   :group 'widget-faces)
 106
 107 (defvar widget-button-face 'widget-button-face
 108   "Face used for buttons in widgets.
 109 This exists as a variable so it can be set locally in certain buffers.")
 110
 111 (defface widget-button-face '((t (:weight bold)))
 112   "Face used for widget buttons."
 113   :group 'widget-faces)
 114
 115 (defcustom widget-mouse-face 'highlight
 116   "Face used for widget buttons when the mouse is above them."
 117   :type 'face
 118   :group 'widget-faces)
 119
 120 ;; TTY gets special definitions here and in the next defface, because
 121 ;; the gray colors defined for other displays cause black text on a black
 122 ;; background, at least on light-background TTYs.
 123 (defface widget-field-face '((((type tty))
 124                               :background "yellow3"
 125                               :foreground "black")
 126                              (((class grayscale color)
 127                                (background light))
 128                               :background "gray85")
 129                              (((class grayscale color)
 130                                (background dark))
 131                               :background "dim gray")
 132                              (t
 133                               :slant italic))
 134   "Face used for editable fields."
 135   :group 'widget-faces)
 136
 137 (defface widget-single-line-field-face '((((type tty))
 138                                           :background "green3"
 139                                           :foreground "black")
 140                                          (((class grayscale color)
 141                                            (background light))
 142                                           :background "gray85")
 143                                          (((class grayscale color)
 144                                            (background dark))
 145                                           :background "dim gray")
 146                                          (t
 147                                           :slant italic))
 148   "Face used for editable fields spanning only a single line."
 149   :group 'widget-faces)
 150
 151 ;;; This causes display-table to be loaded, and not usefully.
 152 ;;;(defvar widget-single-line-display-table
 153 ;;;  (let ((table (make-display-table)))
 154 ;;;    (aset table 9  "^I")
 155 ;;;    (aset table 10 "^J")
 156 ;;;    table)
 157 ;;;  "Display table used for single-line editable fields.")
 158
 159 ;;;(when (fboundp 'set-face-display-table)
 160 ;;;  (set-face-display-table 'widget-single-line-field-face
 161 ;;;                       widget-single-line-display-table))
 162
 163 ;;; Utility functions.
 164 ;;
 165 ;; These are not really widget specific.
 166
 167 (defun widget-princ-to-string (object)
 168   "Return string representation of OBJECT, any Lisp object.
 169 No quoting characters are used; no delimiters are printed around
 170 the contents of strings."
 171   (with-output-to-string
 172       (princ object)))
 173
 174 (defun widget-clear-undo ()
 175   "Clear all undo information."
 176   (buffer-disable-undo (current-buffer))
 177   (buffer-enable-undo))
 178
 179 (defcustom widget-menu-max-size 40
 180   "Largest number of items allowed in a popup-menu.
 181 Larger menus are read through the minibuffer."
 182   :group 'widgets
 183   :type 'integer)
 184
 185 (defcustom widget-menu-max-shortcuts 40
 186   "Largest number of items for which it works to choose one with a character.
 187 For a larger number of items, the minibuffer is used."
 188   :group 'widgets
 189   :type 'integer)
 190
 191 (defcustom widget-menu-minibuffer-flag nil
 192   "*Control how to ask for a choice from the keyboard.
 193 Non-nil means use the minibuffer;
 194 nil means read a single character."
 195   :group 'widgets
 196   :type 'boolean)
 197
 198 (defun widget-choose (title items &optional event)
 199   "Choose an item from a list.
 200
 201 First argument TITLE is the name of the list.
 202 Second argument ITEMS is a list whose members are either
 203  (NAME . VALUE), to indicate selectable items, or just strings to
 204  indicate unselectable items.
 205 Optional third argument EVENT is an input event.
 206
 207 The user is asked to choose between each NAME from the items alist,
 208 and the VALUE of the chosen element will be returned.  If EVENT is a
 209 mouse event, and the number of elements in items is less than
 210 `widget-menu-max-size', a popup menu will be used, otherwise the
 211 minibuffer."
 212   (cond ((and (< (length items) widget-menu-max-size)
 213               event (display-popup-menus-p))
 214          ;; Mouse click.
 215          (x-popup-menu event
 216                        (list title (cons "" items))))
 217         ((or widget-menu-minibuffer-flag
 218              (> (length items) widget-menu-max-shortcuts))
 219          ;; Read the choice of name from the minibuffer.
 220          (setq items (widget-remove-if 'stringp items))
 221          (let ((val (completing-read (concat title ": ") items nil t)))
 222            (if (stringp val)
 223                (let ((try (try-completion val items)))
 224                  (when (stringp try)
 225                    (setq val try))
 226                  (cdr (assoc val items))))))
 227         (t
 228          ;; Construct a menu of the choices
 229          ;; and then use it for prompting for a single character.
 230          (let* ((overriding-terminal-local-map (make-sparse-keymap))
 231                 (next-digit ?0)
 232                 map choice some-choice-enabled value)
 233            ;; Define SPC as a prefix char to get to this menu.
 234            (define-key overriding-terminal-local-map " "
 235              (setq map (make-sparse-keymap title)))
 236            (with-current-buffer (get-buffer-create " widget-choose")
 237              (erase-buffer)
 238              (insert "Available choices:\n\n")
 239              (while items
 240                (setq choice (car items) items (cdr items))
 241                (if (consp choice)
 242                    (let* ((name (car choice))
 243                          (function (cdr choice)))
 244                      (insert (format "%c = %s\n" next-digit name))
 245                      (define-key map (vector next-digit) function)
 246                      (setq some-choice-enabled t)))
 247                ;; Allocate digits to disabled alternatives
 248                ;; so that the digit of a given alternative never varies.
 249                (setq next-digit (1+ next-digit)))
 250              (insert "\nC-g = Quit"))
 251            (or some-choice-enabled
 252                (error "None of the choices is currently meaningful"))
 253            (define-key map [?\C-g] 'keyboard-quit)
 254            (define-key map [t] 'keyboard-quit)
 255            (define-key map [?\M-\C-v] 'scroll-other-window)
 256            (define-key map [?\M--] 'negative-argument)
 257            (setcdr map (nreverse (cdr map)))
 258            ;; Read a char with the menu, and return the result
 259            ;; that corresponds to it.
 260            (save-window-excursion
 261              (let ((buf (get-buffer " widget-choose")))
 262                (fit-window-to-buffer (display-buffer buf))
 263                (let ((cursor-in-echo-area t)
 264                      keys
 265                      (char 0)
 266                      (arg 1))
 267                  (while (not (or (and (>= char ?0) (< char next-digit))
 268                                  (eq value 'keyboard-quit)))
 269                    ;; Unread a SPC to lead to our new menu.
 270                    (setq unread-command-events (cons ?\  unread-command-events))
 271                    (setq keys (read-key-sequence title))
 272                    (setq value
 273                          (lookup-key overriding-terminal-local-map keys t)
 274                          char (string-to-char (substring keys 1)))
 275                    (cond ((eq value 'scroll-other-window)
 276                           (let ((minibuffer-scroll-window
 277                                  (get-buffer-window buf)))
 278                             (if (> 0 arg)
 279                                 (scroll-other-window-down
 280                                  (window-height minibuffer-scroll-window))
 281                               (scroll-other-window))
 282                             (setq arg 1)))
 283                          ((eq value 'negative-argument)
 284                           (setq arg -1))
 285                          (t
 286                           (setq arg 1)))))))
 287            (when (eq value 'keyboard-quit)
 288              (error "Canceled"))
 289            value))))
 290
 291 (defun widget-remove-if (predictate list)
 292   (let (result (tail list))
 293     (while tail
 294       (or (funcall predictate (car tail))
 295           (setq result (cons (car tail) result)))
 296       (setq tail (cdr tail)))
 297     (nreverse result)))
 298
 299 ;;; Widget text specifications.
 300 ;;
 301 ;; These functions are for specifying text properties.
 302
 303 ;; We can set it to nil now that get_local_map uses get_pos_property.
 304 (defconst widget-field-add-space nil
 305   "Non-nil means add extra space at the end of editable text fields.
 306 If you don't add the space, it will become impossible to edit a zero
 307 size field.")
 308
 309 (defvar widget-field-use-before-change t
 310   "Non-nil means use `before-change-functions' to track editable fields.
 311 This enables the use of undo, but doesn't work on Emacs 19.34 and earlier.
 312 Using before hooks also means that the :notify function can't know the
 313 new value.")
 314
 315 (defun widget-specify-field (widget from to)
 316   "Specify editable button for WIDGET between FROM and TO."
 317   ;; Terminating space is not part of the field, but necessary in
 318   ;; order for local-map to work.  Remove next sexp if local-map works
 319   ;; at the end of the overlay.
 320   (save-excursion
 321     (goto-char to)
 322     (cond ((null (widget-get widget :size))
 323            (forward-char 1))
 324           (widget-field-add-space
 325            (insert-and-inherit " ")))
 326     (setq to (point)))
 327   (let ((keymap (widget-get widget :keymap))
 328         (face (or (widget-get widget :value-face) 'widget-field-face))
 329         (help-echo (widget-get widget :help-echo))
 330         (rear-sticky
 331          (or (not widget-field-add-space) (widget-get widget :size))))
 332     (if (functionp help-echo)
 333       (setq help-echo 'widget-mouse-help))
 334     (when (= (char-before to) ?\n)
 335       ;; When the last character in the field is a newline, we want to
 336       ;; give it a `field' char-property of `boundary', which helps the
 337       ;; C-n/C-p act more naturally when entering/leaving the field.  We
 338      ;; do this by making a small secondary overlay to contain just that
 339       ;; one character.
 340       (let ((overlay (make-overlay (1- to) to nil t nil)))
 341         (overlay-put overlay 'field 'boundary)
 342         ;; Use `local-map' here, not `keymap', so that normal editing
 343         ;; works in the field when, say, Custom uses `suppress-keymap'.
 344         (overlay-put overlay 'local-map keymap)
 345         (overlay-put overlay 'face face)
 346         (overlay-put overlay 'help-echo help-echo))
 347       (setq to (1- to))
 348       (setq rear-sticky t))
 349     (let ((overlay (make-overlay from to nil nil rear-sticky)))
 350       (widget-put widget :field-overlay overlay)
 351       ;;(overlay-put overlay 'detachable nil)
 352       (overlay-put overlay 'field widget)
 353       (overlay-put overlay 'local-map keymap)
 354       (overlay-put overlay 'face face)
 355       (overlay-put overlay 'help-echo help-echo)))
 356   (widget-specify-secret widget))
 357
 358 (defun widget-specify-secret (field)
 359   "Replace text in FIELD with value of `:secret', if non-nil."
 360   (let ((secret (widget-get field :secret))
 361         (size (widget-get field :size)))
 362     (when secret
 363       (let ((begin (widget-field-start field))
 364             (end (widget-field-end field)))
 365         (when size
 366           (while (and (> end begin)
 367                       (eq (char-after (1- end)) ?\ ))
 368             (setq end (1- end))))
 369         (while (< begin end)
 370           (let ((old (char-after begin)))
 371             (unless (eq old secret)
 372               (subst-char-in-region begin (1+ begin) old secret)
 373               (put-text-property begin (1+ begin) 'secret old))
 374             (setq begin (1+ begin))))))))
 375
 376 (defun widget-specify-button (widget from to)
 377   "Specify button for WIDGET between FROM and TO."
 378   (let ((overlay (make-overlay from to nil t nil))
 379         (help-echo (widget-get widget :help-echo)))
 380     (widget-put widget :button-overlay overlay)
 381     (if (functionp help-echo)
 382       (setq help-echo 'widget-mouse-help))
 383     (overlay-put overlay 'button widget)
 384     (overlay-put overlay 'keymap (widget-get widget :keymap))
 385     ;; We want to avoid the face with image buttons.
 386     (unless (widget-get widget :suppress-face)
 387       (overlay-put overlay 'face (widget-apply widget :button-face-get))
 388       (overlay-put overlay 'mouse-face widget-mouse-face))
 389     (overlay-put overlay 'help-echo help-echo)))
 390
 391 (defun widget-mouse-help (window overlay point)
 392   "Help-echo callback for widgets whose :help-echo is a function."
 393   (with-current-buffer (overlay-buffer overlay)
 394     (let* ((widget (widget-at (overlay-start overlay)))
 395            (help-echo (if widget (widget-get widget :help-echo))))
 396       (if (functionp help-echo)
 397           (funcall help-echo widget)
 398         help-echo))))
 399
 400 (defun widget-specify-sample (widget from to)
 401   "Specify sample for WIDGET between FROM and TO."
 402   (let ((overlay (make-overlay from to nil t nil)))
 403     (overlay-put overlay 'face (widget-apply widget :sample-face-get))
 404     (widget-put widget :sample-overlay overlay)))
 405
 406 (defun widget-specify-doc (widget from to)
 407   "Specify documentation for WIDGET between FROM and TO."
 408   (let ((overlay (make-overlay from to nil t nil)))
 409     (overlay-put overlay 'widget-doc widget)
 410     (overlay-put overlay 'face widget-documentation-face)
 411     (widget-put widget :doc-overlay overlay)))
 412
 413 (defmacro widget-specify-insert (&rest form)
 414   "Execute FORM without inheriting any text properties."
 415   `(save-restriction
 416     (let ((inhibit-read-only t)
 417           (inhibit-modification-hooks t))
 418       (narrow-to-region (point) (point))
 419       (prog1 (progn ,@form)
 420         (goto-char (point-max))))))
 421
 422 (defface widget-inactive-face '((((class grayscale color)
 423                                   (background dark))
 424                                  (:foreground "light gray"))
 425                                 (((class grayscale color)
 426                                   (background light))
 427                                  (:foreground "dim gray"))
 428                                 (t
 429                                  (:slant italic)))
 430   "Face used for inactive widgets."
 431   :group 'widget-faces)
 432
 433 (defun widget-specify-inactive (widget from to)
 434   "Make WIDGET inactive for user modifications."
 435   (unless (widget-get widget :inactive)
 436     (let ((overlay (make-overlay from to nil t nil)))
 437       (overlay-put overlay 'face 'widget-inactive-face)
 438       ;; This is disabled, as it makes the mouse cursor change shape.
 439       ;; (overlay-put overlay 'mouse-face 'widget-inactive-face)
 440       (overlay-put overlay 'evaporate t)
 441       (overlay-put overlay 'priority 100)
 442       (overlay-put overlay 'modification-hooks '(widget-overlay-inactive))
 443       (widget-put widget :inactive overlay))))
 444
 445 (defun widget-overlay-inactive (&rest junk)
 446   "Ignoring the arguments, signal an error."
 447   (unless inhibit-read-only
 448     (error "The widget here is not active")))
 449
 450
 451 (defun widget-specify-active (widget)
 452   "Make WIDGET active for user modifications."
 453   (let ((inactive (widget-get widget :inactive)))
 454     (when inactive
 455       (delete-overlay inactive)
 456       (widget-put widget :inactive nil))))
 457
 458 ;;; Widget Properties.
 459
 460 (defsubst widget-type (widget)
 461   "Return the type of WIDGET, a symbol."
 462   (car widget))
 463
 464 ;;;###autoload
 465 (defun widgetp (widget)
 466   "Return non-nil iff WIDGET is a widget."
 467   (if (symbolp widget)
 468       (get widget 'widget-type)
 469     (and (consp widget)
 470          (symbolp (car widget))
 471          (get (car widget) 'widget-type))))
 472
 473 (defun widget-get-indirect (widget property)
 474   "In WIDGET, get the value of PROPERTY.
 475 If the value is a symbol, return its binding.
 476 Otherwise, just return the value."
 477   (let ((value (widget-get widget property)))
 478     (if (symbolp value)
 479         (symbol-value value)
 480       value)))
 481
 482 (defun widget-member (widget property)
 483   "Non-nil iff there is a definition in WIDGET for PROPERTY."
 484   (cond ((plist-member (cdr widget) property)
 485          t)
 486         ((car widget)
 487          (widget-member (get (car widget) 'widget-type) property))
 488         (t nil)))
 489
 490 (defun widget-value (widget)
 491   "Extract the current value of WIDGET."
 492   (widget-apply widget
 493                 :value-to-external (widget-apply widget :value-get)))
 494
 495 (defun widget-value-set (widget value)
 496   "Set the current value of WIDGET to VALUE."
 497   (widget-apply widget
 498                 :value-set (widget-apply widget
 499                                          :value-to-internal value)))
 500
 501 (defun widget-default-get (widget)
 502   "Extract the default external value of WIDGET."
 503   (widget-apply widget :value-to-external
 504                 (or (widget-get widget :value)
 505                     (widget-apply widget :default-get))))
 506
 507 (defun widget-match-inline (widget vals)
 508   "In WIDGET, match the start of VALS."
 509   (cond ((widget-get widget :inline)
 510          (widget-apply widget :match-inline vals))
 511         ((and (listp vals)
 512               (widget-apply widget :match (car vals)))
 513          (cons (list (car vals)) (cdr vals)))
 514         (t nil)))
 515
 516 (defun widget-apply-action (widget &optional event)
 517   "Apply :action in WIDGET in response to EVENT."
 518   (if (widget-apply widget :active)
 519       (widget-apply widget :action event)
 520     (error "Attempt to perform action on inactive widget")))
 521
 522 ;;; Helper functions.
 523 ;;
 524 ;; These are widget specific.
 525
 526 ;;;###autoload
 527 (defun widget-prompt-value (widget prompt &optional value unbound)
 528   "Prompt for a value matching WIDGET, using PROMPT.
 529 The current value is assumed to be VALUE, unless UNBOUND is non-nil."
 530   (unless (listp widget)
 531     (setq widget (list widget)))
 532   (setq prompt (format "[%s] %s" (widget-type widget) prompt))
 533   (setq widget (widget-convert widget))
 534   (let ((answer (widget-apply widget :prompt-value prompt value unbound)))
 535     (unless (widget-apply widget :match answer)
 536       (error "Value does not match %S type" (car widget)))
 537     answer))
 538
 539 (defun widget-get-sibling (widget)
 540   "Get the item WIDGET is assumed to toggle.
 541 This is only meaningful for radio buttons or checkboxes in a list."
 542   (let* ((children (widget-get (widget-get widget :parent) :children))
 543          child)
 544     (catch 'child
 545       (while children
 546         (setq child (car children)
 547               children (cdr children))
 548         (when (eq (widget-get child :button) widget)
 549           (throw 'child child)))
 550       nil)))
 551
 552 (defun widget-map-buttons (function &optional buffer maparg)
 553   "Map FUNCTION over the buttons in BUFFER.
 554 FUNCTION is called with the arguments WIDGET and MAPARG.
 555
 556 If FUNCTION returns non-nil, the walk is cancelled.
 557
 558 The arguments MAPARG, and BUFFER default to nil and (current-buffer),
 559 respectively."
 560   (let ((cur (point-min))
 561         (widget nil)
 562         (overlays (if buffer
 563                       (with-current-buffer buffer (overlay-lists))
 564                     (overlay-lists))))
 565     (setq overlays (append (car overlays) (cdr overlays)))
 566     (while (setq cur (pop overlays))
 567       (setq widget (overlay-get cur 'button))
 568       (if (and widget (funcall function widget maparg))
 569           (setq overlays nil)))))
 570
 571 ;;; Images.
 572
 573 (defcustom widget-image-directory (file-name-as-directory
 574                                    (expand-file-name "custom" data-directory))
 575   "Where widget button images are located.
 576 If this variable is nil, widget will try to locate the directory
 577 automatically."
 578   :group 'widgets
 579   :type 'directory)
 580
 581 (defcustom widget-image-enable t
 582   "If non nil, use image buttons in widgets when available."
 583   :version "21.1"
 584   :group 'widgets
 585   :type 'boolean)
 586
 587 (defcustom widget-image-conversion
 588   '((xpm ".xpm") (gif ".gif") (png ".png") (jpeg ".jpg" ".jpeg")
 589     (xbm ".xbm"))
 590   "Conversion alist from image formats to file name suffixes."
 591   :group 'widgets
 592   :type '(repeat (cons :format "%v"
 593                        (symbol :tag "Image Format" unknown)
 594                        (repeat :tag "Suffixes"
 595                                (string :format "%v")))))
 596
 597 (defun widget-image-find (image)
 598   "Create a graphical button from IMAGE.
 599 IMAGE should either already be an image, or be a file name sans
 600 extension (xpm, xbm, gif, jpg, or png) located in
 601 `widget-image-directory' or otherwise where `find-image' will find it."
 602   (cond ((not (and image widget-image-enable (display-graphic-p)))
 603          ;; We don't want or can't use images.
 604          nil)
 605         ((and (consp image)
 606               (eq 'image (car image)))
 607          ;; Already an image spec.  Use it.
 608          image)
 609         ((stringp image)
 610          ;; A string.  Look it up in relevant directories.
 611          (let* ((load-path (cons widget-image-directory load-path))
 612                 specs)
 613            (dolist (elt widget-image-conversion)
 614              (dolist (ext (cdr elt))
 615                (push (list :type (car elt) :file (concat image ext)) specs)))
 616            (setq specs (nreverse specs))
 617            (find-image specs)))
 618         (t
 619          ;; Oh well.
 620          nil)))
 621
 622 (defvar widget-button-pressed-face 'widget-button-pressed-face
 623   "Face used for pressed buttons in widgets.
 624 This exists as a variable so it can be set locally in certain
 625 buffers.")
 626
 627 (defun widget-image-insert (widget tag image &optional down inactive)
 628   "In WIDGET, insert the text TAG or, if supported, IMAGE.
 629 IMAGE should either be an image or an image file name sans extension
 630 \(xpm, xbm, gif, jpg, or png) located in `widget-image-directory'.
 631
 632 Optional arguments DOWN and INACTIVE are used instead of IMAGE when the
 633 button is pressed or inactive, respectively.  These are currently ignored."
 634   (if (and (display-graphic-p)
 635            (setq image (widget-image-find image)))
 636       (progn (widget-put widget :suppress-face t)
 637              (insert-image image
 638                            (propertize
 639                             tag 'mouse-face widget-button-pressed-face)))
 640     (insert tag)))
 641
 642 ;;; Buttons.
 643
 644 (defgroup widget-button nil
 645   "The look of various kinds of buttons."
 646   :group 'widgets)
 647
 648 (defcustom widget-button-prefix ""
 649   "String used as prefix for buttons."
 650   :type 'string
 651   :group 'widget-button)
 652
 653 (defcustom widget-button-suffix ""
 654   "String used as suffix for buttons."
 655   :type 'string
 656   :group 'widget-button)
 657
 658 ;;; Creating Widgets.
 659
 660 ;;;###autoload
 661 (defun widget-create (type &rest args)
 662   "Create widget of TYPE.
 663 The optional ARGS are additional keyword arguments."
 664   (let ((widget (apply 'widget-convert type args)))
 665     (widget-apply widget :create)
 666     widget))
 667
 668 (defun widget-create-child-and-convert (parent type &rest args)
 669   "As part of the widget PARENT, create a child widget TYPE.
 670 The child is converted, using the keyword arguments ARGS."
 671   (let ((widget (apply 'widget-convert type args)))
 672     (widget-put widget :parent parent)
 673     (unless (widget-get widget :indent)
 674       (widget-put widget :indent (+ (or (widget-get parent :indent) 0)
 675                                     (or (widget-get widget :extra-offset) 0)
 676                                     (widget-get parent :offset))))
 677     (widget-apply widget :create)
 678     widget))
 679
 680 (defun widget-create-child (parent type)
 681   "Create widget of TYPE."
 682   (let ((widget (widget-copy type)))
 683     (widget-put widget :parent parent)
 684     (unless (widget-get widget :indent)
 685       (widget-put widget :indent (+ (or (widget-get parent :indent) 0)
 686                                     (or (widget-get widget :extra-offset) 0)
 687                                     (widget-get parent :offset))))
 688     (widget-apply widget :create)
 689     widget))
 690
 691 (defun widget-create-child-value (parent type value)
 692   "Create widget of TYPE with value VALUE."
 693   (let ((widget (widget-copy type)))
 694     (widget-put widget :value (widget-apply widget :value-to-internal value))
 695     (widget-put widget :parent parent)
 696     (unless (widget-get widget :indent)
 697       (widget-put widget :indent (+ (or (widget-get parent :indent) 0)
 698                                     (or (widget-get widget :extra-offset) 0)
 699                                     (widget-get parent :offset))))
 700     (widget-apply widget :create)
 701     widget))
 702
 703 ;;;###autoload
 704 (defun widget-delete (widget)
 705   "Delete WIDGET."
 706   (widget-apply widget :delete))
 707
 708 (defun widget-copy (widget)
 709   "Make a deep copy of WIDGET."
 710   (widget-apply (copy-sequence widget) :copy))
 711
 712 (defun widget-convert (type &rest args)
 713   "Convert TYPE to a widget without inserting it in the buffer.
 714 The optional ARGS are additional keyword arguments."
 715   ;; Don't touch the type.
 716   (let* ((widget (if (symbolp type)
 717                      (list type)
 718                    (copy-sequence type)))
 719          (current widget)
 720          done
 721          (keys args))
 722     ;; First set the :args keyword.
 723     (while (cdr current)                ;Look in the type.
 724       (if (and (keywordp (cadr current))
 725                ;; If the last element is a keyword,
 726                ;; it is still the :args element,
 727                ;; even though it is a keyword.
 728                (cddr current))
 729           (if (eq (cadr current) :args)
 730               ;; If :args is explicitly specified, obey it.
 731               (setq current nil)
 732             ;; Some other irrelevant keyword.
 733             (setq current (cdr (cdr current))))
 734         (setcdr current (list :args (cdr current)))
 735         (setq current nil)))
 736     (while (and args (not done))        ;Look in ARGS.
 737       (cond ((eq (car args) :args)
 738              ;; Handle explicit specification of :args.
 739              (setq args (cadr args)
 740                    done t))
 741             ((keywordp (car args))
 742              (setq args (cddr args)))
 743             (t (setq done t))))
 744     (when done
 745       (widget-put widget :args args))
 746     ;; Then Convert the widget.
 747     (setq type widget)
 748     (while type
 749       (let ((convert-widget (plist-get (cdr type) :convert-widget)))
 750         (if convert-widget
 751             (setq widget (funcall convert-widget widget))))
 752       (setq type (get (car type) 'widget-type)))
 753     ;; Finally set the keyword args.
 754     (while keys
 755       (let ((next (nth 0 keys)))
 756         (if (keywordp next)
 757             (progn
 758               (widget-put widget next (nth 1 keys))
 759               (setq keys (nthcdr 2 keys)))
 760           (setq keys nil))))
 761     ;; Convert the :value to internal format.
 762     (if (widget-member widget :value)
 763         (widget-put widget
 764                     :value (widget-apply widget
 765                                          :value-to-internal
 766                                          (widget-get widget :value))))
 767     ;; Return the newly create widget.
 768     widget))
 769
 770 ;;;###autoload
 771 (defun widget-insert (&rest args)
 772   "Call `insert' with ARGS even if surrounding text is read only."
 773   (let ((inhibit-read-only t)
 774         (inhibit-modification-hooks t))
 775     (apply 'insert args)))
 776
 777 (defun widget-convert-text (type from to
 778                                  &optional button-from button-to
 779                                  &rest args)
 780   "Return a widget of type TYPE with endpoint FROM TO.
 781 Optional ARGS are extra keyword arguments for TYPE.
 782 and TO will be used as the widgets end points. If optional arguments
 783 BUTTON-FROM and BUTTON-TO are given, these will be used as the widgets
 784 button end points.
 785 Optional ARGS are extra keyword arguments for TYPE."
 786   (let ((widget (apply 'widget-convert type :delete 'widget-leave-text args))
 787         (from (copy-marker from))
 788         (to (copy-marker to)))
 789     (set-marker-insertion-type from t)
 790     (set-marker-insertion-type to nil)
 791     (widget-put widget :from from)
 792     (widget-put widget :to to)
 793     (when button-from
 794       (widget-specify-button widget button-from button-to))
 795     widget))
 796
 797 (defun widget-convert-button (type from to &rest args)
 798   "Return a widget of type TYPE with endpoint FROM TO.
 799 Optional ARGS are extra keyword arguments for TYPE.
 800 No text will be inserted to the buffer, instead the text between FROM
 801 and TO will be used as the widgets end points, as well as the widgets
 802 button end points."
 803   (apply 'widget-convert-text type from to from to args))
 804
 805 (defun widget-leave-text (widget)
 806   "Remove markers and overlays from WIDGET and its children."
 807   (let ((button (widget-get widget :button-overlay))
 808         (sample (widget-get widget :sample-overlay))
 809         (doc (widget-get widget :doc-overlay))
 810         (field (widget-get widget :field-overlay)))
 811     (set-marker (widget-get widget :from) nil)
 812     (set-marker (widget-get widget :to) nil)
 813     (when button
 814       (delete-overlay button))
 815     (when sample
 816       (delete-overlay sample))
 817     (when doc
 818       (delete-overlay doc))
 819     (when field
 820       (delete-overlay field))
 821     (mapc 'widget-leave-text (widget-get widget :children))))
 822
 823 ;;; Keymap and Commands.
 824
 825 ;;;###autoload
 826 (defvar widget-keymap
 827   (let ((map (make-sparse-keymap)))
 828     (define-key map "\t" 'widget-forward)
 829     (define-key map [(shift tab)] 'widget-backward)
 830     (define-key map [backtab] 'widget-backward)
 831     (define-key map [down-mouse-2] 'widget-button-click)
 832     (define-key map "\C-m" 'widget-button-press)
 833     map)
 834   "Keymap containing useful binding for buffers containing widgets.
 835 Recommended as a parent keymap for modes using widgets.")
 836
 837 (defvar widget-global-map global-map
 838   "Keymap used for events a widget does not handle itself.")
 839 (make-variable-buffer-local 'widget-global-map)
 840
 841 (defvar widget-field-keymap
 842   (let ((map (copy-keymap widget-keymap)))
 843     (define-key map "\C-k" 'widget-kill-line)
 844     (define-key map "\M-\t" 'widget-complete)
 845     (define-key map "\C-m" 'widget-field-activate)
 846     ;; Since the widget code uses a `field' property to identify fields,
 847     ;; ordinary beginning-of-line does the right thing.
 848     ;;  (define-key map "\C-a" 'widget-beginning-of-line)
 849     (define-key map "\C-e" 'widget-end-of-line)
 850     map)
 851   "Keymap used inside an editable field.")
 852
 853 (defvar widget-text-keymap
 854   (let ((map (copy-keymap widget-keymap)))
 855     ;; Since the widget code uses a `field' property to identify fields,
 856     ;; ordinary beginning-of-line does the right thing.
 857     ;;  (define-key map "\C-a" 'widget-beginning-of-line)
 858     (define-key map "\C-e" 'widget-end-of-line)
 859     map)
 860   "Keymap used inside a text field.")
 861
 862 (defun widget-field-activate (pos &optional event)
 863   "Invoke the editable field at point."
 864   (interactive "@d")
 865   (let ((field (widget-field-at pos)))
 866     (if field
 867         (widget-apply-action field event)
 868       (call-interactively
 869        (lookup-key widget-global-map (this-command-keys))))))
 870
 871 (defface widget-button-pressed-face
 872   '((((class color))
 873      (:foreground "red"))
 874     (t
 875      (:weight bold :underline t)))
 876   "Face used for pressed buttons."
 877   :group 'widget-faces)
 878
 879 (defun widget-button-click (event)
 880   "Invoke the button that the mouse is pointing at."
 881   (interactive "e")
 882   (if (widget-event-point event)
 883       (let* ((pos (widget-event-point event))
 884              (start (event-start event))
 885              (button (get-char-property
 886                       pos 'button (and (windowp (posn-window start))
 887                                        (window-buffer (posn-window start))))))
 888         (if button
 889             ;; Mouse click on a widget button.  Do the following
 890             ;; in a save-excursion so that the click on the button
 891             ;; doesn't change point.
 892             (save-selected-window
 893               (select-window (posn-window (event-start event)))
 894               (save-excursion
 895                 (goto-char (posn-point (event-start event)))
 896                 (let* ((overlay (widget-get button :button-overlay))
 897                        (face (overlay-get overlay 'face))
 898                        (mouse-face (overlay-get overlay 'mouse-face)))
 899                   (unwind-protect
 900                       ;; Read events, including mouse-movement events
 901                       ;; until we receive a release event.  Highlight/
 902                       ;; unhighlight the button the mouse was initially
 903                       ;; on when we move over it.
 904                       (let ((track-mouse t))
 905                         (save-excursion
 906                           (when face    ; avoid changing around image
 907                             (overlay-put overlay
 908                                          'face widget-button-pressed-face)
 909                             (overlay-put overlay
 910                                          'mouse-face widget-button-pressed-face))
 911                           (unless (widget-apply button :mouse-down-action event)
 912                             (while (not (widget-button-release-event-p event))
 913                               (setq event (read-event)
 914                                     pos (widget-event-point event))
 915                               (if (and pos
 916                                        (eq (get-char-property pos 'button)
 917                                            button))
 918                                   (when face
 919                                     (overlay-put overlay
 920                                                  'face
 921                                                  widget-button-pressed-face)
 922                                     (overlay-put overlay
 923                                                  'mouse-face
 924                                                  widget-button-pressed-face))
 925                                 (overlay-put overlay 'face face)
 926                                 (overlay-put overlay 'mouse-face mouse-face))))
 927
 928                           ;; When mouse is released over the button, run
 929                           ;; its action function.
 930                           (when (and pos
 931                                      (eq (get-char-property pos 'button) button))
 932                             (widget-apply-action button event))))
 933                     (overlay-put overlay 'face face)
 934                     (overlay-put overlay 'mouse-face mouse-face))))
 935
 936               (unless (pos-visible-in-window-p (widget-event-point event))
 937                 (mouse-set-point event)
 938                 (beginning-of-line)
 939                 (recenter))
 940               )
 941
 942             (let ((up t) command)
 943               ;; Mouse click not on a widget button.  Find the global
 944               ;; command to run, and check whether it is bound to an
 945               ;; up event.
 946               (mouse-set-point event)
 947               (if (memq (event-basic-type event) '(mouse-1 down-mouse-1))
 948                   (cond ((setq command  ;down event
 949                                (lookup-key widget-global-map [down-mouse-1]))
 950                          (setq up nil))
 951                         ((setq command  ;up event
 952                                (lookup-key widget-global-map [mouse-1]))))
 953                 (cond ((setq command    ;down event
 954                              (lookup-key widget-global-map [down-mouse-2]))
 955                        (setq up nil))
 956                       ((setq command    ;up event
 957                              (lookup-key widget-global-map [mouse-2])))))
 958               (when up
 959                 ;; Don't execute up events twice.
 960                 (while (not (widget-button-release-event-p event))
 961                   (setq event (read-event))))
 962               (when command
 963                 (call-interactively command)))))
 964     (message "You clicked somewhere weird.")))
 965
 966 (defun widget-button-press (pos &optional event)
 967   "Invoke button at POS."
 968   (interactive "@d")
 969   (let ((button (get-char-property pos 'button)))
 970     (if button
 971         (widget-apply-action button event)
 972       (let ((command (lookup-key widget-global-map (this-command-keys))))
 973         (when (commandp command)
 974           (call-interactively command))))))
 975
 976 (defun widget-tabable-at (&optional pos)
 977   "Return the tabable widget at POS, or nil.
 978 POS defaults to the value of (point)."
 979   (let ((widget (widget-at pos)))
 980     (if widget
 981         (let ((order (widget-get widget :tab-order)))
 982           (if order
 983               (if (>= order 0)
 984                   widget)
 985             widget)))))
 986
 987 (defvar widget-use-overlay-change t
 988   "If non-nil, use overlay change functions to tab around in the buffer.
 989 This is much faster, but doesn't work reliably on Emacs 19.34.")
 990
 991 (defun widget-move (arg)
 992   "Move point to the ARG next field or button.
 993 ARG may be negative to move backward."
 994   (or (bobp) (> arg 0) (backward-char))
 995   (let ((wrapped 0)
 996         (number arg)
 997         (old (widget-tabable-at)))
 998     ;; Forward.
 999     (while (> arg 0)
1000       (cond ((eobp)
1001              (goto-char (point-min))
1002              (setq wrapped (1+ wrapped)))
1003             (widget-use-overlay-change
1004              (goto-char (next-overlay-change (point))))
1005             (t
1006              (forward-char 1)))
1007       (and (= wrapped 2)
1008            (eq arg number)
1009            (error "No buttons or fields found"))
1010       (let ((new (widget-tabable-at)))
1011         (when new
1012           (unless (eq new old)
1013             (setq arg (1- arg))
1014             (setq old new)))))
1015     ;; Backward.
1016     (while (< arg 0)
1017       (cond ((bobp)
1018              (goto-char (point-max))
1019              (setq wrapped (1+ wrapped)))
1020             (widget-use-overlay-change
1021              (goto-char (previous-overlay-change (point))))
1022             (t
1023              (backward-char 1)))
1024       (and (= wrapped 2)
1025            (eq arg number)
1026            (error "No buttons or fields found"))
1027       (let ((new (widget-tabable-at)))
1028         (when new
1029           (unless (eq new old)
1030             (setq arg (1+ arg))))))
1031     (let ((new (widget-tabable-at)))
1032       (while (eq (widget-tabable-at) new)
1033         (backward-char)))
1034     (forward-char))
1035   (widget-echo-help (point))
1036   (run-hooks 'widget-move-hook))
1037
1038 (defun widget-forward (arg)
1039   "Move point to the next field or button.
1040 With optional ARG, move across that many fields."
1041   (interactive "p")
1042   (run-hooks 'widget-forward-hook)
1043   (widget-move arg))
1044
1045 (defun widget-backward (arg)
1046   "Move point to the previous field or button.
1047 With optional ARG, move across that many fields."
1048   (interactive "p")
1049   (run-hooks 'widget-backward-hook)
1050   (widget-move (- arg)))
1051
1052 ;; Since the widget code uses a `field' property to identify fields,
1053 ;; ordinary beginning-of-line does the right thing.
1054 (defalias 'widget-beginning-of-line 'beginning-of-line)
1055
1056 (defun widget-end-of-line ()
1057   "Go to end of field or end of line, whichever is first.
1058 Trailing spaces at the end of padded fields are not considered part of
1059 the field."
1060   (interactive)
1061   ;; Ordinary end-of-line does the right thing, because we're inside
1062   ;; text with a `field' property.
1063   (end-of-line)
1064   (unless (eolp)
1065     ;; ... except that we want to ignore trailing spaces in fields that
1066     ;; aren't terminated by a newline, because they are used as padding,
1067     ;; and ignored when extracting the entered value of the field.
1068     (skip-chars-backward " " (field-beginning (1- (point))))))
1069
1070 (defun widget-kill-line ()
1071   "Kill to end of field or end of line, whichever is first."
1072   (interactive)
1073   (let* ((field (widget-field-find (point)))
1074          (end (and field (widget-field-end field))))
1075     (if (and field (> (line-beginning-position 2) end))
1076         (kill-region (point) end)
1077       (call-interactively 'kill-line))))
1078
1079 (defcustom widget-complete-field (lookup-key global-map "\M-\t")
1080   "Default function to call for completion inside fields."
1081   :options '(ispell-complete-word complete-tag lisp-complete-symbol)
1082   :type 'function
1083   :group 'widgets)
1084
1085 (defun widget-complete ()
1086   "Complete content of editable field from point.
1087 When not inside a field, move to the previous button or field."
1088   (interactive)
1089   (let ((field (widget-field-find (point))))
1090     (if field
1091         (widget-apply field :complete)
1092       (error "Not in an editable field"))))
1093
1094 ;;; Setting up the buffer.
1095
1096 (defvar widget-field-new nil
1097   "List of all newly created editable fields in the buffer.")
1098 (make-variable-buffer-local 'widget-field-new)
1099
1100 (defvar widget-field-list nil
1101   "List of all editable fields in the buffer.")
1102 (make-variable-buffer-local 'widget-field-list)
1103
1104 (defun widget-at (&optional pos)
1105   "The button or field at POS (default, point)."
1106   (or (get-char-property (or pos (point)) 'button)
1107       (widget-field-at pos)))
1108
1109 ;;;###autoload
1110 (defun widget-setup ()
1111   "Setup current buffer so editing string widgets works."
1112   (let ((inhibit-read-only t)
1113         (inhibit-modification-hooks t)
1114         field)
1115     (while widget-field-new
1116       (setq field (car widget-field-new)
1117             widget-field-new (cdr widget-field-new)
1118             widget-field-list (cons field widget-field-list))
1119       (let ((from (car (widget-get field :field-overlay)))
1120             (to (cdr (widget-get field :field-overlay))))
1121         (widget-specify-field field
1122                               (marker-position from) (marker-position to))
1123         (set-marker from nil)
1124         (set-marker to nil))))
1125   (widget-clear-undo)
1126   (widget-add-change))
1127
1128 (defvar widget-field-last nil)
1129 ;; Last field containing point.
1130 (make-variable-buffer-local 'widget-field-last)
1131
1132 (defvar widget-field-was nil)
1133 ;; The widget data before the change.
1134 (make-variable-buffer-local 'widget-field-was)
1135
1136 (defun widget-field-at (pos)
1137   "Return the widget field at POS, or nil if none."
1138   (let ((field (get-char-property (or pos (point)) 'field)))
1139     (if (eq field 'boundary)
1140         nil
1141       field)))
1142
1143 (defun widget-field-buffer (widget)
1144   "Return the start of WIDGET's editing field."
1145   (let ((overlay (widget-get widget :field-overlay)))
1146     (cond ((overlayp overlay)
1147            (overlay-buffer overlay))
1148           ((consp overlay)
1149            (marker-buffer (car overlay))))))
1150
1151 (defun widget-field-start (widget)
1152   "Return the start of WIDGET's editing field."
1153   (let ((overlay (widget-get widget :field-overlay)))
1154     (if (overlayp overlay)
1155         (overlay-start overlay)
1156       (car overlay))))
1157
1158 (defun widget-field-end (widget)
1159   "Return the end of WIDGET's editing field."
1160   (let ((overlay (widget-get widget :field-overlay)))
1161     ;; Don't subtract one if local-map works at the end of the overlay,
1162     ;; or if a special `boundary' field has been added after the widget
1163     ;; field.
1164     (if (overlayp overlay)
1165         (if (and (not (eq (get-char-property (overlay-end overlay)
1166                                              'field
1167                                              (widget-field-buffer widget))
1168                           'boundary))
1169                  (or widget-field-add-space
1170                      (null (widget-get widget :size))))
1171             (1- (overlay-end overlay))
1172           (overlay-end overlay))
1173       (cdr overlay))))
1174
1175 (defun widget-field-find (pos)
1176   "Return the field at POS.
1177 Unlike (get-char-property POS 'field) this, works with empty fields too."
1178   (let ((fields widget-field-list)
1179         field found)
1180     (while fields
1181       (setq field (car fields)
1182             fields (cdr fields))
1183       (when (and (<= (widget-field-start field) pos)
1184                  (<= pos (widget-field-end field)))
1185         (when found
1186           (error "Overlapping fields"))
1187         (setq found field)))
1188     found))
1189
1190 (defun widget-before-change (from to)
1191   ;; This is how, for example, a variable changes its state to `modified'.
1192   ;; when it is being edited.
1193   (unless inhibit-read-only
1194     (let ((from-field (widget-field-find from))
1195           (to-field (widget-field-find to)))
1196       (cond ((not (eq from-field to-field))
1197              (add-hook 'post-command-hook 'widget-add-change nil t)
1198              (signal 'text-read-only
1199                      '("Change should be restricted to a single field")))
1200             ((null from-field)
1201              (add-hook 'post-command-hook 'widget-add-change nil t)
1202              (signal 'text-read-only
1203                      '("Attempt to change text outside editable field")))
1204             (widget-field-use-before-change
1205              (widget-apply from-field :notify from-field))))))
1206
1207 (defun widget-add-change ()
1208   (remove-hook 'post-command-hook 'widget-add-change t)
1209   (add-hook 'before-change-functions 'widget-before-change nil t)
1210   (add-hook 'after-change-functions 'widget-after-change nil t))
1211
1212 (defun widget-after-change (from to old)
1213   "Adjust field size and text properties."
1214   (let ((field (widget-field-find from))
1215         (other (widget-field-find to)))
1216     (when field
1217       (unless (eq field other)
1218         (error "Change in different fields"))
1219       (let ((size (widget-get field :size)))
1220         (when size
1221           (let ((begin (widget-field-start field))
1222                 (end (widget-field-end field)))
1223             (cond ((< (- end begin) size)
1224                    ;; Field too small.
1225                    (save-excursion
1226                      (goto-char end)
1227                      (insert-char ?\  (- (+ begin size) end))))
1228                   ((> (- end begin) size)
1229                    ;; Field too large and
1230                    (if (or (< (point) (+ begin size))
1231                            (> (point) end))
1232                        ;; Point is outside extra space.
1233                        (setq begin (+ begin size))
1234                      ;; Point is within the extra space.
1235                      (setq begin (point)))
1236                    (save-excursion
1237                      (goto-char end)
1238                      (while (and (eq (preceding-char) ?\ )
1239                                  (> (point) begin))
1240                        (delete-backward-char 1)))))))
1241         (widget-specify-secret field))
1242       (widget-apply field :notify field))))
1243
1244 ;;; Widget Functions
1245 ;;
1246 ;; These functions are used in the definition of multiple widgets.
1247
1248 (defun widget-parent-action (widget &optional event)
1249   "Tell :parent of WIDGET to handle the :action.
1250 Optional EVENT is the event that triggered the action."
1251   (widget-apply (widget-get widget :parent) :action event))
1252
1253 (defun widget-children-value-delete (widget)
1254   "Delete all :children and :buttons in WIDGET."
1255   (mapc 'widget-delete (widget-get widget :children))
1256   (widget-put widget :children nil)
1257   (mapc 'widget-delete (widget-get widget :buttons))
1258   (widget-put widget :buttons nil))
1259
1260 (defun widget-children-validate (widget)
1261   "All the :children must be valid."
1262   (let ((children (widget-get widget :children))
1263         child found)
1264     (while (and children (not found))
1265       (setq child (car children)
1266             children (cdr children)
1267             found (widget-apply child :validate)))
1268     found))
1269
1270 (defun widget-child-value-get (widget)
1271   "Get the value of the first member of :children in WIDGET."
1272   (widget-value (car (widget-get widget :children))))
1273
1274 (defun widget-child-value-inline (widget)
1275   "Get the inline value of the first member of :children in WIDGET."
1276   (widget-apply (car (widget-get widget :children)) :value-inline))
1277
1278 (defun widget-child-validate (widget)
1279   "The result of validating the first member of :children in WIDGET."
1280   (widget-apply (car (widget-get widget :children)) :validate))
1281
1282 (defun widget-type-value-create (widget)
1283   "Convert and instantiate the value of the :type attribute of WIDGET.
1284 Store the newly created widget in the :children attribute.
1285
1286 The value of the :type attribute should be an unconverted widget type."
1287   (let ((value (widget-get widget :value))
1288         (type (widget-get widget :type)))
1289     (widget-put widget :children
1290                 (list (widget-create-child-value widget
1291                                                  (widget-convert type)
1292                                                  value)))))
1293
1294 (defun widget-type-default-get (widget)
1295   "Get default value from the :type attribute of WIDGET.
1296
1297 The value of the :type attribute should be an unconverted widget type."
1298   (widget-default-get (widget-convert (widget-get widget :type))))
1299
1300 (defun widget-type-match (widget value)
1301   "Non-nil if the :type value of WIDGET matches VALUE.
1302
1303 The value of the :type attribute should be an unconverted widget type."
1304   (widget-apply (widget-convert (widget-get widget :type)) :match value))
1305
1306 (defun widget-types-copy (widget)
1307   "Copy :args as widget types in WIDGET."
1308   (widget-put widget :args (mapcar 'widget-copy (widget-get widget :args)))
1309   widget)
1310
1311 ;; Made defsubst to speed up face editor creation.
1312 (defsubst widget-types-convert-widget (widget)
1313   "Convert :args as widget types in WIDGET."
1314   (widget-put widget :args (mapcar 'widget-convert (widget-get widget :args)))
1315   widget)
1316
1317 (defun widget-value-convert-widget (widget)
1318   "Initialize :value from :args in WIDGET."
1319   (let ((args (widget-get widget :args)))
1320     (when args
1321       (widget-put widget :value (car args))
1322       ;; Don't convert :value here, as this is done in `widget-convert'.
1323       ;; (widget-put widget :value (widget-apply widget
1324       ;;                                      :value-to-internal (car args)))
1325       (widget-put widget :args nil)))
1326   widget)
1327
1328 (defun widget-value-value-get (widget)
1329   "Return the :value property of WIDGET."
1330   (widget-get widget :value))
1331
1332 ;;; The `default' Widget.
1333
1334 (define-widget 'default nil
1335   "Basic widget other widgets are derived from."
1336   :value-to-internal (lambda (widget value) value)
1337   :value-to-external (lambda (widget value) value)
1338   :button-prefix 'widget-button-prefix
1339   :button-suffix 'widget-button-suffix
1340   :complete 'widget-default-complete
1341   :create 'widget-default-create
1342   :indent nil
1343   :offset 0
1344   :format-handler 'widget-default-format-handler
1345   :button-face-get 'widget-default-button-face-get
1346   :sample-face-get 'widget-default-sample-face-get
1347   :delete 'widget-default-delete
1348   :copy 'identity
1349   :value-set 'widget-default-value-set
1350   :value-inline 'widget-default-value-inline
1351   :default-get 'widget-default-default-get
1352   :menu-tag-get 'widget-default-menu-tag-get
1353   :validate #'ignore
1354   :active 'widget-default-active
1355   :activate 'widget-specify-active
1356   :deactivate 'widget-default-deactivate
1357   :mouse-down-action #'ignore
1358   :action 'widget-default-action
1359   :notify 'widget-default-notify
1360   :prompt-value 'widget-default-prompt-value)
1361
1362 (defun widget-default-complete (widget)
1363   "Call the value of the :complete-function property of WIDGET.
1364 If that does not exists, call the value of `widget-complete-field'."
1365   (call-interactively (or (widget-get widget :complete-function)
1366                           widget-complete-field)))
1367
1368 (defun widget-default-create (widget)
1369   "Create WIDGET at point in the current buffer."
1370   (widget-specify-insert
1371    (let ((from (point))
1372          button-begin button-end
1373          sample-begin sample-end
1374          doc-begin doc-end
1375          value-pos)
1376      (insert (widget-get widget :format))
1377      (goto-char from)
1378      ;; Parse escapes in format.
1379      (while (re-search-forward "%\\(.\\)" nil t)
1380        (let ((escape (char-after (match-beginning 1))))
1381          (delete-backward-char 2)
1382          (cond ((eq escape ?%)
1383                 (insert ?%))
1384                ((eq escape ?\[)
1385                 (setq button-begin (point))
1386                 (insert (widget-get-indirect widget :button-prefix)))
1387                ((eq escape ?\])
1388                 (insert (widget-get-indirect widget :button-suffix))
1389                 (setq button-end (point)))
1390                ((eq escape ?\{)
1391                 (setq sample-begin (point)))
1392                ((eq escape ?\})
1393                 (setq sample-end (point)))
1394                ((eq escape ?n)
1395                 (when (widget-get widget :indent)
1396                   (insert ?\n)
1397                   (insert-char ?  (widget-get widget :indent))))
1398                ((eq escape ?t)
1399                 (let ((image (widget-get widget :tag-glyph))
1400                       (tag (widget-get widget :tag)))
1401                   (cond (image
1402                          (widget-image-insert widget (or tag "image") image))
1403                         (tag
1404                          (insert tag))
1405                         (t
1406                          (princ (widget-get widget :value)
1407                                 (current-buffer))))))
1408                ((eq escape ?d)
1409                 (let ((doc (widget-get widget :doc)))
1410                   (when doc
1411                     (setq doc-begin (point))
1412                     (insert doc)
1413                     (while (eq (preceding-char) ?\n)
1414                       (delete-backward-char 1))
1415                     (insert ?\n)
1416                     (setq doc-end (point)))))
1417                ((eq escape ?v)
1418                 (if (and button-begin (not button-end))
1419                     (widget-apply widget :value-create)
1420                   (setq value-pos (point))))
1421                (t
1422                 (widget-apply widget :format-handler escape)))))
1423      ;; Specify button, sample, and doc, and insert value.
1424      (and button-begin button-end
1425           (widget-specify-button widget button-begin button-end))
1426      (and sample-begin sample-end
1427           (widget-specify-sample widget sample-begin sample-end))
1428      (and doc-begin doc-end
1429           (widget-specify-doc widget doc-begin doc-end))
1430      (when value-pos
1431        (goto-char value-pos)
1432        (widget-apply widget :value-create)))
1433    (let ((from (point-min-marker))
1434          (to (point-max-marker)))
1435      (set-marker-insertion-type from t)
1436      (set-marker-insertion-type to nil)
1437      (widget-put widget :from from)
1438      (widget-put widget :to to)))
1439   (widget-clear-undo))
1440
1441 (defun widget-default-format-handler (widget escape)
1442   ;; We recognize the %h escape by default.
1443   (let* ((buttons (widget-get widget :buttons)))
1444     (cond ((eq escape ?h)
1445            (let* ((doc-property (widget-get widget :documentation-property))
1446                   (doc-try (cond ((widget-get widget :doc))
1447                                  ((functionp doc-property)
1448                                   (funcall doc-property
1449                                            (widget-get widget :value)))
1450                                  ((symbolp doc-property)
1451                                   (documentation-property
1452                                    (widget-get widget :value)
1453                                    doc-property))))
1454                   (doc-text (and (stringp doc-try)
1455                                  (> (length doc-try) 1)
1456                                  doc-try))
1457                   (doc-indent (widget-get widget :documentation-indent)))
1458              (when doc-text
1459                (and (eq (preceding-char) ?\n)
1460                     (widget-get widget :indent)
1461                     (insert-char ?  (widget-get widget :indent)))
1462                ;; The `*' in the beginning is redundant.
1463                (when (eq (aref doc-text  0) ?*)
1464                  (setq doc-text (substring doc-text 1)))
1465                ;; Get rid of trailing newlines.
1466                (when (string-match "\n+\\'" doc-text)
1467                  (setq doc-text (substring doc-text 0 (match-beginning 0))))
1468                (push (widget-create-child-and-convert
1469                       widget 'documentation-string
1470                       :indent (cond ((numberp doc-indent )
1471                                      doc-indent)
1472                                     ((null doc-indent)
1473                                      nil)
1474                                     (t 0))
1475                       doc-text)
1476                      buttons))))
1477           (t
1478            (error "Unknown escape `%c'" escape)))
1479     (widget-put widget :buttons buttons)))
1480
1481 (defun widget-default-button-face-get (widget)
1482   ;; Use :button-face or widget-button-face
1483   (or (widget-get widget :button-face)
1484       (let ((parent (widget-get widget :parent)))
1485         (if parent
1486             (widget-apply parent :button-face-get)
1487           widget-button-face))))
1488
1489 (defun widget-default-sample-face-get (widget)
1490   ;; Use :sample-face.
1491   (widget-get widget :sample-face))
1492
1493 (defun widget-default-delete (widget)
1494   "Remove widget from the buffer."
1495   (let ((from (widget-get widget :from))
1496         (to (widget-get widget :to))
1497         (inactive-overlay (widget-get widget :inactive))
1498         (button-overlay (widget-get widget :button-overlay))
1499         (sample-overlay (widget-get widget :sample-overlay))
1500         (doc-overlay (widget-get widget :doc-overlay))
1501         (inhibit-modification-hooks t)
1502         (inhibit-read-only t))
1503     (widget-apply widget :value-delete)
1504     (widget-children-value-delete widget)
1505     (when inactive-overlay
1506       (delete-overlay inactive-overlay))
1507     (when button-overlay
1508       (delete-overlay button-overlay))
1509     (when sample-overlay
1510       (delete-overlay sample-overlay))
1511     (when doc-overlay
1512       (delete-overlay doc-overlay))
1513     (when (< from to)
1514       ;; Kludge: this doesn't need to be true for empty formats.
1515       (delete-region from to))
1516     (set-marker from nil)
1517     (set-marker to nil))
1518   (widget-clear-undo))
1519
1520 (defun widget-default-value-set (widget value)
1521   "Recreate widget with new value."
1522   (let* ((old-pos (point))
1523          (from (copy-marker (widget-get widget :from)))
1524          (to (copy-marker (widget-get widget :to)))
1525          (offset (if (and (<= from old-pos) (<= old-pos to))
1526                      (if (>= old-pos (1- to))
1527                          (- old-pos to 1)
1528                        (- old-pos from)))))
1529     ;;??? Bug: this ought to insert the new value before deleting the old one,
1530     ;; so that markers on either side of the value automatically
1531     ;; stay on the same side.  -- rms.
1532     (save-excursion
1533       (goto-char (widget-get widget :from))
1534       (widget-apply widget :delete)
1535       (widget-put widget :value value)
1536       (widget-apply widget :create))
1537     (if offset
1538         (if (< offset 0)
1539             (goto-char (+ (widget-get widget :to) offset 1))
1540           (goto-char (min (+ from offset) (1- (widget-get widget :to))))))))
1541
1542 (defun widget-default-value-inline (widget)
1543   "Wrap value in a list unless it is inline."
1544   (if (widget-get widget :inline)
1545       (widget-value widget)
1546     (list (widget-value widget))))
1547
1548 (defun widget-default-default-get (widget)
1549   "Get `:value'."
1550   (widget-get widget :value))
1551
1552 (defun widget-default-menu-tag-get (widget)
1553   "Use tag or value for menus."
1554   (or (widget-get widget :menu-tag)
1555       (widget-get widget :tag)
1556       (widget-princ-to-string (widget-get widget :value))))
1557
1558 (defun widget-default-active (widget)
1559   "Return t iff this widget active (user modifiable)."
1560   (or (widget-get widget :always-active)
1561       (and (not (widget-get widget :inactive))
1562            (let ((parent (widget-get widget :parent)))
1563              (or (null parent)
1564                  (widget-apply parent :active))))))
1565
1566 (defun widget-default-deactivate (widget)
1567   "Make WIDGET inactive for user modifications."
1568   (widget-specify-inactive widget
1569                            (widget-get widget :from)
1570                            (widget-get widget :to)))
1571
1572 (defun widget-default-action (widget &optional event)
1573   "Notify the parent when a widget changes."
1574   (let ((parent (widget-get widget :parent)))
1575     (when parent
1576       (widget-apply parent :notify widget event))))
1577
1578 (defun widget-default-notify (widget child &optional event)
1579   "Pass notification to parent."
1580   (widget-default-action widget event))
1581
1582 (defun widget-default-prompt-value (widget prompt value unbound)
1583   "Read an arbitrary value.  Stolen from `set-variable'."
1584 ;; (let ((initial (if unbound
1585 ;; nil
1586 ;; It would be nice if we could do a `(cons val 1)' here.
1587 ;; (prin1-to-string (custom-quote value))))))
1588   (eval-minibuffer prompt))
1589
1590 ;;; The `item' Widget.
1591
1592 (define-widget 'item 'default
1593   "Constant items for inclusion in other widgets."
1594   :convert-widget 'widget-value-convert-widget
1595   :value-create 'widget-item-value-create
1596   :value-delete 'ignore
1597   :value-get 'widget-value-value-get
1598   :match 'widget-item-match
1599   :match-inline 'widget-item-match-inline
1600   :action 'widget-item-action
1601   :format "%t\n")
1602
1603 (defun widget-item-value-create (widget)
1604   "Insert the printed representation of the value."
1605   (princ (widget-get widget :value) (current-buffer)))
1606
1607 (defun widget-item-match (widget value)
1608   ;; Match if the value is the same.
1609   (equal (widget-get widget :value) value))
1610
1611 (defun widget-item-match-inline (widget values)
1612   ;; Match if the value is the same.
1613   (let ((value (widget-get widget :value)))
1614     (and (listp value)
1615          (<= (length value) (length values))
1616          (let ((head (widget-sublist values 0 (length value))))
1617            (and (equal head value)
1618                 (cons head (widget-sublist values (length value))))))))
1619
1620 (defun widget-sublist (list start &optional end)
1621   "Return the sublist of LIST from START to END.
1622 If END is omitted, it defaults to the length of LIST."
1623   (if (> start 0) (setq list (nthcdr start list)))
1624   (if end
1625       (unless (<= end start)
1626         (setq list (copy-sequence list))
1627         (setcdr (nthcdr (- end start 1) list) nil)
1628         list)
1629     (copy-sequence list)))
1630
1631 (defun widget-item-action (widget &optional event)
1632   ;; Just notify itself.
1633   (widget-apply widget :notify widget event))
1634
1635 ;;; The `push-button' Widget.
1636
1637 ;; (defcustom widget-push-button-gui t
1638 ;;   "If non nil, use GUI push buttons when available."
1639 ;;   :group 'widgets
1640 ;;   :type 'boolean)
1641
1642 ;; Cache already created GUI objects.
1643 ;; (defvar widget-push-button-cache nil)
1644
1645 (defcustom widget-push-button-prefix "["
1646   "String used as prefix for buttons."
1647   :type 'string
1648   :group 'widget-button)
1649
1650 (defcustom widget-push-button-suffix "]"
1651   "String used as suffix for buttons."
1652   :type 'string
1653   :group 'widget-button)
1654
1655 (define-widget 'push-button 'item
1656   "A pushable button."
1657   :button-prefix ""
1658   :button-suffix ""
1659   :value-create 'widget-push-button-value-create
1660   :format "%[%v%]")
1661
1662 (defun widget-push-button-value-create (widget)
1663   "Insert text representing the `on' and `off' states."
1664   (let* ((tag (or (widget-get widget :tag)
1665                   (widget-get widget :value)))
1666          (tag-glyph (widget-get widget :tag-glyph))
1667          (text (concat widget-push-button-prefix
1668                        tag widget-push-button-suffix)))
1669     (if tag-glyph
1670         (widget-image-insert widget text tag-glyph)
1671       (insert text))))
1672
1673 ;; (defun widget-gui-action (widget)
1674 ;;   "Apply :action for WIDGET."
1675 ;;   (widget-apply-action widget (this-command-keys)))
1676
1677 ;;; The `link' Widget.
1678
1679 (defcustom widget-link-prefix "["
1680   "String used as prefix for links."
1681   :type 'string
1682   :group 'widget-button)
1683
1684 (defcustom widget-link-suffix "]"
1685   "String used as suffix for links."
1686   :type 'string
1687   :group 'widget-button)
1688
1689 (define-widget 'link 'item
1690   "An embedded link."
1691   :button-prefix 'widget-link-prefix
1692   :button-suffix 'widget-link-suffix
1693   :help-echo "Follow the link."
1694   :format "%[%t%]")
1695
1696 ;;; The `info-link' Widget.
1697
1698 (define-widget 'info-link 'link
1699   "A link to an info file."
1700   :action 'widget-info-link-action)
1701
1702 (defun widget-info-link-action (widget &optional event)
1703   "Open the info node specified by WIDGET."
1704   (info (widget-value widget)))
1705
1706 ;;; The `url-link' Widget.
1707
1708 (define-widget 'url-link 'link
1709   "A link to an www page."
1710   :action 'widget-url-link-action)
1711
1712 (defun widget-url-link-action (widget &optional event)
1713   "Open the url specified by WIDGET."
1714   (browse-url (widget-value widget)))
1715
1716 ;;; The `function-link' Widget.
1717
1718 (define-widget 'function-link 'link
1719   "A link to an Emacs function."
1720   :action 'widget-function-link-action)
1721
1722 (defun widget-function-link-action (widget &optional event)
1723   "Show the function specified by WIDGET."
1724   (describe-function (widget-value widget)))
1725
1726 ;;; The `variable-link' Widget.
1727
1728 (define-widget 'variable-link 'link
1729   "A link to an Emacs variable."
1730   :action 'widget-variable-link-action)
1731
1732 (defun widget-variable-link-action (widget &optional event)
1733   "Show the variable specified by WIDGET."
1734   (describe-variable (widget-value widget)))
1735
1736 ;;; The `file-link' Widget.
1737
1738 (define-widget 'file-link 'link
1739   "A link to a file."
1740   :action 'widget-file-link-action)
1741
1742 (defun widget-file-link-action (widget &optional event)
1743   "Find the file specified by WIDGET."
1744   (find-file (widget-value widget)))
1745
1746 ;;; The `emacs-library-link' Widget.
1747
1748 (define-widget 'emacs-library-link 'link
1749   "A link to an Emacs Lisp library file."
1750   :action 'widget-emacs-library-link-action)
1751
1752 (defun widget-emacs-library-link-action (widget &optional event)
1753   "Find the Emacs Library file specified by WIDGET."
1754   (find-file (locate-library (widget-value widget))))
1755
1756 ;;; The `emacs-commentary-link' Widget.
1757
1758 (define-widget 'emacs-commentary-link 'link
1759   "A link to Commentary in an Emacs Lisp library file."
1760   :action 'widget-emacs-commentary-link-action)
1761
1762 (defun widget-emacs-commentary-link-action (widget &optional event)
1763   "Find the Commentary section of the Emacs file specified by WIDGET."
1764   (finder-commentary (widget-value widget)))
1765
1766 ;;; The `editable-field' Widget.
1767
1768 (define-widget 'editable-field 'default
1769   "An editable text field."
1770   :convert-widget 'widget-value-convert-widget
1771   :keymap widget-field-keymap
1772   :format "%v"
1773   :help-echo "M-TAB: complete field; RET: enter value"
1774   :value ""
1775   :prompt-internal 'widget-field-prompt-internal
1776   :prompt-history 'widget-field-history
1777   :prompt-value 'widget-field-prompt-value
1778   :action 'widget-field-action
1779   :validate 'widget-field-validate
1780   :valid-regexp ""
1781   :error "Field's value doesn't match allowed forms"
1782   :value-create 'widget-field-value-create
1783   :value-delete 'widget-field-value-delete
1784   :value-get 'widget-field-value-get
1785   :match 'widget-field-match)
1786
1787 (defvar widget-field-history nil
1788   "History of field minibuffer edits.")
1789
1790 (defun widget-field-prompt-internal (widget prompt initial history)
1791   "Read string for WIDGET promptinhg with PROMPT.
1792 INITIAL is the initial input and HISTORY is a symbol containing
1793 the earlier input."
1794   (read-string prompt initial history))
1795
1796 (defun widget-field-prompt-value (widget prompt value unbound)
1797   "Prompt for a string."
1798   (widget-apply widget
1799                 :value-to-external
1800                 (widget-apply widget
1801                               :prompt-internal prompt
1802                               (unless unbound
1803                                 (cons (widget-apply widget
1804                                                     :value-to-internal value)
1805                                       0))
1806                               (widget-get widget :prompt-history))))
1807
1808 (defvar widget-edit-functions nil)
1809
1810 (defun widget-field-action (widget &optional event)
1811   "Move to next field."
1812   (widget-forward 1)
1813   (run-hook-with-args 'widget-edit-functions widget))
1814
1815 (defun widget-field-validate (widget)
1816   "Valid if the content matches `:valid-regexp'."
1817   (unless (string-match (widget-get widget :valid-regexp)
1818                         (widget-apply widget :value-get))
1819     widget))
1820
1821 (defun widget-field-value-create (widget)
1822   "Create an editable text field."
1823   (let ((size (widget-get widget :size))
1824         (value (widget-get widget :value))
1825         (from (point))
1826         ;; This is changed to a real overlay in `widget-setup'.  We
1827         ;; need the end points to behave differently until
1828         ;; `widget-setup' is called.
1829         (overlay (cons (make-marker) (make-marker))))
1830     (widget-put widget :field-overlay overlay)
1831     (insert value)
1832     (and size
1833          (< (length value) size)
1834          (insert-char ?\  (- size (length value))))
1835     (unless (memq widget widget-field-list)
1836       (setq widget-field-new (cons widget widget-field-new)))
1837     (move-marker (cdr overlay) (point))
1838     (set-marker-insertion-type (cdr overlay) nil)
1839     (when (null size)
1840       (insert ?\n))
1841     (move-marker (car overlay) from)
1842     (set-marker-insertion-type (car overlay) t)))
1843
1844 (defun widget-field-value-delete (widget)
1845   "Remove the widget from the list of active editing fields."
1846   (setq widget-field-list (delq widget widget-field-list))
1847   (setq widget-field-new (delq widget widget-field-new))
1848   ;; These are nil if the :format string doesn't contain `%v'.
1849   (let ((overlay (widget-get widget :field-overlay)))
1850     (when (overlayp overlay)
1851       (delete-overlay overlay))))
1852
1853 (defun widget-field-value-get (widget)
1854   "Return current text in editing field."
1855   (let ((from (widget-field-start widget))
1856         (to (widget-field-end widget))
1857         (buffer (widget-field-buffer widget))
1858         (size (widget-get widget :size))
1859         (secret (widget-get widget :secret))
1860         (old (current-buffer)))
1861     (if (and from to)
1862         (progn
1863           (set-buffer buffer)
1864           (while (and size
1865                       (not (zerop size))
1866                       (> to from)
1867                       (eq (char-after (1- to)) ?\ ))
1868             (setq to (1- to)))
1869           (let ((result (buffer-substring-no-properties from to)))
1870             (when secret
1871               (let ((index 0))
1872                 (while (< (+ from index) to)
1873                   (aset result index
1874                         (get-char-property (+ from index) 'secret))
1875                   (setq index (1+ index)))))
1876             (set-buffer old)
1877             result))
1878       (widget-get widget :value))))
1879
1880 (defun widget-field-match (widget value)
1881   ;; Match any string.
1882   (stringp value))
1883
1884 ;;; The `text' Widget.
1885
1886 (define-widget 'text 'editable-field
1887   "A multiline text area."
1888   :keymap widget-text-keymap)
1889
1890 ;;; The `menu-choice' Widget.
1891
1892 (define-widget 'menu-choice 'default
1893   "A menu of options."
1894   :convert-widget  'widget-types-convert-widget
1895   :copy 'widget-types-copy
1896   :format "%[%t%]: %v"
1897   :case-fold t
1898   :tag "choice"
1899   :void '(item :format "invalid (%t)\n")
1900   :value-create 'widget-choice-value-create
1901   :value-get 'widget-child-value-get
1902   :value-inline 'widget-child-value-inline
1903   :default-get 'widget-choice-default-get
1904   :mouse-down-action 'widget-choice-mouse-down-action
1905   :action 'widget-choice-action
1906   :error "Make a choice"
1907   :validate 'widget-choice-validate
1908   :match 'widget-choice-match
1909   :match-inline 'widget-choice-match-inline)
1910
1911 (defun widget-choice-value-create (widget)
1912   "Insert the first choice that matches the value."
1913   (let ((value (widget-get widget :value))
1914         (args (widget-get widget :args))
1915         (explicit (widget-get widget :explicit-choice))
1916         current)
1917     (if (and explicit (equal value (widget-get widget :explicit-choice-value)))
1918         (progn
1919           ;; If the user specified the choice for this value,
1920           ;; respect that choice as long as the value is the same.
1921           (widget-put widget :children (list (widget-create-child-value
1922                                               widget explicit value)))
1923           (widget-put widget :choice explicit))
1924       (while args
1925         (setq current (car args)
1926               args (cdr args))
1927         (when (widget-apply current :match value)
1928           (widget-put widget :children (list (widget-create-child-value
1929                                               widget current value)))
1930           (widget-put widget :choice current)
1931           (setq args nil
1932                 current nil)))
1933       (when current
1934         (let ((void (widget-get widget :void)))
1935           (widget-put widget :children (list (widget-create-child-and-convert
1936                                               widget void :value value)))
1937           (widget-put widget :choice void))))))
1938
1939 (defun widget-choice-default-get (widget)
1940   ;; Get default for the first choice.
1941   (widget-default-get (car (widget-get widget :args))))
1942
1943 (defcustom widget-choice-toggle nil
1944   "If non-nil, a binary choice will just toggle between the values.
1945 Otherwise, the user will explicitly have to choose between the values
1946 when he invoked the menu."
1947   :type 'boolean
1948   :group 'widgets)
1949
1950 (defun widget-choice-mouse-down-action (widget &optional event)
1951   ;; Return non-nil if we need a menu.
1952   (let ((args (widget-get widget :args))
1953         (old (widget-get widget :choice)))
1954     (cond ((not (display-popup-menus-p))
1955            ;; No place to pop up a menu.
1956            nil)
1957           ((< (length args) 2)
1958            ;; Empty or singleton list, just return the value.
1959            nil)
1960           ((> (length args) widget-menu-max-size)
1961            ;; Too long, prompt.
1962            nil)
1963           ((> (length args) 2)
1964            ;; Reasonable sized list, use menu.
1965            t)
1966           ((and widget-choice-toggle (memq old args))
1967            ;; We toggle.
1968            nil)
1969           (t
1970            ;; Ask which of the two.
1971            t))))
1972
1973 (defun widget-choice-action (widget &optional event)
1974   ;; Make a choice.
1975   (let ((args (widget-get widget :args))
1976         (old (widget-get widget :choice))
1977         (tag (widget-apply widget :menu-tag-get))
1978         (completion-ignore-case (widget-get widget :case-fold))
1979         this-explicit
1980         current choices)
1981     ;; Remember old value.
1982     (if (and old (not (widget-apply widget :validate)))
1983         (let* ((external (widget-value widget))
1984                (internal (widget-apply old :value-to-internal external)))
1985           (widget-put old :value internal)))
1986     ;; Find new choice.
1987     (setq current
1988           (cond ((= (length args) 0)
1989                  nil)
1990                 ((= (length args) 1)
1991                  (nth 0 args))
1992                 ((and widget-choice-toggle
1993                       (= (length args) 2)
1994                       (memq old args))
1995                  (if (eq old (nth 0 args))
1996                      (nth 1 args)
1997                    (nth 0 args)))
1998                 (t
1999                  (while args
2000                    (setq current (car args)
2001                          args (cdr args))
2002                    (setq choices
2003                          (cons (cons (widget-apply current :menu-tag-get)
2004                                      current)
2005                                choices)))
2006                  (setq this-explicit t)
2007                  (widget-choose tag (reverse choices) event))))
2008     (when current
2009       ;; If this was an explicit user choice,
2010       ;; record the choice, and the record the value it was made for.
2011       ;; widget-choice-value-create will respect this choice,
2012       ;; as long as the value is the same.
2013       (when this-explicit
2014         (widget-put widget :explicit-choice current)
2015         (widget-put widget :explicit-choice-value (widget-get widget :value)))
2016       (widget-value-set widget (widget-default-get current))
2017       (widget-setup)
2018       (widget-apply widget :notify widget event)))
2019   (run-hook-with-args 'widget-edit-functions widget))
2020
2021 (defun widget-choice-validate (widget)
2022   ;; Valid if we have made a valid choice.
2023   (if (eq (widget-get widget :void) (widget-get widget :choice))
2024       widget
2025     (widget-apply (car (widget-get widget :children)) :validate)))
2026
2027 (defun widget-choice-match (widget value)
2028   ;; Matches if one of the choices matches.
2029   (let ((args (widget-get widget :args))
2030         current found)
2031     (while (and args (not found))
2032       (setq current (car args)
2033             args (cdr args)
2034             found (widget-apply current :match value)))
2035     found))
2036
2037 (defun widget-choice-match-inline (widget values)
2038   ;; Matches if one of the choices matches.
2039   (let ((args (widget-get widget :args))
2040         current found)
2041     (while (and args (null found))
2042       (setq current (car args)
2043             args (cdr args)
2044             found (widget-match-inline current values)))
2045     found))
2046
2047 ;;; The `toggle' Widget.
2048
2049 (define-widget 'toggle 'item
2050   "Toggle between two states."
2051   :format "%[%v%]\n"
2052   :value-create 'widget-toggle-value-create
2053   :action 'widget-toggle-action
2054   :match (lambda (widget value) t)
2055   :on "on"
2056   :off "off")
2057
2058 (defun widget-toggle-value-create (widget)
2059   "Insert text representing the `on' and `off' states."
2060   (if (widget-value widget)
2061       (let ((image (widget-get widget :on-glyph)))
2062         (and (display-graphic-p)
2063              (listp image)
2064              (not (eq (car image) 'image))
2065              (widget-put widget :on-glyph (setq image (eval image))))
2066         (widget-image-insert widget
2067                              (widget-get widget :on)
2068                              image))
2069     (let ((image (widget-get widget :off-glyph)))
2070       (and (display-graphic-p)
2071            (listp image)
2072            (not (eq (car image) 'image))
2073            (widget-put widget :off-glyph (setq image (eval image))))
2074       (widget-image-insert widget (widget-get widget :off) image))))
2075
2076 (defun widget-toggle-action (widget &optional event)
2077   ;; Toggle value.
2078   (widget-value-set widget (not (widget-value widget)))
2079   (widget-apply widget :notify widget event)
2080   (run-hook-with-args 'widget-edit-functions widget))
2081
2082 ;;; The `checkbox' Widget.
2083
2084 (define-widget 'checkbox 'toggle
2085   "A checkbox toggle."
2086   :button-suffix ""
2087   :button-prefix ""
2088   :format "%[%v%]"
2089   :on "[X]"
2090   ;; We could probably do the same job as the images using single
2091   ;; space characters in a boxed face with a stretch specification to
2092   ;; make them square.
2093   :on-glyph '(create-image "\300\300\141\143\067\076\034\030"
2094                            'xbm t :width 8 :height 8
2095                            :background "grey75" ; like default mode line
2096                            :foreground "black"
2097                            :relief -2
2098                            :ascent 'center)
2099   :off "[ ]"
2100   :off-glyph '(create-image (make-string 8 0)
2101                             'xbm t :width 8 :height 8
2102                             :background "grey75"
2103                             :foreground "black"
2104                             :relief -2
2105                             :ascent 'center)
2106   :help-echo "Toggle this item."
2107   :action 'widget-checkbox-action)
2108
2109 (defun widget-checkbox-action (widget &optional event)
2110   "Toggle checkbox, notify parent, and set active state of sibling."
2111   (widget-toggle-action widget event)
2112   (let ((sibling (widget-get-sibling widget)))
2113     (when sibling
2114       (if (widget-value widget)
2115           (widget-apply sibling :activate)
2116         (widget-apply sibling :deactivate)))))
2117
2118 ;;; The `checklist' Widget.
2119
2120 (define-widget 'checklist 'default
2121   "A multiple choice widget."
2122   :convert-widget 'widget-types-convert-widget
2123   :copy 'widget-types-copy
2124   :format "%v"
2125   :offset 4
2126   :entry-format "%b %v"
2127   :greedy nil
2128   :value-create 'widget-checklist-value-create
2129   :value-get 'widget-checklist-value-get
2130   :validate 'widget-checklist-validate
2131   :match 'widget-checklist-match
2132   :match-inline 'widget-checklist-match-inline)
2133
2134 (defun widget-checklist-value-create (widget)
2135   ;; Insert all values
2136   (let ((alist (widget-checklist-match-find widget (widget-get widget :value)))
2137         (args (widget-get widget :args)))
2138     (while args
2139       (widget-checklist-add-item widget (car args) (assq (car args) alist))
2140       (setq args (cdr args)))
2141     (widget-put widget :children (nreverse (widget-get widget :children)))))
2142
2143 (defun widget-checklist-add-item (widget type chosen)
2144   "Create checklist item in WIDGET of type TYPE.
2145 If the item is checked, CHOSEN is a cons whose cdr is the value."
2146   (and (eq (preceding-char) ?\n)
2147        (widget-get widget :indent)
2148        (insert-char ?  (widget-get widget :indent)))
2149   (widget-specify-insert
2150    (let* ((children (widget-get widget :children))
2151           (buttons (widget-get widget :buttons))
2152           (button-args (or (widget-get type :sibling-args)
2153                            (widget-get widget :button-args)))
2154           (from (point))
2155           child button)
2156      (insert (widget-get widget :entry-format))
2157      (goto-char from)
2158      ;; Parse % escapes in format.
2159      (while (re-search-forward "%\\([bv%]\\)" nil t)
2160        (let ((escape (char-after (match-beginning 1))))
2161          (delete-backward-char 2)
2162          (cond ((eq escape ?%)
2163                 (insert ?%))
2164                ((eq escape ?b)
2165                 (setq button (apply 'widget-create-child-and-convert
2166                                     widget 'checkbox
2167                                     :value (not (null chosen))
2168                                     button-args)))
2169                ((eq escape ?v)
2170                 (setq child
2171                       (cond ((not chosen)
2172                              (let ((child (widget-create-child widget type)))
2173                                (widget-apply child :deactivate)
2174                                child))
2175                             ((widget-get type :inline)
2176                              (widget-create-child-value
2177                               widget type (cdr chosen)))
2178                             (t
2179                              (widget-create-child-value
2180                               widget type (car (cdr chosen)))))))
2181                (t
2182                 (error "Unknown escape `%c'" escape)))))
2183      ;; Update properties.
2184      (and button child (widget-put child :button button))
2185      (and button (widget-put widget :buttons (cons button buttons)))
2186      (and child (widget-put widget :children (cons child children))))))
2187
2188 (defun widget-checklist-match (widget values)
2189   ;; All values must match a type in the checklist.
2190   (and (listp values)
2191        (null (cdr (widget-checklist-match-inline widget values)))))
2192
2193 (defun widget-checklist-match-inline (widget values)
2194   ;; Find the values which match a type in the checklist.
2195   (let ((greedy (widget-get widget :greedy))
2196         (args (copy-sequence (widget-get widget :args)))
2197         found rest)
2198     (while values
2199       (let ((answer (widget-checklist-match-up args values)))
2200         (cond (answer
2201                (let ((vals (widget-match-inline answer values)))
2202                  (setq found (append found (car vals))
2203                        values (cdr vals)
2204                        args (delq answer args))))
2205               (greedy
2206                (setq rest (append rest (list (car values)))
2207                      values (cdr values)))
2208               (t
2209                (setq rest (append rest values)
2210                      values nil)))))
2211     (cons found rest)))
2212
2213 (defun widget-checklist-match-find (widget vals)
2214   "Find the vals which match a type in the checklist.
2215 Return an alist of (TYPE MATCH)."
2216   (let ((greedy (widget-get widget :greedy))
2217         (args (copy-sequence (widget-get widget :args)))
2218         found)
2219     (while vals
2220       (let ((answer (widget-checklist-match-up args vals)))
2221         (cond (answer
2222                (let ((match (widget-match-inline answer vals)))
2223                  (setq found (cons (cons answer (car match)) found)
2224                        vals (cdr match)
2225                        args (delq answer args))))
2226               (greedy
2227                (setq vals (cdr vals)))
2228               (t
2229                (setq vals nil)))))
2230     found))
2231
2232 (defun widget-checklist-match-up (args vals)
2233   "Return the first type from ARGS that matches VALS."
2234   (let (current found)
2235     (while (and args (null found))
2236       (setq current (car args)
2237             args (cdr args)
2238             found (widget-match-inline current vals)))
2239     (if found
2240         current)))
2241
2242 (defun widget-checklist-value-get (widget)
2243   ;; The values of all selected items.
2244   (let ((children (widget-get widget :children))
2245         child result)
2246     (while children
2247       (setq child (car children)
2248             children (cdr children))
2249       (if (widget-value (widget-get child :button))
2250           (setq result (append result (widget-apply child :value-inline)))))
2251     result))
2252
2253 (defun widget-checklist-validate (widget)
2254   ;; Ticked chilren must be valid.
2255   (let ((children (widget-get widget :children))
2256         child button found)
2257     (while (and children (not found))
2258       (setq child (car children)
2259             children (cdr children)
2260             button (widget-get child :button)
2261             found (and (widget-value button)
2262                        (widget-apply child :validate))))
2263     found))
2264
2265 ;;; The `option' Widget
2266
2267 (define-widget 'option 'checklist
2268   "An widget with an optional item."
2269   :inline t)
2270
2271 ;;; The `choice-item' Widget.
2272
2273 (define-widget 'choice-item 'item
2274   "Button items that delegate action events to their parents."
2275   :action 'widget-parent-action
2276   :format "%[%t%] \n")
2277
2278 ;;; The `radio-button' Widget.
2279
2280 (define-widget 'radio-button 'toggle
2281   "A radio button for use in the `radio' widget."
2282   :notify 'widget-radio-button-notify
2283   :format "%[%v%]"
2284   :button-suffix ""
2285   :button-prefix ""
2286   :on "(*)"
2287   :on-glyph "radio1"
2288   :off "( )"
2289   :off-glyph "radio0")
2290
2291 (defun widget-radio-button-notify (widget child &optional event)
2292   ;; Tell daddy.
2293   (widget-apply (widget-get widget :parent) :action widget event))
2294
2295 ;;; The `radio-button-choice' Widget.
2296
2297 (define-widget 'radio-button-choice 'default
2298   "Select one of multiple options."
2299   :convert-widget 'widget-types-convert-widget
2300   :copy 'widget-types-copy
2301   :offset 4
2302   :format "%v"
2303   :entry-format "%b %v"
2304   :value-create 'widget-radio-value-create
2305   :value-get 'widget-radio-value-get
2306   :value-inline 'widget-radio-value-inline
2307   :value-set 'widget-radio-value-set
2308   :error "You must push one of the buttons"
2309   :validate 'widget-radio-validate
2310   :match 'widget-choice-match
2311   :match-inline 'widget-choice-match-inline
2312   :action 'widget-radio-action)
2313
2314 (defun widget-radio-value-create (widget)
2315   ;; Insert all values
2316   (let ((args (widget-get widget :args))
2317         arg)
2318     (while args
2319       (setq arg (car args)
2320             args (cdr args))
2321       (widget-radio-add-item widget arg))))
2322
2323 (defun widget-radio-add-item (widget type)
2324   "Add to radio widget WIDGET a new radio button item of type TYPE."
2325   ;; (setq type (widget-convert type))
2326   (and (eq (preceding-char) ?\n)
2327        (widget-get widget :indent)
2328        (insert-char ?  (widget-get widget :indent)))
2329   (widget-specify-insert
2330    (let* ((value (widget-get widget :value))
2331           (children (widget-get widget :children))
2332           (buttons (widget-get widget :buttons))
2333           (button-args (or (widget-get type :sibling-args)
2334                            (widget-get widget :button-args)))
2335           (from (point))
2336           (chosen (and (null (widget-get widget :choice))
2337                        (widget-apply type :match value)))
2338           child button)
2339      (insert (widget-get widget :entry-format))
2340      (goto-char from)
2341      ;; Parse % escapes in format.
2342      (while (re-search-forward "%\\([bv%]\\)" nil t)
2343        (let ((escape (char-after (match-beginning 1))))
2344          (delete-backward-char 2)
2345          (cond ((eq escape ?%)
2346                 (insert ?%))
2347                ((eq escape ?b)
2348                 (setq button (apply 'widget-create-child-and-convert
2349                                     widget 'radio-button
2350                                     :value (not (null chosen))
2351                                     button-args)))
2352                ((eq escape ?v)
2353                 (setq child (if chosen
2354                                 (widget-create-child-value
2355                                  widget type value)
2356                               (widget-create-child widget type)))
2357                 (unless chosen
2358                   (widget-apply child :deactivate)))
2359                (t
2360                 (error "Unknown escape `%c'" escape)))))
2361      ;; Update properties.
2362      (when chosen
2363        (widget-put widget :choice type))
2364      (when button
2365        (widget-put child :button button)
2366        (widget-put widget :buttons (nconc buttons (list button))))
2367      (when child
2368        (widget-put widget :children (nconc children (list child))))
2369      child)))
2370
2371 (defun widget-radio-value-get (widget)
2372   ;; Get value of the child widget.
2373   (let ((chosen (widget-radio-chosen widget)))
2374     (and chosen (widget-value chosen))))
2375
2376 (defun widget-radio-chosen (widget)
2377   "Return the widget representing the chosen radio button."
2378   (let ((children (widget-get widget :children))
2379         current found)
2380     (while children
2381       (setq current (car children)
2382             children (cdr children))
2383       (when (widget-apply (widget-get current :button) :value-get)
2384         (setq found current
2385               children nil)))
2386     found))
2387
2388 (defun widget-radio-value-inline (widget)
2389   ;; Get value of the child widget.
2390   (let ((children (widget-get widget :children))
2391         current found)
2392     (while children
2393       (setq current (car children)
2394             children (cdr children))
2395       (when (widget-apply (widget-get current :button) :value-get)
2396         (setq found (widget-apply current :value-inline)
2397               children nil)))
2398     found))
2399
2400 (defun widget-radio-value-set (widget value)
2401   ;; We can't just delete and recreate a radio widget, since children
2402   ;; can be added after the original creation and won't be recreated
2403   ;; by `:create'.
2404   (let ((children (widget-get widget :children))
2405         current found)
2406     (while children
2407       (setq current (car children)
2408             children (cdr children))
2409       (let* ((button (widget-get current :button))
2410              (match (and (not found)
2411                          (widget-apply current :match value))))
2412         (widget-value-set button match)
2413         (if match
2414             (progn
2415               (widget-value-set current value)
2416               (widget-apply current :activate))
2417           (widget-apply current :deactivate))
2418         (setq found (or found match))))))
2419
2420 (defun widget-radio-validate (widget)
2421   ;; Valid if we have made a valid choice.
2422   (let ((children (widget-get widget :children))
2423         current found button)
2424     (while (and children (not found))
2425       (setq current (car children)
2426             children (cdr children)
2427             button (widget-get current :button)
2428             found (widget-apply button :value-get)))
2429     (if found
2430         (widget-apply current :validate)
2431       widget)))
2432
2433 (defun widget-radio-action (widget child event)
2434   ;; Check if a radio button was pressed.
2435   (let ((children (widget-get widget :children))
2436         (buttons (widget-get widget :buttons))
2437         current)
2438     (when (memq child buttons)
2439       (while children
2440         (setq current (car children)
2441               children (cdr children))
2442         (let* ((button (widget-get current :button)))
2443           (cond ((eq child button)
2444                  (widget-value-set button t)
2445                  (widget-apply current :activate))
2446                 ((widget-value button)
2447                  (widget-value-set button nil)
2448                  (widget-apply current :deactivate)))))))
2449   ;; Pass notification to parent.
2450   (widget-apply widget :notify child event))
2451
2452 ;;; The `insert-button' Widget.
2453
2454 (define-widget 'insert-button 'push-button
2455   "An insert button for the `editable-list' widget."
2456   :tag "INS"
2457   :help-echo "Insert a new item into the list at this position."
2458   :action 'widget-insert-button-action)
2459
2460 (defun widget-insert-button-action (widget &optional event)
2461   ;; Ask the parent to insert a new item.
2462   (widget-apply (widget-get widget :parent)
2463                 :insert-before (widget-get widget :widget)))
2464
2465 ;;; The `delete-button' Widget.
2466
2467 (define-widget 'delete-button 'push-button
2468   "A delete button for the `editable-list' widget."
2469   :tag "DEL"
2470   :help-echo "Delete this item from the list."
2471   :action 'widget-delete-button-action)
2472
2473 (defun widget-delete-button-action (widget &optional event)
2474   ;; Ask the parent to insert a new item.
2475   (widget-apply (widget-get widget :parent)
2476                 :delete-at (widget-get widget :widget)))
2477
2478 ;;; The `editable-list' Widget.
2479
2480 ;; (defcustom widget-editable-list-gui nil
2481 ;;   "If non nil, use GUI push-buttons in editable list when available."
2482 ;;   :type 'boolean
2483 ;;   :group 'widgets)
2484
2485 (define-widget 'editable-list 'default
2486   "A variable list of widgets of the same type."
2487   :convert-widget 'widget-types-convert-widget
2488   :copy 'widget-types-copy
2489   :offset 12
2490   :format "%v%i\n"
2491   :format-handler 'widget-editable-list-format-handler
2492   :entry-format "%i %d %v"
2493   :value-create 'widget-editable-list-value-create
2494   :value-get 'widget-editable-list-value-get
2495   :validate 'widget-children-validate
2496   :match 'widget-editable-list-match
2497   :match-inline 'widget-editable-list-match-inline
2498   :insert-before 'widget-editable-list-insert-before
2499   :delete-at 'widget-editable-list-delete-at)
2500
2501 (defun widget-editable-list-format-handler (widget escape)
2502   ;; We recognize the insert button.
2503     ;; (let ((widget-push-button-gui widget-editable-list-gui))
2504     (cond ((eq escape ?i)
2505            (and (widget-get widget :indent)
2506                 (insert-char ?\  (widget-get widget :indent)))
2507            (apply 'widget-create-child-and-convert
2508                   widget 'insert-button
2509                   (widget-get widget :append-button-args)))
2510           (t
2511            (widget-default-format-handler widget escape)))
2512     ;; )
2513   )
2514
2515 (defun widget-editable-list-value-create (widget)
2516   ;; Insert all values
2517   (let* ((value (widget-get widget :value))
2518          (type (nth 0 (widget-get widget :args)))
2519          children)
2520     (widget-put widget :value-pos (copy-marker (point)))
2521     (set-marker-insertion-type (widget-get widget :value-pos) t)
2522     (while value
2523       (let ((answer (widget-match-inline type value)))
2524         (if answer
2525             (setq children (cons (widget-editable-list-entry-create
2526                                   widget
2527                                   (if (widget-get type :inline)
2528                                       (car answer)
2529                                     (car (car answer)))
2530                                   t)
2531                                  children)
2532                   value (cdr answer))
2533           (setq value nil))))
2534     (widget-put widget :children (nreverse children))))
2535
2536 (defun widget-editable-list-value-get (widget)
2537   ;; Get value of the child widget.
2538   (apply 'append (mapcar (lambda (child) (widget-apply child :value-inline))
2539                          (widget-get widget :children))))
2540
2541 (defun widget-editable-list-match (widget value)
2542   ;; Value must be a list and all the members must match the type.
2543   (and (listp value)
2544        (null (cdr (widget-editable-list-match-inline widget value)))))
2545
2546 (defun widget-editable-list-match-inline (widget value)
2547   (let ((type (nth 0 (widget-get widget :args)))
2548         (ok t)
2549         found)
2550     (while (and value ok)
2551       (let ((answer (widget-match-inline type value)))
2552         (if answer
2553             (setq found (append found (car answer))
2554                   value (cdr answer))
2555           (setq ok nil))))
2556     (cons found value)))
2557
2558 (defun widget-editable-list-insert-before (widget before)
2559   ;; Insert a new child in the list of children.
2560   (save-excursion
2561     (let ((children (widget-get widget :children))
2562           (inhibit-read-only t)
2563           before-change-functions
2564           after-change-functions)
2565       (cond (before
2566              (goto-char (widget-get before :entry-from)))
2567             (t
2568              (goto-char (widget-get widget :value-pos))))
2569       (let ((child (widget-editable-list-entry-create
2570                     widget nil nil)))
2571         (when (< (widget-get child :entry-from) (widget-get widget :from))
2572           (set-marker (widget-get widget :from)
2573                       (widget-get child :entry-from)))
2574         (if (eq (car children) before)
2575             (widget-put widget :children (cons child children))
2576           (while (not (eq (car (cdr children)) before))
2577             (setq children (cdr children)))
2578           (setcdr children (cons child (cdr children)))))))
2579   (widget-setup)
2580   (widget-apply widget :notify widget))
2581
2582 (defun widget-editable-list-delete-at (widget child)
2583   ;; Delete child from list of children.
2584   (save-excursion
2585     (let ((buttons (copy-sequence (widget-get widget :buttons)))
2586           button
2587           (inhibit-read-only t)
2588           before-change-functions
2589           after-change-functions)
2590       (while buttons
2591         (setq button (car buttons)
2592               buttons (cdr buttons))
2593         (when (eq (widget-get button :widget) child)
2594           (widget-put widget
2595                       :buttons (delq button (widget-get widget :buttons)))
2596           (widget-delete button))))
2597     (let ((entry-from (widget-get child :entry-from))
2598           (entry-to (widget-get child :entry-to))
2599           (inhibit-read-only t)
2600           before-change-functions
2601           after-change-functions)
2602       (widget-delete child)
2603       (delete-region entry-from entry-to)
2604       (set-marker entry-from nil)
2605       (set-marker entry-to nil))
2606     (widget-put widget :children (delq child (widget-get widget :children))))
2607   (widget-setup)
2608   (widget-apply widget :notify widget))
2609
2610 (defun widget-editable-list-entry-create (widget value conv)
2611   ;; Create a new entry to the list.
2612   (let ((type (nth 0 (widget-get widget :args)))
2613         ;; (widget-push-button-gui widget-editable-list-gui)
2614         child delete insert)
2615     (widget-specify-insert
2616      (save-excursion
2617        (and (widget-get widget :indent)
2618             (insert-char ?\  (widget-get widget :indent)))
2619        (insert (widget-get widget :entry-format)))
2620      ;; Parse % escapes in format.
2621      (while (re-search-forward "%\\(.\\)" nil t)
2622        (let ((escape (char-after (match-beginning 1))))
2623          (delete-backward-char 2)
2624          (cond ((eq escape ?%)
2625                 (insert ?%))
2626                ((eq escape ?i)
2627                 (setq insert (apply 'widget-create-child-and-convert
2628                                     widget 'insert-button
2629                                     (widget-get widget :insert-button-args))))
2630                ((eq escape ?d)
2631                 (setq delete (apply 'widget-create-child-and-convert
2632                                     widget 'delete-button
2633                                     (widget-get widget :delete-button-args))))
2634                ((eq escape ?v)
2635                 (if conv
2636                     (setq child (widget-create-child-value
2637                                  widget type value))
2638                   (setq child (widget-create-child-value
2639                                widget type (widget-default-get type)))))
2640                (t
2641                 (error "Unknown escape `%c'" escape)))))
2642      (let ((buttons (widget-get widget :buttons)))
2643        (if insert (push insert buttons))
2644        (if delete (push delete buttons))
2645        (widget-put widget :buttons buttons))
2646      (let ((entry-from (point-min-marker))
2647            (entry-to (point-max-marker)))
2648        (set-marker-insertion-type entry-from t)
2649        (set-marker-insertion-type entry-to nil)
2650        (widget-put child :entry-from entry-from)
2651        (widget-put child :entry-to entry-to)))
2652     (if insert (widget-put insert :widget child))
2653     (if delete (widget-put delete :widget child))
2654     child))
2655
2656 ;;; The `group' Widget.
2657
2658 (define-widget 'group 'default
2659   "A widget which groups other widgets inside."
2660   :convert-widget 'widget-types-convert-widget
2661   :copy 'widget-types-copy
2662   :format "%v"
2663   :value-create 'widget-group-value-create
2664   :value-get 'widget-editable-list-value-get
2665   :default-get 'widget-group-default-get
2666   :validate 'widget-children-validate
2667   :match 'widget-group-match
2668   :match-inline 'widget-group-match-inline)
2669
2670 (defun widget-group-value-create (widget)
2671   ;; Create each component.
2672   (let ((args (widget-get widget :args))
2673         (value (widget-get widget :value))
2674         arg answer children)
2675     (while args
2676       (setq arg (car args)
2677             args (cdr args)
2678             answer (widget-match-inline arg value)
2679             value (cdr answer))
2680       (and (eq (preceding-char) ?\n)
2681            (widget-get widget :indent)
2682            (insert-char ?\  (widget-get widget :indent)))
2683       (push (cond ((null answer)
2684                    (widget-create-child widget arg))
2685                   ((widget-get arg :inline)
2686                    (widget-create-child-value widget arg (car answer)))
2687                   (t
2688                    (widget-create-child-value widget arg (car (car answer)))))
2689             children))
2690     (widget-put widget :children (nreverse children))))
2691
2692 (defun widget-group-default-get (widget)
2693   ;; Get the default of the components.
2694   (mapcar 'widget-default-get (widget-get widget :args)))
2695
2696 (defun widget-group-match (widget values)
2697   ;; Match if the components match.
2698   (and (listp values)
2699        (let ((match (widget-group-match-inline widget values)))
2700          (and match (null (cdr match))))))
2701
2702 (defun widget-group-match-inline (widget vals)
2703   ;; Match if the components match.
2704   (let ((args (widget-get widget :args))
2705         argument answer found)
2706     (while args
2707       (setq argument (car args)
2708             args (cdr args)
2709             answer (widget-match-inline argument vals))
2710       (if answer
2711           (setq vals (cdr answer)
2712                 found (append found (car answer)))
2713         (setq vals nil
2714               args nil)))
2715     (if answer
2716         (cons found vals))))
2717
2718 ;;; The `visibility' Widget.
2719
2720 (define-widget 'visibility 'item
2721   "An indicator and manipulator for hidden items."
2722   :format "%[%v%]"
2723   :button-prefix ""
2724   :button-suffix ""
2725   :on "Hide"
2726   :off "Show"
2727   :value-create 'widget-visibility-value-create
2728   :action 'widget-toggle-action
2729   :match (lambda (widget value) t))
2730
2731 (defun widget-visibility-value-create (widget)
2732   ;; Insert text representing the `on' and `off' states.
2733   (let ((on (widget-get widget :on))
2734         (off (widget-get widget :off)))
2735     (if on
2736         (setq on (concat widget-push-button-prefix
2737                          on
2738                          widget-push-button-suffix))
2739       (setq on ""))
2740     (if off
2741         (setq off (concat widget-push-button-prefix
2742                           off
2743                           widget-push-button-suffix))
2744       (setq off ""))
2745     (if (widget-value widget)
2746         (widget-image-insert widget on "down" "down-pushed")
2747       (widget-image-insert widget off "right" "right-pushed"))))
2748
2749 ;;; The `documentation-link' Widget.
2750 ;;
2751 ;; This is a helper widget for `documentation-string'.
2752
2753 (define-widget 'documentation-link 'link
2754   "Link type used in documentation strings."
2755   :tab-order -1
2756   :help-echo "Describe this symbol"
2757   :action 'widget-documentation-link-action)
2758
2759 (defun widget-documentation-link-action (widget &optional event)
2760   "Display documentation for WIDGET's value.  Ignore optional argument EVENT."
2761   (let* ((string (widget-get widget :value))
2762          (symbol (intern string)))
2763     (if (and (fboundp symbol) (boundp symbol))
2764         ;; If there are two doc strings, give the user a way to pick one.
2765         (apropos (concat "\\`" (regexp-quote string) "\\'"))
2766       (if (fboundp symbol)
2767           (describe-function symbol)
2768         (describe-variable symbol)))))
2769
2770 (defcustom widget-documentation-links t
2771   "Add hyperlinks to documentation strings when non-nil."
2772   :type 'boolean
2773   :group 'widget-documentation)
2774
2775 (defcustom widget-documentation-link-regexp "`\\([^\n`' ]+\\)'"
2776   "Regexp for matching potential links in documentation strings.
2777 The first group should be the link itself."
2778   :type 'regexp
2779   :group 'widget-documentation)
2780
2781 (defcustom widget-documentation-link-p 'intern-soft
2782   "Predicate used to test if a string is useful as a link.
2783 The value should be a function.  The function will be called one
2784 argument, a string, and should return non-nil if there should be a
2785 link for that string."
2786   :type 'function
2787   :options '(widget-documentation-link-p)
2788   :group 'widget-documentation)
2789
2790 (defcustom widget-documentation-link-type 'documentation-link
2791   "Widget type used for links in documentation strings."
2792   :type 'symbol
2793   :group 'widget-documentation)
2794
2795 (defun widget-documentation-link-add (widget from to)
2796   (widget-specify-doc widget from to)
2797   (when widget-documentation-links
2798     (let ((regexp widget-documentation-link-regexp)
2799           (buttons (widget-get widget :buttons))
2800           (widget-mouse-face (default-value 'widget-mouse-face))
2801           (widget-button-face widget-documentation-face)
2802           (widget-button-pressed-face widget-documentation-face))
2803       (save-excursion
2804         (goto-char from)
2805         (while (re-search-forward regexp to t)
2806           (let ((name (match-string 1))
2807                 (begin (match-beginning 1))
2808                 (end (match-end 1)))
2809             (when (funcall widget-documentation-link-p name)
2810               (push (widget-convert-button widget-documentation-link-type
2811                                            begin end :value name)
2812                     buttons)))))
2813       (widget-put widget :buttons buttons)))
2814   (let ((indent (widget-get widget :indent)))
2815     (when (and indent (not (zerop indent)))
2816       (save-excursion
2817         (save-restriction
2818           (narrow-to-region from to)
2819           (goto-char (point-min))
2820           (while (search-forward "\n" nil t)
2821             (insert-char ?\  indent)))))))
2822
2823 ;;; The `documentation-string' Widget.
2824
2825 (define-widget 'documentation-string 'item
2826   "A documentation string."
2827   :format "%v"
2828   :action 'widget-documentation-string-action
2829   :value-create 'widget-documentation-string-value-create)
2830
2831 (defun widget-documentation-string-value-create (widget)
2832   ;; Insert documentation string.
2833   (let ((doc (widget-value widget))
2834         (indent (widget-get widget :indent))
2835         (shown (widget-get (widget-get widget :parent) :documentation-shown))
2836         (start (point)))
2837     (if (string-match "\n" doc)
2838         (let ((before (substring doc 0 (match-beginning 0)))
2839               (after (substring doc (match-beginning 0)))
2840               button)
2841           (insert before ?\ )
2842           (widget-documentation-link-add widget start (point))
2843           (setq button
2844                 (widget-create-child-and-convert
2845                  widget 'visibility
2846                  :help-echo "Show or hide rest of the documentation."
2847                  :on "Hide Rest"
2848                  :off "More"
2849                  :always-active t
2850                  :action 'widget-parent-action
2851                  shown))
2852           (when shown
2853             (setq start (point))
2854             (when (and indent (not (zerop indent)))
2855               (insert-char ?\  indent))
2856             (insert after)
2857             (widget-documentation-link-add widget start (point)))
2858           (widget-put widget :buttons (list button)))
2859       (insert doc)
2860       (widget-documentation-link-add widget start (point))))
2861   (insert ?\n))
2862
2863 (defun widget-documentation-string-action (widget &rest ignore)
2864   ;; Toggle documentation.
2865   (let ((parent (widget-get widget :parent)))
2866     (widget-put parent :documentation-shown
2867                 (not (widget-get parent :documentation-shown))))
2868   ;; Redraw.
2869   (widget-value-set widget (widget-value widget)))
2870 \f
2871 ;;; The Sexp Widgets.
2872
2873 (define-widget 'const 'item
2874   "An immutable sexp."
2875   :prompt-value 'widget-const-prompt-value
2876   :format "%t\n%d")
2877
2878 (defun widget-const-prompt-value (widget prompt value unbound)
2879   ;; Return the value of the const.
2880   (widget-value widget))
2881
2882 (define-widget 'function-item 'const
2883   "An immutable function name."
2884   :format "%v\n%h"
2885   :documentation-property (lambda (symbol)
2886                             (condition-case nil
2887                                 (documentation symbol t)
2888                               (error nil))))
2889
2890 (define-widget 'variable-item 'const
2891   "An immutable variable name."
2892   :format "%v\n%h"
2893   :documentation-property 'variable-documentation)
2894
2895 (define-widget 'other 'sexp
2896   "Matches any value, but doesn't let the user edit the value.
2897 This is useful as last item in a `choice' widget.
2898 You should use this widget type with a default value,
2899 as in (other DEFAULT) or (other :tag \"NAME\" DEFAULT).
2900 If the user selects this alternative, that specifies DEFAULT
2901 as the value."
2902   :tag "Other"
2903   :format "%t%n"
2904   :value 'other)
2905
2906 (defvar widget-string-prompt-value-history nil
2907   "History of input to `widget-string-prompt-value'.")
2908
2909 (define-widget 'string 'editable-field
2910   "A string"
2911   :tag "String"
2912   :format "%{%t%}: %v"
2913   :complete-function 'ispell-complete-word
2914   :prompt-history 'widget-string-prompt-value-history)
2915
2916 (define-widget 'regexp 'string
2917   "A regular expression."
2918   :match 'widget-regexp-match
2919   :validate 'widget-regexp-validate
2920   ;; Doesn't work well with terminating newline.
2921   ;; :value-face 'widget-single-line-field-face
2922   :tag "Regexp")
2923
2924 (defun widget-regexp-match (widget value)
2925   ;; Match valid regexps.
2926   (and (stringp value)
2927        (condition-case nil
2928            (prog1 t
2929              (string-match value ""))
2930          (error nil))))
2931
2932 (defun widget-regexp-validate (widget)
2933   "Check that the value of WIDGET is a valid regexp."
2934   (condition-case data
2935       (prog1 nil
2936         (string-match (widget-value widget) ""))
2937     (error (widget-put widget :error (error-message-string data))
2938            widget)))
2939
2940 (define-widget 'file 'string
2941   "A file widget.
2942 It will read a file name from the minibuffer when invoked."
2943   :complete-function 'widget-file-complete
2944   :prompt-value 'widget-file-prompt-value
2945   :format "%{%t%}: %v"
2946   ;; Doesn't work well with terminating newline.
2947   ;; :value-face 'widget-single-line-field-face
2948   :tag "File")
2949
2950 (defun widget-file-complete ()
2951   "Perform completion on file name preceding point."
2952   (interactive)
2953   (let* ((end (point))
2954          (beg (save-excursion
2955                 (skip-chars-backward "^ ")
2956                 (point)))
2957          (pattern (buffer-substring beg end))
2958          (name-part (file-name-nondirectory pattern))
2959          (directory (file-name-directory pattern))
2960          (completion (file-name-completion name-part directory)))
2961     (cond ((eq completion t))
2962           ((null completion)
2963            (message "Can't find completion for \"%s\"" pattern)
2964            (ding))
2965           ((not (string= name-part completion))
2966            (delete-region beg end)
2967            (insert (expand-file-name completion directory)))
2968           (t
2969            (message "Making completion list...")
2970            (with-output-to-temp-buffer "*Completions*"
2971              (display-completion-list
2972               (sort (file-name-all-completions name-part directory)
2973                     'string<)))
2974            (message "Making completion list...%s" "done")))))
2975
2976 (defun widget-file-prompt-value (widget prompt value unbound)
2977   ;; Read file from minibuffer.
2978   (abbreviate-file-name
2979    (if unbound
2980        (read-file-name prompt)
2981      (let ((prompt2 (format "%s (default %s) " prompt value))
2982            (dir (file-name-directory value))
2983            (file (file-name-nondirectory value))
2984            (must-match (widget-get widget :must-match)))
2985        (read-file-name prompt2 dir nil must-match file)))))
2986
2987 ;;;(defun widget-file-action (widget &optional event)
2988 ;;;  ;; Read a file name from the minibuffer.
2989 ;;;  (let* ((value (widget-value widget))
2990 ;;;      (dir (file-name-directory value))
2991 ;;;      (file (file-name-nondirectory value))
2992 ;;;      (menu-tag (widget-apply widget :menu-tag-get))
2993 ;;;      (must-match (widget-get widget :must-match))
2994 ;;;      (answer (read-file-name (concat menu-tag ": (default `" value "') ")
2995 ;;;                              dir nil must-match file)))
2996 ;;;    (widget-value-set widget (abbreviate-file-name answer))
2997 ;;;    (widget-setup)
2998 ;;;    (widget-apply widget :notify widget event)))
2999
3000 ;; Fixme: use file-name-as-directory.
3001 (define-widget 'directory 'file
3002   "A directory widget.
3003 It will read a directory name from the minibuffer when invoked."
3004   :tag "Directory")
3005
3006 (defvar widget-symbol-prompt-value-history nil
3007   "History of input to `widget-symbol-prompt-value'.")
3008
3009 (define-widget 'symbol 'editable-field
3010   "A Lisp symbol."
3011   :value nil
3012   :tag "Symbol"
3013   :format "%{%t%}: %v"
3014   :match (lambda (widget value) (symbolp value))
3015   :complete-function 'lisp-complete-symbol
3016   :prompt-internal 'widget-symbol-prompt-internal
3017   :prompt-match 'symbolp
3018   :prompt-history 'widget-symbol-prompt-value-history
3019   :value-to-internal (lambda (widget value)
3020                        (if (symbolp value)
3021                            (symbol-name value)
3022                          value))
3023   :value-to-external (lambda (widget value)
3024                        (if (stringp value)
3025                            (intern value)
3026                          value)))
3027
3028 (defun widget-symbol-prompt-internal (widget prompt initial history)
3029   ;; Read file from minibuffer.
3030   (let ((answer (completing-read prompt obarray
3031                                  (widget-get widget :prompt-match)
3032                                  nil initial history)))
3033     (if (and (stringp answer)
3034              (not (zerop (length answer))))
3035         answer
3036       (error "No value"))))
3037
3038 (defvar widget-function-prompt-value-history nil
3039   "History of input to `widget-function-prompt-value'.")
3040
3041 (define-widget 'function 'sexp
3042   "A Lisp function."
3043   :complete-function (lambda ()
3044                        (interactive)
3045                        (lisp-complete-symbol 'fboundp))
3046   :prompt-value 'widget-field-prompt-value
3047   :prompt-internal 'widget-symbol-prompt-internal
3048   :prompt-match 'fboundp
3049   :prompt-history 'widget-function-prompt-value-history
3050   :action 'widget-field-action
3051   :match-alternatives '(functionp)
3052   :validate (lambda (widget)
3053               (unless (functionp (widget-value widget))
3054                 (widget-put widget :error (format "Invalid function: %S"
3055                                                   (widget-value widget)))
3056                 widget))
3057   :value 'ignore
3058   :tag "Function")
3059
3060 (defvar widget-variable-prompt-value-history nil
3061   "History of input to `widget-variable-prompt-value'.")
3062
3063 (define-widget 'variable 'symbol
3064   "A Lisp variable."
3065   :prompt-match 'boundp
3066   :prompt-history 'widget-variable-prompt-value-history
3067   :complete-function (lambda ()
3068                        (interactive)
3069                        (lisp-complete-symbol 'boundp))
3070   :tag "Variable")
3071
3072 (defvar widget-coding-system-prompt-value-history nil
3073   "History of input to `widget-coding-system-prompt-value'.")
3074
3075 (define-widget 'coding-system 'symbol
3076   "A MULE coding-system."
3077   :format "%{%t%}: %v"
3078   :tag "Coding system"
3079   :base-only nil
3080   :prompt-history 'widget-coding-system-prompt-value-history
3081   :prompt-value 'widget-coding-system-prompt-value
3082   :action 'widget-coding-system-action
3083   :complete-function (lambda ()
3084                        (interactive)
3085                        (lisp-complete-symbol 'coding-system-p))
3086   :validate (lambda (widget)
3087               (unless (coding-system-p (widget-value widget))
3088                 (widget-put widget :error (format "Invalid coding system: %S"
3089                                                   (widget-value widget)))
3090                 widget))
3091   :value 'undecided
3092   :prompt-match 'coding-system-p)
3093
3094 (defun widget-coding-system-prompt-value (widget prompt value unbound)
3095   "Read coding-system from minibuffer."
3096   (if (widget-get widget :base-only)
3097       (intern
3098        (completing-read (format "%s (default %s) " prompt value)
3099                         (mapcar #'list (coding-system-list t)) nil nil nil
3100                         coding-system-history))
3101       (read-coding-system (format "%s (default %s) " prompt value) value)))
3102
3103 (defun widget-coding-system-action (widget &optional event)
3104   (let ((answer
3105          (widget-coding-system-prompt-value
3106           widget
3107           (widget-apply widget :menu-tag-get)
3108           (widget-value widget)
3109           t)))
3110     (widget-value-set widget answer)
3111     (widget-apply widget :notify widget event)
3112     (widget-setup)))
3113 \f
3114 (define-widget 'sexp 'editable-field
3115   "An arbitrary Lisp expression."
3116   :tag "Lisp expression"
3117   :format "%{%t%}: %v"
3118   :value nil
3119   :validate 'widget-sexp-validate
3120   :match (lambda (widget value) t)
3121   :value-to-internal 'widget-sexp-value-to-internal
3122   :value-to-external (lambda (widget value) (read value))
3123   :prompt-history 'widget-sexp-prompt-value-history
3124   :prompt-value 'widget-sexp-prompt-value)
3125
3126 (defun widget-sexp-value-to-internal (widget value)
3127   ;; Use pp for printer representation.
3128   (let ((pp (if (symbolp value)
3129                 (prin1-to-string value)
3130               (pp-to-string value))))
3131     (while (string-match "\n\\'" pp)
3132       (setq pp (substring pp 0 -1)))
3133     (if (or (string-match "\n\\'" pp)
3134             (> (length pp) 40))
3135         (concat "\n" pp)
3136       pp)))
3137
3138 (defun widget-sexp-validate (widget)
3139   ;; Valid if we can read the string and there is no junk left after it.
3140   (with-temp-buffer
3141     (insert (widget-apply widget :value-get))
3142     (goto-char (point-min))
3143     (let (err)
3144       (condition-case data
3145           (progn
3146             ;; Avoid a confusing end-of-file error.
3147             (skip-syntax-forward "\\s-")
3148             (if (eobp)
3149                 (setq err "Empty sexp -- use `nil'?")
3150               (unless (widget-apply widget :match (read (current-buffer)))
3151                 (setq err (widget-get widget :type-error))))
3152             (if (and (not (eobp))
3153                      (not err))
3154                 (setq err (format "Junk at end of expression: %s"
3155                                   (buffer-substring (point)
3156                                                     (point-max))))))
3157         (end-of-file                    ; Avoid confusing error message.
3158          (setq err "Unbalanced sexp"))
3159         (error (setq err (error-message-string data))))
3160       (if (not err)
3161           nil
3162         (widget-put widget :error err)
3163         widget))))
3164
3165 (defvar widget-sexp-prompt-value-history nil
3166   "History of input to `widget-sexp-prompt-value'.")
3167
3168 (defun widget-sexp-prompt-value (widget prompt value unbound)
3169   ;; Read an arbitrary sexp.
3170   (let ((found (read-string prompt
3171                             (if unbound nil (cons (prin1-to-string value) 0))
3172                             (widget-get widget :prompt-history))))
3173     (let ((answer (read-from-string found)))
3174       (unless (= (cdr answer) (length found))
3175         (error "Junk at end of expression: %s"
3176                (substring found (cdr answer))))
3177       (car answer))))
3178
3179 (define-widget 'restricted-sexp 'sexp
3180   "A Lisp expression restricted to values that match.
3181 To use this type, you must define :match or :match-alternatives."
3182   :type-error "The specified value is not valid"
3183   :match 'widget-restricted-sexp-match
3184   :value-to-internal (lambda (widget value)
3185                        (if (widget-apply widget :match value)
3186                            (prin1-to-string value)
3187                          value)))
3188
3189 (defun widget-restricted-sexp-match (widget value)
3190   (let ((alternatives (widget-get widget :match-alternatives))
3191         matched)
3192     (while (and alternatives (not matched))
3193       (if (cond ((functionp (car alternatives))
3194                  (funcall (car alternatives) value))
3195                 ((and (consp (car alternatives))
3196                       (eq (car (car alternatives)) 'quote))
3197                  (eq value (nth 1 (car alternatives)))))
3198           (setq matched t))
3199       (setq alternatives (cdr alternatives)))
3200     matched))
3201 \f
3202 (define-widget 'integer 'restricted-sexp
3203   "An integer."
3204   :tag "Integer"
3205   :value 0
3206   :type-error "This field should contain an integer"
3207   :match-alternatives '(integerp))
3208
3209 (define-widget 'number 'restricted-sexp
3210   "A number (floating point or integer)."
3211   :tag "Number"
3212   :value 0.0
3213   :type-error "This field should contain a number (floating point or integer)"
3214   :match-alternatives '(numberp))
3215
3216 (define-widget 'float 'restricted-sexp
3217   "A floating point number."
3218   :tag "Floating point number"
3219   :value 0.0
3220   :type-error "This field should contain a floating point number"
3221   :match-alternatives '(floatp))
3222
3223 (define-widget 'character 'editable-field
3224   "A character."
3225   :tag "Character"
3226   :value 0
3227   :size 1
3228   :format "%{%t%}: %v\n"
3229   :valid-regexp "\\`.\\'"
3230   :error "This field should contain a single character"
3231   :value-to-internal (lambda (widget value)
3232                        (if (stringp value)
3233                            value
3234                          (char-to-string value)))
3235   :value-to-external (lambda (widget value)
3236                        (if (stringp value)
3237                            (aref value 0)
3238                          value))
3239   :match (lambda (widget value)
3240            (char-valid-p value)))
3241
3242 (define-widget 'list 'group
3243   "A Lisp list."
3244   :tag "List"
3245   :format "%{%t%}:\n%v")
3246
3247 (define-widget 'vector 'group
3248   "A Lisp vector."
3249   :tag "Vector"
3250   :format "%{%t%}:\n%v"
3251   :match 'widget-vector-match
3252   :value-to-internal (lambda (widget value) (append value nil))
3253   :value-to-external (lambda (widget value) (apply 'vector value)))
3254
3255 (defun widget-vector-match (widget value)
3256   (and (vectorp value)
3257        (widget-group-match widget
3258                            (widget-apply widget :value-to-internal value))))
3259
3260 (define-widget 'cons 'group
3261   "A cons-cell."
3262   :tag "Cons-cell"
3263   :format "%{%t%}:\n%v"
3264   :match 'widget-cons-match
3265   :value-to-internal (lambda (widget value)
3266                        (list (car value) (cdr value)))
3267   :value-to-external (lambda (widget value)
3268                        (apply 'cons value)))
3269
3270 (defun widget-cons-match (widget value)
3271   (and (consp value)
3272        (widget-group-match widget
3273                            (widget-apply widget :value-to-internal value))))
3274 \f
3275 ;;; The `lazy' Widget.
3276 ;;
3277 ;; Recursive datatypes.
3278
3279 (define-widget 'lazy 'default
3280   "Base widget for recursive datastructures.
3281
3282 The `lazy' widget will, when instantiated, contain a single inferior
3283 widget, of the widget type specified by the :type parameter.  The
3284 value of the `lazy' widget is the same as the value of the inferior
3285 widget.  When deriving a new widget from the 'lazy' widget, the :type
3286 parameter is allowed to refer to the widget currently being defined,
3287 thus allowing recursive datastructures to be described.
3288
3289 The :type parameter takes the same arguments as the defcustom
3290 parameter with the same name.
3291
3292 Most composite widgets, i.e. widgets containing other widgets, does
3293 not allow recursion.  That is, when you define a new widget type, none
3294 of the inferior widgets may be of the same type you are currently
3295 defining.
3296
3297 In Lisp, however, it is custom to define datastructures in terms of
3298 themselves.  A list, for example, is defined as either nil, or a cons
3299 cell whose cdr itself is a list.  The obvious way to translate this
3300 into a widget type would be
3301
3302   (define-widget 'my-list 'choice
3303     \"A list of sexps.\"
3304     :tag \"Sexp list\"
3305     :args '((const nil) (cons :value (nil) sexp my-list)))
3306
3307 Here we attempt to define my-list as a choice of either the constant
3308 nil, or a cons-cell containing a sexp and my-lisp.  This will not work
3309 because the `choice' widget does not allow recursion.
3310
3311 Using the `lazy' widget you can overcome this problem, as in this
3312 example:
3313
3314   (define-widget 'sexp-list 'lazy
3315     \"A list of sexps.\"
3316     :tag \"Sexp list\"
3317     :type '(choice (const nil) (cons :value (nil) sexp sexp-list)))"
3318   :format "%{%t%}: %v"
3319   ;; We don't convert :type because we want to allow recursive
3320   ;; datastructures.  This is slow, so we should not create speed
3321   ;; critical widgets by deriving from this.
3322   :convert-widget 'widget-value-convert-widget
3323   :value-create 'widget-type-value-create
3324   :value-get 'widget-child-value-get
3325   :value-inline 'widget-child-value-inline
3326   :default-get 'widget-type-default-get
3327   :match 'widget-type-match
3328   :validate 'widget-child-validate)
3329
3330 \f
3331 ;;; The `plist' Widget.
3332 ;;
3333 ;; Property lists.
3334
3335 (define-widget 'plist 'list
3336   "A property list."
3337   :key-type '(symbol :tag "Key")
3338   :value-type '(sexp :tag "Value")
3339   :convert-widget 'widget-plist-convert-widget
3340   :tag "Plist")
3341
3342 (defvar widget-plist-value-type)        ;Dynamic variable
3343
3344 (defun widget-plist-convert-widget (widget)
3345   ;; Handle `:options'.
3346   (let* ((options (widget-get widget :options))
3347          (widget-plist-value-type (widget-get widget :value-type))
3348          (other `(editable-list :inline t
3349                                 (group :inline t
3350                                        ,(widget-get widget :key-type)
3351                                        ,widget-plist-value-type)))
3352          (args (if options
3353                    (list `(checklist :inline t
3354                                      :greedy t
3355                                      ,@(mapcar 'widget-plist-convert-option
3356                                                options))
3357                          other)
3358                  (list other))))
3359     (widget-put widget :args args)
3360     widget))
3361
3362 (defun widget-plist-convert-option (option)
3363   ;; Convert a single plist option.
3364   (let (key-type value-type)
3365     (if (listp option)
3366         (let ((key (nth 0 option)))
3367           (setq value-type (nth 1 option))
3368           (if (listp key)
3369               (setq key-type key)
3370             (setq key-type `(const ,key))))
3371       (setq key-type `(const ,option)
3372             value-type widget-plist-value-type))
3373     `(group :format "Key: %v" :inline t ,key-type ,value-type)))
3374
3375
3376 ;;; The `alist' Widget.
3377 ;;
3378 ;; Association lists.
3379
3380 (define-widget 'alist 'list
3381   "An association list."
3382   :key-type '(sexp :tag "Key")
3383   :value-type '(sexp :tag "Value")
3384   :convert-widget 'widget-alist-convert-widget
3385   :tag "Alist")
3386
3387 (defvar widget-alist-value-type)        ;Dynamic variable
3388
3389 (defun widget-alist-convert-widget (widget)
3390   ;; Handle `:options'.
3391   (let* ((options (widget-get widget :options))
3392          (widget-alist-value-type (widget-get widget :value-type))
3393          (other `(editable-list :inline t
3394                                 (cons :format "%v"
3395                                       ,(widget-get widget :key-type)
3396                                       ,widget-alist-value-type)))
3397          (args (if options
3398                    (list `(checklist :inline t
3399                                      :greedy t
3400                                      ,@(mapcar 'widget-alist-convert-option
3401                                                options))
3402                          other)
3403                  (list other))))
3404     (widget-put widget :args args)
3405     widget))
3406
3407 (defun widget-alist-convert-option (option)
3408   ;; Convert a single alist option.
3409   (let (key-type value-type)
3410     (if (listp option)
3411         (let ((key (nth 0 option)))
3412           (setq value-type (nth 1 option))
3413           (if (listp key)
3414               (setq key-type key)
3415             (setq key-type `(const ,key))))
3416       (setq key-type `(const ,option)
3417             value-type widget-alist-value-type))
3418     `(cons :format "Key: %v" ,key-type ,value-type)))
3419 \f
3420 (define-widget 'choice 'menu-choice
3421   "A union of several sexp types."
3422   :tag "Choice"
3423   :format "%{%t%}: %[Value Menu%] %v"
3424   :button-prefix 'widget-push-button-prefix
3425   :button-suffix 'widget-push-button-suffix
3426   :prompt-value 'widget-choice-prompt-value)
3427
3428 (defun widget-choice-prompt-value (widget prompt value unbound)
3429   "Make a choice."
3430   (let ((args (widget-get widget :args))
3431         (completion-ignore-case (widget-get widget :case-fold))
3432         current choices old)
3433     ;; Find the first arg that matches VALUE.
3434     (let ((look args))
3435       (while look
3436         (if (widget-apply (car look) :match value)
3437             (setq old (car look)
3438                   look nil)
3439           (setq look (cdr look)))))
3440     ;; Find new choice.
3441     (setq current
3442           (cond ((= (length args) 0)
3443                  nil)
3444                 ((= (length args) 1)
3445                  (nth 0 args))
3446                 ((and (= (length args) 2)
3447                       (memq old args))
3448                  (if (eq old (nth 0 args))
3449                      (nth 1 args)
3450                    (nth 0 args)))
3451                 (t
3452                  (while args
3453                    (setq current (car args)
3454                          args (cdr args))
3455                    (setq choices
3456                          (cons (cons (widget-apply current :menu-tag-get)
3457                                      current)
3458                                choices)))
3459                  (let ((val (completing-read prompt choices nil t)))
3460                    (if (stringp val)
3461                        (let ((try (try-completion val choices)))
3462                          (when (stringp try)
3463                            (setq val try))
3464                          (cdr (assoc val choices)))
3465                      nil)))))
3466     (if current
3467         (widget-prompt-value current prompt nil t)
3468       value)))
3469 \f
3470 (define-widget 'radio 'radio-button-choice
3471   "A union of several sexp types."
3472   :tag "Choice"
3473   :format "%{%t%}:\n%v"
3474   :prompt-value 'widget-choice-prompt-value)
3475
3476 (define-widget 'repeat 'editable-list
3477   "A variable length homogeneous list."
3478   :tag "Repeat"
3479   :format "%{%t%}:\n%v%i\n")
3480
3481 (define-widget 'set 'checklist
3482   "A list of members from a fixed set."
3483   :tag "Set"
3484   :format "%{%t%}:\n%v")
3485
3486 (define-widget 'boolean 'toggle
3487   "To be nil or non-nil, that is the question."
3488   :tag "Boolean"
3489   :prompt-value 'widget-boolean-prompt-value
3490   :button-prefix 'widget-push-button-prefix
3491   :button-suffix 'widget-push-button-suffix
3492   :format "%{%t%}: %[Toggle%]  %v\n"
3493   :on "on (non-nil)"
3494   :off "off (nil)")
3495
3496 (defun widget-boolean-prompt-value (widget prompt value unbound)
3497   ;; Toggle a boolean.
3498   (y-or-n-p prompt))
3499 \f
3500 ;;; The `color' Widget.
3501
3502 ;; Fixme: match
3503 (define-widget 'color 'editable-field
3504   "Choose a color name (with sample)."
3505   :format "%t: %v (%{sample%})\n"
3506   :size 10
3507   :tag "Color"
3508   :value "black"
3509   :complete 'widget-color-complete
3510   :sample-face-get 'widget-color-sample-face-get
3511   :notify 'widget-color-notify
3512   :action 'widget-color-action)
3513
3514 (defun widget-color-complete (widget)
3515   "Complete the color in WIDGET."
3516   (require 'facemenu)                   ; for facemenu-color-alist
3517   (let* ((prefix (buffer-substring-no-properties (widget-field-start widget)
3518                                                  (point)))
3519          (list (or facemenu-color-alist (defined-colors)))
3520          (completion (try-completion prefix list)))
3521     (cond ((eq completion t)
3522            (message "Exact match."))
3523           ((null completion)
3524            (error "Can't find completion for \"%s\"" prefix))
3525           ((not (string-equal prefix completion))
3526            (insert-and-inherit (substring completion (length prefix))))
3527           (t
3528            (message "Making completion list...")
3529            (with-output-to-temp-buffer "*Completions*"
3530              (display-completion-list (all-completions prefix list nil)))
3531            (message "Making completion list...done")))))
3532
3533 (defun widget-color-sample-face-get (widget)
3534   (let* ((value (condition-case nil
3535                     (widget-value widget)
3536                   (error (widget-get widget :value)))))
3537     (if (color-defined-p value)
3538         (list (cons 'foreground-color value))
3539       'default)))
3540
3541 (defun widget-color-action (widget &optional event)
3542   "Prompt for a color."
3543   (let* ((tag (widget-apply widget :menu-tag-get))
3544          (prompt (concat tag ": "))
3545          (value (widget-value widget))
3546          (start (widget-field-start widget))
3547          (answer (facemenu-read-color prompt)))
3548     (unless (zerop (length answer))
3549       (widget-value-set widget answer)
3550       (widget-setup)
3551       (widget-apply widget :notify widget event))))
3552
3553 (defun widget-color-notify (widget child &optional event)
3554   "Update the sample, and notofy the parent."
3555   (overlay-put (widget-get widget :sample-overlay)
3556                'face (widget-apply widget :sample-face-get))
3557   (widget-default-notify widget child event))
3558 \f
3559 ;;; The Help Echo
3560
3561 (defun widget-echo-help (pos)
3562   "Display help-echo text for widget at POS."
3563   (let* ((widget (widget-at pos))
3564          (help-echo (and widget (widget-get widget :help-echo))))
3565     (if (functionp help-echo)
3566         (setq help-echo (funcall help-echo widget)))
3567     (if help-echo (message "%s" (eval help-echo)))))
3568
3569 ;;; The End:
3570
3571 (provide 'wid-edit)
3572
3573 ;;; arch-tag: a076e75e-18a1-4b46-8be5-3f317bcbc707
3574 ;;; wid-edit.el ends here