lisp/desktop.el

   1 ;;; desktop.el --- save partial status of Emacs when killed
   2
   3 ;; Copyright (C) 1993, 1994, 1995, 1997, 2000, 2001
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Morten Welinder <terra@diku.dk>
   7 ;; Keywords: convenience
   8 ;; Favourite-brand-of-beer: None, I hate beer.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Save the Desktop, i.e.,
  30 ;;      - some global variables
  31 ;;      - the list of buffers with associated files.  For each buffer also
  32 ;;              - the major mode
  33 ;;              - the default directory
  34 ;;              - the point
  35 ;;              - the mark & mark-active
  36 ;;              - buffer-read-only
  37 ;;              - some local variables
  38
  39 ;; To use this, first put these two lines in the bottom of your .emacs
  40 ;; file (the later the better):
  41 ;;
  42 ;;      (desktop-load-default)
  43 ;;      (desktop-read)
  44 ;;
  45 ;; Between these two lines you may wish to add something that updates the
  46 ;; variables `desktop-globals-to-save' and/or `desktop-locals-to-save'.  If
  47 ;; for instance you want to save the local variable `foobar' for every buffer
  48 ;; in which it is local, you could add the line
  49 ;;
  50 ;;      (setq desktop-locals-to-save (cons 'foobar desktop-locals-to-save))
  51 ;;
  52 ;; To avoid saving excessive amounts of data you may also wish to add
  53 ;; something like the following
  54 ;;
  55 ;;      (add-hook 'kill-emacs-hook
  56 ;;                '(lambda ()
  57 ;;                   (desktop-truncate search-ring 3)
  58 ;;                   (desktop-truncate regexp-search-ring 3)))
  59 ;;
  60 ;; which will make sure that no more than three search items are saved.  You
  61 ;; must place this line *after* the `(desktop-load-default)' line.  See also
  62 ;; the variable `desktop-save-hook'.
  63
  64 ;; Start Emacs in the root directory of your "project". The desktop saver
  65 ;; is inactive by default.  You activate it by M-x desktop-save RET.  When
  66 ;; you exit the next time the above data will be saved.  This ensures that
  67 ;; all the files you were editing will be reloaded the next time you start
  68 ;; Emacs from the same directory and that points will be set where you
  69 ;; left them.  If you save a desktop file in your home directory it will
  70 ;; act as a default desktop when you start Emacs from a directory that
  71 ;; doesn't have its own.  I never do this, but you may want to.
  72
  73 ;; Some words on minor modes: Most minor modes are controlled by
  74 ;; buffer-local variables, which have a standard save / restore
  75 ;; mechanism.  To handle all minor modes, we take the following
  76 ;; approach: (1) check whether the variable name from
  77 ;; `minor-mode-alist' is also a function; and (2) use translation
  78 ;; table `desktop-minor-mode-table' in the case where the two names
  79 ;; are not the same.
  80
  81 ;; By the way: don't use desktop.el to customize Emacs -- the file .emacs
  82 ;; in your home directory is used for that.  Saving global default values
  83 ;; for buffers is an example of misuse.
  84
  85 ;; PLEASE NOTE: The kill ring can be saved as specified by the variable
  86 ;; `desktop-globals-to-save' (by default it isn't).  This may result in saving
  87 ;; things you did not mean to keep.  Use M-x desktop-clear RET.
  88
  89 ;; Thanks to  hetrick@phys.uva.nl (Jim Hetrick)      for useful ideas.
  90 ;;            avk@rtsg.mot.com (Andrew V. Klein)     for a dired tip.
  91 ;;            chris@tecc.co.uk (Chris Boucher)       for a mark tip.
  92 ;;            f89-kam@nada.kth.se (Klas Mellbourn)   for a mh-e tip.
  93 ;;            kifer@sbkifer.cs.sunysb.edu (M. Kifer) for a bug hunt.
  94 ;;            treese@lcs.mit.edu (Win Treese)        for ange-ftp tips.
  95 ;;            pot@cnuce.cnr.it (Francesco Potorti`)  for misc. tips.
  96 ;; ---------------------------------------------------------------------------
  97 ;; TODO:
  98 ;;
  99 ;; Save window configuration.
 100 ;; Recognize more minor modes.
 101 ;; Save mark rings.
 102 ;; Start-up with buffer-menu???
 103
 104 ;;; Code:
 105
 106 ;; Make the compilation more silent
 107 (eval-when-compile
 108   ;; We use functions from these modules
 109   ;; We can't (require 'mh-e) since that wants to load something.
 110   (mapcar 'require '(info dired reporter)))
 111 ;; ----------------------------------------------------------------------------
 112 ;; USER OPTIONS -- settings you might want to play with.
 113 ;; ----------------------------------------------------------------------------
 114
 115 (defgroup desktop nil
 116   "Save status of Emacs when you exit."
 117   :group 'frames)
 118
 119 (defcustom desktop-enable nil
 120   "*Non-nil enable Desktop to save the state of Emacs when you exit."
 121   :group 'desktop
 122   :type 'boolean
 123   :require 'desktop
 124   :initialize 'custom-initialize-default
 125   :version "20.3")
 126
 127 (defcustom desktop-basefilename
 128   (convert-standard-filename ".emacs.desktop")
 129   "File for Emacs desktop, not including the directory name."
 130   :type 'file
 131   :group 'desktop)
 132
 133 (defcustom desktop-missing-file-warning nil
 134   "*If non-nil then desktop warns when a file no longer exists.
 135 Otherwise it simply ignores that file."
 136   :type 'boolean
 137   :group 'desktop)
 138
 139 (defvar desktop-globals-to-save
 140   (list 'desktop-missing-file-warning
 141         ;; Feature: saving kill-ring implies saving kill-ring-yank-pointer
 142         ;; 'kill-ring
 143         'tags-file-name
 144         'tags-table-list
 145         'search-ring
 146         'regexp-search-ring
 147         'register-alist
 148         ;; 'desktop-globals-to-save     ; Itself!
 149         )
 150   "List of global variables to save when killing Emacs.
 151 An element may be variable name (a symbol)
 152 or a cons cell of the form  (VAR . MAX-SIZE),
 153 which means to truncate VAR's value to at most MAX-SIZE elements
 154 \(if the value is a list) before saving the value.")
 155
 156 (defvar desktop-locals-to-save
 157   (list 'desktop-locals-to-save         ; Itself!  Think it over.
 158         'truncate-lines
 159         'case-fold-search
 160         'case-replace
 161         'fill-column
 162         'overwrite-mode
 163         'change-log-default-name
 164         'line-number-mode
 165         )
 166   "List of local variables to save for each buffer.
 167 The variables are saved only when they really are local.")
 168 (make-variable-buffer-local 'desktop-locals-to-save)
 169
 170 ;; We skip .log files because they are normally temporary.
 171 ;;         (ftp) files because they require passwords and whatnot.
 172 ;;         TAGS files to save time (tags-file-name is saved instead).
 173 (defcustom desktop-buffers-not-to-save
 174  "\\(^nn\\.a[0-9]+\\|\\.log\\|(ftp)\\|^tags\\|^TAGS\\)$"
 175  "Regexp identifying buffers that are to be excluded from saving."
 176  :type 'regexp
 177  :group 'desktop)
 178
 179 ;; Skip ange-ftp files
 180 (defcustom desktop-files-not-to-save
 181   "^/[^/:]*:"
 182   "Regexp identifying files whose buffers are to be excluded from saving."
 183   :type 'regexp
 184   :group 'desktop)
 185
 186 (defcustom desktop-buffer-modes-to-save
 187   '(Info-mode rmail-mode)
 188   "If a buffer is of one of these major modes, save the buffer name.
 189 It is up to the functions in `desktop-buffer-handlers' to decide
 190 whether the buffer should be recreated or not, and how."
 191   :type '(repeat symbol)
 192   :group 'desktop)
 193
 194 (defcustom desktop-modes-not-to-save nil
 195   "List of major modes whose buffers should not be saved."
 196   :type '(repeat symbol)
 197   :group 'desktop)
 198
 199 (defcustom desktop-buffer-major-mode nil
 200   "When desktop creates a buffer, this holds the desired Major mode."
 201   :type 'symbol
 202   :group 'desktop)
 203
 204 (defcustom desktop-buffer-file-name nil
 205   "When desktop creates a buffer, this holds the file name to visit."
 206   :type '(choice file (const nil))
 207   :group 'desktop)
 208
 209 (defcustom desktop-buffer-name nil
 210   "When desktop creates a buffer, this holds the desired buffer name."
 211   :type '(choice string (const nil))
 212   :group 'desktop)
 213
 214 (defvar desktop-buffer-misc nil
 215   "When desktop creates a buffer, this holds a list of misc info.
 216 It is used by the `desktop-buffer-handlers' functions.")
 217
 218 (defcustom desktop-buffer-misc-functions
 219   '(desktop-buffer-info-misc-data
 220     desktop-buffer-dired-misc-data)
 221   "*Functions used to determine auxiliary information for a buffer.
 222 These functions are called in order, with no arguments.  If a function
 223 returns non-nil, its value is saved along with the desktop buffer for
 224 which it was called; no further functions will be called.
 225
 226 Later, when desktop.el restores the buffers it has saved, each of the
 227 `desktop-buffer-handlers' functions will have access to a buffer local
 228 variable, named `desktop-buffer-misc', whose value is what the
 229 \"misc\" function returned previously."
 230   :type '(repeat function)
 231   :group 'desktop)
 232
 233 (defcustom desktop-buffer-handlers
 234   '(desktop-buffer-dired
 235     desktop-buffer-rmail
 236     desktop-buffer-mh
 237     desktop-buffer-info
 238     desktop-buffer-file)
 239   "*List of functions to call in order to create a buffer.
 240 The functions are called without explicit parameters but can use the
 241 variables `desktop-buffer-major-mode', `desktop-buffer-file-name',
 242 `desktop-buffer-name'.
 243 If one function returns non-nil, no further functions are called.
 244 If the function returns a buffer, then the saved mode settings
 245 and variable values for that buffer are copied into it."
 246   :type '(repeat function)
 247   :group 'desktop)
 248
 249 (put 'desktop-buffer-handlers 'risky-local-variable t)
 250
 251 (defvar desktop-create-buffer-form "(desktop-create-buffer 205"
 252   "Opening of form for creation of new buffers.")
 253
 254 (defcustom desktop-save-hook nil
 255   "Hook run before desktop saves the state of Emacs.
 256 This is useful for truncating history lists, for example."
 257   :type 'hook
 258   :group 'desktop)
 259
 260 (defcustom desktop-minor-mode-table
 261   '((auto-fill-function auto-fill-mode)
 262     (vc-mode nil))
 263   "Table mapping minor mode variables to minor mode functions.
 264 Each entry has the form (NAME RESTORE-FUNCTION).
 265 NAME is the name of the buffer-local variable indicating that the minor
 266 mode is active.  RESTORE-FUNCTION is the function to activate the minor mode.
 267 called.  RESTORE-FUNCTION nil means don't try to restore the minor mode.
 268 Only minor modes for which the name of the buffer-local variable
 269 and the name of the minor mode function are different have to added to
 270 this table."
 271   :type 'sexp
 272   :group 'desktop)
 273
 274 ;; ----------------------------------------------------------------------------
 275 (defvar desktop-dirname nil
 276   "The directory in which the current desktop file resides.")
 277
 278 (defconst desktop-header
 279 ";; --------------------------------------------------------------------------
 280 ;; Desktop File for Emacs
 281 ;; --------------------------------------------------------------------------
 282 " "*Header to place in Desktop file.")
 283
 284 (defvar desktop-delay-hook nil
 285   "Hooks run after all buffers are loaded; intended for internal use.")
 286
 287 ;; ----------------------------------------------------------------------------
 288 (defun desktop-truncate (l n)
 289   "Truncate LIST to at most N elements destructively."
 290   (let ((here (nthcdr (1- n) l)))
 291     (if (consp here)
 292         (setcdr here nil))))
 293 ;; ----------------------------------------------------------------------------
 294 (defcustom desktop-clear-preserve-buffers
 295   '("*scratch*" "*Messages*")
 296   "*Buffer names that `desktop-clear' should not delete."
 297   :type '(repeat string)
 298   :group 'desktop)
 299
 300 (defun desktop-clear ()
 301   "Empty the Desktop.
 302 This kills all buffers except for internal ones
 303 and those listed in `desktop-clear-preserve-buffers'."
 304   (interactive)
 305   (setq kill-ring nil
 306         kill-ring-yank-pointer nil
 307         search-ring nil
 308         search-ring-yank-pointer nil
 309         regexp-search-ring nil
 310         regexp-search-ring-yank-pointer nil)
 311   (let ((buffers (buffer-list)))
 312     (while buffers
 313       (or (member (buffer-name (car buffers)) desktop-clear-preserve-buffers)
 314           (null (buffer-name (car buffers)))
 315           ;; Don't kill buffers made for internal purposes.
 316           (and (not (equal (buffer-name (car buffers)) ""))
 317                (eq (aref (buffer-name (car buffers)) 0) ?\ ))
 318           (kill-buffer (car buffers)))
 319       (setq buffers (cdr buffers))))
 320   (delete-other-windows))
 321 ;; ----------------------------------------------------------------------------
 322 (add-hook 'kill-emacs-hook 'desktop-kill)
 323
 324 (defun desktop-kill ()
 325   (if desktop-dirname
 326       (condition-case err
 327           (desktop-save desktop-dirname)
 328         (file-error
 329          (if (yes-or-no-p "Error while saving the desktop.  Quit anyway? ")
 330              nil
 331            (signal (car err) (cdr err)))))))
 332 ;; ----------------------------------------------------------------------------
 333 (defun desktop-list* (&rest args)
 334   (if (null (cdr args))
 335       (car args)
 336     (setq args (nreverse args))
 337     (let ((value (cons (nth 1 args) (car args))))
 338       (setq args (cdr (cdr args)))
 339       (while args
 340         (setq value (cons (car args) value))
 341         (setq args (cdr args)))
 342       value)))
 343
 344 (defun desktop-internal-v2s (val)
 345   "Convert VALUE to a pair (QUOTE . TXT); (eval (read TXT)) gives VALUE.
 346 TXT is a string that when read and evaluated yields value.
 347 QUOTE may be `may' (value may be quoted),
 348 `must' (values must be quoted), or nil (value may not be quoted)."
 349   (cond
 350    ((or (numberp val) (null val) (eq t val))
 351     (cons 'may (prin1-to-string val)))
 352    ((stringp val)
 353     (let ((copy (copy-sequence val)))
 354       (set-text-properties 0 (length copy) nil copy)
 355       ;; Get rid of text properties because we cannot read them
 356       (cons 'may (prin1-to-string copy))))
 357    ((symbolp val)
 358     (cons 'must (prin1-to-string val)))
 359    ((vectorp val)
 360     (let* ((special nil)
 361            (pass1 (mapcar
 362                    (lambda (el)
 363                      (let ((res (desktop-internal-v2s el)))
 364                        (if (null (car res))
 365                            (setq special t))
 366                        res))
 367                    val)))
 368       (if special
 369           (cons nil (concat "(vector "
 370                             (mapconcat (lambda (el)
 371                                          (if (eq (car el) 'must)
 372                                              (concat "'" (cdr el))
 373                                            (cdr el)))
 374                                        pass1
 375                                        " ")
 376                             ")"))
 377         (cons 'may (concat "[" (mapconcat 'cdr pass1 " ") "]")))))
 378    ((consp val)
 379     (let ((p val)
 380           newlist
 381           use-list*
 382           anynil)
 383       (while (consp p)
 384         (let ((q.txt (desktop-internal-v2s (car p))))
 385           (or anynil (setq anynil (null (car q.txt))))
 386           (setq newlist (cons q.txt newlist)))
 387         (setq p (cdr p)))
 388       (if p
 389           (let ((last (desktop-internal-v2s p))
 390                 (el (car newlist)))
 391             (or anynil (setq anynil (null (car last))))
 392             (or anynil
 393                 (setq newlist (cons '(must . ".") newlist)))
 394             (setq use-list* t)
 395             (setq newlist (cons last newlist))))
 396       (setq newlist (nreverse newlist))
 397       (if anynil
 398           (cons nil
 399                 (concat (if use-list* "(desktop-list* "  "(list ")
 400                         (mapconcat (lambda (el)
 401                                      (if (eq (car el) 'must)
 402                                          (concat "'" (cdr el))
 403                                        (cdr el)))
 404                                    newlist
 405                                    " ")
 406                         ")"))
 407         (cons 'must
 408               (concat "(" (mapconcat 'cdr newlist " ") ")")))))
 409    ((subrp val)
 410     (cons nil (concat "(symbol-function '"
 411                       (substring (prin1-to-string val) 7 -1)
 412                       ")")))
 413    ((markerp val)
 414     (let ((pos (prin1-to-string (marker-position val)))
 415           (buf (prin1-to-string (buffer-name (marker-buffer val)))))
 416       (cons nil (concat "(let ((mk (make-marker)))"
 417                         " (add-hook 'desktop-delay-hook"
 418                         " (list 'lambda '() (list 'set-marker mk "
 419                         pos " (get-buffer " buf ")))) mk)"))))
 420    (t                                   ; save as text
 421     (cons 'may "\"Unprintable entity\""))))
 422
 423 (defun desktop-value-to-string (val)
 424   "Convert VALUE to a string that when read evaluates to the same value.
 425 Not all types of values are supported."
 426   (let* ((print-escape-newlines t)
 427          (float-output-format nil)
 428          (quote.txt (desktop-internal-v2s val))
 429          (quote (car quote.txt))
 430          (txt (cdr quote.txt)))
 431     (if (eq quote 'must)
 432         (concat "'" txt)
 433       txt)))
 434 ;; ----------------------------------------------------------------------------
 435 (defun desktop-outvar (varspec)
 436   "Output a setq statement for variable VAR to the desktop file.
 437 The argument VARSPEC may be the variable name VAR (a symbol),
 438 or a cons cell of the form  (VAR . MAX-SIZE),
 439 which means to truncate VAR's value to at most MAX-SIZE elements
 440 \(if the value is a list) before saving the value."
 441   (let (var size)
 442     (if (consp varspec)
 443         (setq var (car varspec) size (cdr varspec))
 444       (setq var varspec))
 445     (if (boundp var)
 446         (progn
 447           (if (and (integerp size)
 448                    (> size 0)
 449                    (listp (eval var)))
 450               (desktop-truncate (eval var) size))
 451           (insert "(setq "
 452                   (symbol-name var)
 453                   " "
 454                   (desktop-value-to-string (symbol-value var))
 455                   ")\n")))))
 456 ;; ----------------------------------------------------------------------------
 457 (defun desktop-save-buffer-p (filename bufname mode &rest dummy)
 458   "Return t if the desktop should record a particular buffer for next startup.
 459 FILENAME is the visited file name, BUFNAME is the buffer name, and
 460 MODE is the major mode."
 461   (let ((case-fold-search nil))
 462     (and (not (string-match desktop-buffers-not-to-save bufname))
 463          (not (memq mode desktop-modes-not-to-save))
 464          (or (and filename
 465                   (not (string-match desktop-files-not-to-save filename)))
 466              (and (eq mode 'dired-mode)
 467                   (save-excursion
 468                     (set-buffer (get-buffer bufname))
 469                     (not (string-match desktop-files-not-to-save
 470                                        default-directory))))
 471              (and (null filename)
 472                   (memq mode desktop-buffer-modes-to-save))))))
 473 ;; ----------------------------------------------------------------------------
 474 (defun desktop-save (dirname)
 475   "Save the Desktop file.  Parameter DIRNAME specifies where to save desktop."
 476   (interactive "DDirectory to save desktop file in: ")
 477   (run-hooks 'desktop-save-hook)
 478   (save-excursion
 479     (let ((filename (expand-file-name desktop-basefilename dirname))
 480           (info (nreverse
 481                  (mapcar
 482                   (function
 483                    (lambda (b)
 484                               (set-buffer b)
 485                               (list
 486                                (buffer-file-name)
 487                                (buffer-name)
 488                                major-mode
 489                                ;; minor modes
 490                                (let (ret)
 491                                  (mapcar
 492                                   #'(lambda (mim)
 493                                       (and (boundp mim)
 494                                            (symbol-value mim)
 495                                            (setq ret
 496                                                  (cons (let ((special (assq mim desktop-minor-mode-table)))
 497                                                         (if special
 498                                                             (cadr special)
 499                                                           mim))
 500                                                       ret))))
 501                                   (mapcar #'car minor-mode-alist))
 502                                  ret)
 503                                (point)
 504                                (list (mark t) mark-active)
 505                                buffer-read-only
 506                                (run-hook-with-args-until-success
 507                                 'desktop-buffer-misc-functions)
 508                                (let ((locals desktop-locals-to-save)
 509                                      (loclist (buffer-local-variables))
 510                                      (ll))
 511                                  (while locals
 512                                    (let ((here (assq (car locals) loclist)))
 513                                      (if here
 514                                          (setq ll (cons here ll))
 515                                        (if (member (car locals) loclist)
 516                                            (setq ll (cons (car locals) ll)))))
 517                                    (setq locals (cdr locals)))
 518                                  ll)
 519                                )))
 520                   (buffer-list))))
 521           (buf (get-buffer-create "*desktop*")))
 522       (set-buffer buf)
 523       (erase-buffer)
 524
 525       (insert ";; -*- coding: emacs-mule; -*-\n"
 526               desktop-header
 527               ";; Created " (current-time-string) "\n"
 528               ";; Emacs version " emacs-version "\n\n"
 529               ";; Global section:\n")
 530       (mapcar (function desktop-outvar) desktop-globals-to-save)
 531       (if (memq 'kill-ring desktop-globals-to-save)
 532           (insert "(setq kill-ring-yank-pointer (nthcdr "
 533                   (int-to-string
 534                    (- (length kill-ring) (length kill-ring-yank-pointer)))
 535                   " kill-ring))\n"))
 536
 537       (insert "\n;; Buffer section:\n")
 538       (mapcar
 539        (function (lambda (l)
 540                    (if (apply 'desktop-save-buffer-p l)
 541                        (progn
 542                          (insert desktop-create-buffer-form)
 543                          (mapcar
 544                           (function (lambda (e)
 545                                       (insert "\n  "
 546                                               (desktop-value-to-string e))))
 547                           l)
 548                          (insert ")\n\n")))))
 549        info)
 550       (setq default-directory dirname)
 551       (if (file-exists-p filename) (delete-file filename))
 552       (let ((coding-system-for-write 'emacs-mule))
 553         (write-region (point-min) (point-max) filename nil 'nomessage))))
 554   (setq desktop-dirname dirname))
 555 ;; ----------------------------------------------------------------------------
 556 (defun desktop-remove ()
 557   "Delete the Desktop file and inactivate the desktop system."
 558   (interactive)
 559   (if desktop-dirname
 560       (let ((filename (concat desktop-dirname desktop-basefilename)))
 561         (setq desktop-dirname nil)
 562         (if (file-exists-p filename)
 563             (delete-file filename)))))
 564 ;; ----------------------------------------------------------------------------
 565 ;;;###autoload
 566 (defun desktop-read ()
 567   "Read the Desktop file and the files it specifies.
 568 This is a no-op when Emacs is running in batch mode."
 569   (interactive)
 570   (if noninteractive
 571       nil
 572     (let ((dirs '("./" "~/")))
 573       (while (and dirs
 574                   (not (file-exists-p (expand-file-name
 575                                        desktop-basefilename
 576                                        (car dirs)))))
 577         (setq dirs (cdr dirs)))
 578       (setq desktop-dirname (and dirs (expand-file-name (car dirs))))
 579       (if desktop-dirname
 580           (let ((desktop-last-buffer nil))
 581             ;; `load-with-code-conversion' calls `eval-buffer' which
 582             ;; contains a `save-excursion', so we end up with the same
 583             ;; buffer before and after the load.  This is a problem
 584             ;; when the desktop is read initially when Emacs starts up
 585             ;; because, if we still are in *scratch* after running
 586             ;; `after-init-hook', the splash screen will be displayed.
 587             (load (expand-file-name desktop-basefilename desktop-dirname)
 588                   t t t)
 589             (when desktop-last-buffer
 590               (switch-to-buffer desktop-last-buffer))
 591             (run-hooks 'desktop-delay-hook)
 592             (setq desktop-delay-hook nil)
 593             (message "Desktop loaded."))
 594         (desktop-clear)))))
 595 ;; ----------------------------------------------------------------------------
 596 ;;;###autoload
 597 (defun desktop-load-default ()
 598   "Load the `default' start-up library manually.
 599 Also inhibit further loading of it.  Call this from your `.emacs' file
 600 to provide correct modes for autoloaded files."
 601   (if (not inhibit-default-init)        ; safety check
 602       (progn
 603         (load "default" t t)
 604         (setq inhibit-default-init t))))
 605 ;; ----------------------------------------------------------------------------
 606 ;; Note: the following functions use the dynamic variable binding in Lisp.
 607 ;;
 608 (defun desktop-buffer-info-misc-data ()
 609   (if (eq major-mode 'Info-mode)
 610       (list Info-current-file
 611             Info-current-node)))
 612
 613 (defun desktop-buffer-dired-misc-data ()
 614   (if (eq major-mode 'dired-mode)
 615       (cons
 616        (expand-file-name dired-directory)
 617        (cdr
 618         (nreverse
 619          (mapcar
 620           (function car)
 621           dired-subdir-alist))))))
 622
 623 (defun desktop-buffer-info () "Load an info file."
 624   (if (eq 'Info-mode desktop-buffer-major-mode)
 625       (progn
 626         (let ((first (nth 0 desktop-buffer-misc))
 627               (second (nth 1 desktop-buffer-misc)))
 628         (when (and first second)
 629           (require 'info)
 630           (Info-find-node first second)
 631           (current-buffer))))))
 632 ;; ----------------------------------------------------------------------------
 633 (defun desktop-buffer-rmail () "Load an RMAIL file."
 634   (if (eq 'rmail-mode desktop-buffer-major-mode)
 635       (condition-case error
 636           (progn (rmail-input desktop-buffer-file-name)
 637                          (if (eq major-mode 'rmail-mode)
 638                              (current-buffer)
 639                            rmail-buffer))
 640         (file-locked
 641          (kill-buffer (current-buffer))
 642          'ignored))))
 643 ;; ----------------------------------------------------------------------------
 644 (defun desktop-buffer-mh () "Load a folder in the mh system."
 645   (if (eq 'mh-folder-mode desktop-buffer-major-mode)
 646       (progn
 647         (require 'mh-e)
 648         (mh-find-path)
 649         (mh-visit-folder desktop-buffer-name)
 650         (current-buffer))))
 651 ;; ----------------------------------------------------------------------------
 652 (defun desktop-buffer-dired () "Load a directory using dired."
 653   (if (eq 'dired-mode desktop-buffer-major-mode)
 654       (if (file-directory-p (file-name-directory (car desktop-buffer-misc)))
 655           (progn
 656             (dired (car desktop-buffer-misc))
 657             (mapcar 'dired-maybe-insert-subdir (cdr desktop-buffer-misc))
 658             (current-buffer))
 659         (message "Directory %s no longer exists." (car desktop-buffer-misc))
 660         (sit-for 1)
 661         'ignored)))
 662 ;; ----------------------------------------------------------------------------
 663 (defun desktop-buffer-file () "Load a file."
 664   (if desktop-buffer-file-name
 665       (if (or (file-exists-p desktop-buffer-file-name)
 666               (and desktop-missing-file-warning
 667                    (y-or-n-p (format
 668                               "File \"%s\" no longer exists. Re-create? "
 669                               desktop-buffer-file-name))))
 670           (let ((buf (find-file-noselect desktop-buffer-file-name)))
 671             (condition-case nil
 672                 (switch-to-buffer buf)
 673               (error (pop-to-buffer buf)))
 674             buf)
 675         'ignored)))
 676 ;; ----------------------------------------------------------------------------
 677 ;; Create a buffer, load its file, set is mode, ...;  called from Desktop file
 678 ;; only.
 679
 680 (defvar desktop-last-buffer nil
 681   "Last buffer read.  Dynamically bound in `desktop-read'.")
 682
 683 (defun desktop-create-buffer (ver desktop-buffer-file-name desktop-buffer-name
 684                                   desktop-buffer-major-mode
 685                                   mim pt mk ro desktop-buffer-misc
 686                                   &optional locals)
 687   (let ((hlist desktop-buffer-handlers)
 688         (result)
 689         (handler))
 690     (while (and (not result) hlist)
 691       (setq handler (car hlist))
 692       (setq result (funcall handler))
 693       (setq hlist (cdr hlist)))
 694     (when (bufferp result)
 695       (setq desktop-last-buffer result)
 696       (set-buffer result)
 697       (if (not (equal (buffer-name) desktop-buffer-name))
 698           (rename-buffer desktop-buffer-name))
 699       ;; minor modes
 700       (cond ((equal '(t) mim)   (auto-fill-mode 1))     ; backwards compatible
 701             ((equal '(nil) mim) (auto-fill-mode 0))
 702             (t (mapcar #'(lambda (minor-mode)
 703                            (when (functionp minor-mode)
 704                              (funcall minor-mode 1)))
 705                        mim)))
 706       (goto-char pt)
 707       (if (consp mk)
 708           (progn
 709             (set-mark (car mk))
 710             (setq mark-active (car (cdr mk))))
 711         (set-mark mk))
 712       ;; Never override file system if the file really is read-only marked.
 713       (if ro (setq buffer-read-only ro))
 714       (while locals
 715         (let ((this (car locals)))
 716           (if (consp this)
 717               ;; an entry of this form `(symbol . value)'
 718               (progn
 719                 (make-local-variable (car this))
 720                 (set (car this) (cdr this)))
 721             ;; an entry of the form `symbol'
 722             (make-local-variable this)
 723             (makunbound this)))
 724         (setq locals (cdr locals))))))
 725
 726 ;; Backward compatibility -- update parameters to 205 standards.
 727 (defun desktop-buffer (desktop-buffer-file-name desktop-buffer-name
 728                        desktop-buffer-major-mode
 729                        mim pt mk ro tl fc cfs cr desktop-buffer-misc)
 730   (desktop-create-buffer 205 desktop-buffer-file-name desktop-buffer-name
 731                          desktop-buffer-major-mode (cdr mim) pt mk ro
 732                          desktop-buffer-misc
 733                          (list (cons 'truncate-lines tl)
 734                                (cons 'fill-column fc)
 735                                (cons 'case-fold-search cfs)
 736                                (cons 'case-replace cr)
 737                                (cons 'overwrite-mode (car mim)))))
 738 ;; ----------------------------------------------------------------------------
 739
 740 ;; If the user set desktop-enable to t with Custom,
 741 ;; do the rest of what it takes to use desktop,
 742 ;; but do it after finishing loading the init file.
 743 (add-hook 'after-init-hook
 744           '(lambda ()
 745              (when desktop-enable
 746                (desktop-load-default)
 747                (desktop-read))))
 748
 749 (provide 'desktop)
 750
 751 ;;; desktop.el ends here