| blob | 647752443911f9b6c78400d5575f9e2323e62cfc |
1 @echo off\r
2 rem ----------------------------------------------------------------------\r
3 rem Configuration script for MSDOS\r
4 rem Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2001, 2004\r
5 rem Free Software Foundation, Inc.\r
6 \r
7 rem This file is part of GNU Emacs.\r
8 \r
9 rem GNU Emacs is free software; you can redistribute it and/or modify\r
10 rem it under the terms of the GNU General Public License as published by\r
11 rem the Free Software Foundation; either version 2, or (at your option)\r
12 rem any later version.\r
13 \r
14 rem GNU Emacs is distributed in the hope that it will be useful,\r
15 rem but WITHOUT ANY WARRANTY; without even the implied warranty of\r
16 rem MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the\r
17 rem GNU General Public License for more details.\r
18 \r
19 rem You should have received a copy of the GNU General Public License\r
20 rem along with GNU Emacs; see the file COPYING. If not, write to the\r
21 rem Free Software Foundation, Inc., 59 Temple Place - Suite 330,\r
22 rem Boston, MA 02111-1307, USA.\r
23 rem ----------------------------------------------------------------------\r
24 rem YOU'LL NEED THE FOLLOWING UTILITIES TO MAKE EMACS:\r
25 rem\r
26 rem + msdos version 3 or better.\r
27 rem + DJGPP version 1.12maint1 or later (version 2.03 or later recommended).\r
28 rem + make utility that allows breaking of the 128 chars limit on\r
29 rem command lines. ndmake (as of version 4.5) won't work due to a\r
30 rem line length limit. The make that comes with DJGPP does work.\r
31 rem + rm and mv (from GNU file utilities).\r
32 rem + sed (you can use the port that comes with DJGPP).\r
33 rem\r
34 rem You should be able to get all the above utilities from the DJGPP FTP\r
35 rem site, ftp.delorie.com, in the directory "pub/djgpp/current/v2gnu".\r
36 rem ----------------------------------------------------------------------\r
37 set X11=\r
38 set nodebug=\r
39 set djgpp_ver=\r
40 if "%1" == "" goto usage\r
41 rem ----------------------------------------------------------------------\r
42 rem See if their environment is large enough. We need 28 bytes.\r
43 set $foo$=789012345678901234567\r
44 if not "%$foo$%" == "789012345678901234567" goto SmallEnv\r
45 set $foo$=\r
46 :again\r
47 if "%1" == "" goto usage\r
48 if "%1" == "--with-x" goto withx\r
49 if "%1" == "--no-debug" goto nodebug\r
50 if "%1" == "msdos" goto msdos\r
51 :usage\r
52 echo Usage: config [--with-x] [--no-debug] msdos\r
53 echo [Read the script before you run it.]\r
54 goto end\r
55 rem ----------------------------------------------------------------------\r
56 :withx\r
57 set X11=Y\r
58 shift\r
59 goto again\r
60 rem ----------------------------------------------------------------------\r
61 :nodebug\r
62 set nodebug=Y\r
63 shift\r
64 goto again\r
65 rem ----------------------------------------------------------------------\r
66 :msdos\r
67 Echo Checking whether 'sed' is available...\r
68 sed -e "w junk.$$$" <Nul\r
69 If Exist junk.$$$ Goto sedOk\r
70 Echo To configure 'Emacs' you need to have 'sed'!\r
71 Goto End\r
72 :sedOk\r
73 Echo Checking whether 'rm' is available...\r
74 rm -f junk.$$$\r
75 If Not Exist junk.$$$ Goto rmOk\r
76 Echo To configure 'Emacs' you need to have 'rm'!\r
77 Goto End\r
78 :rmOk\r
79 Echo Checking whether 'mv' is available...\r
80 rm -f junk.1 junk.2\r
81 echo foo >junk.1\r
82 mv junk.1 ./junk.2\r
83 If Exist junk.2 Goto mvOk\r
84 Echo To configure 'Emacs' you need to have 'mv'!\r
85 rm -f junk.1\r
86 Goto End\r
87 :mvOk\r
88 rm -f junk.2\r
89 Echo Checking whether 'gcc' is available...\r
90 echo main(){} >junk.c\r
91 gcc -c junk.c\r
92 if exist junk.o goto gccOk\r
93 Echo To configure 'Emacs' you need to have 'gcc'!\r
94 rm -f junk.c\r
95 Goto End\r
96 :gccOk\r
97 rm -f junk.c junk.o junk junk.exe\r
98 Echo Checking what version of DJGPP is installed...\r
99 If Not "%DJGPP%" == "" goto djgppOk\r
100 Echo To compile 'Emacs' under MS-DOS you MUST have DJGPP installed!\r
101 Goto End\r
102 :djgppOk\r
103 echo int main() >junk.c\r
104 echo #ifdef __DJGPP__ >>junk.c\r
105 echo {return (__DJGPP__)*10;} >>junk.c\r
106 echo #else >>junk.c\r
107 echo #ifdef __GO32__ >>junk.c\r
108 echo {return 10;} >>junk.c\r
109 echo #else >>junk.c\r
110 echo {return 0;} >>junk.c\r
111 echo #endif >>junk.c\r
112 echo #endif >>junk.c\r
113 gcc -o junk junk.c\r
114 if not exist junk.exe coff2exe junk\r
115 junk\r
116 If ErrorLevel 10 Goto go32Ok\r
117 rm -f junk.c junk junk.exe\r
118 Echo To compile 'Emacs' under MS-DOS you MUST have DJGPP installed!\r
119 Goto End\r
120 :go32Ok\r
121 set djgpp_ver=1\r
122 If ErrorLevel 20 set djgpp_ver=2\r
123 rm -f junk.c junk junk.exe\r
124 rem The v1.x build does not need djecho\r
125 if "%DJGPP_VER%" == "1" Goto djechoOk\r
126 rem DJECHO is used by the top-level Makefile in the v2.x build\r
127 Echo Checking whether 'djecho' is available...\r
128 redir -o Nul -eo djecho -o junk.$$$ foo\r
129 If Exist junk.$$$ Goto djechoOk\r
130 Echo To build 'Emacs' you need the 'djecho.exe' program!\r
131 Echo 'djecho.exe' is part of 'djdevNNN.zip' basic DJGPP development kit.\r
132 Echo Versions of DJGPP before 2.02 called this program 'echo.exe'.\r
133 Echo Either unpack 'djecho.exe' from the 'djdevNNN.zip' archive,\r
134 Echo or, if you have 'echo.exe', copy it to 'djecho.exe'.\r
135 Echo Then run CONFIG.BAT again with the same arguments you did now.\r
136 Goto End\r
137 :djechoOk\r
138 rm -f junk.$$$\r
139 Echo Configuring for DJGPP Version %DJGPP_VER% ...\r
140 Rem ----------------------------------------------------------------------\r
141 Echo Configuring the source directory...\r
142 cd src\r
143 \r
144 rem Create "epaths.h"\r
145 sed -f ../msdos/sed4.inp <epaths.in >epaths.tmp\r
146 update epaths.tmp epaths.h >nul\r
147 rm -f epaths.tmp\r
148 \r
149 rem Create "config.h"\r
150 rm -f config.h2 config.tmp\r
151 sed -e '' config.in > config.tmp\r
152 if "%X11%" == "" goto src4\r
153 sed -f ../msdos/sed2x.inp <config.in >config.tmp\r
154 :src4\r
155 if "%DJGPP_VER%" == "2" Goto src41\r
156 sed -f ../msdos/sed2.inp <config.tmp >config.h2\r
157 goto src42\r
158 :src41\r
159 sed -f ../msdos/sed2v2.inp <config.tmp >config.h2\r
160 :src42\r
161 Rem See if DECL_ALIGN can be supported with this GCC\r
162 rm -f junk.c junk.o junk junk.exe\r
163 echo struct { int i; char *p; } __attribute__((__aligned__(8))) foo; >junk.c\r
164 rem Two percent signs because it is a special character for COMMAND.COM\r
165 echo int main(void) { return (unsigned long)&foo %% 8; } >>junk.c\r
166 gcc -o junk junk.c\r
167 if not exist junk.exe coff2exe junk\r
168 junk\r
169 If Not ErrorLevel 1 Goto alignOk\r
170 Echo WARNING: Your GCC does not support 8-byte aligned variables.\r
171 Echo WARNING: Therefore Emacs cannot support buffers larger than 128MB.\r
172 rem The following line disables DECL_ALIGN which in turn disables USE_LSB_TAG\r
173 rem For details see lisp.h where it defines USE_LSB_TAG\r
174 echo #define DECL_ALIGN(type, var) type var >>config.h2\r
175 :alignOk\r
176 rm -f junk.c junk junk.exe\r
177 update config.h2 config.h >nul\r
178 rm -f config.tmp config.h2\r
179 \r
180 rem On my system dir.h gets in the way. It's a VMS file so who cares.\r
181 if exist dir.h ren dir.h vmsdir.h\r
182 \r
183 rem Create "makefile" from "makefile.in".\r
184 rm -f Makefile junk.c\r
185 sed -e "1,/== start of cpp stuff ==/s@^# .*$@@" <Makefile.in >junk.c\r
186 If "%DJGPP_VER%" == "1" Goto mfV1\r
187 gcc -E -traditional junk.c | sed -f ../msdos/sed1v2.inp >Makefile\r
188 goto mfDone\r
189 :mfV1\r
190 gcc -E -traditional junk.c | sed -f ../msdos/sed1.inp >Makefile\r
191 :mfDone\r
192 rm -f junk.c\r
193 \r
194 if "%X11%" == "" goto src5\r
195 mv Makefile makefile.tmp\r
196 sed -f ../msdos/sed1x.inp <makefile.tmp >Makefile\r
197 rm -f makefile.tmp\r
198 :src5\r
199 \r
200 if "%nodebug%" == "" goto src6\r
201 sed -e "/^CFLAGS *=/s/ *-gcoff//" <Makefile >makefile.tmp\r
202 sed -e "/^LDFLAGS *=/s/=/=-s/" <makefile.tmp >Makefile\r
203 rm -f makefile.tmp\r
204 :src6\r
205 cd ..\r
206 rem ----------------------------------------------------------------------\r
207 Echo Configuring the library source directory...\r
208 cd lib-src\r
209 rem Create "makefile" from "makefile.in".\r
210 sed -e "1,/== start of cpp stuff ==/s@^#[ ].*$@@" <Makefile.in >junk.c\r
211 gcc -E -traditional -I. -I../src junk.c | sed -e "s/^ / /" -e "/^#/d" -e "/^[ \f]*$/d" >makefile.new\r
212 If "%DJGPP_VER%" == "2" goto libsrc-v2\r
213 sed -f ../msdos/sed3.inp <makefile.new >Makefile\r
214 Goto libsrc2\r
215 :libsrc-v2\r
216 sed -f ../msdos/sed3v2.inp <makefile.new >Makefile\r
217 :libsrc2\r
218 rm -f makefile.new junk.c\r
219 if "%nodebug%" == "" goto libsrc3\r
220 sed -e "/^CFLAGS *=/s/ *-gcoff//" <Makefile >makefile.tmp\r
221 sed -e "/^ALL_CFLAGS *=/s/=/= -s/" <makefile.tmp >Makefile\r
222 rm -f makefile.tmp\r
223 :libsrc3\r
224 cd ..\r
225 rem ----------------------------------------------------------------------\r
226 if "%X11%" == "" goto oldx1\r
227 Echo Configuring the oldxmenu directory...\r
228 cd oldxmenu\r
229 sed -f ../msdos/sed5x.inp <Makefile.in >Makefile\r
230 if "%nodebug%" == "" goto oldx2\r
231 sed -e "/^CFLAGS *=/s/ *-gcoff//" <Makefile >makefile.tmp\r
232 mv -f makefile.tmp Makefile\r
233 :oldx2\r
234 cd ..\r
235 :oldx1\r
236 rem ----------------------------------------------------------------------\r
237 Echo Configuring the manual directory...\r
238 cd man\r
239 sed -f ../msdos/sed6.inp < Makefile.in > Makefile\r
240 cd ..\r
241 rem ----------------------------------------------------------------------\r
242 Echo Configuring the ELisp manual directory...\r
243 cd lispref\r
244 sed -f ../msdos/sed6.inp < Makefile.in > Makefile\r
245 cd ..\r
246 rem ----------------------------------------------------------------------\r
247 Echo Configuring the ELisp Introduction manual directory...\r
248 Rem The two variants for the line below is for when the shell\r
249 Rem supports long file names but DJGPP does not\r
250 if exist lispintro\Makefile.in cd lispintro\r
251 if exist lispintr\Makefile.in cd lispintr\r
252 sed -f ../msdos/sed6.inp < Makefile.in > Makefile\r
253 cd ..\r
254 rem ----------------------------------------------------------------------\r
255 Echo Configuring the lisp directory...\r
256 cd lisp\r
257 sed -f ../msdos/sedlisp.inp < Makefile.in > Makefile\r
258 cd ..\r
259 rem ----------------------------------------------------------------------\r
260 If not Exist leim\quail\latin-pre.el goto maindir\r
261 Echo Configuring the leim directory...\r
262 cd leim\r
263 sed -f ../msdos/sedleim.inp < Makefile.in > Makefile\r
264 cd ..\r
265 rem ----------------------------------------------------------------------\r
266 :maindir\r
267 Echo Configuring the main directory...\r
268 If "%DJGPP_VER%" == "1" goto mainv1\r
269 Echo Looking for the GDB init file...\r
270 If Exist src\.gdbinit update src/.gdbinit src/_gdbinit\r
271 If Exist src\_gdbinit goto gdbinitOk\r
272 Echo ERROR:\r
273 Echo I cannot find the GDB init file. It was called ".gdbinit" in\r
274 Echo the Emacs distribution, but was probably renamed to some other\r
275 Echo name without the leading dot when you untarred the archive.\r
276 Echo It should be in the "src/" subdirectory. Please make sure this\r
277 Echo file exists and is called "_gdbinit" with a leading underscore.\r
278 Echo Then run CONFIG.BAT again with the same arguments you did now.\r
279 goto End\r
280 :gdbinitOk\r
281 Echo Looking for the GDB init file...found\r
282 copy msdos\mainmake.v2 Makefile >nul\r
283 :mainv1\r
284 If "%DJGPP_VER%" == "1" copy msdos\mainmake Makefile >nul\r
285 rem ----------------------------------------------------------------------\r
286 goto End\r
287 :SmallEnv\r
288 echo Your environment size is too small. Please enlarge it and run me again.\r
289 echo For example, type "command.com /e:2048" to have 2048 bytes available.\r
290 set $foo$=\r
291 :end\r
292 set X11=\r
293 set nodebug=\r
294 set djgpp_ver=\r
295 \r
296 goto skipArchTag\r
297 arch-tag: 2d2fed23-4dc6-4006-a2e4-49daf0031f33\r
298 :skipArchTag\r