lisp/tooltip.el

   1 ;;; tooltip.el --- show tooltip windows
   2
   3 ;; Copyright (C) 1997, 1999, 2000, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Gerd Moellmann <gerd@acm.org>
   6 ;; Keywords: help c mouse tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile
  30   (require 'cl)
  31   (require 'comint)
  32   (require 'gud)
  33   (require 'gdb-ui))
  34
  35 \f
  36 ;;; Customizable settings
  37
  38 (defgroup tooltip nil
  39   "Customization group for the `tooltip' package."
  40   :group 'help
  41   :group 'gud
  42   :group 'mouse
  43   :group 'tools
  44   :version "21.1"
  45   :tag "Tool Tips")
  46
  47 (defvar tooltip-mode)
  48
  49 (defcustom tooltip-delay 0.7
  50   "Seconds to wait before displaying a tooltip the first time."
  51   :tag "Delay"
  52   :type 'number
  53   :group 'tooltip)
  54
  55 (defcustom tooltip-short-delay 0.1
  56   "Seconds to wait between subsequent tooltips on different items."
  57   :tag "Short delay"
  58   :type 'number
  59   :group 'tooltip)
  60
  61 (defcustom tooltip-recent-seconds 1
  62   "Display tooltips if changing tip items within this many seconds.
  63 Do so after `tooltip-short-delay'."
  64   :tag "Recent seconds"
  65   :type 'number
  66   :group 'tooltip)
  67
  68 (defcustom tooltip-hide-delay 10
  69   "Hide tooltips automatically after this many seconds."
  70   :tag "Hide delay"
  71   :type 'number
  72   :group 'tooltip)
  73
  74 (defcustom tooltip-x-offset nil
  75   "X offset, in pixels, for the display of tooltips.
  76 The offset is relative to the position of the mouse.  It must
  77 be chosen so that the tooltip window doesn't contain the mouse
  78 when it pops up.  If the value is nil, the default offset is 5
  79 pixels.
  80
  81 If `tooltip-frame-parameters' includes the `left' parameter,
  82 the value of `tooltip-x-offset' is ignored."
  83   :tag "X offset"
  84   :type '(choice (const :tag "Default" nil)
  85                  (integer :tag "Offset" :value 1))
  86   :group 'tooltip)
  87
  88 (defcustom tooltip-y-offset nil
  89   "Y offset, in pixels, for the display of tooltips.
  90 The offset is relative to the position of the mouse.  It must
  91 be chosen so that the tooltip window doesn't contain the mouse
  92 when it pops up.  If the value is nil, the default offset is -10
  93 pixels.
  94
  95 If `tooltip-frame-parameters' includes the `top' parameter,
  96 the value of `tooltip-y-offset' is ignored."
  97   :tag "Y offset"
  98   :type '(choice (const :tag "Default" nil)
  99                  (integer :tag "Offset" :value 1))
 100   :group 'tooltip)
 101
 102 (defcustom tooltip-frame-parameters
 103   '((name . "tooltip")
 104     (internal-border-width . 5)
 105     (border-width . 1))
 106   "Frame parameters used for tooltips.
 107
 108 If `left' or `top' parameters are included, they specify the absolute
 109 position to pop up the tooltip."
 110   :type 'sexp
 111   :tag "Frame Parameters"
 112   :group 'tooltip)
 113
 114 (defface tooltip
 115   '((((class color))
 116      :background "lightyellow"
 117      :foreground "black"
 118      :inherit variable-pitch)
 119     (t
 120      :inherit variable-pitch))
 121   "Face for tooltips."
 122   :group 'tooltip)
 123
 124 (defcustom tooltip-gud-tips-p nil
 125   "*Non-nil means show tooltips in GUD sessions."
 126   :type 'boolean
 127   :tag "GUD"
 128   :set #'(lambda (symbol on)
 129            (setq tooltip-gud-tips-p on))
 130   :group 'tooltip)
 131
 132 (defcustom tooltip-gud-modes '(gud-mode c-mode c++-mode)
 133   "List of modes for which to enable GUD tips."
 134   :type 'sexp
 135   :tag "GUD modes"
 136   :group 'tooltip)
 137
 138 (defcustom tooltip-gud-display
 139   '((eq (tooltip-event-buffer tooltip-gud-event)
 140         (marker-buffer overlay-arrow-position)))
 141   "List of forms determining where GUD tooltips are displayed.
 142
 143 Forms in the list are combined with AND.  The default is to display
 144 only tooltips in the buffer containing the overlay arrow."
 145   :type 'sexp
 146   :tag "GUD buffers predicate"
 147   :group 'tooltip)
 148
 149 (defcustom tooltip-use-echo-area nil
 150   "Use the echo area instead of tooltip frames.
 151 This is only relevant GUD display, since otherwise it is equivalent to
 152 turning off Tooltip mode."
 153   :type 'boolean
 154   :tag "Use echo area"
 155   :group 'tooltip)
 156
 157 \f
 158 ;;; Variables that are not customizable.
 159
 160 (defvar tooltip-hook nil
 161   "Functions to call to display tooltips.
 162 Each function is called with one argument EVENT which is a copy of
 163 the last mouse movement event that occurred.")
 164
 165 (defvar tooltip-timeout-id nil
 166   "The id of the timeout started when Emacs becomes idle.")
 167
 168 (defvar tooltip-last-mouse-motion-event nil
 169   "A copy of the last mouse motion event seen.")
 170
 171 (defvar tooltip-hide-time nil
 172   "Time when the last tooltip was hidden.")
 173
 174 \f
 175 ;;; Event accessors
 176
 177 (defun tooltip-event-buffer (event)
 178   "Return the buffer over which event EVENT occurred.
 179 This might return nil if the event did not occur over a buffer."
 180   (let ((window (posn-window (event-end event))))
 181     (and window (window-buffer window))))
 182
 183 \f
 184 ;;; Switching tooltips on/off
 185
 186 ;; We don't set track-mouse globally because this is a big redisplay
 187 ;; problem in buffers having a pre-command-hook or such installed,
 188 ;; which does a set-buffer, like the summary buffer of Gnus.  Calling
 189 ;; set-buffer prevents redisplay optimizations, so every mouse motion
 190 ;; would be accompanied by a full redisplay.
 191
 192 ;;;###autoload
 193 (defun tooltip-mode (&optional arg)
 194   "Mode for tooltip display.
 195 With ARG, turn tooltip mode on if and only if ARG is positive."
 196   (interactive "P")
 197   (unless (fboundp 'x-show-tip)
 198     (error "Sorry, tooltips are not yet available on this system"))
 199   (let* ((on (if arg
 200                  (> (prefix-numeric-value arg) 0)
 201                (not tooltip-mode)))
 202          (hook-fn (if on 'add-hook 'remove-hook)))
 203     (setq tooltip-mode on)
 204     (funcall hook-fn 'change-major-mode-hook 'tooltip-change-major-mode)
 205     (tooltip-activate-mouse-motions-if-enabled)
 206     (funcall hook-fn 'pre-command-hook 'tooltip-hide)
 207     (funcall hook-fn 'tooltip-hook 'tooltip-gud-tips)
 208     (funcall hook-fn 'tooltip-hook 'tooltip-help-tips)
 209     (setq show-help-function (if on 'tooltip-show-help-function nil))
 210     ;; `ignore' is the default binding for mouse movements.
 211     (define-key global-map [mouse-movement]
 212       (if on 'tooltip-mouse-motion 'ignore))))
 213
 214 \f
 215 ;;; Timeout for tooltip display
 216
 217 (defun tooltip-delay ()
 218   "Return the delay in seconds for the next tooltip."
 219   (let ((delay tooltip-delay)
 220         (now (float-time)))
 221     (when (and tooltip-hide-time
 222                (< (- now tooltip-hide-time) tooltip-recent-seconds))
 223       (setq delay tooltip-short-delay))
 224     delay))
 225
 226 (defun tooltip-cancel-delayed-tip ()
 227   "Disable the tooltip timeout."
 228   (when tooltip-timeout-id
 229     (disable-timeout tooltip-timeout-id)
 230     (setq tooltip-timeout-id nil)))
 231
 232 (defun tooltip-start-delayed-tip ()
 233   "Add a one-shot timeout to call function tooltip-timeout."
 234   (setq tooltip-timeout-id
 235         (add-timeout (tooltip-delay) 'tooltip-timeout nil)))
 236
 237 (defun tooltip-timeout (object)
 238   "Function called when timer with id tooltip-timeout-id fires."
 239   (run-hook-with-args-until-success 'tooltip-hook
 240                                     tooltip-last-mouse-motion-event))
 241
 242 \f
 243 ;;; Reacting on mouse movements
 244
 245 (defun tooltip-change-major-mode ()
 246   "Function added to `change-major-mode-hook' when tooltip mode is on."
 247   (add-hook 'post-command-hook 'tooltip-activate-mouse-motions-if-enabled))
 248
 249 (defun tooltip-activate-mouse-motions-if-enabled ()
 250   "Reconsider for all buffers whether mouse motion events are desired."
 251   (remove-hook 'post-command-hook 'tooltip-activate-mouse-motions-if-enabled)
 252   (let ((buffers (buffer-list)))
 253     (save-excursion
 254       (while buffers
 255         (set-buffer (car buffers))
 256         (if (and tooltip-mode
 257                  tooltip-gud-tips-p
 258                  (memq major-mode tooltip-gud-modes))
 259             (tooltip-activate-mouse-motions t)
 260           (tooltip-activate-mouse-motions nil))
 261         (setq buffers (cdr buffers))))))
 262
 263 (defvar tooltip-mouse-motions-active nil
 264   "Locally t in a buffer if tooltip processing of mouse motion is enabled.")
 265
 266 (defun tooltip-activate-mouse-motions (activatep)
 267   "Activate/deactivate mouse motion events for the current buffer.
 268 ACTIVATEP non-nil means activate mouse motion events."
 269   (if activatep
 270       (progn
 271         (make-local-variable 'tooltip-mouse-motions-active)
 272         (setq tooltip-mouse-motions-active t)
 273         (make-local-variable 'track-mouse)
 274         (setq track-mouse t))
 275     (when tooltip-mouse-motions-active
 276       (kill-local-variable 'tooltip-mouse-motions-active)
 277       (kill-local-variable 'track-mouse))))
 278
 279 (defun tooltip-mouse-motion (event)
 280   "Command handler for mouse movement events in `global-map'."
 281   (interactive "e")
 282   (tooltip-hide)
 283   (when (car (mouse-pixel-position))
 284     (setq tooltip-last-mouse-motion-event (copy-sequence event))
 285     (tooltip-start-delayed-tip)))
 286
 287 \f
 288 ;;; Displaying tips
 289
 290 (defun tooltip-set-param (alist key value)
 291   "Change the value of KEY in alist ALIST to VALUE.
 292 If there's no association for KEY in ALIST, add one, otherwise
 293 change the existing association.  Value is the resulting alist."
 294   (let ((param (assq key alist)))
 295     (if (consp param)
 296         (setcdr param value)
 297       (push (cons key value) alist))
 298     alist))
 299
 300 (defun tooltip-show (text)
 301   "Show a tooltip window displaying TEXT.
 302
 303 Text larger than `x-max-tooltip-size' (which see) is clipped.
 304
 305 If the alist in `tooltip-frame-parameters' includes `left' and `top'
 306 parameters, they determine the x and y position where the tooltip
 307 is displayed.  Otherwise, the tooltip pops at offsets specified by
 308 `tooltip-x-offset' and `tooltip-y-offset' from the current mouse
 309 position."
 310   (if tooltip-use-echo-area
 311       (message "%s" text)
 312     (condition-case error
 313         (let ((params (copy-sequence tooltip-frame-parameters))
 314               (fg (face-attribute 'tooltip :foreground))
 315               (bg (face-attribute 'tooltip :background)))
 316           (when (stringp fg)
 317             (setq params (tooltip-set-param params 'foreground-color fg))
 318             (setq params (tooltip-set-param params 'border-color fg)))
 319           (when (stringp bg)
 320             (setq params (tooltip-set-param params 'background-color bg)))
 321           (x-show-tip (propertize text 'face 'tooltip)
 322                       (selected-frame)
 323                       params
 324                       tooltip-hide-delay
 325                       tooltip-x-offset
 326                       tooltip-y-offset))
 327       (error
 328        (message "Error while displaying tooltip: %s" error)
 329        (sit-for 1)
 330        (message "%s" text)))))
 331
 332 (defun tooltip-hide (&optional ignored-arg)
 333   "Hide a tooltip, if one is displayed.
 334 Value is non-nil if tooltip was open."
 335   (tooltip-cancel-delayed-tip)
 336   (when (x-hide-tip)
 337     (setq tooltip-hide-time (float-time))))
 338
 339 \f
 340 ;;; Debugger-related functions
 341
 342 (defun tooltip-identifier-from-point (point)
 343   "Extract the identifier at POINT, if any.
 344 Value is nil if no identifier exists at point.  Identifier extraction
 345 is based on the current syntax table."
 346   (save-excursion
 347     (goto-char point)
 348     (let ((start (progn (skip-syntax-backward "w_") (point))))
 349       (unless (looking-at "[0-9]")
 350         (skip-syntax-forward "w_")
 351         (when (> (point) start)
 352           (buffer-substring start (point)))))))
 353
 354 (defmacro tooltip-region-active-p ()
 355   "Value is non-nil if the region is currently active."
 356   (if (string-match "^GNU" (emacs-version))
 357       `(and transient-mark-mode mark-active)
 358     `(region-active-p)))
 359
 360 (defun tooltip-expr-to-print (event)
 361   "Return an expression that should be printed for EVENT.
 362 If a region is active and the mouse is inside the region, print
 363 the region.  Otherwise, figure out the identifier around the point
 364 where the mouse is."
 365   (save-excursion
 366     (set-buffer (tooltip-event-buffer event))
 367     (let ((point (posn-point (event-end event))))
 368       (if (tooltip-region-active-p)
 369           (when (and (<= (region-beginning) point) (<= point (region-end)))
 370             (buffer-substring (region-beginning) (region-end)))
 371         (tooltip-identifier-from-point point)))))
 372
 373 (defun tooltip-process-prompt-regexp (process)
 374   "Return regexp matching the prompt of PROCESS at the end of a string.
 375 The prompt is taken from the value of COMINT-PROMPT-REGEXP in the buffer
 376 of PROCESS."
 377   (let ((prompt-regexp (save-excursion
 378                          (set-buffer (process-buffer process))
 379                          comint-prompt-regexp)))
 380     ;; Most start with `^' but the one for `sdb' cannot be easily
 381     ;; stripped.  Code the prompt for `sdb' fixed here.
 382     (if (= (aref prompt-regexp 0) ?^)
 383         (setq prompt-regexp (substring prompt-regexp 1))
 384       (setq prompt-regexp "\\*"))
 385     (concat "\n*" prompt-regexp "$")))
 386
 387 (defun tooltip-strip-prompt (process output)
 388   "Return OUTPUT with any prompt of PROCESS stripped from its end."
 389   (let ((prompt-regexp (tooltip-process-prompt-regexp process)))
 390     (save-match-data
 391       (when (string-match prompt-regexp output)
 392         (setq output (substring output 0 (match-beginning 0)))))
 393     output))
 394
 395 \f
 396 ;;; Tips for `gud'
 397
 398 (defvar tooltip-gud-original-filter nil
 399   "Process filter to restore after GUD output has been received.")
 400
 401 (defvar tooltip-gud-dereference nil
 402   "Non-nil means print expressions with a `*' in front of them.
 403 For C this would dereference a pointer expression.")
 404
 405 (defvar tooltip-gud-event nil
 406   "The mouse movement event that led to a tooltip display.
 407 This event can be examined by forms in TOOLTIP-GUD-DISPLAY.")
 408
 409 (defun tooltip-gud-toggle-dereference ()
 410   "Toggle whether tooltips should show `* expr' or `expr'."
 411   (interactive)
 412   (setq tooltip-gud-dereference (not tooltip-gud-dereference))
 413   (when (interactive-p)
 414     (message "Dereferencing is now %s."
 415              (if tooltip-gud-dereference "on" "off"))))
 416
 417 ; This will only display data that comes in one chunk.
 418 ; Larger arrays (say 400 elements) are displayed in
 419 ; the tootip incompletely and spill over into the gud buffer.
 420 ; Switching the process-filter creates timing problems and
 421 ; it may be difficult to do better. gdba in gdb-ui.el
 422 ; gets round this problem.
 423 (defun tooltip-gud-process-output (process output)
 424   "Process debugger output and show it in a tooltip window."
 425   (set-process-filter process tooltip-gud-original-filter)
 426   (tooltip-show (tooltip-strip-prompt process output)))
 427
 428 (defun tooltip-gud-print-command (expr)
 429   "Return a suitable command to print the expression EXPR.
 430 If TOOLTIP-GUD-DEREFERENCE is t, also prepend a `*' to EXPR."
 431   (when tooltip-gud-dereference
 432     (setq expr (concat "*" expr)))
 433   (case gud-minor-mode
 434     ((gdb gdba) (concat "server print " expr))
 435     (dbx (concat "print " expr))
 436     (xdb (concat "p " expr))
 437     (sdb (concat expr "/"))
 438     (perldb expr)))
 439
 440 (defun tooltip-gud-tips (event)
 441   "Show tip for identifier or selection under the mouse.
 442 The mouse must either point at an identifier or inside a selected
 443 region for the tip window to be shown.  If tooltip-gud-dereference is t,
 444 add a `*' in front of the printed expression.
 445
 446 This function must return nil if it doesn't handle EVENT."
 447   (let (gud-buffer process)
 448     (when (and (eventp event)
 449                tooltip-gud-tips-p
 450                (boundp 'gud-comint-buffer)
 451                (setq gud-buffer gud-comint-buffer)
 452                (setq process (get-buffer-process gud-buffer))
 453                (posn-point (event-end event))
 454                (progn (setq tooltip-gud-event event)
 455                       (eval (cons 'and tooltip-gud-display))))
 456       (let ((expr (tooltip-expr-to-print event)))
 457         (when expr
 458           (let ((cmd (tooltip-gud-print-command expr)))
 459             (unless (null cmd)         ; CMD can be nil if unknown debugger
 460               (case gud-minor-mode
 461                     (gdba (gdb-enqueue-input
 462                            (list  (concat cmd "\n") 'gdb-tooltip-print)))
 463                     (t
 464                      (setq tooltip-gud-original-filter (process-filter process))
 465                        (set-process-filter process 'tooltip-gud-process-output)
 466                        (gud-basic-call cmd)))
 467                     expr)))))))
 468
 469 (defun gdb-tooltip-print ()
 470   (tooltip-show
 471    (with-current-buffer (gdb-get-buffer 'gdb-partial-output-buffer)
 472      (buffer-string))))
 473
 474 \f
 475 ;;; Tooltip help.
 476
 477 (defvar tooltip-help-message nil
 478   "The last help message received via `tooltip-show-help-function'.")
 479
 480 (defun tooltip-show-help-function (msg)
 481   "Function installed as `show-help-function'.
 482 MSG is either a help string to display, or nil to cancel the display."
 483   (let ((previous-help tooltip-help-message))
 484     (setq tooltip-help-message msg)
 485     (cond ((null msg)
 486            ;; Cancel display.  This also cancels a delayed tip, if
 487            ;; there is one.
 488            (tooltip-hide))
 489           ((equal previous-help msg)
 490            ;; Same help as before (but possibly the mouse has moved).
 491            ;; Keep what we have.
 492            )
 493           (t
 494            ;; A different help.  Remove a previous tooltip, and
 495            ;; display a new one, with some delay.
 496            (tooltip-hide)
 497            (tooltip-start-delayed-tip)))))
 498
 499 (defun tooltip-help-tips (event)
 500   "Hook function to display a help tooltip.
 501 This is installed on the hook `tooltip-hook', which is run when
 502 the timer with ID `tooltip-timeout-id' fires.
 503 Value is non-nil if this function handled the tip."
 504   (when (stringp tooltip-help-message)
 505     (tooltip-show tooltip-help-message)
 506     t))
 507
 508 \f
 509 ;;; Do this after all functions have been defined that are called from
 510 ;;; `tooltip-mode'.  The actual default value of `tooltip-mode' is set
 511 ;;; in startup.el.
 512
 513 ;;;###autoload
 514 (defcustom tooltip-mode nil
 515   "Toggle tooltip-mode.
 516 Setting this variable directly does not take effect;
 517 use either \\[customize] or the function `tooltip-mode'."
 518   :set (lambda (symbol value)
 519          (tooltip-mode (or value 0)))
 520   :initialize 'custom-initialize-default
 521   :type 'boolean
 522   :require 'tooltip
 523   :group 'tooltip)
 524
 525 (provide 'tooltip)
 526
 527 ;;; arch-tag: 3d61135e-4618-4a78-af28-183f6df5636f
 528 ;;; tooltip.el ends here