lisp/progmodes/meta-mode.el

   1 ;;; meta-mode.el --- major mode for editing Metafont or MetaPost sources
   2
   3 ;; Copyright (C) 1997, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010
   4 ;; Free Software Foundation, Inc.
   5
   6 ;; Author: Ulrik Vieth <vieth@thphy.uni-duesseldorf.de>
   7 ;; Version: 1.0
   8 ;; Keywords: Metafont, MetaPost, tex, languages
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Description:
  28 ;;
  29 ;; This Emacs Lisp package provides a major mode for editing Metafont
  30 ;; or MetaPost sources.  It includes all the necessary code to set up
  31 ;; a major mode including an approriate syntax table, keymap, and a
  32 ;; mode-specific pull-down menu.  It also provides a sophisticated set
  33 ;; of font-lock patterns, a fancy indentation function adapted from
  34 ;; AUCTeX's latex.el, and some basic mode-specific editing functions
  35 ;; such as functions to move to the beginning or end of the enclosing
  36 ;; environment, or to mark, re-indent, or comment-out environments.
  37 ;; On the other hand, it doesn't yet provide any functionality for
  38 ;; running Metafont or MetaPost in a shell buffer form within Emacs,
  39 ;; but such functionality might be added later, either as part of this
  40 ;; package or as a separate Emacs Lisp package.
  41
  42 ;; Installation:
  43 ;;
  44 ;; An interface to running Metafont or MetaPost as a shell process
  45 ;; from within Emacs is currently under development as a separate
  46 ;; Emacs Lisp package (meta-buf.el).  In order to have that package
  47 ;; loaded automatically when first entering Metafont or MetaPost mode,
  48 ;; you might use the load-hook provided in this package by adding
  49 ;; these lines to your startup file:
  50 ;;
  51 ;;  (add-hook 'meta-mode-load-hook
  52 ;;            (lambda () (require 'meta-buf)))
  53 ;;
  54 ;; The add-on package loaded this way may in turn make use of the
  55 ;; mode-hooks provided in this package to activate additional features
  56 ;; when entering Metafont or MetaPost mode.
  57
  58 ;; Font Lock Support:
  59 ;;
  60 ;; If you are using global-font-lock-mode (introduced in Emacs 19.31),
  61 ;; fontification in Metafont and/or MetaPost mode will be activated
  62 ;; automatically.  To speed up fontification for the rather complex
  63 ;; patterns used in these modes, it may be a good idea to activate
  64 ;; lazy-lock as a font-lock-support-mode (introduced in Emacs 19.32)
  65 ;; by adding these lines to your startup file:
  66 ;;
  67 ;;  (global-font-lock-mode t)
  68 ;;  (setq font-lock-support-mode 'lazy-lock-mode)
  69 ;;
  70 ;; If you are using an older version of Emacs, which doesn't provide
  71 ;; global-font-lock-mode or font-lock-support-mode, you can also
  72 ;; activate fontification in Metafont and/or MetaPost mode by adding
  73 ;; the following lines to your startup file:
  74 ;;
  75 ;;  (add-hook 'meta-common-mode-hook 'turn-on-font-lock)
  76 ;;  (add-hook 'meta-common-mode-hook 'turn-on-lazy-lock)
  77
  78 ;; Customization:
  79 ;;
  80 ;; Following the usual Emacs Lisp coding conventions, the major modes
  81 ;; defined in this package provide several hook variables to allow for
  82 ;; local customization when entering the modes.  In particular, there
  83 ;; is a `meta-common-mode-hook' which applies to both modes as well as
  84 ;; `metafont-mode-hook' and `metapost-mode-hook' which apply to the
  85 ;; individual modes.  In addition, there are several variables and
  86 ;; regexps controlling e.g. the behavior of the indentation function,
  87 ;; which may be customized via `edit-options'.  Please refer to the
  88 ;; docstrings in the code below for details.
  89
  90 ;; Availability:
  91 ;;
  92 ;; This package is currently available via my "TeX Software" WWW page:
  93 ;;
  94 ;;  http://www.thphy.uni-duesseldorf.de/~vieth/subjects/tex/software.html
  95 ;;
  96 ;; As of this version 1.0, this package will be uploaded to CTAN
  97 ;; archives, where it shall find a permanent home, presumably in
  98 ;; tex-archive/support/emacs-modes.  It will also be submitted for
  99 ;; integration into the GNU Emacs distribution at that time.
 100 ;;
 101 ;; History:
 102 ;;
 103 ;; v 0.0 -- 1997/02/01  UV  Started writing meta-mode.el.
 104 ;; v 0.1 -- 1997/02/02  UV  Added preliminary set of font-lock patterns.
 105 ;; v 0.2 -- 1997/02/03  UV  Improved and debugged font-lock patterns.
 106 ;;                          Added indent-line-function for TAB.
 107 ;; v 0.3 -- 1997/02/17  UV  Improved font-lock patterns and syntax table.
 108 ;;                          Improved and debbuged indentation function.
 109 ;; v 0.4 -- 1997/02/18  UV  Added functions to indent regions for M-C-q,
 110 ;;                          also added a preliminary mode-specific menu.
 111 ;; v 0.5 -- 1997/02/19  UV  Added functions to skip to next or previous
 112 ;;                          defun and to re-indent or comment-out defuns.
 113 ;; v 0.6 -- 1997/02/20  UV  More debugging, testing and clean-up.
 114 ;; v 0.7 -- 1997/02/22  UV  Use easymenu to define mode-specific menu.
 115 ;; v 0.8 -- 1997/02/24  UV  Added completion function for M-TAB.
 116 ;; v 0.9 -- 1997/03/08  UV  Added fill-paragraph function for comments.
 117 ;;                          Also fixed a few remaining font-lock problems.
 118 ;;                          Added meta-mode-load-hook to load meta-buf.el.
 119 ;; v 1.0 -- 1997/04/07  UV  Cleanup for official public release.
 120 ;;
 121 ;; Historical Footnote:
 122 ;;
 123 ;; This package was begun on February 1, 1997, exactly 20 years after
 124 ;; the genesis of TeX took place according to Don Knuth's own account
 125 ;; (cf.  ``The Errors of TeX'', reprinted in ``Literate Programming'',
 126 ;; Chapter 10, p. 249).  What better date could there be to choose?
 127 ;;
 128
 129 \f
 130 ;;; Code:
 131
 132 (require 'easymenu)
 133
 134 (defgroup meta-font nil
 135   "Major mode for editing Metafont or MetaPost sources."
 136   :link '(custom-group-link :tag "Font Lock Faces group" font-lock-faces)
 137   :group 'languages)
 138
 139 ;;; Fontification.
 140
 141 (defvar meta-font-lock-keywords
 142       (let ((input-keywords
 143              "\\(input\\|generate\\)")
 144             (begin-keywords
 145              (concat "\\(begin\\(char\\|fig\\|graph\\|logochar\\)\\|"
 146                      "\\cmchar\\|dcchar\\|ecchar\\)"))
 147             (end-keywords
 148              "\\(end\\(char\\|fig\\|graph\\)\\)")
 149             (macro-keywords-1
 150              "\\(def\\|let\\|mode_def\\|vardef\\)")
 151             (macro-keywords-2
 152              "\\(primarydef\\|secondarydef\\|tertiarydef\\)")
 153 ;(make-regexp
 154 ; '("expr" "suffix" "text" "primary" "secondary" "tertiary") t)
 155             (args-keywords
 156              (concat "\\(expr\\|primary\\|s\\(econdary\\|uffix\\)\\|"
 157                      "te\\(rtiary\\|xt\\)\\)"))
 158 ;(make-regexp
 159 ; '("boolean" "color" "numeric" "pair" "path" "pen" "picture"
 160 ;   "string" "transform" "newinternal") t)
 161             (type-keywords
 162              (concat "\\(boolean\\|color\\|n\\(ewinternal\\|umeric\\)\\|"
 163                      "p\\(a\\(ir\\|th\\)\\|en\\|icture\\)\\|string\\|"
 164                      "transform\\)"))
 165 ;(make-regexp
 166 ; '("for" "forever" "forsuffixes" "endfor"
 167 ;   "step" "until" "upto" "downto" "thru" "within"
 168 ;   "iff" "if" "elseif" "else" "fi" "exitif" "exitunless"
 169 ;   "let" "def" "vardef" "enddef" "mode_def"
 170 ;   "true" "false" "known" "unknown" "and" "or" "not"
 171 ;   "save" "interim" "inner" "outer" "relax"
 172 ;   "begingroup" "endgroup" "expandafter" "scantokens"
 173 ;   "generate" "input" "endinput" "end" "bye"
 174 ;   "message" "errmessage" "errhelp" "special" "numspecial"
 175 ;   "readstring" "readfrom" "write") t)
 176             (syntactic-keywords
 177              (concat "\\(and\\|b\\(egingroup\\|ye\\)\\|"
 178                      "d\\(ef\\|ownto\\)\\|e\\(lse\\(\\|if\\)"
 179                      "\\|nd\\(\\|def\\|for\\|group\\|input\\)"
 180                      "\\|rr\\(help\\|message\\)"
 181                      "\\|x\\(it\\(if\\|unless\\)\\|pandafter\\)\\)\\|"
 182                      "f\\(alse\\|i\\|or\\(\\|ever\\|suffixes\\)\\)\\|"
 183                      "generate\\|i\\(ff?\\|n\\(ner\\|put\\|terim\\)\\)\\|"
 184                      "known\\|let\\|m\\(essage\\|ode_def\\)\\|"
 185                      "n\\(ot\\|umspecial\\)\\|o\\(r\\|uter\\)\\|"
 186                      "re\\(ad\\(from\\|string\\)\\|lax\\)\\|"
 187                      "s\\(ave\\|cantokens\\|pecial\\|tep\\)\\|"
 188                      "t\\(hru\\|rue\\)\\|"
 189                      "u\\(n\\(known\\|til\\)\\|pto\\)\\|"
 190                      "vardef\\|w\\(ithin\\|rite\\)\\)"))
 191             )
 192         (list
 193          ;; embedded TeX code in btex ... etex
 194          (cons (concat "\\(btex\\|verbatimtex\\)"
 195                        "[ \t\f]+\\(.*\\)[ \t\f]+"
 196                        "\\(etex\\)")
 197                '((1 font-lock-keyword-face)
 198                  (2 font-lock-string-face)
 199                  (3 font-lock-keyword-face)))
 200          ;; unary macro definitions: def, vardef, let
 201          (cons (concat "\\<" macro-keywords-1 "\\>"
 202                        "[ \t\f]+\\(\\sw+\\|\\s_+\\|\\s.+\\)")
 203                '((1 font-lock-keyword-face)
 204                  (2 font-lock-function-name-face)))
 205          ;; binary macro defintions: <leveldef> x operator y
 206          (cons (concat "\\<" macro-keywords-2 "\\>"
 207                        "[ \t\f]+\\(\\sw+\\)"
 208                        "[ \t\f]*\\(\\sw+\\|\\s.+\\)"
 209                        "[ \t\f]*\\(\\sw+\\)")
 210                '((1 font-lock-keyword-face)
 211                  (2 font-lock-variable-name-face nil t)
 212                  (3 font-lock-function-name-face nil t)
 213                  (4 font-lock-variable-name-face nil t)))
 214          ;; variable declarations: numeric, pair, color, ...
 215          (cons (concat "\\<" type-keywords "\\>"
 216                        "\\([ \t\f]+\\(\\sw+\\)\\)*")
 217                '((1 font-lock-type-face)
 218                  (font-lock-match-meta-declaration-item-and-skip-to-next
 219                   (goto-char (match-end 1)) nil
 220                   (1 font-lock-variable-name-face nil t))))
 221          ;; argument declarations: expr, suffix, text, ...
 222          (cons (concat "\\<" args-keywords "\\>"
 223                        "\\([ \t\f]+\\(\\sw+\\|\\s_+\\)\\)*")
 224                '((1 font-lock-type-face)
 225                  (font-lock-match-meta-declaration-item-and-skip-to-next
 226                   (goto-char (match-end 1)) nil
 227                   (1 font-lock-variable-name-face nil t))))
 228          ;; special case of arguments: expr x of y
 229          (cons (concat "\\(expr\\)[ \t\f]+\\(\\sw+\\)"
 230                        "[ \t\f]+\\(of\\)[ \t\f]+\\(\\sw+\\)")
 231                '((1 font-lock-type-face)
 232                  (2 font-lock-variable-name-face)
 233                  (3 font-lock-keyword-face nil t)
 234                  (4 font-lock-variable-name-face nil t)))
 235          ;; syntactic keywords
 236          (cons (concat "\\<" syntactic-keywords "\\>")
 237                'font-lock-keyword-face)
 238          ;; beginchar, beginfig
 239          (cons (concat "\\<" begin-keywords "\\>")
 240                'font-lock-keyword-face)
 241          ;; endchar, endfig
 242          (cons (concat "\\<" end-keywords "\\>")
 243                'font-lock-keyword-face)
 244          ;; input, generate
 245          (cons (concat "\\<" input-keywords "\\>"
 246                        "[ \t\f]+\\(\\sw+\\)")
 247                '((1 font-lock-keyword-face)
 248                  (2 font-lock-constant-face)))
 249          ;; embedded Metafont/MetaPost code in comments
 250          (cons "|\\([^|]+\\)|"
 251                '(1 font-lock-constant-face t))
 252      ))
 253   "Default expressions to highlight in Metafont or MetaPost mode.")
 254
 255
 256 (defun font-lock-match-meta-declaration-item-and-skip-to-next (limit)
 257   ;; Match and move over Metafont/MetaPost declaration item after point.
 258   ;;
 259   ;; The expected syntax of an item is either "word" or "symbol",
 260   ;; possibly ending with optional whitespace.  Everything following
 261   ;; the item (but belonging to it) is expected to by skipable by
 262   ;; `forward-sexp'.  The list of items is expected to be separated
 263   ;; by commas and terminated by semicolons or equals signs.
 264   ;;
 265   (if (looking-at "[ \t\f]*\\(\\sw+\\|\\s_+\\)")
 266       (save-match-data
 267         (condition-case nil
 268             (save-restriction
 269               ;; Restrict to end of line, currently guaranteed to be LIMIT.
 270               (narrow-to-region (point-min) limit)
 271               (goto-char (match-end 1))
 272               ;; Move over any item value, etc., to the next item.
 273               (while (not (looking-at "[ \t\f]*\\(\\(,\\)\\|;\\|=\\|$\\)"))
 274                 (goto-char (or (scan-sexps (point) 1) (point-max))))
 275               (goto-char (match-end 2)))
 276           (error t)))))
 277
 278
 279 \f
 280 ;;; Completion.
 281
 282 ;; The data used to prepare the following lists of primitives and
 283 ;; standard macros available in Metafont or MetaPost was extracted
 284 ;; from the original sources like this:
 285 ;;
 286 ;;   grep '^primitive' texk-7.0/web2c/{mf,mp}.web |\
 287 ;;   sed 's/primitive(\("[a-zA-Z]*"\).*/\1/' > {mf,mp}_prim.list
 288 ;;
 289 ;;   grep '\(let\|def\|vardef\|primarydef\|secondarydef\|tertiarydef\)'
 290 ;;     texmf/meta{font,post}/plain.{mf,mp} > {mf,mp}_plain.list
 291
 292 (defconst meta-common-primitives-list
 293   '("ASCII" "addto" "also" "and" "angle" "atleast" "batchmode"
 294     "begingroup" "boolean" "boundarychar" "char" "charcode" "chardp"
 295     "charexists" "charext" "charht" "charic" "charlist" "charwd"
 296     "contour" "controls" "cosd" "curl" "cycle" "day" "decimal" "def"
 297     "delimiters" "designsize" "directiontime" "doublepath" "dump" "else"
 298     "elseif" "end" "enddef" "endfor" "endgroup" "endinput" "errhelp"
 299     "errmessage" "errorstopmode" "everyjob" "exitif" "expandafter"
 300     "expr" "extensible" "false" "fi" "floor" "fontdimen" "fontmaking"
 301     "for" "forever" "forsuffixes" "headerbyte" "hex" "if" "inner"
 302     "input" "interim" "intersectiontimes" "jobname" "kern" "known"
 303     "length" "let" "ligtable" "makepath" "makepen" "message" "mexp"
 304     "mlog" "month" "newinternal" "nonstopmode" "normaldeviate" "not"
 305     "nullpen" "nullpicture" "numeric" "oct" "odd" "of" "or" "outer"
 306     "pair" "path" "pausing" "pen" "pencircle" "penoffset" "picture"
 307     "point" "postcontrol" "precontrol" "primary" "primarydef" "quote"
 308     "randomseed" "readstring" "reverse" "rotated" "save" "scaled"
 309     "scantokens" "scrollmode" "secondary" "secondarydef" "shifted"
 310     "shipout" "show" "showdependencies" "showstats" "showstopping"
 311     "showtoken" "showvariable" "sind" "skipto" "slanted" "special"
 312     "sqrt" "step" "str" "string" "subpath" "substring" "suffix"
 313     "tension" "tertiary" "tertiarydef" "text" "time" "to"
 314     "tracingcapsules" "tracingchoices" "tracingcommands"
 315     "tracingequations" "tracingmacros" "tracingonline" "tracingoutput"
 316     "tracingrestores" "tracingspecs" "tracingstats" "tracingtitles"
 317     "transform" "transformed" "true" "turningnumber" "uniformdeviate"
 318     "unknown" "until" "vardef" "warningcheck" "withpen" "xpart"
 319     "xscaled" "xxpart" "xypart" "year" "ypart" "yscaled" "yxpart"
 320     "yypart" "zscaled")
 321   "List of primitives common to Metafont and MetaPost.")
 322
 323 (defconst metafont-primitives-list
 324   '("at" "autorounding" "chardx" "chardy" "cull" "display"
 325     "dropping" "fillin" "from" "granularity" "hppp" "inwindow"
 326     "keeping" "numspecial" "openwindow" "proofing" "smoothing"
 327     "totalweight" "tracingedges" "tracingpens" "turningcheck" "vppp"
 328     "withweight" "xoffset" "yoffset")
 329   "List of primitives only defined in Metafont.")
 330
 331 (defconst metapost-primitives-list
 332   '("arclength" "arctime" "bluepart" "bounded" "btex" "clip"
 333     "clipped" "color" "dashed" "dashpart" "etex" "filled" "fontpart"
 334     "fontsize" "greenpart" "infont" "linecap" "linejoin" "llcorner"
 335     "lrcorner" "miterlimit" "mpxbreak" "pathpart" "penpart"
 336     "prologues" "readfrom" "redpart" "setbounds" "stroked" "textpart"
 337     "textual" "tracinglostchars" "truecorners" "ulcorner" "urcorner"
 338     "verbatimtex" "withcolor" "within" "write")
 339   "List of primitives only defined in MetaPost.")
 340
 341 (defconst meta-common-plain-macros-list
 342   '( "abs" "bot" "bye" "byte" "ceiling" "clear_pen_memory"
 343      "clearit" "clearpen" "clearxy" "counterclockwise" "cutdraw" "decr"
 344      "dir" "direction" "directionpoint" "div" "dotprod" "downto" "draw"
 345      "drawdot" "erase" "exitunless" "fill" "filldraw" "flex" "gobble"
 346      "hide" "incr" "interact" "interpath" "intersectionpoint" "inverse"
 347      "label" "labels" "lft" "loggingall" "magstep" "makelabel" "max"
 348      "min" "mod" "numtok" "penlabels" "penpos" "penstroke" "pickup"
 349      "range" "reflectedabout" "relax" "rotatedabout" "rotatedaround"
 350      "round" "rt" "savepen" "shipit" "softjoin" "solve" "stop"
 351      "superellipse" "takepower" "tensepath" "thru" "top" "tracingall"
 352      "tracingnone" "undraw" "undrawdot" "unfill" "unfilldraw"
 353      "unitvector" "upto" "whatever")
 354   "List of macros common to plain Metafont and MetaPost.")
 355
 356 (defconst metafont-plain-macros-list
 357   '("beginchar" "change_width" "culldraw" "cullit" "cutoff"
 358     "define_blacker_pixels" "define_corrected_pixels"
 359     "define_good_x_pixels" "define_good_y_pixels"
 360     "define_horizontal_corrected_pixels" "define_pixels"
 361     "define_whole_blacker_pixels" "define_whole_pixels"
 362     "define_whole_vertical_blacker_pixels"
 363     "define_whole_vertical_pixels" "endchar" "fix_units"
 364     "font_coding_scheme" "font_extra_space" "font_identifier"
 365     "font_normal_shrink" "font_normal_space" "font_normal_stretch"
 366     "font_quad" "font_size" "font_slant" "font_x_height" "gfcorners"
 367     "good.bot" "good.lft" "good.rt" "good.top" "good.x" "good.y"
 368     "grayfont" "hround" "imagerules" "italcorr" "labelfont"
 369     "lowres_fix" "makebox" "makegrid" "maketicks" "mode_lowres"
 370     "mode_proof" "mode_setup" "mode_smoke" "nodisplays" "notransforms"
 371     "openit" "penrazor" "pensquare" "proofoffset" "proofrule"
 372     "proofrulethickness" "screenchars" "screenrule" "screenstrokes"
 373     "showit" "slantfont" "smode" "titlefont" "vround")
 374   "List of macros only defined in plain Metafont.")
 375
 376 (defconst metapost-plain-macros-list
 377   '("arrowhead" "bbox" "beginfig" "buildcycle" "center" "cutafter"
 378     "cutbefore" "dashpattern" "dotlabel" "dotlabels" "drawarrow"
 379     "drawdblarrow" "drawoptions" "endfig" "image" "label" "off" "on"
 380     "thelabel")
 381   "List of macros only defined in plain MetaPost.")
 382
 383 (defconst metapost-graph-macros-list
 384   '("augment" "auto.x" "auto.y" "autogrid" "begingraph" "endgraph"
 385     "format" "frame" "gdata" "gdotlabel" "gdraw" "gdrawarrow"
 386     "gdrawdblarrow" "gfill" "glabel" "grid" "itick" "otick" "plot"
 387     "setcoords" "setrange")
 388   "List of macros only defined in MetaPost \"graph\" package.")
 389
 390 (defconst metapost-boxes-macros-list
 391   '("boxit" "boxjoin" "bpath" "circleit" "drawboxed" "drawboxes"
 392     "drawunboxed" "fixpos" "fixsize" "pic" "rboxit")
 393   "List of macros only defined in MetaPost \"boxes\" package.")
 394
 395
 396 (defvar metafont-symbol-list
 397   (append meta-common-primitives-list
 398           metafont-primitives-list
 399           meta-common-plain-macros-list
 400           metafont-plain-macros-list)
 401   "List of known symbols to complete in Metafont mode.")
 402
 403 (defvar metapost-symbol-list
 404   (append meta-common-primitives-list
 405           metapost-primitives-list
 406           meta-common-plain-macros-list
 407           metapost-plain-macros-list
 408           metapost-graph-macros-list
 409           metapost-boxes-macros-list)
 410   "List of known symbols to complete in MetaPost mode.")
 411
 412
 413 (defvar meta-symbol-list nil
 414   "List of known symbols to complete in Metafont or MetaPost mode.")
 415
 416 (defvar meta-symbol-changed nil
 417   "Flag indicating whether `meta-symbol-list' has been initialized.")
 418
 419 (defvar meta-complete-list nil
 420 ;  (list (list "\\<\\(\\sw+\\)" 1 'meta-symbol-list)
 421 ;        (list "" 'ispell-complete-word))
 422   "List of ways to perform completion in Metafont or MetaPost mode.
 423
 424 Each entry is a list with the following elements:
 425 1. Regexp matching the preceding text.
 426 2. A number indicating the subgroup in the regexp containing the text.
 427 3. A function returning an alist of possible completions.
 428 4. Text to append after a succesful completion (if any).
 429
 430 Or alternatively:
 431 1. Regexp matching the preceding text.
 432 2. Function to do the actual completion.")
 433
 434
 435 (defun meta-add-symbols (&rest entries)
 436   "Add entries to list of known symbols in Metafont or MetaPost mode."
 437   (if meta-symbol-changed
 438       (setq meta-symbol-list (cons entries meta-symbol-list))
 439     (setq meta-symbol-changed t)
 440     (setq meta-symbol-list (cons entries meta-symbol-list))))
 441
 442 (defun meta-symbol-list ()
 443   "Return value of list of known symbols in Metafont or MetaPost mode.
 444 If the list was changed, sort the list and remove duplicates first."
 445   (if (not meta-symbol-changed)
 446       ()
 447     (setq meta-symbol-changed nil)
 448     (message "Preparing completion list...")
 449     ;; sort list of symbols
 450     (setq meta-symbol-list
 451           (sort (mapcar 'meta-listify (apply 'append meta-symbol-list))
 452                 'meta-car-string-lessp))
 453     ;; remove duplicates
 454     (let ((entry meta-symbol-list))
 455       (while (and entry (cdr entry))
 456         (let ((this (car entry))
 457               (next (car (cdr entry))))
 458           (if (not (string-equal (car this) (car next)))
 459               (setq entry (cdr entry))
 460             (if (> (length next) (length this))
 461                 (setcdr this (cdr next)))
 462             (setcdr entry (cdr (cdr entry)))))))
 463     (message "Preparing completion list... done"))
 464   meta-symbol-list)
 465
 466 (defun meta-listify (a)
 467   ;; utility function used in `meta-add-symbols'
 468   (if (listp a) a (list a)))
 469
 470 (defun meta-car-string-lessp (a b)
 471   ;; utility function used in `meta-add-symbols'
 472   (string-lessp (car a) (car b)))
 473
 474
 475 (defun meta-complete-symbol ()
 476   "Perform completion on Metafont or MetaPost symbol preceding point."
 477   (interactive "*")
 478   (let ((list meta-complete-list)
 479         entry)
 480     (while list
 481       (setq entry (car list)
 482             list (cdr list))
 483       (if (meta-looking-at-backward (car entry) 200)
 484           (setq list nil)))
 485     (if (numberp (nth 1 entry))
 486         (let* ((sub (nth 1 entry))
 487                (close (nth 3 entry))
 488                (begin (match-beginning sub))
 489                (end (match-end sub))
 490                (list (funcall (nth 2 entry))))
 491           (completion-in-region
 492            begin end
 493            (if (zerop (length close)) list
 494              (apply-partially 'completion-table-with-terminator
 495                               close list))))
 496       (funcall (nth 1 entry)))))
 497
 498
 499 (defun meta-looking-at-backward (regexp &optional limit)
 500   ;; utility function used in `meta-complete-symbol'
 501   (let ((pos (point)))
 502     (save-excursion
 503       (and (re-search-backward
 504             regexp (if limit (max (point-min) (- (point) limit))) t)
 505            (eq (match-end 0) pos)))))
 506
 507 (defun meta-match-buffer (n)
 508   ;; utility function used in `meta-complete-symbol'
 509   (if (match-beginning n)
 510       (let ((str (buffer-substring (match-beginning n) (match-end n))))
 511         (set-text-properties 0 (length str) nil str)
 512         (copy-sequence str))
 513     ""))
 514
 515
 516 \f
 517 ;;; Indentation.
 518
 519 (defcustom meta-indent-level 2
 520   "*Indentation of begin-end blocks in Metafont or MetaPost mode."
 521   :type 'integer
 522   :group 'meta-font)
 523
 524
 525 (defcustom meta-left-comment-regexp "%%+"
 526   "*Regexp matching comments that should be placed on the left margin."
 527   :type 'regexp
 528   :group 'meta-font)
 529
 530 (defcustom meta-right-comment-regexp nil
 531   "*Regexp matching comments that should be placed to the right margin."
 532   :type '(choice regexp
 533                  (const :tag "None" nil))
 534   :group 'meta-font)
 535
 536 (defcustom meta-ignore-comment-regexp "%[^%]"
 537   "*Regexp matching comments that whose indentation should not be touched."
 538   :type 'regexp
 539   :group 'meta-font)
 540
 541
 542 (defcustom meta-begin-environment-regexp
 543   (concat "\\(begin\\(char\\|fig\\|gr\\(aph\\|oup\\)\\|logochar\\)\\|"
 544           "def\\|for\\(\\|ever\\|suffixes\\)\\|if\\|mode_def\\|"
 545           "primarydef\\|secondarydef\\|tertiarydef\\|vardef\\)")
 546   "*Regexp matching the beginning of environments to be indented."
 547   :type 'regexp
 548   :group 'meta-font)
 549
 550 (defcustom meta-end-environment-regexp
 551   (concat "\\(end\\(char\\|def\\|f\\(ig\\|or\\)\\|gr\\(aph\\|oup\\)\\)"
 552           "\\|fi\\)")
 553   "*Regexp matching the end of environments to be indented."
 554   :type 'regexp
 555   :group 'meta-font)
 556
 557 (defcustom meta-within-environment-regexp
 558 ; (concat "\\(e\\(lse\\(\\|if\\)\\|xit\\(if\\|unless\\)\\)\\)")
 559   (concat "\\(else\\(\\|if\\)\\)")
 560   "*Regexp matching keywords within environments not to be indented."
 561   :type 'regexp
 562   :group 'meta-font)
 563
 564
 565 (defun meta-comment-indent ()
 566   "Return the indentation for a comment in Metafont or MetaPost mode."
 567   (if (and meta-left-comment-regexp
 568            (looking-at meta-left-comment-regexp))
 569       (current-column)
 570     (skip-chars-backward "\t\f ")
 571     (max (if (bolp) 0 (1+ (current-column)))
 572          comment-column)))
 573
 574 (defun meta-indent-line ()
 575   "Indent the line containing point as Metafont or MetaPost source."
 576   (interactive)
 577   (let ((indent (meta-indent-calculate)))
 578     (save-excursion
 579       (if (/= (current-indentation) indent)
 580           (let ((beg (progn (beginning-of-line) (point)))
 581                 (end (progn (back-to-indentation) (point))))
 582             (delete-region beg end)
 583             (indent-to indent))))
 584     (if (< (current-column) indent)
 585         (back-to-indentation))))
 586
 587 (defun meta-indent-calculate ()
 588   "Return the indentation of current line of Metafont or MetaPost source."
 589   ;; Indentation within strings is not considered as Meta* don't allow multi
 590   ;; line strings.
 591   (save-excursion
 592     (back-to-indentation)
 593     (cond
 594      ;; Comments to the left margin.
 595      ((and meta-left-comment-regexp
 596            (looking-at meta-left-comment-regexp))
 597       0)
 598      ;; Comments to the right margin.
 599      ((and meta-right-comment-regexp
 600            (looking-at meta-right-comment-regexp))
 601       comment-column)
 602      ;; Comments best left alone.
 603      ((and meta-ignore-comment-regexp
 604            (looking-at meta-ignore-comment-regexp))
 605       (current-indentation))
 606      ;; Beginning of buffer.
 607      ((eq (point-at-bol) (point-min))
 608       0)
 609      ;; Backindent at end of environments.
 610      ((meta-indent-looking-at-code
 611        (concat "\\<" meta-end-environment-regexp "\\>"))
 612       (- (meta-indent-current-indentation) meta-indent-level))
 613      ;; Backindent at keywords within environments.
 614      ((meta-indent-looking-at-code
 615        (concat "\\<" meta-within-environment-regexp "\\>"))
 616       (- (meta-indent-current-indentation) meta-indent-level))
 617      (t (meta-indent-current-indentation)))))
 618
 619 (defun meta-indent-in-string-p ()
 620   "Tell if the point is in a string."
 621   (or (nth 3 (syntax-ppss))
 622       (eq (get-text-property (point) 'face) font-lock-string-face)))
 623
 624 (defun meta-indent-looking-at-code (regexp)
 625   "Same as `looking-at' but checks that the point is not in a string."
 626   (unless (meta-indent-in-string-p)
 627     (looking-at regexp)))
 628
 629 (defun meta-indent-previous-line ()
 630   "Go to the previous line of code, skipping comments."
 631   (skip-chars-backward "\n\t\f ")
 632   (move-to-column (current-indentation))
 633   ;; Ignore comments.
 634   (while (and (looking-at comment-start) (not (bobp)))
 635     (skip-chars-backward "\n\t\f ")
 636     (when (not (bobp))
 637       (move-to-column (current-indentation)))))
 638
 639 (defun meta-indent-unfinished-line ()
 640   "Tell if the current line of code ends with an unfinished expression."
 641   (save-excursion
 642     (end-of-line)
 643     ;; Skip backward the comments.
 644     (let ((point-not-in-string (point)))
 645       (while (search-backward comment-start (point-at-bol) t)
 646         (unless (meta-indent-in-string-p)
 647           (setq point-not-in-string (point))))
 648       (goto-char point-not-in-string))
 649     ;; Search for the end of the previous expression.
 650     (if (search-backward ";" (point-at-bol) t)
 651         (progn (while (and (meta-indent-in-string-p)
 652                            (search-backward ";" (point-at-bol) t)))
 653                (if (= (char-after) ?\;)
 654                    (forward-char)
 655                  (beginning-of-line)))
 656       (beginning-of-line))
 657     ;; See if the last statement of the line is environment-related,
 658     ;; or exists at all.
 659     (if (meta-indent-looking-at-code
 660          (concat "[ \t\f]*\\($\\|" (regexp-quote comment-start)
 661                  "\\|\\<" meta-end-environment-regexp "\\>"
 662                  "\\|\\<" meta-begin-environment-regexp "\\>"
 663                  "\\|\\<" meta-within-environment-regexp "\\>\\)"))
 664         nil
 665       t)))
 666
 667 (defun meta-indent-current-indentation ()
 668   "Return the indentation wanted for the current line of code."
 669   (+ (meta-indent-current-nesting)
 670      (if (save-excursion
 671            (back-to-indentation)
 672            (and (not (looking-at (concat "\\<" meta-end-environment-regexp "\\>"
 673                                          "\\|\\<" meta-within-environment-regexp "\\>")))
 674                 (progn (meta-indent-previous-line)
 675                        (meta-indent-unfinished-line))))
 676          meta-indent-level
 677        0)))
 678
 679 (defun meta-indent-current-nesting ()
 680   "Return the indentation according to the nearest environment keyword."
 681   (save-excursion
 682     (save-restriction
 683       (widen)
 684       (back-to-indentation)
 685       (let ((to-add 0))
 686         ;; If we found some environment marker backward...
 687         (if (catch 'found
 688               (while (re-search-backward
 689                       (concat "(\\|)\\|\\<" meta-end-environment-regexp "\\>"
 690                               "\\|\\<" meta-begin-environment-regexp "\\>"
 691                               "\\|\\<" meta-within-environment-regexp "\\>")
 692                       nil t)
 693                 ;; If we aren't in a string or in a comment, we've found something.
 694                 (unless (or (meta-indent-in-string-p)
 695                             (nth 4 (syntax-ppss)))
 696                   (cond ((= (char-after) ?\()
 697                          (setq to-add (+ to-add meta-indent-level)))
 698                         ((= (char-after) ?\))
 699                          (setq to-add (- to-add meta-indent-level)))
 700                         (t (throw 'found t))))))
 701             (progn
 702               ;; ... then use it to compute the current indentation.
 703               (back-to-indentation)
 704               (+ to-add (current-indentation) (meta-indent-level-count)
 705                  ;; Compensate for backindent of end and within keywords.
 706                  (if (meta-indent-looking-at-code
 707                       (concat "\\<" meta-end-environment-regexp "\\>\\|"
 708                               "\\<" meta-within-environment-regexp "\\>"))
 709                      meta-indent-level
 710                    ;; Compensate for unfinished line.
 711                    (if (save-excursion
 712                          (meta-indent-previous-line)
 713                          (meta-indent-unfinished-line))
 714                        (- meta-indent-level)
 715                      0))))
 716           0)))))
 717
 718 (defun meta-indent-level-count ()
 719   "Count indentation change for begin-end commands in the current line."
 720   (save-excursion
 721     (save-restriction
 722       (let ((count 0))
 723         (narrow-to-region
 724          (point) (save-excursion
 725                    (re-search-forward "[^\\\\\"]%\\|\n\\|\\'" nil t)
 726                    (backward-char) (point)))
 727         (while (re-search-forward "\\<\\sw+\\>\\|(\\|)" nil t)
 728           (save-excursion
 729             (goto-char (match-beginning 0))
 730             (cond
 731              ;; Count number of begin-end keywords within line.
 732              ((meta-indent-looking-at-code
 733                (concat "\\<" meta-begin-environment-regexp "\\>"))
 734               (setq count (+ count meta-indent-level)))
 735              ((meta-indent-looking-at-code
 736                (concat "\\<" meta-end-environment-regexp "\\>"))
 737               (setq count (- count meta-indent-level))))))
 738         count))))
 739
 740
 741 \f
 742 ;;; Editing commands.
 743
 744 (defcustom meta-begin-defun-regexp
 745   (concat "\\(begin\\(char\\|fig\\|logochar\\)\\|def\\|mode_def\\|"
 746           "primarydef\\|secondarydef\\|tertiarydef\\|vardef\\)")
 747   "*Regexp matching beginning of defuns in Metafont or MetaPost mode."
 748   :type 'regexp
 749   :group 'meta-font)
 750
 751 (defcustom meta-end-defun-regexp
 752   (concat "\\(end\\(char\\|def\\|fig\\)\\)")
 753   "*Regexp matching the end of defuns in Metafont or MetaPost mode."
 754   :type 'regexp
 755   :group 'meta-font)
 756
 757
 758 (defun meta-beginning-of-defun (&optional arg)
 759   "Move backward to beginnning of a defun in Metafont or MetaPost code.
 760 With numeric argument, do it that many times.
 761 Negative arg -N means move forward to Nth following beginning of defun.
 762 Returns t unless search stops due to beginning or end of buffer."
 763   (interactive "p")
 764   (if (or (null arg) (= 0 arg)) (setq arg 1))
 765   (and arg (< arg 0) (not (eobp)) (forward-char 1))
 766   (and (re-search-backward
 767         (concat "\\<" meta-begin-defun-regexp "\\>") nil t arg)
 768        (progn (goto-char (match-beginning 0))
 769               (skip-chars-backward "%")
 770               (skip-chars-backward " \t\f") t)))
 771
 772 (defun meta-end-of-defun (&optional arg)
 773   "Move forward to end of a defun in Metafont or MetaPost code.
 774 With numeric argument, do it that many times.
 775 Negative argument -N means move back to Nth preceding end of defun.
 776 Returns t unless search stops due to beginning or end of buffer."
 777   (interactive "p")
 778   (if (or (null arg) (= 0 arg)) (setq arg 1))
 779   (and (< arg 0) (not (bobp)) (forward-line -1))
 780   (and (re-search-forward
 781         (concat "\\<" meta-end-defun-regexp "\\>") nil t arg)
 782        (progn (goto-char (match-end 0))
 783               (skip-chars-forward ";")
 784               (skip-chars-forward " \t\f")
 785               (if (looking-at "\n") (forward-line 1)) t)))
 786
 787
 788 (defun meta-comment-region (beg end &optional arg)
 789   "Comment out active region as Metafont or MetaPost source."
 790   (interactive "r")
 791   (comment-region beg end arg))
 792
 793 (defun meta-uncomment-region (beg end)
 794   "Uncomment active region as Metafont or MetaPost source."
 795   (interactive "r")
 796   (comment-region beg end -1))
 797
 798 (defun meta-comment-defun (&optional arg)
 799   "Comment out current environment as Metafont or MetaPost source.
 800 With prefix argument, uncomment the environment.
 801 The environment used is the one that contains point or follows point."
 802   (interactive "P")
 803   (save-excursion
 804     (let* ((end (if (meta-end-of-defun) (point) (point-max)))
 805            (beg (if (meta-beginning-of-defun) (point) (point-min))))
 806       (comment-region beg end arg))))
 807
 808 (defun meta-uncomment-defun ()
 809   "Uncomment current environment as Metafont or MetaPost source."
 810   (interactive)
 811   (meta-comment-defun -1))
 812
 813
 814 (defun meta-indent-region (beg end)
 815   "Indent the active region as Metafont or MetaPost source."
 816   (interactive "r")
 817   (indent-region beg end nil))
 818
 819 (defun meta-indent-buffer ()
 820   "Indent the whole buffer contents as Metafont or MetaPost source."
 821   (interactive)
 822   (save-excursion
 823     (indent-region (point-min) (point-max) nil)))
 824
 825 (defun meta-indent-defun ()
 826   "Indent the current environment as Metafont or MetaPost source.
 827 The environment indented is the one that contains point or follows point."
 828   (interactive)
 829   (save-excursion
 830     (let* ((end (if (meta-end-of-defun) (point) (point-max)))
 831            (beg (if (meta-beginning-of-defun) (point) (point-min))))
 832       (indent-region beg end nil))))
 833
 834
 835 (defun meta-mark-defun ()
 836   "Put mark at end of the environment, point at the beginning.
 837 The environment marked is the one that contains point or follows point."
 838   (interactive)
 839   (push-mark (point))
 840   (meta-end-of-defun)
 841   (push-mark (point) nil t)
 842   (meta-beginning-of-defun))
 843
 844
 845 \f
 846 ;;; Syntax table, keymap and menu.
 847
 848 (defvar meta-mode-abbrev-table nil
 849   "Abbrev table used in Metafont or MetaPost mode.")
 850 (define-abbrev-table 'meta-mode-abbrev-table ())
 851
 852 (defvar meta-mode-syntax-table
 853   (let ((st (make-syntax-table)))
 854     ;; underscores are word constituents
 855     (modify-syntax-entry ?_  "w"  st)
 856     ;; miscellaneous non-word symbols
 857     (modify-syntax-entry ?#  "_"  st)
 858     (modify-syntax-entry ?@  "_"  st)
 859     (modify-syntax-entry ?$  "_"  st)
 860     (modify-syntax-entry ??  "_"  st)
 861     (modify-syntax-entry ?!  "_"  st)
 862     ;; binary operators
 863     (modify-syntax-entry ?&  "."  st)
 864     (modify-syntax-entry ?+  "."  st)
 865     (modify-syntax-entry ?-  "."  st)
 866     (modify-syntax-entry ?/  "."  st)
 867     (modify-syntax-entry ?*  "."  st)
 868     (modify-syntax-entry ?.  "."  st)
 869     (modify-syntax-entry ?:  "."  st)
 870     (modify-syntax-entry ?=  "."  st)
 871     (modify-syntax-entry ?<  "."  st)
 872     (modify-syntax-entry ?>  "."  st)
 873     (modify-syntax-entry ?|  "."  st)
 874     ;; opening and closing delimiters
 875     (modify-syntax-entry ?\( "()" st)
 876     (modify-syntax-entry ?\) ")(" st)
 877     (modify-syntax-entry ?\[ "(]" st)
 878     (modify-syntax-entry ?\] ")[" st)
 879     (modify-syntax-entry ?\{ "(}" st)
 880     (modify-syntax-entry ?\} "){" st)
 881     ;; comment character
 882     (modify-syntax-entry ?%  "<"  st)
 883     (modify-syntax-entry ?\n ">"  st)
 884     ;; escape character, needed for embedded TeX code
 885     (modify-syntax-entry ?\\ "\\" st)
 886     st)
 887   "Syntax table used in Metafont or MetaPost mode.")
 888
 889 (defvar meta-mode-map
 890   (let ((map (make-sparse-keymap)))
 891     (define-key map "\C-m"      'reindent-then-newline-and-indent)
 892     ;; Comment Paragraphs:
 893     ;; (define-key map "\M-a"      'backward-sentence)
 894     ;; (define-key map "\M-e"      'forward-sentence)
 895     ;; (define-key map "\M-h"      'mark-paragraph)
 896     ;; (define-key map "\M-q"      'fill-paragraph)
 897     ;; Navigation:
 898     (define-key map "\M-\C-a"   'meta-beginning-of-defun)
 899     (define-key map "\M-\C-e"   'meta-end-of-defun)
 900     (define-key map "\M-\C-h"   'meta-mark-defun)
 901     ;; Indentation:
 902     (define-key map "\M-\C-q"   'meta-indent-defun)
 903     (define-key map "\C-c\C-qe" 'meta-indent-defun)
 904     (define-key map "\C-c\C-qr" 'meta-indent-region)
 905     (define-key map "\C-c\C-qb" 'meta-indent-buffer)
 906     ;; Commenting Out:
 907     (define-key map "\C-c%"     'meta-comment-defun)
 908     ;; (define-key map "\C-uC-c%"  'meta-uncomment-defun)
 909     (define-key map "\C-c;"     'meta-comment-region)
 910     (define-key map "\C-c:"     'meta-uncomment-region)
 911     ;; Symbol Completion:
 912     (define-key map "\M-\t"     'meta-complete-symbol)
 913     ;; Shell Commands:
 914     ;; (define-key map "\C-c\C-c"  'meta-command-file)
 915     ;; (define-key map "\C-c\C-k"  'meta-kill-job)
 916     ;; (define-key map "\C-c\C-l"  'meta-recenter-output)
 917     map)
 918   "Keymap used in Metafont or MetaPost mode.")
 919
 920
 921 (easy-menu-define
 922  meta-mode-menu meta-mode-map
 923  "Menu used in Metafont or MetaPost mode."
 924  (list "Meta"
 925        ["Forward Environment"           meta-beginning-of-defun t]
 926        ["Backward Environment"          meta-end-of-defun t]
 927        "--"
 928        ["Indent Line"                   meta-indent-line t]
 929        ["Indent Environment"            meta-indent-defun t]
 930        ["Indent Region"                 meta-indent-region
 931         :active (meta-mark-active)]
 932        ["Indent Buffer"                 meta-indent-buffer t]
 933        "--"
 934        ["Comment Out Environment"       meta-comment-defun t]
 935        ["Uncomment Environment"         meta-uncomment-defun t]
 936        ["Comment Out Region"            meta-comment-region
 937         :active (meta-mark-active)]
 938        ["Uncomment Region"              meta-uncomment-region
 939         :active (meta-mark-active)]
 940        "--"
 941        ["Complete Symbol"               meta-complete-symbol t]
 942 ;      "--"
 943 ;      ["Command on Buffer"             meta-command-file t]
 944 ;      ["Kill Job"                      meta-kill-job t]
 945 ;      ["Recenter Output Buffer"        meta-recenter-output-buffer t]
 946        ))
 947
 948 ;; Compatibility: XEmacs doesn't have the  `mark-active' variable.
 949 (defun meta-mark-active ()
 950   "Return whether the mark and region are currently active in this buffer."
 951   (if (boundp 'mark-active) mark-active (mark)))
 952
 953
 954 \f
 955 ;;; Hook variables.
 956
 957 (defcustom meta-mode-load-hook nil
 958   "*Hook evaluated when first loading Metafont or MetaPost mode."
 959   :type 'hook
 960   :group 'meta-font)
 961
 962 (defcustom meta-common-mode-hook nil
 963   "*Hook evaluated by both `metafont-mode' and `metapost-mode'."
 964   :type 'hook
 965   :group 'meta-font)
 966
 967 (defcustom metafont-mode-hook nil
 968   "*Hook evaluated by `metafont-mode' after `meta-common-mode-hook'."
 969   :type 'hook
 970   :group 'meta-font)
 971 (defcustom metapost-mode-hook nil
 972   "*Hook evaluated by `metapost-mode' after `meta-common-mode-hook'."
 973   :type 'hook
 974   :group 'meta-font)
 975
 976
 977 \f
 978 ;;; Initialization.
 979
 980 (defun meta-common-initialization ()
 981   "Common initialization for Metafont or MetaPost mode."
 982   (kill-all-local-variables)
 983
 984   (make-local-variable 'paragraph-start)
 985   (make-local-variable 'paragraph-separate)
 986   (setq paragraph-start
 987         (concat page-delimiter "\\|$"))
 988   (setq paragraph-separate
 989         (concat page-delimiter "\\|$"))
 990
 991   (make-local-variable 'paragraph-ignore-fill-prefix)
 992   (setq paragraph-ignore-fill-prefix t)
 993
 994   (make-local-variable 'comment-start-skip)
 995   (make-local-variable 'comment-start)
 996   (make-local-variable 'comment-end)
 997   (make-local-variable 'comment-multi-line)
 998   (setq comment-start-skip "%+[ \t\f]*")
 999   (setq comment-start "%")
1000   (setq comment-end "")
1001   (setq comment-multi-line nil)
1002
1003   ;; We use `back-to-indentation' but \f is no indentation sign.
1004   (modify-syntax-entry ?\f "_   ")
1005
1006   (make-local-variable 'parse-sexp-ignore-comments)
1007   (setq parse-sexp-ignore-comments t)
1008
1009   (make-local-variable 'comment-indent-function)
1010   (setq comment-indent-function 'meta-comment-indent)
1011   (make-local-variable 'indent-line-function)
1012   (setq indent-line-function 'meta-indent-line)
1013   ;; No need to define a mode-specific 'indent-region-function.
1014   ;; Simply use the generic 'indent-region and 'comment-region.
1015
1016   ;; Set defaults for font-lock mode.
1017   (make-local-variable 'font-lock-defaults)
1018   (setq font-lock-defaults
1019         '(meta-font-lock-keywords
1020           nil nil ((?_ . "w")) nil
1021           (font-lock-comment-start-regexp . "%")))
1022
1023   ;; Activate syntax table, keymap and menu.
1024   (setq local-abbrev-table meta-mode-abbrev-table)
1025   (set-syntax-table meta-mode-syntax-table)
1026   (use-local-map meta-mode-map)
1027   (easy-menu-add meta-mode-menu)
1028   )
1029
1030
1031 ;;;###autoload
1032 (defun metafont-mode ()
1033   "Major mode for editing Metafont sources.
1034 Special commands:
1035 \\{meta-mode-map}
1036
1037 Turning on Metafont mode calls the value of the variables
1038 `meta-common-mode-hook' and `metafont-mode-hook'."
1039   (interactive)
1040   (meta-common-initialization)
1041   (setq mode-name "Metafont")
1042   (setq major-mode 'metafont-mode)
1043
1044   ;; Set defaults for completion function.
1045   (make-local-variable 'meta-symbol-list)
1046   (make-local-variable 'meta-symbol-changed)
1047   (make-local-variable 'meta-complete-list)
1048   (setq meta-symbol-list nil)
1049   (setq meta-symbol-changed nil)
1050   (apply 'meta-add-symbols metafont-symbol-list)
1051   (setq meta-complete-list
1052         (list (list "\\<\\(\\sw+\\)" 1 'meta-symbol-list)
1053               (list "" 'ispell-complete-word)))
1054   (run-mode-hooks 'meta-common-mode-hook 'metafont-mode-hook))
1055
1056 ;;;###autoload
1057 (defun metapost-mode ()
1058   "Major mode for editing MetaPost sources.
1059 Special commands:
1060 \\{meta-mode-map}
1061
1062 Turning on MetaPost mode calls the value of the variable
1063 `meta-common-mode-hook' and `metafont-mode-hook'."
1064   (interactive)
1065   (meta-common-initialization)
1066   (setq mode-name "MetaPost")
1067   (setq major-mode 'metapost-mode)
1068
1069   ;; Set defaults for completion function.
1070   (make-local-variable 'meta-symbol-list)
1071   (make-local-variable 'meta-symbol-changed)
1072   (make-local-variable 'meta-complete-list)
1073   (setq meta-symbol-list nil)
1074   (setq meta-symbol-changed nil)
1075   (apply 'meta-add-symbols metapost-symbol-list)
1076   (setq meta-complete-list
1077         (list (list "\\<\\(\\sw+\\)" 1 'meta-symbol-list)
1078               (list "" 'ispell-complete-word)))
1079   (run-mode-hooks 'meta-common-mode-hook 'metapost-mode-hook))
1080
1081
1082 ;;; Just in case ...
1083
1084 (provide 'meta-mode)
1085 (run-hooks 'meta-mode-load-hook)
1086
1087 ;; arch-tag: ec2916b2-3a83-4cf7-962d-d8019370c006
1088 ;;; meta-mode.el ends here