lisp/pcmpl-unix.el

   1 ;;; pcmpl-unix.el --- standard UNIX completions
   2
   3 ;; Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software: you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 ;;; Commentary:
  22
  23 ;;; Code:
  24
  25 (require 'pcomplete)
  26
  27 ;; User Variables:
  28
  29 (defcustom pcmpl-unix-group-file "/etc/group"
  30   "If non-nil, a string naming the group file on your system."
  31   :type '(choice file (const nil))
  32   :group 'pcmpl-unix)
  33
  34 (defcustom pcmpl-unix-passwd-file "/etc/passwd"
  35   "If non-nil, a string naming the passwd file on your system."
  36   :type '(choice file (const nil))
  37   :group 'pcmpl-unix)
  38
  39 (defcustom pcmpl-ssh-known-hosts-file "~/.ssh/known_hosts"
  40   "If non-nil, a string naming your SSH \"known_hosts\" file.
  41 This allows completion of SSH host names.  Note that newer
  42 versions of ssh hash the hosts by default to prevent
  43 Island-hopping SSH attacks.  This can be disabled, at some risk,
  44 with the SSH option \"HashKnownHosts no\"."
  45   :type '(choice file (const nil))
  46   :group 'pcmpl-unix
  47   :version "23.1")
  48
  49 ;; Functions:
  50
  51 ;;;###autoload
  52 (defun pcomplete/cd ()
  53   "Completion for `cd'."
  54   (pcomplete-here (pcomplete-dirs)))
  55
  56 ;;;###autoload
  57 (defalias 'pcomplete/pushd 'pcomplete/cd)
  58
  59 ;;;###autoload
  60 (defun pcomplete/rmdir ()
  61   "Completion for `rmdir'."
  62   (while (pcomplete-here (pcomplete-dirs))))
  63
  64 ;;;###autoload
  65 (defun pcomplete/rm ()
  66   "Completion for `rm'."
  67   (let ((pcomplete-help "(fileutils)rm invocation"))
  68     (pcomplete-opt "dfirRv")
  69     (while (pcomplete-here (pcomplete-all-entries) nil
  70                            'expand-file-name))))
  71
  72 ;;;###autoload
  73 (defun pcomplete/xargs ()
  74   "Completion for `xargs'."
  75   (pcomplete-here (funcall pcomplete-command-completion-function))
  76   (funcall (or (pcomplete-find-completion-function (pcomplete-arg 1))
  77                pcomplete-default-completion-function)))
  78
  79 ;;;###autoload
  80 (defalias 'pcomplete/time 'pcomplete/xargs)
  81
  82 ;;;###autoload
  83 (defun pcomplete/which ()
  84   "Completion for `which'."
  85   (while (pcomplete-here (funcall pcomplete-command-completion-function))))
  86
  87 (defun pcmpl-unix-read-passwd-file (file)
  88   "Return an alist correlating gids to group names in FILE."
  89   (let (names)
  90     (when (file-readable-p file)
  91       (with-temp-buffer
  92         (insert-file-contents file)
  93         (goto-char (point-min))
  94         (while (not (eobp))
  95           (let* ((fields
  96                   (split-string (buffer-substring
  97                                  (point) (progn (end-of-line)
  98                                                 (point))) ":")))
  99             (setq names (cons (nth 0 fields) names)))
 100           (forward-line))))
 101     (pcomplete-uniqify-list names)))
 102
 103 (defsubst pcmpl-unix-group-names ()
 104   "Read the contents of /etc/group for group names."
 105   (if pcmpl-unix-group-file
 106       (pcmpl-unix-read-passwd-file pcmpl-unix-group-file)))
 107
 108 (defsubst pcmpl-unix-user-names ()
 109   "Read the contents of /etc/passwd for user names."
 110   (if pcmpl-unix-passwd-file
 111       (pcmpl-unix-read-passwd-file pcmpl-unix-passwd-file)))
 112
 113 ;;;###autoload
 114 (defun pcomplete/chown ()
 115   "Completion for the `chown' command."
 116   (unless (pcomplete-match "\\`-")
 117     (if (pcomplete-match "\\`[^.]*\\'" 0)
 118         (pcomplete-here* (pcmpl-unix-user-names))
 119       (if (pcomplete-match "\\.\\([^.]*\\)\\'" 0)
 120           (pcomplete-here* (pcmpl-unix-group-names)
 121                            (pcomplete-match-string 1 0))
 122         (pcomplete-here*))))
 123   (while (pcomplete-here (pcomplete-entries))))
 124
 125 ;;;###autoload
 126 (defun pcomplete/chgrp ()
 127   "Completion for the `chgrp' command."
 128   (unless (pcomplete-match "\\`-")
 129     (pcomplete-here* (pcmpl-unix-group-names)))
 130   (while (pcomplete-here (pcomplete-entries))))
 131
 132
 133 ;; ssh support by Phil Hagelberg.
 134 ;; http://www.emacswiki.org/cgi-bin/wiki/pcmpl-ssh.el
 135
 136 (defun pcmpl-ssh-hosts ()
 137   "Return a list of hosts found in `pcmpl-ssh-known-hosts-file'."
 138   (when (and pcmpl-ssh-known-hosts-file
 139              (file-readable-p pcmpl-ssh-known-hosts-file))
 140     (with-temp-buffer
 141       (insert-file-contents-literally pcmpl-ssh-known-hosts-file)
 142       (let (ssh-hosts-list)
 143         (while (re-search-forward "^ *\\([-.[:alnum:]]+\\)[, ]" nil t)
 144           (add-to-list 'ssh-hosts-list (match-string 1))
 145           (while (and (looking-back ",")
 146                       (re-search-forward "\\([-.[:alnum:]]+\\)[, ]"
 147                                          (line-end-position) t))
 148             (add-to-list 'ssh-hosts-list (match-string 1))))
 149         ssh-hosts-list))))
 150
 151 ;;;###autoload
 152 (defun pcomplete/ssh ()
 153   "Completion rules for the `ssh' command."
 154   (pcomplete-opt "1246AaCfgKkMNnqsTtVvXxYbcDeFiLlmOopRSw" nil t)
 155   (pcomplete-here (pcmpl-ssh-hosts)))
 156
 157 ;;;###autoload
 158 (defun pcomplete/scp ()
 159   "Completion rules for the `scp' command.
 160 Includes files as well as host names followed by a colon."
 161   (pcomplete-opt "1246BCpqrvcFiloPS")
 162   (while t (pcomplete-here (append (pcomplete-all-entries)
 163                                    (mapcar (lambda (host)
 164                                              (concat host ":"))
 165                                            (pcmpl-ssh-hosts))))))
 166
 167 (provide 'pcmpl-unix)
 168
 169 ;; arch-tag: 3f9eb5af-7e0e-449d-b586-381cbbf8fc5c
 170 ;;; pcmpl-unix.el ends here