lisp/gnus/ietf-drums.el

   1 ;;; ietf-drums.el --- Functions for parsing RFC822bis headers
   2
   3 ;; Copyright (C) 1998-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software: you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 ;;; Commentary:
  22
  23 ;; DRUMS is an IETF Working Group that works (or worked) on the
  24 ;; successor to RFC822, "Standard For The Format Of Arpa Internet Text
  25 ;; Messages".  This library is based on
  26 ;; draft-ietf-drums-msg-fmt-05.txt, released on 1998-08-05.
  27
  28 ;; Pending a real regression self test suite, Simon Josefsson added
  29 ;; various self test expressions snipped from bug reports, and their
  30 ;; expected value, below.  I you believe it could be useful, please
  31 ;; add your own test cases, or write a real self test suite, or just
  32 ;; remove this.
  33
  34 ;; <m3oekvfd50.fsf@whitebox.m5r.de>
  35 ;; (ietf-drums-parse-address "'foo' <foo@example.com>")
  36 ;; => ("foo@example.com" . "'foo'")
  37
  38 ;;; Code:
  39
  40 (eval-when-compile (require 'cl))
  41 (require 'mm-util)
  42
  43 (defvar ietf-drums-no-ws-ctl-token "\001-\010\013\014\016-\037\177"
  44   "US-ASCII control characters excluding CR, LF and white space.")
  45 (defvar ietf-drums-text-token "\001-\011\013\014\016-\177"
  46   "US-ASCII characters excluding CR and LF.")
  47 (defvar ietf-drums-specials-token "()<>[]:;@\\,.\""
  48   "Special characters.")
  49 (defvar ietf-drums-quote-token "\\"
  50   "Quote character.")
  51 (defvar ietf-drums-wsp-token " \t"
  52   "White space.")
  53 (defvar ietf-drums-fws-regexp
  54   (concat "[" ietf-drums-wsp-token "]*\n[" ietf-drums-wsp-token "]+")
  55   "Folding white space.")
  56 (defvar ietf-drums-atext-token "-^a-zA-Z0-9!#$%&'*+/=?_`{|}~"
  57   "Textual token.")
  58 (defvar ietf-drums-dot-atext-token "-^a-zA-Z0-9!#$%&'*+/=?_`{|}~."
  59   "Textual token including full stop.")
  60 (defvar ietf-drums-qtext-token
  61   (concat ietf-drums-no-ws-ctl-token "\041\043-\133\135-\177")
  62   "Non-white-space control characters, plus the rest of ASCII excluding
  63 backslash and doublequote.")
  64 (defvar ietf-drums-tspecials "][()<>@,;:\\\"/?="
  65   "Tspecials.")
  66
  67 (defvar ietf-drums-syntax-table
  68   (let ((table (copy-syntax-table emacs-lisp-mode-syntax-table)))
  69     (modify-syntax-entry ?\\ "/" table)
  70     (modify-syntax-entry ?< "(" table)
  71     (modify-syntax-entry ?> ")" table)
  72     (modify-syntax-entry ?@ "w" table)
  73     (modify-syntax-entry ?/ "w" table)
  74     (modify-syntax-entry ?* "_" table)
  75     (modify-syntax-entry ?\; "_" table)
  76     (modify-syntax-entry ?\' "_" table)
  77     (if (featurep 'xemacs)
  78         (let ((i 128))
  79           (while (< i 256)
  80             (modify-syntax-entry i "w" table)
  81             (setq i (1+ i)))))
  82     table))
  83
  84 (defun ietf-drums-token-to-list (token)
  85   "Translate TOKEN into a list of characters."
  86   (let ((i 0)
  87         b e c out range)
  88     (while (< i (length token))
  89       (setq c (mm-char-int (aref token i)))
  90       (incf i)
  91       (cond
  92        ((eq c (mm-char-int ?-))
  93         (if b
  94             (setq range t)
  95           (push c out)))
  96        (range
  97         (while (<= b c)
  98           (push (make-char 'ascii b) out)
  99           (incf b))
 100         (setq range nil))
 101        ((= i (length token))
 102         (push (make-char 'ascii c) out))
 103        (t
 104         (when b
 105           (push (make-char 'ascii b) out))
 106         (setq b c))))
 107     (nreverse out)))
 108
 109 (defsubst ietf-drums-init (string)
 110   (set-syntax-table ietf-drums-syntax-table)
 111   (insert string)
 112   (ietf-drums-unfold-fws)
 113   (goto-char (point-min)))
 114
 115 (defun ietf-drums-remove-comments (string)
 116   "Remove comments from STRING."
 117   (with-temp-buffer
 118     (let (c)
 119       (ietf-drums-init string)
 120       (while (not (eobp))
 121         (setq c (char-after))
 122         (cond
 123          ((eq c ?\")
 124           (condition-case err
 125               (forward-sexp 1)
 126             (error (goto-char (point-max)))))
 127          ((eq c ?\()
 128           (delete-region
 129                (point)
 130                (condition-case nil
 131                    (with-syntax-table (copy-syntax-table ietf-drums-syntax-table)
 132                      (modify-syntax-entry ?\" "w")
 133                      (forward-sexp 1)
 134                      (point))
 135                  (error (point-max)))))
 136          (t
 137           (forward-char 1))))
 138       (buffer-string))))
 139
 140 (defun ietf-drums-remove-whitespace (string)
 141   "Remove whitespace from STRING."
 142   (with-temp-buffer
 143     (ietf-drums-init string)
 144     (let (c)
 145       (while (not (eobp))
 146         (setq c (char-after))
 147         (cond
 148          ((eq c ?\")
 149           (forward-sexp 1))
 150          ((eq c ?\()
 151           (forward-sexp 1))
 152          ((memq c '(?\  ?\t ?\n))
 153           (delete-char 1))
 154          (t
 155           (forward-char 1))))
 156       (buffer-string))))
 157
 158 (defun ietf-drums-get-comment (string)
 159   "Return the first comment in STRING."
 160   (with-temp-buffer
 161     (ietf-drums-init string)
 162     (let (result c)
 163       (while (not (eobp))
 164         (setq c (char-after))
 165         (cond
 166          ((eq c ?\")
 167           (forward-sexp 1))
 168          ((eq c ?\()
 169           (setq result
 170                 (buffer-substring
 171                  (1+ (point))
 172                  (progn (forward-sexp 1) (1- (point))))))
 173          (t
 174           (forward-char 1))))
 175       result)))
 176
 177 (defun ietf-drums-strip (string)
 178   "Remove comments and whitespace from STRING."
 179   (ietf-drums-remove-whitespace (ietf-drums-remove-comments string)))
 180
 181 (defun ietf-drums-parse-address (string)
 182   "Parse STRING and return a MAILBOX / DISPLAY-NAME pair."
 183   (with-temp-buffer
 184     (let (display-name mailbox c display-string)
 185       (ietf-drums-init string)
 186       (while (not (eobp))
 187         (setq c (char-after))
 188         (cond
 189          ((or (eq c ? )
 190               (eq c ?\t))
 191           (forward-char 1))
 192          ((eq c ?\()
 193           (forward-sexp 1))
 194          ((eq c ?\")
 195           (push (buffer-substring
 196                  (1+ (point)) (progn (forward-sexp 1) (1- (point))))
 197                 display-name))
 198          ((looking-at (concat "[" ietf-drums-atext-token "@" "]"))
 199           (push (buffer-substring (point) (progn (forward-sexp 1) (point)))
 200                 display-name))
 201          ((eq c ?<)
 202           (setq mailbox
 203                 (ietf-drums-remove-whitespace
 204                  (ietf-drums-remove-comments
 205                   (buffer-substring
 206                    (1+ (point))
 207                    (progn (forward-sexp 1) (1- (point))))))))
 208          (t
 209           (message "Unknown symbol: %c" c)
 210           (forward-char 1))))
 211       ;; If we found no display-name, then we look for comments.
 212       (if display-name
 213           (setq display-string
 214                 (mapconcat 'identity (reverse display-name) " "))
 215         (setq display-string (ietf-drums-get-comment string)))
 216       (if (not mailbox)
 217           (when (string-match "@" display-string)
 218             (cons
 219              (mapconcat 'identity (nreverse display-name) "")
 220              (ietf-drums-get-comment string)))
 221         (cons mailbox display-string)))))
 222
 223 (defun ietf-drums-parse-addresses (string &optional rawp)
 224   "Parse STRING and return a list of MAILBOX / DISPLAY-NAME pairs.
 225 If RAWP, don't actually parse the addresses, but instead return
 226 a list of address strings."
 227   (if (null string)
 228       nil
 229     (with-temp-buffer
 230       (ietf-drums-init string)
 231       (let ((beg (point))
 232             pairs c address)
 233         (while (not (eobp))
 234           (setq c (char-after))
 235           (cond
 236            ((memq c '(?\" ?< ?\())
 237             (condition-case nil
 238                 (forward-sexp 1)
 239               (error
 240                (skip-chars-forward "^,"))))
 241            ((eq c ?,)
 242             (setq address
 243                   (if rawp
 244                       (buffer-substring beg (point))
 245                     (condition-case nil
 246                         (ietf-drums-parse-address
 247                          (buffer-substring beg (point)))
 248                       (error nil))))
 249             (if address (push address pairs))
 250             (forward-char 1)
 251             (setq beg (point)))
 252            (t
 253             (forward-char 1))))
 254         (setq address
 255               (if rawp
 256                   (buffer-substring beg (point))
 257                 (condition-case nil
 258                     (ietf-drums-parse-address
 259                      (buffer-substring beg (point)))
 260                   (error nil))))
 261         (if address (push address pairs))
 262         (nreverse pairs)))))
 263
 264 (defun ietf-drums-unfold-fws ()
 265   "Unfold folding white space in the current buffer."
 266   (goto-char (point-min))
 267   (while (re-search-forward ietf-drums-fws-regexp nil t)
 268     (replace-match " " t t))
 269   (goto-char (point-min)))
 270
 271 (defun ietf-drums-parse-date (string)
 272   "Return an Emacs time spec from STRING."
 273   (apply 'encode-time (parse-time-string string)))
 274
 275 (defun ietf-drums-narrow-to-header ()
 276   "Narrow to the header section in the current buffer."
 277   (narrow-to-region
 278    (goto-char (point-min))
 279    (if (re-search-forward "^\r?$" nil 1)
 280        (match-beginning 0)
 281      (point-max)))
 282   (goto-char (point-min)))
 283
 284 (defun ietf-drums-quote-string (string)
 285   "Quote string if it needs quoting to be displayed in a header."
 286   (if (string-match (concat "[^" ietf-drums-atext-token "]") string)
 287       (concat "\"" string "\"")
 288     string))
 289
 290 (defun ietf-drums-make-address (name address)
 291   (if name
 292       (concat (ietf-drums-quote-string name) " <" address ">")
 293     address))
 294
 295 (provide 'ietf-drums)
 296
 297 ;;; ietf-drums.el ends here