lisp/hl-line.el

   1 ;;; hl-line.el --- highlight the current line
   2
   3 ;; Copyright (C) 1998, 2000 Free Software Foundation, Inc.
   4
   5 ;; Author:  Dave Love <fx@gnu.org>
   6 ;; Created: 1998-09-13
   7 ;; Keywords: faces, frames, emulation
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Provides a global minor mode (toggled by M-x hl-line-mode) to
  29 ;; highlight, on a suitable terminal, the line in the current window
  30 ;; on which point is (except in a minibuffer window).  Done to satisfy
  31 ;; a request for a feature of Lesser Editors.
  32
  33 ;; You probably don't really want this; if the cursor is difficult to
  34 ;; spot, try changing its colour, relying on `blink-cursor-mode' or
  35 ;; both.  The hookery used might affect response noticeably on a slow
  36 ;; machine.
  37
  38 ;; An overlay is used, active only on the selected window.  Hooks are
  39 ;; added to `pre-command-hook' and `post-command-hook' to activate and
  40 ;; deactivate (by deleting) the overlay.  `hl-line-unhighlight', on
  41 ;; `pre-command-hook', deactivates it unconditionally in case the
  42 ;; command changes the selected window.  (It does so rather than
  43 ;; keeping track of changes in the selected window).
  44 ;; `hl-line-highlight', on `post-command-hook', activates it again
  45 ;; across the window width.
  46
  47 ;; You could make variable `hl-line-mode' buffer-local to avoid
  48 ;; highlighting specific buffers.
  49
  50 ;;; Code:
  51
  52 (defgroup hl-line nil
  53   "Highliight the current line."
  54   :version "21.1"
  55   :group 'editing)
  56
  57 (defcustom hl-line-face 'highlight
  58   "Face with which to highlight the current line."
  59   :type 'face
  60   :group 'hl-line)
  61
  62 (defvar hl-line-overlay nil)
  63 (make-variable-buffer-local 'hl-line-overlay)
  64 (put 'hl-line-overlay 'permanent-local t)
  65
  66 (defun hl-line-highlight ()
  67   "Active the Hl-Line overlay on the current line in the current window.
  68 \(Unless it's a minibuffer window.)"
  69   (when hl-line-mode                    ; Could be made buffer-local.
  70     (unless (window-minibuffer-p (selected-window)) ; silly in minibuffer
  71       (unless hl-line-overlay           ; new overlay for this buffer
  72         (setq hl-line-overlay (make-overlay 1 1)) ; to be moved
  73         (overlay-put hl-line-overlay 'face hl-line-face))
  74       (overlay-put hl-line-overlay 'window (selected-window))
  75       (move-overlay hl-line-overlay
  76                     (line-beginning-position) (1+ (line-end-position))))))
  77
  78 (defun hl-line-unhighlight ()
  79   "Deactivate the Hl-Line overlay on the current line in the current window."
  80   (if hl-line-overlay
  81       (delete-overlay hl-line-overlay)))
  82
  83 ;;;###autoload
  84 (define-minor-mode hl-line-mode
  85   "Global minor mode to highlight the line about point in the current window.
  86 With ARG, turn Hl-Line mode on if ARG is positive, off otherwise.
  87 Uses functions `hl-line-unhighlight' and `hl-line-highlight' on
  88 `pre-command-hook' and `post-command-hook'."
  89   nil nil nil :global t
  90
  91   (if hl-line-mode
  92       (progn
  93         (add-hook 'pre-command-hook #'hl-line-unhighlight)
  94         (add-hook 'post-command-hook #'hl-line-highlight))
  95     (hl-line-unhighlight)
  96     (remove-hook 'pre-command-hook #'hl-line-unhighlight)
  97     (remove-hook 'post-command-hook #'hl-line-highlight)))
  98
  99 (provide 'hl-line)
 100
 101 ;;; hl-line.el ends here