lisp/xml.el

   1 ;;; xml.el --- XML parser
   2
   3 ;; Copyright (C) 2000, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Emmanuel Briot  <briot@gnat.com>
   6 ;; Maintainer: Emmanuel Briot <briot@gnat.com>
   7 ;; Keywords: xml
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This file contains a full XML parser. It parses a file, and returns a list
  29 ;; that can be used internally by any other lisp file.
  30 ;; See some example in todo.el
  31
  32 ;;; FILE FORMAT
  33
  34 ;; It does not parse the DTD, if present in the XML file, but knows how to
  35 ;; ignore it. The XML file is assumed to be well-formed. In case of error, the
  36 ;; parsing stops and the XML file is shown where the parsing stopped.
  37 ;;
  38 ;; It also knows how to ignore comments, as well as the special ?xml? tag
  39 ;; in the XML file.
  40 ;;
  41 ;; The XML file should have the following format:
  42 ;;    <node1 attr1="name1" attr2="name2" ...>value
  43 ;;       <node2 attr3="name3" attr4="name4">value2</node2>
  44 ;;       <node3 attr5="name5" attr6="name6">value3</node3>
  45 ;;    </node1>
  46 ;; Of course, the name of the nodes and attributes can be anything. There can
  47 ;; be any number of attributes (or none), as well as any number of children
  48 ;; below the nodes.
  49 ;;
  50 ;; There can be only top level node, but with any number of children below.
  51
  52 ;;; LIST FORMAT
  53
  54 ;; The functions `xml-parse-file' and `xml-parse-tag' return a list with
  55 ;; the following format:
  56 ;;
  57 ;;    xml-list   ::= (node node ...)
  58 ;;    node       ::= (tag_name attribute-list . child_node_list)
  59 ;;    child_node_list ::= child_node child_node ...
  60 ;;    child_node ::= node | string
  61 ;;    tag_name   ::= string
  62 ;;    attribute_list ::= (("attribute" . "value") ("attribute" . "value") ...)
  63 ;;                       | nil
  64 ;;    string     ::= "..."
  65 ;;
  66 ;; Some macros are provided to ease the parsing of this list
  67
  68 ;;; Code:
  69
  70 ;;*******************************************************************
  71 ;;**
  72 ;;**  Macros to parse the list
  73 ;;**
  74 ;;*******************************************************************
  75
  76 (defsubst xml-node-name (node)
  77   "Return the tag associated with NODE.
  78 The tag is a lower-case symbol."
  79   (car node))
  80
  81 (defsubst xml-node-attributes (node)
  82   "Return the list of attributes of NODE.
  83 The list can be nil."
  84   (nth 1 node))
  85
  86 (defsubst xml-node-children (node)
  87   "Return the list of children of NODE.
  88 This is a list of nodes, and it can be nil."
  89   (cddr node))
  90
  91 (defun xml-get-children (node child-name)
  92   "Return the children of NODE whose tag is CHILD-NAME.
  93 CHILD-NAME should be a lower case symbol."
  94   (let ((match ()))
  95     (dolist (child (xml-node-children node))
  96       (if child
  97           (if (equal (xml-node-name child) child-name)
  98               (push child match))))
  99     (nreverse match)))
 100
 101 (defun xml-get-attribute (node attribute)
 102   "Get from NODE the value of ATTRIBUTE.
 103 An empty string is returned if the attribute was not found."
 104   (if (xml-node-attributes node)
 105       (let ((value (assoc attribute (xml-node-attributes node))))
 106         (if value
 107             (cdr value)
 108           ""))
 109     ""))
 110
 111 ;;*******************************************************************
 112 ;;**
 113 ;;**  Creating the list
 114 ;;**
 115 ;;*******************************************************************
 116
 117 (defun xml-parse-file (file &optional parse-dtd)
 118   "Parse the well-formed XML FILE.
 119 If FILE is already edited, this will keep the buffer alive.
 120 Returns the top node with all its children.
 121 If PARSE-DTD is non-nil, the DTD is parsed rather than skipped."
 122   (let ((keep))
 123     (if (get-file-buffer file)
 124         (progn
 125           (set-buffer (get-file-buffer file))
 126           (setq keep (point)))
 127       (find-file file))
 128
 129     (let ((xml (xml-parse-region (point-min)
 130                                  (point-max)
 131                                  (current-buffer)
 132                                  parse-dtd)))
 133       (if keep
 134           (goto-char keep)
 135         (kill-buffer (current-buffer)))
 136       xml)))
 137
 138 (defun xml-parse-region (beg end &optional buffer parse-dtd)
 139   "Parse the region from BEG to END in BUFFER.
 140 If BUFFER is nil, it defaults to the current buffer.
 141 Returns the XML list for the region, or raises an error if the region
 142 is not a well-formed XML file.
 143 If PARSE-DTD is non-nil, the DTD is parsed rather than skipped,
 144 and returned as the first element of the list"
 145   (let (xml result dtd)
 146     (save-excursion
 147       (if buffer
 148           (set-buffer buffer))
 149       (goto-char beg)
 150       (while (< (point) end)
 151         (if (search-forward "<" end t)
 152             (progn
 153               (forward-char -1)
 154               (if (null xml)
 155                   (progn
 156                     (setq result (xml-parse-tag end parse-dtd))
 157                     (cond
 158                      ((null result))
 159                      ((listp (car result))
 160                       (setq dtd (car result))
 161                       (add-to-list 'xml (cdr result)))
 162                      (t
 163                       (add-to-list 'xml result))))
 164
 165                 ;;  translation of rule [1] of XML specifications
 166                 (error "XML files can have only one toplevel tag")))
 167           (goto-char end)))
 168       (if parse-dtd
 169           (cons dtd (reverse xml))
 170         (reverse xml)))))
 171
 172
 173 (defun xml-parse-tag (end &optional parse-dtd)
 174   "Parse the tag that is just in front of point.
 175 The end tag must be found before the position END in the current buffer.
 176 If PARSE-DTD is non-nil, the DTD of the document, if any, is parsed and
 177 returned as the first element in the list.
 178 Returns one of:
 179    - a list : the matching node
 180    - nil    : the point is not looking at a tag.
 181    - a cons cell: the first element is the DTD, the second is the node"
 182   (cond
 183    ;; Processing instructions (like the <?xml version="1.0"?> tag at the
 184    ;; beginning of a document)
 185    ((looking-at "<\\?")
 186     (search-forward "?>" end)
 187     (goto-char (- (re-search-forward "[^[:space:]]") 1))
 188     (xml-parse-tag end))
 189    ;;  Character data (CDATA) sections, in which no tag should be interpreted
 190    ((looking-at "<!\\[CDATA\\[")
 191     (let ((pos (match-end 0)))
 192       (unless (search-forward "]]>" end t)
 193         (error "CDATA section does not end anywhere in the document"))
 194       (buffer-substring-no-properties pos (match-beginning 0))))
 195    ;;  DTD for the document
 196    ((looking-at "<!DOCTYPE")
 197     (let (dtd)
 198       (if parse-dtd
 199           (setq dtd (xml-parse-dtd end))
 200         (xml-skip-dtd end))
 201       (goto-char (- (re-search-forward "[^[:space:]]") 1))
 202       (if dtd
 203           (cons dtd (xml-parse-tag end))
 204         (xml-parse-tag end))))
 205    ;;  skip comments
 206    ((looking-at "<!--")
 207     (search-forward "-->" end)
 208     nil)
 209    ;;  end tag
 210    ((looking-at "</")
 211     '())
 212    ;;  opening tag
 213    ((looking-at "<\\([^/>[:space:]]+\\)")
 214     (goto-char (match-end 1))
 215     (let* ((case-fold-search nil) ;; XML is case-sensitive.
 216            (node-name (match-string 1))
 217            ;; Parse the attribute list.
 218            (children (list (xml-parse-attlist end) (intern node-name)))
 219            pos)
 220
 221       ;; is this an empty element ?
 222       (if (looking-at "/[[:space:]]*>")
 223           (progn
 224             (forward-char 2)
 225             (nreverse (cons '("") children)))
 226
 227         ;; is this a valid start tag ?
 228         (if (eq (char-after) ?>)
 229             (progn
 230               (forward-char 1)
 231               ;;  Now check that we have the right end-tag. Note that this
 232               ;;  one might contain spaces after the tag name
 233               (while (not (looking-at (concat "</" node-name "[[:space:]]*>")))
 234                 (cond
 235                  ((looking-at "</")
 236                   (error (concat
 237                           "XML: invalid syntax -- invalid end tag (expecting "
 238                           node-name
 239                           ") at pos " (number-to-string (point)))))
 240                  ((= (char-after) ?<)
 241                   (let ((tag (xml-parse-tag end)))
 242                     (when tag
 243                       (push tag children))))
 244                  (t
 245                   (setq pos (point))
 246                   (search-forward "<" end)
 247                   (forward-char -1)
 248                   (let ((string (buffer-substring-no-properties pos (point)))
 249                         (pos 0))
 250
 251                     ;; Clean up the string (no newline characters)
 252                     ;; Not done, since as per XML specifications, the XML processor
 253                     ;; should always pass the whole string to the application.
 254                     ;;      (while (string-match "\\s +" string pos)
 255                     ;;        (setq string (replace-match " " t t string))
 256                     ;;        (setq pos (1+ (match-beginning 0))))
 257
 258                     (setq string (xml-substitute-special string))
 259                     (setq children
 260                           (if (stringp (car children))
 261                               ;; The two strings were separated by a comment.
 262                               (cons (concat (car children) string)
 263                                     (cdr children))
 264                             (cons string children)))))))
 265               (goto-char (match-end 0))
 266               (if (> (point) end)
 267                   (error "XML: End tag for %s not found before end of region"
 268                          node-name))
 269               (nreverse children))
 270
 271           ;;  This was an invalid start tag
 272           (error "XML: Invalid attribute list")
 273           ))))
 274    (t ;; This is not a tag.
 275     (error "XML: Invalid character"))
 276    ))
 277
 278 (defun xml-parse-attlist (end)
 279   "Return the attribute-list that point is looking at.
 280 The search for attributes end at the position END in the current buffer.
 281 Leaves the point on the first non-blank character after the tag."
 282   (let ((attlist ())
 283         name)
 284     (goto-char (- (re-search-forward "[^[:space:]]") 1))
 285     (while (looking-at "\\([a-zA-Z_:][-a-zA-Z0-9._:]*\\)[[:space:]]*=[[:space:]]*")
 286       (setq name (intern (match-string 1)))
 287       (goto-char (match-end 0))
 288
 289       ;; Do we have a string between quotes (or double-quotes),
 290       ;;  or a simple word ?
 291       (unless (looking-at "\"\\([^\"]*\\)\"")
 292         (unless (looking-at "'\\([^']*\\)'")
 293           (error "XML: Attribute values must be given between quotes")))
 294
 295       ;; Each attribute must be unique within a given element
 296       (if (assoc name attlist)
 297           (error "XML: each attribute must be unique within an element"))
 298
 299       (push (cons name (match-string-no-properties 1)) attlist)
 300       (goto-char (match-end 0))
 301       (goto-char (- (re-search-forward "[^[:space:]]") 1))
 302       (if (> (point) end)
 303           (error "XML: end of attribute list not found before end of region"))
 304       )
 305     (nreverse attlist)))
 306
 307 ;;*******************************************************************
 308 ;;**
 309 ;;**  The DTD (document type declaration)
 310 ;;**  The following functions know how to skip or parse the DTD of
 311 ;;**  a document
 312 ;;**
 313 ;;*******************************************************************
 314
 315 (defun xml-skip-dtd (end)
 316   "Skip the DTD that point is looking at.
 317 The DTD must end before the position END in the current buffer.
 318 The point must be just before the starting tag of the DTD.
 319 This follows the rule [28] in the XML specifications."
 320   (forward-char (length "<!DOCTYPE"))
 321   (if (looking-at "[[:space:]]*>")
 322       (error "XML: invalid DTD (excepting name of the document)"))
 323   (condition-case nil
 324       (progn
 325         (forward-word 1)  ;; name of the document
 326         (goto-char (- (re-search-forward "[[:space:]]") 1))
 327         (goto-char (- (re-search-forward "[^[:space:]]") 1))
 328         (if (looking-at "\\[")
 329             (re-search-forward "\\][[:space:]]*>" end)
 330           (search-forward ">" end)))
 331     (error (error "XML: No end to the DTD"))))
 332
 333 (defun xml-parse-dtd (end)
 334   "Parse the DTD that point is looking at.
 335 The DTD must end before the position END in the current buffer."
 336   (forward-char (length "<!DOCTYPE"))
 337   (goto-char (- (re-search-forward "[^[:space:]]") 1))
 338   (if (looking-at ">")
 339       (error "XML: invalid DTD (excepting name of the document)"))
 340
 341   ;;  Get the name of the document
 342   (looking-at "\\sw+")
 343   (let ((dtd (list (match-string-no-properties 0) 'dtd))
 344         type element end-pos)
 345     (goto-char (match-end 0))
 346
 347     (goto-char (- (re-search-forward "[^[:space:]]") 1))
 348
 349     ;;  External DTDs => don't know how to handle them yet
 350     (if (looking-at "SYSTEM")
 351         (error "XML: Don't know how to handle external DTDs"))
 352
 353     (if (not (= (char-after) ?\[))
 354         (error "XML: Unknown declaration in the DTD"))
 355
 356     ;;  Parse the rest of the DTD
 357     (forward-char 1)
 358     (while (and (not (looking-at "[[:space:]]*\\]"))
 359                 (<= (point) end))
 360       (cond
 361
 362        ;;  Translation of rule [45] of XML specifications
 363        ((looking-at
 364          "[[:space:]]*<!ELEMENT[[:space:]]+\\([a-zA-Z0-9.%;]+\\)[[:space:]]+\\([^>]+\\)>")
 365
 366         (setq element (intern (match-string-no-properties 1))
 367               type    (match-string-no-properties 2))
 368         (setq end-pos (match-end 0))
 369
 370         ;;  Translation of rule [46] of XML specifications
 371         (cond
 372          ((string-match "^EMPTY[[:space:]]*$" type)     ;; empty declaration
 373           (setq type 'empty))
 374          ((string-match "^ANY[[:space:]]*$" type)       ;; any type of contents
 375           (setq type 'any))
 376          ((string-match "^(\\(.*\\))[[:space:]]*$" type) ;; children ([47])
 377           (setq type (xml-parse-elem-type (match-string-no-properties 1 type))))
 378          ((string-match "^%[^;]+;[[:space:]]*$" type)   ;; substitution
 379           nil)
 380          (t
 381           (error "XML: Invalid element type in the DTD")))
 382
 383         ;;  rule [45]: the element declaration must be unique
 384         (if (assoc element dtd)
 385             (error "XML: elements declaration must be unique in a DTD (<%s>)"
 386                    (symbol-name element)))
 387
 388         ;;  Store the element in the DTD
 389         (push (list element type) dtd)
 390         (goto-char end-pos))
 391
 392
 393        (t
 394         (error "XML: Invalid DTD item"))
 395        )
 396       )
 397
 398     ;;  Skip the end of the DTD
 399     (search-forward ">" end)
 400     (nreverse dtd)))
 401
 402
 403 (defun xml-parse-elem-type (string)
 404   "Convert a STRING for an element type into an elisp structure."
 405
 406   (let (elem modifier)
 407     (if (string-match "(\\([^)]+\\))\\([+*?]?\\)" string)
 408         (progn
 409           (setq elem     (match-string 1 string)
 410                 modifier (match-string 2 string))
 411           (if (string-match "|" elem)
 412               (setq elem (cons 'choice
 413                                (mapcar 'xml-parse-elem-type
 414                                        (split-string elem "|"))))
 415             (if (string-match "," elem)
 416                 (setq elem (cons 'seq
 417                                  (mapcar 'xml-parse-elem-type
 418                                          (split-string elem ","))))
 419               )))
 420       (if (string-match "[[:space:]]*\\([^+*?]+\\)\\([+*?]?\\)" string)
 421           (setq elem     (match-string 1 string)
 422                 modifier (match-string 2 string))))
 423
 424     (if (and (stringp elem) (string= elem "#PCDATA"))
 425         (setq elem 'pcdata))
 426
 427     (cond
 428      ((string= modifier "+")
 429       (list '+ elem))
 430      ((string= modifier "*")
 431       (list '* elem))
 432      ((string= modifier "?")
 433       (list '\? elem))
 434      (t
 435       elem))))
 436
 437
 438 ;;*******************************************************************
 439 ;;**
 440 ;;**  Substituting special XML sequences
 441 ;;**
 442 ;;*******************************************************************
 443
 444 (defun xml-substitute-special (string)
 445   "Return STRING, after subsituting special XML sequences."
 446   (while (string-match "&lt;" string)
 447     (setq string (replace-match "<"  t nil string)))
 448   (while (string-match "&gt;" string)
 449     (setq string (replace-match ">"  t nil string)))
 450   (while (string-match "&apos;" string)
 451     (setq string (replace-match "'"  t nil string)))
 452   (while (string-match "&quot;" string)
 453     (setq string (replace-match "\"" t nil string)))
 454   ;; This goes last so it doesn't confuse the matches above.
 455   (while (string-match "&amp;" string)
 456     (setq string (replace-match "&"  t nil string)))
 457   string)
 458
 459 ;;*******************************************************************
 460 ;;**
 461 ;;**  Printing a tree.
 462 ;;**  This function is intended mainly for debugging purposes.
 463 ;;**
 464 ;;*******************************************************************
 465
 466 (defun xml-debug-print (xml)
 467   (dolist (node xml)
 468     (xml-debug-print-internal node "")))
 469
 470 (defun xml-debug-print-internal (xml indent-string)
 471   "Outputs the XML tree in the current buffer.
 472 The first line indented with INDENT-STRING."
 473   (let ((tree xml)
 474         attlist)
 475     (insert indent-string "<" (symbol-name (xml-node-name tree)))
 476
 477     ;;  output the attribute list
 478     (setq attlist (xml-node-attributes tree))
 479     (while attlist
 480       (insert " ")
 481       (insert (symbol-name (caar attlist)) "=\"" (cdar attlist) "\"")
 482       (setq attlist (cdr attlist)))
 483
 484     (insert ">")
 485
 486     (setq tree (xml-node-children tree))
 487
 488     ;;  output the children
 489     (dolist (node tree)
 490       (cond
 491        ((listp node)
 492         (insert "\n")
 493         (xml-debug-print-internal node (concat indent-string "  ")))
 494        ((stringp node) (insert node))
 495        (t
 496         (error "Invalid XML tree"))))
 497
 498     (insert "\n" indent-string
 499             "</" (symbol-name (xml-node-name xml)) ">")))
 500
 501 (provide 'xml)
 502
 503 ;;; xml.el ends here