lisp/pcvs.el

   1 ;;; pcvs.el --- a front-end to CVS
   2
   3 ;; Copyright (C) 1991, 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4 ;;   2000, 2002, 2003, 2004  Free Software Foundation, Inc.
   5
   6 ;; Author: (The PCL-CVS Trust) pcl-cvs@cyclic.com
   7 ;;      (Per Cederqvist) ceder@lysator.liu.se
   8 ;;      (Greg A. Woods) woods@weird.com
   9 ;;      (Jim Blandy) jimb@cyclic.com
  10 ;;      (Karl Fogel) kfogel@floss.red-bean.com
  11 ;;      (Jim Kingdon) kingdon@cyclic.com
  12 ;;      (Stefan Monnier) monnier@cs.yale.edu
  13 ;;      (Greg Klanderman) greg@alphatech.com
  14 ;;      (Jari Aalto+mail.emacs) jari.aalto@poboxes.com
  15 ;; Maintainer: (Stefan Monnier) monnier@gnu.org
  16 ;; Keywords: CVS, version control, release management
  17
  18 ;; This file is part of GNU Emacs.
  19
  20 ;; GNU Emacs is free software; you can redistribute it and/or modify
  21 ;; it under the terms of the GNU General Public License as published by
  22 ;; the Free Software Foundation; either version 2, or (at your option)
  23 ;; any later version.
  24
  25 ;; GNU Emacs is distributed in the hope that it will be useful,
  26 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  27 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  28 ;; GNU General Public License for more details.
  29
  30 ;; You should have received a copy of the GNU General Public License
  31 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  32 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  33 ;; Boston, MA 02111-1307, USA.
  34
  35 ;;; Commentary:
  36
  37 ;; PCL-CVS is a front-end to the CVS version control system.  For people
  38 ;; familiar with VC, it is somewhat like VC-dired: it presents the status of
  39 ;; all the files in your working area and allows you to commit/update several
  40 ;; of them at a time.  Compared to VC-dired, it is considerably better and
  41 ;; faster (but only for CVS).
  42
  43 ;; PCL-CVS was originally written by Per Cederqvist many years ago.  This
  44 ;; version derives from the XEmacs-21 version, itself based on the 2.0b2
  45 ;; version (last release from Per).  It is a thorough rework.
  46
  47 ;; Contrary to what you'd expect, PCL-CVS is not a replacement for VC but only
  48 ;; for VC-dired.  As such, I've tried to make PCL-CVS and VC interoperate
  49 ;; seamlessly (I also use VC).
  50
  51 ;; To use PCL-CVS just use `M-x cvs-examine RET <dir> RET'.
  52 ;; There is a TeXinfo manual, which can be helpful to get started.
  53
  54 ;;; Bugs:
  55
  56 ;; - Extracting an old version seems not to recognize encoding correctly.
  57 ;;   That's probably because it's done via a process rather than a file.
  58
  59 ;;; Todo:
  60
  61 ;; ******** FIX THE DOCUMENTATION *********
  62 ;;
  63 ;; - rework the displaying of error messages.
  64 ;; - allow to flush messages only
  65 ;; - allow to protect files like ChangeLog from flushing
  66 ;; - automatically cvs-mode-insert files from find-file-hook
  67 ;;   (and don't flush them as long as they are visited)
  68 ;; - query the user for cvs-get-marked (for some cmds or if nothing's selected)
  69 ;; - don't return the first (resp last) FI if the cursor is before
  70 ;;   (resp after) it.
  71 ;; - allow cvs-confirm-removals to force always confirmation.
  72 ;; - cvs-checkout should ask for a revision (with completion).
  73 ;; - removal confirmation should allow specifying another file name.
  74 ;;
  75 ;; - hide fileinfos without getting rid of them (will require ewok work).
  76 ;; - add toolbar entries
  77 ;; - marking
  78 ;;    marking directories should jump to just after the dir.
  79 ;;    allow (un)marking directories at a time with the mouse.
  80 ;;    allow cvs-cmd-do to either clear the marks or not.
  81 ;;    add a "marks active" notion, like transient-mark-mode does.
  82 ;; - liveness indicator
  83 ;; - indicate in docstring if the cmd understands the `b' prefix(es).
  84 ;; - call smerge-mode when opening CONFLICT files.
  85 ;; - have vc-checkin delegate to cvs-mode-commit when applicable
  86 ;; - higher-level CVS operations
  87 ;;    cvs-mode-rename
  88 ;;    cvs-mode-branch
  89 ;; - module-level commands
  90 ;;    add support for parsing 'modules' file ("cvs co -c")
  91 ;;    cvs-mode-rcs2log
  92 ;;    cvs-rdiff
  93 ;;    cvs-release
  94 ;;    cvs-import
  95 ;;    C-u M-x cvs-checkout should ask for a cvsroot
  96 ;;    cvs-mode-handle-new-vendor-version
  97 ;;      - checks out module, or alternately does update join
  98 ;;      - does "cvs -n tag LAST_VENDOR" to find old files into *cvs*
  99 ;;    cvs-export
 100 ;;      (with completion on tag names and hooks to help generate full releases)
 101 ;; - display stickiness information.  And current CVS/Tag as well.
 102 ;; - write 'cvs-mode-admin' to do arbitrary 'cvs admin' commands
 103 ;;   Most interesting would be version removal and log message replacement.
 104 ;;   The last one would be neat when called from log-view-mode.
 105 ;; - cvs-mode-incorporate
 106 ;;      It would merge in the status from one *cvs* buffer into another.
 107 ;;      This would be used to populate such a buffer that had been created with
 108 ;;      a `cvs {update,status,checkout} -l'.
 109 ;; - cvs-mode-(i)diff-other-{file,buffer,cvs-buffer}
 110 ;; - offer the choice to kill the process when the user kills the cvs buffer.
 111 ;;      right now, it's killed without further ado.
 112 ;; - make `cvs-mode-ignore' allow manually entering a pattern.
 113 ;;      to which dir should it apply ?
 114 ;; - cvs-mode-ignore should try to remove duplicate entries.
 115 ;; - maybe poll/check CVS/Entries files to react to external `cvs' commands ?
 116 ;; - some kind of `cvs annotate' support ?
 117 ;;      but vc-annotate can be used instead.
 118 ;; - proper `g' that passes safe args and uses either cvs-status or cvs-examine
 119 ;;   maybe also use cvs-update depending on I-don't-know-what.
 120 ;; - add message-levels so that we can hide some levels of messages
 121
 122 ;;; Code:
 123
 124 (eval-when-compile (require 'cl))
 125 (require 'ewoc)                         ;Ewoc was once cookie
 126 (require 'pcvs-defs)
 127 (require 'pcvs-util)
 128 (require 'pcvs-parse)
 129 (require 'pcvs-info)
 130
 131 \f
 132 ;;;;
 133 ;;;; global vars
 134 ;;;;
 135
 136 (defvar cvs-cookies) ;;nil
 137   ;;"Handle for the cookie structure that is displayed in the *cvs* buffer.")
 138 ;;(make-variable-buffer-local 'cvs-cookies)
 139
 140 ;;;;
 141 ;;;; Dynamically scoped variables
 142 ;;;;
 143
 144 (defvar cvs-from-vc nil "Bound to t inside VC advice.")
 145
 146 ;;;;
 147 ;;;; flags variables
 148 ;;;;
 149
 150 (defun cvs-defaults (&rest defs)
 151   (let ((defs (cvs-first defs cvs-shared-start)))
 152     (append defs
 153             (make-list (- cvs-shared-start (length defs)) (car defs))
 154             cvs-shared-flags)))
 155
 156 ;; For cvs flags, we need to add "-f" to override the cvsrc settings
 157 ;; we also want to evict the annoying -q and -Q options that hide useful
 158 ;; information from pcl-cvs.
 159 (cvs-flags-define cvs-cvs-flags '(("-f")))
 160
 161 (cvs-flags-define cvs-checkout-flags (cvs-defaults '("-P")))
 162 (cvs-flags-define cvs-status-flags (cvs-defaults '("-v") nil))
 163 (cvs-flags-define cvs-log-flags (cvs-defaults nil))
 164 (cvs-flags-define cvs-diff-flags (cvs-defaults '("-u" "-N") '("-c" "-N") '("-u" "-b")))
 165 (cvs-flags-define cvs-tag-flags (cvs-defaults nil))
 166 (cvs-flags-define cvs-add-flags (cvs-defaults nil))
 167 (cvs-flags-define cvs-commit-flags (cvs-defaults nil))
 168 (cvs-flags-define cvs-remove-flags (cvs-defaults nil))
 169 ;;(cvs-flags-define cvs-undo-flags (cvs-defaults nil))
 170 (cvs-flags-define cvs-update-flags (cvs-defaults '("-d" "-P")))
 171
 172 (defun cvs-reread-cvsrc ()
 173   "Reset the default arguments to those in the `cvs-cvsrc-file'."
 174   (interactive)
 175   (condition-case nil
 176       (with-temp-buffer
 177         (insert-file-contents cvs-cvsrc-file)
 178         ;; fetch the values
 179         (dolist (cmd '("cvs" "checkout" "status" "log" "diff" "tag"
 180                        "add" "commit" "remove" "update"))
 181           (goto-char (point-min))
 182           (when (re-search-forward
 183                  (concat "^" cmd "\\(\\s-+\\(.*\\)\\)?$") nil t)
 184             (let* ((sym (intern (concat "cvs-" cmd "-flags")))
 185                    (val (cvs-string->strings (or (match-string 2) ""))))
 186               (cvs-flags-set sym 0 val))))
 187         ;; ensure that cvs doesn't have -q or -Q
 188         (cvs-flags-set 'cvs-cvs-flags 0
 189                        (cons "-f"
 190                              (cdr (cvs-partition
 191                                    (lambda (x) (member x '("-q" "-Q" "-f")))
 192                                    (cvs-flags-query 'cvs-cvs-flags
 193                                                     nil 'noquery))))))
 194       (file-error nil)))
 195
 196 ;; initialize to cvsrc's default values
 197 (cvs-reread-cvsrc)
 198
 199 \f
 200 ;;;;
 201 ;;;; Mouse bindings and mode motion
 202 ;;;;
 203
 204 (defvar cvs-minor-current-files)
 205
 206 (defun cvs-menu (e)
 207   "Popup the CVS menu."
 208   (interactive "e")
 209   (let ((cvs-minor-current-files
 210          (list (ewoc-data (ewoc-locate
 211                            cvs-cookies (posn-point (event-end e)))))))
 212     (popup-menu cvs-menu e)))
 213
 214 (defvar cvs-mode-line-process nil
 215   "Mode-line control for displaying info on cvs process status.")
 216
 217
 218 ;;;;
 219 ;;;; Query-Type-Descriptor for Tags
 220 ;;;;
 221
 222 (autoload 'cvs-status-get-tags "cvs-status")
 223 (defun cvs-tags-list ()
 224   "Return a list of acceptable tags, ready for completions."
 225   (assert (cvs-buffer-p))
 226   (let ((marked (cvs-get-marked)))
 227     (list* '("BASE") '("HEAD")
 228            (when marked
 229              (with-temp-buffer
 230                (call-process cvs-program
 231                              nil        ;no input
 232                              t          ;output to current-buffer
 233                              nil        ;don't update display while running
 234                              "status"
 235                              "-v"
 236                              (cvs-fileinfo->full-path (car marked)))
 237                (goto-char (point-min))
 238                (let ((tags (cvs-status-get-tags)))
 239                  (when (listp tags) tags)))))))
 240
 241 (defvar cvs-tag-history nil)
 242 (defconst cvs-qtypedesc-tag
 243   (cvs-qtypedesc-create 'identity 'identity 'cvs-tags-list 'cvs-tag-history))
 244
 245 ;;;;
 246
 247 (defun cvs-mode! (&optional -cvs-mode!-fun)
 248   "Switch to the *cvs* buffer.
 249 If -CVS-MODE!-FUN is provided, it is executed *cvs* being the current buffer
 250   and with its window selected.  Else, the *cvs* buffer is simply selected.
 251 -CVS-MODE!-FUN is called interactively if applicable and else with no argument."
 252   (let* ((-cvs-mode!-buf (current-buffer))
 253          (cvsbuf (cond ((cvs-buffer-p) (current-buffer))
 254                        ((and cvs-buffer (cvs-buffer-p cvs-buffer)) cvs-buffer)
 255                        (t (error "can't find the *cvs* buffer"))))
 256          (-cvs-mode!-wrapper cvs-minor-wrap-function)
 257          (-cvs-mode!-cont (lambda ()
 258                             (save-current-buffer
 259                               (if (commandp -cvs-mode!-fun)
 260                                   (call-interactively -cvs-mode!-fun)
 261                                 (funcall -cvs-mode!-fun))))))
 262     (if (not -cvs-mode!-fun) (set-buffer cvsbuf)
 263       (let ((cvs-mode!-buf (current-buffer))
 264             (cvs-mode!-owin (selected-window))
 265             (cvs-mode!-nwin (get-buffer-window cvsbuf 'visible)))
 266         (unwind-protect
 267             (progn
 268               (set-buffer cvsbuf)
 269               (when cvs-mode!-nwin (select-window cvs-mode!-nwin))
 270               (if -cvs-mode!-wrapper
 271                   (funcall -cvs-mode!-wrapper -cvs-mode!-buf -cvs-mode!-cont)
 272                 (funcall -cvs-mode!-cont)))
 273           (set-buffer cvs-mode!-buf)
 274           (when (and cvs-mode!-nwin (eq cvs-mode!-nwin (selected-window)))
 275             ;; the selected window has not been changed by FUN
 276             (select-window cvs-mode!-owin)))))))
 277
 278 ;;;;
 279 ;;;; Prefixes
 280 ;;;;
 281
 282 (defvar cvs-branches (list cvs-vendor-branch "HEAD" "HEAD"))
 283 (cvs-prefix-define cvs-branch-prefix
 284   "Current selected branch."
 285   "version"
 286   (cons cvs-vendor-branch cvs-branches)
 287   cvs-qtypedesc-tag)
 288
 289 (defun cvs-set-branch-prefix (arg)
 290   "Set the branch prefix to take action at the next command.
 291 See `cvs-prefix-set' for a further the description of the behavior.
 292 \\[universal-argument] 1 selects the vendor branch
 293 and \\[universal-argument] 2 selects the HEAD."
 294   (interactive "P")
 295   (cvs-mode!)
 296   (cvs-prefix-set 'cvs-branch-prefix arg))
 297
 298 (defun cvs-add-branch-prefix (flags &optional arg)
 299   "Add branch selection argument if the branch prefix was set.
 300 The argument is added (or not) to the list of FLAGS and is constructed
 301 by appending the branch to ARG which defaults to \"-r\"."
 302   (let ((branch (cvs-prefix-get 'cvs-branch-prefix)))
 303     ;; deactivate the secondary prefix, even if not used.
 304     (cvs-prefix-get 'cvs-secondary-branch-prefix)
 305     (if branch (cons (concat (or arg "-r") branch) flags) flags)))
 306
 307 (cvs-prefix-define cvs-secondary-branch-prefix
 308   "Current secondary selected branch."
 309   "version"
 310   (cons cvs-vendor-branch cvs-branches)
 311   cvs-qtypedesc-tag)
 312
 313 (defun cvs-set-secondary-branch-prefix (arg)
 314   "Set the branch prefix to take action at the next command.
 315 See `cvs-prefix-set' for a further the description of the behavior.
 316 \\[universal-argument] 1 selects the vendor branch
 317 and \\[universal-argument] 2 selects the HEAD."
 318   (interactive "P")
 319   (cvs-mode!)
 320   (cvs-prefix-set 'cvs-secondary-branch-prefix arg))
 321
 322 (defun cvs-add-secondary-branch-prefix (flags &optional arg)
 323   "Add branch selection argument if the secondary branch prefix was set.
 324 The argument is added (or not) to the list of FLAGS and is constructed
 325 by appending the branch to ARG which defaults to \"-r\".
 326 Since the `cvs-secondary-branch-prefix' is only active if the primary
 327 prefix is active, it is important to read the secondary prefix before
 328 the primay since reading the primary can deactivate it."
 329   (let ((branch (and (cvs-prefix-get 'cvs-branch-prefix 'read-only)
 330                      (cvs-prefix-get 'cvs-secondary-branch-prefix))))
 331     (if branch (cons (concat (or arg "-r") branch) flags) flags)))
 332
 333 ;;;;
 334
 335 (define-minor-mode cvs-minor-mode
 336   "This mode is used for buffers related to a main *cvs* buffer.
 337 All the `cvs-mode' buffer operations are simply rebound under
 338 the \\[cvs-mode-map] prefix."
 339   nil " CVS"
 340   :group 'pcl-cvs)
 341 (put 'cvs-minor-mode 'permanent-local t)
 342
 343
 344 (defvar cvs-temp-buffers nil)
 345 (defun cvs-temp-buffer (&optional cmd normal nosetup)
 346   "Create a temporary buffer to run CMD in.
 347 If CMD is a string, use it to lookup `cvs-buffer-name-alist' to find
 348 the buffer name to be used and its `major-mode'.
 349
 350 The selected window will not be changed.  The new buffer will not maintain undo
 351 information and will be read-only unless NORMAL is non-nil.  It will be emptied
 352 \(unless NOSETUP is non-nil\) and its `default-directory' will be inherited
 353 from the current buffer."
 354   (let* ((cvs-buf (current-buffer))
 355          (info (cdr (assoc cmd cvs-buffer-name-alist)))
 356          (name (eval (nth 0 info)))
 357          (mode (nth 1 info))
 358          (dir default-directory)
 359          (buf (cond
 360                (name (cvs-get-buffer-create name))
 361                ((and (bufferp cvs-temp-buffer) (buffer-name cvs-temp-buffer))
 362                 cvs-temp-buffer)
 363                (t
 364                 (set (make-local-variable 'cvs-temp-buffer)
 365                      (cvs-get-buffer-create
 366                       (eval cvs-temp-buffer-name) 'noreuse))))))
 367
 368     ;; handle the potential pre-existing process
 369     (let ((proc (get-buffer-process buf)))
 370       (when (and (not normal) (processp proc)
 371                  (memq (process-status proc) '(run stop)))
 372         (if cmd
 373             ;; When CMD is specified, the buffer is normally shown to the
 374             ;; user, so interrupting the process is not harmful.
 375             ;; Use `delete-process' rather than `kill-process' otherwise
 376             ;; the pending output of the process will still get inserted
 377             ;; after we erase the buffer.
 378             (delete-process proc)
 379           (error "Can not run two cvs processes simultaneously"))))
 380
 381     (if (not name) (kill-local-variable 'other-window-scroll-buffer)
 382       ;; Strangely, if no window is created, `display-buffer' ends up
 383       ;; doing a `switch-to-buffer' which does a `set-buffer', hence
 384       ;; the need for `save-excursion'.
 385       (unless nosetup (save-excursion (display-buffer buf)))
 386       ;; FIXME: this doesn't do the right thing if the user later on
 387       ;; does a `find-file-other-window' and `scroll-other-window'
 388       (set (make-local-variable 'other-window-scroll-buffer) buf))
 389
 390     (add-to-list 'cvs-temp-buffers buf)
 391
 392     (with-current-buffer buf
 393       (setq buffer-read-only nil)
 394       (setq default-directory dir)
 395       (unless nosetup (erase-buffer))
 396       (set (make-local-variable 'cvs-buffer) cvs-buf)
 397       ;;(cvs-minor-mode 1)
 398       (let ((lbd list-buffers-directory))
 399         (if (fboundp mode) (funcall mode) (fundamental-mode))
 400         (when lbd (set (make-local-variable 'list-buffers-directory) lbd)))
 401       (cvs-minor-mode 1)
 402       ;;(set (make-local-variable 'cvs-buffer) cvs-buf)
 403       (unless normal
 404         (setq buffer-read-only t)
 405         (buffer-disable-undo))
 406       buf)))
 407
 408 (defun cvs-mode-kill-buffers ()
 409   "Kill all the \"temporary\" buffers created by the *cvs* buffer."
 410   (interactive)
 411   (dolist (buf cvs-temp-buffers) (ignore-errors (kill-buffer buf))))
 412
 413 (defun cvs-make-cvs-buffer (dir &optional new)
 414   "Create the *cvs* buffer for directory DIR.
 415 If non-nil, NEW means to create a new buffer no matter what."
 416   ;; the real cvs-buffer creation
 417   (setq dir (cvs-expand-dir-name dir))
 418   (let* ((buffer-name (eval cvs-buffer-name))
 419          (buffer
 420           (or (and (not new)
 421                    (eq cvs-reuse-cvs-buffer 'current)
 422                    (cvs-buffer-p)       ;reuse the current buffer if possible
 423                    (current-buffer))
 424               ;; look for another cvs buffer visiting the same directory
 425               (save-excursion
 426                 (unless new
 427                   (dolist (buffer (cons (current-buffer) (buffer-list)))
 428                     (set-buffer buffer)
 429                     (and (cvs-buffer-p)
 430                          (case cvs-reuse-cvs-buffer
 431                            (always t)
 432                            (subdir
 433                             (or (cvs-string-prefix-p default-directory dir)
 434                                 (cvs-string-prefix-p dir default-directory)))
 435                            (samedir (string= default-directory dir)))
 436                          (return buffer)))))
 437               ;; we really have to create a new buffer:
 438               ;; we temporarily bind cwd to "" to prevent
 439               ;; create-file-buffer from using directory info
 440               ;; unless it is explicitly in the cvs-buffer-name.
 441               (cvs-get-buffer-create buffer-name new))))
 442     (with-current-buffer buffer
 443       (or
 444        (and (string= dir default-directory) (cvs-buffer-p)
 445             ;; just a refresh
 446             (ignore-errors
 447               (cvs-cleanup-collection cvs-cookies nil nil t)
 448               (current-buffer)))
 449        ;; setup from scratch
 450        (progn
 451          (setq default-directory dir)
 452          (setq buffer-read-only nil)
 453          (erase-buffer)
 454          (insert "Repository : " (directory-file-name (cvs-get-cvsroot))
 455                  "\nModule     : " (cvs-get-module)
 456                  "\nWorking dir: " (abbreviate-file-name dir)
 457                  (if (not (file-readable-p "CVS/Tag")) "\n"
 458                    (let ((tag (cvs-file-to-string "CVS/Tag")))
 459                      (cond
 460                       ((string-match "\\`T" tag)
 461                        (concat "\nTag        : " (substring tag 1)))
 462                       ((string-match "\\`D" tag)
 463                        (concat "\nDate       : " (substring tag 1)))
 464                       ("\n"))))
 465                  "\n")
 466          (setq buffer-read-only t)
 467          (cvs-mode)
 468          (set (make-local-variable 'list-buffers-directory) buffer-name)
 469          ;;(set (make-local-variable 'cvs-temp-buffer) (cvs-temp-buffer))
 470          (let ((cookies (ewoc-create 'cvs-fileinfo-pp "\n" "")))
 471            (set (make-local-variable 'cvs-cookies) cookies)
 472            (add-hook 'kill-buffer-hook
 473                      (lambda ()
 474                        (ignore-errors (kill-buffer cvs-temp-buffer)))
 475                      nil t)
 476            ;;(set-buffer buf)
 477            buffer))))))
 478
 479 (defun* cvs-cmd-do (cmd dir flags fis new
 480                         &key cvsargs noexist dont-change-disc noshow)
 481   (let* ((dir (file-name-as-directory
 482                (abbreviate-file-name (expand-file-name dir))))
 483          (cvsbuf (cvs-make-cvs-buffer dir new)))
 484     ;; Check that dir is under CVS control.
 485     (unless (file-directory-p dir)
 486       (error "%s is not a directory" dir))
 487     (unless (or noexist (file-directory-p (expand-file-name "CVS" dir))
 488                 (file-expand-wildcards (expand-file-name "*/CVS" dir)))
 489       (error "%s does not contain CVS controlled files" dir))
 490
 491     (set-buffer cvsbuf)
 492     (cvs-mode-run cmd flags fis
 493                   :cvsargs cvsargs :dont-change-disc dont-change-disc)
 494
 495     (if noshow cvsbuf
 496       (let ((pop-up-windows nil)) (pop-to-buffer cvsbuf)))))
 497 ;;      (funcall (if (and (boundp 'pop-up-frames) pop-up-frames)
 498 ;;                 'pop-to-buffer 'switch-to-buffer)
 499 ;;             cvsbuf))))
 500
 501 (defun cvs-run-process (args fis postprocess &optional single-dir)
 502   (assert (cvs-buffer-p cvs-buffer))
 503   (save-current-buffer
 504     (let ((procbuf (current-buffer))
 505           (cvsbuf cvs-buffer)
 506           (single-dir (or single-dir (eq cvs-execute-single-dir t))))
 507
 508       (set-buffer procbuf)
 509       (goto-char (point-max))
 510       (unless (bolp) (let ((inhibit-read-only t)) (insert "\n")))
 511       ;; find the set of files we'll process in this round
 512       (let* ((dir+files+rest
 513               (if (or (null fis) (not single-dir))
 514                   ;; not single-dir mode: just process the whole thing
 515                   (list "" (mapcar 'cvs-fileinfo->full-path fis) nil)
 516                 ;; single-dir mode: extract the same-dir-elements
 517                 (let ((dir (cvs-fileinfo->dir (car fis))))
 518                   ;; output the concerned dir so the parser can translate paths
 519                   (let ((inhibit-read-only t))
 520                     (insert "pcl-cvs: descending directory " dir "\n"))
 521                   ;; loop to find the same-dir-elems
 522                   (do* ((files () (cons (cvs-fileinfo->file fi) files))
 523                         (fis fis (cdr fis))
 524                         (fi (car fis) (car fis)))
 525                       ((not (and fis (string= dir (cvs-fileinfo->dir fi))))
 526                        (list dir files fis))))))
 527              (dir (nth 0 dir+files+rest))
 528              (files (nth 1 dir+files+rest))
 529              (rest (nth 2 dir+files+rest)))
 530
 531         ;; setup the (current) process buffer
 532         (set (make-local-variable 'cvs-postprocess)
 533              (if (null rest)
 534                  ;; this is the last invocation
 535                  postprocess
 536                ;; else, we have to register ourselves to be rerun on the rest
 537                `(cvs-run-process ',args ',rest ',postprocess ',single-dir)))
 538         (add-hook 'kill-buffer-hook
 539                   (lambda ()
 540                     (let ((proc (get-buffer-process (current-buffer))))
 541                       (when (processp proc)
 542                         (set-process-filter proc nil)
 543                         (set-process-sentinel proc nil)
 544                         (delete-process proc))))
 545                   nil t)
 546
 547         ;; create the new process and setup the procbuffer correspondingly
 548         (let* ((args (append (cvs-flags-query 'cvs-cvs-flags nil 'noquery)
 549                              (if cvs-cvsroot (list "-d" cvs-cvsroot))
 550                              args
 551                              files))
 552                ;; If process-connection-type is nil and the repository
 553                ;; is accessed via SSH, a bad interaction between libc,
 554                ;; CVS and SSH can lead to garbled output.
 555                ;; It might be a glibc-specific problem (but it also happens
 556                ;; under Mac OS X, it seems).
 557                ;; Until the problem is cleared, we'll use a pty rather than
 558                ;; a pipe.
 559                ;; (process-connection-type nil) ; Use a pipe, not a pty.
 560                (process
 561                 ;; the process will be run in the selected dir
 562                 (let ((default-directory (cvs-expand-dir-name dir)))
 563                   (apply 'start-process "cvs" procbuf cvs-program args))))
 564           (set-process-sentinel process 'cvs-sentinel)
 565           (set-process-filter process 'cvs-update-filter)
 566           (set-marker (process-mark process) (point-max))
 567           (ignore-errors (process-send-eof process)) ;close its stdin to avoid hangs
 568
 569           ;; now finish setting up the cvs-buffer
 570           (set-buffer cvsbuf)
 571           (setq cvs-mode-line-process (symbol-name (process-status process)))
 572           (force-mode-line-update)))))
 573
 574   ;; The following line is said to improve display updates on some
 575   ;; emacsen. It shouldn't be needed, but it does no harm.
 576   (sit-for 0))
 577
 578 (defun cvs-update-header (args fis) ; inline
 579   (let* ((lastarg nil)
 580          (args (mapcar (lambda (arg)
 581                          (cond
 582                           ;; filter out the largish commit message
 583                           ((and (eq lastarg nil) (string= arg "commit"))
 584                            (setq lastarg 'commit) arg)
 585                           ((and (eq lastarg 'commit) (string= arg "-m"))
 586                            (setq lastarg '-m) arg)
 587                           ((eq lastarg '-m)
 588                            (setq lastarg 'done) "<log message>")
 589                           ;; filter out the largish `admin -mrev:msg' message
 590                           ((and (eq lastarg nil) (string= arg "admin"))
 591                            (setq lastarg 'admin) arg)
 592                           ((and (eq lastarg 'admin)
 593                                 (string-match "\\`-m[^:]*:" arg))
 594                            (setq lastarg 'done)
 595                            (concat (match-string 0 arg) "<log message>"))
 596                           ;; Keep the rest as is.
 597                           (t arg)))
 598                        args))
 599          ;; turn them into a string
 600          (arg (cvs-strings->string
 601                (append (cvs-flags-query 'cvs-cvs-flags nil 'noquery)
 602                        (if cvs-cvsroot (list "-d" cvs-cvsroot))
 603                        args
 604                        (mapcar 'cvs-fileinfo->full-path fis))))
 605          (str (if args (concat "-- Running " cvs-program " " arg " ...\n")
 606                 "\n")))
 607     (if nil (insert str)                ;inline
 608       ;;(with-current-buffer cvs-buffer
 609       (let* ((prev-msg (car (ewoc-get-hf cvs-cookies)))
 610              (tin (ewoc-nth cvs-cookies 0)))
 611         ;; look for the first *real* fileinfo (to determine emptyness)
 612         (while
 613             (and tin
 614                  (memq (cvs-fileinfo->type (ewoc-data tin))
 615                        '(MESSAGE DIRCHANGE)))
 616           (setq tin (ewoc-next cvs-cookies tin)))
 617         ;; cleanup the prev-msg
 618         (when (string-match "Running \\(.*\\) ...\n" prev-msg)
 619           (setq prev-msg
 620                 (concat
 621                  "-- last cmd: "
 622                  (match-string 1 prev-msg)
 623                  " --")))
 624         ;; set the new header and footer
 625         (ewoc-set-hf cvs-cookies
 626                      str (concat "\n--------------------- "
 627                                  (if tin "End" "Empty")
 628                                  " ---------------------\n"
 629                                  prev-msg))))))
 630
 631
 632 (defun cvs-sentinel (proc msg)
 633   "Sentinel for the cvs update process.
 634 This is responsible for parsing the output from the cvs update when
 635 it is finished."
 636   (when (memq (process-status proc) '(signal exit))
 637     (if (null (buffer-name (process-buffer proc)))
 638         ;;(set-process-buffer proc nil)
 639         (error "cvs' process buffer was killed")
 640       (let* ((obuf (current-buffer))
 641              (procbuffer (process-buffer proc)))
 642         (set-buffer (with-current-buffer procbuffer cvs-buffer))
 643         (setq cvs-mode-line-process (symbol-name (process-status proc)))
 644         (force-mode-line-update)
 645         (set-buffer procbuffer)
 646         (let ((cvs-postproc cvs-postprocess))
 647           ;; Since the buffer and mode line will show that the
 648           ;; process is dead, we can delete it now.  Otherwise it
 649           ;; will stay around until M-x list-processes.
 650           (delete-process proc)
 651           (setq cvs-postprocess nil)
 652           ;; do the postprocessing like parsing and such
 653           (save-excursion (eval cvs-postproc))
 654           ;; check whether something is left
 655           (unless cvs-postprocess
 656             ;; IIRC, we enable undo again once the process is finished
 657             ;; for cases where the output was inserted in *vc-diff* or
 658             ;; in a file-like buffer.  -stef
 659             (buffer-enable-undo)
 660             (with-current-buffer cvs-buffer
 661               (cvs-update-header nil nil) ;FIXME: might need to be inline
 662               (message "CVS process has completed in %s" (buffer-name)))))
 663         ;; This might not even be necessary
 664         (set-buffer obuf)))))
 665
 666 (defun cvs-parse-process (dcd &optional subdir old-fis)
 667   "Parse the output of a cvs process.
 668 DCD is the `dont-change-disc' flag to use when parsing that output.
 669 SUBDIR is the subdirectory (if any) where this command was run.
 670 OLD-FIS is the list of fileinfos on which the cvs command was applied and
 671   which should be considered up-to-date if they are missing from the output."
 672   (when (eq system-type 'darwin)
 673     ;; Fixup the ^D^H^H inserted at beginning of buffer sometimes on MacOSX
 674     ;; because of the call to `process-send-eof'.
 675     (save-excursion
 676       (goto-char (point-min))
 677       (while (re-search-forward "^\\^D\b+" nil t)
 678         (let ((inhibit-read-only t))
 679           (delete-region (match-beginning 0) (match-end 0))))))
 680   (let* ((fileinfos (cvs-parse-buffer 'cvs-parse-table dcd subdir))
 681          last)
 682     (with-current-buffer cvs-buffer
 683       ;; Expand OLD-FIS to actual files.
 684       (let ((fis nil))
 685         (dolist (fi old-fis)
 686           (setq fis (if (eq (cvs-fileinfo->type fi) 'DIRCHANGE)
 687                         (nconc (ewoc-collect cvs-cookies 'cvs-dir-member-p
 688                                              (cvs-fileinfo->dir fi))
 689                                fis)
 690                       (cons fi fis))))
 691         (setq old-fis fis))
 692       ;; Drop OLD-FIS which were already up-to-date.
 693       (let ((fis nil))
 694         (dolist (fi old-fis)
 695           (unless (eq (cvs-fileinfo->type fi) 'UP-TO-DATE) (push fi fis)))
 696         (setq old-fis fis))
 697       ;; Add the new fileinfos to the ewoc.
 698       (dolist (fi fileinfos)
 699         (setq last (cvs-addto-collection cvs-cookies fi last))
 700         ;; This FI was in the output, so remove it from OLD-FIS.
 701         (setq old-fis (delq (ewoc-data last) old-fis)))
 702       ;; Process the "silent output" (i.e. absence means up-to-date).
 703       (dolist (fi old-fis)
 704         (setf (cvs-fileinfo->type fi) 'UP-TO-DATE)
 705         (setq last (cvs-addto-collection cvs-cookies fi last)))
 706       (setq fileinfos (nconc old-fis fileinfos))
 707       ;; Clean up the ewoc as requested by the user.
 708       (cvs-cleanup-collection cvs-cookies
 709                               (eq cvs-auto-remove-handled t)
 710                               cvs-auto-remove-directories
 711                               nil)
 712       ;; Revert buffers if necessary.
 713       (when (and cvs-auto-revert (not dcd) (not cvs-from-vc))
 714         (cvs-revert-if-needed fileinfos)))))
 715
 716 (defmacro defun-cvs-mode (fun args docstring interact &rest body)
 717   "Define a function to be used in a *cvs* buffer.
 718 This will look for a *cvs* buffer and execute BODY in it.
 719 Since the interactive arguments might need to be queried after
 720 switching to the *cvs* buffer, the generic code is rather ugly,
 721 but luckily we can often use simpler alternatives.
 722
 723 FUN can be either a symbol (i.e. STYLE is nil) or a cons (FUN . STYLE).
 724 ARGS and DOCSTRING are the normal argument list.
 725 INTERACT is the interactive specification or nil for non-commands.
 726
 727 STYLE can be either SIMPLE, NOARGS or DOUBLE.  It's an error for it
 728 to have any other value, unless other details of the function make it
 729 clear what alternative to use.
 730 - SIMPLE will get all the interactive arguments from the original buffer.
 731 - NOARGS will get all the arguments from the *cvs* buffer and will
 732   always behave as if called interactively.
 733 - DOUBLE is the generic case."
 734   (declare (debug (&define sexp lambda-list stringp ("interactive" interactive) def-body)))
 735   (let ((style (cvs-cdr fun))
 736         (fun (cvs-car fun)))
 737     (cond
 738      ;; a trivial interaction, no need to move it
 739      ((or (eq style 'SIMPLE)
 740           (null (nth 1 interact))
 741           (stringp (nth 1 interact)))
 742       `(defun ,fun ,args ,docstring ,interact
 743          (cvs-mode! (lambda () ,@body))))
 744
 745      ;; fun is only called interactively:  move all the args to the inner fun
 746      ((eq style 'NOARGS)
 747       `(defun ,fun () ,docstring (interactive)
 748          (cvs-mode! (lambda ,args ,interact ,@body))))
 749
 750      ;; bad case
 751      ((eq style 'DOUBLE)
 752       (string-match ".*" docstring)
 753       (let ((line1 (match-string 0 docstring))
 754             (fun-1 (intern (concat (symbol-name fun) "-1"))))
 755         `(progn
 756            (defun ,fun-1 ,args
 757              ,(concat docstring "\nThis function only works within a *cvs* buffer.
 758 For interactive use, use `" (symbol-name fun) "' instead.")
 759              ,interact
 760              ,@body)
 761            (defun ,fun ()
 762              ,(concat line1 "\nWrapper function that switches to a *cvs* buffer
 763 before calling the real function `" (symbol-name fun-1) "'.\n")
 764              (interactive)
 765              (cvs-mode! ',fun-1)))))
 766
 767      (t (error "Unknown style %s in `defun-cvs-mode'" style)))))
 768
 769 (defun-cvs-mode cvs-mode-kill-process ()
 770   "Kill the temporary buffer and associated process."
 771   (interactive)
 772   (when (and (bufferp cvs-temp-buffer) (buffer-name cvs-temp-buffer))
 773     (let ((proc (get-buffer-process cvs-temp-buffer)))
 774       (when proc (delete-process proc)))))
 775
 776 ;;
 777 ;; Maintaining the collection in the face of updates
 778 ;;
 779
 780 (defun cvs-addto-collection (c fi &optional tin)
 781   "Add FI to C and return FI's corresponding tin.
 782 FI is inserted in its proper place or maybe even merged with a preexisting
 783   fileinfo if applicable.
 784 TIN specifies an optional starting point."
 785   (unless tin (setq tin (ewoc-nth c 0)))
 786   (while (and tin (cvs-fileinfo< fi (ewoc-data tin)))
 787     (setq tin (ewoc-prev c tin)))
 788   (if (null tin) (ewoc-enter-first c fi) ;empty collection
 789     (assert (not (cvs-fileinfo< fi (ewoc-data tin))))
 790     (let ((next-tin (ewoc-next c tin)))
 791       (while (not (or (null next-tin)
 792                       (cvs-fileinfo< fi (ewoc-data next-tin))))
 793         (setq tin next-tin next-tin (ewoc-next c next-tin)))
 794       (if (or (cvs-fileinfo< (ewoc-data tin) fi)
 795               (eq (cvs-fileinfo->type  fi) 'MESSAGE))
 796           ;; tin < fi < next-tin
 797           (ewoc-enter-after c tin fi)
 798         ;; fi == tin
 799         (cvs-fileinfo-update (ewoc-data tin) fi)
 800         (ewoc-invalidate c tin)
 801         ;; Move cursor back to where it belongs.
 802         (when (bolp) (cvs-move-to-goal-column))
 803         tin))))
 804
 805 (defcustom cvs-cleanup-functions nil
 806   "Functions to tweak the cleanup process.
 807 The functions are called with a single argument (a FILEINFO) and should
 808 return a non-nil value if that fileinfo should be removed."
 809   :group 'pcl-cvs
 810   :type '(hook :options (cvs-cleanup-removed)))
 811
 812 (defun cvs-cleanup-removed (fi)
 813   "Non-nil if FI has been cvs-removed but still exists.
 814 This is intended for use on `cvs-cleanup-functions' when you have cvs-removed
 815 automatically generated files (which should hence not be under CVS control)
 816 but can't commit the removal because the repository's owner doesn't understand
 817 the problem."
 818   (and (or (eq (cvs-fileinfo->type fi) 'REMOVED)
 819            (and (eq (cvs-fileinfo->type fi) 'CONFLICT)
 820                 (eq (cvs-fileinfo->subtype fi) 'REMOVED)))
 821        (file-exists-p (cvs-fileinfo->full-path fi))))
 822
 823 ;; called at the following times:
 824 ;; - postparse  ((eq cvs-auto-remove-handled t) cvs-auto-remove-directories nil)
 825 ;; - pre-run    ((eq cvs-auto-remove-handled 'delayed) nil t)
 826 ;; - remove-handled (t (or cvs-auto-remove-directories 'handled) t)
 827 ;; - cvs-cmd-do (nil nil t)
 828 ;; - post-ignore (nil nil nil)
 829 ;; - acknowledge (nil nil nil)
 830 ;; - remove     (nil nil nil)
 831 (defun cvs-cleanup-collection (c rm-handled rm-dirs rm-msgs)
 832   "Remove undesired entries.
 833 C is the collection
 834 RM-HANDLED if non-nil means remove handled entries.
 835 RM-DIRS behaves like `cvs-auto-remove-directories'.
 836 RM-MSGS if non-nil means remove messages."
 837   (let (last-fi first-dir (rerun t))
 838     (while rerun
 839       (setq rerun nil)
 840       (setq first-dir t)
 841       (setq last-fi (cvs-create-fileinfo 'DEAD "../" "" "")) ;place-holder
 842       (ewoc-filter
 843        c (lambda (fi)
 844            (let* ((type (cvs-fileinfo->type fi))
 845                   (subtype (cvs-fileinfo->subtype fi))
 846                   (keep
 847                    (case type
 848                      ;; remove temp messages and keep the others
 849                      (MESSAGE (not (or rm-msgs (eq subtype 'TEMP))))
 850                      ;; remove entries
 851                      (DEAD nil)
 852                      ;; handled also?
 853                      (UP-TO-DATE (not rm-handled))
 854                      ;; keep the rest
 855                      (t (not (run-hook-with-args-until-success
 856                               'cvs-cleanup-functions fi))))))
 857
 858              ;; mark dirs for removal
 859              (when (and keep rm-dirs
 860                         (eq (cvs-fileinfo->type last-fi) 'DIRCHANGE)
 861                         (not (when first-dir (setq first-dir nil) t))
 862                         (or (eq rm-dirs 'all)
 863                             (not (cvs-string-prefix-p
 864                                   (cvs-fileinfo->dir last-fi)
 865                                   (cvs-fileinfo->dir fi)))
 866                             (and (eq type 'DIRCHANGE) (eq rm-dirs 'empty))
 867                             (eq subtype 'FOOTER)))
 868                (setf (cvs-fileinfo->type last-fi) 'DEAD)
 869                (setq rerun t))
 870              (when keep (setq last-fi fi)))))
 871       ;; remove empty last dir
 872       (when (and rm-dirs
 873                  (not first-dir)
 874                  (eq (cvs-fileinfo->type last-fi) 'DIRCHANGE))
 875         (setf (cvs-fileinfo->type last-fi) 'DEAD)
 876         (setq rerun t)))))
 877
 878 (defun cvs-get-cvsroot ()
 879   "Gets the CVSROOT for DIR."
 880   (let ((cvs-cvsroot-file (expand-file-name "Root" "CVS")))
 881     (or (cvs-file-to-string cvs-cvsroot-file t)
 882         cvs-cvsroot
 883         (getenv "CVSROOT")
 884         "?????")))
 885
 886 (defun cvs-get-module ()
 887   "Return the current CVS module.
 888 This usually doesn't really work but is a handy initval in a prompt."
 889   (let* ((repfile (expand-file-name "Repository" "CVS"))
 890          (rep (cvs-file-to-string repfile t)))
 891     (cond
 892      ((null rep) "")
 893      ((not (file-name-absolute-p rep)) rep)
 894      (t
 895       (let* ((root (cvs-get-cvsroot))
 896              (str (concat (file-name-as-directory (or root "/")) " || " rep)))
 897         (if (and root (string-match "\\(.*\\) || \\1\\(.*\\)\\'" str))
 898             (match-string 2 str)
 899           (file-name-nondirectory rep)))))))
 900
 901
 902 \f
 903 ;;;;
 904 ;;;; running a "cvs checkout".
 905 ;;;;
 906
 907 ;;;###autoload
 908 (defun cvs-checkout (modules dir flags)
 909   "Run a 'cvs checkout MODULES' in DIR.
 910 Feed the output to a *cvs* buffer, display it in the current window,
 911 and run `cvs-mode' on it.
 912
 913 With a prefix argument, prompt for cvs FLAGS to use."
 914   (interactive
 915    (list (cvs-string->strings (read-string "Module(s): " (cvs-get-module)))
 916          (read-directory-name "CVS Checkout Directory: "
 917                          nil default-directory nil)
 918          (cvs-add-branch-prefix
 919           (cvs-flags-query 'cvs-checkout-flags "cvs checkout flags"))))
 920   (when (eq flags t)
 921     (setf flags (cvs-flags-query 'cvs-checkout-flags nil 'noquery)))
 922   (cvs-cmd-do "checkout" (or dir default-directory)
 923               (append flags modules) nil 'new
 924               :noexist t))
 925
 926 (defun-cvs-mode (cvs-mode-checkout . NOARGS) (dir)
 927   "Run cvs checkout against the current branch.
 928 The files are stored to DIR."
 929   (interactive
 930    (let* ((branch (cvs-prefix-get 'cvs-branch-prefix))
 931           (prompt (format "CVS Checkout Directory for `%s%s': "
 932                          (cvs-get-module)
 933                          (if branch (format " (branch: %s)" branch)
 934                            ""))))
 935      (list (read-directory-name prompt nil default-directory nil))))
 936   (let ((modules (cvs-string->strings (cvs-get-module)))
 937         (flags (cvs-add-branch-prefix
 938                 (cvs-flags-query 'cvs-checkout-flags "cvs checkout flags")))
 939         (cvs-cvsroot (cvs-get-cvsroot)))
 940     (cvs-checkout modules dir flags)))
 941 \f
 942 ;;;;
 943 ;;;; The code for running a "cvs update" and friends in various ways.
 944 ;;;;
 945
 946 (defun-cvs-mode (cvs-mode-revert-buffer . SIMPLE)
 947                 (&optional ignore-auto noconfirm)
 948   "Rerun `cvs-examine' on the current directory with the default flags."
 949   (interactive)
 950   (cvs-examine default-directory t))
 951
 952 (defun cvs-query-directory (msg)
 953   ;; last-command-char = ?\r hints that the command was run via M-x
 954   (if (and (cvs-buffer-p)
 955            (not current-prefix-arg)
 956            (not (eq last-command-char ?\r)))
 957       default-directory
 958     (read-directory-name msg nil default-directory nil)))
 959
 960 ;;;###autoload
 961 (defun cvs-quickdir (dir &optional flags noshow)
 962   "Open a *cvs* buffer on DIR without running cvs.
 963 With a prefix argument, prompt for a directory to use.
 964 A prefix arg >8 (ex: \\[universal-argument] \\[universal-argument]),
 965   prevents reuse of an existing *cvs* buffer.
 966 Optional argument NOSHOW if non-nil means not to display the buffer.
 967 FLAGS is ignored."
 968   (interactive (list (cvs-query-directory "CVS quickdir (directory): ")))
 969   ;; FIXME: code duplication with cvs-cmd-do and cvs-parse-process
 970   (let* ((dir (file-name-as-directory
 971                (abbreviate-file-name (expand-file-name dir))))
 972          (new (> (prefix-numeric-value current-prefix-arg) 8))
 973          (cvsbuf (cvs-make-cvs-buffer dir new))
 974          last)
 975     ;; Check that dir is under CVS control.
 976     (unless (file-directory-p dir)
 977       (error "%s is not a directory" dir))
 978     (unless (file-directory-p (expand-file-name "CVS" dir))
 979       (error "%s does not contain CVS controlled files" dir))
 980     (set-buffer cvsbuf)
 981     (dolist (fi (cvs-fileinfo-from-entries ""))
 982       (setq last (cvs-addto-collection cvs-cookies fi last)))
 983     (cvs-cleanup-collection cvs-cookies
 984                             (eq cvs-auto-remove-handled t)
 985                             cvs-auto-remove-directories
 986                             nil)
 987     (if noshow cvsbuf
 988       (let ((pop-up-windows nil)) (pop-to-buffer cvsbuf)))))
 989
 990 ;;;###autoload
 991 (defun cvs-examine (directory flags &optional noshow)
 992   "Run a `cvs -n update' in the specified DIRECTORY.
 993 That is, check what needs to be done, but don't change the disc.
 994 Feed the output to a *cvs* buffer and run `cvs-mode' on it.
 995 With a prefix argument, prompt for a directory and cvs FLAGS to use.
 996 A prefix arg >8 (ex: \\[universal-argument] \\[universal-argument]),
 997   prevents reuse of an existing *cvs* buffer.
 998 Optional argument NOSHOW if non-nil means not to display the buffer."
 999   (interactive (list (cvs-query-directory "CVS Examine (directory): ")
1000                      (cvs-flags-query 'cvs-update-flags "cvs -n update flags")))
1001   (when (eq flags t)
1002     (setf flags (cvs-flags-query 'cvs-update-flags nil 'noquery)))
1003   (when find-file-visit-truename (setq directory (file-truename directory)))
1004   (cvs-cmd-do "update" directory flags nil
1005               (> (prefix-numeric-value current-prefix-arg) 8)
1006               :cvsargs '("-n")
1007               :noshow noshow
1008               :dont-change-disc t))
1009
1010
1011 ;;;###autoload
1012 (defun cvs-update (directory flags)
1013   "Run a `cvs update' in the current working DIRECTORY.
1014 Feed the output to a *cvs* buffer and run `cvs-mode' on it.
1015 With a \\[universal-argument] prefix argument, prompt for a directory to use.
1016 A prefix arg >8 (ex: \\[universal-argument] \\[universal-argument]),
1017   prevents reuse of an existing *cvs* buffer.
1018 The prefix is also passed to `cvs-flags-query' to select the FLAGS
1019   passed to cvs."
1020   (interactive (list (cvs-query-directory "CVS Update (directory): ")
1021                      (cvs-flags-query 'cvs-update-flags "cvs update flags")))
1022   (when (eq flags t)
1023     (setf flags (cvs-flags-query 'cvs-update-flags nil 'noquery)))
1024   (cvs-cmd-do "update" directory flags nil
1025               (> (prefix-numeric-value current-prefix-arg) 8)))
1026
1027
1028 ;;;###autoload
1029 (defun cvs-status (directory flags &optional noshow)
1030   "Run a `cvs status' in the current working DIRECTORY.
1031 Feed the output to a *cvs* buffer and run `cvs-mode' on it.
1032 With a prefix argument, prompt for a directory and cvs FLAGS to use.
1033 A prefix arg >8 (ex: \\[universal-argument] \\[universal-argument]),
1034   prevents reuse of an existing *cvs* buffer.
1035 Optional argument NOSHOW if non-nil means not to display the buffer."
1036   (interactive (list (cvs-query-directory "CVS Status (directory): ")
1037                      (cvs-flags-query 'cvs-status-flags "cvs status flags")))
1038   (when (eq flags t)
1039     (setf flags (cvs-flags-query 'cvs-status-flags nil 'noquery)))
1040   (cvs-cmd-do "status" directory flags nil
1041               (> (prefix-numeric-value current-prefix-arg) 8)
1042               :noshow noshow :dont-change-disc t))
1043
1044 (defun cvs-update-filter (proc string)
1045   "Filter function for pcl-cvs.
1046 This function gets the output that CVS sends to stdout.  It inserts
1047 the STRING into (process-buffer PROC) but it also checks if CVS is waiting
1048 for a lock file.  If so, it inserts a message cookie in the *cvs* buffer."
1049   (save-match-data
1050     (with-current-buffer (process-buffer proc)
1051       (let ((inhibit-read-only t))
1052         (save-excursion
1053           ;; Insert the text, moving the process-marker.
1054           (goto-char (process-mark proc))
1055           (insert string)
1056           (set-marker (process-mark proc) (point))
1057           ;; FIXME: Delete any old lock message
1058           ;;(if (tin-nth cookies 1)
1059           ;;  (tin-delete cookies
1060           ;;          (tin-nth cookies 1)))
1061           ;; Check if CVS is waiting for a lock.
1062           (beginning-of-line 0)       ;Move to beginning of last complete line.
1063           (when (looking-at "^[ a-z]+: \\(.*waiting for .*lock in \\(.*\\)\\)$")
1064             (let ((msg (match-string 1))
1065                   (lock (match-string 2)))
1066               (with-current-buffer cvs-buffer
1067                 (set (make-local-variable 'cvs-lock-file) lock)
1068                 ;; display the lock situation in the *cvs* buffer:
1069                 (ewoc-enter-last
1070                  cvs-cookies
1071                  (cvs-create-fileinfo
1072                   'MESSAGE "" " "
1073                   (concat msg
1074                           (when (file-exists-p lock)
1075                             (substitute-command-keys
1076                              "\n\t(type \\[cvs-mode-delete-lock] to delete it)")))
1077                   :subtype 'TEMP))
1078                 (pop-to-buffer (current-buffer))
1079                 (goto-char (point-max))
1080                 (beep)))))))))
1081
1082 \f
1083 ;;;;
1084 ;;;; The cvs-mode and its associated commands.
1085 ;;;;
1086
1087 (cvs-prefix-define cvs-force-command "" "" '("/F") cvs-qtypedesc-string1)
1088 (defun-cvs-mode cvs-mode-force-command (arg)
1089   "Force the next cvs command to operate on all the selected files.
1090 By default, cvs commands only operate on files on which the command
1091 \"makes sense\".  This overrides the safety feature on the next cvs command.
1092 It actually behaves as a toggle.  If prefixed by \\[universal-argument] \\[universal-argument],
1093 the override will persist until the next toggle."
1094   (interactive "P")
1095   (cvs-prefix-set 'cvs-force-command arg))
1096
1097 (put 'cvs-mode 'mode-class 'special)
1098 (define-derived-mode cvs-mode nil "CVS"
1099   "Mode used for PCL-CVS, a frontend to CVS.
1100 Full documentation is in the Texinfo file."
1101   (setq mode-line-process
1102         '("" cvs-force-command cvs-ignore-marks-modif
1103           ":" (cvs-branch-prefix
1104                ("" cvs-branch-prefix (cvs-secondary-branch-prefix
1105                                       ("->" cvs-secondary-branch-prefix))))
1106           " " cvs-mode-line-process))
1107   (if buffer-file-name
1108       (error "Use M-x cvs-quickdir to get a *cvs* buffer."))
1109   (buffer-disable-undo)
1110   ;;(set (make-local-variable 'goal-column) cvs-cursor-column)
1111   (set (make-local-variable 'revert-buffer-function) 'cvs-mode-revert-buffer)
1112   (setq truncate-lines t)
1113   (cvs-prefix-make-local 'cvs-branch-prefix)
1114   (cvs-prefix-make-local 'cvs-secondary-branch-prefix)
1115   (cvs-prefix-make-local 'cvs-force-command)
1116   (cvs-prefix-make-local 'cvs-ignore-marks-modif)
1117   (make-local-variable 'cvs-mode-line-process)
1118   (make-local-variable 'cvs-temp-buffers))
1119
1120
1121 (defun cvs-buffer-p (&optional buffer)
1122   "Return whether the (by default current) BUFFER is a `cvs-mode' buffer."
1123   (save-excursion
1124     (if buffer (set-buffer buffer))
1125     (and (eq major-mode 'cvs-mode))))
1126
1127 (defun cvs-buffer-check ()
1128   "Check that the current buffer follows cvs-buffer's conventions."
1129   (let ((buf (current-buffer))
1130         (check 'none))
1131     (or (and (setq check 'collection)
1132              (eq (ewoc-buffer cvs-cookies) buf)
1133              (setq check 'cvs-temp-buffer)
1134              (or (null cvs-temp-buffer)
1135                  (null (buffer-name cvs-temp-buffer))
1136                  (and (eq (with-current-buffer cvs-temp-buffer cvs-buffer) buf)
1137                       (equal (with-current-buffer cvs-temp-buffer
1138                                default-directory)
1139                              default-directory)))
1140              t)
1141         (error "Inconsistent %s in buffer %s" check (buffer-name buf)))))
1142
1143
1144 (defun cvs-mode-quit ()
1145   "Quit PCL-CVS, killing the *cvs* buffer."
1146   (interactive)
1147   (and (y-or-n-p "Quit pcl-cvs? ") (kill-buffer (current-buffer))))
1148
1149 ;; Give help....
1150
1151 (defun cvs-help ()
1152   "Display help for various PCL-CVS commands."
1153   (interactive)
1154   (if (eq last-command 'cvs-help)
1155       (describe-function 'cvs-mode)   ; would need minor-mode for log-edit-mode
1156     (message
1157      (substitute-command-keys
1158       "`\\[cvs-help]':help `\\[cvs-mode-add]':add `\\[cvs-mode-commit]':commit \
1159 `\\[cvs-mode-diff-map]':diff* `\\[cvs-mode-log]':log \
1160 `\\[cvs-mode-remove]':remove `\\[cvs-mode-status]':status \
1161 `\\[cvs-mode-undo]':undo"))))
1162
1163 ;; Move around in the buffer
1164
1165 (defun cvs-move-to-goal-column ()
1166   (let* ((eol (line-end-position))
1167          (fpos (next-single-property-change (point) 'cvs-goal-column nil eol)))
1168     (when (< fpos eol)
1169       (goto-char fpos))))
1170
1171 (defun-cvs-mode cvs-mode-previous-line (arg)
1172   "Go to the previous line.
1173 If a prefix argument is given, move by that many lines."
1174   (interactive "p")
1175   (ewoc-goto-prev cvs-cookies arg)
1176   (cvs-move-to-goal-column))
1177
1178 (defun-cvs-mode cvs-mode-next-line (arg)
1179   "Go to the next line.
1180 If a prefix argument is given, move by that many lines."
1181   (interactive "p")
1182   (ewoc-goto-next cvs-cookies arg)
1183   (cvs-move-to-goal-column))
1184
1185 ;;;;
1186 ;;;; Mark handling
1187 ;;;;
1188
1189 (defun-cvs-mode cvs-mode-mark (&optional arg)
1190   "Mark the fileinfo on the current line.
1191 If the fileinfo is a directory, all the contents of that directory are
1192 marked instead. A directory can never be marked."
1193   (interactive)
1194   (let* ((tin (ewoc-locate cvs-cookies))
1195          (fi (ewoc-data tin)))
1196     (if (eq (cvs-fileinfo->type fi) 'DIRCHANGE)
1197         ;; it's a directory: let's mark all files inside
1198         (ewoc-map
1199          (lambda (f dir)
1200            (when (cvs-dir-member-p f dir)
1201              (setf (cvs-fileinfo->marked f)
1202                    (not (if (eq arg 'toggle) (cvs-fileinfo->marked f) arg)))
1203              t))                        ;Tell cookie to redisplay this cookie.
1204          cvs-cookies
1205          (cvs-fileinfo->dir fi))
1206       ;; not a directory: just do the obvious
1207       (setf (cvs-fileinfo->marked fi)
1208             (not (if (eq arg 'toggle) (cvs-fileinfo->marked fi) arg)))
1209       (ewoc-invalidate cvs-cookies tin)
1210       (cvs-mode-next-line 1))))
1211
1212 (defalias 'cvs-mouse-toggle-mark 'cvs-mode-toggle-mark)
1213 (defun cvs-mode-toggle-mark (e)
1214   "Toggle the mark of the entry at point."
1215   (interactive (list last-input-event))
1216   (save-excursion
1217     (posn-set-point (event-end e))
1218     (cvs-mode-mark 'toggle)))
1219
1220 (defun-cvs-mode cvs-mode-unmark ()
1221   "Unmark the fileinfo on the current line."
1222   (interactive)
1223   (cvs-mode-mark t))
1224
1225 (defun-cvs-mode cvs-mode-mark-all-files ()
1226   "Mark all files."
1227   (interactive)
1228   (ewoc-map (lambda (cookie)
1229               (unless (eq (cvs-fileinfo->type cookie) 'DIRCHANGE)
1230                 (setf (cvs-fileinfo->marked cookie) t)))
1231             cvs-cookies))
1232
1233 (defun-cvs-mode (cvs-mode-mark-on-state . SIMPLE) (state)
1234   "Mark all files in state STATE."
1235   (interactive
1236    (list
1237     (let ((default
1238             (condition-case nil
1239                 (downcase
1240                  (symbol-name
1241                   (cvs-fileinfo->type
1242                    (cvs-mode-marked nil nil :read-only t :one t :noquery t))))
1243               (error nil))))
1244       (intern
1245        (upcase
1246         (completing-read
1247          (concat
1248           "Mark files in state" (if default (concat " [" default "]")) ": ")
1249          (mapcar (lambda (x)
1250                    (list (downcase (symbol-name (car x)))))
1251                  cvs-states)
1252          nil t nil nil default))))))
1253   (ewoc-map (lambda (fi)
1254               (when (eq (cvs-fileinfo->type fi) state)
1255                 (setf (cvs-fileinfo->marked fi) t)))
1256             cvs-cookies))
1257
1258 (defun-cvs-mode cvs-mode-mark-matching-files (regex)
1259   "Mark all files matching REGEX."
1260   (interactive "sMark files matching: ")
1261   (ewoc-map (lambda (cookie)
1262               (when (and (not (eq (cvs-fileinfo->type cookie) 'DIRCHANGE))
1263                          (string-match regex (cvs-fileinfo->file cookie)))
1264                 (setf (cvs-fileinfo->marked cookie) t)))
1265             cvs-cookies))
1266
1267 (defun-cvs-mode cvs-mode-unmark-all-files ()
1268   "Unmark all files.
1269 Directories are also unmarked, but that doesn't matter, since
1270 they should always be unmarked."
1271   (interactive)
1272   (ewoc-map (lambda (cookie)
1273               (setf (cvs-fileinfo->marked cookie) nil)
1274               t)
1275             cvs-cookies))
1276
1277 (defun-cvs-mode cvs-mode-unmark-up ()
1278   "Unmark the file on the previous line."
1279   (interactive)
1280   (let ((tin (ewoc-goto-prev cvs-cookies 1)))
1281     (when tin
1282       (setf (cvs-fileinfo->marked (ewoc-data tin)) nil)
1283       (ewoc-invalidate cvs-cookies tin)))
1284   (cvs-move-to-goal-column))
1285
1286 (defconst cvs-ignore-marks-alternatives
1287   '(("toggle-marks"     . "/TM")
1288     ("force-marks"      . "/FM")
1289     ("ignore-marks"     . "/IM")))
1290
1291 (cvs-prefix-define cvs-ignore-marks-modif
1292   "Prefix to decide whether to ignore marks or not."
1293   "active"
1294   (mapcar 'cdr cvs-ignore-marks-alternatives)
1295   (cvs-qtypedesc-create
1296    (lambda (str) (cdr (assoc str cvs-ignore-marks-alternatives)))
1297    (lambda (obj) (car (rassoc obj cvs-ignore-marks-alternatives)))
1298    (lambda () cvs-ignore-marks-alternatives)
1299    nil t))
1300
1301 (defun-cvs-mode cvs-mode-toggle-marks (arg)
1302   "Toggle whether the next CVS command uses marks.
1303 See `cvs-prefix-set' for further description of the behavior.
1304 \\[universal-argument] 1 selects `force-marks',
1305 \\[universal-argument] 2 selects `ignore-marks',
1306 \\[universal-argument] 3 selects `toggle-marks'."
1307   (interactive "P")
1308   (cvs-prefix-set 'cvs-ignore-marks-modif arg))
1309
1310 (defun cvs-ignore-marks-p (cmd &optional read-only)
1311   (let ((default (if (member cmd cvs-invert-ignore-marks)
1312                      (not cvs-default-ignore-marks)
1313                    cvs-default-ignore-marks))
1314         (modif (cvs-prefix-get 'cvs-ignore-marks-modif read-only)))
1315     (cond
1316      ((equal modif "/IM") t)
1317      ((equal modif "/TM") (not default))
1318      ((equal modif "/FM") nil)
1319      (t default))))
1320
1321 (defun cvs-mode-mark-get-modif (cmd)
1322   (if (cvs-ignore-marks-p cmd 'read-only) "/IM" "/FM"))
1323
1324 (defun cvs-get-marked (&optional ignore-marks ignore-contents)
1325   "Return a list of all selected fileinfos.
1326 If there are any marked tins, and IGNORE-MARKS is nil, return them.
1327 Otherwise, if the cursor selects a directory, and IGNORE-CONTENTS is
1328 nil, return all files in it, else return just the directory.
1329 Otherwise return (a list containing) the file the cursor points to, or
1330 an empty list if it doesn't point to a file at all."
1331   (let ((fis nil))
1332     (dolist (fi (if (and (boundp 'cvs-minor-current-files)
1333                          (consp cvs-minor-current-files))
1334                     (mapcar
1335                      (lambda (f)
1336                        (if (cvs-fileinfo-p f) f
1337                          (let ((f (file-relative-name f)))
1338                            (if (file-directory-p f)
1339                                (cvs-create-fileinfo
1340                                 'DIRCHANGE (file-name-as-directory f) "." "")
1341                              (let ((dir (file-name-directory f))
1342                                    (file (file-name-nondirectory f)))
1343                                (cvs-create-fileinfo
1344                                 'UNKNOWN (or dir "") file ""))))))
1345                      cvs-minor-current-files)
1346                   (or (and (not ignore-marks)
1347                            (ewoc-collect cvs-cookies 'cvs-fileinfo->marked))
1348                       (list (ewoc-data (ewoc-locate cvs-cookies))))))
1349
1350       (if (or ignore-contents (not (eq (cvs-fileinfo->type fi) 'DIRCHANGE)))
1351           (push fi fis)
1352         ;; If a directory is selected, return members, if any.
1353         (setq fis
1354               (append (ewoc-collect
1355                        cvs-cookies 'cvs-dir-member-p (cvs-fileinfo->dir fi))
1356                       fis))))
1357     (nreverse fis)))
1358
1359 (defun* cvs-mode-marked (filter &optional cmd
1360                                 &key read-only one file noquery)
1361   "Get the list of marked FIS.
1362 CMD is used to determine whether to use the marks or not.
1363 Only files for which FILTER is applicable are returned.
1364 If READ-ONLY is non-nil, the current toggling is left intact.
1365 If ONE is non-nil, marks are ignored and a single FI is returned.
1366 If FILE is non-nil, directory entries won't be selected."
1367   (unless cmd (setq cmd (symbol-name filter)))
1368   (let* ((fis (cvs-get-marked (or one (cvs-ignore-marks-p cmd read-only))
1369                               (and (not file)
1370                                    (cvs-applicable-p 'DIRCHANGE filter))))
1371          (force (cvs-prefix-get 'cvs-force-command))
1372          (fis (car (cvs-partition
1373                     (lambda (fi) (cvs-applicable-p fi (and (not force) filter)))
1374                     fis))))
1375     (when (and (or (null fis) (and one (cdr fis))) (not noquery))
1376       (message (if (null fis)
1377                    "`%s' is not applicable to any of the selected files."
1378                  "`%s' is only applicable to a single file.") cmd)
1379       (sit-for 1)
1380       (setq fis (list (cvs-insert-file
1381                        (read-file-name (format "File to %s: " cmd))))))
1382     (if one (car fis) fis)))
1383
1384 (defun cvs-enabledp (filter)
1385   "Determine whether FILTER applies to at least one of the selected files."
1386   (ignore-errors (cvs-mode-marked filter nil :read-only t :noquery t)))
1387
1388 (defun cvs-mode-files (&rest -cvs-mode-files-args)
1389   (cvs-mode!
1390    (lambda ()
1391      (mapcar 'cvs-fileinfo->full-path
1392              (apply 'cvs-mode-marked -cvs-mode-files-args)))))
1393
1394 ;;
1395 ;; Interface between Log-Edit and PCL-CVS
1396 ;;
1397
1398 (defun cvs-mode-commit-setup ()
1399   "Run `cvs-mode-commit' with setup."
1400   (interactive)
1401   (cvs-mode-commit 'force))
1402
1403 (defcustom cvs-mode-commit-hook nil
1404   "Hook run after setting up the commit buffer."
1405   :type 'hook
1406   :options '(cvs-mode-diff)
1407   :group 'pcl-cvs)
1408
1409 (defun cvs-mode-commit (setup)
1410   "Check in all marked files, or the current file.
1411 The user will be asked for a log message in a buffer.
1412 The buffer's mode and name is determined by the \"message\" setting
1413   of `cvs-buffer-name-alist'.
1414 The POSTPROC specified there (typically `log-edit') is then called,
1415   passing it the SETUP argument."
1416   (interactive "P")
1417   ;; It seems that the save-excursion that happens if I use the better
1418   ;; form of `(cvs-mode! (lambda ...))' screws up a couple things which
1419   ;; end up being rather annoying (like log-edit-mode's message being
1420   ;; displayed in the wrong minibuffer).
1421   (cvs-mode!)
1422   (let ((buf (cvs-temp-buffer "message" 'normal 'nosetup))
1423         (lbd list-buffers-directory)
1424         (setupfun (or (nth 2 (cdr (assoc "message" cvs-buffer-name-alist)))
1425                       'log-edit)))
1426     (funcall setupfun 'cvs-do-commit setup 'cvs-commit-filelist buf)
1427     (set (make-local-variable 'cvs-minor-wrap-function) 'cvs-commit-minor-wrap)
1428     (set (make-local-variable 'list-buffers-directory) lbd)
1429     (run-hooks 'cvs-mode-commit-hook)))
1430
1431 (defun cvs-commit-minor-wrap (buf f)
1432   (let ((cvs-ignore-marks-modif (cvs-mode-mark-get-modif "commit")))
1433     (funcall f)))
1434
1435 (defun cvs-commit-filelist ()
1436   (cvs-mode-files 'commit nil :read-only t :file t :noquery t))
1437
1438 (defun cvs-do-commit (flags)
1439   "Do the actual commit, using the current buffer as the log message."
1440   (interactive (list (cvs-flags-query 'cvs-commit-flags "cvs commit flags")))
1441   (let ((msg (buffer-substring-no-properties (point-min) (point-max))))
1442     (cvs-mode!)
1443     ;;(pop-to-buffer cvs-buffer)
1444     (cvs-mode-do "commit" (list* "-m" msg flags) 'commit)))
1445
1446
1447 ;;;; Editing existing commit log messages.
1448
1449 (defun cvs-edit-log-text-at-point ()
1450   (save-excursion
1451     (end-of-line)
1452     (when (re-search-backward "^revision " nil t)
1453       (forward-line 1)
1454       (if (looking-at "date:") (forward-line 1))
1455       (if (looking-at "branches:") (forward-line 1))
1456       (buffer-substring
1457        (point)
1458        (if (re-search-forward
1459             "^\\(-\\{28\\}\\|=\\{77\\}\\|revision [.0-9]+\\)$"
1460             nil t)
1461            (match-beginning 0)
1462          (point))))))
1463
1464 (defvar cvs-edit-log-revision)
1465 (defun cvs-mode-edit-log (rev &optional text)
1466   "Edit the log message at point.
1467 This is best called from a `log-view-mode' buffer."
1468   (interactive
1469    (list
1470     (or (cvs-mode! (lambda () (cvs-prefix-get 'cvs-branch-prefix)))
1471         (read-string "Revision to edit: "))
1472     (cvs-edit-log-text-at-point)))
1473   ;; It seems that the save-excursion that happens if I use the better
1474   ;; form of `(cvs-mode! (lambda ...))' screws up a couple things which
1475   ;; end up being rather annoying (like log-edit-mode's message being
1476   ;; displayed in the wrong minibuffer).
1477   (cvs-mode!)
1478   (let ((buf (cvs-temp-buffer "message" 'normal 'nosetup))
1479         (lbd list-buffers-directory)
1480         (setupfun (or (nth 2 (cdr (assoc "message" cvs-buffer-name-alist)))
1481                       'log-edit)))
1482     (funcall setupfun 'cvs-do-edit-log nil 'cvs-edit-log-filelist buf)
1483     (when text (erase-buffer) (insert text))
1484     (set (make-local-variable 'cvs-edit-log-revision) rev)
1485     (set (make-local-variable 'cvs-minor-wrap-function) 'cvs-edit-log-minor-wrap)
1486     (set (make-local-variable 'list-buffers-directory) lbd)
1487     ;; (run-hooks 'cvs-mode-commit-hook)
1488     ))
1489
1490 (defun cvs-edit-log-minor-wrap (buf f)
1491   (let ((cvs-ignore-marks-modif (cvs-mode-mark-get-modif "commit")))
1492     (funcall f)))
1493
1494 (defun cvs-edit-log-filelist ()
1495   (cvs-mode-files nil nil :read-only t :file t :noquery t))
1496
1497 (defun cvs-do-edit-log (rev)
1498   "Do the actual commit, using the current buffer as the log message."
1499   (interactive (list cvs-edit-log-revision))
1500   (let ((msg (buffer-substring-no-properties (point-min) (point-max))))
1501     (cvs-mode!)
1502     (cvs-mode-do "admin" (list (concat "-m" rev ":" msg)) nil)))
1503
1504
1505 ;;;;
1506 ;;;; CVS Mode commands
1507 ;;;;
1508
1509 (defun-cvs-mode (cvs-mode-insert . NOARGS) (file)
1510   "Insert an entry for a specific file into the current listing.
1511 This is typically used if the file is up-to-date (or has been added
1512 outside of PCL-CVS) and one wants to do some operation on it."
1513   (interactive
1514    (list (read-file-name
1515           "File to insert: "
1516           ;; Can't use ignore-errors here because interactive
1517           ;; specs aren't byte-compiled.
1518           (condition-case nil
1519               (file-name-as-directory
1520                (expand-file-name
1521                 (cvs-fileinfo->dir
1522                  (cvs-mode-marked nil nil :read-only t :one t :noquery t))))
1523             (error nil)))))
1524   (cvs-insert-file file))
1525
1526 (defun cvs-insert-file (file)
1527   "Insert FILE (and its contents if it's a dir) and return its FI."
1528   (let ((file (file-relative-name (directory-file-name file))) last)
1529     (dolist (fi (cvs-fileinfo-from-entries file))
1530       (setq last (cvs-addto-collection cvs-cookies fi last)))
1531     ;; There should have been at least one entry.
1532     (goto-char (ewoc-location last))
1533     (ewoc-data last)))
1534
1535 (defun cvs-mark-fis-dead (fis)
1536   ;; Helper function, introduced because of the need for macro-expansion.
1537   (dolist (fi fis)
1538     (setf (cvs-fileinfo->type fi) 'DEAD)))
1539
1540 (defun-cvs-mode (cvs-mode-add . SIMPLE) (flags)
1541   "Add marked files to the cvs repository.
1542 With prefix argument, prompt for cvs flags."
1543   (interactive (list (cvs-flags-query 'cvs-add-flags "cvs add flags")))
1544   (let ((fis (cvs-mode-marked 'add))
1545         (needdesc nil) (dirs nil))
1546     ;; find directories and look for fis needing a description
1547     (dolist (fi fis)
1548       (cond
1549        ((file-directory-p (cvs-fileinfo->full-path fi)) (push fi dirs))
1550        ((eq (cvs-fileinfo->type fi) 'UNKNOWN) (setq needdesc t))))
1551     ;; prompt for description if necessary
1552     (let* ((msg (if (and needdesc
1553                          (or current-prefix-arg (not cvs-add-default-message)))
1554                     (read-from-minibuffer "Enter description: ")
1555                   (or cvs-add-default-message "")))
1556            (flags (list* "-m" msg flags))
1557            (postproc
1558             ;; setup postprocessing for the directory entries
1559             (when dirs
1560               `((cvs-run-process (list "-n" "update")
1561                                  ',dirs
1562                                  '(cvs-parse-process t))
1563                 (cvs-mark-fis-dead ',dirs)))))
1564       (cvs-mode-run "add" flags fis :postproc postproc))))
1565
1566 (defun-cvs-mode (cvs-mode-diff . DOUBLE) (flags)
1567   "Diff the selected files against the repository.
1568 This command compares the files in your working area against the
1569 revision which they are based upon."
1570   (interactive
1571    (list (cvs-add-branch-prefix
1572           (cvs-add-secondary-branch-prefix
1573            (cvs-flags-query 'cvs-diff-flags "cvs diff flags")))))
1574   (cvs-mode-do "diff" flags 'diff
1575                :show t)) ;; :ignore-exit t
1576
1577 (defun-cvs-mode (cvs-mode-diff-head . SIMPLE) (flags)
1578   "Diff the selected files against the head of the current branch.
1579 See ``cvs-mode-diff'' for more info."
1580   (interactive (list (cvs-flags-query 'cvs-diff-flags "cvs diff flags")))
1581   (cvs-mode-diff-1 (cons "-rHEAD" flags)))
1582
1583 (defun-cvs-mode (cvs-mode-diff-repository . SIMPLE) (flags)
1584   "Diff the files for changes in the repository since last co/update/commit.
1585 See ``cvs-mode-diff'' for more info."
1586   (interactive (list (cvs-flags-query 'cvs-diff-flags "cvs diff flags")))
1587   (cvs-mode-diff-1 (cons "-rBASE" (cons "-rHEAD" flags))))
1588
1589 (defun-cvs-mode (cvs-mode-diff-yesterday . SIMPLE) (flags)
1590   "Diff the selected files against yesterday's head of the current branch.
1591 See ``cvs-mode-diff'' for more info."
1592   (interactive (list (cvs-flags-query 'cvs-diff-flags "cvs diff flags")))
1593   (cvs-mode-diff-1 (cons "-Dyesterday" flags)))
1594
1595 (defun-cvs-mode (cvs-mode-diff-vendor . SIMPLE) (flags)
1596   "Diff the selected files against the head of the vendor branch.
1597 See ``cvs-mode-diff'' for more info."
1598   (interactive (list (cvs-flags-query 'cvs-diff-flags "cvs diff flags")))
1599   (cvs-mode-diff-1 (cons (concat "-r" cvs-vendor-branch) flags)))
1600
1601 ;; sadly, this is not provided by cvs, so we have to roll our own
1602 (defun-cvs-mode (cvs-mode-diff-backup . SIMPLE) (flags)
1603   "Diff the files against the backup file.
1604 This command can be used on files that are marked with \"Merged\"
1605 or \"Conflict\" in the *cvs* buffer."
1606   (interactive (list (cvs-flags-query 'cvs-diff-flags "diff flags")))
1607   (unless (listp flags) (error "flags should be a list of strings"))
1608   (save-some-buffers)
1609   (let* ((marked (cvs-get-marked (cvs-ignore-marks-p "diff")))
1610          (fis (car (cvs-partition 'cvs-fileinfo->backup-file marked))))
1611     (unless (consp fis)
1612       (error "No files with a backup file selected!"))
1613     ;; let's extract some info into the environment for `buffer-name'
1614     (let* ((dir (cvs-fileinfo->dir (car fis)))
1615            (file (cvs-fileinfo->file (car fis))))
1616       (set-buffer (cvs-temp-buffer "diff")))
1617     (message "cvs diff backup...")
1618     (cvs-execute-single-file-list fis 'cvs-diff-backup-extractor
1619                                   cvs-diff-program flags))
1620   (message "cvs diff backup... Done."))
1621
1622 (defun cvs-diff-backup-extractor (fileinfo)
1623   "Return the filename and the name of the backup file as a list.
1624 Signal an error if there is no backup file."
1625   (let ((backup-file (cvs-fileinfo->backup-file fileinfo)))
1626     (unless backup-file
1627       (error "%s has no backup file" (cvs-fileinfo->full-path fileinfo)))
1628     (list backup-file (cvs-fileinfo->full-path fileinfo))))
1629
1630 ;;
1631 ;; Emerge support
1632 ;;
1633 (defun cvs-emerge-diff (b1 b2) (emerge-buffers b1 b2 b1))
1634 (defun cvs-emerge-merge (b1 b2 base out)
1635   (emerge-buffers-with-ancestor b1 b2 base (find-file-noselect out)))
1636
1637 ;;
1638 ;; Ediff support
1639 ;;
1640
1641 (defvar ediff-after-quit-destination-buffer)
1642 (defvar ediff-after-quit-hook-internal)
1643 (defvar cvs-transient-buffers)
1644 (defun cvs-ediff-startup-hook ()
1645   (add-hook 'ediff-after-quit-hook-internal
1646             `(lambda ()
1647                (cvs-ediff-exit-hook
1648                 ',ediff-after-quit-destination-buffer ',cvs-transient-buffers))
1649             nil 'local))
1650
1651 (defun cvs-ediff-exit-hook (cvs-buf tmp-bufs)
1652   ;; kill the temp buffers (and their associated windows)
1653   (dolist (tb tmp-bufs)
1654     (when (and tb (buffer-live-p tb) (not (buffer-modified-p tb)))
1655       (let ((win (get-buffer-window tb t)))
1656         (kill-buffer tb)
1657         (when (window-live-p win) (ignore-errors (delete-window win))))))
1658   ;; switch back to the *cvs* buffer
1659   (when (and cvs-buf (buffer-live-p cvs-buf)
1660              (not (get-buffer-window cvs-buf t)))
1661     (ignore-errors (switch-to-buffer cvs-buf))))
1662
1663 (defun cvs-ediff-diff (b1 b2)
1664   (let ((ediff-after-quit-destination-buffer (current-buffer))
1665         (startup-hook '(cvs-ediff-startup-hook)))
1666     (ediff-buffers b1 b2 startup-hook 'ediff-revision)))
1667
1668 (defun cvs-ediff-merge (b1 b2 base out)
1669   (let ((ediff-after-quit-destination-buffer (current-buffer))
1670         (startup-hook '(cvs-ediff-startup-hook)))
1671     (ediff-merge-buffers-with-ancestor
1672      b1 b2 base startup-hook
1673      'ediff-merge-revisions-with-ancestor
1674      out)))
1675
1676 ;;
1677 ;; Interactive merge/diff support.
1678 ;;
1679
1680 (defun cvs-retrieve-revision (fileinfo rev)
1681   "Retrieve the given REVision of the file in FILEINFO into a new buffer."
1682   (let* ((file (cvs-fileinfo->full-path fileinfo))
1683          (buffile (concat file "." rev)))
1684     (or (find-buffer-visiting buffile)
1685         (with-current-buffer (create-file-buffer buffile)
1686           (message "Retrieving revision %s..." rev)
1687           ;; Discard stderr output to work around the CVS+SSH+libc
1688           ;; problem when stdout and stderr are the same.
1689           ;; FIXME: this doesn't seem to make any difference :-(
1690           (let ((res (apply 'call-process cvs-program nil '(t . nil) nil
1691                             "-q" "update" "-p"
1692                             ;; If `rev' is HEAD, don't pass it at all:
1693                             ;; the default behavior is to get the head
1694                             ;; of the current branch whereas "-r HEAD"
1695                             ;; stupidly gives you the head of the trunk.
1696                             (append (unless (equal rev "HEAD") (list "-r" rev))
1697                                     (list file)))))
1698             (when (and res (not (and (equal 0 res))))
1699               (error "Something went wrong retrieving revision %s: %s" rev res))
1700             (set-buffer-modified-p nil)
1701             (let ((buffer-file-name (expand-file-name file)))
1702               (after-find-file))
1703             (toggle-read-only 1)
1704             (message "Retrieving revision %s... Done" rev)
1705             (current-buffer))))))
1706
1707 (eval-and-compile (autoload 'smerge-ediff "smerge-mode"))
1708
1709 ;; FIXME: The user should be able to specify ancestor/head/backup and we should
1710 ;; provide sensible defaults when merge info is unavailable (rather than rely
1711 ;; on smerge-ediff).  Also provide sane defaults for need-merge files.
1712 (defun-cvs-mode cvs-mode-imerge ()
1713   "Merge interactively appropriate revisions of the selected file."
1714   (interactive)
1715   (let ((fi (cvs-mode-marked 'merge nil :one t :file t)))
1716     (let ((merge (cvs-fileinfo->merge fi))
1717           (file (cvs-fileinfo->full-path fi))
1718           (backup-file (cvs-fileinfo->backup-file fi)))
1719       (if (not (and merge backup-file))
1720           (let ((buf (find-file-noselect file)))
1721             (message "Missing merge info or backup file, using VC.")
1722             (with-current-buffer buf
1723               (smerge-ediff)))
1724         (let* ((ancestor-buf (cvs-retrieve-revision fi (car merge)))
1725                (head-buf (cvs-retrieve-revision fi (cdr merge)))
1726                (backup-buf (let ((auto-mode-alist nil))
1727                              (find-file-noselect backup-file)))
1728                ;; this binding is used by cvs-ediff-startup-hook
1729                (cvs-transient-buffers (list ancestor-buf backup-buf head-buf)))
1730           (with-current-buffer backup-buf
1731             (let ((buffer-file-name (expand-file-name file)))
1732               (after-find-file)))
1733           (funcall (cdr cvs-idiff-imerge-handlers)
1734                    backup-buf head-buf ancestor-buf file))))))
1735
1736 (cvs-flags-define cvs-idiff-version
1737                   (list "BASE" cvs-vendor-branch cvs-vendor-branch "BASE" "BASE")
1738                   "version: " cvs-qtypedesc-tag)
1739
1740 (defun-cvs-mode (cvs-mode-idiff . NOARGS) (&optional rev1 rev2)
1741   "Diff interactively current file to revisions."
1742   (interactive
1743    (let* ((rev1 (cvs-prefix-get 'cvs-branch-prefix))
1744           (rev2 (and rev1 (cvs-prefix-get 'cvs-secondary-branch-prefix))))
1745      (list (or rev1 (cvs-flags-query 'cvs-idiff-version))
1746            rev2)))
1747   (let ((fi (cvs-mode-marked 'diff "idiff" :one t :file t)))
1748     (let* ((file (cvs-fileinfo->full-path fi))
1749            (rev1-buf (cvs-retrieve-revision fi (or rev1 "BASE")))
1750            (rev2-buf (if rev2 (cvs-retrieve-revision fi rev2)))
1751            ;; this binding is used by cvs-ediff-startup-hook
1752            (cvs-transient-buffers (list rev1-buf rev2-buf)))
1753       (funcall (car cvs-idiff-imerge-handlers)
1754                rev1-buf (or rev2-buf (find-file-noselect file))))))
1755
1756 (defun-cvs-mode (cvs-mode-idiff-other . NOARGS) ()
1757   "Diff interactively current file to revisions."
1758   (interactive)
1759   (let* ((rev1 (cvs-prefix-get 'cvs-branch-prefix))
1760          (rev2 (and rev1 (cvs-prefix-get 'cvs-secondary-branch-prefix)))
1761          (fis (cvs-mode-marked 'diff "idiff" :file t)))
1762     (when (> (length fis) 2)
1763       (error "idiff-other cannot be applied to more than 2 files at a time"))
1764     (let* ((fi1 (car fis))
1765            (rev1-buf (if rev1 (cvs-retrieve-revision fi1 rev1)
1766                        (find-file-noselect (cvs-fileinfo->full-path fi1))))
1767            rev2-buf)
1768       (if (cdr fis)
1769           (let ((fi2 (nth 1 fis)))
1770             (setq rev2-buf
1771                   (if rev2 (cvs-retrieve-revision fi2 rev2)
1772                     (find-file-noselect (cvs-fileinfo->full-path fi2)))))
1773         (error "idiff-other doesn't know what other file/buffer to use"))
1774       (let* (;; this binding is used by cvs-ediff-startup-hook
1775              (cvs-transient-buffers (list rev1-buf rev2-buf)))
1776         (funcall (car cvs-idiff-imerge-handlers)
1777                  rev1-buf rev2-buf)))))
1778
1779
1780 (defun cvs-is-within-p (fis dir)
1781   "Non-nil if buffer is inside one of FIS (in DIR)."
1782   (when (stringp buffer-file-name)
1783     (setq buffer-file-name (expand-file-name buffer-file-name))
1784     (let (ret)
1785       (dolist (fi (or fis (list (cvs-create-fileinfo 'DIRCHANGE "" "." ""))))
1786         (when (cvs-string-prefix-p
1787                (expand-file-name (cvs-fileinfo->full-path fi) dir)
1788                buffer-file-name)
1789           (setq ret t)))
1790       ret)))
1791
1792 (defun* cvs-mode-run (cmd flags fis
1793                       &key (buf (cvs-temp-buffer))
1794                            dont-change-disc cvsargs postproc)
1795   "Generic cvs-mode-<foo> function.
1796 Executes `cvs CVSARGS CMD FLAGS FIS'.
1797 BUF is the buffer to be used for cvs' output.
1798 DONT-CHANGE-DISC non-nil indicates that the command will not change the
1799   contents of files.  This is only used by the parser.
1800 POSTPROC is a list of expressions to be evaluated at the very end (after
1801   parsing if applicable).  It will be prepended with `progn' if necessary."
1802   (let ((def-dir default-directory))
1803     ;; Save the relevant buffers
1804     (save-some-buffers nil (lambda () (cvs-is-within-p fis def-dir))))
1805   (unless (listp flags) (error "flags should be a list of strings"))
1806   ;; Some w32 versions of CVS don't like an explicit . too much.
1807   (when (and (car fis) (null (cdr fis))
1808              (eq (cvs-fileinfo->type (car fis)) 'DIRCHANGE)
1809              ;; (equal (cvs-fileinfo->file (car fis)) ".")
1810              (equal (cvs-fileinfo->dir (car fis)) ""))
1811     (setq fis nil))
1812   (let* ((single-dir (or (not (listp cvs-execute-single-dir))
1813                          (member cmd cvs-execute-single-dir)))
1814          (parse (member cmd cvs-parse-known-commands))
1815          (args (append cvsargs (list cmd) flags))
1816          (after-mode (nth 2 (cdr (assoc cmd cvs-buffer-name-alist)))))
1817     (cvs-cleanup-collection cvs-cookies ;cleanup remaining messages
1818                             (eq cvs-auto-remove-handled 'delayed) nil t)
1819     (when (fboundp after-mode)
1820       (setq postproc (append postproc `((,after-mode)))))
1821     (when parse
1822       (let ((old-fis
1823              (when (member cmd '("status" "update"))    ;FIXME: Yuck!!
1824                 ;; absence of `cvs update' output has a specific meaning.
1825                 (or fis (list (cvs-create-fileinfo 'DIRCHANGE "" "." ""))))))
1826         (push `(cvs-parse-process ',dont-change-disc nil ',old-fis) postproc)))
1827     (setq postproc (if (cdr postproc) (cons 'progn postproc) (car postproc)))
1828     (cvs-update-header args fis)
1829     (with-current-buffer buf
1830       (let ((inhibit-read-only t)) (erase-buffer))
1831       (message "Running cvs %s ..." cmd)
1832       (cvs-run-process args fis postproc single-dir))))
1833
1834
1835 (defun* cvs-mode-do (cmd flags filter
1836                      &key show dont-change-disc cvsargs postproc)
1837   "Generic cvs-mode-<foo> function.
1838 Executes `cvs CVSARGS CMD FLAGS' on the selected files.
1839 FILTER is passed to `cvs-applicable-p' to only apply the command to
1840   files for which it makes sense.
1841 SHOW indicates that CMD should be not be run in the default temp buffer and
1842   should be shown to the user.  The buffer and mode to be used is determined
1843   by `cvs-buffer-name-alist'.
1844 DONT-CHANGE-DISC non-nil indicates that the command will not change the
1845   contents of files.  This is only used by the parser."
1846   (cvs-mode-run cmd flags (cvs-mode-marked filter cmd)
1847                 :buf (cvs-temp-buffer (when show cmd))
1848                 :dont-change-disc dont-change-disc
1849                 :cvsargs cvsargs
1850                 :postproc postproc))
1851
1852 (defun-cvs-mode (cvs-mode-status . SIMPLE) (flags)
1853   "Show cvs status for all marked files.
1854 With prefix argument, prompt for cvs flags."
1855   (interactive (list (cvs-flags-query 'cvs-status-flags "cvs status flags")))
1856   (cvs-mode-do "status" flags nil :dont-change-disc t :show t
1857                :postproc (when (eq cvs-auto-remove-handled 'status)
1858                            '((with-current-buffer ,(current-buffer)
1859                                (cvs-mode-remove-handled))))))
1860
1861 (defun-cvs-mode (cvs-mode-tree . SIMPLE) (flags)
1862   "Call cvstree using the file under the point as a keyfile."
1863   (interactive (list (cvs-flags-query 'cvs-status-flags "cvs status flags")))
1864   (cvs-mode-run "status" (cons "-v" flags) (cvs-mode-marked nil "status")
1865                 :buf (cvs-temp-buffer "tree")
1866                 :dont-change-disc t
1867                 :postproc '((cvs-status-cvstrees))))
1868
1869 ;; cvs log
1870
1871 (defun-cvs-mode (cvs-mode-log . NOARGS) (flags)
1872   "Display the cvs log of all selected files.
1873 With prefix argument, prompt for cvs flags."
1874   (interactive (list (cvs-add-branch-prefix
1875                       (cvs-flags-query 'cvs-log-flags "cvs log flags"))))
1876   (cvs-mode-do "log" flags nil :show t))
1877
1878
1879 (defun-cvs-mode (cvs-mode-update . NOARGS) (flags)
1880   "Update all marked files.
1881 With a prefix argument, prompt for cvs flags."
1882   (interactive
1883    (list (cvs-add-branch-prefix
1884           (cvs-add-secondary-branch-prefix
1885            (cvs-flags-query 'cvs-update-flags "cvs update flags")
1886            "-j") "-j")))
1887   (cvs-mode-do "update" flags 'update))
1888
1889
1890 (defun-cvs-mode (cvs-mode-examine . NOARGS) (flags)
1891   "Re-examine all marked files.
1892 With a prefix argument, prompt for cvs flags."
1893   (interactive
1894    (list (cvs-add-branch-prefix
1895           (cvs-add-secondary-branch-prefix
1896            (cvs-flags-query 'cvs-update-flags "cvs -n update flags")
1897            "-j") "-j")))
1898   (cvs-mode-do "update" flags nil :cvsargs '("-n") :dont-change-disc t))
1899
1900
1901 (defun-cvs-mode cvs-mode-ignore (&optional pattern)
1902   "Arrange so that CVS ignores the selected files.
1903 This command ignores files that are not flagged as `Unknown'."
1904   (interactive)
1905   (dolist (fi (cvs-mode-marked 'ignore))
1906     (cvs-append-to-ignore (cvs-fileinfo->dir fi) (cvs-fileinfo->file fi)
1907                           (eq (cvs-fileinfo->subtype fi) 'NEW-DIR))
1908     (setf (cvs-fileinfo->type fi) 'DEAD))
1909   (cvs-cleanup-collection cvs-cookies nil nil nil))
1910
1911
1912 (defun cvs-append-to-ignore (dir str &optional old-dir)
1913   "Add STR to the .cvsignore file in DIR.
1914 If OLD-DIR is non-nil, then this is a directory that we don't want
1915 to hear about anymore."
1916   (with-current-buffer
1917       (find-file-noselect (expand-file-name ".cvsignore" dir))
1918     (when (ignore-errors
1919             (and buffer-read-only
1920                  (eq 'CVS (vc-backend buffer-file-name))
1921                  (not (vc-editable-p buffer-file-name))))
1922       ;; CVSREAD=on special case
1923       (vc-checkout buffer-file-name t))
1924     (goto-char (point-max))
1925     (unless (bolp) (insert "\n"))
1926     (insert str (if old-dir "/\n" "\n"))
1927     (if cvs-sort-ignore-file (sort-lines nil (point-min) (point-max)))
1928     (save-buffer)))
1929
1930
1931 (defun cvs-mode-find-file-other-window (e)
1932   "Select a buffer containing the file in another window."
1933   (interactive (list last-input-event))
1934   (cvs-mode-find-file e t))
1935
1936
1937 (defun cvs-mode-display-file (e)
1938   "Show a buffer containing the file in another window."
1939   (interactive (list last-input-event))
1940   (cvs-mode-find-file e 'dont-select))
1941
1942
1943 (defun cvs-mode-view-file (e)
1944   "View the file."
1945   (interactive (list last-input-event))
1946   (cvs-mode-find-file e nil t))
1947
1948
1949 (defun cvs-mode-view-file-other-window (e)
1950   "View the file."
1951   (interactive (list last-input-event))
1952   (cvs-mode-find-file e t t))
1953
1954
1955 (defun cvs-find-modif (fi)
1956   (with-temp-buffer
1957     (call-process cvs-program nil (current-buffer) nil
1958                   "-f" "diff" (cvs-fileinfo->file fi))
1959     (goto-char (point-min))
1960     (if (re-search-forward "^\\([0-9]+\\)" nil t)
1961         (string-to-number (match-string 1))
1962       1)))
1963
1964
1965 (defun cvs-mode-find-file (e &optional other view)
1966   "Select a buffer containing the file.
1967 With a prefix, opens the buffer in an OTHER window."
1968   (interactive (list last-input-event current-prefix-arg))
1969   ;; If the event moves point, check that it moves it to a valid location.
1970   (when (and (/= (point) (progn (posn-set-point (event-end e)) (point)))
1971              (not (memq (get-text-property (1- (line-end-position))
1972                                            'font-lock-face)
1973                         '(cvs-header-face cvs-filename-face))))
1974     (error "Not a file name"))
1975   (cvs-mode!
1976    (lambda (&optional rev)
1977      (interactive (list (cvs-prefix-get 'cvs-branch-prefix)))
1978      (let* ((cvs-buf (current-buffer))
1979             (fi (cvs-mode-marked nil nil :one t)))
1980        (if (eq (cvs-fileinfo->type fi) 'DIRCHANGE)
1981            (let ((odir default-directory))
1982              (setq default-directory
1983                    (cvs-expand-dir-name (cvs-fileinfo->dir fi)))
1984              (cond ((eq other 'dont-select)
1985                     (display-buffer (find-file-noselect default-directory)))
1986                    (other (dired-other-window default-directory))
1987                    (t (dired default-directory)))
1988              (set-buffer cvs-buf)
1989              (setq default-directory odir))
1990          (let ((buf (if rev (cvs-retrieve-revision fi rev)
1991                       (find-file-noselect (cvs-fileinfo->full-path fi)))))
1992            (funcall (cond ((eq other 'dont-select) 'display-buffer)
1993                           (other
1994                            (if view 'view-buffer-other-window
1995                              'switch-to-buffer-other-window))
1996                           (t (if view 'view-buffer 'switch-to-buffer)))
1997                     buf)
1998            (when (and cvs-find-file-and-jump (cvs-applicable-p fi 'diff-base))
1999              (goto-line (cvs-find-modif fi)))
2000            buf))))))
2001
2002
2003 (defun-cvs-mode (cvs-mode-undo . SIMPLE) (flags)
2004   "Undo local changes to all marked files.
2005 The file is removed and `cvs update FILE' is run."
2006   ;;"With prefix argument, prompt for cvs FLAGS."
2007   (interactive (list nil));; (cvs-flags-query 'cvs-undo-flags "undo flags")
2008   (if current-prefix-arg (call-interactively 'cvs-mode-revert-to-rev)
2009     (let* ((fis (cvs-do-removal 'undo "update" 'all))
2010            (removedp (lambda (fi)
2011                        (or (eq (cvs-fileinfo->type fi) 'REMOVED)
2012                            (and (eq (cvs-fileinfo->type fi) 'CONFLICT)
2013                                 (eq (cvs-fileinfo->subtype fi) 'REMOVED)))))
2014            (fis-split (cvs-partition removedp fis))
2015            (fis-removed (car fis-split))
2016            (fis-other (cdr fis-split)))
2017       (if (null fis-other)
2018           (when fis-removed (cvs-mode-run "add" nil fis-removed))
2019         (cvs-mode-run "update" flags fis-other
2020                       :postproc
2021                       (when fis-removed
2022                         `((with-current-buffer ,(current-buffer)
2023                             (cvs-mode-run "add" nil ',fis-removed)))))))))
2024
2025
2026 (defun-cvs-mode (cvs-mode-revert-to-rev . NOARGS) (rev)
2027   "Revert the selected files to an old revision."
2028   (interactive
2029    (list (or (cvs-prefix-get 'cvs-branch-prefix)
2030              (let ((current-prefix-arg '(4)))
2031                (cvs-flags-query 'cvs-idiff-version)))))
2032   (let* ((fis (cvs-mode-marked 'revert "revert" :file t))
2033          (tag (concat "tmp_pcl_tag_" (make-temp-name "")))
2034          (untag `((with-current-buffer ,(current-buffer)
2035                     (cvs-mode-run "tag" (list "-d" ',tag) ',fis))))
2036          (update `((with-current-buffer ,(current-buffer)
2037                      (cvs-mode-run "update" (list "-j" ',tag "-j" ',rev) ',fis
2038                                    :postproc ',untag)))))
2039     (cvs-mode-run "tag" (list tag) fis :postproc update)))
2040
2041
2042 (defun-cvs-mode cvs-mode-delete-lock ()
2043   "Delete the lock file that CVS is waiting for.
2044 Note that this can be dangerous.  You should only do this
2045 if you are convinced that the process that created the lock is dead."
2046   (interactive)
2047   (let* ((default-directory (cvs-expand-dir-name cvs-lock-file))
2048          (locks (directory-files default-directory nil cvs-lock-file-regexp)))
2049     (cond
2050      ((not locks) (error "No lock files found"))
2051      ((yes-or-no-p (concat "Really delete locks in " cvs-lock-file "? "))
2052       (dolist (lock locks)
2053         (cond ((file-directory-p lock) (delete-directory lock))
2054               ((file-exists-p lock) (delete-file lock))))))))
2055
2056
2057 (defun-cvs-mode cvs-mode-remove-handled ()
2058   "Remove all lines that are handled.
2059 Empty directories are removed."
2060   (interactive)
2061   (cvs-cleanup-collection cvs-cookies
2062                           t (or cvs-auto-remove-directories 'handled) t))
2063
2064
2065 (defun-cvs-mode cvs-mode-acknowledge ()
2066   "Remove all marked files from the buffer."
2067   (interactive)
2068   (dolist (fi (cvs-get-marked (cvs-ignore-marks-p "acknowledge") t))
2069     (setf (cvs-fileinfo->type fi) 'DEAD))
2070   (cvs-cleanup-collection cvs-cookies nil nil nil))
2071
2072 (defun cvs-do-removal (filter &optional cmd all)
2073   "Remove files.
2074 Returns a list of FIS that should be `cvs remove'd."
2075   (let* ((files (cvs-mode-marked filter cmd :file t :read-only t))
2076          (fis (cdr (cvs-partition (lambda (fi)
2077                                     (eq (cvs-fileinfo->type fi) 'UNKNOWN))
2078                                   (cvs-mode-marked filter cmd))))
2079          (silent (or (not cvs-confirm-removals)
2080                      (cvs-every (lambda (fi)
2081                                   (or (not (file-exists-p
2082                                             (cvs-fileinfo->full-path fi)))
2083                                       (cvs-applicable-p fi 'safe-rm)))
2084                                 files)))
2085          (tmpbuf (cvs-temp-buffer)))
2086     (when (and (not silent) (equal cvs-confirm-removals 'list))
2087       (with-current-buffer tmpbuf
2088         (let ((inhibit-read-only t))
2089           (cvs-insert-strings (mapcar 'cvs-fileinfo->full-path fis))
2090           (cvs-pop-to-buffer-same-frame (current-buffer))
2091           (shrink-window-if-larger-than-buffer))))
2092     (if (not (or silent
2093                  (unwind-protect
2094                      (yes-or-no-p
2095                       (let ((nfiles (length files))
2096                             (verb (if (eq filter 'undo) "Undo" "Delete")))
2097                         (if (= 1 nfiles)
2098                             (format "%s file: \"%s\" ? "
2099                                     verb
2100                                     (cvs-fileinfo->file (car files)))
2101                           (format "%s %d files? "
2102                                   verb
2103                                   nfiles))))
2104                    (cvs-bury-buffer tmpbuf cvs-buffer))))
2105         (progn (message "Aborting") nil)
2106       (dolist (fi files)
2107         (let* ((type (cvs-fileinfo->type fi))
2108                (file (cvs-fileinfo->full-path fi)))
2109           (when (or all (eq type 'UNKNOWN))
2110             (when (file-exists-p file) (delete-file file))
2111             (unless all (setf (cvs-fileinfo->type fi) 'DEAD) t))))
2112       fis)))
2113
2114 (defun-cvs-mode (cvs-mode-remove . SIMPLE) (flags)
2115   "Remove all marked files.
2116 With prefix argument, prompt for cvs flags."
2117   (interactive (list (cvs-flags-query 'cvs-remove-flags "cvs remove flags")))
2118   (let ((fis (cvs-do-removal 'remove)))
2119     (if fis (cvs-mode-run "remove" (cons "-f" flags) fis)
2120       (cvs-cleanup-collection cvs-cookies nil nil nil))))
2121
2122
2123 (defvar cvs-tag-name "")
2124 (defun-cvs-mode (cvs-mode-tag . SIMPLE) (tag &optional flags)
2125   "Run `cvs tag TAG' on all selected files.
2126 With prefix argument, prompt for cvs flags.
2127 By default this can only be used on directories.
2128 Use \\[cvs-mode-force-command] or change `cvs-force-dir-tag' if you need
2129 to use it on individual files."
2130   (interactive
2131    (list (setq cvs-tag-name
2132                (cvs-query-read cvs-tag-name "Tag name: " cvs-qtypedesc-tag))
2133          (cvs-flags-query 'cvs-tag-flags "tag flags")))
2134   (cvs-mode-do "tag" (append flags (list tag))
2135                (when cvs-force-dir-tag 'tag)))
2136
2137 (defun-cvs-mode (cvs-mode-untag . SIMPLE) (tag &optional flags)
2138   "Run `cvs tag -d TAG' on all selected files.
2139 With prefix argument, prompt for cvs flags."
2140   (interactive
2141    (list (setq cvs-tag-name
2142                (cvs-query-read cvs-tag-name "Tag to delete: " cvs-qtypedesc-tag))
2143          (cvs-flags-query 'cvs-tag-flags "tag flags")))
2144   (cvs-mode-do "tag" (append '("-d") flags (list tag))
2145                (when cvs-force-dir-tag 'tag)))
2146
2147
2148 ;; Byte compile files.
2149
2150 (defun-cvs-mode cvs-mode-byte-compile-files ()
2151   "Run byte-compile-file on all selected files that end in '.el'."
2152   (interactive)
2153   (let ((marked (cvs-get-marked (cvs-ignore-marks-p "byte-compile"))))
2154     (dolist (fi marked)
2155       (let ((filename (cvs-fileinfo->full-path fi)))
2156         (when (string-match "\\.el\\'" filename)
2157           (byte-compile-file filename))))))
2158
2159 ;; ChangeLog support.
2160
2161 (defun-cvs-mode cvs-mode-add-change-log-entry-other-window ()
2162   "Add a ChangeLog entry in the ChangeLog of the current directory."
2163   (interactive)
2164   (dolist (fi (cvs-mode-marked nil nil))
2165     (let* ((default-directory (cvs-expand-dir-name (cvs-fileinfo->dir fi)))
2166            (buffer-file-name (expand-file-name (cvs-fileinfo->file fi))))
2167       (kill-local-variable 'change-log-default-name)
2168       (save-excursion (add-change-log-entry-other-window)))))
2169
2170 ;; interactive commands to set optional flags
2171
2172 (defun cvs-mode-set-flags (flag)
2173   "Ask for new setting of cvs-FLAG-flags."
2174   (interactive
2175    (list (completing-read
2176           "Which flag: "
2177           '("cvs" "diff" "update" "status" "log" "tag" ;"rtag"
2178             "commit" "remove" "undo" "checkout")
2179           nil t)))
2180   (let* ((sym (intern (concat "cvs-" flag "-flags"))))
2181     (let ((current-prefix-arg '(16)))
2182       (cvs-flags-query sym (concat flag " flags")))))
2183
2184 \f
2185 ;;;;
2186 ;;;; Utilities for the *cvs* buffer
2187 ;;;;
2188
2189 (defun cvs-dir-member-p (fileinfo dir)
2190   "Return true if FILEINFO represents a file in directory DIR."
2191   (and (not (eq (cvs-fileinfo->type fileinfo) 'DIRCHANGE))
2192        (cvs-string-prefix-p dir (cvs-fileinfo->dir fileinfo))))
2193
2194 (defun cvs-execute-single-file (fi extractor program constant-args)
2195   "Internal function for `cvs-execute-single-file-list'."
2196   (let* ((arg-list (funcall extractor fi))
2197          (inhibit-read-only t))
2198
2199     ;; Execute the command unless extractor returned t.
2200     (when (listp arg-list)
2201       (let* ((args (append constant-args arg-list)))
2202
2203         (insert (format "=== %s %s\n\n"
2204                         program (cvs-strings->string args)))
2205
2206         ;; FIXME: return the exit status?
2207         (apply 'call-process program nil t t args)
2208         (goto-char (point-max))))))
2209
2210 ;; FIXME: make this run in the background ala cvs-run-process...
2211 (defun cvs-execute-single-file-list (fis extractor program constant-args)
2212   "Run PROGRAM on all elements on FIS.
2213 CONSTANT-ARGS is a list of strings to pass as arguments to PROGRAM.
2214 The arguments given to the program will be CONSTANT-ARGS followed by
2215 the list that EXTRACTOR returns.
2216
2217 EXTRACTOR will be called once for each file on FIS.  It is given
2218 one argument, the cvs-fileinfo.  It can return t, which means ignore
2219 this file, or a list of arguments to send to the program."
2220   (dolist (fi fis)
2221     (cvs-execute-single-file fi extractor program constant-args)))
2222
2223 \f
2224 (defun cvs-revert-if-needed (fis)
2225   (dolist (fileinfo fis)
2226     (let* ((file (cvs-fileinfo->full-path fileinfo))
2227            (buffer (find-buffer-visiting file)))
2228       ;; For a revert to happen the user must be editing the file...
2229       (unless (or (null buffer)
2230                   (eq (cvs-fileinfo->type fileinfo) 'MESSAGE)
2231                   ;; FIXME: check whether revert is really needed.
2232                   ;; `(verify-visited-file-modtime buffer)' doesn't cut it
2233                   ;; because it only looks at the time stamp (it ignores
2234                   ;; read-write changes) which is not changed by `commit'.
2235                   (buffer-modified-p buffer))
2236         (with-current-buffer buffer
2237           (ignore-errors
2238             (revert-buffer 'ignore-auto 'dont-ask 'preserve-modes)
2239             ;; `preserve-modes' avoids changing the (minor) modes.  But we
2240             ;; do want to reset the mode for VC, so we do it explicitly.
2241             (vc-find-file-hook)
2242             (when (eq (cvs-fileinfo->type fileinfo) 'CONFLICT)
2243               (smerge-mode 1))))))))
2244
2245 \f
2246 (defun cvs-change-cvsroot (newroot)
2247   "Change the cvsroot."
2248   (interactive "DNew repository: ")
2249   (if (or (file-directory-p (expand-file-name "CVSROOT" newroot))
2250           (y-or-n-p (concat "Warning: no CVSROOT found inside repository."
2251                             " Change cvs-cvsroot anyhow?")))
2252       (setq cvs-cvsroot newroot)))
2253
2254 ;;;;
2255 ;;;; useful global settings
2256 ;;;;
2257
2258 ;;;###autoload
2259 (add-to-list 'completion-ignored-extensions "CVS/")
2260
2261 ;;
2262 ;; Hook to allow calling PCL-CVS by visiting the /CVS subdirectory
2263 ;;
2264
2265 ;;;###autoload
2266 (defcustom cvs-dired-action 'cvs-quickdir
2267   "The action to be performed when opening a CVS directory.
2268 Sensible values are `cvs-examine', `cvs-status' and `cvs-quickdir'."
2269   :group 'pcl-cvs
2270   :type '(choice (const cvs-examine) (const cvs-status) (const cvs-quickdir)))
2271
2272 ;;;###autoload
2273 (defcustom cvs-dired-use-hook '(4)
2274   "Whether or not opening a CVS directory should run PCL-CVS.
2275 nil means never do it.
2276 ALWAYS means to always do it unless a prefix argument is given to the
2277   command that prompted the opening of the directory.
2278 Anything else means to do it only if the prefix arg is equal to this value."
2279   :group 'pcl-cvs
2280   :type '(choice (const :tag "Never" nil)
2281                  (const :tag "Always" always)
2282                  (const :tag "Prefix" (4))))
2283
2284 ;;;###autoload
2285 (progn (defun cvs-dired-noselect (dir)
2286   "Run `cvs-examine' if DIR is a CVS administrative directory.
2287 The exact behavior is determined also by `cvs-dired-use-hook'."
2288   (when (stringp dir)
2289     (setq dir (directory-file-name dir))
2290     (when (and (string= "CVS" (file-name-nondirectory dir))
2291                (file-readable-p (expand-file-name "Entries" dir))
2292                cvs-dired-use-hook
2293                (if (eq cvs-dired-use-hook 'always)
2294                    (not current-prefix-arg)
2295                  (equal current-prefix-arg cvs-dired-use-hook)))
2296       (save-excursion
2297         (funcall cvs-dired-action (file-name-directory dir) t t))))))
2298
2299 ;;
2300 ;; hook into VC
2301 ;;
2302
2303 (add-hook 'vc-post-command-functions 'cvs-vc-command-advice)
2304
2305 (defun cvs-vc-command-advice (command file flags)
2306   (when (and (equal command "cvs")
2307              (progn
2308                (while (and (stringp (car flags))
2309                            (string-match "\\`-" (car flags)))
2310                  (pop flags))
2311                ;; don't parse output we don't understand.
2312                (member (car flags) cvs-parse-known-commands))
2313              ;; Don't parse "update -p" output.
2314              (not (and (member (car flags) '("update" "checkout"))
2315                        (let ((found-p nil))
2316                          (dolist (flag flags found-p)
2317                            (if (equal flag "-p") (setq found-p t)))))))
2318     (save-current-buffer
2319       (let ((buffer (current-buffer))
2320             (dir default-directory)
2321             (cvs-from-vc t))
2322         (dolist (cvs-buf (buffer-list))
2323           (set-buffer cvs-buf)
2324           ;; look for a corresponding pcl-cvs buffer
2325           (when (and (eq major-mode 'cvs-mode)
2326                      (cvs-string-prefix-p default-directory dir))
2327             (let ((subdir (substring dir (length default-directory))))
2328               (set-buffer buffer)
2329               (set (make-local-variable 'cvs-buffer) cvs-buf)
2330               ;; `cvs -q add file' produces no useful output :-(
2331               (when (and (equal (car flags) "add")
2332                          (goto-char (point-min))
2333                          (looking-at ".*to add this file permanently\n\\'"))
2334                 (insert "cvs add: scheduling file `"
2335                         (file-name-nondirectory file)
2336                         "' for addition\n"))
2337               ;; VC never (?) does `cvs -n update' so dcd=nil
2338               ;; should probably always be the right choice.
2339               (cvs-parse-process nil subdir))))))))
2340
2341 ;;
2342 ;; Hook into write-buffer
2343 ;;
2344
2345 (defun cvs-mark-buffer-changed ()
2346   (let* ((file (expand-file-name buffer-file-name))
2347          (version (and (fboundp 'vc-backend)
2348                        (eq (vc-backend file) 'CVS)
2349                        (vc-workfile-version file))))
2350     (when version
2351       (save-excursion
2352         (dolist (cvs-buf (buffer-list))
2353           (set-buffer cvs-buf)
2354           ;; look for a corresponding pcl-cvs buffer
2355           (when (and (eq major-mode 'cvs-mode)
2356                      (cvs-string-prefix-p default-directory file))
2357             (let* ((file (substring file (length default-directory)))
2358                    (fi (cvs-create-fileinfo
2359                         (if (string= "0" version)
2360                             'ADDED 'MODIFIED)
2361                         (or (file-name-directory file) "")
2362                         (file-name-nondirectory file)
2363                         "cvs-mark-buffer-changed")))
2364               (cvs-addto-collection cvs-cookies fi))))))))
2365
2366 (add-hook 'after-save-hook 'cvs-mark-buffer-changed)
2367
2368 \f
2369 (provide 'pcvs)
2370
2371 ;; arch-tag: 8e3a7494-0453-4389-9ab3-a557ce9fab61
2372 ;;; pcvs.el ends here