lisp/eshell/esh-module.el

   1 ;;; esh-module --- Eshell modules
   2
   3 ;; Copyright (C) 1999, 2000 Free Software Foundation
   4
   5 ;; Author: John Wiegley <johnw@gnu.org>
   6 ;; Keywords: processes
   7 ;; X-URL: http://www.emacs.org/~johnw/eshell.html
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 (provide 'esh-module)
  27
  28 (eval-when-compile (require 'esh-maint) (require 'cl))
  29
  30 (defgroup eshell-module nil
  31   "The `eshell-module' group is for Eshell extension modules, which
  32 provide optional behavior which the user can enable or disable by
  33 customizing the variable `eshell-modules-list'."
  34   :tag "Extension modules"
  35   :group 'eshell)
  36
  37 ;;; Commentary:
  38
  39 (require 'esh-util)
  40
  41 (defun eshell-load-defgroups (&optional directory)
  42   "Load `defgroup' statements from Eshell's module files."
  43   (with-current-buffer
  44       (find-file-noselect (expand-file-name "esh-groups.el" directory))
  45     (erase-buffer)
  46     (insert ";;; do not modify this file; it is auto-generated\n\n")
  47     (let ((files (directory-files (or directory
  48                                       (car command-line-args-left))
  49                                   nil "\\`em-.*\\.el\\'")))
  50       (while files
  51         (message "Loading defgroup from `%s'" (car files))
  52         (let (defgroup)
  53           (catch 'handled
  54             (with-current-buffer (find-file-noselect (car files))
  55               (goto-char (point-min))
  56               (while t
  57                 (forward-sexp)
  58                 (if (eobp) (throw 'handled t))
  59                 (backward-sexp)
  60                 (let ((begin (point))
  61                       (defg (looking-at "(defgroup")))
  62                   (forward-sexp)
  63                   (if defg
  64                       (setq defgroup (buffer-substring begin (point))))))))
  65           (if defgroup
  66               (insert defgroup "\n\n")))
  67         (setq files (cdr files))))
  68     (save-buffer)))
  69
  70 ;; load the defgroup's for the standard extension modules, so that
  71 ;; documentation can be provided when the user customize's
  72 ;; `eshell-modules-list'.
  73 (eval-when-compile
  74   (when (and (boundp 'byte-compile-current-file)
  75              byte-compile-current-file
  76              (equal (file-name-nondirectory byte-compile-current-file)
  77                     "esh-module.el"))
  78     (let* ((directory (file-name-directory byte-compile-current-file))
  79            (elc-file (expand-file-name "esh-groups.elc" directory)))
  80       (eshell-load-defgroups directory)
  81       (if (file-exists-p elc-file) (delete-file elc-file)))))
  82
  83 (load "esh-groups" t t)
  84
  85 ;;; User Variables:
  86
  87 (defcustom eshell-module-unload-hook
  88   '(eshell-unload-extension-modules)
  89   "*A hook run when `eshell-module' is unloaded."
  90   :type 'hook
  91   :group 'eshell-module)
  92
  93 (defcustom eshell-modules-list
  94   '(eshell-alias
  95     eshell-banner
  96     eshell-basic
  97     eshell-cmpl
  98     eshell-dirs
  99     eshell-glob
 100     eshell-hist
 101     eshell-ls
 102     eshell-pred
 103     eshell-prompt
 104     eshell-script
 105     eshell-term
 106     eshell-unix)
 107   "*A list of optional add-on modules to be loaded by Eshell.
 108 Changes will only take effect in future Eshell buffers."
 109   :type (append
 110          (list 'set ':tag "Supported modules")
 111          (mapcar
 112           (function
 113            (lambda (modname)
 114              (let ((modsym (intern modname)))
 115                (list 'const
 116                      ':tag (format "%s -- %s" modname
 117                                    (get modsym 'custom-tag))
 118                      ':link (caar (get modsym 'custom-links))
 119                      ':doc (concat "\n" (get modsym 'group-documentation)
 120                                    "\n ")
 121                      modsym))))
 122           (sort (mapcar 'symbol-name
 123                         (eshell-subgroups 'eshell-module))
 124                 'string-lessp))
 125          '((repeat :inline t :tag "Other modules" symbol)))
 126   :group 'eshell-module)
 127
 128 ;;; Code:
 129
 130 (defsubst eshell-using-module (module)
 131   "Return non-nil if a certain Eshell MODULE is in use.
 132 The MODULE should be a symbol corresponding to that module's
 133 customization group.  Example: `eshell-cmpl' for that module."
 134   (memq module eshell-modules-list))
 135
 136 (defun eshell-unload-extension-modules ()
 137   "Unload any memory resident extension modules."
 138   (eshell-for module (eshell-subgroups 'eshell-module)
 139     (if (featurep module)
 140         (ignore-errors
 141           (message "Unloading %s..." (symbol-name module))
 142           (unload-feature module)
 143           (message "Unloading %s...done" (symbol-name module))))))
 144
 145 ;;; esh-module.el ends here