lisp/vc-cvs.el

   1 ;;; vc-cvs.el --- non-resident support for CVS version-control
   2
   3 ;; Copyright (C) 1995, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005,
   4 ;;   2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author:      FSF (see vc.el for full credits)
   7 ;; Maintainer:  Andre Spiegel <spiegel@gnu.org>
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl) (require 'vc))
  29
  30 ;; Clear up the cache to force vc-call to check again and discover
  31 ;; new functions when we reload this file.
  32 (put 'CVS 'vc-functions nil)
  33
  34 ;;; Properties of the backend.
  35
  36 (defun vc-cvs-revision-granularity () 'file)
  37
  38 (defun vc-cvs-checkout-model (files)
  39   "CVS-specific version of `vc-checkout-model'."
  40   (if (getenv "CVSREAD")
  41       'announce
  42     (let* ((file (if (consp files) (car files) files))
  43            (attrib (file-attributes file)))
  44       (or (vc-file-getprop file 'vc-checkout-model)
  45           (vc-file-setprop
  46            file 'vc-checkout-model
  47            (if (and attrib ;; don't check further if FILE doesn't exist
  48                     ;; If the file is not writable (despite CVSREAD being
  49                     ;; undefined), this is probably because the file is being
  50                     ;; "watched" by other developers.
  51                     ;; (If vc-mistrust-permissions was t, we actually shouldn't
  52                     ;; trust this, but there is no other way to learn this from
  53                     ;; CVS at the moment (version 1.9).)
  54                     (string-match "r-..-..-." (nth 8 attrib)))
  55                'announce
  56              'implicit))))))
  57
  58 ;;;
  59 ;;; Customization options
  60 ;;;
  61
  62 (defcustom vc-cvs-global-switches nil
  63   "Global switches to pass to any CVS command."
  64   :type '(choice (const :tag "None" nil)
  65                  (string :tag "Argument String")
  66                  (repeat :tag "Argument List"
  67                          :value ("")
  68                          string))
  69   :version "22.1"
  70   :group 'vc)
  71
  72 (defcustom vc-cvs-register-switches nil
  73   "Switches for registering a file into CVS.
  74 A string or list of strings passed to the checkin program by
  75 \\[vc-register].  If nil, use the value of `vc-register-switches'.
  76 If t, use no switches."
  77   :type '(choice (const :tag "Unspecified" nil)
  78                  (const :tag "None" t)
  79                  (string :tag "Argument String")
  80                  (repeat :tag "Argument List" :value ("") string))
  81   :version "21.1"
  82   :group 'vc)
  83
  84 (defcustom vc-cvs-diff-switches nil
  85   "String or list of strings specifying switches for CVS diff under VC.
  86 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
  87   :type '(choice (const :tag "Unspecified" nil)
  88                  (const :tag "None" t)
  89                  (string :tag "Argument String")
  90                  (repeat :tag "Argument List" :value ("") string))
  91   :version "21.1"
  92   :group 'vc)
  93
  94 (defcustom vc-cvs-header (or (cdr (assoc 'CVS vc-header-alist)) '("\$Id\$"))
  95   "Header keywords to be inserted by `vc-insert-headers'."
  96   :version "21.1"
  97   :type '(repeat string)
  98   :group 'vc)
  99
 100 (defcustom vc-cvs-use-edit t
 101   "Non-nil means to use `cvs edit' to \"check out\" a file.
 102 This is only meaningful if you don't use the implicit checkout model
 103 \(i.e. if you have $CVSREAD set)."
 104   :type 'boolean
 105   :version "21.1"
 106   :group 'vc)
 107
 108 (defcustom vc-cvs-stay-local 'only-file
 109   "Non-nil means use local operations when possible for remote repositories.
 110 This avoids slow queries over the network and instead uses heuristics
 111 and past information to determine the current status of a file.
 112
 113 If value is the symbol `only-file' `vc-dir' will connect to the
 114 server, but heuristics will be used to determine the status for
 115 all other VC operations.
 116
 117 The value can also be a regular expression or list of regular
 118 expressions to match against the host name of a repository; then VC
 119 only stays local for hosts that match it.  Alternatively, the value
 120 can be a list of regular expressions where the first element is the
 121 symbol `except'; then VC always stays local except for hosts matched
 122 by these regular expressions."
 123   :type '(choice (const :tag "Always stay local" t)
 124                  (const :tag "Only for file operations" only-file)
 125                  (const :tag "Don't stay local" nil)
 126                  (list :format "\nExamine hostname and %v"
 127                        :tag "Examine hostname ..."
 128                        (set :format "%v" :inline t
 129                             (const :format "%t" :tag "don't" except))
 130                        (regexp :format " stay local,\n%t: %v"
 131                                :tag "if it matches")
 132                        (repeat :format "%v%i\n" :inline t (regexp :tag "or"))))
 133   :version "23.1"
 134   :group 'vc)
 135
 136 (defcustom vc-cvs-sticky-date-format-string "%c"
 137   "Format string for mode-line display of sticky date.
 138 Format is according to `format-time-string'.  Only used if
 139 `vc-cvs-sticky-tag-display' is t."
 140   :type '(string)
 141   :version "22.1"
 142   :group 'vc)
 143
 144 (defcustom vc-cvs-sticky-tag-display t
 145   "Specify the mode-line display of sticky tags.
 146 Value t means default display, nil means no display at all.  If the
 147 value is a function or macro, it is called with the sticky tag and
 148 its' type as parameters, in that order.  TYPE can have three different
 149 values: `symbolic-name' (TAG is a string), `revision-number' (TAG is a
 150 string) and `date' (TAG is a date as returned by `encode-time').  The
 151 return value of the function or macro will be displayed as a string.
 152
 153 Here's an example that will display the formatted date for sticky
 154 dates and the word \"Sticky\" for sticky tag names and revisions.
 155
 156   (lambda (tag type)
 157     (cond ((eq type 'date) (format-time-string
 158                               vc-cvs-sticky-date-format-string tag))
 159           ((eq type 'revision-number) \"Sticky\")
 160           ((eq type 'symbolic-name) \"Sticky\")))
 161
 162 Here's an example that will abbreviate to the first character only,
 163 any text before the first occurrence of `-' for sticky symbolic tags.
 164 If the sticky tag is a revision number, the word \"Sticky\" is
 165 displayed.  Date and time is displayed for sticky dates.
 166
 167    (lambda (tag type)
 168      (cond ((eq type 'date) (format-time-string \"%Y%m%d %H:%M\" tag))
 169            ((eq type 'revision-number) \"Sticky\")
 170            ((eq type 'symbolic-name)
 171             (condition-case nil
 172                 (progn
 173                   (string-match \"\\\\([^-]*\\\\)\\\\(.*\\\\)\" tag)
 174                   (concat (substring (match-string 1 tag) 0 1) \":\"
 175                           (substring (match-string 2 tag) 1 nil)))
 176               (error tag)))))       ; Fall-back to given tag name.
 177
 178 See also variable `vc-cvs-sticky-date-format-string'."
 179   :type '(choice boolean function)
 180   :version "22.1"
 181   :group 'vc)
 182
 183 ;;;
 184 ;;; Internal variables
 185 ;;;
 186
 187
 188 ;;;
 189 ;;; State-querying functions
 190 ;;;
 191
 192 ;;;###autoload (defun vc-cvs-registered (f)
 193 ;;;###autoload   (when (file-readable-p (expand-file-name
 194 ;;;###autoload                    "CVS/Entries" (file-name-directory f)))
 195 ;;;###autoload       (load "vc-cvs")
 196 ;;;###autoload       (vc-cvs-registered f)))
 197
 198 (defun vc-cvs-registered (file)
 199   "Check if FILE is CVS registered."
 200   (let ((dirname (or (file-name-directory file) ""))
 201         (basename (file-name-nondirectory file))
 202         ;; make sure that the file name is searched case-sensitively
 203         (case-fold-search nil))
 204     (if (file-readable-p (expand-file-name "CVS/Entries" dirname))
 205         (or (string= basename "")
 206             (with-temp-buffer
 207               (vc-cvs-get-entries dirname)
 208               (goto-char (point-min))
 209               (cond ((re-search-forward
 210                       (concat "^/" (regexp-quote basename) "/[^/]") nil t)
 211                      (beginning-of-line)
 212                      (vc-cvs-parse-entry file)
 213                      t)
 214                     (t nil))))
 215       nil)))
 216
 217 (defun vc-cvs-state (file)
 218   "CVS-specific version of `vc-state'."
 219   (if (vc-stay-local-p file)
 220       (let ((state (vc-file-getprop file 'vc-state)))
 221         ;; If we should stay local, use the heuristic but only if
 222         ;; we don't have a more precise state already available.
 223         (if (memq state '(up-to-date edited nil))
 224             (vc-cvs-state-heuristic file)
 225           state))
 226     (with-temp-buffer
 227       (cd (file-name-directory file))
 228       (vc-cvs-command t 0 file "status")
 229       (vc-cvs-parse-status t))))
 230
 231 (defun vc-cvs-state-heuristic (file)
 232   "CVS-specific state heuristic."
 233   ;; If the file has not changed since checkout, consider it `up-to-date'.
 234   ;; Otherwise consider it `edited'.
 235   (let ((checkout-time (vc-file-getprop file 'vc-checkout-time))
 236         (lastmod (nth 5 (file-attributes file))))
 237     (cond
 238      ((equal checkout-time lastmod) 'up-to-date)
 239      ((string= (vc-working-revision file) "0") 'added)
 240      ((null checkout-time) 'unregistered)
 241      (t 'edited))))
 242
 243 (defun vc-cvs-working-revision (file)
 244   "CVS-specific version of `vc-working-revision'."
 245   ;; There is no need to consult RCS headers under CVS, because we
 246   ;; get the workfile version for free when we recognize that a file
 247   ;; is registered in CVS.
 248   (vc-cvs-registered file)
 249   (vc-file-getprop file 'vc-working-revision))
 250
 251 (defun vc-cvs-mode-line-string (file)
 252   "Return string for placement into the modeline for FILE.
 253 Compared to the default implementation, this function does two things:
 254 Handle the special case of a CVS file that is added but not yet
 255 committed and support display of sticky tags."
 256   (let* ((sticky-tag (vc-file-getprop file 'vc-cvs-sticky-tag))
 257          help-echo
 258          (string
 259           (let ((def-ml (vc-default-mode-line-string 'CVS file)))
 260             (setq help-echo
 261                   (get-text-property 0 'help-echo def-ml))
 262             def-ml)))
 263     (propertize
 264      (if (zerop (length sticky-tag))
 265          string
 266        (setq help-echo (format "%s on the '%s' branch"
 267                                help-echo sticky-tag))
 268        (concat string "[" sticky-tag "]"))
 269      'help-echo help-echo)))
 270
 271
 272 ;;;
 273 ;;; State-changing functions
 274 ;;;
 275
 276 (defun vc-cvs-register (files &optional rev comment)
 277   "Register FILES into the CVS version-control system.
 278 COMMENT can be used to provide an initial description of FILES.
 279 Passes either `vc-cvs-register-switches' or `vc-register-switches'
 280 to the CVS command."
 281   ;; Register the directories if needed.
 282   (let (dirs)
 283     (dolist (file files)
 284       (and (not (vc-cvs-responsible-p file))
 285            (vc-cvs-could-register file)
 286            (push (directory-file-name (file-name-directory file)) dirs)))
 287     (if dirs (vc-cvs-register dirs)))
 288   (apply 'vc-cvs-command nil 0 files
 289          "add"
 290          (and comment (string-match "[^\t\n ]" comment)
 291               (concat "-m" comment))
 292          (vc-switches 'CVS 'register)))
 293
 294 (defun vc-cvs-responsible-p (file)
 295   "Return non-nil if CVS thinks it is responsible for FILE."
 296   (file-directory-p (expand-file-name "CVS"
 297                                       (if (file-directory-p file)
 298                                           file
 299                                         (file-name-directory file)))))
 300
 301 (defun vc-cvs-could-register (file)
 302   "Return non-nil if FILE could be registered in CVS.
 303 This is only possible if CVS is managing FILE's directory or one of
 304 its parents."
 305   (let ((dir file))
 306     (while (and (stringp dir)
 307                 (not (equal dir (setq dir (file-name-directory dir))))
 308                 dir)
 309       (setq dir (if (file-exists-p
 310                      (expand-file-name "CVS/Entries" dir))
 311                     t
 312                   (directory-file-name dir))))
 313     (eq dir t)))
 314
 315 (defun vc-cvs-checkin (files rev comment)
 316   "CVS-specific version of `vc-backend-checkin'."
 317   (unless (or (not rev) (vc-cvs-valid-revision-number-p rev))
 318     (if (not (vc-cvs-valid-symbolic-tag-name-p rev))
 319         (error "%s is not a valid symbolic tag name" rev)
 320       ;; If the input revison is a valid symbolic tag name, we create it
 321       ;; as a branch, commit and switch to it.
 322       (apply 'vc-cvs-command nil 0 files "tag" "-b" (list rev))
 323       (apply 'vc-cvs-command nil 0 files "update" "-r" (list rev))
 324       (mapc (lambda (file) (vc-file-setprop file 'vc-cvs-sticky-tag rev))
 325             files)))
 326   (let ((status (apply 'vc-cvs-command nil 1 files
 327                        "ci" (if rev (concat "-r" rev))
 328                        (concat "-m" comment)
 329                        (vc-switches 'CVS 'checkin))))
 330     (set-buffer "*vc*")
 331     (goto-char (point-min))
 332     (when (not (zerop status))
 333       ;; Check checkin problem.
 334       (cond
 335        ((re-search-forward "Up-to-date check failed" nil t)
 336         (mapc (lambda (file) (vc-file-setprop file 'vc-state 'needs-merge))
 337               files)
 338         (error "%s" (substitute-command-keys
 339                 (concat "Up-to-date check failed: "
 340                         "type \\[vc-next-action] to merge in changes"))))
 341        (t
 342         (pop-to-buffer (current-buffer))
 343         (goto-char (point-min))
 344         (shrink-window-if-larger-than-buffer)
 345         (error "Check-in failed"))))
 346     ;; Single-file commit?  Then update the revision by parsing the buffer.
 347     ;; Otherwise we can't necessarily tell what goes with what; clear
 348     ;; its properties so they have to be refetched.
 349     (if (= (length files) 1)
 350         (vc-file-setprop
 351          (car files) 'vc-working-revision
 352          (vc-parse-buffer "^\\(new\\|initial\\) revision: \\([0-9.]+\\)" 2))
 353       (mapc 'vc-file-clearprops files))
 354     ;; Anyway, forget the checkout model of the file, because we might have
 355     ;; guessed wrong when we found the file.  After commit, we can
 356     ;; tell it from the permissions of the file (see
 357     ;; vc-cvs-checkout-model).
 358     (mapc (lambda (file) (vc-file-setprop file 'vc-checkout-model nil))
 359           files)
 360
 361     ;; if this was an explicit check-in (does not include creation of
 362     ;; a branch), remove the sticky tag.
 363     (if (and rev (not (vc-cvs-valid-symbolic-tag-name-p rev)))
 364         (vc-cvs-command nil 0 files "update" "-A"))))
 365
 366 (defun vc-cvs-find-revision (file rev buffer)
 367   (apply 'vc-cvs-command
 368          buffer 0 file
 369          "-Q"                           ; suppress diagnostic output
 370          "update"
 371          (and rev (not (string= rev ""))
 372               (concat "-r" rev))
 373          "-p"
 374          (vc-switches 'CVS 'checkout)))
 375
 376 (defun vc-cvs-checkout (file &optional editable rev)
 377   "Checkout a revision of FILE into the working area.
 378 EDITABLE non-nil means that the file should be writable.
 379 REV is the revision to check out."
 380   (message "Checking out %s..." file)
 381   ;; Change buffers to get local value of vc-checkout-switches.
 382   (with-current-buffer (or (get-file-buffer file) (current-buffer))
 383     (if (and (file-exists-p file) (not rev))
 384         ;; If no revision was specified, just make the file writable
 385         ;; if necessary (using `cvs-edit' if requested).
 386         (and editable (not (eq (vc-cvs-checkout-model (list file)) 'implicit))
 387              (if vc-cvs-use-edit
 388                  (vc-cvs-command nil 0 file "edit")
 389                (set-file-modes file (logior (file-modes file) 128))
 390                (if (equal file buffer-file-name) (toggle-read-only -1))))
 391       ;; Check out a particular revision (or recreate the file).
 392       (vc-file-setprop file 'vc-working-revision nil)
 393       (apply 'vc-cvs-command nil 0 file
 394              (and editable "-w")
 395              "update"
 396              (when rev
 397                (unless (eq rev t)
 398                  ;; default for verbose checkout: clear the
 399                  ;; sticky tag so that the actual update will
 400                  ;; get the head of the trunk
 401                  (if (string= rev "")
 402                      "-A"
 403                    (concat "-r" rev))))
 404              (vc-switches 'CVS 'checkout)))
 405     (vc-mode-line file))
 406   (message "Checking out %s...done" file))
 407
 408 (defun vc-cvs-delete-file (file)
 409   (vc-cvs-command nil 0 file "remove" "-f"))
 410
 411 (defun vc-cvs-revert (file &optional contents-done)
 412   "Revert FILE to the working revision on which it was based."
 413   (vc-default-revert 'CVS file contents-done)
 414   (unless (eq (vc-cvs-checkout-model (list file)) 'implicit)
 415     (if vc-cvs-use-edit
 416         (vc-cvs-command nil 0 file "unedit")
 417       ;; Make the file read-only by switching off all w-bits
 418       (set-file-modes file (logand (file-modes file) 3950)))))
 419
 420 (defun vc-cvs-merge (file first-revision &optional second-revision)
 421   "Merge changes into current working copy of FILE.
 422 The changes are between FIRST-REVISION and SECOND-REVISION."
 423   (vc-cvs-command nil 0 file
 424                  "update" "-kk"
 425                  (concat "-j" first-revision)
 426                  (concat "-j" second-revision))
 427   (vc-file-setprop file 'vc-state 'edited)
 428   (with-current-buffer (get-buffer "*vc*")
 429     (goto-char (point-min))
 430     (if (re-search-forward "conflicts during merge" nil t)
 431         (progn
 432           (vc-file-setprop file 'vc-state 'conflict)
 433           ;; signal error
 434           1)
 435       (vc-file-setprop file 'vc-state 'edited)
 436       ;; signal success
 437       0)))
 438
 439 (defun vc-cvs-merge-news (file)
 440   "Merge in any new changes made to FILE."
 441   (message "Merging changes into %s..." file)
 442   ;; (vc-file-setprop file 'vc-working-revision nil)
 443   (vc-file-setprop file 'vc-checkout-time 0)
 444   (vc-cvs-command nil nil file "update")
 445   ;; Analyze the merge result reported by CVS, and set
 446   ;; file properties accordingly.
 447   (with-current-buffer (get-buffer "*vc*")
 448     (goto-char (point-min))
 449     ;; get new working revision
 450     (if (re-search-forward
 451          "^Merging differences between [0-9.]* and \\([0-9.]*\\) into" nil t)
 452         (vc-file-setprop file 'vc-working-revision (match-string 1))
 453       (vc-file-setprop file 'vc-working-revision nil))
 454     ;; get file status
 455     (prog1
 456         (if (eq (buffer-size) 0)
 457             0 ;; there were no news; indicate success
 458           (if (re-search-forward
 459                (concat "^\\([CMUP] \\)?"
 460                        (regexp-quote (file-name-nondirectory file))
 461                        "\\( already contains the differences between \\)?")
 462                nil t)
 463               (cond
 464                ;; Merge successful, we are in sync with repository now
 465                ((or (match-string 2)
 466                     (string= (match-string 1) "U ")
 467                     (string= (match-string 1) "P "))
 468                 (vc-file-setprop file 'vc-state 'up-to-date)
 469                 (vc-file-setprop file 'vc-checkout-time
 470                                  (nth 5 (file-attributes file)))
 471                 0);; indicate success to the caller
 472                ;; Merge successful, but our own changes are still in the file
 473                ((string= (match-string 1) "M ")
 474                 (vc-file-setprop file 'vc-state 'edited)
 475                 0);; indicate success to the caller
 476                ;; Conflicts detected!
 477                (t
 478                 (vc-file-setprop file 'vc-state 'conflict)
 479                 1);; signal the error to the caller
 480                )
 481             (pop-to-buffer "*vc*")
 482             (error "Couldn't analyze cvs update result")))
 483       (message "Merging changes into %s...done" file))))
 484
 485 (defun vc-cvs-modify-change-comment (files rev comment)
 486   "Modify the change comments for FILES on a specified REV.
 487 Will fail unless you have administrative privileges on the repo."
 488   (vc-cvs-command nil 0 files "admin" (concat "-m" rev ":" comment)))
 489
 490 ;;;
 491 ;;; History functions
 492 ;;;
 493
 494 (defun vc-cvs-print-log (files &optional buffer)
 495   "Get change logs associated with FILES."
 496   ;; It's just the catenation of the individual logs.
 497   (vc-cvs-command
 498    buffer
 499    (if (vc-stay-local-p files) 'async 0)
 500    files "log"))
 501
 502 (defun vc-cvs-comment-history (file)
 503   "Get comment history of a file."
 504   (vc-call-backend 'RCS 'comment-history file))
 505
 506 (defun vc-cvs-diff (files &optional oldvers newvers buffer)
 507   "Get a difference report using CVS between two revisions of FILE."
 508   (let* ((async (and (not vc-disable-async-diff)
 509                      (vc-stay-local-p files)))
 510          (invoke-cvs-diff-list nil)
 511          status)
 512     ;; Look through the file list and see if any files have backups
 513     ;; that can be used to do a plain "diff" instead of "cvs diff".
 514     (dolist (file files)
 515       (let ((ov oldvers)
 516             (nv newvers))
 517         (when (or (not ov) (string-equal ov ""))
 518           (setq ov (vc-working-revision file)))
 519         (when (string-equal nv "")
 520           (setq nv nil))
 521         (let ((file-oldvers (vc-version-backup-file file ov))
 522               (file-newvers (if (not nv)
 523                                 file
 524                               (vc-version-backup-file file nv)))
 525               (coding-system-for-read (vc-coding-system-for-diff file)))
 526           (if (and file-oldvers file-newvers)
 527               (progn
 528                 ;; This used to append diff-switches and vc-diff-switches,
 529                 ;; which was consistent with the vc-diff-switches doc at that
 530                 ;; time, but not with the actual behavior of any other VC diff.
 531                 (apply 'vc-do-command (or buffer "*vc-diff*") 1 "diff" nil
 532                        ;; Not a CVS diff, does not use vc-cvs-diff-switches.
 533                        (append (vc-switches nil 'diff)
 534                                (list (file-relative-name file-oldvers)
 535                                      (file-relative-name file-newvers))))
 536                 (setq status 0))
 537             (push file invoke-cvs-diff-list)))))
 538     (when invoke-cvs-diff-list
 539       (setq status (apply 'vc-cvs-command (or buffer "*vc-diff*")
 540                           (if async 'async 1)
 541                           invoke-cvs-diff-list "diff"
 542                           (and oldvers (concat "-r" oldvers))
 543                           (and newvers (concat "-r" newvers))
 544                           (vc-switches 'CVS 'diff))))
 545     (if async 1 status))) ; async diff, pessimistic assumption
 546
 547 (defconst vc-cvs-annotate-first-line-re "^[0-9]")
 548
 549 (defun vc-cvs-annotate-process-filter (process string)
 550   (setq string (concat (process-get process 'output) string))
 551   (if (not (string-match vc-cvs-annotate-first-line-re string))
 552       ;; Still waiting for the first real line.
 553       (process-put process 'output string)
 554     (let ((vc-filter (process-get process 'vc-filter)))
 555       (set-process-filter process vc-filter)
 556       (funcall vc-filter process (substring string (match-beginning 0))))))
 557
 558 (defun vc-cvs-annotate-command (file buffer &optional revision)
 559   "Execute \"cvs annotate\" on FILE, inserting the contents in BUFFER.
 560 Optional arg REVISION is a revision to annotate from."
 561   (vc-cvs-command buffer
 562                   (if (vc-stay-local-p file)
 563                       'async 0)
 564                   file "annotate"
 565                   (if revision (concat "-r" revision)))
 566   ;; Strip the leading few lines.
 567   (let ((proc (get-buffer-process buffer)))
 568     (if proc
 569         ;; If running asynchronously, use a process filter.
 570         (progn
 571           (process-put proc 'vc-filter (process-filter proc))
 572           (set-process-filter proc 'vc-cvs-annotate-process-filter))
 573       (with-current-buffer buffer
 574         (goto-char (point-min))
 575         (re-search-forward vc-cvs-annotate-first-line-re)
 576         (delete-region (point-min) (1- (point)))))))
 577
 578 (declare-function vc-annotate-convert-time "vc-annotate" (time))
 579
 580 (defun vc-cvs-annotate-current-time ()
 581   "Return the current time, based at midnight of the current day, and
 582 encoded as fractional days."
 583   (vc-annotate-convert-time
 584    (apply 'encode-time 0 0 0 (nthcdr 3 (decode-time (current-time))))))
 585
 586 (defun vc-cvs-annotate-time ()
 587   "Return the time of the next annotation (as fraction of days)
 588 systime, or nil if there is none."
 589   (let* ((bol (point))
 590          (cache (get-text-property bol 'vc-cvs-annotate-time))
 591          (inhibit-read-only t)
 592          (inhibit-modification-hooks t))
 593     (cond
 594      (cache)
 595      ((looking-at
 596        "^\\S-+\\s-+\\S-+\\s-+\\([0-9]+\\)-\\(\\sw+\\)-\\([0-9]+\\)): ")
 597       (let ((day (string-to-number (match-string 1)))
 598             (month (cdr (assq (intern (match-string 2))
 599                               '((Jan .  1) (Feb .  2) (Mar .  3)
 600                                 (Apr .  4) (May .  5) (Jun .  6)
 601                                 (Jul .  7) (Aug .  8) (Sep .  9)
 602                                 (Oct . 10) (Nov . 11) (Dec . 12)))))
 603             (year (let ((tmp (string-to-number (match-string 3))))
 604                     ;; Years 0..68 are 2000..2068.
 605                     ;; Years 69..99 are 1969..1999.
 606                     (+ (cond ((> 69 tmp) 2000)
 607                              ((> 100 tmp) 1900)
 608                              (t 0))
 609                        tmp))))
 610         (put-text-property
 611          bol (1+ bol) 'vc-cvs-annotate-time
 612          (setq cache (cons
 613                       ;; Position at end makes for nicer overlay result.
 614                       ;; Don't put actual buffer pos here, but only relative
 615                       ;; distance, so we don't ever move backward in the
 616                       ;; goto-char below, even if the text is moved.
 617                       (- (match-end 0) (match-beginning 0))
 618                       (vc-annotate-convert-time
 619                        (encode-time 0 0 0 day month year))))))))
 620     (when cache
 621       (goto-char (+ bol (car cache)))   ; Fontify from here to eol.
 622       (cdr cache))))                    ; days (float)
 623
 624 (defun vc-cvs-annotate-extract-revision-at-line ()
 625   (save-excursion
 626     (beginning-of-line)
 627     (if (re-search-forward "^\\([0-9]+\\.[0-9]+\\(\\.[0-9]+\\)*\\) +("
 628                            (line-end-position) t)
 629         (match-string-no-properties 1)
 630       nil)))
 631
 632 ;;;
 633 ;;; Tag system
 634 ;;;
 635
 636 (defun vc-cvs-create-tag (dir name branchp)
 637   "Assign to DIR's current revision a given NAME.
 638 If BRANCHP is non-nil, the name is created as a branch (and the current
 639 workspace is immediately moved to that new branch)."
 640   (vc-cvs-command nil 0 dir "tag" "-c" (if branchp "-b") name)
 641   (when branchp (vc-cvs-command nil 0 dir "update" "-r" name)))
 642
 643 (defun vc-cvs-retrieve-tag (dir name update)
 644   "Retrieve a tag at and below DIR.
 645 NAME is the name of the tag; if it is empty, do a `cvs update'.
 646 If UPDATE is non-nil, then update (resynch) any affected buffers."
 647   (with-current-buffer (get-buffer-create "*vc*")
 648     (let ((default-directory dir)
 649           (sticky-tag))
 650       (erase-buffer)
 651       (if (or (not name) (string= name ""))
 652           (vc-cvs-command t 0 nil "update")
 653         (vc-cvs-command t 0 nil "update" "-r" name)
 654         (setq sticky-tag name))
 655       (when update
 656         (goto-char (point-min))
 657         (while (not (eobp))
 658           (if (looking-at "\\([CMUP]\\) \\(.*\\)")
 659               (let* ((file (expand-file-name (match-string 2) dir))
 660                      (state (match-string 1))
 661                      (buffer (find-buffer-visiting file)))
 662                 (when buffer
 663                   (cond
 664                    ((or (string= state "U")
 665                         (string= state "P"))
 666                     (vc-file-setprop file 'vc-state 'up-to-date)
 667                     (vc-file-setprop file 'vc-working-revision nil)
 668                     (vc-file-setprop file 'vc-checkout-time
 669                                      (nth 5 (file-attributes file))))
 670                    ((or (string= state "M")
 671                         (string= state "C"))
 672                     (vc-file-setprop file 'vc-state 'edited)
 673                     (vc-file-setprop file 'vc-working-revision nil)
 674                     (vc-file-setprop file 'vc-checkout-time 0)))
 675                   (vc-file-setprop file 'vc-cvs-sticky-tag sticky-tag)
 676                   (vc-resynch-buffer file t t))))
 677           (forward-line 1))))))
 678
 679
 680 ;;;
 681 ;;; Miscellaneous
 682 ;;;
 683
 684 (defalias 'vc-cvs-make-version-backups-p 'vc-stay-local-p
 685   "Return non-nil if version backups should be made for FILE.")
 686
 687 (defun vc-cvs-check-headers ()
 688   "Check if the current file has any headers in it."
 689   (save-excursion
 690     (goto-char (point-min))
 691     (re-search-forward "\\$[A-Za-z\300-\326\330-\366\370-\377]+\
 692 \\(: [\t -#%-\176\240-\377]*\\)?\\$" nil t)))
 693
 694
 695 ;;;
 696 ;;; Internal functions
 697 ;;;
 698
 699 (defun vc-cvs-command (buffer okstatus files &rest flags)
 700   "A wrapper around `vc-do-command' for use in vc-cvs.el.
 701 The difference to vc-do-command is that this function always invokes `cvs',
 702 and that it passes `vc-cvs-global-switches' to it before FLAGS."
 703   (apply 'vc-do-command (or buffer "*vc*") okstatus "cvs" files
 704          (if (stringp vc-cvs-global-switches)
 705              (cons vc-cvs-global-switches flags)
 706            (append vc-cvs-global-switches
 707                    flags))))
 708
 709 (defalias 'vc-cvs-stay-local-p 'vc-stay-local-p)  ;Back-compatibility.
 710
 711 (defun vc-cvs-repository-hostname (dirname)
 712   "Hostname of the CVS server associated to workarea DIRNAME."
 713   (let ((rootname (expand-file-name "CVS/Root" dirname)))
 714     (when (file-readable-p rootname)
 715       (with-temp-buffer
 716         (let ((coding-system-for-read
 717                (or file-name-coding-system
 718                    default-file-name-coding-system)))
 719           (vc-insert-file rootname))
 720         (goto-char (point-min))
 721         (nth 2 (vc-cvs-parse-root
 722                 (buffer-substring (point)
 723                                   (line-end-position))))))))
 724
 725 (defun vc-cvs-parse-uhp (path)
 726   "parse user@host/path into (user@host /path)"
 727   (if (string-match "\\([^/]+\\)\\(/.*\\)" path)
 728       (list (match-string 1 path) (match-string 2 path))
 729       (list nil path)))
 730
 731 (defun vc-cvs-parse-root (root)
 732   "Split CVS ROOT specification string into a list of fields.
 733 A CVS root specification of the form
 734   [:METHOD:][[USER@]HOSTNAME]:?/path/to/repository
 735 is converted to a normalized record with the following structure:
 736   \(METHOD USER HOSTNAME CVS-ROOT).
 737 The default METHOD for a CVS root of the form
 738   /path/to/repository
 739 is `local'.
 740 The default METHOD for a CVS root of the form
 741   [USER@]HOSTNAME:/path/to/repository
 742 is `ext'.
 743 For an empty string, nil is returned (invalid CVS root)."
 744   ;; Split CVS root into colon separated fields (0-4).
 745   ;; The `x:' makes sure, that leading colons are not lost;
 746   ;; `HOST:/PATH' is then different from `:METHOD:/PATH'.
 747   (let* ((root-list (cdr (split-string (concat "x:" root) ":")))
 748          (len (length root-list))
 749          ;; All syntactic varieties will get a proper METHOD.
 750          (root-list
 751           (cond
 752            ((= len 0)
 753             ;; Invalid CVS root
 754             nil)
 755            ((= len 1)
 756             (let ((uhp (vc-cvs-parse-uhp (car root-list))))
 757               (cons (if (car uhp) "ext" "local") uhp)))
 758            ((= len 2)
 759             ;; [USER@]HOST:PATH => method `ext'
 760             (and (not (equal (car root-list) ""))
 761                  (cons "ext" root-list)))
 762            ((= len 3)
 763             ;; :METHOD:PATH or :METHOD:USER@HOSTNAME/PATH
 764             (cons (cadr root-list)
 765                   (vc-cvs-parse-uhp (caddr root-list))))
 766            (t
 767             ;; :METHOD:[USER@]HOST:PATH
 768             (cdr root-list)))))
 769     (if root-list
 770         (let ((method (car root-list))
 771               (uhost (or (cadr root-list) ""))
 772               (root (nth 2 root-list))
 773               user host)
 774           ;; Split USER@HOST
 775           (if (string-match "\\(.*\\)@\\(.*\\)" uhost)
 776               (setq user (match-string 1 uhost)
 777                     host (match-string 2 uhost))
 778             (setq host uhost))
 779           ;; Remove empty HOST
 780           (and (equal host "")
 781                (setq host))
 782           ;; Fix windows style CVS root `:local:C:\\project\\cvs\\some\\dir'
 783           (and host
 784                (equal method "local")
 785                (setq root (concat host ":" root) host))
 786           ;; Normalize CVS root record
 787           (list method user host root)))))
 788
 789 ;; XXX: This does not work correctly for subdirectories.  "cvs status"
 790 ;; information is context sensitive, it contains lines like:
 791 ;; cvs status: Examining DIRNAME
 792 ;; and the file entries after that don't show the full path.
 793 ;; Because of this VC directory listings only show changed files
 794 ;; at the top level for CVS.
 795 (defun vc-cvs-parse-status (&optional full)
 796   "Parse output of \"cvs status\" command in the current buffer.
 797 Set file properties accordingly.  Unless FULL is t, parse only
 798 essential information. Note that this can never set the 'ignored
 799 state."
 800   (let (file status missing)
 801     (goto-char (point-min))
 802     (while (looking-at "? \\(.*\\)")
 803       (setq file (expand-file-name (match-string 1)))
 804       (vc-file-setprop file 'vc-state 'unregistered)
 805       (forward-line 1))
 806     (when (re-search-forward "^File: " nil t)
 807       (when (setq missing (looking-at "no file "))
 808         (goto-char (match-end 0)))
 809       (cond
 810        ((re-search-forward "\\=\\([^ \t]+\\)" nil t)
 811         (setq file (expand-file-name (match-string 1)))
 812         (setq status(if (re-search-forward "\\=[ \t]+Status: \\(.*\\)" nil t)
 813                         (match-string 1) "Unknown"))
 814         (when (and full
 815                    (re-search-forward
 816                     "\\(RCS Version\\|RCS Revision\\|Repository revision\\):\
 817 \[\t ]+\\([0-9.]+\\)"
 818                     nil t))
 819             (vc-file-setprop file 'vc-latest-revision (match-string 2)))
 820         (vc-file-setprop
 821          file 'vc-state
 822          (cond
 823           ((string-match "Up-to-date" status)
 824            (vc-file-setprop file 'vc-checkout-time
 825                             (nth 5 (file-attributes file)))
 826            'up-to-date)
 827           ((string-match "Locally Modified" status)             'edited)
 828           ((string-match "Needs Merge" status)                  'needs-merge)
 829           ((string-match "Needs \\(Checkout\\|Patch\\)" status)
 830            (if missing 'missing 'needs-update))
 831           ((string-match "Locally Added" status)                'added)
 832           ((string-match "Locally Removed" status)              'removed)
 833           ((string-match "File had conflicts " status)          'conflict)
 834           ((string-match "Unknown" status)                      'unregistered)
 835           (t 'edited))))))))
 836
 837 (defun vc-cvs-after-dir-status (update-function)
 838   ;; Heavily inspired by vc-cvs-parse-status. AKA a quick hack.
 839   ;; This needs a lot of testing.
 840   (let ((status nil)
 841         (status-str nil)
 842         (file nil)
 843         (result nil)
 844         (missing nil)
 845         (ignore-next nil)
 846         (subdir default-directory))
 847     (goto-char (point-min))
 848     (while
 849         ;; Look for either a file entry, an unregistered file, or a
 850         ;; directory change.
 851         (re-search-forward
 852          "\\(^=+\n\\([^=c?\n].*\n\\|\n\\)+\\)\\|\\(\\(^?? .*\n\\)+\\)\\|\\(^cvs status: \\(Examining\\|nothing\\) .*\n\\)"
 853          nil t)
 854       ;; FIXME: get rid of narrowing here.
 855       (narrow-to-region (match-beginning 0) (match-end 0))
 856       (goto-char (point-min))
 857       ;; The subdir
 858       (when (looking-at "cvs status: Examining \\(.+\\)")
 859         (setq subdir (expand-file-name (match-string 1))))
 860       ;; Unregistered files
 861       (while (looking-at "? \\(.*\\)")
 862         (setq file (file-relative-name
 863                     (expand-file-name (match-string 1) subdir)))
 864         (push (list file 'unregistered) result)
 865         (forward-line 1))
 866       (when (looking-at "cvs status: nothing known about")
 867         ;; We asked about a non existent file.  The output looks like this:
 868
 869         ;; cvs status: nothing known about `lisp/v.diff'
 870         ;; ===================================================================
 871         ;; File: no file v.diff            Status: Unknown
 872         ;;
 873         ;;    Working revision:    No entry for v.diff
 874         ;;    Repository revision: No revision control file
 875         ;;
 876
 877         ;; Due to narrowing in this iteration we only see the "cvs
 878         ;; status:" line, so just set a flag so that we can ignore the
 879         ;; file in the next iteration.
 880         (setq ignore-next t))
 881       ;; A file entry.
 882       (when (re-search-forward "^File: \\(no file \\)?\\(.*[^ \t]\\)[ \t]+Status: \\(.*\\)" nil t)
 883         (setq missing (match-string 1))
 884         (setq file (file-relative-name
 885                     (expand-file-name (match-string 2) subdir)))
 886         (setq status-str (match-string 3))
 887         (setq status
 888               (cond
 889                ((string-match "Up-to-date" status-str) 'up-to-date)
 890                ((string-match "Locally Modified" status-str) 'edited)
 891                ((string-match "Needs Merge" status-str) 'needs-merge)
 892                ((string-match "Needs \\(Checkout\\|Patch\\)" status-str)
 893                 (if missing 'missing 'needs-update))
 894                ((string-match "Locally Added" status-str) 'added)
 895                ((string-match "Locally Removed" status-str) 'removed)
 896                ((string-match "File had conflicts " status-str) 'conflict)
 897                ((string-match "Unknown" status-str) 'unregistered)
 898                (t 'edited)))
 899         (if ignore-next
 900             (setq ignore-next nil)
 901           (unless (eq status 'up-to-date)
 902             (push (list file status) result))))
 903       (goto-char (point-max))
 904       (widen))
 905     (funcall update-function result))
 906   ;; Alternative implementation: use the "update" command instead of
 907   ;; the "status" command.
 908   ;; (let ((result nil)
 909   ;;    (translation '((?? . unregistered)
 910   ;;                   (?A . added)
 911   ;;                   (?C . conflict)
 912   ;;                   (?M . edited)
 913   ;;                   (?P . needs-merge)
 914   ;;                   (?R . removed)
 915   ;;                   (?U . needs-update))))
 916   ;;   (goto-char (point-min))
 917   ;;   (while (not (eobp))
 918   ;;     (if (looking-at "^[ACMPRU?] \\(.*\\)$")
 919   ;;      (push (list (match-string 1)
 920   ;;                  (cdr (assoc (char-after) translation)))
 921   ;;            result)
 922   ;;    (cond
 923   ;;     ((looking-at "cvs update: warning: \\(.*\\) was lost")
 924   ;;      ;; Format is:
 925   ;;      ;; cvs update: warning: FILENAME was lost
 926   ;;      ;; U FILENAME
 927   ;;      (push (list (match-string 1) 'missing) result)
 928   ;;      ;; Skip the "U" line
 929   ;;      (forward-line 1))
 930   ;;     ((looking-at "cvs update: New directory `\\(.*\\)' -- ignored")
 931   ;;      (push (list (match-string 1) 'unregistered) result))))
 932   ;;     (forward-line 1))
 933   ;;   (funcall update-function result)))
 934   )
 935
 936 ;; Based on vc-cvs-dir-state-heuristic from Emacs 22.
 937 (defun vc-cvs-dir-status-heuristic (dir update-function &optional basedir)
 938   "Find the CVS state of all files in DIR, using only local information."
 939   (let (file basename status result dirlist)
 940     (with-temp-buffer
 941       (vc-cvs-get-entries dir)
 942       (goto-char (point-min))
 943       (while (not (eobp))
 944         (if (looking-at "D/\\([^/]*\\)////")
 945             (push (expand-file-name (match-string 1) dir) dirlist)
 946           ;; CVS-removed files are not taken under VC control.
 947           (when (looking-at "/\\([^/]*\\)/[^/-]")
 948             (setq basename (match-string 1)
 949                   file (expand-file-name basename dir)
 950                   status (or (vc-file-getprop file 'vc-state)
 951                              (vc-cvs-parse-entry file t)))
 952             (unless (eq status 'up-to-date)
 953               (push (list (if basedir
 954                               (file-relative-name file basedir)
 955                             basename)
 956                           status) result))))
 957         (forward-line 1)))
 958     (dolist (subdir dirlist)
 959       (setq result (append result
 960                            (vc-cvs-dir-status-heuristic subdir nil
 961                                                         (or basedir dir)))))
 962     (if basedir result
 963       (funcall update-function result))))
 964
 965 (defun vc-cvs-dir-status (dir update-function)
 966   "Create a list of conses (file . state) for DIR."
 967   ;; FIXME check all files in DIR instead?
 968   (let ((local (vc-stay-local-p dir)))
 969     (if (and local (not (eq local 'only-file)))
 970         (vc-cvs-dir-status-heuristic dir update-function)
 971       (vc-cvs-command (current-buffer) 'async dir "-f" "status")
 972       ;; Alternative implementation: use the "update" command instead of
 973       ;; the "status" command.
 974       ;; (vc-cvs-command (current-buffer) 'async
 975       ;;                  (file-relative-name dir)
 976       ;;                  "-f" "-n" "update" "-d" "-P")
 977       (vc-exec-after
 978        `(vc-cvs-after-dir-status (quote ,update-function))))))
 979
 980 (defun vc-cvs-dir-status-files (dir files default-state update-function)
 981   "Create a list of conses (file . state) for DIR."
 982   (apply 'vc-cvs-command (current-buffer) 'async dir "-f" "status" files)
 983   (vc-exec-after
 984    `(vc-cvs-after-dir-status (quote ,update-function))))
 985
 986 (defun vc-cvs-file-to-string (file)
 987   "Read the content of FILE and return it as a string."
 988   (condition-case nil
 989       (with-temp-buffer
 990         (insert-file-contents file)
 991         (goto-char (point-min))
 992         (buffer-substring (point) (point-max)))
 993     (file-error nil)))
 994
 995 (defun vc-cvs-dir-extra-headers (dir)
 996   "Extract and represent per-directory properties of a CVS working copy."
 997   (let ((repo
 998          (condition-case nil
 999              (with-temp-buffer
1000                (insert-file-contents "CVS/Root")
1001                (goto-char (point-min))
1002                (and (looking-at ":ext:") (delete-char 5))
1003                (concat (buffer-substring (point) (1- (point-max))) "\n"))
1004            (file-error nil)))
1005         (module
1006          (condition-case nil
1007              (with-temp-buffer
1008                (insert-file-contents "CVS/Repository")
1009                (goto-char (point-min))
1010                (skip-chars-forward "^\n")
1011                (concat (buffer-substring (point-min) (point)) "\n"))
1012            (file-error nil))))
1013     (concat
1014      (cond (repo
1015             (concat (propertize "Repository : " 'face 'font-lock-type-face)
1016                     (propertize repo 'face 'font-lock-variable-name-face)))
1017            (t ""))
1018      (cond (module
1019             (concat (propertize "Module     : " 'face 'font-lock-type-face)
1020                     (propertize module 'face 'font-lock-variable-name-face)))
1021            (t ""))
1022      (if (file-readable-p "CVS/Tag")
1023          (let ((tag (vc-cvs-file-to-string "CVS/Tag")))
1024            (cond
1025             ((string-match "\\`T" tag)
1026              (concat (propertize "Tag        : " 'face 'font-lock-type-face)
1027                      (propertize (substring tag 1)
1028                                  'face 'font-lock-variable-name-face)))
1029             ((string-match "\\`D" tag)
1030              (concat (propertize "Date       : " 'face 'font-lock-type-face)
1031                      (propertize (substring tag 1)
1032                                  'face 'font-lock-variable-name-face)))
1033             (t ""))))
1034
1035      ;; In CVS, branch is a per-file property, not a per-directory property.
1036      ;; We can't really do this here without making dangerous assumptions.
1037      ;;(propertize "Branch:     " 'face 'font-lock-type-face)
1038      ;;(propertize "ADD CODE TO PRINT THE BRANCH NAME\n"
1039      ;;  'face 'font-lock-warning-face)
1040      )))
1041
1042 (defun vc-cvs-get-entries (dir)
1043   "Insert the CVS/Entries file from below DIR into the current buffer.
1044 This function ensures that the correct coding system is used for that,
1045 which may not be the one that is used for the files' contents.
1046 CVS/Entries should only be accessed through this function."
1047   (let ((coding-system-for-read (or file-name-coding-system
1048                                     default-file-name-coding-system)))
1049     (vc-insert-file (expand-file-name "CVS/Entries" dir))))
1050
1051 (defun vc-cvs-valid-symbolic-tag-name-p (tag)
1052   "Return non-nil if TAG is a valid symbolic tag name."
1053   ;; According to the CVS manual, a valid symbolic tag must start with
1054   ;; an uppercase or lowercase letter and can contain uppercase and
1055   ;; lowercase letters, digits, `-', and `_'.
1056   (and (string-match "^[a-zA-Z]" tag)
1057        (not (string-match "[^a-z0-9A-Z-_]" tag))))
1058
1059 (defun vc-cvs-valid-revision-number-p (tag)
1060   "Return non-nil if TAG is a valid revision number."
1061   (and (string-match "^[0-9]" tag)
1062        (not (string-match "[^0-9.]" tag))))
1063
1064 (defun vc-cvs-parse-sticky-tag (match-type match-tag)
1065   "Parse and return the sticky tag as a string.
1066 `match-data' is protected."
1067   (let ((data (match-data))
1068         (tag)
1069         (type (cond ((string= match-type "D") 'date)
1070                     ((string= match-type "T")
1071                      (if (vc-cvs-valid-symbolic-tag-name-p match-tag)
1072                          'symbolic-name
1073                        'revision-number))
1074                     (t nil))))
1075     (unwind-protect
1076         (progn
1077           (cond
1078            ;; Sticky Date tag.  Convert to a proper date value (`encode-time')
1079            ((eq type 'date)
1080             (string-match
1081              "\\([0-9]+\\)\\.\\([0-9]+\\)\\.\\([0-9]+\\)\\.\\([0-9]+\\)\\.\\([0-9]+\\)\\.\\([0-9]+\\)"
1082              match-tag)
1083             (let* ((year-tmp (string-to-number (match-string 1 match-tag)))
1084                    (month    (string-to-number (match-string 2 match-tag)))
1085                    (day      (string-to-number (match-string 3 match-tag)))
1086                    (hour     (string-to-number (match-string 4 match-tag)))
1087                    (min      (string-to-number (match-string 5 match-tag)))
1088                    (sec      (string-to-number (match-string 6 match-tag)))
1089                    ;; Years 0..68 are 2000..2068.
1090                    ;; Years 69..99 are 1969..1999.
1091                    (year (+ (cond ((> 69 year-tmp) 2000)
1092                                   ((> 100 year-tmp) 1900)
1093                                   (t 0))
1094                             year-tmp)))
1095               (setq tag (encode-time sec min hour day month year))))
1096            ;; Sticky Tag name or revision number
1097            ((eq type 'symbolic-name) (setq tag match-tag))
1098            ((eq type 'revision-number) (setq tag match-tag))
1099            ;; Default is no sticky tag at all
1100            (t nil))
1101           (cond ((eq vc-cvs-sticky-tag-display nil) nil)
1102                 ((eq vc-cvs-sticky-tag-display t)
1103                  (cond ((eq type 'date) (format-time-string
1104                                          vc-cvs-sticky-date-format-string
1105                                          tag))
1106                        ((eq type 'symbolic-name) tag)
1107                        ((eq type 'revision-number) tag)
1108                        (t nil)))
1109                 ((functionp vc-cvs-sticky-tag-display)
1110                  (funcall vc-cvs-sticky-tag-display tag type))
1111                 (t nil)))
1112
1113       (set-match-data data))))
1114
1115 (defun vc-cvs-parse-entry (file &optional set-state)
1116   "Parse a line from CVS/Entries.
1117 Compare modification time to that of the FILE, set file properties
1118 accordingly.  However, `vc-state' is set only if optional arg SET-STATE
1119 is non-nil."
1120   (cond
1121    ;; entry for a "locally added" file (not yet committed)
1122    ((looking-at "/[^/]+/0/")
1123     (vc-file-setprop file 'vc-checkout-time 0)
1124     (vc-file-setprop file 'vc-working-revision "0")
1125     (if set-state (vc-file-setprop file 'vc-state 'added)))
1126    ;; normal entry
1127    ((looking-at
1128      (concat "/[^/]+"
1129              ;; revision
1130              "/\\([^/]*\\)"
1131              ;; timestamp and optional conflict field
1132              "/\\([^/]*\\)/"
1133              ;; options
1134              "\\([^/]*\\)/"
1135              ;; sticky tag
1136              "\\(.\\|\\)" ;Sticky tag type (date or tag name, could be empty)
1137              "\\(.*\\)"))               ;Sticky tag
1138     (vc-file-setprop file 'vc-working-revision (match-string 1))
1139     (vc-file-setprop file 'vc-cvs-sticky-tag
1140                      (vc-cvs-parse-sticky-tag (match-string 4)
1141                                               (match-string 5)))
1142     ;; Compare checkout time and modification time.
1143     ;; This is intentionally different from the algorithm that CVS uses
1144     ;; (which is based on textual comparison), because there can be problems
1145     ;; generating a time string that looks exactly like the one from CVS.
1146     (let ((mtime (nth 5 (file-attributes file))))
1147       (require 'parse-time)
1148       (let ((parsed-time
1149              (parse-time-string (concat (match-string 2) " +0000"))))
1150         (cond ((and (not (string-match "\\+" (match-string 2)))
1151                     (car parsed-time)
1152                     (equal mtime (apply 'encode-time parsed-time)))
1153                (vc-file-setprop file 'vc-checkout-time mtime)
1154                (if set-state (vc-file-setprop file 'vc-state 'up-to-date)))
1155               (t
1156                (vc-file-setprop file 'vc-checkout-time 0)
1157                (if set-state (vc-file-setprop file 'vc-state 'edited)))))))))
1158
1159 ;; Completion of revision names.
1160 ;; Just so I don't feel like I'm duplicating code from pcl-cvs, I'll use
1161 ;; `cvs log' so I can list all the revision numbers rather than only
1162 ;; tag names.
1163
1164 (defun vc-cvs-revision-table (file)
1165   (let ((default-directory (file-name-directory file))
1166         (res nil))
1167     (with-temp-buffer
1168       (vc-cvs-command t nil file "log")
1169       (goto-char (point-min))
1170       (when (re-search-forward "^symbolic names:\n" nil t)
1171         (while (looking-at "^   \\(.*\\): \\(.*\\)")
1172           (push (cons (match-string 1) (match-string 2)) res)
1173           (forward-line 1)))
1174       (while (re-search-forward "^revision \\([0-9.]+\\)" nil t)
1175         (push (match-string 1) res))
1176       res)))
1177
1178 (defun vc-cvs-revision-completion-table (files)
1179   (lexical-let ((files files)
1180                 table)
1181     (setq table (lazy-completion-table
1182                  table (lambda () (vc-cvs-revision-table (car files)))))
1183     table))
1184
1185
1186 (provide 'vc-cvs)
1187
1188 ;; arch-tag: 60e1402a-aa53-4607-927a-cf74f144b432
1189 ;;; vc-cvs.el ends here