lisp/tooltip.el

   1 ;;; tooltip.el --- show tooltip windows
   2
   3 ;; Copyright (C) 1997, 1999-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Gerd Moellmann <gerd@acm.org>
   6 ;; Keywords: help c mouse tools
   7 ;; Package: emacs
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'syntax)
  29
  30 (defvar comint-prompt-regexp)
  31
  32 (defgroup tooltip nil
  33   "Customization group for the `tooltip' package."
  34   :group 'help
  35   :group 'gud
  36   :group 'mouse
  37   :group 'tools
  38   :version "21.1"
  39   :tag "Tool Tips")
  40 \f
  41 ;;; Switching tooltips on/off
  42
  43 (define-minor-mode tooltip-mode
  44   "Toggle Tooltip mode.
  45 With a prefix argument ARG, enable Tooltip mode if ARG is positive,
  46 and disable it otherwise.  If called from Lisp, enable the mode
  47 if ARG is omitted or nil.
  48
  49 When this global minor mode is enabled, Emacs displays help
  50 text (e.g. for buttons and menu items that you put the mouse on)
  51 in a pop-up window.
  52
  53 When Tooltip mode is disabled, Emacs displays help text in the
  54 echo area, instead of making a pop-up window."
  55   :global t
  56   ;; Even if we start on a text-only terminal, make this non-nil by
  57   ;; default because we can open a graphical frame later (multi-tty).
  58   :init-value t
  59   :initialize 'custom-initialize-delay
  60   :group 'tooltip
  61   (unless (or (null tooltip-mode) (fboundp 'x-show-tip))
  62     (error "Sorry, tooltips are not yet available on this system"))
  63   (if tooltip-mode
  64       (progn
  65         (add-hook 'pre-command-hook 'tooltip-hide)
  66         (add-hook 'tooltip-functions 'tooltip-help-tips))
  67     (unless (and (boundp 'gud-tooltip-mode) gud-tooltip-mode)
  68       (remove-hook 'pre-command-hook 'tooltip-hide))
  69     (remove-hook 'tooltip-functions 'tooltip-help-tips))
  70   (setq show-help-function
  71         (if tooltip-mode 'tooltip-show-help 'tooltip-show-help-non-mode)))
  72
  73 \f
  74 ;;; Customizable settings
  75
  76 (defcustom tooltip-delay 0.7
  77   "Seconds to wait before displaying a tooltip the first time."
  78   :type 'number
  79   :group 'tooltip)
  80
  81 (defcustom tooltip-short-delay 0.1
  82   "Seconds to wait between subsequent tooltips on different items."
  83   :type 'number
  84   :group 'tooltip)
  85
  86 (defcustom tooltip-recent-seconds 1
  87   "Display tooltips if changing tip items within this many seconds.
  88 Do so after `tooltip-short-delay'."
  89   :type 'number
  90   :group 'tooltip)
  91
  92 (defcustom tooltip-hide-delay 10
  93   "Hide tooltips automatically after this many seconds."
  94   :type 'number
  95   :group 'tooltip)
  96
  97 (defcustom tooltip-x-offset 5
  98   "X offset, in pixels, for the display of tooltips.
  99 The offset is the distance between the X position of the mouse and
 100 the left border of the tooltip window.  It must be chosen so that the
 101 tooltip window doesn't contain the mouse when it pops up, or it may
 102 interfere with clicking where you wish.
 103
 104 If `tooltip-frame-parameters' includes the `left' parameter,
 105 the value of `tooltip-x-offset' is ignored."
 106   :type 'integer
 107   :group 'tooltip)
 108
 109 (defcustom tooltip-y-offset +20
 110   "Y offset, in pixels, for the display of tooltips.
 111 The offset is the distance between the Y position of the mouse and
 112 the top border of the tooltip window.  It must be chosen so that the
 113 tooltip window doesn't contain the mouse when it pops up, or it may
 114 interfere with clicking where you wish.
 115
 116 If `tooltip-frame-parameters' includes the `top' parameter,
 117 the value of `tooltip-y-offset' is ignored."
 118   :type 'integer
 119   :group 'tooltip)
 120
 121 (defcustom tooltip-frame-parameters
 122   '((name . "tooltip")
 123     (internal-border-width . 2)
 124     (border-width . 1))
 125   "Frame parameters used for tooltips.
 126
 127 If `left' or `top' parameters are included, they specify the absolute
 128 position to pop up the tooltip.
 129
 130 Note that font and color parameters are ignored, and the attributes
 131 of the `tooltip' face are used instead."
 132   :type 'sexp
 133   :group 'tooltip)
 134
 135 (defface tooltip
 136   '((((class color))
 137      :background "lightyellow"
 138      :foreground "black"
 139      :inherit variable-pitch)
 140     (t
 141      :inherit variable-pitch))
 142   "Face for tooltips."
 143   :group 'tooltip
 144   :group 'basic-faces)
 145
 146 (defcustom tooltip-use-echo-area nil
 147   "Use the echo area instead of tooltip frames for help and GUD tooltips.
 148 This variable is obsolete; instead of setting it to t, disable
 149 `tooltip-mode' (which has a similar effect)."
 150   :type 'boolean
 151   :group 'tooltip)
 152
 153 (make-obsolete-variable 'tooltip-use-echo-area
 154                         "disable Tooltip mode instead" "24.1")
 155
 156 \f
 157 ;;; Variables that are not customizable.
 158
 159 (define-obsolete-variable-alias 'tooltip-hook 'tooltip-functions "23.1")
 160
 161 (defvar tooltip-functions nil
 162   "Functions to call to display tooltips.
 163 Each function is called with one argument EVENT which is a copy
 164 of the last mouse movement event that occurred.  If one of these
 165 functions displays the tooltip, it should return non-nil and the
 166 rest are not called.")
 167
 168 (defvar tooltip-timeout-id nil
 169   "The id of the timeout started when Emacs becomes idle.")
 170
 171 (defvar tooltip-last-mouse-motion-event nil
 172   "A copy of the last mouse motion event seen.")
 173
 174 (defvar tooltip-hide-time nil
 175   "Time when the last tooltip was hidden.")
 176
 177 (defvar gud-tooltip-mode) ;; Prevent warning.
 178
 179 ;;; Event accessors
 180
 181 (defun tooltip-event-buffer (event)
 182   "Return the buffer over which event EVENT occurred.
 183 This might return nil if the event did not occur over a buffer."
 184   (let ((window (posn-window (event-end event))))
 185     (and window (window-buffer window))))
 186
 187 \f
 188 ;;; Timeout for tooltip display
 189
 190 (defun tooltip-delay ()
 191   "Return the delay in seconds for the next tooltip."
 192   (if (and tooltip-hide-time
 193            (< (- (float-time) tooltip-hide-time) tooltip-recent-seconds))
 194       tooltip-short-delay
 195     tooltip-delay))
 196
 197 (defun tooltip-cancel-delayed-tip ()
 198   "Disable the tooltip timeout."
 199   (when tooltip-timeout-id
 200     (disable-timeout tooltip-timeout-id)
 201     (setq tooltip-timeout-id nil)))
 202
 203 (defun tooltip-start-delayed-tip ()
 204   "Add a one-shot timeout to call function `tooltip-timeout'."
 205   (setq tooltip-timeout-id
 206         (add-timeout (tooltip-delay) 'tooltip-timeout nil)))
 207
 208 (defun tooltip-timeout (_object)
 209   "Function called when timer with id `tooltip-timeout-id' fires."
 210   (run-hook-with-args-until-success 'tooltip-functions
 211                                     tooltip-last-mouse-motion-event))
 212
 213 \f
 214 ;;; Displaying tips
 215
 216 (defun tooltip-set-param (alist key value)
 217   "Change the value of KEY in alist ALIST to VALUE.
 218 If there's no association for KEY in ALIST, add one, otherwise
 219 change the existing association.  Value is the resulting alist."
 220   (let ((param (assq key alist)))
 221     (if (consp param)
 222         (setcdr param value)
 223       (push (cons key value) alist))
 224     alist))
 225
 226 (declare-function x-show-tip "xfns.c"
 227                   (string &optional frame parms timeout dx dy))
 228
 229 (defun tooltip-show (text &optional use-echo-area)
 230   "Show a tooltip window displaying TEXT.
 231
 232 Text larger than `x-max-tooltip-size' is clipped.
 233
 234 If the alist in `tooltip-frame-parameters' includes `left' and `top'
 235 parameters, they determine the x and y position where the tooltip
 236 is displayed.  Otherwise, the tooltip pops at offsets specified by
 237 `tooltip-x-offset' and `tooltip-y-offset' from the current mouse
 238 position.
 239
 240 Optional second arg USE-ECHO-AREA non-nil means to show tooltip
 241 in echo area."
 242   (if use-echo-area
 243       (tooltip-show-help-non-mode text)
 244     (condition-case error
 245         (let ((params (copy-sequence tooltip-frame-parameters))
 246               (fg (face-attribute 'tooltip :foreground))
 247               (bg (face-attribute 'tooltip :background)))
 248           (when (stringp fg)
 249             (setq params (tooltip-set-param params 'foreground-color fg))
 250             (setq params (tooltip-set-param params 'border-color fg)))
 251           (when (stringp bg)
 252             (setq params (tooltip-set-param params 'background-color bg)))
 253           (x-show-tip (propertize text 'face 'tooltip)
 254                       (selected-frame)
 255                       params
 256                       tooltip-hide-delay
 257                       tooltip-x-offset
 258                       tooltip-y-offset))
 259       (error
 260        (message "Error while displaying tooltip: %s" error)
 261        (sit-for 1)
 262        (message "%s" text)))))
 263
 264 (declare-function x-hide-tip "xfns.c" ())
 265
 266 (defun tooltip-hide (&optional _ignored-arg)
 267   "Hide a tooltip, if one is displayed.
 268 Value is non-nil if tooltip was open."
 269   (tooltip-cancel-delayed-tip)
 270   (when (x-hide-tip)
 271     (setq tooltip-hide-time (float-time))))
 272
 273 \f
 274 ;;; Debugger-related functions
 275
 276 (defun tooltip-identifier-from-point (point)
 277   "Extract the identifier at POINT, if any.
 278 Value is nil if no identifier exists at point.  Identifier extraction
 279 is based on the current syntax table."
 280   (save-excursion
 281     (goto-char point)
 282     (let* ((start (progn (skip-syntax-backward "w_") (point)))
 283            (pstate (syntax-ppss)))
 284       (unless (or (looking-at "[0-9]")
 285                   (nth 3 pstate)
 286                   (nth 4 pstate))
 287         (skip-syntax-forward "w_")
 288         (when (> (point) start)
 289           (buffer-substring start (point)))))))
 290
 291 (defmacro tooltip-region-active-p ()
 292   "Value is non-nil if the region should override command actions."
 293   `(use-region-p))
 294
 295 (defun tooltip-expr-to-print (event)
 296   "Return an expression that should be printed for EVENT.
 297 If a region is active and the mouse is inside the region, print
 298 the region.  Otherwise, figure out the identifier around the point
 299 where the mouse is."
 300   (with-current-buffer (tooltip-event-buffer event)
 301     (let ((point (posn-point (event-end event))))
 302       (if (tooltip-region-active-p)
 303           (when (and (<= (region-beginning) point) (<= point (region-end)))
 304             (buffer-substring (region-beginning) (region-end)))
 305         (tooltip-identifier-from-point point)))))
 306
 307 (defun tooltip-process-prompt-regexp (process)
 308   "Return regexp matching the prompt of PROCESS at the end of a string.
 309 The prompt is taken from the value of `comint-prompt-regexp' in
 310 the buffer of PROCESS."
 311   (let ((prompt-regexp (with-current-buffer (process-buffer process)
 312                          comint-prompt-regexp)))
 313     (concat "\n*"
 314             ;; Most start with `^' but the one for `sdb' cannot be easily
 315             ;; stripped.  Code the prompt for `sdb' fixed here.
 316             (if (= (aref prompt-regexp 0) ?^)
 317                 (substring prompt-regexp 1)
 318               "\\*")
 319             "$")))
 320
 321 (defun tooltip-strip-prompt (process output)
 322   "Return OUTPUT with any prompt of PROCESS stripped from its end."
 323   (save-match-data
 324     (if (string-match (tooltip-process-prompt-regexp process) output)
 325         (substring output 0 (match-beginning 0))
 326       output)))
 327
 328 \f
 329 ;;; Tooltip help.
 330
 331 (defvar tooltip-help-message nil
 332   "The last help message received via `show-help-function'.
 333 This is used by `tooltip-show-help' and
 334 `tooltip-show-help-non-mode'.")
 335
 336 (defvar tooltip-previous-message nil
 337   "The previous content of the echo area.")
 338
 339 (defun tooltip-show-help-non-mode (help)
 340   "Function installed as `show-help-function' when Tooltip mode is off.
 341 It is also called if Tooltip mode is on, for text-only displays."
 342   (when (and (not (window-minibuffer-p)) ;Don't overwrite minibuffer contents.
 343              (not cursor-in-echo-area))  ;Don't overwrite a prompt.
 344     (cond
 345      ((stringp help)
 346       (setq help (replace-regexp-in-string "\n" ", " help))
 347       (unless (or tooltip-previous-message
 348                   (string-equal help (current-message))
 349                   (and (stringp tooltip-help-message)
 350                        (string-equal tooltip-help-message
 351                                      (current-message))))
 352         (setq tooltip-previous-message (current-message)))
 353       (setq tooltip-help-message help)
 354       (let ((message-truncate-lines t)
 355             (message-log-max nil))
 356         (message "%s" help)))
 357      ((stringp tooltip-previous-message)
 358       (let ((message-log-max nil))
 359         (message "%s" tooltip-previous-message)
 360         (setq tooltip-previous-message nil)))
 361      (t
 362       (message nil)))))
 363
 364 (defun tooltip-show-help (msg)
 365   "Function installed as `show-help-function'.
 366 MSG is either a help string to display, or nil to cancel the display."
 367   (if (display-graphic-p)
 368       (let ((previous-help tooltip-help-message))
 369         (setq tooltip-help-message msg)
 370         (cond ((null msg)
 371                ;; Cancel display.  This also cancels a delayed tip, if
 372                ;; there is one.
 373                (tooltip-hide))
 374               ((equal previous-help msg)
 375                ;; Same help as before (but possibly the mouse has moved).
 376                ;; Keep what we have.
 377                )
 378               (t
 379                ;; A different help.  Remove a previous tooltip, and
 380                ;; display a new one, with some delay.
 381                (tooltip-hide)
 382                (tooltip-start-delayed-tip))))
 383     ;; On text-only displays, try `tooltip-show-help-non-mode'.
 384     (tooltip-show-help-non-mode msg)))
 385
 386 (defun tooltip-help-tips (_event)
 387   "Hook function to display a help tooltip.
 388 This is installed on the hook `tooltip-functions', which
 389 is run when the timer with id `tooltip-timeout-id' fires.
 390 Value is non-nil if this function handled the tip."
 391   (when (stringp tooltip-help-message)
 392     (tooltip-show tooltip-help-message tooltip-use-echo-area)
 393     t))
 394
 395 (provide 'tooltip)
 396
 397 ;;; tooltip.el ends here