lisp/gnus/nnmh.el

   1 ;;; nnmh.el --- mhspool access for Gnus
   2
   3 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   8 ;; Keywords: news, mail
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  30 ;; For an overview of what the interface functions do, please see the
  31 ;; Gnus sources.
  32
  33 ;;; Code:
  34
  35 (require 'nnheader)
  36 (require 'nnmail)
  37 (require 'gnus-start)
  38 (require 'nnoo)
  39 (eval-when-compile (require 'cl))
  40
  41 (nnoo-declare nnmh)
  42
  43 (defvoo nnmh-directory message-directory
  44   "Mail spool directory.")
  45
  46 (defvoo nnmh-get-new-mail t
  47   "If non-nil, nnmh will check the incoming mail file and split the mail.")
  48
  49 (defvoo nnmh-prepare-save-mail-hook nil
  50   "Hook run narrowed to an article before saving.")
  51
  52 (defvoo nnmh-be-safe nil
  53   "If non-nil, nnmh will check all articles to make sure whether they are new or not.
  54 Go through the .nnmh-articles file and compare with the actual
  55 articles in this folder.  The articles that are \"new\" will be marked
  56 as unread by Gnus.")
  57
  58 \f
  59
  60 (defconst nnmh-version "nnmh 1.0"
  61   "nnmh version.")
  62
  63 (defvoo nnmh-current-directory nil
  64   "Current news group directory.")
  65
  66 (defvoo nnmh-status-string "")
  67 (defvoo nnmh-group-alist nil)
  68 ;; Don't even think about setting this variable.  It does not exist.
  69 ;; Forget about it.  Uh-huh.  Nope.  Nobody here.  It's only bound
  70 ;; dynamically by certain functions in nndraft.
  71 (defvar nnmh-allow-delete-final nil)
  72
  73 \f
  74
  75 ;;; Interface functions.
  76
  77 (nnoo-define-basics nnmh)
  78
  79 (deffoo nnmh-retrieve-headers (articles &optional newsgroup server fetch-old)
  80   (save-excursion
  81     (set-buffer nntp-server-buffer)
  82     (erase-buffer)
  83     (let* ((file nil)
  84            (number (length articles))
  85            (large (and (numberp nnmail-large-newsgroup)
  86                        (> number nnmail-large-newsgroup)))
  87            (count 0)
  88            (file-name-coding-system nnmail-pathname-coding-system)
  89            beg article)
  90       (nnmh-possibly-change-directory newsgroup server)
  91       ;; We don't support fetching by Message-ID.
  92       (if (stringp (car articles))
  93           'headers
  94         (while articles
  95           (when (and (file-exists-p
  96                       (setq file (concat (file-name-as-directory
  97                                           nnmh-current-directory)
  98                                          (int-to-string
  99                                           (setq article (pop articles))))))
 100                      (not (file-directory-p file)))
 101             (insert (format "221 %d Article retrieved.\n" article))
 102             (setq beg (point))
 103             (nnheader-insert-head file)
 104             (goto-char beg)
 105             (if (search-forward "\n\n" nil t)
 106                 (forward-char -1)
 107               (goto-char (point-max))
 108               (insert "\n\n"))
 109             (insert ".\n")
 110             (delete-region (point) (point-max)))
 111           (setq count (1+ count))
 112
 113           (and large
 114                (zerop (% count 20))
 115                (nnheader-message 5 "nnmh: Receiving headers... %d%%"
 116                                  (/ (* count 100) number))))
 117
 118         (when large
 119           (nnheader-message 5 "nnmh: Receiving headers...done"))
 120
 121         (nnheader-fold-continuation-lines)
 122         'headers))))
 123
 124 (deffoo nnmh-open-server (server &optional defs)
 125   (nnoo-change-server 'nnmh server defs)
 126   (when (not (file-exists-p nnmh-directory))
 127     (condition-case ()
 128         (make-directory nnmh-directory t)
 129       (error t)))
 130   (cond
 131    ((not (file-exists-p nnmh-directory))
 132     (nnmh-close-server)
 133     (nnheader-report 'nnmh "Couldn't create directory: %s" nnmh-directory))
 134    ((not (file-directory-p (file-truename nnmh-directory)))
 135     (nnmh-close-server)
 136     (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory))
 137    (t
 138     (nnheader-report 'nnmh "Opened server %s using directory %s"
 139                      server nnmh-directory)
 140     t)))
 141
 142 (deffoo nnmh-request-article (id &optional newsgroup server buffer)
 143   (nnmh-possibly-change-directory newsgroup server)
 144   (let ((file (if (stringp id)
 145                   nil
 146                 (concat nnmh-current-directory (int-to-string id))))
 147         (file-name-coding-system nnmail-pathname-coding-system)
 148         (nntp-server-buffer (or buffer nntp-server-buffer)))
 149     (and (stringp file)
 150          (file-exists-p file)
 151          (not (file-directory-p file))
 152          (save-excursion (nnmail-find-file file))
 153          (string-to-number (file-name-nondirectory file)))))
 154
 155 (deffoo nnmh-request-group (group &optional server dont-check)
 156   (nnheader-init-server-buffer)
 157   (nnmh-possibly-change-directory group server)
 158   (let ((pathname (nnmail-group-pathname group nnmh-directory))
 159         (file-name-coding-system nnmail-pathname-coding-system)
 160         dir)
 161     (cond
 162      ((not (file-directory-p pathname))
 163       (nnheader-report
 164        'nnmh "Can't select group (no such directory): %s" group))
 165      (t
 166       (setq nnmh-current-directory pathname)
 167       (and nnmh-get-new-mail
 168            nnmh-be-safe
 169            (nnmh-update-gnus-unreads group))
 170       (cond
 171        (dont-check
 172         (nnheader-report 'nnmh "Selected group %s" group)
 173         t)
 174        (t
 175         ;; Re-scan the directory if it's on a foreign system.
 176         (nnheader-re-read-dir pathname)
 177         (setq dir
 178               (sort
 179                (mapcar 'string-to-number
 180                        (directory-files pathname nil "^[0-9]+$" t))
 181                '<))
 182         (cond
 183          (dir
 184           (setq nnmh-group-alist
 185                 (delq (assoc group nnmh-group-alist) nnmh-group-alist))
 186           (push (list group (cons (car dir) (car (last dir))))
 187                 nnmh-group-alist)
 188           (nnheader-report 'nnmh "Selected group %s" group)
 189           (nnheader-insert
 190            "211 %d %d %d %s\n" (length dir) (car dir)
 191            (car (last dir)) group))
 192          (t
 193           (nnheader-report 'nnmh "Empty group %s" group)
 194           (nnheader-insert (format "211 0 1 0 %s\n" group))))))))))
 195
 196 (deffoo nnmh-request-scan (&optional group server)
 197   (nnmail-get-new-mail 'nnmh nil nnmh-directory group))
 198
 199 (deffoo nnmh-request-list (&optional server dir)
 200   (nnheader-insert "")
 201   (nnmh-possibly-change-directory nil server)
 202   (let ((file-name-coding-system nnmail-pathname-coding-system)
 203         (nnmh-toplev
 204          (file-truename (or dir (file-name-as-directory nnmh-directory)))))
 205     (nnmh-request-list-1 nnmh-toplev))
 206   (setq nnmh-group-alist (nnmail-get-active))
 207   t)
 208
 209 (defvar nnmh-toplev)
 210 (defun nnmh-request-list-1 (dir)
 211   (setq dir (expand-file-name dir))
 212   ;; Recurse down all directories.
 213   (let ((dirs (and (file-readable-p dir)
 214                    (nnheader-directory-files dir t nil t)))
 215         rdir)
 216     ;; Recurse down directories.
 217     (while (setq rdir (pop dirs))
 218       (when (and (file-directory-p rdir)
 219                  (file-readable-p rdir)
 220                  (not (equal (file-truename rdir)
 221                              (file-truename dir))))
 222         (nnmh-request-list-1 rdir))))
 223   ;; For each directory, generate an active file line.
 224   (unless (string= (expand-file-name nnmh-toplev) dir)
 225     (let ((files (mapcar 'string-to-number
 226                          (directory-files dir nil "^[0-9]+$" t))))
 227       (when files
 228         (save-excursion
 229           (set-buffer nntp-server-buffer)
 230           (goto-char (point-max))
 231           (insert
 232            (format
 233             "%s %.0f %.0f y\n"
 234             (progn
 235               (string-match
 236                (regexp-quote
 237                 (file-truename (file-name-as-directory
 238                                 (expand-file-name nnmh-toplev))))
 239                dir)
 240               (mm-string-as-multibyte
 241                (mm-encode-coding-string
 242                 (nnheader-replace-chars-in-string
 243                  (substring dir (match-end 0))
 244                  ?/ ?.)
 245                 nnmail-pathname-coding-system)))
 246             (apply 'max files)
 247             (apply 'min files)))))))
 248   t)
 249
 250 (deffoo nnmh-request-newgroups (date &optional server)
 251   (nnmh-request-list server))
 252
 253 (deffoo nnmh-request-expire-articles (articles newsgroup
 254                                                &optional server force)
 255   (nnmh-possibly-change-directory newsgroup server)
 256   (let* ((is-old t)
 257          article rest mod-time)
 258     (nnheader-init-server-buffer)
 259
 260     (while (and articles is-old)
 261       (setq article (concat nnmh-current-directory
 262                             (int-to-string (car articles))))
 263       (when (setq mod-time (nth 5 (file-attributes article)))
 264         (if (and (nnmh-deletable-article-p newsgroup (car articles))
 265                  (setq is-old
 266                        (nnmail-expired-article-p newsgroup mod-time force)))
 267             (progn
 268               ;; Allow a special target group. -- jcn
 269               (unless (eq nnmail-expiry-target 'delete)
 270                 (with-temp-buffer
 271                   (nnmh-request-article (car articles)
 272                                         newsgroup server (current-buffer))
 273                   (nnmail-expiry-target-group
 274                    nnmail-expiry-target newsgroup)))
 275               (nnheader-message 5 "Deleting article %s in %s..."
 276                                 article newsgroup)
 277               (condition-case ()
 278                   (funcall nnmail-delete-file-function article)
 279                 (file-error
 280                  (nnheader-message 1 "Couldn't delete article %s in %s"
 281                                    article newsgroup)
 282                  (push (car articles) rest))))
 283           (push (car articles) rest)))
 284       (setq articles (cdr articles)))
 285     (nnheader-message 5 "")
 286     (nconc rest articles)))
 287
 288 (deffoo nnmh-close-group (group &optional server)
 289   t)
 290
 291 (deffoo nnmh-request-move-article (article group server accept-form
 292                                            &optional last move-is-internal)
 293   (let ((buf (get-buffer-create " *nnmh move*"))
 294         result)
 295     (and
 296      (nnmh-deletable-article-p group article)
 297      (nnmh-request-article article group server)
 298      (save-excursion
 299        (set-buffer buf)
 300        (erase-buffer)
 301        (insert-buffer-substring nntp-server-buffer)
 302        (setq result (eval accept-form))
 303        (kill-buffer (current-buffer))
 304        result)
 305      (progn
 306        (nnmh-possibly-change-directory group server)
 307        (condition-case ()
 308            (funcall nnmail-delete-file-function
 309                     (concat nnmh-current-directory (int-to-string article)))
 310          (file-error nil))))
 311     result))
 312
 313 (deffoo nnmh-request-accept-article (group &optional server last noinsert)
 314   (nnmh-possibly-change-directory group server)
 315   (nnmail-check-syntax)
 316   (when nnmail-cache-accepted-message-ids
 317     (nnmail-cache-insert (nnmail-fetch-field "message-id")
 318                          group
 319                          (nnmail-fetch-field "subject")
 320                          (nnmail-fetch-field "from")))
 321   (nnheader-init-server-buffer)
 322   (prog1
 323       (if (stringp group)
 324           (if noinsert
 325               (nnmh-active-number group)
 326             (car (nnmh-save-mail
 327                   (list (cons group (nnmh-active-number group)))
 328                   noinsert)))
 329         (let ((res (nnmail-article-group 'nnmh-active-number)))
 330           (if (and (null res)
 331                    (yes-or-no-p "Moved to `junk' group; delete article? "))
 332               'junk
 333             (car (nnmh-save-mail res noinsert)))))
 334     (when (and last nnmail-cache-accepted-message-ids)
 335       (nnmail-cache-close))))
 336
 337 (deffoo nnmh-request-replace-article (article group buffer)
 338   (nnmh-possibly-change-directory group)
 339   (save-excursion
 340     (set-buffer buffer)
 341     (nnmh-possibly-create-directory group)
 342     (ignore-errors
 343       (nnmail-write-region
 344        (point-min) (point-max)
 345        (concat nnmh-current-directory (int-to-string article))
 346        nil (if (nnheader-be-verbose 5) nil 'nomesg))
 347       t)))
 348
 349 (deffoo nnmh-request-create-group (group &optional server args)
 350   (nnheader-init-server-buffer)
 351   (unless (assoc group nnmh-group-alist)
 352     (let (active)
 353       (push (list group (setq active (cons 1 0)))
 354             nnmh-group-alist)
 355       (nnmh-possibly-create-directory group)
 356       (nnmh-possibly-change-directory group server)
 357       (let ((articles (mapcar 'string-to-number
 358                               (directory-files
 359                                nnmh-current-directory nil "^[0-9]+$"))))
 360         (when articles
 361           (setcar active (apply 'min articles))
 362           (setcdr active (apply 'max articles))))))
 363   t)
 364
 365 (deffoo nnmh-request-delete-group (group &optional force server)
 366   (nnmh-possibly-change-directory group server)
 367   ;; Delete all articles in GROUP.
 368   (if (not force)
 369       ()                                ; Don't delete the articles.
 370     (let ((articles (directory-files nnmh-current-directory t "^[0-9]+$")))
 371       (while articles
 372         (when (file-writable-p (car articles))
 373           (nnheader-message 5 "Deleting article %s in %s..."
 374                             (car articles) group)
 375           (funcall nnmail-delete-file-function (car articles)))
 376         (setq articles (cdr articles))))
 377     ;; Try to delete the directory itself.
 378     (ignore-errors
 379       (delete-directory nnmh-current-directory)))
 380   ;; Remove the group from all structures.
 381   (setq nnmh-group-alist
 382         (delq (assoc group nnmh-group-alist) nnmh-group-alist)
 383         nnmh-current-directory nil)
 384   t)
 385
 386 (deffoo nnmh-request-rename-group (group new-name &optional server)
 387   (nnmh-possibly-change-directory group server)
 388   (let ((new-dir (nnmail-group-pathname new-name nnmh-directory))
 389         (old-dir (nnmail-group-pathname group nnmh-directory)))
 390     (when (ignore-errors
 391             (make-directory new-dir t)
 392             t)
 393       ;; We move the articles file by file instead of renaming
 394       ;; the directory -- there may be subgroups in this group.
 395       ;; One might be more clever, I guess.
 396       (let ((files (nnheader-article-to-file-alist old-dir)))
 397         (while files
 398           (rename-file
 399            (concat old-dir (cdar files))
 400            (concat new-dir (cdar files)))
 401           (pop files)))
 402       (when (<= (length (directory-files old-dir)) 2)
 403         (ignore-errors
 404           (delete-directory old-dir)))
 405       ;; That went ok, so we change the internal structures.
 406       (let ((entry (assoc group nnmh-group-alist)))
 407         (when entry
 408           (setcar entry new-name))
 409         (setq nnmh-current-directory nil)
 410         t))))
 411
 412 (nnoo-define-skeleton nnmh)
 413
 414 \f
 415 ;;; Internal functions.
 416
 417 (defun nnmh-possibly-change-directory (newsgroup &optional server)
 418   (when (and server
 419              (not (nnmh-server-opened server)))
 420     (nnmh-open-server server))
 421   (when newsgroup
 422     (let ((pathname (nnmail-group-pathname newsgroup nnmh-directory))
 423           (file-name-coding-system nnmail-pathname-coding-system))
 424       (if (file-directory-p pathname)
 425           (setq nnmh-current-directory pathname)
 426         (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory)))))
 427
 428 (defun nnmh-possibly-create-directory (group)
 429   (let (dir dirs)
 430     (setq dir (nnmail-group-pathname group nnmh-directory))
 431     (while (not (file-directory-p dir))
 432       (push dir dirs)
 433       (setq dir (file-name-directory (directory-file-name dir))))
 434     (while dirs
 435       (when (make-directory (directory-file-name (car dirs)))
 436         (error "Could not create directory %s" (car dirs)))
 437       (nnheader-message 5 "Creating mail directory %s" (car dirs))
 438       (setq dirs (cdr dirs)))))
 439
 440 (defun nnmh-save-mail (group-art &optional noinsert)
 441   "Called narrowed to an article."
 442   (unless noinsert
 443     (nnmail-insert-lines)
 444     (nnmail-insert-xref group-art))
 445   (run-hooks 'nnmail-prepare-save-mail-hook)
 446   (run-hooks 'nnmh-prepare-save-mail-hook)
 447   (goto-char (point-min))
 448   (while (looking-at "From ")
 449     (replace-match "X-From-Line: ")
 450     (forward-line 1))
 451   ;; We save the article in all the newsgroups it belongs in.
 452   (let ((ga group-art)
 453         first)
 454     (while ga
 455       (nnmh-possibly-create-directory (caar ga))
 456       (let ((file (concat (nnmail-group-pathname
 457                            (caar ga) nnmh-directory)
 458                           (int-to-string (cdar ga)))))
 459         (if first
 460             ;; It was already saved, so we just make a hard link.
 461             (funcall nnmail-crosspost-link-function first file t)
 462           ;; Save the article.
 463           (nnmail-write-region (point-min) (point-max) file nil nil)
 464           (setq first file)))
 465       (setq ga (cdr ga))))
 466   group-art)
 467
 468 (defun nnmh-active-number (group)
 469   "Compute the next article number in GROUP."
 470   (let ((active (cadr (assoc group nnmh-group-alist)))
 471         (dir (nnmail-group-pathname group nnmh-directory))
 472         (file-name-coding-system nnmail-pathname-coding-system)
 473         file)
 474     (unless active
 475       ;; The group wasn't known to nnmh, so we just create an active
 476       ;; entry for it.
 477       (setq active (cons 1 0))
 478       (push (list group active) nnmh-group-alist)
 479       (unless (file-exists-p dir)
 480         (gnus-make-directory dir))
 481       ;; Find the highest number in the group.
 482       (let ((files (sort
 483                     (mapcar 'string-to-number
 484                             (directory-files dir nil "^[0-9]+$"))
 485                     '>)))
 486         (when files
 487           (setcdr active (car files)))))
 488     (setcdr active (1+ (cdr active)))
 489     (while (or
 490             ;; See whether the file exists...
 491             (file-exists-p
 492              (setq file (concat (nnmail-group-pathname group nnmh-directory)
 493                                 (int-to-string (cdr active)))))
 494             ;; ... or there is a buffer that will make that file exist
 495             ;; in the future.
 496             (get-file-buffer file))
 497       ;; Skip past that file.
 498       (setcdr active (1+ (cdr active))))
 499     (cdr active)))
 500
 501 (defun nnmh-update-gnus-unreads (group)
 502   ;; Go through the .nnmh-articles file and compare with the actual
 503   ;; articles in this folder.  The articles that are "new" will be
 504   ;; marked as unread by Gnus.
 505   (let* ((dir nnmh-current-directory)
 506          (files (sort (mapcar 'string-to-number
 507                               (directory-files nnmh-current-directory
 508                                                nil "^[0-9]+$" t))
 509                       '<))
 510          (nnmh-file (concat dir ".nnmh-articles"))
 511          new articles)
 512     ;; Load the .nnmh-articles file.
 513     (when (file-exists-p nnmh-file)
 514       (setq articles
 515             (let (nnmh-newsgroup-articles)
 516               (ignore-errors (load nnmh-file nil t t))
 517               nnmh-newsgroup-articles)))
 518     ;; Add all new articles to the `new' list.
 519     (let ((art files))
 520       (while art
 521         (unless (assq (car art) articles)
 522           (push (car art) new))
 523         (setq art (cdr art))))
 524     ;; Remove all deleted articles.
 525     (let ((art articles))
 526       (while art
 527         (unless (memq (caar art) files)
 528           (setq articles (delq (car art) articles)))
 529         (setq art (cdr art))))
 530     ;; Check whether the articles really are the ones that Gnus thinks
 531     ;; they are by looking at the time-stamps.
 532     (let ((arts articles)
 533           art)
 534       (while (setq art (pop arts))
 535         (when (not (equal
 536                     (nth 5 (file-attributes
 537                             (concat dir (int-to-string (car art)))))
 538                     (cdr art)))
 539           (setq articles (delq art articles))
 540           (push (car art) new))))
 541     ;; Go through all the new articles and add them, and their
 542     ;; time-stamps, to the list.
 543     (setq articles
 544           (nconc articles
 545                  (mapcar
 546                   (lambda (art)
 547                     (cons art
 548                           (nth 5 (file-attributes
 549                                   (concat dir (int-to-string art))))))
 550                   new)))
 551     ;; Make Gnus mark all new articles as unread.
 552     (when new
 553       (gnus-make-articles-unread
 554        (gnus-group-prefixed-name group (list 'nnmh ""))
 555        (setq new (sort new '<))))
 556     ;; Sort the article list with highest numbers first.
 557     (setq articles (sort articles (lambda (art1 art2)
 558                                     (> (car art1) (car art2)))))
 559     ;; Finally write this list back to the .nnmh-articles file.
 560     (with-temp-file nnmh-file
 561       (insert ";; Gnus article active file for " group "\n\n")
 562       (insert "(setq nnmh-newsgroup-articles '")
 563       (gnus-prin1 articles)
 564       (insert ")\n"))))
 565
 566 (defun nnmh-deletable-article-p (group article)
 567   "Say whether ARTICLE in GROUP can be deleted."
 568   (let ((path (concat nnmh-current-directory (int-to-string article))))
 569     ;; Writable.
 570     (and (file-writable-p path)
 571          (or
 572           ;; We can never delete the last article in the group.
 573           (not (eq (cdr (nth 1 (assoc group nnmh-group-alist)))
 574                    article))
 575           ;; Well, we can.
 576           nnmh-allow-delete-final))))
 577
 578 (provide 'nnmh)
 579
 580 ;;; arch-tag: 36c12a98-3bad-44b3-9953-628078ef0e04
 581 ;;; nnmh.el ends here