lisp/novice.el

   1 ;;; novice.el --- handling of disabled commands ("novice mode") for Emacs
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1994, 2002, 2003, 2004,
   4 ;;   2005 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal, help
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This mode provides a hook which is, by default, attached to various
  29 ;; putatively dangerous commands in a (probably futile) attempt to
  30 ;; prevent lusers from shooting themselves in the feet.
  31
  32 ;;; Code:
  33
  34 ;; This function is called (by autoloading)
  35 ;; to handle any disabled command.
  36 ;; The command is found in this-command
  37 ;; and the keys are returned by (this-command-keys).
  38
  39 ;;;###autoload
  40 (defvar disabled-command-function 'disabled-command-function
  41   "Function to call to handle disabled commands.
  42 If nil, the feature is disabled, i.e., all commands work normally.")
  43
  44 ;;;###autoload
  45 (define-obsolete-variable-alias 'disabled-command-hook 'disabled-command-function "22.1")
  46
  47 ;;;###autoload
  48 (defun disabled-command-function (&rest ignore)
  49   (let (char)
  50     (save-window-excursion
  51      (with-output-to-temp-buffer "*Disabled Command*"
  52        (let ((keys (this-command-keys)))
  53          (if (or (eq (aref keys 0)
  54                      (if (stringp keys)
  55                          (aref "\M-x" 0)
  56                        ?\M-x))
  57                  (and (>= (length keys) 2)
  58                       (eq (aref keys 0) meta-prefix-char)
  59                       (eq (aref keys 1) ?x)))
  60              (princ (format "You have invoked the disabled command %s.\n"
  61                             (symbol-name this-command)))
  62            (princ (format "You have typed %s, invoking disabled command %s.\n"
  63                           (key-description keys) (symbol-name this-command)))))
  64        ;; Print any special message saying why the command is disabled.
  65        (if (stringp (get this-command 'disabled))
  66            (princ (get this-command 'disabled))
  67          (princ "It is disabled because new users often find it confusing.\n")
  68          (princ "Here's the first part of its description:\n\n")
  69          ;; Keep only the first paragraph of the documentation.
  70          (with-current-buffer "*Disabled Command*"
  71            (goto-char (point-max))
  72            (let ((start (point)))
  73              (save-excursion
  74                (princ (or (condition-case ()
  75                               (documentation this-command)
  76                             (error nil))
  77                           "<< not documented >>")))
  78              (if (search-forward "\n\n" nil t)
  79                  (delete-region (match-beginning 0) (point-max)))
  80              (goto-char (point-max))
  81              (indent-rigidly start (point) 3))))
  82        (princ "\n\nDo you want to use this command anyway?\n\n")
  83        (princ "You can now type
  84 y   to try it and enable it (no questions if you use it again).
  85 n   to cancel--don't try the command, and it remains disabled.
  86 SPC to try the command just this once, but leave it disabled.
  87 !   to try it, and enable all disabled commands for this session only.")
  88        (save-excursion
  89         (set-buffer standard-output)
  90         (help-mode)))
  91      (message "Type y, n, ! or SPC (the space bar): ")
  92      (let ((cursor-in-echo-area t))
  93        (while (progn (setq char (read-event))
  94                      (or (not (numberp char))
  95                          (not (memq (downcase char)
  96                                     '(?! ?y ?n ?\  ?\C-g)))))
  97          (ding)
  98          (message "Please type y, n, ! or SPC (the space bar): "))))
  99     (setq char (downcase char))
 100     (if (= char ?\C-g)
 101         (setq quit-flag t))
 102     (if (= char ?!)
 103         (setq disabled-command-function nil))
 104     (if (= char ?y)
 105         (if (and user-init-file
 106                  (not (string= "" user-init-file))
 107                  (y-or-n-p "Enable command for future editing sessions also? "))
 108             (enable-command this-command)
 109           (put this-command 'disabled nil)))
 110     (if (/= char ?n)
 111         (call-interactively this-command))))
 112
 113 ;;;###autoload
 114 (defun enable-command (command)
 115   "Allow COMMAND to be executed without special confirmation from now on.
 116 COMMAND must be a symbol.
 117 This command alters the user's .emacs file so that this will apply
 118 to future sessions."
 119   (interactive "CEnable command: ")
 120   (put command 'disabled nil)
 121   (let ((init-file user-init-file)
 122         (default-init-file
 123           (if (eq system-type 'ms-dos) "~/_emacs" "~/.emacs")))
 124     (when (null init-file)
 125       (if (or (file-exists-p default-init-file)
 126               (and (eq system-type 'windows-nt)
 127                    (file-exists-p "~/_emacs")))
 128           ;; Started with -q, i.e. the file containing
 129           ;; enabled/disabled commands hasn't been read.  Saving
 130           ;; settings there would overwrite other settings.
 131           (error "Saving settings from \"emacs -q\" would overwrite existing customizations"))
 132       (setq init-file default-init-file)
 133       (if (and (not (file-exists-p init-file))
 134                (eq system-type 'windows-nt)
 135                (file-exists-p "~/_emacs"))
 136           (setq init-file "~/_emacs")))
 137     (save-excursion
 138       (set-buffer (find-file-noselect
 139                    (substitute-in-file-name init-file)))
 140       (goto-char (point-min))
 141       (if (search-forward (concat "(put '" (symbol-name command) " ") nil t)
 142           (delete-region
 143            (progn (beginning-of-line) (point))
 144            (progn (forward-line 1) (point))))
 145       ;; Explicitly enable, in case this command is disabled by default
 146       ;; or in case the code we deleted was actually a comment.
 147       (goto-char (point-max))
 148       (insert "\n(put '" (symbol-name command) " 'disabled nil)\n")
 149       (save-buffer))))
 150
 151 ;;;###autoload
 152 (defun disable-command (command)
 153   "Require special confirmation to execute COMMAND from now on.
 154 COMMAND must be a symbol.
 155 This command alters the user's .emacs file so that this will apply
 156 to future sessions."
 157   (interactive "CDisable command: ")
 158   (if (not (commandp command))
 159       (error "Invalid command name `%s'" command))
 160   (put command 'disabled t)
 161   (let ((init-file user-init-file)
 162         (default-init-file
 163           (if (eq system-type 'ms-dos) "~/_emacs" "~/.emacs")))
 164     (when (null init-file)
 165       (if (or (file-exists-p default-init-file)
 166               (and (eq system-type 'windows-nt)
 167                    (file-exists-p "~/_emacs")))
 168           ;; Started with -q, i.e. the file containing
 169           ;; enabled/disabled commands hasn't been read.  Saving
 170           ;; settings there would overwrite other settings.
 171           (error "Saving settings from \"emacs -q\" would overwrite existing customizations"))
 172       (setq init-file default-init-file)
 173       (if (and (not (file-exists-p init-file))
 174                (eq system-type 'windows-nt)
 175                (file-exists-p "~/_emacs"))
 176           (setq init-file "~/_emacs")))
 177     (save-excursion
 178       (set-buffer (find-file-noselect
 179                    (substitute-in-file-name init-file)))
 180       (goto-char (point-min))
 181       (if (search-forward (concat "(put '" (symbol-name command) " ") nil t)
 182           (delete-region
 183            (progn (beginning-of-line) (point))
 184            (progn (forward-line 1) (point)))
 185         (goto-char (point-max))
 186         (insert ?\n))
 187       (insert "(put '" (symbol-name command) " 'disabled t)\n")
 188       (save-buffer))))
 189
 190 (provide 'novice)
 191
 192 ;; arch-tag: f83c0f96-497e-4db6-a430-8703716c6dd9
 193 ;;; novice.el ends here