lisp/vc-git.el

   1 ;;; vc-git.el --- VC backend for the git version control system
   2
   3 ;; Copyright (C) 2006, 2007, 2008 Free Software Foundation, Inc.
   4
   5 ;; Author: Alexandre Julliard <julliard@winehq.org>
   6 ;; Keywords: tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This file contains a VC backend for the git version control
  26 ;; system.
  27 ;;
  28
  29 ;;; Installation:
  30
  31 ;; To install: put this file on the load-path and add Git to the list
  32 ;; of supported backends in `vc-handled-backends'; the following line,
  33 ;; placed in your ~/.emacs, will accomplish this:
  34 ;;
  35 ;;     (add-to-list 'vc-handled-backends 'Git)
  36
  37 ;;; Todo:
  38 ;;  - check if more functions could use vc-git-command instead
  39 ;;     of start-process.
  40 ;;  - changelog generation
  41
  42 ;; Implement the rest of the vc interface. See the comment at the
  43 ;; beginning of vc.el. The current status is:
  44 ;; ("??" means: "figure out what to do about it")
  45 ;;
  46 ;; FUNCTION NAME                        STATUS
  47 ;; BACKEND PROPERTIES
  48 ;; * revision-granularity                      OK
  49 ;; STATE-QUERYING FUNCTIONS
  50 ;; * registered (file)                     OK
  51 ;; * state (file)                                  OK
  52 ;; - state-heuristic (file)                        NOT NEEDED
  53 ;; * working-revision (file)               OK
  54 ;; - latest-on-branch-p (file)             NOT NEEDED
  55 ;; * checkout-model (files)                OK
  56 ;; - workfile-unchanged-p (file)                   OK
  57 ;; - mode-line-string (file)                       OK
  58 ;; STATE-CHANGING FUNCTIONS
  59 ;; * create-repo ()                        OK
  60 ;; * register (files &optional rev comment)    OK
  61 ;; - init-revision (file)                          NOT NEEDED
  62 ;; - responsible-p (file)                          OK
  63 ;; - could-register (file)                         NOT NEEDED, DEFAULT IS GOOD
  64 ;; - receive-file (file rev)                       NOT NEEDED
  65 ;; - unregister (file)                     OK
  66 ;; * checkin (files rev comment)                   OK
  67 ;; * find-revision (file rev buffer)               OK
  68 ;; * checkout (file &optional editable rev)        OK
  69 ;; * revert (file &optional contents-done)         OK
  70 ;; - rollback (files)                      COULD BE SUPPORTED
  71 ;; - merge (file rev1 rev2)                   It would be possible to merge
  72 ;;                                          changes into a single file, but when
  73 ;;                                          committing they wouldn't
  74 ;;                                          be identified as a merge
  75 ;;                                          by git, so it's probably
  76 ;;                                          not a good idea.
  77 ;; - merge-news (file)                     see `merge'
  78 ;; - steal-lock (file &optional revision)          NOT NEEDED
  79 ;; HISTORY FUNCTIONS
  80 ;; * print-log (files &optional buffer)            OK
  81 ;; - log-view-mode ()                              OK
  82 ;; - show-log-entry (revision)                     OK
  83 ;; - comment-history (file)                        ??
  84 ;; - update-changelog (files)                      COULD BE SUPPORTED
  85 ;; * diff (file &optional rev1 rev2 buffer)                OK
  86 ;; - revision-completion-table (files)             OK
  87 ;; - annotate-command (file buf &optional rev)     OK
  88 ;; - annotate-time ()                              OK
  89 ;; - annotate-current-time ()                      NOT NEEDED
  90 ;; - annotate-extract-revision-at-line ()                  OK
  91 ;; TAG SYSTEM
  92 ;; - create-tag (dir name branchp)         OK
  93 ;; - retrieve-tag (dir name update)        OK, needs to update buffers
  94 ;; MISCELLANEOUS
  95 ;; - make-version-backups-p (file)         NOT NEEDED
  96 ;; - repository-hostname (dirname)         NOT NEEDED
  97 ;; - previous-revision (file rev)                  OK
  98 ;; - next-revision (file rev)              OK
  99 ;; - check-headers ()                      COULD BE SUPPORTED
 100 ;; - clear-headers ()                      NOT NEEDED
 101 ;; - delete-file (file)                    OK
 102 ;; - rename-file (old new)                 OK
 103 ;; - find-file-hook ()                     NOT NEEDED
 104 ;; - find-file-not-found-hook ()                NOT NEEDED
 105
 106 (eval-when-compile
 107   (require 'cl)
 108   (require 'vc)
 109   (require 'vc-dir)
 110   (require 'grep))
 111
 112 (defcustom vc-git-diff-switches t
 113   "String or list of strings specifying switches for Git diff under VC.
 114 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
 115   :type '(choice (const :tag "Unspecified" nil)
 116                  (const :tag "None" t)
 117                  (string :tag "Argument String")
 118                  (repeat :tag "Argument List" :value ("") string))
 119   :version "23.1"
 120   :group 'vc)
 121
 122 (defvar git-commits-coding-system 'utf-8
 123   "Default coding system for git commits.")
 124
 125 ;;; BACKEND PROPERTIES
 126
 127 (defun vc-git-revision-granularity () 'repository)
 128 (defun vc-git-checkout-model (files) 'implicit)
 129
 130 ;;; STATE-QUERYING FUNCTIONS
 131
 132 ;;;###autoload (defun vc-git-registered (file)
 133 ;;;###autoload   "Return non-nil if FILE is registered with git."
 134 ;;;###autoload   (if (vc-find-root file ".git")       ; short cut
 135 ;;;###autoload       (progn
 136 ;;;###autoload         (load "vc-git")
 137 ;;;###autoload         (vc-git-registered file))))
 138
 139 (defun vc-git-registered (file)
 140   "Check whether FILE is registered with git."
 141   (when (vc-git-root file)
 142     (with-temp-buffer
 143       (let* ((dir (file-name-directory file))
 144              (name (file-relative-name file dir))
 145              (str (ignore-errors
 146                     (when dir (cd dir))
 147                     (vc-git--out-ok "ls-files" "-c" "-z" "--" name)
 148                     ;; if result is empty, use ls-tree to check for deleted file
 149                     (when (eq (point-min) (point-max))
 150                       (vc-git--out-ok "ls-tree" "--name-only" "-z" "HEAD" "--" name))
 151                     (buffer-string))))
 152         (and str
 153              (> (length str) (length name))
 154              (string= (substring str 0 (1+ (length name)))
 155                       (concat name "\0")))))))
 156
 157 (defun vc-git--state-code (code)
 158   "Convert from a string to a added/deleted/modified state."
 159   (case (string-to-char code)
 160     (?M 'edited)
 161     (?A 'added)
 162     (?D 'removed)
 163     (?U 'edited)     ;; FIXME
 164     (?T 'edited)))   ;; FIXME
 165
 166 (defun vc-git-state (file)
 167   "Git-specific version of `vc-state'."
 168   ;; FIXME: This can't set 'ignored yet
 169   (if (not (vc-git-registered file))
 170       'unregistered
 171     (vc-git--call nil "add" "--refresh" "--" (file-relative-name file))
 172     (let ((diff (vc-git--run-command-string file "diff-index" "-z" "HEAD" "--")))
 173       (if (and diff (string-match ":[0-7]\\{6\\} [0-7]\\{6\\} [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} \\([ADMUT]\\)\0[^\0]+\0"
 174                                   diff))
 175           (vc-git--state-code (match-string 1 diff))
 176         (if (vc-git--empty-db-p) 'added 'up-to-date)))))
 177
 178 (defun vc-git-working-revision (file)
 179   "Git-specific version of `vc-working-revision'."
 180   (let ((str (with-output-to-string
 181                (with-current-buffer standard-output
 182                  (vc-git--out-ok "symbolic-ref" "HEAD")))))
 183     (if (string-match "^\\(refs/heads/\\)?\\(.+\\)$" str)
 184         (match-string 2 str)
 185       str)))
 186
 187 (defun vc-git-workfile-unchanged-p (file)
 188   (eq 'up-to-date (vc-git-state file)))
 189
 190 (defun vc-git-mode-line-string (file)
 191   "Return string for placement into the modeline for FILE."
 192   (let* ((branch (vc-git-working-revision file))
 193          (def-ml (vc-default-mode-line-string 'Git file))
 194          (help-echo (get-text-property 0 'help-echo def-ml)))
 195     (if (zerop (length branch))
 196         (propertize
 197          (concat def-ml "!")
 198          'help-echo (concat help-echo "\nNo current branch (detached HEAD)"))
 199       (propertize def-ml
 200                   'help-echo (concat help-echo "\nCurrent branch: " branch)))))
 201
 202 (defstruct (vc-git-extra-fileinfo
 203             (:copier nil)
 204             (:constructor vc-git-create-extra-fileinfo (old-perm new-perm &optional rename-state orig-name))
 205             (:conc-name vc-git-extra-fileinfo->))
 206   old-perm new-perm   ;; permission flags
 207   rename-state        ;; rename or copy state
 208   orig-name)          ;; original name for renames or copies
 209
 210 (defun vc-git-escape-file-name (name)
 211   "Escape a file name if necessary."
 212   (if (string-match "[\n\t\"\\]" name)
 213       (concat "\""
 214               (mapconcat (lambda (c)
 215                    (case c
 216                      (?\n "\\n")
 217                      (?\t "\\t")
 218                      (?\\ "\\\\")
 219                      (?\" "\\\"")
 220                      (t (char-to-string c))))
 221                  name "")
 222               "\"")
 223     name))
 224
 225 (defun vc-git-file-type-as-string (old-perm new-perm)
 226   "Return a string describing the file type based on its permissions."
 227   (let* ((old-type (lsh (or old-perm 0) -9))
 228          (new-type (lsh (or new-perm 0) -9))
 229          (str (case new-type
 230                 (?\100  ;; file
 231                  (case old-type
 232                    (?\100 nil)
 233                    (?\120 "   (type change symlink -> file)")
 234                    (?\160 "   (type change subproject -> file)")))
 235                  (?\120  ;; symlink
 236                   (case old-type
 237                     (?\100 "   (type change file -> symlink)")
 238                     (?\160 "   (type change subproject -> symlink)")
 239                     (t "   (symlink)")))
 240                   (?\160  ;; subproject
 241                    (case old-type
 242                      (?\100 "   (type change file -> subproject)")
 243                      (?\120 "   (type change symlink -> subproject)")
 244                      (t "   (subproject)")))
 245                   (?\110 nil)  ;; directory (internal, not a real git state)
 246                   (?\000  ;; deleted or unknown
 247                    (case old-type
 248                      (?\120 "   (symlink)")
 249                      (?\160 "   (subproject)")))
 250                   (t (format "   (unknown type %o)" new-type)))))
 251     (cond (str (propertize str 'face 'font-lock-comment-face))
 252           ((eq new-type ?\110) "/")
 253           (t ""))))
 254
 255 (defun vc-git-rename-as-string (state extra)
 256   "Return a string describing the copy or rename associated with INFO, or an empty string if none."
 257   (let ((rename-state (when extra
 258                         (vc-git-extra-fileinfo->rename-state extra))))
 259     (if rename-state
 260         (propertize
 261          (concat "   ("
 262                  (if (eq rename-state 'copy) "copied from "
 263                    (if (eq state 'added) "renamed from "
 264                      "renamed to "))
 265                  (vc-git-escape-file-name (vc-git-extra-fileinfo->orig-name extra))
 266                  ")") 'face 'font-lock-comment-face)
 267       "")))
 268
 269 (defun vc-git-permissions-as-string (old-perm new-perm)
 270   "Format a permission change as string."
 271   (propertize
 272    (if (or (not old-perm)
 273            (not new-perm)
 274            (eq 0 (logand ?\111 (logxor old-perm new-perm))))
 275        "  "
 276      (if (eq 0 (logand ?\111 old-perm)) "+x" "-x"))
 277   'face 'font-lock-type-face))
 278
 279 (defun vc-git-dir-printer (info)
 280   "Pretty-printer for the vc-dir-fileinfo structure."
 281   (let* ((isdir (vc-dir-fileinfo->directory info))
 282          (state (if isdir "" (vc-dir-fileinfo->state info)))
 283          (extra (vc-dir-fileinfo->extra info))
 284          (old-perm (when extra (vc-git-extra-fileinfo->old-perm extra)))
 285          (new-perm (when extra (vc-git-extra-fileinfo->new-perm extra))))
 286     (insert
 287      "  "
 288      (propertize (format "%c" (if (vc-dir-fileinfo->marked info) ?* ? ))
 289                  'face 'font-lock-type-face)
 290      "  "
 291      (propertize
 292       (format "%-12s" state)
 293       'face (cond ((eq state 'up-to-date) 'font-lock-builtin-face)
 294                   ((eq state 'missing) 'font-lock-warning-face)
 295                   (t 'font-lock-variable-name-face))
 296       'mouse-face 'highlight)
 297      "  " (vc-git-permissions-as-string old-perm new-perm)
 298      "    "
 299      (propertize (vc-git-escape-file-name (vc-dir-fileinfo->name info))
 300                  'face (if isdir 'font-lock-comment-delimiter-face 'font-lock-function-name-face)
 301                  'help-echo
 302                  (if isdir
 303                      "Directory\nVC operations can be applied to it\nmouse-3: Pop-up menu"
 304                    "File\nmouse-3: Pop-up menu")
 305                  'mouse-face 'highlight)
 306      (vc-git-file-type-as-string old-perm new-perm)
 307      (vc-git-rename-as-string state extra))))
 308
 309 (defun vc-git-after-dir-status-stage (stage files update-function)
 310   "Process sentinel for the various dir-status stages."
 311   (let (remaining next-stage result)
 312     (goto-char (point-min))
 313     (case stage
 314       ('update-index
 315        (setq next-stage (if (vc-git--empty-db-p) 'ls-files-added
 316                           (if files 'ls-files-up-to-date 'diff-index))))
 317       ('ls-files-added
 318        (setq next-stage 'ls-files-unknown)
 319        (while (re-search-forward "\\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} 0\t\\([^\0]+\\)\0" nil t)
 320          (let ((new-perm (string-to-number (match-string 1) 8))
 321                (name (match-string 2)))
 322            (push (list name 'added (vc-git-create-extra-fileinfo 0 new-perm)) result))))
 323       ('ls-files-up-to-date
 324        (setq next-stage 'diff-index)
 325        (while (re-search-forward "\\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} 0\t\\([^\0]+\\)\0" nil t)
 326          (let ((perm (string-to-number (match-string 1) 8))
 327                (name (match-string 2)))
 328            (push (list name 'up-to-date (vc-git-create-extra-fileinfo perm perm)) result))))
 329       ('ls-files-unknown
 330        (when files (setq next-stage 'ls-files-ignored))
 331        (while (re-search-forward "\\([^\0]*?\\)\0" nil t 1)
 332          (push (list (match-string 1) 'unregistered (vc-git-create-extra-fileinfo 0 0)) result)))
 333       ('ls-files-ignored
 334        (while (re-search-forward "\\([^\0]*?\\)\0" nil t 1)
 335          (push (list (match-string 1) 'ignored (vc-git-create-extra-fileinfo 0 0)) result)))
 336       ('diff-index
 337        (setq next-stage 'ls-files-unknown)
 338        (while (re-search-forward
 339                ":\\([0-7]\\{6\\}\\) \\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} \\(\\([ADMUT]\\)\0\\([^\0]+\\)\\|\\([CR]\\)[0-9]*\0\\([^\0]+\\)\0\\([^\0]+\\)\\)\0"
 340                nil t 1)
 341          (let ((old-perm (string-to-number (match-string 1) 8))
 342                (new-perm (string-to-number (match-string 2) 8))
 343                (state (or (match-string 4) (match-string 6)))
 344                (name (or (match-string 5) (match-string 7)))
 345                (new-name (match-string 8)))
 346            (if new-name  ; copy or rename
 347                (if (eq ?C (string-to-char state))
 348                    (push (list new-name 'added (vc-git-create-extra-fileinfo old-perm new-perm 'copy name)) result)
 349                  (push (list name 'removed (vc-git-create-extra-fileinfo 0 0 'rename new-name)) result)
 350                  (push (list new-name 'added (vc-git-create-extra-fileinfo old-perm new-perm 'rename name)) result))
 351              (push (list name (vc-git--state-code state) (vc-git-create-extra-fileinfo old-perm new-perm)) result))))))
 352     (when result
 353       (setq result (nreverse result))
 354       (when files
 355         (dolist (entry result) (setq files (delete (car entry) files)))
 356         (unless files (setq next-stage nil))))
 357     (when (or result (not next-stage)) (funcall update-function result next-stage))
 358     (when next-stage (vc-git-dir-status-goto-stage next-stage files update-function))))
 359
 360 (defun vc-git-dir-status-goto-stage (stage files update-function)
 361   (erase-buffer)
 362   (case stage
 363     ('update-index
 364      (if files
 365          (vc-git-command (current-buffer) 'async files "add" "--refresh" "--")
 366        (vc-git-command (current-buffer) 'async nil "update-index" "--refresh")))
 367     ('ls-files-added
 368      (vc-git-command (current-buffer) 'async files "ls-files" "-z" "-c" "-s" "--"))
 369     ('ls-files-up-to-date
 370      (vc-git-command (current-buffer) 'async files "ls-files" "-z" "-c" "-s" "--"))
 371     ('ls-files-unknown
 372      (vc-git-command (current-buffer) 'async files "ls-files" "-z" "-o"
 373                      "--directory" "--no-empty-directory" "--exclude-standard" "--"))
 374     ('ls-files-ignored
 375      (vc-git-command (current-buffer) 'async files "ls-files" "-z" "-o" "-i"
 376                      "--directory" "--no-empty-directory" "--exclude-standard" "--"))
 377     ('diff-index
 378      (vc-git-command (current-buffer) 'async files "diff-index" "-z" "-M" "HEAD" "--")))
 379   (vc-exec-after
 380    `(vc-git-after-dir-status-stage (quote ,stage) (quote ,files) (quote ,update-function))))
 381
 382 (defun vc-git-dir-status (dir update-function)
 383   "Return a list of (FILE STATE EXTRA) entries for DIR."
 384   ;; Further things that would have to be fixed later:
 385   ;; - how to handle unregistered directories
 386   ;; - how to support vc-dir on a subdir of the project tree
 387   (vc-git-dir-status-goto-stage 'update-index nil update-function))
 388
 389 (defun vc-git-dir-status-files (dir files default-state update-function)
 390   "Return a list of (FILE STATE EXTRA) entries for FILES in DIR."
 391   (vc-git-dir-status-goto-stage 'update-index files update-function))
 392
 393 (defun vc-git-dir-extra-headers (dir)
 394   (let ((str (with-output-to-string
 395                (with-current-buffer standard-output
 396                  (vc-git--out-ok "symbolic-ref" "HEAD")))))
 397     (concat
 398      (propertize "Branch     : " 'face 'font-lock-type-face)
 399      (propertize
 400       (if (string-match "^\\(refs/heads/\\)?\\(.+\\)$" str)
 401           (match-string 2 str)
 402         "not (detached HEAD)")
 403        'face 'font-lock-variable-name-face))))
 404
 405 ;;; STATE-CHANGING FUNCTIONS
 406
 407 (defun vc-git-create-repo ()
 408   "Create a new Git repository."
 409   (vc-git-command nil 0 nil "init"))
 410
 411 (defun vc-git-register (files &optional rev comment)
 412   "Register FILE into the git version-control system."
 413   (vc-git-command nil 0 files "update-index" "--add" "--"))
 414
 415 (defalias 'vc-git-responsible-p 'vc-git-root)
 416
 417 (defun vc-git-unregister (file)
 418   (vc-git-command nil 0 file "rm" "-f" "--cached" "--"))
 419
 420
 421 (defun vc-git-checkin (files rev comment)
 422   (let ((coding-system-for-write git-commits-coding-system))
 423     (vc-git-command nil 0 files "commit" "-m" comment "--only" "--")))
 424
 425 (defun vc-git-find-revision (file rev buffer)
 426   (let ((coding-system-for-read 'binary)
 427         (coding-system-for-write 'binary)
 428         (fullname (substring
 429                    (vc-git--run-command-string
 430                     file "ls-files" "-z" "--full-name" "--")
 431                    0 -1)))
 432     (vc-git-command
 433      buffer 0
 434      (concat (if rev rev "HEAD") ":" fullname) "cat-file" "blob")))
 435
 436 (defun vc-git-checkout (file &optional editable rev)
 437   (vc-git-command nil 0 file "checkout" (or rev "HEAD")))
 438
 439 (defun vc-git-revert (file &optional contents-done)
 440   "Revert FILE to the version stored in the git repository."
 441   (if contents-done
 442       (vc-git-command nil 0 file "update-index" "--")
 443     (vc-git-command nil 0 file "checkout" "HEAD")))
 444
 445 ;;; HISTORY FUNCTIONS
 446
 447 (defun vc-git-print-log (files &optional buffer)
 448   "Get change log associated with FILES."
 449   (let ((coding-system-for-read git-commits-coding-system)
 450         ;; Support both the old print-log interface that passes a
 451         ;; single file, and the new one that passes a file list.
 452         (flist (if (listp files) files (list files))))
 453     ;; `vc-do-command' creates the buffer, but we need it before running
 454     ;; the command.
 455     (vc-setup-buffer buffer)
 456     ;; If the buffer exists from a previous invocation it might be
 457     ;; read-only.
 458     (let ((inhibit-read-only t))
 459       (with-current-buffer
 460           buffer
 461         (vc-git-command buffer 'async files
 462                         "rev-list" "--pretty" "HEAD" "--")))))
 463
 464 (defvar log-view-message-re)
 465 (defvar log-view-file-re)
 466 (defvar log-view-font-lock-keywords)
 467 (defvar log-view-per-file-logs)
 468
 469 (define-derived-mode vc-git-log-view-mode log-view-mode "Git-Log-View"
 470   (require 'add-log) ;; we need the faces add-log
 471   ;; Don't have file markers, so use impossible regexp.
 472   (set (make-local-variable 'log-view-file-re) "\\`a\\`")
 473   (set (make-local-variable 'log-view-per-file-logs) nil)
 474   (set (make-local-variable 'log-view-message-re)
 475        "^commit *\\([0-9a-z]+\\)")
 476   (set (make-local-variable 'log-view-font-lock-keywords)
 477        (append
 478         `((,log-view-message-re  (1 'change-log-acknowledgement)))
 479         ;; Handle the case:
 480         ;; user: foo@bar
 481         '(("^Author:[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 482            (1 'change-log-email))
 483           ;; Handle the case:
 484           ;; user: FirstName LastName <foo@bar>
 485           ("^Author:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 486            (1 'change-log-name)
 487            (2 'change-log-email))
 488           ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 489            (1 'change-log-name))
 490           ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 491            (1 'change-log-name)
 492            (2 'change-log-email))
 493           ("^Merge: \\([0-9a-z]+\\) \\([0-9a-z]+\\)"
 494            (1 'change-log-acknowledgement)
 495            (2 'change-log-acknowledgement))
 496           ("^Date:   \\(.+\\)" (1 'change-log-date))
 497           ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message))))))
 498
 499 (defun vc-git-show-log-entry (revision)
 500   "Move to the log entry for REVISION.
 501 REVISION may have the form BRANCH, BRANCH~N,
 502 or BRANCH^ (where \"^\" can be repeated)."
 503   (goto-char (point-min))
 504   (when revision
 505     (search-forward (format "\ncommit %s" revision) nil t
 506                     (cond ((string-match "~\\([0-9]\\)$" revision)
 507                            (1+ (string-to-number (match-string 1 revision))))
 508                           ((string-match "\\^+$" revision)
 509                            (1+ (length (match-string 0 revision))))
 510                           (t nil))))
 511   (beginning-of-line))
 512
 513 (defun vc-git-diff (files &optional rev1 rev2 buffer)
 514   "Get a difference report using Git between two revisions of FILES."
 515   (apply #'vc-git-command (or buffer "*vc-diff*") 1 files
 516          (if (and rev1 rev2) "diff-tree" "diff-index")
 517          "--exit-code"
 518          (append (vc-switches 'git 'diff)
 519                  (list "-p" (or rev1 "HEAD") rev2 "--"))))
 520
 521 (defun vc-git-revision-table (files)
 522   ;; What about `files'?!?  --Stef
 523   (let ((table (list "HEAD")))
 524     (with-temp-buffer
 525       (vc-git-command t nil nil "for-each-ref" "--format=%(refname)")
 526       (goto-char (point-min))
 527       (while (re-search-forward "^refs/\\(heads\\|tags\\)/\\(.*\\)$" nil t)
 528         (push (match-string 2) table)))
 529     table))
 530
 531 (defun vc-git-revision-completion-table (files)
 532   (lexical-let ((files files)
 533                 table)
 534     (setq table (lazy-completion-table
 535                  table (lambda () (vc-git-revision-table files))))
 536     table))
 537
 538 (defun vc-git-annotate-command (file buf &optional rev)
 539   (let ((name (file-relative-name file)))
 540     (vc-git-command buf 0 name "blame" rev)))
 541
 542 (declare-function vc-annotate-convert-time "vc-annotate" (time))
 543
 544 (defun vc-git-annotate-time ()
 545   (and (re-search-forward "[0-9a-f]+[^()]+(.* \\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\) \\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\) \\([-+0-9]+\\) +[0-9]+) " nil t)
 546        (vc-annotate-convert-time
 547         (apply #'encode-time (mapcar (lambda (match)
 548                                        (string-to-number (match-string match)))
 549                                      '(6 5 4 3 2 1 7))))))
 550
 551 (defun vc-git-annotate-extract-revision-at-line ()
 552   (save-excursion
 553     (move-beginning-of-line 1)
 554     (and (looking-at "[0-9a-f^][0-9a-f]+")
 555          (buffer-substring-no-properties (match-beginning 0) (match-end 0)))))
 556
 557 ;;; TAG SYSTEM
 558
 559 (defun vc-git-create-tag (dir name branchp)
 560   (let ((default-directory dir))
 561     (and (vc-git-command nil 0 nil "update-index" "--refresh")
 562          (if branchp
 563              (vc-git-command nil 0 nil "checkout" "-b" name)
 564            (vc-git-command nil 0 nil "tag" name)))))
 565
 566 (defun vc-git-retrieve-tag (dir name update)
 567   (let ((default-directory dir))
 568     (vc-git-command nil 0 nil "checkout" name)
 569     ;; FIXME: update buffers if `update' is true
 570     ))
 571
 572
 573 ;;; MISCELLANEOUS
 574
 575 (defun vc-git-previous-revision (file rev)
 576   "Git-specific version of `vc-previous-revision'."
 577   (if file
 578       (let ((default-directory (file-name-directory (expand-file-name file)))
 579             (file (file-name-nondirectory file)))
 580         (vc-git-symbolic-commit
 581          (with-temp-buffer
 582            (and
 583             (vc-git--out-ok "rev-list" "-2" rev "--" file)
 584             (goto-char (point-max))
 585             (bolp)
 586             (zerop (forward-line -1))
 587             (not (bobp))
 588             (buffer-substring-no-properties
 589              (point)
 590              (1- (point-max)))))))
 591     (with-temp-buffer
 592       (and
 593        (vc-git--out-ok "rev-parse" (concat rev "^"))
 594        (buffer-substring-no-properties (point-min) (+ (point-min) 40))))))
 595
 596 (defun vc-git-next-revision (file rev)
 597   "Git-specific version of `vc-next-revision'."
 598   (let* ((default-directory (file-name-directory
 599                              (expand-file-name file)))
 600          (file (file-name-nondirectory file))
 601          (current-rev
 602           (with-temp-buffer
 603             (and
 604              (vc-git--out-ok "rev-list" "-1" rev "--" file)
 605              (goto-char (point-max))
 606              (bolp)
 607              (zerop (forward-line -1))
 608              (bobp)
 609              (buffer-substring-no-properties
 610               (point)
 611               (1- (point-max)))))))
 612     (and current-rev
 613          (vc-git-symbolic-commit
 614           (with-temp-buffer
 615             (and
 616              (vc-git--out-ok "rev-list" "HEAD" "--" file)
 617              (goto-char (point-min))
 618              (search-forward current-rev nil t)
 619              (zerop (forward-line -1))
 620              (buffer-substring-no-properties
 621               (point)
 622               (progn (forward-line 1) (1- (point))))))))))
 623
 624 (defun vc-git-delete-file (file)
 625   (vc-git-command nil 0 file "rm" "-f" "--"))
 626
 627 (defun vc-git-rename-file (old new)
 628   (vc-git-command nil 0 (list old new) "mv" "-f" "--"))
 629
 630 (defvar vc-git-extra-menu-map
 631   (let ((map (make-sparse-keymap)))
 632     (define-key map [git-grep]
 633       '(menu-item "Git grep..." vc-git-grep
 634                   :help "Run the `git grep' command"))
 635     map))
 636
 637 (defun vc-git-extra-menu () vc-git-extra-menu-map)
 638
 639 (defun vc-git-extra-status-menu () vc-git-extra-menu-map)
 640
 641 ;; Derived from `lgrep'.
 642 (defun vc-git-grep (regexp &optional files dir)
 643   "Run git grep, searching for REGEXP in FILES in directory DIR.
 644 The search is limited to file names matching shell pattern FILES.
 645 FILES may use abbreviations defined in `grep-files-aliases', e.g.
 646 entering `ch' is equivalent to `*.[ch]'.
 647
 648 With \\[universal-argument] prefix, you can edit the constructed shell command line
 649 before it is executed.
 650 With two \\[universal-argument] prefixes, directly edit and run `grep-command'.
 651
 652 Collect output in a buffer.  While git grep runs asynchronously, you
 653 can use \\[next-error] (M-x next-error), or \\<grep-mode-map>\\[compile-goto-error] \
 654 in the grep output buffer,
 655 to go to the lines where grep found matches.
 656
 657 This command shares argument histories with \\[rgrep] and \\[grep]."
 658   (interactive
 659    (progn
 660      (grep-compute-defaults)
 661      (cond
 662       ((equal current-prefix-arg '(16))
 663        (list (read-from-minibuffer "Run: " "git grep"
 664                                    nil nil 'grep-history)
 665              nil))
 666       (t (let* ((regexp (grep-read-regexp))
 667                 (files (grep-read-files regexp))
 668                 (dir (read-directory-name "In directory: "
 669                                           nil default-directory t)))
 670            (list regexp files dir))))))
 671   (require 'grep)
 672   (when (and (stringp regexp) (> (length regexp) 0))
 673     (let ((command regexp))
 674       (if (null files)
 675           (if (string= command "git grep")
 676               (setq command nil))
 677         (setq dir (file-name-as-directory (expand-file-name dir)))
 678         (setq command
 679               (grep-expand-template "git grep -n -e <R> -- <F>" regexp files))
 680         (when command
 681           (if (equal current-prefix-arg '(4))
 682               (setq command
 683                     (read-from-minibuffer "Confirm: "
 684                                           command nil nil 'grep-history))
 685             (add-to-history 'grep-history command))))
 686       (when command
 687         (let ((default-directory dir)
 688               (compilation-environment '("PAGER=")))
 689           ;; Setting process-setup-function makes exit-message-function work
 690           ;; even when async processes aren't supported.
 691           (compilation-start command 'grep-mode))
 692         (if (eq next-error-last-buffer (current-buffer))
 693             (setq default-directory dir))))))
 694 \f
 695 ;;; Internal commands
 696
 697 (defun vc-git-root (file)
 698   (vc-find-root file ".git"))
 699
 700 (defun vc-git-command (buffer okstatus file-or-list &rest flags)
 701   "A wrapper around `vc-do-command' for use in vc-git.el.
 702 The difference to vc-do-command is that this function always invokes `git'."
 703   (apply 'vc-do-command (or buffer "*vc*") okstatus "git" file-or-list flags))
 704
 705 (defun vc-git--empty-db-p ()
 706   "Check if the git db is empty (no commit done yet)."
 707   (not (eq 0 (vc-git--call nil "rev-parse" "--verify" "HEAD"))))
 708
 709 (defun vc-git--call (buffer command &rest args)
 710   ;; We don't need to care the arguments.  If there is a file name, it
 711   ;; is always a relative one.  This works also for remote
 712   ;; directories.
 713   (apply 'process-file "git" nil buffer nil command args))
 714
 715 (defun vc-git--out-ok (command &rest args)
 716   (zerop (apply 'vc-git--call '(t nil) command args)))
 717
 718 (defun vc-git--run-command-string (file &rest args)
 719   "Run a git command on FILE and return its output as string."
 720   (let* ((ok t)
 721          (str (with-output-to-string
 722                 (with-current-buffer standard-output
 723                   (unless (apply 'vc-git--out-ok
 724                                  (append args (list (file-relative-name
 725                                                      file))))
 726                     (setq ok nil))))))
 727     (and ok str)))
 728
 729 (defun vc-git-symbolic-commit (commit)
 730   "Translate COMMIT string into symbolic form.
 731 Returns nil if not possible."
 732   (and commit
 733        (with-temp-buffer
 734          (and
 735           (vc-git--out-ok "name-rev" "--name-only" "--tags" commit)
 736           (goto-char (point-min))
 737           (= (forward-line 2) 1)
 738           (bolp)
 739           (buffer-substring-no-properties (point-min) (1- (point-max)))))))
 740
 741 (provide 'vc-git)
 742
 743 ;; arch-tag: bd10664a-0e5b-48f5-a877-6c17b135be12
 744 ;;; vc-git.el ends here