lisp/calendar/cal-dst.el

   1 ;;; cal-dst.el --- calendar functions for daylight saving rules
   2
   3 ;; Copyright (C) 1993-1996, 2001-2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Paul Eggert <eggert@twinsun.com>
   6 ;;         Edward M. Reingold <reingold@cs.uiuc.edu>
   7 ;; Maintainer: Glenn Morris <rgm@gnu.org>
   8 ;; Keywords: calendar
   9 ;; Human-Keywords: daylight saving time, calendar, diary, holidays
  10 ;; Package: calendar
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; See calendar.el.
  30
  31 ;;; Code:
  32
  33 (require 'calendar)
  34
  35
  36 (defgroup calendar-dst nil
  37   "Options related to Daylight Saving Time."
  38   :prefix "calendar-"
  39   :group 'calendar)
  40
  41
  42 (defcustom calendar-dst-check-each-year-flag t
  43   "Non-nil means to check each year for DST transitions as needed.
  44 Otherwise assume the next two transitions found after the
  45 current date apply to all years.  This is faster, but not always
  46 correct, since the dates of daylight saving transitions sometimes
  47 change."
  48   :type 'boolean
  49   :version "22.1"
  50   :group 'calendar-dst)
  51
  52 ;;;###autoload
  53 (put 'calendar-daylight-savings-starts 'risky-local-variable t)
  54 (defcustom calendar-daylight-savings-starts '(calendar-dst-starts year)
  55   "Sexp giving the date on which daylight saving time starts.
  56 This is an expression in the variable `year' whose value gives the Gregorian
  57 date in the form (month day year) on which daylight saving time starts.  It is
  58 used to determine the starting date of daylight saving time for the holiday
  59 list and for correcting times of day in the solar and lunar calculations.
  60
  61 For example, if daylight saving time is mandated to start on October 1,
  62 you would set `calendar-daylight-savings-starts' to
  63
  64       '(10 1 year)
  65
  66 If it starts on the first Sunday in April, you would set it to
  67
  68       '(calendar-nth-named-day 1 0 4 year)
  69
  70 If the locale never uses daylight saving time, set this to nil."
  71   :type 'sexp
  72   :group 'calendar-dst)
  73
  74 ;;;###autoload
  75 (put 'calendar-daylight-savings-ends 'risky-local-variable t)
  76 (defcustom calendar-daylight-savings-ends '(calendar-dst-ends year)
  77   "Sexp giving the date on which daylight saving time ends.
  78 This is an expression in the variable `year' whose value gives the Gregorian
  79 date in the form (month day year) on which daylight saving time ends.  It is
  80 used to determine the starting date of daylight saving time for the holiday
  81 list and for correcting times of day in the solar and lunar calculations.
  82
  83 For example, if daylight saving time ends on the last Sunday in October:
  84
  85       '(calendar-nth-named-day -1 0 10 year)
  86
  87 If the locale never uses daylight saving time, set this to nil."
  88   :type 'sexp
  89   :group 'calendar-dst)
  90
  91 ;;; More defcustoms below.
  92
  93
  94 (defvar calendar-current-time-zone-cache nil
  95   "Cache for result of `calendar-current-time-zone'.")
  96 ;; It gets eval'd, eg by calendar-dst-starts.
  97 ;;;###autoload
  98 (put 'calendar-current-time-zone-cache 'risky-local-variable t)
  99
 100 (defvar calendar-system-time-basis
 101   (calendar-absolute-from-gregorian '(1 1 1970))
 102   "Absolute date of starting date of system clock.")
 103
 104 (defun calendar-absolute-from-time (x utc-diff)
 105   "Absolute local date of time X; local time is UTC-DIFF seconds from UTC.
 106
 107 X is (HIGH . LOW) or (HIGH LOW . IGNORED) where HIGH and LOW are the
 108 high and low 16 bits, respectively, of the number of seconds since
 109 1970-01-01 00:00:00 UTC, ignoring leap seconds.
 110
 111 Returns the pair (ABS-DATE . SECONDS) where SECONDS after local midnight on
 112 absolute date ABS-DATE is the equivalent moment to X."
 113   (let* ((h (car x))
 114          (xtail (cdr x))
 115          (l (+ utc-diff (if (numberp xtail) xtail (car xtail))))
 116          (u (+ (* 512 (mod h 675)) (floor l 128))))
 117     ;; Overflow is a terrible thing!
 118     (cons (+ calendar-system-time-basis
 119              ;; floor((2^16 h +l) / (60*60*24))
 120              (* 512 (floor h 675)) (floor u 675))
 121           ;; (2^16 h +l) mod (60*60*24)
 122           (+ (* (mod u 675) 128) (mod l 128)))))
 123
 124 (defun calendar-time-from-absolute (abs-date s)
 125   "Time of absolute date ABS-DATE, S seconds after midnight.
 126
 127 Returns the list (HIGH LOW) where HIGH and LOW are the high and low
 128 16 bits, respectively, of the number of seconds 1970-01-01 00:00:00 UTC,
 129 ignoring leap seconds, that is the equivalent moment to S seconds after
 130 midnight UTC on absolute date ABS-DATE."
 131   (let* ((a (- abs-date calendar-system-time-basis))
 132          (u (+ (* 163 (mod a 512)) (floor s 128))))
 133     ;; Overflow is a terrible thing!
 134     (list
 135      ;; floor((60*60*24*a + s) / 2^16)
 136      (+ a (* 163 (floor a 512)) (floor u 512))
 137      ;; (60*60*24*a + s) mod 2^16
 138      (+ (* 128 (mod u 512)) (mod s 128)))))
 139
 140 (defun calendar-next-time-zone-transition (time)
 141   "Return the time of the next time zone transition after TIME.
 142 Both TIME and the result are acceptable arguments to `current-time-zone'.
 143 Return nil if no such transition can be found."
 144   (let* ((base 65536)           ; 2^16 = base of current-time output
 145          (quarter-multiple 120) ; approx = (seconds per quarter year) / base
 146          (time-zone (current-time-zone time))
 147          (time-utc-diff (car time-zone))
 148          hi
 149          hi-zone
 150          (hi-utc-diff time-utc-diff)
 151          (quarters '(2 1 3)))
 152     ;; Heuristic: probe the time zone offset in the next three calendar
 153     ;; quarters, looking for a time zone offset different from TIME.
 154     (while (and quarters (eq time-utc-diff hi-utc-diff))
 155       (setq hi (cons (+ (car time) (* (car quarters) quarter-multiple)) 0)
 156             hi-zone (current-time-zone hi)
 157             hi-utc-diff (car hi-zone)
 158             quarters (cdr quarters)))
 159     (and
 160      time-utc-diff
 161      hi-utc-diff
 162      (not (eq time-utc-diff hi-utc-diff))
 163      ;; Now HI is after the next time zone transition.
 164      ;; Set LO to TIME, and then binary search to increase LO and decrease HI
 165      ;; until LO is just before and HI is just after the time zone transition.
 166      (let* ((tail (cdr time))
 167             (lo (cons (car time) (if (numberp tail) tail (car tail))))
 168             probe)
 169        (while
 170            ;; Set PROBE to halfway between LO and HI, rounding down.
 171            ;; If PROBE equals LO, we are done.
 172            (let* ((lsum (+ (cdr lo) (cdr hi)))
 173                   (hsum (+ (car lo) (car hi) (/ lsum base)))
 174                   (hsumodd (logand 1 hsum)))
 175              (setq probe (cons (/ (- hsum hsumodd) 2)
 176                                (/ (+ (* hsumodd base) (% lsum base)) 2)))
 177              (not (equal lo probe)))
 178          ;; Set either LO or HI to PROBE, depending on probe results.
 179          (if (eq (car (current-time-zone probe)) hi-utc-diff)
 180              (setq hi probe)
 181            (setq lo probe)))
 182        (setcdr hi (list (cdr hi)))
 183        hi))))
 184
 185 (autoload 'calendar-persian-to-absolute "cal-persia")
 186
 187 (defun calendar-time-zone-daylight-rules (abs-date utc-diff)
 188   "Return daylight transition rule for ABS-DATE, UTC-DIFF sec offset from UTC.
 189 ABS-DATE must specify a day that contains a daylight saving transition.
 190 The result has the proper form for `calendar-daylight-savings-starts'."
 191   (let* ((date (calendar-gregorian-from-absolute abs-date))
 192          (weekday (% abs-date 7))
 193          (m (calendar-extract-month date))
 194          (d (calendar-extract-day date))
 195          (y (calendar-extract-year date))
 196          (last (calendar-last-day-of-month m y))
 197          j rlist
 198          (candidate-rules               ; these return Gregorian dates
 199           (append
 200            ;; Day D of month M.
 201            `((list ,m ,d year))
 202            ;; The first WEEKDAY of month M.
 203            (if (< d 8)
 204                `((calendar-nth-named-day 1 ,weekday ,m year)))
 205            ;; The last WEEKDAY of month M.
 206            (if (> d (- last 7))
 207                `((calendar-nth-named-day -1 ,weekday ,m year)))
 208            (progn
 209              ;; The first WEEKDAY after day J of month M, for D-6 < J <= D.
 210              (setq j (1- (max 2 (- d 6))))
 211              (while (<= (setq j (1+ j)) (min d (- last 8)))
 212                (push `(calendar-nth-named-day 1 ,weekday ,m year ,j) rlist))
 213              rlist)
 214            ;; 01-01 and 07-01 for this year's Persian calendar.
 215            ;; FIXME what does the Persian calendar have to do with this?
 216            (and (= m 3) (memq d '(20 21))
 217                 '((calendar-gregorian-from-absolute
 218                    (calendar-persian-to-absolute `(1 1 ,(- year 621))))))
 219            (and (= m 9) (memq d '(22 23))
 220                 '((calendar-gregorian-from-absolute
 221                    (calendar-persian-to-absolute `(7 1 ,(- year 621))))))))
 222          (prevday-sec (- -1 utc-diff)) ; last sec of previous local day
 223          (year (1+ y))
 224          new-rules)
 225     ;; Scan through the next few years until only one rule remains.
 226     (while (cdr candidate-rules)
 227       (dolist (rule candidate-rules)
 228         ;; The rule we return should give a Gregorian date, but here
 229         ;; we require an absolute date.  The following is for efficiency.
 230         (setq date (cond ((eq (car rule) 'calendar-nth-named-day)
 231                           (eval (cons 'calendar-nth-named-absday (cdr rule))))
 232                          ((eq (car rule) 'calendar-gregorian-from-absolute)
 233                           (eval (cadr rule)))
 234                          (t (calendar-absolute-from-gregorian (eval rule)))))
 235         (or (equal (current-time-zone
 236                     (calendar-time-from-absolute date prevday-sec))
 237                    (current-time-zone
 238                     (calendar-time-from-absolute (1+ date) prevday-sec)))
 239             (setq new-rules (cons rule new-rules))))
 240       ;; If no rules remain, just use the first candidate rule;
 241       ;; it's wrong in general, but it's right for at least one year.
 242       (setq candidate-rules (if new-rules (nreverse new-rules)
 243                               (list (car candidate-rules)))
 244             new-rules nil
 245             year (1+ year)))
 246     (car candidate-rules)))
 247
 248 ;; TODO it might be better to extract this information directly from
 249 ;; the system timezone database. But cross-platform...?
 250 ;; See thread
 251 ;; http://lists.gnu.org/archive/html/emacs-pretest-bug/2006-11/msg00060.html
 252 (defun calendar-dst-find-data (&optional time)
 253   "Find data on the first daylight saving time transitions after TIME.
 254 TIME defaults to `current-time'.  Return value is as described
 255 for `calendar-current-time-zone'."
 256   (let* ((t0 (or time (current-time)))
 257          (t0-zone (current-time-zone t0))
 258          (t0-utc-diff (car t0-zone))
 259          (t0-name (cadr t0-zone)))
 260     (if (not t0-utc-diff)
 261         ;; Little or no time zone information is available.
 262         (list nil nil t0-name t0-name nil nil nil nil)
 263       (let* ((t1 (calendar-next-time-zone-transition t0))
 264              (t2 (and t1 (calendar-next-time-zone-transition t1))))
 265         (if (not t2)
 266             ;; This locale does not have daylight saving time.
 267             (list (/ t0-utc-diff 60) 0 t0-name t0-name nil nil 0 0)
 268           ;; Use heuristics to find daylight saving parameters.
 269           (let* ((t1-zone (current-time-zone t1))
 270                  (t1-utc-diff (car t1-zone))
 271                  (t1-name (cadr t1-zone))
 272                  (t1-date-sec (calendar-absolute-from-time t1 t0-utc-diff))
 273                  (t2-date-sec (calendar-absolute-from-time t2 t1-utc-diff))
 274                  ;; TODO When calendar-dst-check-each-year-flag is non-nil,
 275                  ;; the rules can be simpler than they currently are.
 276                  (t1-rules (calendar-time-zone-daylight-rules
 277                             (car t1-date-sec) t0-utc-diff))
 278                  (t2-rules (calendar-time-zone-daylight-rules
 279                             (car t2-date-sec) t1-utc-diff))
 280                  (t1-time (/ (cdr t1-date-sec) 60))
 281                  (t2-time (/ (cdr t2-date-sec) 60)))
 282             (cons
 283              (/ (min t0-utc-diff t1-utc-diff) 60)
 284              (cons
 285               (/ (abs (- t0-utc-diff t1-utc-diff)) 60)
 286               (if (< t0-utc-diff t1-utc-diff)
 287                   (list t0-name t1-name t1-rules t2-rules t1-time t2-time)
 288                 (list t1-name t0-name t2-rules t1-rules t2-time t1-time)
 289                 )))))))))
 290
 291 (defvar calendar-dst-transition-cache nil
 292   "Internal cal-dst variable storing date of daylight saving time transitions.
 293 Value is a list with elements of the form (YEAR START END), where
 294 START and END are expressions that when evaluated return the
 295 start and end dates (respectively) for DST in YEAR.  Used by the
 296 function `calendar-dst-find-startend'.")
 297
 298 (defun calendar-dst-find-startend (year)
 299   "Find the dates in YEAR on which daylight saving time starts and ends.
 300 Returns a list (YEAR START END), where START and END are
 301 expressions that when evaluated return the start and end dates,
 302 respectively. This function first attempts to use pre-calculated
 303 data from `calendar-dst-transition-cache', otherwise it calls
 304 `calendar-dst-find-data' (and adds the results to the cache).
 305 If dates in YEAR cannot be handled by `encode-time' (e.g. if they
 306 are too large to be represented as a lisp integer), then rather
 307 than an error this function returns the result appropriate for
 308 the current year."
 309   (let ((e (assoc year calendar-dst-transition-cache))
 310         f)
 311     (or e
 312         (progn
 313           (setq e (calendar-dst-find-data
 314                    (condition-case nil
 315                        (encode-time 1 0 0 1 1 year)
 316                      (error
 317                       (encode-time 1 0 0 1 1 (nth 5 (decode-time))))))
 318                 f (nth 4 e)
 319                 e (list year f (nth 5 e))
 320                 calendar-dst-transition-cache
 321                 (append calendar-dst-transition-cache (list e)))
 322           e))))
 323
 324 (defun calendar-current-time-zone ()
 325   "Return UTC difference, dst offset, names and rules for current time zone.
 326
 327 Returns (UTC-DIFF DST-OFFSET STD-ZONE DST-ZONE DST-STARTS DST-ENDS
 328 DST-STARTS-TIME DST-ENDS-TIME), based on a heuristic probing of what the
 329 system knows:
 330
 331 UTC-DIFF is an integer specifying the number of minutes difference between
 332     standard time in the current time zone and Coordinated Universal Time
 333     (Greenwich Mean Time).  A negative value means west of Greenwich.
 334 DST-OFFSET is an integer giving the daylight saving time offset in minutes.
 335 STD-ZONE is a string giving the name of the time zone when no seasonal time
 336     adjustment is in effect.
 337 DST-ZONE is a string giving the name of the time zone when there is a seasonal
 338     time adjustment in effect.
 339 DST-STARTS and DST-ENDS are sexps in the variable `year' giving the daylight
 340     saving time start and end rules, in the form expected by
 341     `calendar-daylight-savings-starts'.
 342 DST-STARTS-TIME and DST-ENDS-TIME are integers giving the number of minutes
 343     after midnight that daylight saving time starts and ends.
 344
 345 If the local area does not use a seasonal time adjustment, STD-ZONE and
 346 DST-ZONE are equal, and all the DST-* integer variables are 0.
 347
 348 Some operating systems cannot provide all this information to Emacs; in this
 349 case, `calendar-current-time-zone' returns a list containing nil for the data
 350 it can't find."
 351   (or calendar-current-time-zone-cache
 352       (setq calendar-current-time-zone-cache (calendar-dst-find-data))))
 353
 354
 355 ;; Following options should be set based on conditions when the code
 356 ;; is invoked, so are not suitable for dumping into loaddefs.el.  They
 357 ;; default to US Eastern time if time zone info is not available.
 358
 359 (calendar-current-time-zone)
 360
 361 (defcustom calendar-time-zone (or (car calendar-current-time-zone-cache) -300)
 362   "Number of minutes difference between local standard time and UTC.
 363 For example, -300 for New York City, -480 for Los Angeles."
 364   :type 'integer
 365   :group 'calendar-dst)
 366
 367 (defcustom calendar-daylight-time-offset
 368   (or (cadr calendar-current-time-zone-cache) 60)
 369   "Number of minutes difference between daylight saving and standard time.
 370 If the locale never uses daylight saving time, set this to 0."
 371   :type 'integer
 372   :group 'calendar-dst)
 373
 374 (defcustom calendar-standard-time-zone-name
 375   (or (nth 2 calendar-current-time-zone-cache) "EST")
 376   "Abbreviated name of standard time zone at `calendar-location-name'.
 377 For example, \"EST\" in New York City, \"PST\" for Los Angeles."
 378   :type 'string
 379   :group 'calendar-dst)
 380
 381 (defcustom calendar-daylight-time-zone-name
 382   (or (nth 3 calendar-current-time-zone-cache) "EDT")
 383   "Abbreviated name of daylight saving time zone at `calendar-location-name'.
 384 For example, \"EDT\" in New York City, \"PDT\" for Los Angeles."
 385   :type 'string
 386   :group 'calendar-dst)
 387
 388 (defcustom calendar-daylight-savings-starts-time
 389   (or (nth 6 calendar-current-time-zone-cache) 120)
 390   "Number of minutes after midnight that daylight saving time starts."
 391   :type 'integer
 392   :group 'calendar-dst)
 393
 394 (defcustom calendar-daylight-savings-ends-time
 395   (or (nth 7 calendar-current-time-zone-cache)
 396       calendar-daylight-savings-starts-time)
 397   "Number of minutes after midnight that daylight saving time ends."
 398   :type 'integer
 399   :group 'calendar-dst)
 400
 401
 402 (defun calendar-dst-starts (year)
 403   "Return the date of YEAR on which daylight saving time starts.
 404 This function respects the value of `calendar-dst-check-each-year-flag'."
 405   (or (let ((expr (if calendar-dst-check-each-year-flag
 406                       (cadr (calendar-dst-find-startend year))
 407                     (nth 4 calendar-current-time-zone-cache))))
 408         (if expr (eval expr)))
 409       ;; New US rules commencing 2007.  ftp://elsie.nci.nih.gov/pub/.
 410       (and (not (zerop calendar-daylight-time-offset))
 411            (calendar-nth-named-day 2 0 3 year))))
 412
 413 (defun calendar-dst-ends (year)
 414   "Return the date of YEAR on which daylight saving time ends.
 415 This function respects the value of `calendar-dst-check-each-year-flag'."
 416   (or (let ((expr (if calendar-dst-check-each-year-flag
 417                       (nth 2 (calendar-dst-find-startend year))
 418                     (nth 5 calendar-current-time-zone-cache))))
 419         (if expr (eval expr)))
 420       ;; New US rules commencing 2007.  ftp://elsie.nci.nih.gov/pub/.
 421       (and (not (zerop calendar-daylight-time-offset))
 422            (calendar-nth-named-day 1 0 11 year))))
 423
 424 ;; used by calc, solar.
 425 (defun dst-in-effect (date)
 426   "True if on absolute DATE daylight saving time is in effect.
 427 Fractional part of DATE is local standard time of day."
 428   (let* ((year (calendar-extract-year
 429                 (calendar-gregorian-from-absolute (floor date))))
 430          (dst-starts-gregorian (eval calendar-daylight-savings-starts))
 431          (dst-ends-gregorian (eval calendar-daylight-savings-ends))
 432          (dst-starts (and dst-starts-gregorian
 433                           (+ (calendar-absolute-from-gregorian
 434                               dst-starts-gregorian)
 435                              (/ calendar-daylight-savings-starts-time
 436                                 60.0 24.0))))
 437          (dst-ends (and dst-ends-gregorian
 438                         (+ (calendar-absolute-from-gregorian
 439                             dst-ends-gregorian)
 440                            (/ (- calendar-daylight-savings-ends-time
 441                                  calendar-daylight-time-offset)
 442                               60.0 24.0)))))
 443     (and dst-starts dst-ends
 444          (if (< dst-starts dst-ends)
 445              (and (<= dst-starts date) (< date dst-ends))
 446            (or (<= dst-starts date) (< date dst-ends))))))
 447
 448 ;; used by calc, lunar, solar.
 449 (defun dst-adjust-time (date time)
 450   "Adjust, to account for dst on DATE, decimal fraction standard TIME.
 451 Returns a list (date adj-time zone) where `date' and `adj-time' are the values
 452 adjusted for `zone'; here `date' is a list (month day year), `adj-time' is a
 453 decimal fraction time, and `zone' is a string.
 454
 455 Conversion to daylight saving time is done according to
 456 `calendar-daylight-savings-starts', `calendar-daylight-savings-ends',
 457 `calendar-daylight-savings-starts-time',
 458 `calendar-daylight-savings-ends-time', and `calendar-daylight-time-offset'."
 459   (let* ((rounded-abs-date (+ (calendar-absolute-from-gregorian date)
 460                               (/ (round (* 60 time)) 60.0 24.0)))
 461          (dst (dst-in-effect rounded-abs-date))
 462          (time-zone (if dst
 463                         calendar-daylight-time-zone-name
 464                       calendar-standard-time-zone-name))
 465          (time (+ rounded-abs-date
 466                   (if dst (/ calendar-daylight-time-offset 24.0 60.0) 0))))
 467     (list (calendar-gregorian-from-absolute (truncate time))
 468           (* 24.0 (- time (truncate time)))
 469           time-zone)))
 470
 471 (provide 'cal-dst)
 472
 473 ;;; cal-dst.el ends here