lisp/dired-x.el

   1 ;;; dired-x.el --- extra Dired functionality -*-byte-compile-dynamic: t;-*-
   2
   3 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   4 ;;      Lawrence R. Dodd <dodd@roebling.poly.edu>
   5 ;; Maintainer: Romain Francoise <rfrancoise@gnu.org>
   6 ;; Version: 2.37+
   7 ;; Date: 1994/08/18 19:27:42
   8 ;; Keywords: dired extensions files
   9
  10 ;; Copyright (C) 1993, 1994, 1997, 2001, 2002, 2003, 2004,
  11 ;;   2005, 2006 Free Software Foundation, Inc.
  12
  13 ;; This file is part of GNU Emacs.
  14
  15 ;; GNU Emacs is free software; you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation; either version 2, or (at your option)
  18 ;; any later version.
  19
  20 ;; GNU Emacs is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  27 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  28 ;; Boston, MA 02110-1301, USA.
  29
  30 ;;; Commentary:
  31
  32 ;; This is Sebastian Kremer's excellent dired-x.el (Dired Extra), version
  33 ;; 1.191, hacked up for GNU Emacs.  Redundant or conflicting material has
  34 ;; been removed or renamed in order to work properly with dired of GNU
  35 ;; Emacs.  All suggestions or comments are most welcomed.
  36
  37 ;;
  38 ;; Please, PLEASE, *PLEASE* see the info pages.
  39 ;;
  40
  41 ;; BUGS: Type M-x dired-x-submit-report and a report will be generated.
  42
  43 ;; INSTALLATION: In your ~/.emacs,
  44 ;;
  45 ;; (add-hook 'dired-load-hook
  46 ;;           (function (lambda ()
  47 ;;                       (load "dired-x")
  48 ;;                       ;; Set global variables here.  For example:
  49 ;;                       ;; (setq dired-guess-shell-gnutar "gtar")
  50 ;;                       )))
  51 ;; (add-hook 'dired-mode-hook
  52 ;;           (function (lambda ()
  53 ;;                       ;; Set buffer-local variables here.  For example:
  54 ;;                       ;; (dired-omit-mode 1)
  55 ;;                       )))
  56 ;;
  57 ;; At load time dired-x.el will install itself, redefine some functions, and
  58 ;; bind some dired keys.  *Please* see the info pages for more details.
  59
  60 ;; *Please* see the info pages for more details.
  61
  62 ;; User defined variables:
  63 ;;
  64 ;;      dired-bind-vm
  65 ;;      dired-vm-read-only-folders
  66 ;;      dired-bind-jump
  67 ;;      dired-bind-info
  68 ;;      dired-bind-man
  69 ;;      dired-x-hands-off-my-keys
  70 ;;      dired-find-subdir
  71 ;;      dired-enable-local-variables
  72 ;;      dired-local-variables-file
  73 ;;      dired-guess-shell-gnutar
  74 ;;      dired-guess-shell-gzip-quiet
  75 ;;      dired-guess-shell-znew-switches
  76 ;;      dired-guess-shell-alist-user
  77 ;;      dired-clean-up-buffers-too
  78 ;;      dired-omit-mode
  79 ;;      dired-omit-files
  80 ;;      dired-omit-extensions
  81 ;;      dired-omit-size-limit
  82 ;;
  83 ;; To find out more about these variables, load this file, put your cursor at
  84 ;; the end of any of the variable names, and hit C-h v [RET].  *Please* see
  85 ;; the info pages for more details.
  86
  87 ;; When loaded this code redefines the following functions of GNU Emacs
  88 ;;
  89 ;;   Function                         Found in this file of GNU Emacs
  90 ;;   --------                         -------------------------------
  91 ;;   dired-clean-up-after-deletion    ../lisp/dired.el
  92 ;;   dired-find-buffer-nocreate       ../lisp/dired.el
  93 ;;   dired-initial-position           ../lisp/dired.el
  94 ;;
  95 ;;   dired-add-entry                  ../lisp/dired-aux.el
  96 ;;   dired-read-shell-command         ../lisp/dired-aux.el
  97
  98 \f
  99 ;;; Code:
 100
 101 ;; LOAD.
 102
 103 ;; This is a no-op if dired-x is being loaded via `dired-load-hook'.  It is
 104 ;; here in case the user has autoloaded dired-x via the dired-jump key binding
 105 ;; (instead of autoloading to dired as is suggested in the info-pages).
 106
 107 (require 'dired)
 108
 109 ;; We will redefine some functions and also need some macros so we need to
 110 ;; load dired stuff of GNU Emacs.
 111
 112 (require 'dired-aux)
 113
 114 (defvar vm-folder-directory)
 115 (eval-when-compile (require 'man))
 116
 117 ;;; User-defined variables.
 118
 119 (defgroup dired-x nil
 120   "Extended directory editing (dired-x)."
 121   :group 'dired)
 122
 123 (defgroup dired-keys nil
 124   "Dired keys customizations."
 125   :prefix "dired-"
 126   :group 'dired-x)
 127
 128 (defcustom dired-bind-vm nil
 129   "*Non-nil means \"V\" runs `dired-vm', otherwise \"V\" runs `dired-rmail'.
 130 Also, RMAIL files contain -*- rmail -*- at the top so \"f\",
 131 `dired-advertised-find-file', will run rmail."
 132   :type 'boolean
 133   :group 'dired-keys)
 134
 135 (defcustom dired-bind-jump t
 136   "*Non-nil means bind `dired-jump' to C-x C-j, otherwise do not."
 137   :type 'boolean
 138   :group 'dired-keys)
 139
 140 (defcustom dired-bind-man t
 141   "*Non-nil means bind `dired-man' to \"N\" in dired-mode, otherwise do not."
 142   :type 'boolean
 143   :group 'dired-keys)
 144
 145 (defcustom dired-bind-info t
 146   "*Non-nil means bind `dired-info' to \"I\" in dired-mode, otherwise do not."
 147   :type 'boolean
 148   :group 'dired-keys)
 149
 150 (defcustom dired-vm-read-only-folders nil
 151   "*If non-nil, \\[dired-vm] will visit all folders read-only.
 152 If neither nil nor t, e.g. the symbol `if-file-read-only', only
 153 files not writable by you are visited read-only.
 154
 155 Read-only folders only work in VM 5, not in VM 4."
 156   :type '(choice (const :tag "off" nil)
 157                  (const :tag "on" t)
 158                  (other :tag "non-writable only" if-file-read-only))
 159   :group 'dired-x)
 160
 161 (define-minor-mode dired-omit-mode
 162   "Toggle Dired-Omit mode.
 163 With numeric ARG, enable Dired-Omit mode if ARG is positive, disable
 164 otherwise.  Enabling and disabling is buffer-local.
 165 If enabled, \"uninteresting\" files are not listed.
 166 Uninteresting files are those whose filenames match regexp `dired-omit-files',
 167 plus those ending with extensions in `dired-omit-extensions'."
 168   :group 'dired-x
 169   (if dired-omit-mode
 170       ;; This will mention how many lines were omitted:
 171       (let ((dired-omit-size-limit nil)) (dired-omit-expunge))
 172     (revert-buffer)))
 173
 174 ;; For backward compatibility
 175 (defvaralias 'dired-omit-files-p 'dired-omit-mode)
 176 (make-obsolete-variable 'dired-omit-files-p 'dired-omit-mode)
 177
 178 (defcustom dired-omit-files "^\\.?#\\|^\\.$\\|^\\.\\.$"
 179   "*Filenames matching this regexp will not be displayed.
 180 This only has effect when `dired-omit-mode' is t.  See interactive function
 181 `dired-omit-mode' \(\\[dired-omit-mode]\) and variable
 182 `dired-omit-extensions'.  The default is to omit  `.', `..', auto-save
 183 files and lock files."
 184   :type 'regexp
 185   :group 'dired-x)
 186
 187 (defcustom dired-find-subdir nil           ; t is pretty near to DWIM...
 188   "*If non-nil, Dired always finds a directory in a buffer of its own.
 189 If nil, Dired finds the directory as a subdirectory in some other buffer
 190 if it is present as one.
 191
 192 If there are several dired buffers for a directory, the most recently
 193 used is chosen.
 194
 195 Dired avoids switching to the current buffer, so that if you have
 196 a normal and a wildcard buffer for the same directory, \\[dired] will
 197 toggle between those two."
 198   :type 'boolean
 199   :group 'dired-x)
 200
 201 (defcustom dired-omit-size-limit 30000
 202   "*Maximum size for the \"omitting\" feature.
 203 If nil, there is no maximum size."
 204   :type '(choice (const :tag "no maximum" nil) integer)
 205   :group 'dired-x)
 206
 207 (defcustom dired-enable-local-variables t
 208   "*Control use of local-variables lists in Dired.
 209 The value can be t, nil or something else.
 210 A value of t means local-variables lists are obeyed;
 211 nil means they are ignored; anything else means query.
 212
 213 This temporarily overrides the value of `enable-local-variables' when listing
 214 a directory.  See also `dired-local-variables-file'."
 215   :type 'boolean
 216   :group 'dired-x)
 217
 218 (defcustom dired-guess-shell-gnutar nil
 219   "*If non-nil, name of GNU tar executable.
 220 \(E.g., \"tar\" or \"gtar\").  The `z' switch will be used with it for
 221 compressed or gzip'ed tar files.  If you don't have GNU tar, set this
 222 to nil: a pipe using `zcat' or `gunzip -c' will be used."
 223   :type '(choice (const :tag "Not GNU tar" nil)
 224                  (string :tag "Command name"))
 225   :group 'dired-x)
 226
 227 (defcustom dired-guess-shell-gzip-quiet t
 228   "*Non-nil says pass -q to gzip overriding verbose GZIP environment."
 229   :type 'boolean
 230   :group 'dired-x)
 231
 232 (defcustom dired-guess-shell-znew-switches nil
 233   "*If non-nil, then string of switches passed to `znew', example: \"-K\"."
 234   :type '(choice (const :tag "None" nil)
 235                  (string :tag "Switches"))
 236   :group 'dired-x)
 237
 238 (defcustom dired-clean-up-buffers-too t
 239   "*Non-nil means offer to kill buffers visiting files and dirs deleted in Dired."
 240   :type 'boolean
 241   :group 'dired-x)
 242
 243 ;;; KEY BINDINGS.
 244
 245 (define-key dired-mode-map "\M-o" 'dired-omit-mode)
 246 (define-key dired-mode-map "*O" 'dired-mark-omitted)
 247 (define-key dired-mode-map "\M-(" 'dired-mark-sexp)
 248 (define-key dired-mode-map "*(" 'dired-mark-sexp)
 249 (define-key dired-mode-map "*." 'dired-mark-extension)
 250 (define-key dired-mode-map "\M-!" 'dired-smart-shell-command)
 251 (define-key dired-mode-map "w" 'dired-copy-filename-as-kill)
 252 (define-key dired-mode-map "\M-g" 'dired-goto-file)
 253 (define-key dired-mode-map "\M-G" 'dired-goto-subdir)
 254 (define-key dired-mode-map "F" 'dired-do-find-marked-files)
 255 (define-key dired-mode-map "Y"  'dired-do-relsymlink)
 256 (define-key dired-mode-map "%Y" 'dired-do-relsymlink-regexp)
 257 (define-key dired-mode-map "V" 'dired-do-run-mail)
 258
 259 (if dired-bind-man
 260     (define-key dired-mode-map "N" 'dired-man))
 261
 262 (if dired-bind-info
 263     (define-key dired-mode-map "I" 'dired-info))
 264
 265 ;;; MENU BINDINGS
 266
 267 (let ((menu-bar (lookup-key dired-mode-map [menu-bar])))
 268   (let ((menu (lookup-key menu-bar [operate])))
 269     (define-key-after
 270       menu
 271       [find-files]
 272       '(menu-item
 273         "Find files"
 274         dired-do-find-marked-files
 275         :help "Find current or marked files")
 276       'delete)
 277     (define-key-after
 278       menu
 279       [relsymlink]
 280       '(menu-item
 281         "Relative symlink to..."
 282         dired-do-relsymlink
 283         :visible (fboundp 'make-symbolic-link)
 284         :help "Make relative symbolic links for current or marked files")
 285       'symlink))
 286   (let ((menu (lookup-key menu-bar [mark])))
 287     (define-key-after
 288       menu
 289       [flag-extension]
 290       '(menu-item
 291         "Flag extension..."
 292         dired-flag-extension
 293         :help "Flag files with a certain extension for deletion")
 294       'garbage-files)
 295     (define-key-after
 296       menu
 297       [mark-extension]
 298       '(menu-item
 299         "Mark extension..."
 300         dired-mark-extension
 301         :help "Mark files with a certain extension")
 302       'symlinks)
 303     (define-key-after
 304       menu
 305       [mark-omitted]
 306       '(menu-item
 307         "Mark omitted"
 308         dired-mark-omitted
 309         :help "Mark files matching `dired-omit-files' and `dired-omit-extensions'")
 310       'mark-extension))
 311   (let ((menu (lookup-key menu-bar [regexp])))
 312     (define-key-after
 313       menu
 314       [relsymlink-regexp]
 315       '(menu-item
 316         "Relative symlink..."
 317         dired-do-relsymlink-regexp
 318         :visible (fboundp 'make-symbolic-link)
 319         :help "Make relative symbolic links for files matching regexp")
 320       'symlink))
 321   (let ((menu (lookup-key menu-bar [immediate])))
 322     (define-key-after
 323       menu
 324       [omit-mode]
 325       '(menu-item
 326         "Omit mode" dired-omit-mode
 327         :button (:toggle . dired-omit-mode)
 328         :help "Enable or disable omitting \"uninteresting\" files")
 329       'dashes)))
 330
 331 ;;; GLOBAL BINDING.
 332 (if dired-bind-jump
 333     (progn
 334       (define-key global-map "\C-x\C-j" 'dired-jump)
 335       (define-key global-map "\C-x4\C-j" 'dired-jump-other-window)))
 336
 337 \f
 338 ;;; Install into appropriate hooks.
 339
 340 (add-hook 'dired-mode-hook 'dired-extra-startup)
 341 (add-hook 'dired-after-readin-hook 'dired-omit-expunge)
 342
 343 (defun dired-extra-startup ()
 344   "Automatically put on `dired-mode-hook' to get extra Dired features:
 345 \\<dired-mode-map>
 346   \\[dired-do-run-mail]\t-- run mail on folder (see `dired-bind-vm')
 347   \\[dired-info]\t-- run info on file
 348   \\[dired-man]\t-- run man on file
 349   \\[dired-do-find-marked-files]\t-- visit all marked files simultaneously
 350   \\[dired-omit-mode]\t-- toggle omitting of files
 351   \\[dired-mark-sexp]\t-- mark by Lisp expression
 352   \\[dired-copy-filename-as-kill]\t-- copy the file or subdir names into the kill ring;
 353   \t   you can feed it to other commands using \\[yank]
 354
 355 For more features, see variables
 356
 357   `dired-bind-vm'
 358   `dired-bind-jump'
 359   `dired-bind-info'
 360   `dired-bind-man'
 361   `dired-vm-read-only-folders'
 362   `dired-omit-mode'
 363   `dired-omit-files'
 364   `dired-omit-extensions'
 365   `dired-omit-size-limit'
 366   `dired-find-subdir'
 367   `dired-enable-local-variables'
 368   `dired-local-variables-file'
 369   `dired-guess-shell-gnutar'
 370   `dired-guess-shell-gzip-quiet'
 371   `dired-guess-shell-znew-switches'
 372   `dired-guess-shell-alist-user'
 373   `dired-clean-up-buffers-too'
 374
 375 See also functions
 376
 377   `dired-flag-extension'
 378   `dired-virtual'
 379   `dired-jump'
 380   `dired-man'
 381   `dired-vm'
 382   `dired-rmail'
 383   `dired-info'
 384   `dired-do-find-marked-files'"
 385   (interactive)
 386
 387   ;; These must be done in each new dired buffer.
 388   (dired-hack-local-variables)
 389   (dired-omit-startup))
 390
 391 \f
 392 ;;; BUFFER CLEANING.
 393
 394 ;; REDEFINE.
 395 (defun dired-clean-up-after-deletion (fn)
 396   "Clean up after a deleted file or directory FN.
 397 Remove expanded subdir of deleted dir, if any."
 398   (save-excursion (and (cdr dired-subdir-alist)
 399                        (dired-goto-subdir fn)
 400                        (dired-kill-subdir)))
 401
 402   ;; Offer to kill buffer of deleted file FN.
 403   (if dired-clean-up-buffers-too
 404       (progn
 405         (let ((buf (get-file-buffer fn)))
 406           (and buf
 407                (funcall (function y-or-n-p)
 408                         (format "Kill buffer of %s, too? "
 409                                 (file-name-nondirectory fn)))
 410                (save-excursion ; you never know where kill-buffer leaves you
 411                  (kill-buffer buf))))
 412         (let ((buf-list (dired-buffers-for-dir (expand-file-name fn)))
 413               (buf nil))
 414           (and buf-list
 415                (y-or-n-p (format "Kill dired buffer%s of %s, too? "
 416                                  (dired-plural-s (length buf-list))
 417                                  (file-name-nondirectory fn)))
 418                (while buf-list
 419                  (save-excursion (kill-buffer (car buf-list)))
 420                  (setq buf-list (cdr buf-list)))))))
 421   ;; Anything else?
 422   )
 423
 424 \f
 425 ;;; EXTENSION MARKING FUNCTIONS.
 426
 427 ;;; Mark files with some extension.
 428 (defun dired-mark-extension (extension &optional marker-char)
 429   "Mark all files with a certain EXTENSION for use in later commands.
 430 A `.' is *not* automatically prepended to the string entered."
 431   ;; EXTENSION may also be a list of extensions instead of a single one.
 432   ;; Optional MARKER-CHAR is marker to use.
 433   (interactive "sMarking extension: \nP")
 434   (or (listp extension)
 435       (setq extension (list extension)))
 436   (dired-mark-files-regexp
 437    (concat ".";; don't match names with nothing but an extension
 438            "\\("
 439            (mapconcat 'regexp-quote extension "\\|")
 440            "\\)$")
 441    marker-char))
 442
 443 (defun dired-flag-extension (extension)
 444   "In dired, flag all files with a certain EXTENSION for deletion.
 445 A `.' is *not* automatically prepended to the string entered."
 446   (interactive "sFlagging extension: ")
 447   (dired-mark-extension extension dired-del-marker))
 448
 449 ;;; Define some unpopular file extensions.  Used for cleaning and omitting.
 450
 451 (defvar dired-patch-unclean-extensions
 452   '(".rej" ".orig")
 453   "List of extensions of dispensable files created by the `patch' program.")
 454
 455 (defvar dired-tex-unclean-extensions
 456   '(".toc" ".log" ".aux");; these are already in completion-ignored-extensions
 457   "List of extensions of dispensable files created by TeX.")
 458
 459 (defvar dired-latex-unclean-extensions
 460   '(".idx" ".lof" ".lot" ".glo")
 461   "List of extensions of dispensable files created by LaTeX.")
 462
 463 (defvar dired-bibtex-unclean-extensions
 464   '(".blg" ".bbl")
 465   "List of extensions of dispensable files created by BibTeX.")
 466
 467 (defvar dired-texinfo-unclean-extensions
 468   '(".cp" ".cps" ".fn" ".fns" ".ky" ".kys" ".pg" ".pgs"
 469     ".tp" ".tps" ".vr" ".vrs")
 470   "List of extensions of dispensable files created by texinfo.")
 471
 472 (defun dired-clean-patch ()
 473   "Flag dispensable files created by patch for deletion.
 474 See variable `dired-patch-unclean-extensions'."
 475   (interactive)
 476   (dired-flag-extension dired-patch-unclean-extensions))
 477
 478 (defun dired-clean-tex ()
 479   "Flag dispensable files created by [La]TeX etc. for deletion.
 480 See variables `dired-tex-unclean-extensions',
 481 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 482 `dired-texinfo-unclean-extensions'."
 483   (interactive)
 484   (dired-flag-extension (append dired-texinfo-unclean-extensions
 485                                 dired-latex-unclean-extensions
 486                                 dired-bibtex-unclean-extensions
 487                                 dired-tex-unclean-extensions)))
 488
 489 (defun dired-very-clean-tex ()
 490   "Flag dispensable files created by [La]TeX *and* \".dvi\" for deletion.
 491 See variables `dired-texinfo-unclean-extensions',
 492 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 493 `dired-texinfo-unclean-extensions'."
 494   (interactive)
 495   (dired-flag-extension (append dired-texinfo-unclean-extensions
 496                                 dired-latex-unclean-extensions
 497                                 dired-bibtex-unclean-extensions
 498                                 dired-tex-unclean-extensions
 499                                 (list ".dvi"))))
 500 \f
 501 ;;; JUMP.
 502
 503 ;;;###autoload
 504 (defun dired-jump (&optional other-window)
 505   "Jump to dired buffer corresponding to current buffer.
 506 If in a file, dired the current directory and move to file's line.
 507 If in Dired already, pop up a level and goto old directory's line.
 508 In case the proper dired file line cannot be found, refresh the dired
 509 buffer and try again."
 510   (interactive "P")
 511   (let* ((file buffer-file-name)
 512          (dir (if file (file-name-directory file) default-directory)))
 513     (if (eq major-mode 'dired-mode)
 514         (progn
 515           (setq dir (dired-current-directory))
 516           (dired-up-directory other-window)
 517           (or (dired-goto-file dir)
 518               ;; refresh and try again
 519               (progn
 520                 (dired-insert-subdir (file-name-directory dir))
 521                 (dired-goto-file dir))))
 522       (if other-window
 523           (dired-other-window dir)
 524         (dired dir))
 525       (if file
 526           (or (dired-goto-file file)
 527               ;; refresh and try again
 528               (progn
 529                 (dired-insert-subdir (file-name-directory file))
 530                 (dired-goto-file file))
 531               ;; Toggle omitting, if it is on, and try again.
 532               (if dired-omit-mode
 533                   (progn
 534                     (dired-omit-mode)
 535                     (dired-goto-file file))))))))
 536
 537 (defun dired-jump-other-window ()
 538   "Like \\[dired-jump] (`dired-jump') but in other window."
 539   (interactive)
 540   (dired-jump t))
 541 \f
 542 ;;; OMITTING.
 543
 544 ;;; Enhanced omitting of lines from directory listings.
 545 ;;; Marked files are never omitted.
 546
 547 ;; should probably get rid of this and always use 'no-dir.
 548 ;; sk 28-Aug-1991 09:37
 549 (defvar dired-omit-localp 'no-dir
 550   "The LOCALP argument `dired-omit-expunge' passes to `dired-get-filename'.
 551 If it is `no-dir', omitting is much faster, but you can only match
 552 against the non-directory part of the file name.  Set it to nil if you
 553 need to match the entire file name.")
 554
 555 ;; \017=^O for Omit - other packages can chose other control characters.
 556 (defvar dired-omit-marker-char ?\017
 557   "Temporary marker used by dired-omit.
 558 Should never be used as marker by the user or other packages.")
 559
 560 (defun dired-omit-startup ()
 561   (or (assq 'dired-omit-mode minor-mode-alist)
 562       (setq minor-mode-alist
 563             (append '((dired-omit-mode
 564                        (:eval (if (eq major-mode 'dired-mode)
 565                                   " Omit" ""))))
 566                     minor-mode-alist))))
 567
 568 (defun dired-mark-omitted ()
 569   "Mark files matching `dired-omit-files' and `dired-omit-extensions'."
 570   (interactive)
 571   (let ((dired-omit-mode nil)) (revert-buffer)) ;; Show omitted files
 572   (dired-mark-unmarked-files (dired-omit-regexp) nil nil dired-omit-localp))
 573
 574 (defvar dired-omit-extensions
 575   (append completion-ignored-extensions
 576           dired-latex-unclean-extensions
 577           dired-bibtex-unclean-extensions
 578           dired-texinfo-unclean-extensions)
 579   "If non-nil, a list of extensions \(strings\) to omit from Dired listings.
 580 Defaults to elements of `completion-ignored-extensions',
 581 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions', and
 582 `dired-texinfo-unclean-extensions'.
 583
 584 See interactive function `dired-omit-mode' \(\\[dired-omit-mode]\) and
 585 variables `dired-omit-mode' and `dired-omit-files'.")
 586
 587 (defun dired-omit-expunge (&optional regexp)
 588   "Erases all unmarked files matching REGEXP.
 589 Does nothing if global variable `dired-omit-mode' is nil, or if called
 590   non-interactively and buffer is bigger than `dired-omit-size-limit'.
 591 If REGEXP is nil or not specified, uses `dired-omit-files', and also omits
 592   filenames ending in `dired-omit-extensions'.
 593 If REGEXP is the empty string, this function is a no-op.
 594
 595 This functions works by temporarily binding `dired-marker-char' to
 596 `dired-omit-marker-char' and calling `dired-do-kill-lines'."
 597   (interactive "sOmit files (regexp): ")
 598   (if (and dired-omit-mode
 599            (or (interactive-p)
 600                (not dired-omit-size-limit)
 601                (< (buffer-size) dired-omit-size-limit)
 602                (progn
 603                  (message "Not omitting: directory larger than %d characters."
 604                           dired-omit-size-limit)
 605                  (setq dired-omit-mode nil)
 606                  nil)))
 607       (let ((omit-re (or regexp (dired-omit-regexp)))
 608             (old-modified-p (buffer-modified-p))
 609             count)
 610         (or (string= omit-re "")
 611             (let ((dired-marker-char dired-omit-marker-char))
 612               (message "Omitting...")
 613               (if (dired-mark-unmarked-files omit-re nil nil dired-omit-localp)
 614                   (progn
 615                     (setq count (dired-do-kill-lines nil "Omitted %d line%s."))
 616                     (force-mode-line-update))
 617                 (message "(Nothing to omit)"))))
 618         ;; Try to preserve modified state of buffer.  So `%*' doesn't appear
 619         ;; in mode-line of omitted buffers.
 620         (set-buffer-modified-p (and old-modified-p
 621                                     (save-excursion
 622                                       (goto-char (point-min))
 623                                       (re-search-forward dired-re-mark nil t))))
 624         count)))
 625
 626 (defun dired-omit-regexp ()
 627   (concat (if dired-omit-files (concat "\\(" dired-omit-files "\\)") "")
 628           (if (and dired-omit-files dired-omit-extensions) "\\|" "")
 629           (if dired-omit-extensions
 630               (concat ".";; a non-extension part should exist
 631                       "\\("
 632                       (mapconcat 'regexp-quote dired-omit-extensions "\\|")
 633                       "\\)$")
 634             "")))
 635
 636 ;; Returns t if any work was done, nil otherwise.
 637 (defun dired-mark-unmarked-files (regexp msg &optional unflag-p localp)
 638   "Mark unmarked files matching REGEXP, displaying MSG.
 639 REGEXP is matched against the entire file name.
 640 Does not re-mark files which already have a mark.
 641 With prefix argument, unflag all those files.
 642 Optional fourth argument LOCALP is as in `dired-get-filename'."
 643   (interactive "P")
 644   (let ((dired-marker-char (if unflag-p ?\s dired-marker-char)))
 645     (dired-mark-if
 646      (and
 647       ;; not already marked
 648       (looking-at " ")
 649       ;; uninteresting
 650       (let ((fn (dired-get-filename localp t)))
 651         (and fn (string-match regexp fn))))
 652      msg)))
 653
 654 ;;; REDEFINE.
 655 (defun dired-omit-new-add-entry (filename &optional marker-char relative)
 656   ;; This redefines dired-aux.el's dired-add-entry to avoid calling ls for
 657   ;; files that are going to be omitted anyway.
 658   (if dired-omit-mode
 659       ;; perhaps return t without calling ls
 660       (let ((omit-re (dired-omit-regexp)))
 661         (if (or (string= omit-re "")
 662                 (not
 663                  (string-match omit-re
 664                                (cond
 665                                 ((eq 'no-dir dired-omit-localp)
 666                                  filename)
 667                                 ((eq t dired-omit-localp)
 668                                  (dired-make-relative filename))
 669                                 (t
 670                                  (dired-make-absolute
 671                                   filename
 672                                   (file-name-directory filename)))))))
 673             ;; if it didn't match, go ahead and add the entry
 674             (dired-omit-old-add-entry filename marker-char relative)
 675           ;; dired-add-entry returns t for success, perhaps we should
 676           ;; return file-exists-p
 677           t))
 678     ;; omitting is not turned on at all
 679     (dired-omit-old-add-entry filename marker-char relative)))
 680
 681 ;;; REDEFINE.
 682 ;;; Redefine dired-aux.el's version of `dired-add-entry'
 683 ;;; Save old defun if not already done:
 684 (or (fboundp 'dired-omit-old-add-entry)
 685     (fset 'dired-omit-old-add-entry (symbol-function 'dired-add-entry)))
 686 ;; Redefine it.
 687 (fset 'dired-add-entry 'dired-omit-new-add-entry)
 688
 689 \f
 690 ;;; VIRTUAL DIRED MODE.
 691
 692 ;;; For browsing `ls -lR' listings in a dired-like fashion.
 693
 694 (defalias 'virtual-dired 'dired-virtual)
 695 (defun dired-virtual (dirname &optional switches)
 696   "Put this buffer into Virtual Dired mode.
 697
 698 In Virtual Dired mode, all commands that do not actually consult the
 699 filesystem will work.
 700
 701 This is useful if you want to peruse and move around in an ls -lR
 702 output file, for example one you got from an ftp server.  With
 703 ange-ftp, you can even dired a directory containing an ls-lR file,
 704 visit that file and turn on virtual dired mode.  But don't try to save
 705 this file, as dired-virtual indents the listing and thus changes the
 706 buffer.
 707
 708 If you have save a Dired buffer in a file you can use \\[dired-virtual] to
 709 resume it in a later session.
 710
 711 Type \\<dired-mode-map>\\[revert-buffer] \
 712 in the Virtual Dired buffer and answer `y' to convert
 713 the virtual to a real dired buffer again.  You don't have to do this, though:
 714 you can relist single subdirs using \\[dired-do-redisplay]."
 715
 716   ;; DIRNAME is the top level directory of the buffer.  It will become
 717   ;; its `default-directory'.  If nil, the old value of
 718   ;; default-directory is used.
 719
 720   ;; Optional SWITCHES are the ls switches to use.
 721
 722   ;; Shell wildcards will be used if there already is a `wildcard'
 723   ;; line in the buffer (thus it is a saved Dired buffer), but there
 724   ;; is no other way to get wildcards.  Insert a `wildcard' line by
 725   ;; hand if you want them.
 726
 727   (interactive
 728    (list (read-string "Virtual Dired directory: " (dired-virtual-guess-dir))))
 729   (goto-char (point-min))
 730   (or (looking-at "  ")
 731       ;; if not already indented, do it now:
 732       (indent-region (point-min) (point-max) 2))
 733   (or dirname (setq dirname default-directory))
 734   (setq dirname (expand-file-name (file-name-as-directory dirname)))
 735   (setq default-directory dirname)      ; contains no wildcards
 736   (let ((wildcard (save-excursion
 737                     (goto-char (point-min))
 738                     (forward-line 1)
 739                     (and (looking-at "^  wildcard ")
 740                          (buffer-substring (match-end 0)
 741                                            (progn (end-of-line) (point)))))))
 742   (if wildcard
 743         (setq dirname (expand-file-name wildcard default-directory))))
 744   ;; If raw ls listing (not a saved old dired buffer), give it a
 745   ;; decent subdir headerline:
 746   (goto-char (point-min))
 747   (or (looking-at dired-subdir-regexp)
 748       (insert "  "
 749               (directory-file-name (file-name-directory default-directory))
 750               ":\n"))
 751   (dired-mode dirname (or switches dired-listing-switches))
 752   (setq mode-name "Virtual Dired"
 753         revert-buffer-function 'dired-virtual-revert)
 754   (set (make-local-variable 'dired-subdir-alist) nil)
 755   (dired-build-subdir-alist)
 756   (goto-char (point-min))
 757   (dired-initial-position dirname))
 758
 759 (defun dired-virtual-guess-dir ()
 760   "Guess and return appropriate working directory of this buffer.
 761 The buffer is assumed to be in Dired or ls -lR format.  The guess is
 762 based upon buffer contents.  If nothing could be guessed, returns
 763 nil."
 764
 765   (let ((regexp "^\\(  \\)?\\([^ \n\r]*\\)\\(:\\)[\n\r]")
 766         (subexpr 2))
 767     (goto-char (point-min))
 768     (cond ((looking-at regexp)
 769            ;; If a saved dired buffer, look to which dir and
 770            ;; perhaps wildcard it belongs:
 771            (let ((dir (buffer-substring (match-beginning subexpr)
 772                                         (match-end subexpr))))
 773              (file-name-as-directory dir)))
 774           ;; Else no match for headerline found.  It's a raw ls listing.
 775           ;; In raw ls listings the directory does not have a headerline
 776           ;; try parent of first subdir, if any
 777           ((re-search-forward regexp nil t)
 778            (file-name-directory
 779             (directory-file-name
 780              (file-name-as-directory
 781               (buffer-substring (match-beginning subexpr)
 782                                 (match-end subexpr))))))
 783           (t                            ; if all else fails
 784            nil))))
 785
 786
 787 (defun dired-virtual-revert (&optional arg noconfirm)
 788   (if (not
 789        (y-or-n-p "Cannot revert a Virtual Dired buffer - switch to Real Dired mode? "))
 790       (error "Cannot revert a Virtual Dired buffer")
 791     (setq mode-name "Dired"
 792           revert-buffer-function 'dired-revert)
 793     (revert-buffer)))
 794
 795 ;; A zero-arg version of dired-virtual.
 796 ;; You need my modified version of set-auto-mode for the
 797 ;; `buffer-contents-mode-alist'.
 798 ;; Or you use infer-mode.el and infer-mode-alist, same syntax.
 799 (defun dired-virtual-mode ()
 800   "Put current buffer into Virtual Dired mode (see `dired-virtual').
 801 Useful on `buffer-contents-mode-alist' (which see) with the regexp
 802
 803     \"^  \\(/[^ /]+\\)/?+:$\"
 804
 805 to put saved dired buffers automatically into Virtual Dired mode.
 806
 807 Also useful for `auto-mode-alist' (which see) like this:
 808
 809   \(setq auto-mode-alist (cons '(\"[^/]\\.dired\\'\" . dired-virtual-mode)
 810                               auto-mode-alist)\)"
 811   (interactive)
 812   (dired-virtual (dired-virtual-guess-dir)))
 813
 814 \f
 815 ;;; SMART SHELL.
 816
 817 ;;; An Emacs buffer can have but one working directory, stored in the
 818 ;;; buffer-local variable `default-directory'.  A Dired buffer may have
 819 ;;; several subdirectories inserted, but still has but one working directory:
 820 ;;; that of the top level Dired directory in that buffer.  For some commands
 821 ;;; it is appropriate that they use the current Dired directory instead of
 822 ;;; `default-directory', e.g., `find-file' and `compile'.  This is a general
 823 ;;; mechanism is provided for special handling of the working directory in
 824 ;;; special major modes.
 825
 826 ;; It's easier to add to this alist than redefine function
 827 ;; default-directory while keeping the old information.
 828 (defconst default-directory-alist
 829   '((dired-mode . (if (fboundp 'dired-current-directory)
 830                       (dired-current-directory)
 831                     default-directory)))
 832   "Alist of major modes and their opinion on `default-directory'.
 833 This is given as a Lisp expression to evaluate.  A resulting value of
 834 nil is ignored in favor of `default-directory'.")
 835
 836 (defun dired-default-directory ()
 837   "Usage like variable `default-directory'.
 838 Knows about the special cases in variable `default-directory-alist'."
 839   (or (eval (cdr (assq major-mode default-directory-alist)))
 840       default-directory))
 841
 842 (defun dired-smart-shell-command (cmd &optional insert)
 843   "Like function `shell-command', but in the current Virtual Dired directory."
 844   (interactive (list (read-from-minibuffer "Shell command: "
 845                                            nil nil nil 'shell-command-history)
 846                      current-prefix-arg))
 847   (let ((default-directory (dired-default-directory)))
 848     (shell-command cmd insert)))
 849
 850 \f
 851 ;;; LOCAL VARIABLES FOR DIRED BUFFERS.
 852
 853 ;;; Brief Description:
 854 ;;;
 855 ;;; * `dired-extra-startup' is part of the `dired-mode-hook'.
 856 ;;;
 857 ;;; * `dired-extra-startup' calls `dired-hack-local-variables'
 858 ;;;
 859 ;;; * `dired-hack-local-variables' checks the value of
 860 ;;;   `dired-local-variables-file'
 861 ;;;
 862 ;;; * Check if `dired-local-variables-file' is a non-nil string and is a
 863 ;;;   filename found in the directory of the Dired Buffer being created.
 864 ;;;
 865 ;;; * If `dired-local-variables-file' satisfies the above, then temporarily
 866 ;;;   include it in the Dired Buffer at the bottom.
 867 ;;;
 868 ;;; * Set `enable-local-variables' temporarily to the user variable
 869 ;;;   `dired-enable-local-variables' and run `hack-local-variables' on the
 870 ;;;   Dired Buffer.
 871
 872 (defvar dired-local-variables-file (convert-standard-filename ".dired")
 873   "Filename, as string, containing local dired buffer variables to be hacked.
 874 If this file found in current directory, then it will be inserted into dired
 875 buffer and `hack-local-variables' will be run.  See Info node
 876 `(emacs)File Variables' for more information on local variables.
 877 See also `dired-enable-local-variables'.")
 878
 879 (defun dired-hack-local-variables ()
 880   "Evaluate local variables in `dired-local-variables-file' for dired buffer."
 881   (if (and dired-local-variables-file
 882            (stringp dired-local-variables-file)
 883            (file-exists-p dired-local-variables-file))
 884       (let ((opoint (point-max))
 885             buffer-read-only
 886             ;; In case user has `enable-local-variables' set to nil we
 887             ;; override it locally with dired's variable.
 888             (enable-local-variables dired-enable-local-variables))
 889         ;; Insert 'em.
 890         (save-excursion
 891           (goto-char opoint)
 892           (insert "\^L\n")
 893           (insert-file-contents dired-local-variables-file))
 894         ;; Hack 'em.
 895         (let ((buffer-file-name dired-local-variables-file))
 896           (hack-local-variables))
 897         ;; Make sure that the modeline shows the proper information.
 898         (dired-sort-set-modeline)
 899         ;; Delete this stuff: `eobp' is used to find last subdir by dired.el.
 900         (delete-region opoint (point-max)))))
 901
 902 (defun dired-omit-here-always ()
 903   "Create `dired-local-variables-file' for omitting and reverts directory.
 904 Sets `dired-omit-mode' to t in a local variables file that is readable by
 905 dired."
 906   (interactive)
 907   (if (file-exists-p dired-local-variables-file)
 908       (message "File `./%s' already exists." dired-local-variables-file)
 909
 910     ;; Create `dired-local-variables-file'.
 911     (save-excursion
 912       (set-buffer (get-buffer-create " *dot-dired*"))
 913       (erase-buffer)
 914       (insert "Local Variables:\ndired-omit-mode: t\nEnd:\n")
 915       (write-file dired-local-variables-file)
 916       (kill-buffer (current-buffer)))
 917
 918     ;; Run extra-hooks and revert directory.
 919     (dired-extra-startup)
 920     (dired-revert)))
 921
 922 \f
 923 ;;; GUESS SHELL COMMAND.
 924
 925 ;;; Brief Description:
 926 ;;;
 927 ;;; `dired-do-shell-command' is bound to `!' by dired.el.
 928 ;;;
 929 ;;; * Redefine `dired-do-shell-command' so it calls
 930 ;;;   `dired-guess-shell-command'.
 931 ;;;
 932 ;;; * `dired-guess-shell-command' calls `dired-guess-default' with list of
 933 ;;;    marked files.
 934 ;;;
 935 ;;; * Parse `dired-guess-shell-alist-user' and
 936 ;;;   `dired-guess-shell-alist-default' (in that order) for the first REGEXP
 937 ;;;   that matches the first file in the file list.
 938 ;;;
 939 ;;; * If the REGEXP matches all the entries of the file list then evaluate
 940 ;;;   COMMAND, which is either a string or a Lisp expression returning a
 941 ;;;   string.  COMMAND may be a list of commands.
 942 ;;;
 943 ;;; * Return this command to `dired-guess-shell-command' which prompts user
 944 ;;;   with it.  The list of commands is temporarily put into the history list.
 945 ;;;   If a command is used successfully then it is stored permanently in
 946 ;;;   `dired-shell-command-history'.
 947
 948 ;;; Guess what shell command to apply to a file.
 949 (defvar dired-shell-command-history nil
 950   "History list for commands that read dired-shell commands.")
 951
 952 ;;; Default list of shell commands.
 953
 954 ;;; NOTE: Use `gunzip -c' instead of `zcat' on `.gz' files.  Some do not
 955 ;;; install GNU zip's version of zcat.
 956
 957 (defvar dired-guess-shell-alist-default
 958   (list
 959    (list "\\.tar$"
 960          '(if dired-guess-shell-gnutar
 961               (concat dired-guess-shell-gnutar " xvf")
 962             "tar xvf")
 963          ;; Extract files into a separate subdirectory
 964          '(if dired-guess-shell-gnutar
 965               (concat "mkdir " (file-name-sans-extension file)
 966                       "; " dired-guess-shell-gnutar " -C "
 967                       (file-name-sans-extension file) " -xvf")
 968             (concat "mkdir " (file-name-sans-extension file)
 969                     "; tar -C " (file-name-sans-extension file) " -xvf")))
 970
 971    ;; REGEXPS for compressed archives must come before the .Z rule to
 972    ;; be recognized:
 973    (list "\\.tar\\.Z$"
 974          ;; Untar it.
 975          '(if dired-guess-shell-gnutar
 976               (concat dired-guess-shell-gnutar " zxvf")
 977             (concat "zcat * | tar xvf -"))
 978          ;; Optional conversion to gzip format.
 979          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 980                   " " dired-guess-shell-znew-switches))
 981
 982    ;; gzip'ed archives
 983    (list "\\.t\\(ar\\.\\)?gz$"
 984          '(if dired-guess-shell-gnutar
 985               (concat dired-guess-shell-gnutar " zxvf")
 986             (concat "gunzip -qc * | tar xvf -"))
 987          ;; Extract files into a separate subdirectory
 988          '(if dired-guess-shell-gnutar
 989               (concat "mkdir " (file-name-sans-extension file)
 990                       "; " dired-guess-shell-gnutar " -C "
 991                       (file-name-sans-extension file) " -zxvf")
 992             (concat "mkdir " (file-name-sans-extension file)
 993                     "; gunzip -qc * | tar -C "
 994                     (file-name-sans-extension file) " -xvf -"))
 995          ;; Optional decompression.
 996          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q" "")))
 997
 998    ;; bzip2'ed archives
 999    (list "\\.t\\(ar\\.bz2\\|bz\\)$"
1000          "bunzip2 -c * | tar xvf -"
1001          ;; Extract files into a separate subdirectory
1002          '(concat "mkdir " (file-name-sans-extension file)
1003                   "; bunzip2 -c * | tar -C "
1004                   (file-name-sans-extension file) " -xvf -")
1005          ;; Optional decompression.
1006          "bunzip2")
1007
1008    '("\\.shar\\.Z$" "zcat * | unshar")
1009    '("\\.shar\\.g?z$" "gunzip -qc * | unshar")
1010
1011    '("\\.e?ps$" "ghostview" "xloadimage" "lpr")
1012    (list "\\.e?ps\\.g?z$" "gunzip -qc * | ghostview -"
1013          ;; Optional decompression.
1014          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1015    (list "\\.e?ps\\.Z$" "zcat * | ghostview -"
1016          ;; Optional conversion to gzip format.
1017          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1018                   " " dired-guess-shell-znew-switches))
1019
1020    '("\\.patch$" "cat * | patch")
1021    (list "\\.patch\\.g?z$" "gunzip -qc * | patch"
1022          ;; Optional decompression.
1023          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1024    (list "\\.patch\\.Z$" "zcat * | patch"
1025          ;; Optional conversion to gzip format.
1026          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1027                   " " dired-guess-shell-znew-switches))
1028
1029    ;; The following four extensions are useful with dired-man ("N" key)
1030    (list "\\.\\(?:[0-9]\\|man\\)$" '(progn (require 'man)
1031                              (if (Man-support-local-filenames)
1032                                  "man -l"
1033                                "cat * | tbl | nroff -man -h")))
1034    (list "\\.\\(?:[0-9]\\|man\\)\\.g?z$" '(progn (require 'man)
1035                                    (if (Man-support-local-filenames)
1036                                        "man -l"
1037                                      "gunzip -qc * | tbl | nroff -man -h"))
1038          ;; Optional decompression.
1039          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1040    (list "\\.[0-9]\\.Z$" '(progn (require 'man)
1041                                  (if (Man-support-local-filenames)
1042                                      "man -l"
1043                                    "zcat * | tbl | nroff -man -h"))
1044          ;; Optional conversion to gzip format.
1045          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1046                   " " dired-guess-shell-znew-switches))
1047    '("\\.pod$" "perldoc" "pod2man * | nroff -man")
1048
1049    '("\\.dvi$" "xdvi" "dvips")          ; preview and printing
1050    '("\\.au$" "play")                   ; play Sun audiofiles
1051    '("\\.mpg$" "mpeg_play")
1052    '("\\.uu$" "uudecode")               ; for uudecoded files
1053    '("\\.hqx$" "mcvert")
1054    '("\\.sh$" "sh")                     ; execute shell scripts
1055    '("\\.xbm$" "bitmap")                ; view X11 bitmaps
1056    '("\\.gp$" "gnuplot")
1057    '("\\.p[bgpn]m$" "xloadimage")
1058    '("\\.gif$" "xloadimage")                    ; view gif pictures
1059    '("\\.tif$" "xloadimage")
1060    '("\\.png$" "display")               ; xloadimage 4.1 doesn't grok PNG
1061    '("\\.jpe?g$" "xloadimage")
1062    '("\\.fig$" "xfig")                  ; edit fig pictures
1063    '("\\.out$" "xgraph")                ; for plotting purposes.
1064    '("\\.tex$" "latex" "tex")
1065    '("\\.texi\\(nfo\\)?$" "makeinfo" "texi2dvi")
1066    '("\\.pdf$" "xpdf")              ; edit PDF files
1067
1068    ;; Some other popular archivers.
1069    (list "\\.zip$" "unzip"
1070          ;; Extract files into a separate subdirectory
1071          '(concat "unzip" (if dired-guess-shell-gzip-quiet " -q")
1072                   " -d " (file-name-sans-extension file)))
1073    '("\\.zoo$" "zoo x//")
1074    '("\\.lzh$" "lharc x")
1075    '("\\.arc$" "arc x")
1076    '("\\.shar$" "unshar")
1077
1078    ;; Compression.
1079    (list "\\.g?z$" '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1080    (list "\\.dz$" "dictunzip")
1081    (list "\\.bz2$" "bunzip2")
1082    (list "\\.Z$" "uncompress"
1083          ;; Optional conversion to gzip format.
1084          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1085                   " " dired-guess-shell-znew-switches))
1086    )
1087
1088   "Default alist used for shell command guessing.
1089 See `dired-guess-shell-alist-user'.")
1090
1091 (defcustom dired-guess-shell-alist-user nil
1092   "User-defined alist of rules for suggested commands.
1093 These rules take precedence over the predefined rules in the variable
1094 `dired-guess-shell-alist-default' (to which they are prepended).
1095
1096 Each element of this list looks like
1097
1098     \(REGEXP COMMAND...\)
1099
1100 where each COMMAND can either be a string or a Lisp expression that evaluates
1101 to a string.  If several COMMANDs are given, the first one will be the default
1102 and the rest will be added temporarily to the history and can be retrieved
1103 with \\[previous-history-element] (M-p) .
1104
1105 You can set this variable in your ~/.emacs.  For example, to add rules for
1106 `.foo' and `.bar' files, write
1107
1108  \(setq dired-guess-shell-alist-user
1109        (list (list \"\\\\.foo\\\\'\" \"FOO-COMMAND\");; fixed rule
1110               ;; possibly more rules ...
1111               (list \"\\\\.bar\\\'\";; rule with condition test
1112                     '(if condition
1113                           \"BAR-COMMAND-1\"
1114                         \"BAR-COMMAND-2\")))\)"
1115   :group 'dired-x
1116   :type '(alist :key-type regexp :value-type (repeat sexp)))
1117
1118 (defcustom dired-guess-shell-case-fold-search t
1119   "If non-nil, `dired-guess-shell-alist-default' and
1120 `dired-guess-shell-alist-user' are matched case-insensitively."
1121   :group 'dired-x
1122   :type 'boolean)
1123
1124 (defun dired-guess-default (files)
1125   "Guess a shell commands for FILES.  Return command or list of commands.
1126 See `dired-guess-shell-alist-user'."
1127
1128   (let* ((case-fold-search dired-guess-shell-case-fold-search)
1129          ;; Prepend the user's alist to the default alist.
1130          (alist (append dired-guess-shell-alist-user
1131                         dired-guess-shell-alist-default))
1132          (file (car files))
1133          (flist (cdr files))
1134          elt regexp cmds)
1135
1136     ;; Find the first match in the alist for first file in FILES.
1137     (while alist
1138       (setq elt (car alist)
1139             regexp (car elt)
1140             alist (cdr alist))
1141       (if (string-match regexp file)
1142           (setq cmds (cdr elt)
1143                 alist nil)))
1144
1145     ;; If more than one file, see if all of FILES match regular expression.
1146     (while (and flist
1147                 (string-match regexp (car flist)))
1148       (setq flist (cdr flist)))
1149
1150     ;; If flist is still non-nil, then do not guess since this means that not
1151     ;; all the files in FILES were matched by the regexp.
1152     (setq cmds (and (not flist) cmds))
1153
1154     ;; Return commands or nil if flist is still non-nil.
1155     ;; Evaluate the commands in order that any logical testing will be done.
1156     (cond ((not (cdr cmds))
1157            (eval (car cmds))) ; single command
1158           (t
1159            (mapcar (function eval) cmds)))))
1160
1161 (defun dired-guess-shell-command (prompt files)
1162   "Ask user with PROMPT for a shell command, guessing a default from FILES."
1163
1164   (let ((default (dired-guess-default files))
1165         default-list old-history val (failed t))
1166
1167     (if (null default)
1168         ;; Nothing to guess
1169         (read-from-minibuffer prompt nil nil nil 'dired-shell-command-history)
1170
1171       ;; Save current history list
1172       (setq old-history dired-shell-command-history)
1173
1174       (if (listp default)
1175
1176           ;; More than one guess
1177           (setq default-list default
1178                 default (car default)
1179                 prompt (concat
1180                         prompt
1181                         (format "{%d guesses} " (length default-list))))
1182
1183         ;; Just one guess
1184         (setq default-list (list default)))
1185
1186       ;; Push all guesses onto history so that they can be retrieved with M-p
1187       ;; and put the first guess in the prompt but not in the initial value.
1188       (setq dired-shell-command-history
1189             (append default-list dired-shell-command-history)
1190             prompt (concat prompt (format "[%s] " default)))
1191
1192       ;; The unwind-protect returns VAL, and we too.
1193       (unwind-protect
1194           ;; BODYFORM
1195           (progn
1196             (setq val (read-from-minibuffer prompt nil nil nil
1197                                             'dired-shell-command-history)
1198                   failed nil)
1199             ;; If we got a return, then use default.
1200             (if (equal val "")
1201                 (setq val default))
1202             val)
1203
1204         ;; UNWINDFORMS
1205         ;; Undo pushing onto the history list so that an aborted
1206         ;; command doesn't get the default in the next command.
1207         (setq dired-shell-command-history old-history)
1208         (if (not failed)
1209             (or (equal val (car-safe dired-shell-command-history))
1210                 (setq dired-shell-command-history
1211                       (cons val dired-shell-command-history))))))))
1212
1213
1214 ;;; REDEFINE.
1215 ;;; Redefine dired-aux.el's version:
1216 (defun dired-read-shell-command (prompt arg files)
1217   "Read a dired shell command prompting with PROMPT (using read-string).
1218 ARG is the prefix arg and may be used to indicate in the prompt which
1219   files are affected.
1220 This is an extra function so that you can redefine it."
1221   (dired-mark-pop-up
1222    nil 'shell files
1223    'dired-guess-shell-command
1224    (format prompt (dired-mark-prompt arg files)) ; PROMPT
1225    files))                                       ; FILES
1226
1227 \f
1228 ;;; RELATIVE SYMBOLIC LINKS.
1229
1230 (defvar dired-keep-marker-relsymlink ?S
1231   "See variable `dired-keep-marker-move'.")
1232
1233 (defun dired-make-relative-symlink (file1 file2 &optional ok-if-already-exists)
1234   "Make a symbolic link (pointing to FILE1) in FILE2.
1235 The link is relative (if possible), for example
1236
1237     \"/vol/tex/bin/foo\" \"/vol/local/bin/foo\"
1238
1239 results in
1240
1241     \"../../tex/bin/foo\" \"/vol/local/bin/foo\""
1242   (interactive "FRelSymLink: \nFRelSymLink %s: \np")
1243   (let (name1 name2 len1 len2 (index 0) sub)
1244     (setq file1 (expand-file-name file1)
1245           file2 (expand-file-name file2)
1246           len1 (length file1)
1247           len2 (length file2))
1248     ;; Find common initial file name components:
1249     (let (next)
1250       (while (and (setq next (string-match "/" file1 index))
1251                   (setq next (1+ next))
1252                   (< next (min len1 len2))
1253                   ;; For the comparison, both substrings must end in
1254                   ;; `/', so NEXT is *one plus* the result of the
1255                   ;; string-match.
1256                   ;; E.g., consider the case of linking "/tmp/a/abc"
1257                   ;; to "/tmp/abc" erroneously giving "/tmp/a" instead
1258                   ;; of "/tmp/" as common initial component
1259                   (string-equal (substring file1 0 next)
1260                                 (substring file2 0 next)))
1261         (setq index next))
1262       (setq name2 file2
1263             sub (substring file1 0 index)
1264             name1 (substring file1 index)))
1265     (if (string-equal sub "/")
1266         ;; No common initial file name found
1267         (setq name1 file1)
1268       ;; Else they have a common parent directory
1269       (let ((tem (substring file2 index))
1270             (start 0)
1271             (count 0))
1272         ;; Count number of slashes we must compensate for ...
1273         (while (setq start (string-match "/" tem start))
1274           (setq count (1+ count)
1275                 start (1+ start)))
1276         ;; ... and prepend a "../" for each slash found:
1277         (while (> count 0)
1278           (setq count (1- count)
1279                 name1 (concat "../" name1)))))
1280     (make-symbolic-link
1281      (directory-file-name name1)        ; must not link to foo/
1282                                         ; (trailing slash!)
1283      name2 ok-if-already-exists)))
1284
1285 (defun dired-do-relsymlink (&optional arg)
1286    "Relative symlink all marked (or next ARG) files into a directory.
1287 Otherwise make a relative symbolic link to the current file.
1288 This creates relative symbolic links like
1289
1290     foo -> ../bar/foo
1291
1292 not absolute ones like
1293
1294     foo -> /ugly/file/name/that/may/change/any/day/bar/foo"
1295   (interactive "P")
1296   (dired-do-create-files 'relsymlink (function dired-make-relative-symlink)
1297                            "RelSymLink" arg dired-keep-marker-relsymlink))
1298
1299 (defun dired-do-relsymlink-regexp (regexp newname &optional arg whole-name)
1300   "RelSymlink all marked files containing REGEXP to NEWNAME.
1301 See functions `dired-do-rename-regexp' and `dired-do-relsymlink'
1302 for more info."
1303   (interactive (dired-mark-read-regexp "RelSymLink"))
1304   (dired-do-create-files-regexp
1305    (function dired-make-relative-symlink)
1306    "RelSymLink" arg regexp newname whole-name dired-keep-marker-relsymlink))
1307
1308 \f
1309 ;;; VISIT ALL MARKED FILES SIMULTANEOUSLY.
1310
1311 ;;; Brief Description:
1312 ;;;
1313 ;;; `dired-do-find-marked-files' is bound to `F' by dired-x.el.
1314 ;;;
1315 ;;; * Use `dired-get-marked-files' to collect the marked files in the current
1316 ;;;   Dired Buffer into a list of filenames `FILE-LIST'.
1317 ;;;
1318 ;;; * Pass FILE-LIST to `dired-simultaneous-find-file' all with
1319 ;;;   `dired-do-find-marked-files''s prefix argument NOSELECT.
1320 ;;;
1321 ;;; * `dired-simultaneous-find-file' runs through FILE-LIST decrementing the
1322 ;;;   list each time.
1323 ;;;
1324 ;;; * If NOSELECT is non-nil then just run `find-file-noselect'  on each
1325 ;;;   element of FILE-LIST.
1326 ;;;
1327 ;;; * If NOSELECT is nil then calculate the `size' of the window for each file
1328 ;;;   by dividing the `window-height' by length of FILE-LIST.  Thus, `size' is
1329 ;;;   cognizant of the window-configuration.
1330 ;;;
1331 ;;; * If `size' is too small abort, otherwise run `find-file' on each element
1332 ;;;   of FILE-LIST giving each a window of height `size'.
1333
1334 (defun dired-do-find-marked-files (&optional noselect)
1335   "Find all marked files displaying all of them simultaneously.
1336 With optional NOSELECT just find files but do not select them.
1337
1338 The current window is split across all files marked, as evenly as possible.
1339 Remaining lines go to bottom-most window.  The number of files that can be
1340 displayed this way is restricted by the height of the current window and
1341 `window-min-height'.
1342
1343 To keep dired buffer displayed, type \\[split-window-vertically] first.
1344 To display just marked files, type \\[delete-other-windows] first."
1345
1346   (interactive "P")
1347   (dired-simultaneous-find-file (dired-get-marked-files) noselect))
1348
1349 (defun dired-simultaneous-find-file (file-list noselect)
1350
1351   "Visit all files in FILE-LIST and display them simultaneously.
1352 The current window is split across all files in FILE-LIST, as evenly as
1353 possible.  Remaining lines go to the bottom-most window.  The number of
1354 files that can be displayed this way is restricted by the height of the
1355 current window and the variable `window-min-height'.  With non-nil
1356 NOSELECT the files are merely found but not selected."
1357
1358   ;; We don't make this function interactive because it is usually too clumsy
1359   ;; to specify FILE-LIST interactively unless via dired.
1360
1361   (let (size)
1362
1363     (if noselect
1364         ;; Do not select the buffer.
1365         (find-file-noselect (car file-list))
1366
1367       ;; We will have to select the buffer.  Calculate and check window size.
1368       (setq size (/ (window-height) (length file-list)))
1369       (or (<= window-min-height size)
1370           (error "Too many files to visit simultaneously.  Try C-u prefix"))
1371       (find-file (car file-list)))
1372
1373     ;; Decrement.
1374     (setq file-list (cdr file-list))
1375
1376     (while file-list
1377
1378       (if noselect
1379           ;; Do not select the buffer.
1380           (find-file-noselect (car file-list))
1381
1382         ;; Vertically split off a window of desired size.  Upper window will
1383         ;; have SIZE lines.  Select lower (larger) window.  We split it again.
1384         (select-window (split-window nil size))
1385         (find-file (car file-list)))
1386
1387       ;; Decrement.
1388       (setq file-list (cdr file-list)))))
1389
1390 \f
1391 ;;; MISCELLANEOUS COMMANDS.
1392
1393 ;;; Run man on files.
1394
1395 (defun dired-man ()
1396   "Run man on this file.  Display old buffer if buffer name matches filename.
1397 Uses `man.el' of \\[manual-entry] fame."
1398   (interactive)
1399   (require 'man)
1400   (let* ((file (dired-get-filename))
1401          (manual-program (replace-regexp-in-string "\\*" "%s"
1402                           (dired-guess-shell-command
1403                            "Man command: " (list file)))))
1404     (Man-getpage-in-background file)))
1405
1406 ;;; Run Info on files.
1407
1408 (defun dired-info ()
1409   "Run info on this file."
1410   (interactive)
1411   (info (dired-get-filename)))
1412
1413 ;;; Run mail on mail folders.
1414
1415 ;; Avoid compiler warning.
1416 (eval-when-compile
1417   (when (not (fboundp 'vm-visit-folder))
1418     (defun vm-visit-folder (file &optional arg)
1419       nil)))
1420
1421 (defun dired-vm (&optional read-only)
1422   "Run VM on this file.
1423 With prefix arg, visit folder read-only (this requires at least VM 5).
1424 See also variable `dired-vm-read-only-folders'."
1425   (interactive "P")
1426   (let ((dir (dired-current-directory))
1427         (fil (dired-get-filename)))
1428     ;; take care to supply 2nd arg only if requested - may still run VM 4!
1429     (cond (read-only (vm-visit-folder fil t))
1430           ((eq t dired-vm-read-only-folders) (vm-visit-folder fil t))
1431           ((null dired-vm-read-only-folders) (vm-visit-folder fil))
1432           (t (vm-visit-folder fil (not (file-writable-p fil)))))
1433     ;; so that pressing `v' inside VM does prompt within current directory:
1434     (set (make-local-variable 'vm-folder-directory) dir)))
1435
1436 (defun dired-rmail ()
1437   "Run RMAIL on this file."
1438   (interactive)
1439   (rmail (dired-get-filename)))
1440
1441 (defun dired-do-run-mail ()
1442   "If `dired-bind-vm' is t, then function `dired-vm', otherwise `dired-rmail'."
1443   (interactive)
1444   (if dired-bind-vm
1445       ;; Read mail folder using vm.
1446       (dired-vm)
1447     ;; Read mail folder using rmail.
1448     (dired-rmail)))
1449
1450 \f
1451 ;;; MISCELLANEOUS INTERNAL FUNCTIONS.
1452
1453 (or (fboundp 'dired-old-find-buffer-nocreate)
1454     (fset 'dired-old-find-buffer-nocreate
1455           (symbol-function 'dired-find-buffer-nocreate)))
1456
1457 ;;; REDEFINE.
1458 ;;; Redefines dired.el's version of `dired-find-buffer-nocreate'
1459 (defun dired-find-buffer-nocreate (dirname &optional mode)
1460   (if (and dired-find-subdir
1461            ;; don't try to find a wildcard as a subdirectory
1462            (string-equal dirname (file-name-directory dirname)))
1463       (let* ((cur-buf (current-buffer))
1464              (buffers (nreverse
1465                        (dired-buffers-for-dir (expand-file-name dirname))))
1466              (cur-buf-matches (and (memq cur-buf buffers)
1467                                    ;; wildcards must match, too:
1468                                    (equal dired-directory dirname))))
1469         ;; We don't want to switch to the same buffer---
1470         (setq buffers (delq cur-buf buffers));;need setq with delq
1471         (or (car (sort buffers (function dired-buffer-more-recently-used-p)))
1472             ;; ---unless it's the only possibility:
1473             (and cur-buf-matches cur-buf)))
1474     (dired-old-find-buffer-nocreate dirname mode)))
1475
1476 ;; This should be a builtin
1477 (defun dired-buffer-more-recently-used-p (buffer1 buffer2)
1478   "Return t if BUFFER1 is more recently used than BUFFER2."
1479   (if (equal buffer1 buffer2)
1480       nil
1481     (let ((more-recent nil)
1482           (list (buffer-list)))
1483       (while (and list
1484                   (not (setq more-recent (equal buffer1 (car list))))
1485                   (not (equal buffer2 (car list))))
1486         (setq list (cdr list)))
1487       more-recent)))
1488
1489 ;;; Same thing as `dired-buffers-for-dir' of dired.el? - lrd 11/23/93
1490 ;;; (defun dired-buffers-for-dir-exact (dir)
1491 ;;; ;; Return a list of buffers that dired DIR (a directory or wildcard)
1492 ;;; ;; at top level, or as subdirectory.
1493 ;;; ;; Top level matches must match the wildcard part too, if any.
1494 ;;; ;; The list is in reverse order of buffer creation, most recent last.
1495 ;;; ;; As a side effect, killed dired buffers for DIR are removed from
1496 ;;; ;; dired-buffers.
1497 ;;;   (let ((alist dired-buffers) result elt)
1498 ;;;     (while alist
1499 ;;;       (setq elt (car alist)
1500 ;;;             alist (cdr alist))
1501 ;;;       (let ((buf (cdr elt)))
1502 ;;;         (if (buffer-name buf)
1503 ;;;             ;; Top level must match exactly against dired-directory in
1504 ;;;             ;; case one of them is a wildcard.
1505 ;;;             (if (or (equal dir (save-excursion (set-buffer buf)
1506 ;;;                                                dired-directory))
1507 ;;;                     (assoc dir (save-excursion (set-buffer buf)
1508 ;;;                                                dired-subdir-alist)))
1509 ;;;                 (setq result (cons buf result)))
1510 ;;;           ;; else buffer is killed - clean up:
1511 ;;;           (setq dired-buffers (delq elt dired-buffers)))))
1512 ;;;     result))
1513
1514 ;;; REDEFINE.
1515 ;;; Redefines dired.el's version of `dired-initial-position'
1516 (defun dired-initial-position (dirname)
1517   "Where point should go in a new listing of DIRNAME.
1518 Point assumed at beginning of new subdir line.
1519 You may redefine this function as you wish, e.g. like in `dired-x.el'."
1520   (end-of-line)
1521   (if dired-find-subdir (dired-goto-subdir dirname)) ; new
1522   (if dired-trivial-filenames (dired-goto-next-nontrivial-file)))
1523
1524 \f
1525 ;; Does anyone use this? - lrd 6/29/93.
1526 ;; Apparently people do use it. - lrd 12/22/97.
1527 (defun dired-mark-sexp (predicate &optional unflag-p)
1528   "Mark files for which PREDICATE returns non-nil.
1529 With a prefix arg, unflag those files instead.
1530
1531 PREDICATE is a lisp expression that can refer to the following symbols:
1532
1533     inode  [integer] the inode of the file (only for ls -i output)
1534     s      [integer] the size of the file for ls -s output
1535                      (usually in blocks or, with -k, in KByte)
1536     mode   [string]  file permission bits, e.g. \"-rw-r--r--\"
1537     nlink  [integer] number of links to file
1538     uid    [string]  owner
1539     gid    [string]  group  (If the gid is not displayed by ls,
1540                      this will still be set (to the same as uid))
1541     size   [integer] file size in bytes
1542     time   [string]  the time that ls displays, e.g. \"Feb 12 14:17\"
1543     name   [string]  the name of the file
1544     sym    [string]  if file is a symbolic link, the linked-to name, else \"\"
1545
1546 For example, use
1547
1548         (equal 0 size)
1549
1550 to mark all zero length files."
1551   ;; Using sym="" instead of nil avoids the trap of
1552   ;; (string-match "foo" sym) into which a user would soon fall.
1553   ;; Give `equal' instead of `=' in the example, as this works on
1554   ;; integers and strings.
1555   (interactive "xMark if (lisp expr): \nP")
1556   (message "%s" predicate)
1557   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char))
1558         inode s mode nlink uid gid size time name sym)
1559     (dired-mark-if
1560      (save-excursion
1561        (and
1562         ;; Sets vars
1563         ;;                inode s mode nlink uid gid size time name sym
1564
1565         ;; according to current file line.  Returns t for success, nil if
1566         ;; there is no file line.  Upon success, all variables are set, either
1567         ;; to nil or the appropriate value, so they need not be initialized.
1568         ;; Moves point within the current line.
1569         (if (dired-move-to-filename)
1570             (let (pos
1571                   (mode-len 10) ; length of mode string
1572                   ;; like in dired.el, but with subexpressions \1=inode, \2=s:
1573                   (dired-re-inode-size "\\s *\\([0-9]*\\)\\s *\\([0-9]*\\) ?"))
1574               (beginning-of-line)
1575               (forward-char 2)
1576               (if (looking-at dired-re-inode-size)
1577                   (progn
1578                     (goto-char (match-end 0))
1579                     (setq inode (string-to-number (buffer-substring (match-beginning 1)
1580                                                                     (match-end 1)))
1581                           s (string-to-number (buffer-substring (match-beginning 2)
1582                                                                 (match-end 2)))))
1583                 (setq inode nil
1584                       s nil))
1585               (setq mode (buffer-substring (point) (+ mode-len (point))))
1586               (forward-char mode-len)
1587               (setq nlink (read (current-buffer)))
1588               ;; Karsten Wenger <kw@cis.uni-muenchen.de> fixed uid.
1589               (setq uid (buffer-substring (+ (point) 1)
1590                                           (progn (forward-word 1) (point))))
1591               (re-search-forward directory-listing-before-filename-regexp)
1592               (goto-char (match-beginning 1))
1593               (forward-char -1)
1594               (setq size (string-to-number (buffer-substring (save-excursion
1595                                                                (backward-word 1)
1596                                                                (setq pos (point)))
1597                                                              (point))))
1598               (goto-char pos)
1599               (backward-word 1)
1600               ;; if no gid is displayed, gid will be set to uid
1601               ;; but user will then not reference it anyway in PREDICATE.
1602               (setq gid (buffer-substring (save-excursion
1603                                             (forward-word 1) (point))
1604                                           (point))
1605                     time (buffer-substring (match-beginning 1)
1606                                            (1- (dired-move-to-filename)))
1607                     name (buffer-substring (point)
1608                                            (or
1609                                             (dired-move-to-end-of-filename t)
1610                                             (point)))
1611                     sym  (progn
1612                            (if (looking-at " -> ")
1613                                (buffer-substring
1614                                 (progn (forward-char 4) (point))
1615                                 (progn (end-of-line) (point)))
1616                              "")))
1617               t)
1618           nil)
1619                       (eval predicate)))
1620      (format "'%s file" predicate))))
1621
1622 \f
1623 ;;; FIND FILE AT POINT.
1624
1625 (defvar dired-x-hands-off-my-keys t
1626   "*Non-nil means don't bind `dired-x-find-file' over `find-file' on keyboard.
1627 Similarly for `dired-x-find-file-other-window' over `find-file-other-window'.
1628 If you change this variable after `dired-x.el' is loaded then do
1629 \\[dired-x-bind-find-file].")
1630
1631 ;;; Bind `dired-x-find-file{-other-window}' over wherever
1632 ;;; `find-file{-other-window}' is bound?
1633 (defun dired-x-bind-find-file ()
1634   "Bind `dired-x-find-file' in place of `find-file' \(or reverse\).
1635 Similarly for `dired-x-find-file-other-window' and `find-file-other-window'.
1636 Binding direction based on `dired-x-hands-off-my-keys'.
1637 This function is part of `after-init-hook'."
1638   (interactive)
1639   (if (interactive-p)
1640       (setq dired-x-hands-off-my-keys
1641             (not (y-or-n-p "Bind dired-x-find-file over find-file? "))))
1642   (cond ((not dired-x-hands-off-my-keys)
1643          (substitute-key-definition 'find-file
1644                                     'dired-x-find-file
1645                                     (current-global-map))
1646          (substitute-key-definition 'find-file-other-window
1647                                     'dired-x-find-file-other-window
1648                                     (current-global-map)))
1649         (t
1650          (substitute-key-definition 'dired-x-find-file
1651                                     'find-file
1652                                     (current-global-map))
1653          (substitute-key-definition 'dired-x-find-file-other-window
1654                                     'find-file-other-window
1655                                     (current-global-map))))
1656   ;; Clear mini-buffer.
1657   (message nil))
1658
1659 ;;; Now call it so binding is correct and put on `after-init-hook' in case
1660 ;;; user changes binding.
1661 (dired-x-bind-find-file)
1662 (add-hook 'after-init-hook 'dired-x-bind-find-file)
1663
1664 (defun dired-x-find-file (filename)
1665   "Edit file FILENAME.
1666 May create a new window, or reuse an existing one.
1667 See the function `display-buffer'.
1668
1669 Identical to `find-file' except when called interactively, with a prefix arg
1670 \(e.g., \\[universal-argument]\), in which case it guesses filename near point.
1671 Useful for editing file mentioned in buffer you are viewing,
1672 or to test if that file exists.  Use minibuffer after snatching filename."
1673   (interactive (list (read-filename-at-point "Find file: ")))
1674   (find-file (expand-file-name filename)))
1675
1676 (defun dired-x-find-file-other-window (filename)
1677   "Edit file FILENAME, in another window.
1678 May create a new window, or reuse an existing one.
1679 See the function `display-buffer'.
1680
1681 Identical to `find-file-other-window' except when called interactively, with a
1682 prefix arg \(e.g., \\[universal-argument]\), in which case it guesses filename near point.
1683 Useful for editing file mentioned in buffer you are viewing,
1684 or to test if that file exists.  Use minibuffer after snatching filename."
1685   (interactive (list (read-filename-at-point "Find file: ")))
1686   (find-file-other-window (expand-file-name filename)))
1687
1688 ;;; Internal functions.
1689
1690 ;; Fixme: This should probably use `thing-at-point'.  -- fx
1691 (defun dired-filename-at-point ()
1692   "Get the filename closest to point, but do not change position.
1693 Has a preference for looking backward when not directly on a symbol.  Not
1694 perfect - point must be in middle of or end of filename."
1695
1696   (let ((filename-chars "-.[:alnum:]_/:$+@")
1697         start end filename prefix)
1698
1699     (save-excursion
1700       ;; First see if just past a filename.
1701       (if (not (eobp))
1702           (if (looking-at "[] \t\n[{}()]") ; whitespace or some parens
1703               (progn
1704                 (skip-chars-backward " \n\t\r({[]})")
1705                 (if (not (bobp))
1706                     (backward-char 1)))))
1707
1708       (if (string-match (concat "[" filename-chars "]")
1709                         (char-to-string (following-char)))
1710           (progn
1711             (if (re-search-backward (concat "[^" filename-chars "]") nil t)
1712                 (forward-char)
1713               (goto-char (point-min)))
1714             (setq start (point))
1715             (setq prefix
1716                   (and (string-match
1717                         "^\\w+@"
1718                         (buffer-substring start (line-beginning-position)))
1719                        "/"))
1720             (goto-char start)
1721             (if (string-match "[/~]" (char-to-string (preceding-char)))
1722                 (setq start (1- start)))
1723             (re-search-forward (concat "\\=[" filename-chars "]*") nil t))
1724
1725         (error "No file found around point!"))
1726
1727       ;; Return string.
1728       (expand-file-name (concat prefix (buffer-substring start (point)))))))
1729
1730 (defun read-filename-at-point (prompt)
1731   "Return filename prompting with PROMPT with completion.
1732 If `current-prefix-arg' is non-nil, uses name at point as guess."
1733   (if current-prefix-arg
1734       (let ((guess (dired-filename-at-point)))
1735         (read-file-name prompt
1736                         (file-name-directory guess)
1737                         guess
1738                         nil (file-name-nondirectory guess)))
1739     (read-file-name prompt default-directory)))
1740 \f
1741 ;;; BUG REPORTS
1742
1743 ;; Fixme: get rid of this later.
1744
1745 ;;; This section is provided for reports.  It uses Barry A. Warsaw's
1746 ;;; reporter.el which is bundled with GNU Emacs v19.
1747
1748 (defconst dired-x-help-address "bug-gnu-emacs@gnu.org"
1749   "Address(es) accepting submission of reports on dired-x.el.")
1750
1751 (defconst dired-x-variable-list
1752   (list
1753    'dired-bind-vm
1754    'dired-vm-read-only-folders
1755    'dired-bind-jump
1756    'dired-bind-info
1757    'dired-bind-man
1758    'dired-find-subdir
1759    'dired-enable-local-variables
1760    'dired-local-variables-file
1761    'dired-guess-shell-gnutar
1762    'dired-guess-shell-gzip-quiet
1763    'dired-guess-shell-znew-switches
1764    'dired-guess-shell-alist-user
1765    'dired-clean-up-buffers-too
1766    'dired-omit-mode
1767    'dired-omit-files
1768    'dired-omit-extensions
1769    )
1770   "List of variables to be appended to reports sent by `dired-x-submit-report'.")
1771
1772 (defun dired-x-submit-report ()
1773   "Submit via `reporter.el' a bug report on program.
1774 Send report on `dired-x-file' version `dired-x-version,' to
1775 `dired-x-maintainer' at address `dired-x-help-address' listing
1776 variables `dired-x-variable-list' in the message."
1777   (interactive)
1778
1779   (reporter-submit-bug-report
1780    dired-x-help-address                 ; address
1781    "dired-x"                            ; pkgname
1782    dired-x-variable-list                ; varlist
1783    nil nil                              ; pre-/post-hooks
1784    ""))
1785
1786 \f
1787 ;; As Barry Warsaw would say: "This might be useful..."
1788 (provide 'dired-x)
1789
1790 ;; arch-tag: 71a43ba2-7a00-4793-a028-0613dd7765ae
1791 ;;; dired-x.el ends here