lisp/faces.el

   1 ;;; faces.el --- Lisp faces
   2
   3 ;; Copyright (C) 1992-1996, 1998-2011  Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: internal
   7 ;; Package: emacs
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile
  29   (require 'cl))
  30
  31 (declare-function xw-defined-colors "term/common-win" (&optional frame))
  32
  33 (defvar help-xref-stack-item)
  34
  35 (defvar face-name-history nil
  36   "History list for some commands that read face names.
  37 Maximum length of the history list is determined by the value
  38 of `history-length', which see.")
  39
  40 \f
  41 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  42 ;;; Font selection.
  43 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  44
  45 (defgroup font-selection nil
  46   "Influencing face font selection."
  47   :group 'faces)
  48
  49
  50 (defcustom face-font-selection-order
  51   '(:width :height :weight :slant)
  52   "A list specifying how face font selection chooses fonts.
  53 Each of the four symbols `:width', `:height', `:weight', and `:slant'
  54 must appear once in the list, and the list must not contain any other
  55 elements.  Font selection first tries to find a best matching font
  56 for those face attributes that appear before in the list.  For
  57 example, if `:slant' appears before `:height', font selection first
  58 tries to find a font with a suitable slant, even if this results in
  59 a font height that isn't optimal."
  60   :tag "Font selection order"
  61   :type '(list symbol symbol symbol symbol)
  62   :group 'font-selection
  63   :set #'(lambda (symbol value)
  64            (set-default symbol value)
  65            (internal-set-font-selection-order value)))
  66
  67
  68 ;; In the absence of Fontconfig support, Monospace and Sans Serif are
  69 ;; unavailable, and we fall back on the courier and helv families,
  70 ;; which are generally available.
  71 (defcustom face-font-family-alternatives
  72   (mapcar (lambda (arg) (mapcar 'purecopy arg))
  73   '(("Monospace" "courier" "fixed")
  74     ("courier" "CMU Typewriter Text" "fixed")
  75     ("Sans Serif" "helv" "helvetica" "arial" "fixed")
  76     ("helv" "helvetica" "arial" "fixed")))
  77   "Alist of alternative font family names.
  78 Each element has the form (FAMILY ALTERNATIVE1 ALTERNATIVE2 ...).
  79 If fonts of family FAMILY can't be loaded, try ALTERNATIVE1, then
  80 ALTERNATIVE2 etc."
  81   :tag "Alternative font families to try"
  82   :type '(repeat (repeat string))
  83   :group 'font-selection
  84   :set #'(lambda (symbol value)
  85            (set-default symbol value)
  86            (internal-set-alternative-font-family-alist value)))
  87
  88
  89 ;; This is defined originally in xfaces.c.
  90 (defcustom face-font-registry-alternatives
  91   (mapcar (lambda (arg) (mapcar 'purecopy arg))
  92   (if (eq system-type 'windows-nt)
  93       '(("iso8859-1" "ms-oemlatin")
  94         ("gb2312.1980" "gb2312" "gbk" "gb18030")
  95         ("jisx0208.1990" "jisx0208.1983" "jisx0208.1978")
  96         ("ksc5601.1989" "ksx1001.1992" "ksc5601.1987")
  97         ("muletibetan-2" "muletibetan-0"))
  98     '(("gb2312.1980" "gb2312.80&gb8565.88" "gbk" "gb18030")
  99       ("jisx0208.1990" "jisx0208.1983" "jisx0208.1978")
 100       ("ksc5601.1989" "ksx1001.1992" "ksc5601.1987")
 101       ("muletibetan-2" "muletibetan-0"))))
 102   "Alist of alternative font registry names.
 103 Each element has the form (REGISTRY ALTERNATIVE1 ALTERNATIVE2 ...).
 104 If fonts of registry REGISTRY can be loaded, font selection
 105 tries to find a best matching font among all fonts of registry
 106 REGISTRY, ALTERNATIVE1, ALTERNATIVE2, and etc."
 107   :tag "Alternative font registries to try"
 108   :type '(repeat (repeat string))
 109   :version "21.1"
 110   :group 'font-selection
 111   :set #'(lambda (symbol value)
 112            (set-default symbol value)
 113            (internal-set-alternative-font-registry-alist value)))
 114
 115 \f
 116 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 117 ;;; Creation, copying.
 118 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 119
 120
 121 (defun face-list ()
 122   "Return a list of all defined face names."
 123   (mapcar #'car face-new-frame-defaults))
 124
 125
 126 ;;; ### If not frame-local initialize by what X resources?
 127
 128 (defun make-face (face &optional no-init-from-resources)
 129   "Define a new face with name FACE, a symbol.
 130 NO-INIT-FROM-RESOURCES non-nil means don't initialize frame-local
 131 variants of FACE from X resources.  (X resources recognized are found
 132 in the global variable `face-x-resources'.)  If FACE is already known
 133 as a face, leave it unmodified.  Value is FACE."
 134   (interactive (list (read-from-minibuffer
 135                       "Make face: " nil nil t 'face-name-history)))
 136   (unless (facep face)
 137     ;; Make frame-local faces (this also makes the global one).
 138     (dolist (frame (frame-list))
 139       (internal-make-lisp-face face frame))
 140     ;; Add the face to the face menu.
 141     (when (fboundp 'facemenu-add-new-face)
 142       (facemenu-add-new-face face))
 143     ;; Define frame-local faces for all frames from X resources.
 144     (unless no-init-from-resources
 145       (make-face-x-resource-internal face)))
 146   face)
 147
 148
 149 (defun make-empty-face (face)
 150   "Define a new, empty face with name FACE.
 151 If the face already exists, it is left unmodified.  Value is FACE."
 152   (interactive (list (read-from-minibuffer
 153                       "Make empty face: " nil nil t 'face-name-history)))
 154   (make-face face 'no-init-from-resources))
 155
 156
 157 (defun copy-face (old-face new-face &optional frame new-frame)
 158   "Define a face just like OLD-FACE, with name NEW-FACE.
 159
 160 If NEW-FACE already exists as a face, it is modified to be like
 161 OLD-FACE.  If it doesn't already exist, it is created.
 162
 163 If the optional argument FRAME is given as a frame, NEW-FACE is
 164 changed on FRAME only.
 165 If FRAME is t, the frame-independent default specification for OLD-FACE
 166 is copied to NEW-FACE.
 167 If FRAME is nil, copying is done for the frame-independent defaults
 168 and for each existing frame.
 169
 170 If the optional fourth argument NEW-FRAME is given,
 171 copy the information from face OLD-FACE on frame FRAME
 172 to NEW-FACE on frame NEW-FRAME.  In this case, FRAME may not be nil."
 173   (let ((inhibit-quit t))
 174     (if (null frame)
 175         (progn
 176           (when new-frame
 177             (error "Copying face %s from all frames to one frame"
 178                    old-face))
 179           (make-empty-face new-face)
 180           (dolist (frame (frame-list))
 181             (copy-face old-face new-face frame))
 182           (copy-face old-face new-face t))
 183       (make-empty-face new-face)
 184       (internal-copy-lisp-face old-face new-face frame new-frame))
 185     new-face))
 186
 187 \f
 188 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 189 ;;; Predicates, type checks.
 190 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 191
 192 (defun facep (face)
 193   "Return non-nil if FACE is a face name; nil otherwise.
 194 A face name can be a string or a symbol."
 195   (internal-lisp-face-p face))
 196
 197
 198 (defun check-face (face)
 199   "Signal an error if FACE doesn't name a face.
 200 Value is FACE."
 201   (unless (facep face)
 202     (error "Not a face: %s" face))
 203   face)
 204
 205
 206 ;; The ID returned is not to be confused with the internally used IDs
 207 ;; of realized faces.  The ID assigned to Lisp faces is used to
 208 ;; support faces in display table entries.
 209
 210 (defun face-id (face &optional frame)
 211   "Return the internal ID of face with name FACE.
 212 If FACE is a face-alias, return the ID of the target face.
 213 The optional argument FRAME is ignored, since the internal face ID
 214 of a face name is the same for all frames."
 215   (check-face face)
 216   (or (get face 'face)
 217       (face-id (get face 'face-alias))))
 218
 219 (defun face-equal (face1 face2 &optional frame)
 220   "Non-nil if faces FACE1 and FACE2 are equal.
 221 Faces are considered equal if all their attributes are equal.
 222 If the optional argument FRAME is given, report on FACE1 and FACE2 in that frame.
 223 If FRAME is t, report on the defaults for FACE1 and FACE2 (for new frames).
 224 If FRAME is omitted or nil, use the selected frame."
 225   (internal-lisp-face-equal-p face1 face2 frame))
 226
 227
 228 (defun face-differs-from-default-p (face &optional frame)
 229   "Return non-nil if FACE displays differently from the default face.
 230 If the optional argument FRAME is given, report on face FACE in that frame.
 231 If FRAME is t, report on the defaults for face FACE (for new frames).
 232 If FRAME is omitted or nil, use the selected frame."
 233   (let ((attrs
 234          (delq :inherit (mapcar 'car face-attribute-name-alist)))
 235         (differs nil))
 236     (while (and attrs (not differs))
 237       (let* ((attr (pop attrs))
 238              (attr-val (face-attribute face attr frame t)))
 239         (when (and
 240                (not (eq attr-val 'unspecified))
 241                (display-supports-face-attributes-p (list attr attr-val)
 242                                                    frame))
 243           (setq differs attr))))
 244     differs))
 245
 246
 247 (defun face-nontrivial-p (face &optional frame)
 248   "True if face FACE has some non-nil attribute.
 249 If the optional argument FRAME is given, report on face FACE in that frame.
 250 If FRAME is t, report on the defaults for face FACE (for new frames).
 251 If FRAME is omitted or nil, use the selected frame."
 252   (not (internal-lisp-face-empty-p face frame)))
 253
 254
 255 \f
 256 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 257 ;;; Setting face attributes from X resources.
 258 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 259
 260 (defcustom face-x-resources
 261   (mapcar
 262    (lambda (arg)
 263      ;; FIXME; can we purecopy some of the conses too?
 264      (cons (car arg)
 265            (cons (purecopy (car (cdr arg))) (purecopy (cdr (cdr arg))))))
 266   '((:family (".attributeFamily" . "Face.AttributeFamily"))
 267     (:foundry (".attributeFoundry" . "Face.AttributeFoundry"))
 268     (:width (".attributeWidth" . "Face.AttributeWidth"))
 269     (:height (".attributeHeight" . "Face.AttributeHeight"))
 270     (:weight (".attributeWeight" . "Face.AttributeWeight"))
 271     (:slant (".attributeSlant" . "Face.AttributeSlant"))
 272     (:foreground (".attributeForeground" . "Face.AttributeForeground"))
 273     (:background (".attributeBackground" . "Face.AttributeBackground"))
 274     (:overline (".attributeOverline" . "Face.AttributeOverline"))
 275     (:strike-through (".attributeStrikeThrough" . "Face.AttributeStrikeThrough"))
 276     (:box (".attributeBox" . "Face.AttributeBox"))
 277     (:underline (".attributeUnderline" . "Face.AttributeUnderline"))
 278     (:inverse-video (".attributeInverse" . "Face.AttributeInverse"))
 279     (:stipple
 280      (".attributeStipple" . "Face.AttributeStipple")
 281      (".attributeBackgroundPixmap" . "Face.AttributeBackgroundPixmap"))
 282     (:bold (".attributeBold" . "Face.AttributeBold"))
 283     (:italic (".attributeItalic" . "Face.AttributeItalic"))
 284     (:font (".attributeFont" . "Face.AttributeFont"))
 285     (:inherit (".attributeInherit" . "Face.AttributeInherit"))))
 286   "List of X resources and classes for face attributes.
 287 Each element has the form (ATTRIBUTE ENTRY1 ENTRY2...) where ATTRIBUTE is
 288 the name of a face attribute, and each ENTRY is a cons of the form
 289 \(RESOURCE . CLASS) with RESOURCE being the resource and CLASS being the
 290 X resource class for the attribute."
 291   :type '(repeat (cons symbol (repeat (cons string string))))
 292   :group 'faces)
 293
 294
 295 (declare-function internal-face-x-get-resource "xfaces.c"
 296                   (resource class frame))
 297
 298 (declare-function internal-set-lisp-face-attribute-from-resource "xfaces.c"
 299                   (face attr value &optional frame))
 300
 301 (defun set-face-attribute-from-resource (face attribute resource class frame)
 302   "Set FACE's ATTRIBUTE from X resource RESOURCE, class CLASS on FRAME.
 303 Value is the attribute value specified by the resource, or nil
 304 if not present.  This function displays a message if the resource
 305 specifies an invalid attribute."
 306   (let* ((face-name (face-name face))
 307          (value (internal-face-x-get-resource (concat face-name resource)
 308                                               class frame)))
 309     (when value
 310       (condition-case ()
 311           (internal-set-lisp-face-attribute-from-resource
 312            face attribute (downcase value) frame)
 313         (error
 314          (message "Face %s, frame %s: invalid attribute %s %s from X resource"
 315                   face-name frame attribute value))))
 316     value))
 317
 318
 319 (defun set-face-attributes-from-resources (face frame)
 320   "Set attributes of FACE from X resources for FRAME."
 321   (when (memq (framep frame) '(x w32))
 322     (dolist (definition face-x-resources)
 323       (let ((attribute (car definition)))
 324         (dolist (entry (cdr definition))
 325           (set-face-attribute-from-resource face attribute (car entry)
 326                                             (cdr entry) frame))))))
 327
 328
 329 (defun make-face-x-resource-internal (face &optional frame)
 330   "Fill frame-local FACE on FRAME from X resources.
 331 FRAME nil or not specified means do it for all frames."
 332   (if (null frame)
 333       (dolist (frame (frame-list))
 334         (set-face-attributes-from-resources face frame))
 335     (set-face-attributes-from-resources face frame)))
 336
 337
 338 \f
 339 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 340 ;;; Retrieving face attributes.
 341 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 342
 343 (defun face-name (face)
 344   "Return the name of face FACE."
 345   (symbol-name (check-face face)))
 346
 347
 348 (defun face-all-attributes (face &optional frame)
 349   "Return an alist stating the attributes of FACE.
 350 Each element of the result has the form (ATTR-NAME . ATTR-VALUE).
 351 If FRAME is omitted or nil the value describes the default attributes,
 352 but if you specify FRAME, the value describes the attributes
 353 of FACE on FRAME."
 354   (mapcar (lambda (pair)
 355             (let ((attr (car pair)))
 356               (cons attr (face-attribute face attr (or frame t)))))
 357           face-attribute-name-alist))
 358
 359 (defun face-attribute (face attribute &optional frame inherit)
 360   "Return the value of FACE's ATTRIBUTE on FRAME.
 361 If the optional argument FRAME is given, report on face FACE in that frame.
 362 If FRAME is t, report on the defaults for face FACE (for new frames).
 363 If FRAME is omitted or nil, use the selected frame.
 364
 365 If INHERIT is nil, only attributes directly defined by FACE are considered,
 366   so the return value may be `unspecified', or a relative value.
 367 If INHERIT is non-nil, FACE's definition of ATTRIBUTE is merged with the
 368   faces specified by its `:inherit' attribute; however the return value
 369   may still be `unspecified' or relative.
 370 If INHERIT is a face or a list of faces, then the result is further merged
 371   with that face (or faces), until it becomes specified and absolute.
 372
 373 To ensure that the return value is always specified and absolute, use a
 374 value of `default' for INHERIT; this will resolve any unspecified or
 375 relative values by merging with the `default' face (which is always
 376 completely specified)."
 377   (let ((value (internal-get-lisp-face-attribute face attribute frame)))
 378     (when (and inherit (face-attribute-relative-p attribute value))
 379       ;; VALUE is relative, so merge with inherited faces
 380       (let ((inh-from (face-attribute face :inherit frame)))
 381         (unless (or (null inh-from) (eq inh-from 'unspecified))
 382           (condition-case nil
 383               (setq value
 384                     (face-attribute-merged-with attribute value inh-from frame))
 385             ;; The `inherit' attribute may point to non existent faces.
 386             (error nil)))))
 387     (when (and inherit
 388                (not (eq inherit t))
 389                (face-attribute-relative-p attribute value))
 390       ;; We should merge with INHERIT as well
 391       (setq value (face-attribute-merged-with attribute value inherit frame)))
 392     value))
 393
 394 (defun face-attribute-merged-with (attribute value faces &optional frame)
 395   "Merges ATTRIBUTE, initially VALUE, with faces from FACES until absolute.
 396 FACES may be either a single face or a list of faces.
 397 \[This is an internal function.]"
 398   (cond ((not (face-attribute-relative-p attribute value))
 399          value)
 400         ((null faces)
 401          value)
 402         ((consp faces)
 403          (face-attribute-merged-with
 404           attribute
 405           (face-attribute-merged-with attribute value (car faces) frame)
 406           (cdr faces)
 407           frame))
 408         (t
 409          (merge-face-attribute attribute
 410                                value
 411                                (face-attribute faces attribute frame t)))))
 412
 413
 414 (defmacro face-attribute-specified-or (value &rest body)
 415   "Return VALUE, unless it's `unspecified', in which case evaluate BODY and return the result."
 416   (let ((temp (make-symbol "value")))
 417     `(let ((,temp ,value))
 418        (if (not (eq ,temp 'unspecified))
 419            ,temp
 420          ,@body))))
 421
 422 (defun face-foreground (face &optional frame inherit)
 423   "Return the foreground color name of FACE, or nil if unspecified.
 424 If the optional argument FRAME is given, report on face FACE in that frame.
 425 If FRAME is t, report on the defaults for face FACE (for new frames).
 426 If FRAME is omitted or nil, use the selected frame.
 427
 428 If INHERIT is nil, only a foreground color directly defined by FACE is
 429   considered, so the return value may be nil.
 430 If INHERIT is t, and FACE doesn't define a foreground color, then any
 431   foreground color that FACE inherits through its `:inherit' attribute
 432   is considered as well; however the return value may still be nil.
 433 If INHERIT is a face or a list of faces, then it is used to try to
 434   resolve an unspecified foreground color.
 435
 436 To ensure that a valid color is always returned, use a value of
 437 `default' for INHERIT; this will resolve any unspecified values by
 438 merging with the `default' face (which is always completely specified)."
 439   (face-attribute-specified-or (face-attribute face :foreground frame inherit)
 440                                nil))
 441
 442 (defun face-background (face &optional frame inherit)
 443   "Return the background color name of FACE, or nil if unspecified.
 444 If the optional argument FRAME is given, report on face FACE in that frame.
 445 If FRAME is t, report on the defaults for face FACE (for new frames).
 446 If FRAME is omitted or nil, use the selected frame.
 447
 448 If INHERIT is nil, only a background color directly defined by FACE is
 449   considered, so the return value may be nil.
 450 If INHERIT is t, and FACE doesn't define a background color, then any
 451   background color that FACE inherits through its `:inherit' attribute
 452   is considered as well; however the return value may still be nil.
 453 If INHERIT is a face or a list of faces, then it is used to try to
 454   resolve an unspecified background color.
 455
 456 To ensure that a valid color is always returned, use a value of
 457 `default' for INHERIT; this will resolve any unspecified values by
 458 merging with the `default' face (which is always completely specified)."
 459   (face-attribute-specified-or (face-attribute face :background frame inherit)
 460                                nil))
 461
 462 (defun face-stipple (face &optional frame inherit)
 463  "Return the stipple pixmap name of FACE, or nil if unspecified.
 464 If the optional argument FRAME is given, report on face FACE in that frame.
 465 If FRAME is t, report on the defaults for face FACE (for new frames).
 466 If FRAME is omitted or nil, use the selected frame.
 467
 468 If INHERIT is nil, only a stipple directly defined by FACE is
 469   considered, so the return value may be nil.
 470 If INHERIT is t, and FACE doesn't define a stipple, then any stipple
 471   that FACE inherits through its `:inherit' attribute is considered as
 472   well; however the return value may still be nil.
 473 If INHERIT is a face or a list of faces, then it is used to try to
 474   resolve an unspecified stipple.
 475
 476 To ensure that a valid stipple or nil is always returned, use a value of
 477 `default' for INHERIT; this will resolve any unspecified values by merging
 478 with the `default' face (which is always completely specified)."
 479   (face-attribute-specified-or (face-attribute face :stipple frame inherit)
 480                                nil))
 481
 482
 483 (defalias 'face-background-pixmap 'face-stipple)
 484
 485
 486 (defun face-underline-p (face &optional frame)
 487  "Return non-nil if FACE is underlined.
 488 If the optional argument FRAME is given, report on face FACE in that frame.
 489 If FRAME is t, report on the defaults for face FACE (for new frames).
 490 If FRAME is omitted or nil, use the selected frame."
 491  (eq (face-attribute face :underline frame) t))
 492
 493
 494 (defun face-inverse-video-p (face &optional frame)
 495  "Return non-nil if FACE is in inverse video on FRAME.
 496 If the optional argument FRAME is given, report on face FACE in that frame.
 497 If FRAME is t, report on the defaults for face FACE (for new frames).
 498 If FRAME is omitted or nil, use the selected frame."
 499  (eq (face-attribute face :inverse-video frame) t))
 500
 501
 502 (defun face-bold-p (face &optional frame)
 503   "Return non-nil if the font of FACE is bold on FRAME.
 504 If the optional argument FRAME is given, report on face FACE in that frame.
 505 If FRAME is t, report on the defaults for face FACE (for new frames).
 506 If FRAME is omitted or nil, use the selected frame.
 507 Use `face-attribute' for finer control."
 508   (let ((bold (face-attribute face :weight frame)))
 509     (memq bold '(semi-bold bold extra-bold ultra-bold))))
 510
 511
 512 (defun face-italic-p (face &optional frame)
 513   "Return non-nil if the font of FACE is italic on FRAME.
 514 If the optional argument FRAME is given, report on face FACE in that frame.
 515 If FRAME is t, report on the defaults for face FACE (for new frames).
 516 If FRAME is omitted or nil, use the selected frame.
 517 Use `face-attribute' for finer control."
 518   (let ((italic (face-attribute face :slant frame)))
 519     (memq italic '(italic oblique))))
 520
 521
 522 \f
 523 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 524 ;;; Face documentation.
 525 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 526
 527 (defun face-documentation (face)
 528   "Get the documentation string for FACE.
 529 If FACE is a face-alias, get the documentation for the target face."
 530   (let ((alias (get face 'face-alias))
 531         doc)
 532     (if alias
 533         (progn
 534           (setq doc (get alias 'face-documentation))
 535           (format "%s is an alias for the face `%s'.%s" face alias
 536                   (if doc (format "\n%s" doc)
 537                     "")))
 538       (get face 'face-documentation))))
 539
 540
 541 (defun set-face-documentation (face string)
 542   "Set the documentation string for FACE to STRING."
 543   ;; Perhaps the text should go in DOC.
 544   (put face 'face-documentation (purecopy string)))
 545
 546
 547 (defalias 'face-doc-string 'face-documentation)
 548 (defalias 'set-face-doc-string 'set-face-documentation)
 549
 550
 551 \f
 552 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 553 ;; Setting face attributes.
 554 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 555
 556
 557 (defun set-face-attribute (face frame &rest args)
 558   "Set attributes of FACE on FRAME from ARGS.
 559
 560 FRAME nil means change attributes on all frames.  FRAME t means change
 561 the default for new frames (this is done automatically each time an
 562 attribute is changed on all frames).
 563
 564 ARGS must come in pairs ATTRIBUTE VALUE.  ATTRIBUTE must be a valid
 565 face attribute name.  All attributes can be set to `unspecified';
 566 this fact is not further mentioned below.
 567
 568 The following attributes are recognized:
 569
 570 `:family'
 571
 572 VALUE must be a string specifying the font family, e.g. ``monospace'',
 573 or a fontset alias name.  If a font family is specified, wild-cards `*'
 574 and `?' are allowed.
 575
 576 `:foundry'
 577
 578 VALUE must be a string specifying the font foundry,
 579 e.g. ``adobe''.  If a font foundry is specified, wild-cards `*'
 580 and `?' are allowed.
 581
 582 `:width'
 583
 584 VALUE specifies the relative proportionate width of the font to use.
 585 It must be one of the symbols `ultra-condensed', `extra-condensed',
 586 `condensed', `semi-condensed', `normal', `semi-expanded', `expanded',
 587 `extra-expanded', or `ultra-expanded'.
 588
 589 `:height'
 590
 591 VALUE specifies the height of the font, in either absolute or relative
 592 terms.  An absolute height is an integer, and specifies font height in
 593 units of 1/10 pt.  A relative height is either a floating point number,
 594 which specifies a scaling factor for the underlying face height;
 595 or a function that takes a single argument (the underlying face height)
 596 and returns the new height.  Note that for the `default' face,
 597 you can only specify an absolute height (since there is nothing
 598 for it to be relative to).
 599
 600 `:weight'
 601
 602 VALUE specifies the weight of the font to use.  It must be one of the
 603 symbols `ultra-bold', `extra-bold', `bold', `semi-bold', `normal',
 604 `semi-light', `light', `extra-light', `ultra-light'.
 605
 606 `:slant'
 607
 608 VALUE specifies the slant of the font to use.  It must be one of the
 609 symbols `italic', `oblique', `normal', `reverse-italic', or
 610 `reverse-oblique'.
 611
 612 `:foreground', `:background'
 613
 614 VALUE must be a color name, a string.
 615
 616 `:underline'
 617
 618 VALUE specifies whether characters in FACE should be underlined.  If
 619 VALUE is t, underline with foreground color of the face.  If VALUE is
 620 a string, underline with that color.  If VALUE is nil, explicitly
 621 don't underline.
 622
 623 `:overline'
 624
 625 VALUE specifies whether characters in FACE should be overlined.  If
 626 VALUE is t, overline with foreground color of the face.  If VALUE is a
 627 string, overline with that color.  If VALUE is nil, explicitly don't
 628 overline.
 629
 630 `:strike-through'
 631
 632 VALUE specifies whether characters in FACE should be drawn with a line
 633 striking through them.  If VALUE is t, use the foreground color of the
 634 face.  If VALUE is a string, strike-through with that color.  If VALUE
 635 is nil, explicitly don't strike through.
 636
 637 `:box'
 638
 639 VALUE specifies whether characters in FACE should have a box drawn
 640 around them.  If VALUE is nil, explicitly don't draw boxes.  If
 641 VALUE is t, draw a box with lines of width 1 in the foreground color
 642 of the face.  If VALUE is a string, the string must be a color name,
 643 and the box is drawn in that color with a line width of 1.  Otherwise,
 644 VALUE must be a property list of the form `(:line-width WIDTH
 645 :color COLOR :style STYLE)'.  If a keyword/value pair is missing from
 646 the property list, a default value will be used for the value, as
 647 specified below.  WIDTH specifies the width of the lines to draw; it
 648 defaults to 1.  If WIDTH is negative, the absolute value is the width
 649 of the lines, and draw top/bottom lines inside the characters area,
 650 not around it.  COLOR is the name of the color to draw in, default is
 651 the foreground color of the face for simple boxes, and the background
 652 color of the face for 3D boxes.  STYLE specifies whether a 3D box
 653 should be draw.  If STYLE is `released-button', draw a box looking
 654 like a released 3D button.  If STYLE is `pressed-button' draw a box
 655 that appears like a pressed button.  If STYLE is nil, the default if
 656 the property list doesn't contain a style specification, draw a 2D
 657 box.
 658
 659 `:inverse-video'
 660
 661 VALUE specifies whether characters in FACE should be displayed in
 662 inverse video.  VALUE must be one of t or nil.
 663
 664 `:stipple'
 665
 666 If VALUE is a string, it must be the name of a file of pixmap data.
 667 The directories listed in the `x-bitmap-file-path' variable are
 668 searched.  Alternatively, VALUE may be a list of the form (WIDTH
 669 HEIGHT DATA) where WIDTH and HEIGHT are the size in pixels, and DATA
 670 is a string containing the raw bits of the bitmap.  VALUE nil means
 671 explicitly don't use a stipple pattern.
 672
 673 For convenience, attributes `:family', `:foundry', `:width',
 674 `:height', `:weight', and `:slant' may also be set in one step
 675 from an X font name:
 676
 677 `:font'
 678
 679 Set font-related face attributes from VALUE.  VALUE must be a valid
 680 XLFD font name.  If it is a font name pattern, the first matching font
 681 will be used.
 682
 683 For compatibility with Emacs 20, keywords `:bold' and `:italic' can
 684 be used to specify that a bold or italic font should be used.  VALUE
 685 must be t or nil in that case.  A value of `unspecified' is not allowed.
 686
 687 `:inherit'
 688
 689 VALUE is the name of a face from which to inherit attributes, or a list
 690 of face names.  Attributes from inherited faces are merged into the face
 691 like an underlying face would be, with higher priority than underlying faces."
 692   (setq args (purecopy args))
 693   (let ((where (if (null frame) 0 frame))
 694         (spec args)
 695         family foundry)
 696     ;; If we set the new-frame defaults, this face is modified outside Custom.
 697     (if (memq where '(0 t))
 698         (put (or (get face 'face-alias) face) 'face-modified t))
 699     ;; If family and/or foundry are specified, set it first.  Certain
 700     ;; face attributes, e.g. :weight semi-condensed, are not supported
 701     ;; in every font.  See bug#1127.
 702     (while spec
 703       (cond ((eq (car spec) :family)
 704              (setq family (cadr spec)))
 705             ((eq (car spec) :foundry)
 706              (setq foundry (cadr spec))))
 707       (setq spec (cddr spec)))
 708     (when (or family foundry)
 709       (when (and (stringp family)
 710                  (string-match "\\([^-]*\\)-\\([^-]*\\)" family))
 711         (unless foundry
 712           (setq foundry (match-string 1 family)))
 713         (setq family (match-string 2 family)))
 714       (when (or (stringp family) (eq family 'unspecified))
 715         (internal-set-lisp-face-attribute face :family (purecopy family)
 716                                           where))
 717       (when (or (stringp foundry) (eq foundry 'unspecified))
 718         (internal-set-lisp-face-attribute face :foundry (purecopy foundry)
 719                                           where)))
 720     (while args
 721       (unless (memq (car args) '(:family :foundry))
 722         (internal-set-lisp-face-attribute face (car args)
 723                                           (purecopy (cadr args))
 724                                           where))
 725       (setq args (cddr args)))))
 726
 727 (defun make-face-bold (face &optional frame noerror)
 728   "Make the font of FACE be bold, if possible.
 729 FRAME nil or not specified means change face on all frames.
 730 Argument NOERROR is ignored and retained for compatibility.
 731 Use `set-face-attribute' for finer control of the font weight."
 732   (interactive (list (read-face-name "Make which face bold")))
 733   (set-face-attribute face frame :weight 'bold))
 734
 735
 736 (defun make-face-unbold (face &optional frame noerror)
 737   "Make the font of FACE be non-bold, if possible.
 738 FRAME nil or not specified means change face on all frames.
 739 Argument NOERROR is ignored and retained for compatibility."
 740   (interactive (list (read-face-name "Make which face non-bold")))
 741   (set-face-attribute face frame :weight 'normal))
 742
 743
 744 (defun make-face-italic (face &optional frame noerror)
 745   "Make the font of FACE be italic, if possible.
 746 FRAME nil or not specified means change face on all frames.
 747 Argument NOERROR is ignored and retained for compatibility.
 748 Use `set-face-attribute' for finer control of the font slant."
 749   (interactive (list (read-face-name "Make which face italic")))
 750   (set-face-attribute face frame :slant 'italic))
 751
 752
 753 (defun make-face-unitalic (face &optional frame noerror)
 754   "Make the font of FACE be non-italic, if possible.
 755 FRAME nil or not specified means change face on all frames.
 756 Argument NOERROR is ignored and retained for compatibility."
 757   (interactive (list (read-face-name "Make which face non-italic")))
 758   (set-face-attribute face frame :slant 'normal))
 759
 760
 761 (defun make-face-bold-italic (face &optional frame noerror)
 762   "Make the font of FACE be bold and italic, if possible.
 763 FRAME nil or not specified means change face on all frames.
 764 Argument NOERROR is ignored and retained for compatibility.
 765 Use `set-face-attribute' for finer control of font weight and slant."
 766   (interactive (list (read-face-name "Make which face bold-italic")))
 767   (set-face-attribute face frame :weight 'bold :slant 'italic))
 768
 769
 770 (defun set-face-font (face font &optional frame)
 771   "Change font-related attributes of FACE to those of FONT (a string).
 772 FRAME nil or not specified means change face on all frames.
 773 This sets the attributes `:family', `:foundry', `:width',
 774 `:height', `:weight', and `:slant'.  When called interactively,
 775 prompt for the face and font."
 776   (interactive (read-face-and-attribute :font))
 777   (set-face-attribute face frame :font font))
 778
 779
 780 ;; Implementation note: Emulating gray background colors with a
 781 ;; stipple pattern is now part of the face realization process, and is
 782 ;; done in C depending on the frame on which the face is realized.
 783
 784 (defun set-face-background (face color &optional frame)
 785   "Change the background color of face FACE to COLOR (a string).
 786 FRAME nil or not specified means change face on all frames.
 787 COLOR can be a system-defined color name (see `list-colors-display')
 788 or a hex spec of the form #RRGGBB.
 789 When called interactively, prompts for the face and color."
 790   (interactive (read-face-and-attribute :background))
 791   (set-face-attribute face frame :background (or color 'unspecified)))
 792
 793
 794 (defun set-face-foreground (face color &optional frame)
 795   "Change the foreground color of face FACE to COLOR (a string).
 796 FRAME nil or not specified means change face on all frames.
 797 COLOR can be a system-defined color name (see `list-colors-display')
 798 or a hex spec of the form #RRGGBB.
 799 When called interactively, prompts for the face and color."
 800   (interactive (read-face-and-attribute :foreground))
 801   (set-face-attribute face frame :foreground (or color 'unspecified)))
 802
 803
 804 (defun set-face-stipple (face stipple &optional frame)
 805   "Change the stipple pixmap of face FACE to STIPPLE.
 806 FRAME nil or not specified means change face on all frames.
 807 STIPPLE should be a string, the name of a file of pixmap data.
 808 The directories listed in the `x-bitmap-file-path' variable are searched.
 809
 810 Alternatively, STIPPLE may be a list of the form (WIDTH HEIGHT DATA)
 811 where WIDTH and HEIGHT are the size in pixels,
 812 and DATA is a string, containing the raw bits of the bitmap."
 813   (interactive (read-face-and-attribute :stipple))
 814   (set-face-attribute face frame :stipple (or stipple 'unspecified)))
 815
 816
 817 (defun set-face-underline-p (face underline &optional frame)
 818   "Specify whether face FACE is underlined.
 819 UNDERLINE nil means FACE explicitly doesn't underline.
 820 UNDERLINE non-nil means FACE explicitly does underlining
 821 with the same of the foreground color.
 822 If UNDERLINE is a string, underline with the color named UNDERLINE.
 823 FRAME nil or not specified means change face on all frames.
 824 Use `set-face-attribute' to ``unspecify'' underlining."
 825   (interactive
 826    (let ((list (read-face-and-attribute :underline)))
 827      (list (car list) (eq (car (cdr list)) t))))
 828   (set-face-attribute face frame :underline underline))
 829
 830 (define-obsolete-function-alias 'set-face-underline
 831                                 'set-face-underline-p "22.1")
 832
 833
 834 (defun set-face-inverse-video-p (face inverse-video-p &optional frame)
 835   "Specify whether face FACE is in inverse video.
 836 INVERSE-VIDEO-P non-nil means FACE displays explicitly in inverse video.
 837 INVERSE-VIDEO-P nil means FACE explicitly is not in inverse video.
 838 FRAME nil or not specified means change face on all frames.
 839 Use `set-face-attribute' to ``unspecify'' the inverse video attribute."
 840   (interactive
 841    (let ((list (read-face-and-attribute :inverse-video)))
 842      (list (car list) (eq (car (cdr list)) t))))
 843   (set-face-attribute face frame :inverse-video inverse-video-p))
 844
 845
 846 (defun set-face-bold-p (face bold-p &optional frame)
 847   "Specify whether face FACE is bold.
 848 BOLD-P non-nil means FACE should explicitly display bold.
 849 BOLD-P nil means FACE should explicitly display non-bold.
 850 FRAME nil or not specified means change face on all frames.
 851 Use `set-face-attribute' or `modify-face' for finer control."
 852   (if (null bold-p)
 853       (make-face-unbold face frame)
 854     (make-face-bold face frame)))
 855
 856
 857 (defun set-face-italic-p (face italic-p &optional frame)
 858   "Specify whether face FACE is italic.
 859 ITALIC-P non-nil means FACE should explicitly display italic.
 860 ITALIC-P nil means FACE should explicitly display non-italic.
 861 FRAME nil or not specified means change face on all frames.
 862 Use `set-face-attribute' or `modify-face' for finer control."
 863   (if (null italic-p)
 864       (make-face-unitalic face frame)
 865     (make-face-italic face frame)))
 866
 867
 868 (defalias 'set-face-background-pixmap 'set-face-stipple)
 869
 870
 871 (defun invert-face (face &optional frame)
 872   "Swap the foreground and background colors of FACE.
 873 If FRAME is omitted or nil, it means change face on all frames.
 874 If FACE specifies neither foreground nor background color,
 875 set its foreground and background to the background and foreground
 876 of the default face.  Value is FACE."
 877   (interactive (list (read-face-name "Invert face")))
 878   (let ((fg (face-attribute face :foreground frame))
 879         (bg (face-attribute face :background frame)))
 880     (if (not (and (eq fg 'unspecified) (eq bg 'unspecified)))
 881         (set-face-attribute face frame :foreground bg :background fg)
 882       (set-face-attribute face frame
 883                           :foreground
 884                           (face-attribute 'default :background frame)
 885                           :background
 886                           (face-attribute 'default :foreground frame))))
 887   face)
 888
 889 \f
 890 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 891 ;;; Interactively modifying faces.
 892 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 893
 894 (defun read-face-name (prompt &optional default multiple)
 895   "Read a face, defaulting to the face or faces on the char after point.
 896 If it has the property `read-face-name', that overrides the `face' property.
 897 PROMPT should be a string that describes what the caller will do with the face;
 898 it should not end in a space.
 899 The optional argument DEFAULT provides the value to display in the
 900 minibuffer prompt that is returned if the user just types RET
 901 unless DEFAULT is a string (in which case nil is returned).
 902 If MULTIPLE is non-nil, return a list of faces (possibly only one).
 903 Otherwise, return a single face."
 904   (let ((faceprop (or (get-char-property (point) 'read-face-name)
 905                       (get-char-property (point) 'face)))
 906         (aliasfaces nil)
 907         (nonaliasfaces nil)
 908         faces)
 909     ;; Try to get a face name from the buffer.
 910     (if (memq (intern-soft (thing-at-point 'symbol)) (face-list))
 911         (setq faces (list (intern-soft (thing-at-point 'symbol)))))
 912     ;; Add the named faces that the `face' property uses.
 913     (if (and (listp faceprop)
 914              ;; Don't treat an attribute spec as a list of faces.
 915              (not (keywordp (car faceprop)))
 916              (not (memq (car faceprop) '(foreground-color background-color))))
 917         (dolist (f faceprop)
 918           (if (symbolp f)
 919               (push f faces)))
 920       (if (symbolp faceprop)
 921           (push faceprop faces)))
 922     (delete-dups faces)
 923
 924     ;; Build up the completion tables.
 925     (mapatoms (lambda (s)
 926                 (if (custom-facep s)
 927                     (if (get s 'face-alias)
 928                         (push (symbol-name s) aliasfaces)
 929                       (push (symbol-name s) nonaliasfaces)))))
 930
 931     ;; If we only want one, and the default is more than one,
 932     ;; discard the unwanted ones now.
 933     (unless multiple
 934       (if faces
 935           (setq faces (list (car faces)))))
 936     (require 'crm)
 937     (let* ((input
 938             ;; Read the input.
 939             (completing-read-multiple
 940              (if (or faces default)
 941                  (format "%s (default `%s'): " prompt
 942                          (if faces (mapconcat 'symbol-name faces ",")
 943                            default))
 944                (format "%s: " prompt))
 945              (completion-table-in-turn nonaliasfaces aliasfaces)
 946              nil t nil 'face-name-history
 947              (if faces (mapconcat 'symbol-name faces ","))))
 948            ;; Canonicalize the output.
 949            (output
 950             (cond ((or (equal input "") (equal input '("")))
 951                    (or faces (unless (stringp default) default)))
 952                   ((stringp input)
 953                    (mapcar 'intern (split-string input ", *" t)))
 954                   ((listp input)
 955                    (mapcar 'intern input))
 956                   (input))))
 957       ;; Return either a list of faces or just one face.
 958       (if multiple
 959           output
 960         (car output)))))
 961
 962 ;; Not defined without X, but behind window-system test.
 963 (defvar x-bitmap-file-path)
 964
 965 (defun face-valid-attribute-values (attribute &optional frame)
 966   "Return valid values for face attribute ATTRIBUTE.
 967 The optional argument FRAME is used to determine available fonts
 968 and colors.  If it is nil or not specified, the selected frame is used.
 969 Value is an alist of (NAME . VALUE) if ATTRIBUTE expects a value out
 970 of a set of discrete values.  Value is `integerp' if ATTRIBUTE expects
 971 an integer value."
 972   (let ((valid
 973          (case attribute
 974            (:family
 975             (if (window-system frame)
 976                 (mapcar (lambda (x) (cons x x))
 977                         (font-family-list))
 978               ;; Only one font on TTYs.
 979               (list (cons "default" "default"))))
 980            (:foundry
 981             (list nil))
 982            (:width
 983             (mapcar #'(lambda (x) (cons (symbol-name (aref x 1)) (aref x 1)))
 984                     font-width-table))
 985            (:weight
 986             (mapcar #'(lambda (x) (cons (symbol-name (aref x 1)) (aref x 1)))
 987                     font-weight-table))
 988            (:slant
 989             (mapcar #'(lambda (x) (cons (symbol-name (aref x 1)) (aref x 1)))
 990                     font-slant-table))
 991            (:inverse-video
 992             (mapcar #'(lambda (x) (cons (symbol-name x) x))
 993                     (internal-lisp-face-attribute-values attribute)))
 994            ((:underline :overline :strike-through :box)
 995             (if (window-system frame)
 996                 (nconc (mapcar #'(lambda (x) (cons (symbol-name x) x))
 997                                (internal-lisp-face-attribute-values attribute))
 998                        (mapcar #'(lambda (c) (cons c c))
 999                                (defined-colors frame)))
1000               (mapcar #'(lambda (x) (cons (symbol-name x) x))
1001                       (internal-lisp-face-attribute-values attribute))))
1002            ((:foreground :background)
1003             (mapcar #'(lambda (c) (cons c c))
1004                     (defined-colors frame)))
1005            ((:height)
1006             'integerp)
1007            (:stipple
1008             (and (memq (window-system frame) '(x ns)) ; No stipple on w32
1009                  (mapcar #'list
1010                          (apply #'nconc
1011                                 (mapcar (lambda (dir)
1012                                           (and (file-readable-p dir)
1013                                                (file-directory-p dir)
1014                                                (directory-files dir)))
1015                                         x-bitmap-file-path)))))
1016            (:inherit
1017             (cons '("none" . nil)
1018                   (mapcar #'(lambda (c) (cons (symbol-name c) c))
1019                           (face-list))))
1020            (t
1021             (error "Internal error")))))
1022     (if (and (listp valid) (not (memq attribute '(:inherit))))
1023         (nconc (list (cons "unspecified" 'unspecified)) valid)
1024       valid)))
1025
1026
1027 (defconst face-attribute-name-alist
1028   '((:family . "font family")
1029     (:foundry . "font foundry")
1030     (:width . "character set width")
1031     (:height . "height in 1/10 pt")
1032     (:weight . "weight")
1033     (:slant . "slant")
1034     (:underline . "underline")
1035     (:overline . "overline")
1036     (:strike-through . "strike-through")
1037     (:box . "box")
1038     (:inverse-video . "inverse-video display")
1039     (:foreground . "foreground color")
1040     (:background . "background color")
1041     (:stipple . "background stipple")
1042     (:inherit . "inheritance"))
1043   "An alist of descriptive names for face attributes.
1044 Each element has the form (ATTRIBUTE-NAME . DESCRIPTION) where
1045 ATTRIBUTE-NAME is a face attribute name (a keyword symbol), and
1046 DESCRIPTION is a descriptive name for ATTRIBUTE-NAME.")
1047
1048
1049 (defun face-descriptive-attribute-name (attribute)
1050   "Return a descriptive name for ATTRIBUTE."
1051   (cdr (assq attribute face-attribute-name-alist)))
1052
1053
1054 (defun face-read-string (face default name &optional completion-alist)
1055   "Interactively read a face attribute string value.
1056 FACE is the face whose attribute is read.  If non-nil, DEFAULT is the
1057 default string to return if no new value is entered.  NAME is a
1058 descriptive name of the attribute for prompting.  COMPLETION-ALIST is an
1059 alist of valid values, if non-nil.
1060
1061 Entering nothing accepts the default string DEFAULT.
1062 Value is the new attribute value."
1063   ;; Capitalize NAME (we don't use `capitalize' because that capitalizes
1064   ;; each word in a string separately).
1065   (setq name (concat (upcase (substring name 0 1)) (substring name 1)))
1066   (let* ((completion-ignore-case t)
1067          (value (completing-read
1068                  (if default
1069                      (format "%s for face `%s' (default %s): "
1070                              name face default)
1071                    (format "%s for face `%s': " name face))
1072                  completion-alist nil nil nil nil default)))
1073     (if (equal value "") default value)))
1074
1075
1076 (defun face-read-integer (face default name)
1077   "Interactively read an integer face attribute value.
1078 FACE is the face whose attribute is read.  DEFAULT is the default
1079 value to return if no new value is entered.  NAME is a descriptive
1080 name of the attribute for prompting.  Value is the new attribute value."
1081   (let ((new-value
1082          (face-read-string face
1083                            (format "%s" default)
1084                            name
1085                            (list (cons "unspecified" 'unspecified)))))
1086     (cond ((equal new-value "unspecified")
1087            'unspecified)
1088           ((member new-value '("unspecified-fg" "unspecified-bg"))
1089            new-value)
1090           (t
1091            (string-to-number new-value)))))
1092
1093
1094 (defun read-face-attribute (face attribute &optional frame)
1095   "Interactively read a new value for FACE's ATTRIBUTE.
1096 Optional argument FRAME nil or unspecified means read an attribute value
1097 of a global face.  Value is the new attribute value."
1098   (let* ((old-value (face-attribute face attribute frame))
1099          (attribute-name (face-descriptive-attribute-name attribute))
1100          (valid (face-valid-attribute-values attribute frame))
1101          new-value)
1102     ;; Represent complex attribute values as strings by printing them
1103     ;; out.  Stipple can be a vector; (WIDTH HEIGHT DATA).  Box can be
1104     ;; a list `(:width WIDTH :color COLOR)' or `(:width WIDTH :shadow
1105     ;; SHADOW)'.
1106     (when (and (or (eq attribute :stipple)
1107                    (eq attribute :box))
1108                (or (consp old-value)
1109                    (vectorp old-value)))
1110       (setq old-value (prin1-to-string old-value)))
1111     (cond ((listp valid)
1112            (let ((default
1113                    (or (car (rassoc old-value valid))
1114                        (format "%s" old-value))))
1115              (setq new-value
1116                    (face-read-string face default attribute-name valid))
1117              (if (equal new-value default)
1118                  ;; Nothing changed, so don't bother with all the stuff
1119                  ;; below.  In particular, this avoids a non-tty color
1120                  ;; from being canonicalized for a tty when the user
1121                  ;; just uses the default.
1122                  (setq new-value old-value)
1123                ;; Terminal frames can support colors that don't appear
1124                ;; explicitly in VALID, using color approximation code
1125                ;; in tty-colors.el.
1126                (when (and (memq attribute '(:foreground :background))
1127                           (not (memq (window-system frame) '(x w32 ns)))
1128                           (not (member new-value
1129                                        '("unspecified"
1130                                          "unspecified-fg" "unspecified-bg"))))
1131                  (setq new-value (car (tty-color-desc new-value frame))))
1132                (when (assoc new-value valid)
1133                  (setq new-value (cdr (assoc new-value valid)))))))
1134           ((eq valid 'integerp)
1135            (setq new-value (face-read-integer face old-value attribute-name)))
1136           (t (error "Internal error")))
1137     ;; Convert stipple and box value text we read back to a list or
1138     ;; vector if it looks like one.  This makes the assumption that a
1139     ;; pixmap file name won't start with an open-paren.
1140     (when (and (or (eq attribute :stipple)
1141                    (eq attribute :box))
1142                (stringp new-value)
1143                (string-match "^[[(]" new-value))
1144       (setq new-value (read new-value)))
1145     new-value))
1146
1147 (declare-function fontset-list "fontset.c" ())
1148 (declare-function x-list-fonts "xfaces.c"
1149                   (pattern &optional face frame maximum width))
1150
1151 (defun read-face-font (face &optional frame)
1152   "Read the name of a font for FACE on FRAME.
1153 If optional argument FRAME is nil or omitted, use the selected frame."
1154   (let ((completion-ignore-case t))
1155     (completing-read (format "Set font attributes of face `%s' from font: " face)
1156                      (append (fontset-list) (x-list-fonts "*" nil frame)))))
1157
1158
1159 (defun read-all-face-attributes (face &optional frame)
1160   "Interactively read all attributes for FACE.
1161 If optional argument FRAME is nil or omitted, use the selected frame.
1162 Value is a property list of attribute names and new values."
1163   (let (result)
1164     (dolist (attribute face-attribute-name-alist result)
1165       (setq result (cons (car attribute)
1166                          (cons (read-face-attribute face (car attribute) frame)
1167                                result))))))
1168
1169 (defun modify-face (&optional face foreground background stipple
1170                               bold-p italic-p underline inverse-p frame)
1171   "Modify attributes of faces interactively.
1172 If optional argument FRAME is nil or omitted, modify the face used
1173 for newly created frame, i.e. the global face.
1174 For non-interactive use, `set-face-attribute' is preferred.
1175 When called from Lisp, if FACE is nil, all arguments but FRAME are ignored
1176 and the face and its settings are obtained by querying the user."
1177   (interactive)
1178   (if face
1179       (set-face-attribute face frame
1180                           :foreground (or foreground 'unspecified)
1181                           :background (or background 'unspecified)
1182                           :stipple stipple
1183                           :bold bold-p
1184                           :italic italic-p
1185                           :underline underline
1186                           :inverse-video inverse-p)
1187     (setq face (read-face-name "Modify face"))
1188     (apply #'set-face-attribute face frame
1189            (read-all-face-attributes face frame))))
1190
1191 (defun read-face-and-attribute (attribute &optional frame)
1192   "Read face name and face attribute value.
1193 ATTRIBUTE is the attribute whose new value is read.
1194 FRAME nil or unspecified means read attribute value of global face.
1195 Value is a list (FACE NEW-VALUE) where FACE is the face read
1196 \(a symbol), and NEW-VALUE is value read."
1197   (cond ((eq attribute :font)
1198          (let* ((prompt "Set font-related attributes of face")
1199                 (face (read-face-name prompt))
1200                 (font (read-face-font face frame)))
1201            (list face font)))
1202         (t
1203          (let* ((attribute-name (face-descriptive-attribute-name attribute))
1204                 (prompt (format "Set %s of face" attribute-name))
1205                 (face (read-face-name prompt))
1206                 (new-value (read-face-attribute face attribute frame)))
1207            (list face new-value)))))
1208
1209
1210 \f
1211 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1212 ;;; Listing faces.
1213 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1214
1215 (defconst list-faces-sample-text
1216   "abcdefghijklmnopqrstuvwxyz ABCDEFGHIJKLMNOPQRSTUVWXYZ"
1217   "*Text string to display as the sample text for `list-faces-display'.")
1218
1219
1220 ;; The name list-faces would be more consistent, but let's avoid a
1221 ;; conflict with Lucid, which uses that name differently.
1222
1223 (defvar help-xref-stack)
1224 (defun list-faces-display (&optional regexp)
1225   "List all faces, using the same sample text in each.
1226 The sample text is a string that comes from the variable
1227 `list-faces-sample-text'.
1228
1229 If REGEXP is non-nil, list only those faces with names matching
1230 this regular expression.  When called interactively with a prefix
1231 arg, prompt for a regular expression."
1232   (interactive (list (and current-prefix-arg
1233                           (read-regexp "List faces matching regexp"))))
1234   (let ((all-faces (zerop (length regexp)))
1235         (frame (selected-frame))
1236         (max-length 0)
1237         faces line-format
1238         disp-frame window face-name)
1239     ;; We filter and take the max length in one pass
1240     (setq faces
1241           (delq nil
1242                 (mapcar (lambda (f)
1243                           (let ((s (symbol-name f)))
1244                             (when (or all-faces (string-match regexp s))
1245                               (setq max-length (max (length s) max-length))
1246                               f)))
1247                         (sort (face-list) #'string-lessp))))
1248     (unless faces
1249       (error "No faces matching \"%s\"" regexp))
1250     (setq max-length (1+ max-length)
1251           line-format (format "%%-%ds" max-length))
1252     (with-help-window "*Faces*"
1253       (with-current-buffer standard-output
1254         (setq truncate-lines t)
1255         (insert
1256          (substitute-command-keys
1257           (concat
1258            "Use "
1259            (if (display-mouse-p) "\\[help-follow-mouse] or ")
1260            "\\[help-follow] on a face name to customize it\n"
1261            "or on its sample text for a description of the face.\n\n")))
1262         (setq help-xref-stack nil)
1263         (dolist (face faces)
1264           (setq face-name (symbol-name face))
1265           (insert (format line-format face-name))
1266           ;; Hyperlink to a customization buffer for the face.  Using
1267           ;; the help xref mechanism may not be the best way.
1268           (save-excursion
1269             (save-match-data
1270               (search-backward face-name)
1271               (setq help-xref-stack-item `(list-faces-display ,regexp))
1272               (help-xref-button 0 'help-customize-face face)))
1273           (let ((beg (point))
1274                 (line-beg (line-beginning-position)))
1275             (insert list-faces-sample-text)
1276             ;; Hyperlink to a help buffer for the face.
1277             (save-excursion
1278               (save-match-data
1279                 (search-backward list-faces-sample-text)
1280                 (help-xref-button 0 'help-face face)))
1281             (insert "\n")
1282             (put-text-property beg (1- (point)) 'face face)
1283             ;; Make all face commands default to the proper face
1284             ;; anywhere in the line.
1285             (put-text-property line-beg (1- (point)) 'read-face-name face)
1286             ;; If the sample text has multiple lines, line up all of them.
1287             (goto-char beg)
1288             (forward-line 1)
1289             (while (not (eobp))
1290               (insert-char ?\s max-length)
1291               (forward-line 1))))
1292         (goto-char (point-min))))
1293     ;; If the *Faces* buffer appears in a different frame,
1294     ;; copy all the face definitions from FRAME,
1295     ;; so that the display will reflect the frame that was selected.
1296     (setq window (get-buffer-window (get-buffer "*Faces*") t))
1297     (setq disp-frame (if window (window-frame window)
1298                        (car (frame-list))))
1299     (or (eq frame disp-frame)
1300         (let ((faces (face-list)))
1301           (while faces
1302             (copy-face (car faces) (car faces) frame disp-frame)
1303             (setq faces (cdr faces)))))))
1304
1305
1306 (defun describe-face (face &optional frame)
1307   "Display the properties of face FACE on FRAME.
1308 Interactively, FACE defaults to the faces of the character after point
1309 and FRAME defaults to the selected frame.
1310
1311 If the optional argument FRAME is given, report on face FACE in that frame.
1312 If FRAME is t, report on the defaults for face FACE (for new frames).
1313 If FRAME is omitted or nil, use the selected frame."
1314   (interactive (list (read-face-name "Describe face" 'default t)))
1315   (let* ((attrs '((:family . "Family")
1316                   (:foundry . "Foundry")
1317                   (:width . "Width")
1318                   (:height . "Height")
1319                   (:weight . "Weight")
1320                   (:slant . "Slant")
1321                   (:foreground . "Foreground")
1322                   (:background . "Background")
1323                   (:underline . "Underline")
1324                   (:overline . "Overline")
1325                   (:strike-through . "Strike-through")
1326                   (:box . "Box")
1327                   (:inverse-video . "Inverse")
1328                   (:stipple . "Stipple")
1329                   (:font . "Font")
1330                   (:fontset . "Fontset")
1331                   (:inherit . "Inherit")))
1332         (max-width (apply #'max (mapcar #'(lambda (x) (length (cdr x)))
1333                                         attrs))))
1334     (help-setup-xref (list #'describe-face face)
1335                      (called-interactively-p 'interactive))
1336     (unless face
1337       (setq face 'default))
1338     (if (not (listp face))
1339         (setq face (list face)))
1340     (with-help-window (help-buffer)
1341       (with-current-buffer standard-output
1342         (dolist (f face)
1343           (if (stringp f) (setq f (intern f)))
1344           ;; We may get called for anonymous faces (i.e., faces
1345           ;; expressed using prop-value plists).  Those can't be
1346           ;; usefully customized, so ignore them.
1347           (when (symbolp f)
1348             (insert "Face: " (symbol-name f))
1349             (if (not (facep f))
1350                 (insert "   undefined face.\n")
1351               (let ((customize-label "customize this face")
1352                     file-name)
1353                 (insert (concat " (" (propertize "sample" 'font-lock-face f) ")"))
1354                 (princ (concat " (" customize-label ")\n"))
1355                 ;; FIXME not sure how much of this belongs here, and
1356                 ;; how much in `face-documentation'.  The latter is
1357                 ;; not used much, but needs to return nil for
1358                 ;; undocumented faces.
1359                 (let ((alias (get f 'face-alias))
1360                       (face f)
1361                       obsolete)
1362                   (when alias
1363                     (setq face alias)
1364                     (insert
1365                      (format "\n  %s is an alias for the face `%s'.\n%s"
1366                              f alias
1367                              (if (setq obsolete (get f 'obsolete-face))
1368                                  (format "  This face is obsolete%s; use `%s' instead.\n"
1369                                          (if (stringp obsolete)
1370                                              (format " since %s" obsolete)
1371                                            "")
1372                                          alias)
1373                                ""))))
1374                   (insert "\nDocumentation:\n"
1375                           (or (face-documentation face)
1376                               "Not documented as a face.")
1377                           "\n\n"))
1378                 (with-current-buffer standard-output
1379                   (save-excursion
1380                     (re-search-backward
1381                      (concat "\\(" customize-label "\\)") nil t)
1382                     (help-xref-button 1 'help-customize-face f)))
1383                 (setq file-name (find-lisp-object-file-name f 'defface))
1384                 (when file-name
1385                   (princ "Defined in `")
1386                   (princ (file-name-nondirectory file-name))
1387                   (princ "'")
1388                   ;; Make a hyperlink to the library.
1389                   (save-excursion
1390                     (re-search-backward "`\\([^`']+\\)'" nil t)
1391                     (help-xref-button 1 'help-face-def f file-name))
1392                   (princ ".")
1393                   (terpri)
1394                   (terpri))
1395                 (dolist (a attrs)
1396                   (let ((attr (face-attribute f (car a) frame)))
1397                     (insert (make-string (- max-width (length (cdr a))) ?\s)
1398                             (cdr a) ": " (format "%s" attr))
1399                     (if (and (eq (car a) :inherit)
1400                              (not (eq attr 'unspecified)))
1401                         ;; Make a hyperlink to the parent face.
1402                         (save-excursion
1403                           (re-search-backward ": \\([^:]+\\)" nil t)
1404                           (help-xref-button 1 'help-face attr)))
1405                     (insert "\n")))))
1406             (terpri)))))))
1407
1408 \f
1409 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1410 ;;; Face specifications (defface).
1411 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1412
1413 ;; Parameter FRAME Is kept for call compatibility to with previous
1414 ;; face implementation.
1415
1416 (defun face-attr-construct (face &optional frame)
1417   "Return a `defface'-style attribute list for FACE on FRAME.
1418 Value is a property list of pairs ATTRIBUTE VALUE for all specified
1419 face attributes of FACE where ATTRIBUTE is the attribute name and
1420 VALUE is the specified value of that attribute."
1421   (let (result)
1422     (dolist (entry face-attribute-name-alist result)
1423       (let* ((attribute (car entry))
1424              (value (face-attribute face attribute)))
1425         (unless (eq value 'unspecified)
1426           (setq result (nconc (list attribute value) result)))))))
1427
1428
1429 (defun face-spec-set-match-display (display frame)
1430   "Non-nil if DISPLAY matches FRAME.
1431 DISPLAY is part of a spec such as can be used in `defface'.
1432 If FRAME is nil, the current FRAME is used."
1433   (let* ((conjuncts display)
1434          conjunct req options
1435          ;; t means we have succeeded against all the conjuncts in
1436          ;; DISPLAY that have been tested so far.
1437          (match t))
1438     (if (eq conjuncts t)
1439         (setq conjuncts nil))
1440     (while (and conjuncts match)
1441       (setq conjunct (car conjuncts)
1442             conjuncts (cdr conjuncts)
1443             req (car conjunct)
1444             options (cdr conjunct)
1445             match (cond ((eq req 'type)
1446                          (or (memq (window-system frame) options)
1447                              ;; FIXME: This should be revisited to use
1448                              ;; display-graphic-p, provided that the
1449                              ;; color selection depends on the number
1450                              ;; of supported colors, and all defface's
1451                              ;; are changed to look at number of colors
1452                              ;; instead of (type graphic) etc.
1453                              (and (null (window-system frame))
1454                                   (memq 'tty options))
1455                              (and (memq 'motif options)
1456                                   (featurep 'motif))
1457                              (and (memq 'gtk options)
1458                                   (featurep 'gtk))
1459                              (and (memq 'lucid options)
1460                                   (featurep 'x-toolkit)
1461                                   (not (featurep 'motif))
1462                                   (not (featurep 'gtk)))
1463                              (and (memq 'x-toolkit options)
1464                                   (featurep 'x-toolkit))))
1465                         ((eq req 'min-colors)
1466                          (>= (display-color-cells frame) (car options)))
1467                         ((eq req 'class)
1468                          (memq (frame-parameter frame 'display-type) options))
1469                         ((eq req 'background)
1470                          (memq (frame-parameter frame 'background-mode)
1471                                options))
1472                         ((eq req 'supports)
1473                          (display-supports-face-attributes-p options frame))
1474                         (t (error "Unknown req `%S' with options `%S'"
1475                                   req options)))))
1476     match))
1477
1478
1479 (defun face-spec-choose (spec &optional frame)
1480   "Choose the proper attributes for FRAME, out of SPEC.
1481 If SPEC is nil, return nil."
1482   (unless frame
1483     (setq frame (selected-frame)))
1484   (let ((tail spec)
1485         result defaults)
1486     (while tail
1487       (let* ((entry (pop tail))
1488              (display (car entry))
1489              (attrs (cdr entry))
1490              thisval)
1491         ;; Get the attributes as actually specified by this alternative.
1492         (setq thisval
1493               (if (null (cdr attrs)) ;; was (listp (car attrs))
1494                   ;; Old-style entry, the attribute list is the
1495                   ;; first element.
1496                   (car attrs)
1497                 attrs))
1498
1499         ;; If the condition is `default', that sets the default
1500         ;; for following conditions.
1501         (if (eq display 'default)
1502             (setq defaults thisval)
1503           ;; Otherwise, if it matches, use it.
1504           (when (face-spec-set-match-display display frame)
1505             (setq result thisval)
1506             (setq tail nil)))))
1507     (if defaults (append result defaults) result)))
1508
1509
1510 (defun face-spec-reset-face (face &optional frame)
1511   "Reset all attributes of FACE on FRAME to unspecified."
1512   (let (reset-args)
1513     (dolist (attr-and-name face-attribute-name-alist)
1514       (push 'unspecified reset-args)
1515       (push (car attr-and-name) reset-args))
1516     (apply 'set-face-attribute face frame reset-args)))
1517
1518 (defun face-spec-set (face spec &optional for-defface)
1519   "Set FACE's face spec, which controls its appearance, to SPEC.
1520 If FOR-DEFFACE is t, set the base spec, the one that `defface'
1521   and Custom set.  (In that case, the caller must put it in the
1522   appropriate property, because that depends on the caller.)
1523 If FOR-DEFFACE is nil, set the overriding spec (and store it
1524   in the `face-override-spec' property of FACE).
1525
1526 The appearance of FACE is controlled by the base spec,
1527 by any custom theme specs on top of that, and by the
1528 overriding spec on top of all the rest.
1529
1530 FOR-DEFFACE can also be a frame, in which case we set the
1531 frame-specific attributes of FACE for that frame based on SPEC.
1532 That usage is deprecated.
1533
1534 See `defface' for information about the format and meaning of SPEC."
1535   (if (framep for-defface)
1536       ;; Handle the deprecated case where third arg is a frame.
1537       (face-spec-set-2 face for-defface spec)
1538     (if for-defface
1539         ;; When we reset the face based on its custom spec, then it is
1540         ;; unmodified as far as Custom is concerned.
1541         (put (or (get face 'face-alias) face) 'face-modified nil)
1542       ;; When we change a face based on a spec from outside custom,
1543       ;; record it for future frames.
1544       (put (or (get face 'face-alias) face) 'face-override-spec spec))
1545     ;; Reset each frame according to the rules implied by all its specs.
1546     (dolist (frame (frame-list))
1547       (face-spec-recalc face frame))))
1548
1549 (defun face-spec-recalc (face frame)
1550   "Reset the face attributes of FACE on FRAME according to its specs.
1551 This applies the defface/custom spec first, then the custom theme specs,
1552 then the override spec."
1553   (face-spec-reset-face face frame)
1554   (let ((face-sym (or (get face 'face-alias) face)))
1555     (or (get face 'customized-face)
1556         (get face 'saved-face)
1557         (face-spec-set-2 face frame (face-default-spec face)))
1558     (let ((theme-faces (reverse (get face-sym 'theme-face))))
1559       (dolist (spec theme-faces)
1560         (face-spec-set-2 face frame (cadr spec))))
1561     (face-spec-set-2 face frame (get face-sym 'face-override-spec))))
1562
1563 (defun face-spec-set-2 (face frame spec)
1564   "Set the face attributes of FACE on FRAME according to SPEC."
1565   (let* ((spec (face-spec-choose spec frame))
1566          attrs)
1567     (while spec
1568       (when (assq (car spec) face-x-resources)
1569         (push (car spec) attrs)
1570         (push (cadr spec) attrs))
1571       (setq spec (cddr spec)))
1572     (apply 'set-face-attribute face frame (nreverse attrs))))
1573
1574 (defun face-attr-match-p (face attrs &optional frame)
1575   "Return t if attributes of FACE match values in plist ATTRS.
1576 Optional parameter FRAME is the frame whose definition of FACE
1577 is used.  If nil or omitted, use the selected frame."
1578   (unless frame
1579     (setq frame (selected-frame)))
1580   (let* ((list face-attribute-name-alist)
1581          (match t)
1582          (bold (and (plist-member attrs :bold)
1583                     (not (plist-member attrs :weight))))
1584          (italic (and (plist-member attrs :italic)
1585                       (not (plist-member attrs :slant))))
1586          (plist (if (or bold italic)
1587                     (copy-sequence attrs)
1588                   attrs)))
1589     ;; Handle the Emacs 20 :bold and :italic properties.
1590     (if bold
1591         (plist-put plist :weight (if bold 'bold 'normal)))
1592     (if italic
1593         (plist-put plist :slant (if italic 'italic 'normal)))
1594     (while (and match list)
1595       (let* ((attr (caar list))
1596              (specified-value
1597               (if (plist-member plist attr)
1598                   (plist-get plist attr)
1599                 'unspecified))
1600              (value-now (face-attribute face attr frame)))
1601         (setq match (equal specified-value value-now))
1602         (setq list (cdr list))))
1603     match))
1604
1605 (defsubst face-spec-match-p (face spec &optional frame)
1606   "Return t if FACE, on FRAME, matches what SPEC says it should look like."
1607   (face-attr-match-p face (face-spec-choose spec frame) frame))
1608
1609 (defsubst face-default-spec (face)
1610   "Return the default face-spec for FACE, ignoring any user customization.
1611 If there is no default for FACE, return nil."
1612   (get face 'face-defface-spec))
1613
1614 (defsubst face-user-default-spec (face)
1615   "Return the user's customized face-spec for FACE, or the default if none.
1616 If there is neither a user setting nor a default for FACE, return nil."
1617   (or (get face 'customized-face)
1618       (get face 'saved-face)
1619       (face-default-spec face)))
1620
1621 \f
1622 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1623 ;;; Frame-type independent color support.
1624 ;;; We keep the old x-* names as aliases for back-compatibility.
1625 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1626
1627 (defun defined-colors (&optional frame)
1628   "Return a list of colors supported for a particular frame.
1629 The argument FRAME specifies which frame to try.
1630 The value may be different for frames on different display types.
1631 If FRAME doesn't support colors, the value is nil.
1632 If FRAME is nil, that stands for the selected frame."
1633   (if (memq (framep (or frame (selected-frame))) '(x w32 ns))
1634       (xw-defined-colors frame)
1635     (mapcar 'car (tty-color-alist frame))))
1636 (defalias 'x-defined-colors 'defined-colors)
1637
1638 (declare-function xw-color-defined-p "xfns.c" (color &optional frame))
1639
1640 (defun color-defined-p (color &optional frame)
1641   "Return non-nil if color COLOR is supported on frame FRAME.
1642 If FRAME is omitted or nil, use the selected frame.
1643 If COLOR is the symbol `unspecified' or one of the strings
1644 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1645   (if (member color '(unspecified "unspecified-bg" "unspecified-fg"))
1646       nil
1647     (if (member (framep (or frame (selected-frame))) '(x w32 ns))
1648         (xw-color-defined-p color frame)
1649       (numberp (tty-color-translate color frame)))))
1650 (defalias 'x-color-defined-p 'color-defined-p)
1651
1652 (declare-function xw-color-values "xfns.c" (color &optional frame))
1653
1654 (defun color-values (color &optional frame)
1655   "Return a description of the color named COLOR on frame FRAME.
1656 COLOR should be a string naming a color (e.g. \"white\"), or a
1657 string specifying a color's RGB components (e.g. \"#ff12ec\").
1658
1659 Return a list of three integers, (RED GREEN BLUE), each between 0
1660 and either 65280 or 65535 (the maximum depends on the system).
1661 Use `color-name-to-rgb' if you want RGB floating-point values
1662 normalized to 1.0.
1663
1664 If FRAME is omitted or nil, use the selected frame.
1665 If FRAME cannot display COLOR, the value is nil.
1666
1667 COLOR can also be the symbol `unspecified' or one of the strings
1668 \"unspecified-fg\" or \"unspecified-bg\", in which case the
1669 return value is nil."
1670   (cond
1671    ((member color '(unspecified "unspecified-fg" "unspecified-bg"))
1672     nil)
1673    ((memq (framep (or frame (selected-frame))) '(x w32 ns))
1674     (xw-color-values color frame))
1675    (t
1676     (tty-color-values color frame))))
1677
1678 (defalias 'x-color-values 'color-values)
1679
1680 (declare-function xw-display-color-p "xfns.c" (&optional terminal))
1681
1682 (defun display-color-p (&optional display)
1683   "Return t if DISPLAY supports color.
1684 The optional argument DISPLAY specifies which display to ask about.
1685 DISPLAY should be either a frame or a display name (a string).
1686 If omitted or nil, that stands for the selected frame's display."
1687   (if (memq (framep-on-display display) '(x w32 ns))
1688       (xw-display-color-p display)
1689     (tty-display-color-p display)))
1690 (defalias 'x-display-color-p 'display-color-p)
1691
1692 (declare-function x-display-grayscale-p "xfns.c" (&optional terminal))
1693
1694 (defun display-grayscale-p (&optional display)
1695   "Return non-nil if frames on DISPLAY can display shades of gray."
1696   (let ((frame-type (framep-on-display display)))
1697     (cond
1698      ((memq frame-type '(x w32 ns))
1699       (x-display-grayscale-p display))
1700      (t
1701       (> (tty-color-gray-shades display) 2)))))
1702
1703 (defun read-color (&optional prompt convert-to-RGB allow-empty-name msg)
1704   "Read a color name or RGB triplet of the form \"#RRRRGGGGBBBB\".
1705 Completion is available for color names, but not for RGB triplets.
1706
1707 RGB triplets have the form #XXXXXXXXXXXX, where each X is a hex
1708 digit.  The number of Xs must be a multiple of 3, with the same
1709 number of Xs for each of red, green, and blue.  The order is red,
1710 green, blue.
1711
1712 In addition to standard color names and RGB hex values, the
1713 following are available as color candidates.  In each case, the
1714 corresponding color is used.
1715
1716  * `foreground at point'   - foreground under the cursor
1717  * `background at point'   - background under the cursor
1718
1719 Optional arg PROMPT is the prompt; if nil, use a default prompt.
1720
1721 Interactively, or with optional arg CONVERT-TO-RGB-P non-nil,
1722 convert an input color name to an RGB hex string.  Return the RGB
1723 hex string.
1724
1725 If optional arg ALLOW-EMPTY-NAME is non-nil, the user is allowed
1726 to enter an empty color name (the empty string).
1727
1728 Interactively, or with optional arg MSG non-nil, print the
1729 resulting color name in the echo area."
1730   (interactive "i\np\ni\np")    ; Always convert to RGB interactively.
1731   (let* ((completion-ignore-case t)
1732          (colors (or facemenu-color-alist
1733                      (append '("foreground at point" "background at point")
1734                              (if allow-empty-name '(""))
1735                              (defined-colors))))
1736          (color (completing-read
1737                  (or prompt "Color (name or #RGB triplet): ")
1738                  ;; Completing function for reading colors, accepting
1739                  ;; both color names and RGB triplets.
1740                  (lambda (string pred flag)
1741                    (cond
1742                     ((null flag) ; Try completion.
1743                      (or (try-completion string colors pred)
1744                          (if (color-defined-p string)
1745                              string)))
1746                     ((eq flag t) ; List all completions.
1747                      (or (all-completions string colors pred)
1748                          (if (color-defined-p string)
1749                              (list string))))
1750                     ((eq flag 'lambda) ; Test completion.
1751                      (or (memq string colors)
1752                          (color-defined-p string)))))
1753                  nil t))
1754          hex-string)
1755
1756     ;; Process named colors.
1757     (when (member color colors)
1758       (cond ((string-equal color "foreground at point")
1759              (setq color (foreground-color-at-point)))
1760             ((string-equal color "background at point")
1761              (setq color (background-color-at-point))))
1762       (when (and convert-to-RGB
1763                  (not (string-equal color "")))
1764         (let ((components (x-color-values color)))
1765           (unless (string-match "^#\\([a-fA-F0-9][a-fA-F0-9][a-fA-F0-9]\\)+$" color)
1766             (setq color (format "#%04X%04X%04X"
1767                                 (logand 65535 (nth 0 components))
1768                                 (logand 65535 (nth 1 components))
1769                                 (logand 65535 (nth 2 components))))))))
1770     (when msg (message "Color: `%s'" color))
1771     color))
1772
1773
1774 (defun face-at-point ()
1775   "Return the face of the character after point.
1776 If it has more than one face, return the first one.
1777 Return nil if it has no specified face."
1778   (let* ((faceprop (or (get-char-property (point) 'read-face-name)
1779                        (get-char-property (point) 'face)
1780                        'default))
1781          (face (cond ((symbolp faceprop) faceprop)
1782                      ;; List of faces (don't treat an attribute spec).
1783                      ;; Just use the first face.
1784                      ((and (consp faceprop) (not (keywordp (car faceprop)))
1785                            (not (memq (car faceprop)
1786                                       '(foreground-color background-color))))
1787                       (car faceprop))
1788                      (t nil))))         ; Invalid face value.
1789     (if (facep face) face nil)))
1790
1791 (defun foreground-color-at-point ()
1792   "Return the foreground color of the character after point."
1793   ;; `face-at-point' alone is not sufficient.  It only gets named faces.
1794   ;; Need also pick up any face properties that are not associated with named faces.
1795   (let ((face (or (face-at-point)
1796                   (get-char-property (point) 'read-face-name)
1797                   (get-char-property (point) 'face))))
1798     (cond ((and face (symbolp face))
1799            (let ((value (face-foreground face nil 'default)))
1800              (if (member value '("unspecified-fg" "unspecified-bg"))
1801                  nil
1802                value)))
1803           ((consp face)
1804            (cond ((memq 'foreground-color face) (cdr (memq 'foreground-color face)))
1805                  ((memq ':foreground face) (cadr (memq ':foreground face)))))
1806           (t nil))))                    ; Invalid face value.
1807
1808 (defun background-color-at-point ()
1809   "Return the background color of the character after point."
1810   ;; `face-at-point' alone is not sufficient.  It only gets named faces.
1811   ;; Need also pick up any face properties that are not associated with named faces.
1812   (let ((face (or (face-at-point)
1813                   (get-char-property (point) 'read-face-name)
1814                   (get-char-property (point) 'face))))
1815     (cond ((and face (symbolp face))
1816            (let ((value (face-background face nil 'default)))
1817              (if (member value '("unspecified-fg" "unspecified-bg"))
1818                  nil
1819                value)))
1820           ((consp face)
1821            (cond ((memq 'background-color face) (cdr (memq 'background-color face)))
1822                  ((memq ':background face) (cadr (memq ':background face)))))
1823           (t nil))))                    ; Invalid face value.
1824 \f
1825 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1826 ;;; Background mode.
1827 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1828
1829 (defcustom frame-background-mode nil
1830   "The brightness of the background.
1831 Set this to the symbol `dark' if your background color is dark,
1832 `light' if your background is light, or nil (automatic by default)
1833 if you want Emacs to examine the brightness for you.  Don't set this
1834 variable with `setq'; this won't have the expected effect."
1835   :group 'faces
1836   :set #'(lambda (var value)
1837            (set-default var value)
1838            (mapc 'frame-set-background-mode (frame-list)))
1839   :initialize 'custom-initialize-changed
1840   :type '(choice (const dark)
1841                  (const light)
1842                  (const :tag "automatic" nil)))
1843
1844
1845 (declare-function x-get-resource "frame.c"
1846                   (attribute class &optional component subclass))
1847
1848 (defvar inhibit-frame-set-background-mode nil)
1849
1850 (defun frame-set-background-mode (frame &optional keep-face-specs)
1851   "Set up display-dependent faces on FRAME.
1852 Display-dependent faces are those which have different definitions
1853 according to the `background-mode' and `display-type' frame parameters.
1854
1855 If optional arg KEEP-FACE-SPECS is non-nil, don't recalculate
1856 face specs for the new background mode."
1857   (unless inhibit-frame-set-background-mode
1858     (let* ((bg-resource
1859             (and (window-system frame)
1860                  (x-get-resource "backgroundMode" "BackgroundMode")))
1861            (bg-color (frame-parameter frame 'background-color))
1862            (terminal-bg-mode (terminal-parameter frame 'background-mode))
1863            (tty-type (tty-type frame))
1864            (default-bg-mode
1865              (if (or (window-system frame)
1866                      (and tty-type
1867                           (string-match "^\\(xterm\\|\\rxvt\\|dtterm\\|eterm\\)"
1868                                         tty-type)))
1869                  'light
1870                'dark))
1871            (non-default-bg-mode (if (eq default-bg-mode 'light) 'dark 'light))
1872            (bg-mode
1873             (cond (frame-background-mode)
1874                   (bg-resource (intern (downcase bg-resource)))
1875                   (terminal-bg-mode)
1876                   ((equal bg-color "unspecified-fg") ; inverted colors
1877                    non-default-bg-mode)
1878                   ((not (color-values bg-color frame))
1879                    default-bg-mode)
1880                   ((>= (apply '+ (color-values bg-color frame))
1881                        ;; Just looking at the screen, colors whose
1882                        ;; values add up to .6 of the white total
1883                        ;; still look dark to me.
1884                        (* (apply '+ (color-values "white" frame)) .6))
1885                    'light)
1886                   (t 'dark)))
1887            (display-type
1888             (cond ((null (window-system frame))
1889                    (if (tty-display-color-p frame) 'color 'mono))
1890                   ((display-color-p frame)
1891                    'color)
1892                   ((x-display-grayscale-p frame)
1893                    'grayscale)
1894                   (t 'mono)))
1895            (old-bg-mode
1896             (frame-parameter frame 'background-mode))
1897            (old-display-type
1898             (frame-parameter frame 'display-type)))
1899
1900       (unless (and (eq bg-mode old-bg-mode) (eq display-type old-display-type))
1901         (let ((locally-modified-faces nil)
1902               ;; Prevent face-spec-recalc from calling this function
1903               ;; again, resulting in a loop (bug#911).
1904               (inhibit-frame-set-background-mode t)
1905               (params (list (cons 'background-mode bg-mode)
1906                             (cons 'display-type display-type))))
1907           (if keep-face-specs
1908               (modify-frame-parameters frame params)
1909             ;; If we are recomputing face specs, first collect a list
1910             ;; of faces that don't match their face-specs.  These are
1911             ;; the faces modified on FRAME, and we avoid changing them
1912             ;; below.  Use a negative list to avoid consing (we assume
1913             ;; most faces are unmodified).
1914             (dolist (face (face-list))
1915               (and (not (get face 'face-override-spec))
1916                    (not (face-spec-match-p face
1917                                            (face-user-default-spec face)
1918                                            (selected-frame)))
1919                    (push face locally-modified-faces)))
1920             ;; Now change to the new frame parameters
1921             (modify-frame-parameters frame params)
1922             ;; For all unmodified named faces, choose face specs
1923             ;; matching the new frame parameters.
1924             (dolist (face (face-list))
1925               (unless (memq face locally-modified-faces)
1926                 (face-spec-recalc face frame)))))))))
1927
1928 \f
1929 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1930 ;;; Frame creation.
1931 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1932
1933 (declare-function x-parse-geometry "frame.c" (string))
1934
1935 (defun x-handle-named-frame-geometry (parameters)
1936   "Add geometry parameters for a named frame to parameter list PARAMETERS.
1937 Value is the new parameter list."
1938   ;; Note that `x-resource-name' has a global meaning.
1939   (let ((x-resource-name (cdr (assq 'name parameters))))
1940     (when x-resource-name
1941       ;; Before checking X resources, we must have an X connection.
1942       (or (window-system)
1943           (x-display-list)
1944           (x-open-connection (or (cdr (assq 'display parameters))
1945                                  x-display-name)))
1946       (let (res-geometry parsed)
1947         (and (setq res-geometry (x-get-resource "geometry" "Geometry"))
1948              (setq parsed (x-parse-geometry res-geometry))
1949              (setq parameters
1950                    (append parameters parsed
1951                            ;; If the resource specifies a position,
1952                            ;; take note of that.
1953                            (if (or (assq 'top parsed) (assq 'left parsed))
1954                                '((user-position . t) (user-size . t)))))))))
1955   parameters)
1956
1957
1958 (defun x-handle-reverse-video (frame parameters)
1959   "Handle the reverse-video frame parameter and X resource.
1960 `x-create-frame' does not handle this one."
1961   (when (cdr (or (assq 'reverse parameters)
1962                  (let ((resource (x-get-resource "reverseVideo"
1963                                                  "ReverseVideo")))
1964                    (if resource
1965                        (cons nil (member (downcase resource)
1966                                          '("on" "true")))))))
1967       (let* ((params (frame-parameters frame))
1968              (bg (cdr (assq 'foreground-color params)))
1969              (fg (cdr (assq 'background-color params))))
1970         (modify-frame-parameters frame
1971                                  (list (cons 'foreground-color fg)
1972                                        (cons 'background-color bg)))
1973         (if (equal bg (cdr (assq 'border-color params)))
1974             (modify-frame-parameters frame
1975                                      (list (cons 'border-color fg))))
1976         (if (equal bg (cdr (assq 'mouse-color params)))
1977             (modify-frame-parameters frame
1978                                      (list (cons 'mouse-color fg))))
1979         (if (equal bg (cdr (assq 'cursor-color params)))
1980             (modify-frame-parameters frame
1981                                      (list (cons 'cursor-color fg)))))))
1982
1983 (declare-function x-create-frame "xfns.c" (parms))
1984 (declare-function x-setup-function-keys "term/common-win" (frame))
1985
1986 (defun x-create-frame-with-faces (&optional parameters)
1987   "Create and return a frame with frame parameters PARAMETERS.
1988 If PARAMETERS specify a frame name, handle X geometry resources
1989 for that name.  If PARAMETERS includes a `reverse' parameter, or
1990 the X resource ``reverseVideo'' is present, handle that."
1991   (setq parameters (x-handle-named-frame-geometry parameters))
1992   (let* ((params (copy-tree parameters))
1993          (visibility-spec (assq 'visibility parameters))
1994          (delayed-params '(foreground-color background-color font
1995                            border-color cursor-color mouse-color
1996                            visibility scroll-bar-foreground
1997                            scroll-bar-background))
1998          frame success)
1999     (dolist (param delayed-params)
2000       (setq params (assq-delete-all param params)))
2001     (setq frame (x-create-frame `((visibility . nil) . ,params)))
2002     (unwind-protect
2003         (progn
2004           (x-setup-function-keys frame)
2005           (x-handle-reverse-video frame parameters)
2006           (frame-set-background-mode frame t)
2007           (face-set-after-frame-default frame parameters)
2008           (if (null visibility-spec)
2009               (make-frame-visible frame)
2010             (modify-frame-parameters frame (list visibility-spec)))
2011           (setq success t))
2012       (unless success
2013         (delete-frame frame)))
2014     frame))
2015
2016 (defun face-set-after-frame-default (frame &optional parameters)
2017   "Initialize the frame-local faces of FRAME.
2018 Calculate the face definitions using the face specs, custom theme
2019 settings, X resources, and `face-new-frame-defaults'.
2020 Finally, apply any relevant face attributes found amongst the
2021 frame parameters in PARAMETERS."
2022   (let ((window-system-p (memq (window-system frame) '(x w32))))
2023     (dolist (face (nreverse (face-list))) ;Why reverse?  --Stef
2024       (condition-case ()
2025           (progn
2026             ;; Initialize faces from face spec and custom theme.
2027             (face-spec-recalc face frame)
2028             ;; X resouces for the default face are applied during
2029             ;; `x-create-frame'.
2030             (and (not (eq face 'default)) window-system-p
2031                  (make-face-x-resource-internal face frame))
2032             ;; Apply attributes specified by face-new-frame-defaults
2033             (internal-merge-in-global-face face frame))
2034         ;; Don't let invalid specs prevent frame creation.
2035         (error nil))))
2036
2037   ;; Apply attributes specified by frame parameters.
2038   (let ((face-params '((foreground-color default :foreground)
2039                        (background-color default :background)
2040                        (font default :font)
2041                        (border-color border :background)
2042                        (cursor-color cursor :background)
2043                        (scroll-bar-foreground scroll-bar :foreground)
2044                        (scroll-bar-background scroll-bar :background)
2045                        (mouse-color mouse :background))))
2046     (dolist (param face-params)
2047       (let* ((param-name (nth 0 param))
2048              (value (cdr (assq param-name parameters))))
2049         (if value
2050             (set-face-attribute (nth 1 param) frame
2051                                 (nth 2 param) value))))))
2052
2053 (defun tty-handle-reverse-video (frame parameters)
2054   "Handle the reverse-video frame parameter for terminal frames."
2055   (when (cdr (assq 'reverse parameters))
2056     (let* ((params (frame-parameters frame))
2057            (bg (cdr (assq 'foreground-color params)))
2058            (fg (cdr (assq 'background-color params))))
2059       (modify-frame-parameters frame
2060                                (list (cons 'foreground-color fg)
2061                                      (cons 'background-color bg)))
2062       (if (equal bg (cdr (assq 'mouse-color params)))
2063           (modify-frame-parameters frame
2064                                    (list (cons 'mouse-color fg))))
2065       (if (equal bg (cdr (assq 'cursor-color params)))
2066           (modify-frame-parameters frame
2067                                    (list (cons 'cursor-color fg)))))))
2068
2069
2070 (defun tty-create-frame-with-faces (&optional parameters)
2071   "Create and return a frame from optional frame parameters PARAMETERS.
2072 If PARAMETERS contains a `reverse' parameter, handle that."
2073   (let ((frame (make-terminal-frame parameters))
2074         success)
2075     (unwind-protect
2076         (with-selected-frame frame
2077           (tty-handle-reverse-video frame (frame-parameters frame))
2078
2079           (unless (terminal-parameter frame 'terminal-initted)
2080             (set-terminal-parameter frame 'terminal-initted t)
2081             (set-locale-environment nil frame)
2082             (tty-run-terminal-initialization frame))
2083           (frame-set-background-mode frame t)
2084           (face-set-after-frame-default frame parameters)
2085           (setq success t))
2086       (unless success
2087         (delete-frame frame)))
2088     frame))
2089
2090 (defun tty-find-type (pred type)
2091   "Return the longest prefix of TYPE to which PRED returns non-nil.
2092 TYPE should be a tty type name such as \"xterm-16color\".
2093
2094 The function tries only those prefixes that are followed by a
2095 dash or underscore in the original type name, like \"xterm\" in
2096 the above example."
2097   (let (hyphend)
2098     (while (and type
2099                 (not (funcall pred type)))
2100       ;; Strip off last hyphen and what follows, then try again
2101       (setq type
2102             (if (setq hyphend (string-match "[-_][^-_]+$" type))
2103                 (substring type 0 hyphend)
2104               nil))))
2105   type)
2106
2107 (defun tty-run-terminal-initialization (frame &optional type)
2108   "Run the special initialization code for the terminal type of FRAME.
2109 The optional TYPE parameter may be used to override the autodetected
2110 terminal type to a different value."
2111   (setq type (or type (tty-type frame)))
2112   ;; Load library for our terminal type.
2113   ;; User init file can set term-file-prefix to nil to prevent this.
2114   (with-selected-frame frame
2115     (unless (null term-file-prefix)
2116       (let* (term-init-func)
2117         ;; First, load the terminal initialization file, if it is
2118         ;; available and it hasn't been loaded already.
2119         (tty-find-type #'(lambda (type)
2120                            (let ((file (locate-library (concat term-file-prefix type))))
2121                              (and file
2122                                   (or (assoc file load-history)
2123                                       (load file t t)))))
2124                        type)
2125         ;; Next, try to find a matching initialization function, and call it.
2126         (tty-find-type #'(lambda (type)
2127                            (fboundp (setq term-init-func
2128                                           (intern (concat "terminal-init-" type)))))
2129                        type)
2130         (when (fboundp term-init-func)
2131           (funcall term-init-func))
2132         (set-terminal-parameter frame 'terminal-initted term-init-func)))))
2133
2134 ;; Called from C function init_display to initialize faces of the
2135 ;; dumped terminal frame on startup.
2136
2137 (defun tty-set-up-initial-frame-faces ()
2138   (let ((frame (selected-frame)))
2139     (frame-set-background-mode frame t)
2140     (face-set-after-frame-default frame)))
2141
2142
2143 \f
2144 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2145 ;;; Standard faces.
2146 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2147
2148 (defgroup basic-faces nil
2149   "The standard faces of Emacs."
2150   :group 'faces)
2151
2152 (defface default
2153   '((t nil)) ; If this were nil, face-defface-spec would not be set.
2154   "Basic default face."
2155   :group 'basic-faces)
2156
2157 (defface bold
2158   '((t :weight bold))
2159   "Basic bold face."
2160   :group 'basic-faces)
2161
2162 (defface italic
2163   '((((supports :slant italic))
2164      :slant italic)
2165     (((supports :underline t))
2166      :underline t)
2167     (t
2168      ;; default to italic, even it doesn't appear to be supported,
2169      ;; because in some cases the display engine will do it's own
2170      ;; workaround (to `dim' on ttys)
2171      :slant italic))
2172   "Basic italic face."
2173   :group 'basic-faces)
2174
2175 (defface bold-italic
2176   '((t :weight bold :slant italic))
2177   "Basic bold-italic face."
2178   :group 'basic-faces)
2179
2180 (defface underline
2181   '((((supports :underline t))
2182      :underline t)
2183     (((supports :weight bold))
2184      :weight bold)
2185     (t :underline t))
2186   "Basic underlined face."
2187   :group 'basic-faces)
2188
2189 (defface fixed-pitch
2190   '((t :family "Monospace"))
2191   "The basic fixed-pitch face."
2192   :group 'basic-faces)
2193
2194 (defface variable-pitch
2195   '((t :family "Sans Serif"))
2196   "The basic variable-pitch face."
2197   :group 'basic-faces)
2198
2199 (defface shadow
2200   '((((class color grayscale) (min-colors 88) (background light))
2201      :foreground "grey50")
2202     (((class color grayscale) (min-colors 88) (background dark))
2203      :foreground "grey70")
2204     (((class color) (min-colors 8) (background light))
2205      :foreground "green")
2206     (((class color) (min-colors 8) (background dark))
2207      :foreground "yellow"))
2208   "Basic face for shadowed text."
2209   :group 'basic-faces
2210   :version "22.1")
2211
2212 (defface link
2213   '((((class color) (min-colors 88) (background light))
2214      :foreground "blue1" :underline t)
2215     (((class color) (background light))
2216      :foreground "blue" :underline t)
2217     (((class color) (min-colors 88) (background dark))
2218      :foreground "cyan1" :underline t)
2219     (((class color) (background dark))
2220      :foreground "cyan" :underline t)
2221     (t :inherit underline))
2222   "Basic face for unvisited links."
2223   :group 'basic-faces
2224   :version "22.1")
2225
2226 (defface link-visited
2227   '((default :inherit link)
2228     (((class color) (background light)) :foreground "magenta4")
2229     (((class color) (background dark)) :foreground "violet"))
2230   "Basic face for visited links."
2231   :group 'basic-faces
2232   :version "22.1")
2233
2234 (defface highlight
2235   '((((class color) (min-colors 88) (background light))
2236      :background "darkseagreen2")
2237     (((class color) (min-colors 88) (background dark))
2238      :background "darkolivegreen")
2239     (((class color) (min-colors 16) (background light))
2240      :background "darkseagreen2")
2241     (((class color) (min-colors 16) (background dark))
2242      :background "darkolivegreen")
2243     (((class color) (min-colors 8))
2244      :background "green" :foreground "black")
2245     (t :inverse-video t))
2246   "Basic face for highlighting."
2247   :group 'basic-faces)
2248
2249 ;; Region face: under NS, default to the system-defined selection
2250 ;; color (optimized for the fixed white background of other apps),
2251 ;; if background is light.
2252 (defface region
2253   '((((class color) (min-colors 88) (background dark))
2254      :background "blue3")
2255     (((class color) (min-colors 88) (background light) (type gtk))
2256      :foreground "gtk_selection_fg_color"
2257      :background "gtk_selection_bg_color")
2258     (((class color) (min-colors 88) (background light) (type ns))
2259      :background "ns_selection_color")
2260     (((class color) (min-colors 88) (background light))
2261      :background "lightgoldenrod2")
2262     (((class color) (min-colors 16) (background dark))
2263      :background "blue3")
2264     (((class color) (min-colors 16) (background light))
2265      :background "lightgoldenrod2")
2266     (((class color) (min-colors 8))
2267      :background "blue" :foreground "white")
2268     (((type tty) (class mono))
2269      :inverse-video t)
2270     (t :background "gray"))
2271   "Basic face for highlighting the region."
2272   :version "21.1"
2273   :group 'basic-faces)
2274
2275 (defface secondary-selection
2276   '((((class color) (min-colors 88) (background light))
2277      :background "yellow1")
2278     (((class color) (min-colors 88) (background dark))
2279      :background "SkyBlue4")
2280     (((class color) (min-colors 16) (background light))
2281      :background "yellow")
2282     (((class color) (min-colors 16) (background dark))
2283      :background "SkyBlue4")
2284     (((class color) (min-colors 8))
2285      :background "cyan" :foreground "black")
2286     (t :inverse-video t))
2287   "Basic face for displaying the secondary selection."
2288   :group 'basic-faces)
2289
2290 (defface trailing-whitespace
2291   '((((class color) (background light))
2292      :background "red1")
2293     (((class color) (background dark))
2294      :background "red1")
2295     (t :inverse-video t))
2296   "Basic face for highlighting trailing whitespace."
2297   :version "21.1"
2298   :group 'whitespace-faces      ; like `show-trailing-whitespace'
2299   :group 'basic-faces)
2300
2301 (defface escape-glyph
2302   '((((background dark)) :foreground "cyan")
2303     ;; See the comment in minibuffer-prompt for
2304     ;; the reason not to use blue on MS-DOS.
2305     (((type pc)) :foreground "magenta")
2306     ;; red4 is too dark, but some say blue is too loud.
2307     ;; brown seems to work ok. -- rms.
2308     (t :foreground "brown"))
2309   "Face for characters displayed as sequences using `^' or `\\'."
2310   :group 'basic-faces
2311   :version "22.1")
2312
2313 (defface nobreak-space
2314   '((((class color) (min-colors 88)) :inherit escape-glyph :underline t)
2315     (((class color) (min-colors 8)) :background "magenta")
2316     (t :inverse-video t))
2317   "Face for displaying nobreak space."
2318   :group 'basic-faces
2319   :version "22.1")
2320
2321 (defgroup mode-line-faces nil
2322   "Faces used in the mode line."
2323   :group 'mode-line
2324   :group 'faces
2325   :version "22.1")
2326
2327 (defface mode-line
2328   '((((class color) (min-colors 88))
2329      :box (:line-width -1 :style released-button)
2330      :background "grey75" :foreground "black")
2331     (t
2332      :inverse-video t))
2333   "Basic mode line face for selected window."
2334   :version "21.1"
2335   :group 'mode-line-faces
2336   :group 'basic-faces)
2337 ;; No need to define aliases of this form for new faces.
2338 (define-obsolete-face-alias 'modeline 'mode-line "21.1")
2339
2340 (defface mode-line-inactive
2341   '((default
2342      :inherit mode-line)
2343     (((class color) (min-colors 88) (background light))
2344      :weight light
2345      :box (:line-width -1 :color "grey75" :style nil)
2346      :foreground "grey20" :background "grey90")
2347     (((class color) (min-colors 88) (background dark) )
2348      :weight light
2349      :box (:line-width -1 :color "grey40" :style nil)
2350      :foreground "grey80" :background "grey30"))
2351   "Basic mode line face for non-selected windows."
2352   :version "22.1"
2353   :group 'mode-line-faces
2354   :group 'basic-faces)
2355 (define-obsolete-face-alias 'modeline-inactive 'mode-line-inactive "22.1")
2356
2357 (defface mode-line-highlight
2358   '((((class color) (min-colors 88))
2359      :box (:line-width 2 :color "grey40" :style released-button))
2360     (t
2361      :inherit highlight))
2362   "Basic mode line face for highlighting."
2363   :version "22.1"
2364   :group 'mode-line-faces
2365   :group 'basic-faces)
2366 (define-obsolete-face-alias 'modeline-highlight 'mode-line-highlight "22.1")
2367
2368 (defface mode-line-emphasis
2369   '((t (:weight bold)))
2370   "Face used to emphasize certain mode line features.
2371 Use the face `mode-line-highlight' for features that can be selected."
2372   :version "23.1"
2373   :group 'mode-line-faces
2374   :group 'basic-faces)
2375
2376 (defface mode-line-buffer-id
2377   '((t (:weight bold)))
2378   "Face used for buffer identification parts of the mode line."
2379   :version "22.1"
2380   :group 'mode-line-faces
2381   :group 'basic-faces)
2382 (define-obsolete-face-alias 'modeline-buffer-id 'mode-line-buffer-id "22.1")
2383
2384 (defface header-line
2385   '((default
2386      :inherit mode-line)
2387     (((type tty))
2388      ;; This used to be `:inverse-video t', but that doesn't look very
2389      ;; good when combined with inverse-video mode-lines and multiple
2390      ;; windows.  Underlining looks better, and is more consistent with
2391      ;; the window-system face variants, which deemphasize the
2392      ;; header-line in relation to the mode-line face.  If a terminal
2393      ;; can't underline, then the header-line will end up without any
2394      ;; highlighting; this may be too confusing in general, although it
2395      ;; happens to look good with the only current use of header-lines,
2396      ;; the info browser. XXX
2397      :inverse-video nil        ;Override the value inherited from mode-line.
2398      :underline t)
2399     (((class color grayscale) (background light))
2400      :background "grey90" :foreground "grey20"
2401      :box nil)
2402     (((class color grayscale) (background dark))
2403      :background "grey20" :foreground "grey90"
2404      :box nil)
2405     (((class mono) (background light))
2406      :background "white" :foreground "black"
2407      :inverse-video nil
2408      :box nil
2409      :underline t)
2410     (((class mono) (background dark))
2411      :background "black" :foreground "white"
2412      :inverse-video nil
2413      :box nil
2414      :underline t))
2415   "Basic header-line face."
2416   :version "21.1"
2417   :group 'basic-faces)
2418
2419 (defface vertical-border
2420   '((((type tty)) :inherit mode-line-inactive))
2421   "Face used for vertical window dividers on ttys."
2422   :version "22.1"
2423   :group 'basic-faces)
2424
2425 (defface minibuffer-prompt
2426   '((((background dark)) :foreground "cyan")
2427     ;; Don't use blue because many users of the MS-DOS port customize
2428     ;; their foreground color to be blue.
2429     (((type pc)) :foreground "magenta")
2430     (t :foreground "medium blue"))
2431   "Face for minibuffer prompts.
2432 By default, Emacs automatically adds this face to the value of
2433 `minibuffer-prompt-properties', which is a list of text properties
2434 used to display the prompt text."
2435   :version "22.1"
2436   :group 'basic-faces)
2437
2438 (setq minibuffer-prompt-properties
2439       (append minibuffer-prompt-properties (list 'face 'minibuffer-prompt)))
2440
2441 (defface fringe
2442   '((((class color) (background light))
2443      :background "grey95")
2444     (((class color) (background dark))
2445      :background "grey10")
2446     (t
2447      :background "gray"))
2448   "Basic face for the fringes to the left and right of windows under X."
2449   :version "21.1"
2450   :group 'frames
2451   :group 'basic-faces)
2452
2453 (defface scroll-bar '((t nil))
2454   "Basic face for the scroll bar colors under X."
2455   :version "21.1"
2456   :group 'frames
2457   :group 'basic-faces)
2458
2459 (defface border '((t nil))
2460   "Basic face for the frame border under X."
2461   :version "21.1"
2462   :group 'frames
2463   :group 'basic-faces)
2464
2465 (defface cursor
2466   '((((background light)) :background "black")
2467     (((background dark))  :background "white"))
2468   "Basic face for the cursor color under X.
2469 Note: Other faces cannot inherit from the cursor face."
2470   :version "21.1"
2471   :group 'cursor
2472   :group 'basic-faces)
2473
2474 (put 'cursor 'face-no-inherit t)
2475
2476 (defface mouse '((t nil))
2477   "Basic face for the mouse color under X."
2478   :version "21.1"
2479   :group 'mouse
2480   :group 'basic-faces)
2481
2482 (defface tool-bar
2483   '((default
2484      :box (:line-width 1 :style released-button)
2485      :foreground "black")
2486     (((type x w32 ns) (class color))
2487      :background "grey75")
2488     (((type x) (class mono))
2489      :background "grey"))
2490   "Basic tool-bar face."
2491   :version "21.1"
2492   :group 'basic-faces)
2493
2494 (defface menu
2495   '((((type tty))
2496      :inverse-video t)
2497     (((type x-toolkit))
2498      )
2499     (t
2500      :inverse-video t))
2501   "Basic face for the font and colors of the menu bar and popup menus."
2502   :version "21.1"
2503   :group 'menu
2504   :group 'basic-faces)
2505
2506 (defface help-argument-name '((((supports :slant italic)) :inherit italic))
2507   "Face to highlight argument names in *Help* buffers."
2508   :group 'help)
2509
2510 (defface glyphless-char
2511   '((((type tty)) :inherit underline)
2512     (((type pc)) :inherit escape-glyph)
2513     (t :height 0.6))
2514   "Face for displaying non-graphic characters (e.g. U+202A (LRE)).
2515 It is used for characters of no fonts too."
2516   :version "24.1"
2517   :group 'basic-faces)
2518 \f
2519 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2520 ;;; Manipulating font names.
2521 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2522
2523 ;; This is here for compatibilty with Emacs 20.2.  For example,
2524 ;; international/fontset.el uses x-resolve-font-name.  The following
2525 ;; functions are not used in the face implementation itself.
2526
2527 (defvar x-font-regexp nil)
2528 (defvar x-font-regexp-head nil)
2529 (defvar x-font-regexp-weight nil)
2530 (defvar x-font-regexp-slant nil)
2531
2532 (defconst x-font-regexp-weight-subnum 1)
2533 (defconst x-font-regexp-slant-subnum 2)
2534 (defconst x-font-regexp-swidth-subnum 3)
2535 (defconst x-font-regexp-adstyle-subnum 4)
2536
2537 ;;; Regexps matching font names in "Host Portable Character Representation."
2538 ;;;
2539 (let ((-                "[-?]")
2540       (foundry          "[^-]+")
2541       (family           "[^-]+")
2542       (weight           "\\(bold\\|demibold\\|medium\\)")               ; 1
2543 ;     (weight\?         "\\(\\*\\|bold\\|demibold\\|medium\\|\\)")      ; 1
2544       (weight\?         "\\([^-]*\\)")                                  ; 1
2545       (slant            "\\([ior]\\)")                                  ; 2
2546 ;     (slant\?          "\\([ior?*]?\\)")                               ; 2
2547       (slant\?          "\\([^-]?\\)")                                  ; 2
2548 ;     (swidth           "\\(\\*\\|normal\\|semicondensed\\|\\)")        ; 3
2549       (swidth           "\\([^-]*\\)")                                  ; 3
2550 ;     (adstyle          "\\(\\*\\|sans\\|\\)")                          ; 4
2551       (adstyle          "\\([^-]*\\)")                                  ; 4
2552       (pixelsize        "[0-9]+")
2553       (pointsize        "[0-9][0-9]+")
2554       (resx             "[0-9][0-9]+")
2555       (resy             "[0-9][0-9]+")
2556       (spacing          "[cmp?*]")
2557       (avgwidth         "[0-9]+")
2558       (registry         "[^-]+")
2559       (encoding         "[^-]+")
2560       )
2561   (setq x-font-regexp
2562         (purecopy (concat "\\`\\*?[-?*]"
2563                 foundry - family - weight\? - slant\? - swidth - adstyle -
2564                 pixelsize - pointsize - resx - resy - spacing - avgwidth -
2565                 registry - encoding "\\*?\\'"
2566                 )))
2567   (setq x-font-regexp-head
2568         (purecopy (concat "\\`[-?*]" foundry - family - weight\? - slant\?
2569                 "\\([-*?]\\|\\'\\)")))
2570   (setq x-font-regexp-slant (purecopy (concat - slant -)))
2571   (setq x-font-regexp-weight (purecopy (concat - weight -)))
2572   nil)
2573
2574
2575 (defun x-resolve-font-name (pattern &optional face frame)
2576   "Return a font name matching PATTERN.
2577 All wildcards in PATTERN are instantiated.
2578 If PATTERN is nil, return the name of the frame's base font, which never
2579 contains wildcards.
2580 Given optional arguments FACE and FRAME, return a font which is
2581 also the same size as FACE on FRAME, or fail."
2582   (or (symbolp face)
2583       (setq face (face-name face)))
2584   (and (eq frame t)
2585        (setq frame nil))
2586   (if pattern
2587       ;; Note that x-list-fonts has code to handle a face with nil as its font.
2588       (let ((fonts (x-list-fonts pattern face frame 1)))
2589         (or fonts
2590             (if face
2591                 (if (string-match "\\*" pattern)
2592                     (if (null (face-font face))
2593                         (error "No matching fonts are the same height as the frame default font")
2594                       (error "No matching fonts are the same height as face `%s'" face))
2595                   (if (null (face-font face))
2596                       (error "Height of font `%s' doesn't match the frame default font"
2597                              pattern)
2598                     (error "Height of font `%s' doesn't match face `%s'"
2599                            pattern face)))
2600               (error "No fonts match `%s'" pattern)))
2601         (car fonts))
2602     (cdr (assq 'font (frame-parameters (selected-frame))))))
2603
2604 (provide 'faces)
2605
2606 ;;; faces.el ends here