configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008, 2009  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.62)
  25 AC_INIT(emacs, 23.1.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 if test "$with_hesiod" != no; then
  95   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  96 fi
  97
  98 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
  99
 100 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 101 if test "$with_sync_input" = yes; then
 102    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 103 fi
 104
 105 dnl FIXME currently it is not the last.
 106 dnl This should be the last --with option, because --with-x is
 107 dnl added later on when we find the path of X, and it's best to
 108 dnl keep them together visually.
 109 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 110  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 111 [         case "${withval}" in
 112             y | ye | yes )      val=gtk ;;
 113             n | no )            val=no  ;;
 114             l | lu | luc | luci | lucid )       val=lucid ;;
 115             a | at | ath | athe | athen | athena )      val=athena ;;
 116             m | mo | mot | moti | motif )       val=motif ;;
 117             g | gt | gtk  )     val=gtk ;;
 118             * )
 119 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 120 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 121 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 122             ;;
 123           esac
 124           with_x_toolkit=$val
 125 ])
 126
 127 dnl _ON results in a '--without' option in the --help output, so
 128 dnl the help text should refer to "don't compile", etc.
 129 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 130 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 131 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 132 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 133 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 134 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 135
 136 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 137 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 138 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 139
 140 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 141 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 142 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 143 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 144
 145 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 146 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 147 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 148
 149 ## For the times when you want to build Emacs but don't have
 150 ## a suitable makeinfo, and can live without the manuals.
 151 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 152 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 153
 154 dnl Can remove these in Emacs 24.
 155 AC_ARG_WITH([gtk],,
 156   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 157 specify a toolkit.])],,)
 158
 159 AC_ARG_WITH([gcc],,
 160   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 161 variable to specify a compiler.])],,)
 162
 163 AC_ARG_WITH([pkg-config-prog],dnl
 164 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 165                   [path to pkg-config for finding GTK and librsvg])])
 166 if test "X${with_pkg_config_prog}" != X; then
 167    if test "${with_pkg_config_prog}" != yes; then
 168       PKG_CONFIG="${with_pkg_config_prog}"
 169    fi
 170 fi
 171
 172 AC_ARG_WITH([gnustep-conf],dnl
 173 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 174 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 175   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 176 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 177      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 178
 179 AC_ARG_ENABLE(ns-self-contained,
 180 [AS_HELP_STRING([--disable-ns-self-contained],
 181                 [disable self contained build under NeXTstep])],
 182    EN_NS_SELF_CONTAINED=$enableval,
 183    EN_NS_SELF_CONTAINED=yes)
 184
 185 AC_ARG_ENABLE(asserts,
 186 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 187       USE_XASSERTS=$enableval,
 188       USE_XASSERTS=no)
 189
 190 AC_ARG_ENABLE(maintainer-mode,
 191 [AS_HELP_STRING([--enable-maintainer-mode],
 192                 [enable make rules and dependencies not useful (and sometimes
 193                  confusing) to the casual installer])],
 194       USE_MAINTAINER_MODE=$enableval,
 195       USE_MAINTAINER_MODE=no)
 196 if test $USE_MAINTAINER_MODE = yes; then
 197   MAINT=
 198 else
 199   MAINT=#
 200 fi
 201 AC_SUBST(MAINT)
 202
 203 AC_ARG_ENABLE(locallisppath,
 204 [AS_HELP_STRING([--enable-locallisppath=PATH],
 205                 [directories Emacs should search for lisp files specific
 206                  to this site])],
 207 if test "${enableval}" = "no"; then
 208   locallisppath=
 209 elif test "${enableval}" != "yes"; then
 210   locallisppath=${enableval}
 211 fi)
 212
 213 AC_ARG_ENABLE(checking,
 214 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 215                 [enable expensive run-time checks.  With LIST,
 216                  enable only specific categories of checks.
 217                  Categories are: all,yes,no.
 218                  Flags are: stringbytes, stringoverrun, stringfreelist,
 219                  xmallocoverrun, conslist])],
 220 [ac_checking_flags="${enableval}"],[])
 221 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 222 for check in $ac_checking_flags
 223 do
 224         case $check in
 225         # these set all the flags to specific states
 226         yes)            ac_enable_checking=1 ;;
 227         no)             ac_enable_checking= ;
 228                         ac_gc_check_stringbytes= ;
 229                         ac_gc_check_string_overrun= ;
 230                         ac_gc_check_string_free_list= ;
 231                         ac_xmalloc_overrun= ;
 232                         ac_gc_check_cons_list= ;;
 233         all)            ac_enable_checking=1 ;
 234                         ac_gc_check_stringbytes=1 ;
 235                         ac_gc_check_string_overrun=1 ;
 236                         ac_gc_check_string_free_list=1 ;
 237                         ac_xmalloc_overrun=1 ;
 238                         ac_gc_check_cons_list=1 ;;
 239         # these enable particular checks
 240         stringbytes)    ac_gc_check_stringbytes=1 ;;
 241         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 242         stringfreelist) ac_gc_check_string_free_list=1 ;;
 243         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 244         conslist)       ac_gc_check_cons_list=1 ;;
 245         *)      AC_MSG_ERROR(unknown check category $check) ;;
 246         esac
 247 done
 248 IFS="$ac_save_IFS"
 249
 250 if test x$ac_enable_checking != x ; then
 251   AC_DEFINE(ENABLE_CHECKING, 1,
 252 [Enable expensive run-time checking of data types?])
 253 fi
 254 if test x$ac_gc_check_stringbytes != x ; then
 255   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 256 [Define this temporarily to hunt a bug.  If defined, the size of
 257    strings is redundantly recorded in sdata structures so that it can
 258    be compared to the sizes recorded in Lisp strings.])
 259 fi
 260 if test x$ac_gc_check_stringoverrun != x ; then
 261   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 262 [Define this to check for short string overrun.])
 263 fi
 264 if test x$ac_gc_check_string_free_list != x ; then
 265   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 266 [Define this to check the string free list.])
 267 fi
 268 if test x$ac_xmalloc_overrun != x ; then
 269   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 270 [Define this to check for malloc buffer overrun.])
 271 fi
 272 if test x$ac_gc_check_cons_list != x ; then
 273   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 274 [Define this to check for errors in cons list.])
 275 fi
 276
 277 AC_ARG_ENABLE(profiling,
 278 [AS_HELP_STRING([--enable-profiling],
 279                 [build emacs with profiling support.
 280                  This might not work on all platforms])],
 281 [ac_enable_profiling="${enableval}"],[])
 282 if test x$ac_enable_profiling != x ; then
 283    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 284    PROFILING_LDFLAGS="-pg"
 285 else
 286    PROFILING_CFLAGS=
 287    PROFILING_LDFLAGS=
 288 fi
 289
 290 AC_ARG_ENABLE(autodepend,
 291 [AS_HELP_STRING([--enable-autodepend],
 292                 [automatically generate dependencies to .h-files.
 293                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 294                  found])],
 295 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 296
 297 #### Make srcdir absolute, if it isn't already.  It's important to
 298 #### avoid running the path through pwd unnecessarily, since pwd can
 299 #### give you automounter prefixes, which can go away.  We do all this
 300 #### so Emacs can find its files when run uninstalled.
 301 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 302 unset CDPATH
 303 case "${srcdir}" in
 304   /* ) ;;
 305   . )
 306     ## We may be able to use the $PWD environment variable to make this
 307     ## absolute.  But sometimes PWD is inaccurate.
 308     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 309     ## but that tested only for a well-formed and valid PWD,
 310     ## it did not object when PWD was well-formed and valid but just wrong.
 311     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 312     then
 313       srcdir="$PWD"
 314     else
 315       srcdir="`(cd ${srcdir}; pwd)`"
 316     fi
 317   ;;
 318   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 319 esac
 320
 321 #### Check if the source directory already has a configured system in it.
 322 if test `pwd` != `(cd ${srcdir} && pwd)` \
 323    && test -f "${srcdir}/src/config.h" ; then
 324   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 325    as a build directory right now; it has been configured in its own
 326    right.  To configure in another directory as well, you MUST
 327    use GNU make.  If you do not have GNU make, then you must
 328    now do `make distclean' in ${srcdir},
 329    and then run $0 again.]])
 330 fi
 331
 332 #### Given the configuration name, set machfile and opsysfile to the
 333 #### names of the m/*.h and s/*.h files we should use.
 334
 335 ### Canonicalize the configuration name.
 336
 337 AC_CANONICAL_HOST
 338 canonical=$host
 339 configuration=${host_alias-${build_alias-$host}}
 340
 341 dnl This used to use changequote, but, apart from `changequote is evil'
 342 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 343 dnl the great gob of text.  Thus it's not processed for possible expansion.
 344 dnl Just make sure the brackets remain balanced.
 345 dnl
 346 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 347 dnl indicated by comments.
 348 dnl quotation begins
 349 [
 350
 351 ### If you add support for a new configuration, add code to this
 352 ### switch statement to recognize your configuration name and select
 353 ### the appropriate operating system and machine description files.
 354
 355 ### You would hope that you could choose an m/*.h file pretty much
 356 ### based on the machine portion of the configuration name, and an s-
 357 ### file based on the operating system portion.  However, it turns out
 358 ### that each m/*.h file is pretty manufacturer-specific - for
 359 ### example mips.h is MIPS
 360 ### So we basically have to have a special case for each
 361 ### configuration name.
 362 ###
 363 ### As far as handling version numbers on operating systems is
 364 ### concerned, make sure things will fail in a fixable way.  If
 365 ### /etc/MACHINES doesn't say anything about version numbers, be
 366 ### prepared to handle anything reasonably.  If version numbers
 367 ### matter, be sure /etc/MACHINES says something about it.
 368 ###
 369 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 370 ### "System V Release 4"; he writes, "The old convention encouraged
 371 ### confusion between `system' and `release' levels'."
 372
 373 machine='' opsys='' unported=no
 374 case "${canonical}" in
 375
 376   ## FreeBSD ports
 377   *-*-freebsd* )
 378     opsys=freebsd
 379     case "${canonical}" in
 380       alpha*-*-freebsd*)        machine=alpha ;;
 381       arm*-*-freebsd*)          machine=arm ;;
 382       ia64-*-freebsd*)          machine=ia64 ;;
 383       sparc-*-freebsd*)         machine=sparc ;;
 384       sparc64-*-freebsd*)       machine=sparc ;;
 385       powerpc-*-freebsd*)       machine=macppc ;;
 386       i[3456]86-*-freebsd*)     machine=intel386 ;;
 387       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 388     esac
 389   ;;
 390
 391   ## FreeBSD kernel + glibc based userland
 392   *-*-kfreebsd*gnu* )
 393     opsys=gnu-kfreebsd
 394     case "${canonical}" in
 395       alpha*-*-kfreebsd*)       machine=alpha ;;
 396       ia64-*-kfreebsd*)         machine=ia64 ;;
 397       sparc-*-kfreebsd*)        machine=sparc ;;
 398       sparc64-*-kfreebsd*)      machine=sparc ;;
 399       powerpc-*-kfreebsd*)      machine=macppc ;;
 400       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 401       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 402     esac
 403   ;;
 404
 405   ## NetBSD ports
 406   *-*-netbsd* )
 407     opsys=netbsd
 408     if test -f /usr/lib/crti.o; then]
 409 dnl The close and open brackets here are because this section is quoted --
 410 dnl see the `changequote' comment above.
 411       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 412 [   fi
 413
 414     case "${canonical}" in
 415       alpha*-*-netbsd*) machine=alpha ;;
 416       i[3456]86-*-netbsd*) machine=intel386 ;;
 417       mips-*-netbsd*)   machine=mips ;;
 418       mipsel-*-netbsd*) machine=mips ;;
 419       mipseb-*-netbsd*) machine=mips ;;
 420       powerpc-*-netbsd*) machine=macppc ;;
 421       sparc*-*-netbsd*) machine=sparc ;;
 422       vax-*-netbsd*)    machine=vax ;;
 423       arm-*-netbsd*)    machine=arm ;;
 424       x86_64-*-netbsd*) machine=amdx86-64 ;;
 425       hppa-*-netbsd*)   machine=hp800 ;;
 426       m68k-*-netbsd*)   machine=m68k ;;
 427     esac
 428   ;;
 429
 430   ## OpenBSD ports
 431   *-*-openbsd* )
 432     opsys=openbsd
 433     case "${canonical}" in
 434       alpha*-*-openbsd*)        machine=alpha ;;
 435       arm-*-openbsd*)          machine=arm ;;
 436       i386-*-openbsd*)         machine=intel386 ;;
 437       powerpc-*-openbsd*)      machine=macppc ;;
 438       sparc*-*-openbsd*)       machine=sparc ;;
 439       vax-*-openbsd*)          machine=vax ;;
 440       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 441       hppa-*-openbsd*)         machine=hp800 ;;
 442     esac
 443   ;;
 444
 445   ## LynxOS ports
 446   *-*-lynxos* )
 447     opsys=lynxos
 448     case "${canonical}" in
 449       i[3456]86-*-lynxos*) machine=intel386 ;;
 450       powerpc-*-lynxos*) machine=powerpc ;;
 451     esac
 452   ;;
 453
 454   alpha*-*-linux-gnu* )
 455     machine=alpha opsys=gnu-linux
 456   ;;
 457
 458   arm*-*-linux-gnu* )
 459     machine=arm opsys=gnu-linux
 460   ;;
 461
 462   ## Apple Darwin / Mac OS X
 463   *-apple-darwin* )
 464     case "${canonical}" in
 465       i[3456]86-* )  machine=intel386 ;;
 466       powerpc-* )    machine=macppc ;;
 467       x86_64-* )     machine=amdx86-64 ;;
 468       * )            unported=yes ;;
 469     esac
 470     opsys=darwin
 471     # Define CPP as follows to make autoconf work correctly.
 472     CPP="${CC-cc} -E -no-cpp-precomp"
 473     # Use fink packages if available.
 474     if test -d /sw/include && test -d /sw/lib; then
 475       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 476       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 477       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 478     fi
 479   ;;
 480
 481   ## HP 9000 series 700 and 800, running HP/UX
 482   hppa*-hp-hpux10.2* )
 483     machine=hp800 opsys=hpux10-20
 484   ;;
 485   hppa*-hp-hpux1[1-9]* )
 486     machine=hp800 opsys=hpux11
 487     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 488   ;;
 489
 490   hppa*-*-linux-gnu* )
 491     machine=hp800 opsys=gnu-linux
 492   ;;
 493
 494   ## IBM machines
 495   s390-*-linux-gnu* )
 496     machine=ibms390 opsys=gnu-linux
 497   ;;
 498   s390x-*-linux-gnu* )
 499     machine=ibms390x opsys=gnu-linux
 500   ;;
 501   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 502     machine=ibmrs6000 opsys=aix4-2
 503   ;;
 504   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 505     machine=ibmrs6000 opsys=aix4-2
 506   ;;
 507   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 508     machine=ibmrs6000 opsys=aix4-2
 509   ;;
 510   rs6000-ibm-aix6* | powerpc-ibm-aix6*  )
 511     machine=ibmrs6000 opsys=aix4-2
 512   ;;
 513
 514   ## Macintosh PowerPC
 515   powerpc*-*-linux-gnu* )
 516     machine=macppc opsys=gnu-linux
 517   ;;
 518
 519   ## Silicon Graphics machines
 520   ## Iris 4D
 521   mips-sgi-irix6.5 )
 522     machine=iris4d opsys=irix6-5
 523     # Without defining _LANGUAGE_C, things get masked out in the headers
 524     # so that, for instance, grepping for `free' in stdlib.h fails and
 525     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 526     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 527     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 528   ;;
 529
 530   ## Suns
 531   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 532     machine=sparc opsys=gnu-linux
 533   ;;
 534
 535   *-sun-solaris* \
 536     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 537     | x86_64-*-solaris2*    | x86_64-*-sunos5*    \
 538     | powerpc*-*-solaris2*  | rs6000-*-solaris2*)
 539     case "${canonical}" in
 540       i[3456]86-*-* )     machine=intel386 ;;
 541       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 542       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 543       sparc* )          machine=sparc ;;
 544       * )               unported=yes ;;
 545     esac
 546     case "${canonical}" in
 547       *-sunos5.3* | *-solaris2.3* )
 548                 opsys=sol2-3
 549                 NON_GNU_CPP=/usr/ccs/lib/cpp
 550                 ;;
 551       *-sunos5.4* | *-solaris2.4* )
 552                 opsys=sol2-4
 553                 NON_GNU_CPP=/usr/ccs/lib/cpp
 554                 RANLIB="ar -ts"
 555                 ;;
 556       *-sunos5.5* | *-solaris2.5* )
 557                 opsys=sol2-5
 558                 NON_GNU_CPP=/usr/ccs/lib/cpp
 559                 RANLIB="ar -ts"
 560                 ;;
 561       *-sunos5.6* | *-solaris2.6* )
 562                 opsys=sol2-6
 563                 NON_GNU_CPP=/usr/ccs/lib/cpp
 564                 RANLIB="ar -ts"
 565                 ;;
 566       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 567                 opsys=sol2-6
 568                 emacs_check_sunpro_c=yes
 569                 NON_GNU_CPP=/usr/ccs/lib/cpp
 570                 ;;
 571       *-sunos5* | *-solaris* )
 572                 opsys=sol2-10
 573                 emacs_check_sunpro_c=yes
 574                 NON_GNU_CPP=/usr/ccs/lib/cpp
 575                 ;;
 576     esac
 577     ## Watch out for a compiler that we know will not work.
 578     case "${canonical}" in
 579      *-solaris* | *-sunos5* )
 580                 if [ "x$CC" = x/usr/ucb/cc ]; then
 581                   ## /usr/ucb/cc doesn't work;
 582                   ## we should find some other compiler that does work.
 583                   unset CC
 584                 fi
 585                 ;;
 586       *) ;;
 587     esac
 588   ;;
 589
 590   ## IA-64
 591   ia64*-*-linux* )
 592     machine=ia64 opsys=gnu-linux
 593   ;;
 594
 595   ## Intel 386 machines where we don't care about the manufacturer
 596   i[3456]86-*-* )
 597     machine=intel386
 598     case "${canonical}" in
 599       *-cygwin )                opsys=cygwin ;;
 600       *-darwin* )               opsys=darwin
 601                                 CPP="${CC-cc} -E -no-cpp-precomp"
 602                                 ;;
 603       *-linux-gnu* )            opsys=gnu-linux ;;
 604       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 605       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 606       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 607       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 608     esac
 609   ;;
 610
 611   ## m68k Linux-based GNU system
 612   m68k-*-linux-gnu* )
 613     machine=m68k opsys=gnu-linux
 614   ;;
 615
 616   ## Mips Linux-based GNU system
 617   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 618     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 619     machine=mips opsys=gnu-linux
 620   ;;
 621
 622   ## AMD x86-64 Linux-based GNU system
 623   x86_64-*-linux-gnu* )
 624     machine=amdx86-64 opsys=gnu-linux
 625   ;;
 626
 627   ## Tensilica Xtensa Linux-based GNU system
 628   xtensa*-*-linux-gnu* )
 629     machine=xtensa opsys=gnu-linux
 630     ;;
 631
 632   ## SuperH Linux-based GNU system
 633   sh[34]*-*-linux-gnu* )
 634     machine=sh3 opsys=gnu-linux
 635   ;;
 636
 637   * )
 638     unported=yes
 639   ;;
 640 esac
 641
 642 ### If the code above didn't choose an operating system, just choose
 643 ### an operating system based on the configuration name.  You really
 644 ### only want to use this when you have no idea what the right
 645 ### operating system is; if you know what operating systems a machine
 646 ### runs, it's cleaner to make it explicit in the case statement
 647 ### above.
 648 if test x"${opsys}" = x; then
 649   case "${canonical}" in
 650     *-gnu* )                            opsys=gnu ;;
 651     *-sysv4.2uw* )                      opsys=unixware ;;
 652     *-sysv5uw* )                        opsys=unixware ;;
 653     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 654     *-sysv4.1* | *-sysvr4.1* )
 655         NON_GNU_CPP=/usr/lib/cpp
 656         opsys=usg5-4 ;;
 657     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 658         if [ x$NON_GNU_CPP = x ]; then
 659           if [ -f /usr/ccs/lib/cpp ]; then
 660             NON_GNU_CPP=/usr/ccs/lib/cpp
 661           else
 662             NON_GNU_CPP=/lib/cpp
 663           fi
 664         fi
 665         opsys=usg5-4-2 ;;
 666     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 667     * )
 668       unported=yes
 669     ;;
 670   esac
 671 fi
 672
 673 ]
 674 dnl quotation ends
 675
 676 if test $unported = yes; then
 677   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 678 Check `etc/MACHINES' for recognized configuration names.])
 679 fi
 680
 681 machfile="m/${machine}.h"
 682 opsysfile="s/${opsys}.h"
 683
 684
 685 #### Choose a compiler.
 686 test -n "$CC" && cc_specified=yes
 687
 688 # Save the value of CFLAGS that the user specified.
 689 SPECIFIED_CFLAGS="$CFLAGS"
 690
 691 dnl Sets GCC=yes if using gcc.
 692 AC_PROG_CC
 693
 694 # On Suns, sometimes $CPP names a directory.
 695 if test -n "$CPP" && test -d "$CPP"; then
 696   CPP=
 697 fi
 698
 699 ## If not using gcc, and on Solaris, and no CPP specified, see if
 700 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 701 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 702  test x"$CPP" = x; then
 703   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 704   AC_CACHE_VAL(emacs_cv_sunpro_c,
 705   [AC_TRY_LINK([],
 706 [#ifndef __SUNPRO_C
 707 fail;
 708 #endif
 709 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 710   AC_MSG_RESULT($emacs_cv_sunpro_c)
 711
 712   if test x"$emacs_cv_sunpro_c" = xyes; then
 713     NON_GNU_CPP="$CC -E -Xs"
 714   fi
 715 fi
 716
 717 #### Some systems specify a CPP to use unless we are using GCC.
 718 #### Now that we know whether we are using GCC, we can decide whether
 719 #### to use that one.
 720 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 721 then
 722   CPP="$NON_GNU_CPP"
 723 fi
 724
 725 #### Some systems specify a CC to use unless we are using GCC.
 726 #### Now that we know whether we are using GCC, we can decide whether
 727 #### to use that one.
 728 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 729   test x$cc_specified != xyes
 730 then
 731   CC="$NON_GNU_CC"
 732 fi
 733
 734 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 735 then
 736   CC="$CC $GCC_TEST_OPTIONS"
 737 fi
 738
 739 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 740 then
 741   CC="$CC $NON_GCC_TEST_OPTIONS"
 742 fi
 743
 744 dnl checks for Unix variants
 745 AC_USE_SYSTEM_EXTENSIONS
 746
 747 ### Use -Wno-pointer-sign if the compiler supports it
 748 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 749 SAVE_CFLAGS="$CFLAGS"
 750 CFLAGS="$CFLAGS -Wno-pointer-sign"
 751 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 752 if test $has_option = yes; then
 753    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 754 fi
 755 AC_MSG_RESULT($has_option)
 756 CFLAGS="$SAVE_CFLAGS"
 757 unset has_option
 758 unset SAVE_CFLAGS
 759
 760 #### Some other nice autoconf tests.
 761
 762 dnl checks for programs
 763 AC_PROG_LN_S
 764 AC_PROG_CPP
 765 AC_PROG_INSTALL
 766 if test "x$RANLIB" = x; then
 767   AC_PROG_RANLIB
 768 fi
 769 AC_PATH_PROG(INSTALL_INFO, install-info)
 770 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 771 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 772 dnl Don't use GZIP, which is used by gzip for additional parameters.
 773 AC_PATH_PROG(GZIP_PROG, gzip)
 774
 775
 776 ## Need makeinfo >= 4.6 (?) to build the manuals.
 777 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 778 dnl By this stage, configure has already checked for egrep and set EGREP,
 779 dnl or exited with an error if no egrep was found.
 780 if test "$MAKEINFO" != "no" && \
 781   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 782    MAKEINFO=no
 783 fi
 784
 785 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 786 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 787 ## therefore in the category of "special tools" not normally required, which
 788 ## configure does not have to check for (eg autoconf itself).
 789 ## In a CVS checkout on the other hand, the manuals are not included.
 790 ## So makeinfo is a requirement to build from CVS, and configure
 791 ## should test for it as it does for any other build requirement.
 792 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 793 ## with pre-built manuals, from a CVS checkout.
 794 if test "$MAKEINFO" = "no"; then
 795   if test "x${with_makeinfo}" = "xno"; then
 796     MAKEINFO=off
 797   elif ! test -e $srcdir/info/emacs; then
 798     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 799 source tree does not seem to have pre-built manuals in the `info' directory.
 800 Either install a suitable version of makeinfo, or re-run configure
 801 with the `--without-makeinfo' option to build without the manuals.] )
 802   fi
 803 fi
 804
 805 dnl Add our options to ac_link now, after it is set up.
 806
 807 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 808 then
 809   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 810 fi
 811
 812 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 813 then
 814   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 815 fi
 816
 817 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 818 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 819 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 820 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 821 dnl if not built to support GNU ld.
 822
 823 late_LDFLAGS=$LDFLAGS
 824 if test "$GCC" = yes; then
 825   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 826 else
 827   LDFLAGS="$LDFLAGS -znocombreloc"
 828 fi
 829
 830 AC_MSG_CHECKING([for -znocombreloc])
 831 AC_LINK_IFELSE([main(){return 0;}],
 832   [AC_MSG_RESULT(yes)],
 833   LDFLAGS=$late_LDFLAGS
 834   [AC_MSG_RESULT(no)])
 835
 836 #### Extract some information from the operating system and machine files.
 837
 838 AC_CHECKING([the machine- and system-dependent files to find out
 839  - which libraries the lib-src programs will want, and
 840  - whether the GNU malloc routines are usable])
 841
 842 ### First figure out CFLAGS (which we use for running the compiler here)
 843 ### and REAL_CFLAGS (which we use for real compilation).
 844 ### The two are the same except on a few systems, where they are made
 845 ### different to work around various lossages.  For example,
 846 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 847 ### as implying static linking.
 848
 849 ### If the CFLAGS env var is specified, we use that value
 850 ### instead of the default.
 851
 852 ### It's not important that this name contain the PID; you can't run
 853 ### two configures in the same directory and have anything work
 854 ### anyway.
 855 tempcname="conftest.c"
 856
 857 echo '
 858 #include "'${srcdir}'/src/'${opsysfile}'"
 859 #include "'${srcdir}'/src/'${machfile}'"
 860 #ifndef LIBS_MACHINE
 861 #define LIBS_MACHINE
 862 #endif
 863 #ifndef LIBS_SYSTEM
 864 #define LIBS_SYSTEM
 865 #endif
 866 #ifndef C_SWITCH_SYSTEM
 867 #define C_SWITCH_SYSTEM
 868 #endif
 869 #ifndef C_SWITCH_MACHINE
 870 #define C_SWITCH_MACHINE
 871 #endif
 872 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 873 configure___ c_switch_system=C_SWITCH_SYSTEM
 874 configure___ c_switch_machine=C_SWITCH_MACHINE
 875
 876 #ifndef LIB_X11_LIB
 877 #define LIB_X11_LIB -lX11
 878 #endif
 879
 880 #ifndef LIBX11_SYSTEM
 881 #define LIBX11_SYSTEM
 882 #endif
 883 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
 884
 885 #ifdef UNEXEC
 886 configure___ unexec=UNEXEC
 887 #else
 888 configure___ unexec=unexec.o
 889 #endif
 890
 891 #ifdef SYSTEM_MALLOC
 892 configure___ system_malloc=yes
 893 #else
 894 configure___ system_malloc=no
 895 #endif
 896
 897 #ifdef USE_MMAP_FOR_BUFFERS
 898 configure___ use_mmap_for_buffers=yes
 899 #else
 900 configure___ use_mmap_for_buffers=no
 901 #endif
 902
 903 #ifndef C_DEBUG_SWITCH
 904 #define C_DEBUG_SWITCH -g
 905 #endif
 906
 907 #ifndef C_OPTIMIZE_SWITCH
 908 #ifdef __GNUC__
 909 #define C_OPTIMIZE_SWITCH -O2
 910 #else
 911 #define C_OPTIMIZE_SWITCH -O
 912 #endif
 913 #endif
 914
 915 #ifndef C_WARNINGS_SWITCH
 916 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 917 #endif
 918
 919 #ifndef LD_SWITCH_MACHINE
 920 #define LD_SWITCH_MACHINE
 921 #endif
 922
 923 #ifndef LD_SWITCH_SYSTEM
 924 #define LD_SWITCH_SYSTEM
 925 #endif
 926
 927 #ifndef LD_SWITCH_X_SITE_AUX
 928 #define LD_SWITCH_X_SITE_AUX
 929 #endif
 930
 931 configure___ ld_switch_system=LD_SWITCH_SYSTEM
 932 configure___ ld_switch_machine=LD_SWITCH_MACHINE
 933
 934 #ifdef THIS_IS_CONFIGURE
 935
 936 /* Get the CFLAGS for tests in configure.  */
 937 #ifdef __GNUC__
 938 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 939 #else
 940 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 941 #endif
 942
 943 #else /* not THIS_IS_CONFIGURE */
 944
 945 /* Get the CFLAGS for real compilation.  */
 946 #ifdef __GNUC__
 947 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH ${PROFILING_CFLAGS} '${SPECIFIED_CFLAGS}'
 948 #else
 949 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 950 #endif
 951
 952 #endif /* not THIS_IS_CONFIGURE */
 953 ' > ${tempcname}
 954
 955 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 956
 957 # The value of CPP is a quoted variable reference, so we need to do this
 958 # to get its actual value...
 959 CPP=`eval "echo $CPP"`
 960 [eval `${CPP} -Isrc ${tempcname} \
 961        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 962 if test "x$SPECIFIED_CFLAGS" = x; then
 963   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 964          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 965 else
 966   REAL_CFLAGS="$CFLAGS"
 967 fi]
 968 rm ${tempcname}
 969
 970 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
 971
 972 ### Make sure subsequent tests use flags consistent with the build flags.
 973
 974 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 975   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 976 else
 977   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
 978 fi
 979
 980 dnl For AC_FUNC_GETLOADAVG, at least:
 981 AC_CONFIG_LIBOBJ_DIR(src)
 982
 983 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 984 AC_SYS_LARGEFILE
 985
 986
 987 ### The standard library on x86-64 and s390x GNU/Linux distributions can
 988 ### be located in either /usr/lib64 or /usr/lib.
 989 ### In some rare cases, /usr/lib64 exists but does not contain the
 990 ### relevant files (bug#1287).  Hence test for crtn.o.
 991 case "${canonical}" in
 992   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
 993     if test -e /usr/lib64/crtn.o; then
 994       AC_DEFINE(HAVE_LIB64_DIR, 1,
 995         [Define to 1 if the directory /usr/lib64 exists.])
 996 fi
 997 esac
 998
 999 dnl This function defintion taken from Gnome 2.0
1000 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1001 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1002 dnl also defines GSTUFF_PKG_ERRORS on error
1003 AC_DEFUN([PKG_CHECK_MODULES], [
1004   succeeded=no
1005
1006   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1007
1008   if test "$PKG_CONFIG" = "no" ; then
1009      ifelse([$4], , [AC_MSG_ERROR([
1010       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1011   else
1012      PKG_CONFIG_MIN_VERSION=0.9.0
1013      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1014         AC_MSG_CHECKING(for $2)
1015
1016         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1017             AC_MSG_RESULT(yes)
1018             succeeded=yes
1019
1020             AC_MSG_CHECKING($1_CFLAGS)
1021             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1022             AC_MSG_RESULT($$1_CFLAGS)
1023
1024             AC_MSG_CHECKING($1_LIBS)
1025             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1026             AC_MSG_RESULT($$1_LIBS)
1027         else
1028             AC_MSG_RESULT(no)
1029             $1_CFLAGS=""
1030             $1_LIBS=""
1031             ## If we have a custom action on failure, don't print errors, but
1032             ## do set a variable so people can do so.
1033             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1034             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1035         fi
1036
1037         AC_SUBST($1_CFLAGS)
1038         AC_SUBST($1_LIBS)
1039      else
1040         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1041         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1042      fi
1043   fi
1044
1045   if test $succeeded = yes; then
1046      ifelse([$3], , :, [$3])
1047   else
1048      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1049   fi
1050 ])
1051
1052
1053 if test "${with_sound}" != "no"; then
1054   # Sound support for GNU/Linux and the free BSDs.
1055   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1056   # Emulation library used on NetBSD.
1057   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1058   AC_SUBST(LIBSOUND)
1059
1060   ALSA_REQUIRED=1.0.0
1061   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1062   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1063   if test $HAVE_ALSA = yes; then
1064     SAVE_CFLAGS="$CFLAGS"
1065     SAVE_LDFLAGS="$LDFLAGS"
1066     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1067     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1068     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1069                     emacs_alsa_normal=yes,
1070                     emacs_alsa_normal=no)
1071     if test "$emacs_alsa_normal" != yes; then
1072       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1073                      [snd_lib_error_set_handler (0);],
1074                      emacs_alsa_subdir=yes,
1075                      emacs_alsa_subdir=no)
1076       if test "$emacs_alsa_subdir" != yes; then
1077         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1078       fi
1079       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1080     fi
1081
1082     CFLAGS="$SAVE_CFLAGS"
1083     LDFLAGS="$SAVE_LDFLAGS"
1084     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1085     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1086     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1087   fi
1088   AC_SUBST(CFLAGS_SOUND)
1089 fi
1090
1091 dnl checks for header files
1092 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1093   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1094   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1095   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1096   sys/utsname.h pwd.h)
1097
1098 AC_MSG_CHECKING(if personality LINUX32 can be set)
1099 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1100                emacs_cv_personality_linux32=yes,
1101                emacs_cv_personality_linux32=no)
1102 AC_MSG_RESULT($emacs_cv_personality_linux32)
1103
1104 if test $emacs_cv_personality_linux32 = yes; then
1105   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1106             [Define to 1 if personality LINUX32 can be set.])
1107 fi
1108
1109 dnl On Solaris 8 there's a compilation warning for term.h because
1110 dnl it doesn't define `bool'.
1111 AC_CHECK_HEADERS(term.h, , , -)
1112 AC_HEADER_STDC
1113 AC_HEADER_TIME
1114 AC_CHECK_DECLS([sys_siglist])
1115 if test $ac_cv_have_decl_sys_siglist != yes; then
1116   # For Tru64, at least:
1117   AC_CHECK_DECLS([__sys_siglist])
1118   if test $ac_cv_have_decl___sys_siglist = yes; then
1119     AC_DEFINE(sys_siglist, __sys_siglist,
1120               [Define to any substitute for sys_siglist.])
1121   fi
1122 fi
1123 AC_HEADER_SYS_WAIT
1124
1125 dnl Some systems have utime.h but don't declare the struct anyplace.
1126 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1127 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1128 #include <sys/time.h>
1129 #include <time.h>
1130 #else
1131 #ifdef HAVE_SYS_TIME_H
1132 #include <sys/time.h>
1133 #else
1134 #include <time.h>
1135 #endif
1136 #endif
1137 #ifdef HAVE_UTIME_H
1138 #include <utime.h>
1139 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1140   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1141 if test $emacs_cv_struct_utimbuf = yes; then
1142   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1143 fi
1144
1145 dnl checks for typedefs
1146 AC_TYPE_SIGNAL
1147
1148 dnl Check for speed_t typedef.
1149 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1150   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1151     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1152 if test $emacs_cv_speed_t = yes; then
1153   AC_DEFINE(HAVE_SPEED_T, 1,
1154            [Define to 1 if `speed_t' is declared by <termios.h>.])
1155 fi
1156
1157 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1158 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1159 #include <sys/time.h>
1160 #include <time.h>
1161 #else
1162 #ifdef HAVE_SYS_TIME_H
1163 #include <sys/time.h>
1164 #else
1165 #include <time.h>
1166 #endif
1167 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1168   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1169 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1170 if test $emacs_cv_struct_timeval = yes; then
1171   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1172 fi
1173
1174 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1175 AC_TRY_COMPILE([#include <math.h>],
1176 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1177   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1178 HAVE_EXCEPTION=$emacs_cv_struct_exception
1179 if test $emacs_cv_struct_exception != yes; then
1180   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1181 fi
1182
1183 AC_CHECK_HEADERS(sys/socket.h)
1184 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1185 #if HAVE_SYS_SOCKET_H
1186 #include <sys/socket.h>
1187 #endif])
1188
1189 dnl checks for structure members
1190 AC_STRUCT_TM
1191 AC_STRUCT_TIMEZONE
1192 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1193                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1194                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1195                 [#include <time.h>])
1196 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1197                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1198                   struct ifreq.ifr_addr], , ,
1199                  [AC_INCLUDES_DEFAULT
1200 #if HAVE_SYS_SOCKET_H
1201 #include <sys/socket.h>
1202 #endif
1203 #if HAVE_NET_IF_H
1204 #include <net/if.h>
1205 #endif])
1206
1207 dnl checks for compiler characteristics
1208
1209 dnl Testing __STDC__ to determine prototype support isn't good enough.
1210 dnl DEC C, for instance, doesn't define it with default options, and
1211 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1212 dnl and void *.
1213 AC_C_PROTOTYPES
1214 AC_C_VOLATILE
1215 AC_C_CONST
1216 dnl This isn't useful because we can't turn on use of `inline' unless
1217 dnl the compiler groks `extern inline'.
1218 dnl AC_C_INLINE
1219 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1220   [AC_TRY_COMPILE(, [void * foo;],
1221                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1222 if test $emacs_cv_void_star = yes; then
1223   AC_DEFINE(POINTER_TYPE, void)
1224 else
1225   AC_DEFINE(POINTER_TYPE, char)
1226 fi
1227 AH_TEMPLATE(POINTER_TYPE,
1228             [Define as `void' if your compiler accepts `void *'; otherwise
1229              define as `char'.])dnl
1230
1231
1232
1233 dnl This could be used for targets which can have both byte sexes.
1234 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1235 dnl AC_C_BIGENDIAN
1236
1237 dnl check for Make feature
1238 AC_PROG_MAKE_SET
1239
1240 dnl check for GNU Make if we have GCC and autodepend is on.
1241 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1242    AC_MSG_CHECKING([whether we are using GNU Make])
1243    HAVE_GNU_MAKE=no
1244    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1245    if test "x$testval" != x; then
1246       HAVE_GNU_MAKE=yes
1247    else
1248       ac_enable_autodepend=no
1249    fi
1250    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1251    if test $HAVE_GNU_MAKE = yes; then
1252       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1253       SAVE_CFLAGS="$CFLAGS"
1254       CFLAGS="$CFLAGS -MMD -MF deps.d"
1255       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1256       CFLAGS="$SAVE_CFLAGS"
1257       test -f deps.d || ac_enable_autodepend=no
1258       rm -rf deps.d
1259       AC_MSG_RESULT([$ac_enable_autodepend])
1260    fi
1261    if test $ac_enable_autodepend = yes; then
1262       AC_DEFINE(AUTO_DEPEND, 1, [Generate dependencies with gcc.])
1263    fi
1264 fi
1265
1266 dnl checks for operating system services
1267 AC_SYS_LONG_FILE_NAMES
1268
1269 #### Choose a window system.
1270
1271 AC_PATH_X
1272 if test "$no_x" = yes; then
1273   window_system=none
1274 else
1275   window_system=x11
1276 fi
1277
1278 ## Workaround for bug in autoconf <= 2.62.
1279 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1280 ## No need to do anything special for these standard directories.
1281 ## This is an experiment, take it out if it causes problems.
1282 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1283
1284    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1285
1286 fi
1287
1288 if test "${x_libraries}" != NONE; then
1289   if test -n "${x_libraries}"; then
1290     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1291     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1292   fi
1293   x_default_search_path=""
1294   x_search_path=${x_libraries}
1295   if test -z "${x_search_path}"; then
1296     x_search_path=/usr/lib
1297   fi
1298   for x_library in `echo ${x_search_path}: | \
1299                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1300     x_search_path="\
1301 ${x_library}/X11/%L/%T/%N%C%S:\
1302 ${x_library}/X11/%l/%T/%N%C%S:\
1303 ${x_library}/X11/%T/%N%C%S:\
1304 ${x_library}/X11/%L/%T/%N%S:\
1305 ${x_library}/X11/%l/%T/%N%S:\
1306 ${x_library}/X11/%T/%N%S"
1307     if test x"${x_default_search_path}" = x; then
1308       x_default_search_path=${x_search_path}
1309     else
1310       x_default_search_path="${x_search_path}:${x_default_search_path}"
1311     fi
1312   done
1313 fi
1314 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1315   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1316 fi
1317
1318 if test x"${x_includes}" = x; then
1319   bitmapdir=/usr/include/X11/bitmaps
1320 else
1321   # accumulate include directories that have X11 bitmap subdirectories
1322   bmd_acc="dummyval"
1323   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1324     if test -d "${bmd}/X11/bitmaps"; then
1325       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1326     fi
1327     if test -d "${bmd}/bitmaps"; then
1328       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1329     fi
1330   done
1331   if test ${bmd_acc} != "dummyval"; then
1332     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1333   fi
1334 fi
1335
1336 HAVE_NS=no
1337 NS_IMPL_COCOA=no
1338 NS_IMPL_GNUSTEP=no
1339 tmp_CPPFLAGS="$CPPFLAGS"
1340 tmp_CFLAGS="$CFLAGS"
1341 CPPFLAGS="$CPPFLAGS -x objective-c"
1342 CFLAGS="$CFLAGS -x objective-c"
1343 if test "${with_ns}" != no; then
1344   if test "${opsys}" = darwin; then
1345      NS_IMPL_COCOA=yes
1346      ns_appdir=`pwd`/nextstep/Emacs.app
1347      ns_appbindir=`pwd`/nextstep/Emacs.app/Contents/MacOS
1348      ns_appresdir=`pwd`/nextstep/Emacs.app/Contents/Resources
1349      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1350   elif test -f $GNUSTEP_CONFIG_FILE; then
1351      NS_IMPL_GNUSTEP=yes
1352      ns_appdir=`pwd`/nextstep/Emacs.app
1353      ns_appbindir=`pwd`/nextstep/Emacs.app
1354      ns_appresdir=`pwd`/nextstep/Emacs.app/Resources
1355      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1356      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1357      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1358      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1359      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1360      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1361      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1362      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1363      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1364   fi
1365   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1366                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1367   files are missing or cannot be compiled.])])
1368   NS_HAVE_NSINTEGER=yes
1369   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1370                                      [NSInteger i;])],
1371                     ns_have_nsinteger=yes,
1372                     ns_have_nsinteger=no)
1373   if test $ns_have_nsinteger = no; then
1374     NS_HAVE_NSINTEGER=no
1375   fi
1376 fi
1377 if test "${HAVE_NS}" = yes; then
1378   window_system=nextstep
1379   with_xft=no
1380   # set up packaging dirs
1381   exec_prefix=${ns_appbindir}
1382   libexecdir=${ns_appbindir}/libexec
1383   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1384      prefix=${ns_appresdir}
1385   fi
1386 fi
1387 CFLAGS="$tmp_CFLAGS"
1388 CPPFLAGS="$tmp_CPPFLAGS"
1389
1390 case "${window_system}" in
1391   x11 )
1392     HAVE_X_WINDOWS=yes
1393     HAVE_X11=yes
1394     case "${with_x_toolkit}" in
1395       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1396       motif ) USE_X_TOOLKIT=MOTIF ;;
1397       gtk ) with_gtk=yes
1398 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1399 dnl USE_X_TOOLKIT is set.
1400             USE_X_TOOLKIT=none ;;
1401       no ) USE_X_TOOLKIT=none ;;
1402 dnl If user did not say whether to use a toolkit, make this decision later:
1403 dnl use the toolkit if we have gtk, or X11R5 or newer.
1404       * ) USE_X_TOOLKIT=maybe ;;
1405     esac
1406   ;;
1407   nextstep | none )
1408     HAVE_X_WINDOWS=no
1409     HAVE_X11=no
1410     USE_X_TOOLKIT=none
1411   ;;
1412 esac
1413
1414 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1415    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1416    if test "$HAVE_XSERVER" = true ||
1417       test -n "$DISPLAY" ||
1418       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1419         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1420 were found.  You should install the relevant development files for X
1421 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1422 sure you have development files for image handling, i.e.
1423 tiff, gif, jpeg, png and xpm.
1424 If you are sure you want Emacs compiled without X window support, pass
1425   --without-x
1426 to configure.])
1427    fi
1428 fi
1429
1430 ### If we're using X11, we should use the X menu package.
1431 HAVE_MENUS=no
1432 case ${HAVE_X11} in
1433   yes ) HAVE_MENUS=yes ;;
1434 esac
1435
1436 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1437 # Assume not, until told otherwise.
1438 GNU_MALLOC=yes
1439 doug_lea_malloc=yes
1440 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1441 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1442 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1443                emacs_cv_var___after_morecore_hook,
1444 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1445   emacs_cv_var___after_morecore_hook=yes,
1446   emacs_cv_var___after_morecore_hook=no)])
1447 if test $emacs_cv_var___after_morecore_hook = no; then
1448   doug_lea_malloc=no
1449 fi
1450 if test "${system_malloc}" = "yes"; then
1451   GNU_MALLOC=no
1452   GNU_MALLOC_reason="
1453     (The GNU allocators don't work with this system configuration.)"
1454 fi
1455 if test "$doug_lea_malloc" = "yes" ; then
1456   if test "$GNU_MALLOC" = yes ; then
1457     GNU_MALLOC_reason="
1458       (Using Doug Lea's new malloc from the GNU C Library.)"
1459   fi
1460   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1461             [Define to 1 if you are using the GNU C Library.])
1462 fi
1463
1464 if test x"${REL_ALLOC}" = x; then
1465   REL_ALLOC=${GNU_MALLOC}
1466 fi
1467
1468 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1469 dnl the system configuration file (s/*.h) to turn the use of mmap
1470 dnl in the relocating allocator on.
1471
1472 AC_FUNC_MMAP
1473 if test $use_mmap_for_buffers = yes; then
1474   REL_ALLOC=no
1475 fi
1476
1477 LIBS="$libsrc_libs $LIBS"
1478
1479 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1480 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1481 AC_CHECK_LIB(dnet, dnet_ntoa)
1482 dnl This causes -lresolv to get used in subsequent tests,
1483 dnl which causes failures on some systems such as HPUX 9.
1484 dnl AC_CHECK_LIB(resolv, gethostbyname)
1485
1486 dnl FIXME replace main with a function we actually want from this library.
1487 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1488
1489 AC_CHECK_LIB(pthreads, cma_open)
1490
1491 dnl Check for need for bigtoc support on IBM AIX
1492
1493 case ${host_os} in
1494 aix*)
1495   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1496     case $GCC in
1497     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1498     *) gdb_cv_bigtoc=-bbigtoc ;;
1499     esac
1500
1501     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1502     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1503   ])
1504   ;;
1505 esac
1506
1507 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1508 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1509 # REAL_CPPFLAGS later on.
1510
1511 REAL_CPPFLAGS="$CPPFLAGS"
1512
1513 if test "${HAVE_X11}" = "yes"; then
1514   DEFS="$C_SWITCH_X_SITE $DEFS"
1515   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1516   LIBS="$LIBX $LIBS"
1517   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1518   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1519
1520   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1521   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1522   # but it's more convenient here to set LD_RUN_PATH
1523   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1524   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1525     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1526     export LD_RUN_PATH
1527   fi
1528
1529   if test "${opsys}" = "gnu-linux"; then
1530     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1531     AC_TRY_LINK([],
1532      [XOpenDisplay ("foo");],
1533      [xlinux_first_failure=no],
1534      [xlinux_first_failure=yes])
1535     if test "${xlinux_first_failure}" = "yes"; then
1536       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1537       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1538       OLD_CPPFLAGS="$CPPFLAGS"
1539       OLD_LIBS="$LIBS"
1540       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1541       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1542       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1543       LIBS="$LIBS -b i486-linuxaout"
1544       AC_TRY_LINK([],
1545        [XOpenDisplay ("foo");],
1546        [xlinux_second_failure=no],
1547        [xlinux_second_failure=yes])
1548       if test "${xlinux_second_failure}" = "yes"; then
1549         # If we get the same failure with -b, there is no use adding -b.
1550         # So take it out.  This plays safe.
1551         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1552         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1553         CPPFLAGS="$OLD_CPPFLAGS"
1554         LIBS="$OLD_LIBS"
1555         AC_MSG_RESULT(no)
1556       else
1557         AC_MSG_RESULT(yes)
1558       fi
1559     else
1560       AC_MSG_RESULT(no)
1561     fi
1562   fi
1563
1564   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1565   # header files included from there.
1566   AC_MSG_CHECKING(for Xkb)
1567   AC_TRY_LINK([#include <X11/Xlib.h>
1568 #include <X11/XKBlib.h>],
1569         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1570         emacs_xkb=yes, emacs_xkb=no)
1571   AC_MSG_RESULT($emacs_xkb)
1572   if test $emacs_xkb = yes; then
1573     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1574   fi
1575
1576   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1577 XScreenNumberOfScreen XSetWMProtocols)
1578 fi
1579
1580 if test "${window_system}" = "x11"; then
1581   AC_MSG_CHECKING(X11 version 6)
1582   AC_CACHE_VAL(emacs_cv_x11_version_6,
1583   [AC_TRY_LINK([#include <X11/Xlib.h>],
1584 [#if XlibSpecificationRelease < 6
1585 fail;
1586 #endif
1587 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1588   if test $emacs_cv_x11_version_6 = yes; then
1589     AC_MSG_RESULT(6 or newer)
1590     AC_DEFINE(HAVE_X11R6, 1,
1591               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1592   else
1593     AC_MSG_RESULT(before 6)
1594   fi
1595 fi
1596
1597
1598 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1599 HAVE_RSVG=no
1600 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1601   if test "${with_rsvg}" != "no"; then
1602     RSVG_REQUIRED=2.11.0
1603     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1604
1605     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1606     AC_SUBST(RSVG_CFLAGS)
1607     AC_SUBST(RSVG_LIBS)
1608
1609     if test ".${RSVG_CFLAGS}" != "."; then
1610       HAVE_RSVG=yes
1611       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1612       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1613       LIBS="$RSVG_LIBS $LIBS"
1614     fi
1615   fi
1616 fi
1617
1618
1619 HAVE_GTK=no
1620 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1621   GLIB_REQUIRED=2.6
1622   GTK_REQUIRED=2.6
1623   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1624
1625   dnl Checks for libraries.
1626   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1627   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1628      AC_MSG_ERROR($GTK_PKG_ERRORS)
1629   fi
1630 fi
1631
1632
1633 if test x"$pkg_check_gtk" = xyes; then
1634
1635   AC_SUBST(GTK_CFLAGS)
1636   AC_SUBST(GTK_LIBS)
1637   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1638   CFLAGS="$CFLAGS $GTK_CFLAGS"
1639   LIBS="$GTK_LIBS $LIBS"
1640   dnl Try to compile a simple GTK program.
1641   GTK_COMPILES=no
1642   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1643   if test "${GTK_COMPILES}" != "yes"; then
1644     if test "$USE_X_TOOLKIT" != "maybe"; then
1645       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1646     fi
1647   else
1648     HAVE_GTK=yes
1649     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1650     USE_X_TOOLKIT=none
1651     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1652       :
1653     else
1654       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1655        closing open displays.  This is no problem if you just use
1656        one display, but if you use more than one and close one of them
1657        Emacs may crash.]])
1658       sleep 3
1659     fi
1660   fi
1661
1662 fi
1663
1664
1665 if test "${HAVE_GTK}" = "yes"; then
1666
1667   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1668   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1669   if test "$with_toolkit_scroll_bars" != no; then
1670     with_toolkit_scroll_bars=yes
1671   fi
1672
1673   dnl  Check if we can use multiple displays with this GTK version.
1674   dnl  If gdk_display_open exists, assume all others are there also.
1675   HAVE_GTK_MULTIDISPLAY=no
1676   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1677   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1678     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1679               [Define to 1 if GTK can handle more than one display.])
1680   fi
1681
1682   dnl  Check if we have the old file selection dialog declared and
1683   dnl  in the link library.  In 2.x it may be in the library,
1684   dnl  but not declared if deprecated featured has been selected out.
1685   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1686   HAVE_GTK_FILE_SELECTION=no
1687   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1688                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1689 #include <gtk/gtk.h>])
1690   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1691     AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes,
1692                    HAVE_GTK_FILE_SELECTION=no)
1693   fi
1694
1695   dnl  Check if we have the new file chooser dialog
1696   HAVE_GTK_FILE_CHOOSER=no
1697   AC_CHECK_DECL(GTK_TYPE_FILE_CHOOSER, HAVE_GTK_FILE_CHOOSER=yes,
1698                 HAVE_GTK_FILE_CHOOSER=no, [AC_INCLUDES_DEFAULT
1699 #include <gtk/gtk.h>])
1700   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1701     AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes,
1702                    HAVE_GTK_FILE_CHOOSER=no)
1703   fi
1704
1705   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1706      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1707     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1708               [Define to 1 if GTK has both file selection and chooser dialog.])
1709   fi
1710
1711   dnl Check if pthreads are available.  Emacs only needs this when using
1712   dnl gtk_file_chooser under Gnome.
1713   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1714     HAVE_GTK_AND_PTHREAD=no
1715     AC_CHECK_HEADERS(pthread.h)
1716     if test "$ac_cv_header_pthread_h"; then
1717       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1718     fi
1719     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1720       case "${canonical}" in
1721         *-hpux*) ;;
1722         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1723       esac
1724       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1725                [Define to 1 if you have GTK and pthread (-lpthread).])
1726     fi
1727   fi
1728 fi
1729
1730 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1731 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1732 dnl also not configured.
1733 HAVE_DBUS=no
1734 if test "${with_dbus}" = "yes"; then
1735    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1736    if test "$HAVE_DBUS" = yes; then
1737      LIBS="$LIBS $DBUS_LIBS"
1738      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1739      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1740    fi
1741 fi
1742
1743 dnl GConf has been tested under GNU/Linux only.
1744 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1745 HAVE_GCONF=no
1746 if test "${with_gconf}" = "yes"; then
1747    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1748    if test "$HAVE_GCONF" = yes; then
1749       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1750    fi
1751 fi
1752
1753 dnl Do not put whitespace before the #include statements below.
1754 dnl Older compilers (eg sunos4 cc) choke on it.
1755 HAVE_XAW3D=no
1756 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1757   if test "$with_xaw3d" != no; then
1758     AC_MSG_CHECKING(for xaw3d)
1759     AC_CACHE_VAL(emacs_cv_xaw3d,
1760     [AC_TRY_LINK([
1761 #include <X11/Intrinsic.h>
1762 #include <X11/Xaw3d/Simple.h>],
1763       [],
1764       emacs_cv_xaw3d=yes,
1765       emacs_cv_xaw3d=no)])
1766   else
1767     emacs_cv_xaw3d=no
1768   fi
1769   if test $emacs_cv_xaw3d = yes; then
1770     AC_MSG_RESULT([yes; using Lucid toolkit])
1771     USE_X_TOOLKIT=LUCID
1772     HAVE_XAW3D=yes
1773     AC_DEFINE(HAVE_XAW3D, 1,
1774               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1775   else
1776     AC_MSG_RESULT(no)
1777     AC_MSG_CHECKING(for libXaw)
1778     AC_CACHE_VAL(emacs_cv_xaw,
1779     [AC_TRY_LINK([
1780 #include <X11/Intrinsic.h>
1781 #include <X11/Xaw/Simple.h>],
1782       [],
1783       emacs_cv_xaw=yes,
1784       emacs_cv_xaw=no)])
1785     if test $emacs_cv_xaw = yes; then
1786       AC_MSG_RESULT([yes; using Lucid toolkit])
1787       USE_X_TOOLKIT=LUCID
1788     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1789       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1790     else
1791       AC_MSG_RESULT([no; do not use toolkit by default])
1792       USE_X_TOOLKIT=none
1793     fi
1794   fi
1795 fi
1796
1797 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1798
1799 if test "${USE_X_TOOLKIT}" != "none"; then
1800   AC_MSG_CHECKING(X11 toolkit version)
1801   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1802   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1803 [#if XtSpecificationRelease < 6
1804 fail;
1805 #endif
1806 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1807   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1808   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1809     AC_MSG_RESULT(6 or newer)
1810     AC_DEFINE(HAVE_X11XTR6, 1,
1811               [Define to 1 if you have the X11R6 or newer version of Xt.])
1812   else
1813     AC_MSG_RESULT(before 6)
1814   fi
1815
1816 dnl If using toolkit, check whether libXmu.a exists.
1817 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1818   OLDLIBS="$LIBS"
1819   if test x$HAVE_X11XTR6 = xyes; then
1820     LIBS="-lXt -lSM -lICE $LIBS"
1821   else
1822     LIBS="-lXt $LIBS"
1823   fi
1824   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1825   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1826 fi
1827
1828 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1829 if test "${HAVE_X11}" = "yes"; then
1830   if test "${USE_X_TOOLKIT}" != "none"; then
1831     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1832   fi
1833 fi
1834
1835 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1836   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1837   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1838     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1839 int x = 5;
1840 #else
1841 Motif version prior to 2.1.
1842 #endif],
1843     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1844   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1845   if test $emacs_cv_motif_version_2_1 = yes; then
1846     HAVE_LIBXP=no
1847     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1848               [Define to 1 if you have Motif 2.1 or newer.])
1849     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1850     if test ${HAVE_LIBXP} = yes; then
1851       AC_DEFINE(HAVE_LIBXP, 1,
1852                 [Define to 1 if you have the Xp library (-lXp).])
1853     fi
1854   else
1855     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1856     # We put this in CFLAGS temporarily to precede other -I options
1857     # that might be in CFLAGS temporarily.
1858     # We put this in CPPFLAGS where it precedes the other -I options.
1859     OLD_CPPFLAGS=$CPPFLAGS
1860     OLD_CFLAGS=$CFLAGS
1861     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1862     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1863     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1864       [int x = 5;],
1865       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1866     if test $emacs_cv_lesstif = yes; then
1867       # Make sure this -I option remains in CPPFLAGS after it is set
1868       # back to REAL_CPPFLAGS.
1869       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1870       # have those other -I options anyway.  Ultimately, having this
1871       # directory ultimately in CPPFLAGS will be enough.
1872       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1873       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1874     else
1875       CFLAGS=$OLD_CFLAGS
1876       CPPFLAGS=$OLD_CPPFLAGS
1877     fi
1878   fi
1879 fi
1880
1881 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1882 dnl using Motif or Xaw3d is available, and unless
1883 dnl --with-toolkit-scroll-bars=no was specified.
1884
1885 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1886             [Define to 1 if we should use toolkit scroll bars.])dnl
1887 USE_TOOLKIT_SCROLL_BARS=no
1888 if test "${with_toolkit_scroll_bars}" != "no"; then
1889   if test "${USE_X_TOOLKIT}" != "none"; then
1890     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1891       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1892       HAVE_XAW3D=no
1893       USE_TOOLKIT_SCROLL_BARS=yes
1894     elif test "${HAVE_XAW3D}" = "yes"; then
1895       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1896       USE_TOOLKIT_SCROLL_BARS=yes
1897     fi
1898   elif test "${HAVE_GTK}" = "yes"; then
1899     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1900     USE_TOOLKIT_SCROLL_BARS=yes
1901   elif test "${HAVE_NS}" = "yes"; then
1902     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1903     USE_TOOLKIT_SCROLL_BARS=yes
1904   fi
1905 fi
1906
1907 dnl See if XIM is available.
1908 AC_TRY_COMPILE([
1909           #include <X11/Xlib.h>
1910           #include <X11/Xresource.h>],
1911          [XIMProc  callback;],
1912          [HAVE_XIM=yes
1913          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1914          HAVE_XIM=no)
1915
1916 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1917
1918 if test "${with_xim}" != "no"; then
1919   AC_DEFINE(USE_XIM, 1,
1920             [Define to 1 if we should use XIM, if it is available.])
1921 fi
1922
1923
1924 if test "${HAVE_XIM}" != "no"; then
1925   late_CFLAGS=$CFLAGS
1926   if test "$GCC" = yes; then
1927     CFLAGS="$CFLAGS --pedantic-errors"
1928   fi
1929   AC_TRY_COMPILE([
1930 #include <X11/Xlib.h>
1931 #include <X11/Xresource.h>],
1932 [Display *display;
1933 XrmDatabase db;
1934 char *res_name;
1935 char *res_class;
1936 XIMProc  callback;
1937 XPointer *client_data;
1938 #ifndef __GNUC__
1939 /* If we're not using GCC, it's probably not XFree86, and this is
1940    probably right, but we can't use something like --pedantic-errors.  */
1941 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1942                                            char*, XIMProc, XPointer*);
1943 #endif
1944 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1945    client_data);],
1946     [emacs_cv_arg6_star=yes])
1947   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1948          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1949 either XPointer or XPointer*.])dnl
1950   if test "$emacs_cv_arg6_star" = yes; then
1951     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1952   else
1953     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1954   fi
1955   CFLAGS=$late_CFLAGS
1956 fi
1957
1958 ### Start of font-backend (under any platform) section.
1959 # (nothing here yet -- this is a placeholder)
1960 ### End of font-backend (under any platform) section.
1961
1962 ### Start of font-backend (under X11) section.
1963 if test "${HAVE_X11}" = "yes"; then
1964    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
1965
1966    ## Use -lXft if available, unless `--with-xft=no'.
1967    HAVE_XFT=maybe
1968     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
1969       with_xft="no";
1970     fi
1971     if test "x${with_xft}" != "xno"; then
1972
1973       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1974       if test "$HAVE_XFT" != no; then
1975         OLD_CPPFLAGS="$CPPFLAGS"
1976         OLD_CFLAGS="$CFLAGS"
1977         OLD_LIBS="$LIBS"
1978         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
1979         CFLAGS="$CFLAGS $XFT_CFLAGS"
1980         LIBS="$XFT_LIBS $LIBS"
1981         AC_CHECK_HEADER(X11/Xft/Xft.h,
1982           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
1983
1984         if test "${HAVE_XFT}" = "yes"; then
1985           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
1986             AC_SUBST(XFT_LIBS)
1987           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
1988         else
1989           CPPFLAGS="$OLD_CPPFLAGS"
1990           CFLAGS="$OLD_CFLAGS"
1991           LIBS="$OLD_LIBS"
1992         fi                        # "${HAVE_XFT}" = "yes"
1993       fi                          # "$HAVE_XFT" != no
1994     fi                            # "x${with_xft}" != "xno"
1995
1996     dnl For the "Does Emacs use" message at the end.
1997     if test "$HAVE_XFT" != "yes"; then
1998        HAVE_XFT=no
1999     fi
2000
2001
2002     HAVE_FREETYPE=no
2003     ## We used to allow building with FreeType and without Xft.
2004     ## However, the ftx font backend driver is not in good shape.
2005     if test "${HAVE_XFT}" = "yes"; then
2006       dnl As we use Xft, we anyway use freetype.
2007       dnl There's no need for additional CFLAGS and LIBS.
2008       HAVE_FREETYPE=yes
2009       FONTCONFIG_CFLAGS=
2010       FONTCONFIG_LIBS=
2011     fi
2012
2013     HAVE_LIBOTF=no
2014     if test "${HAVE_FREETYPE}" = "yes"; then
2015       AC_DEFINE(HAVE_FREETYPE, 1,
2016                 [Define to 1 if using the freetype and fontconfig libraries.])
2017       if test "${with_libotf}" != "no"; then
2018         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2019                           HAVE_LIBOTF=no)
2020         if test "$HAVE_LIBOTF" = "yes"; then
2021           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2022           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2023                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2024                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2025           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2026             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2027                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2028           fi
2029         fi
2030       fi
2031     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2032     dnl Does the new font backend require it, or can it work without it?
2033     fi
2034
2035     HAVE_M17N_FLT=no
2036     if test "${HAVE_LIBOTF}" = yes; then
2037       if test "${with_m17n_flt}" != "no"; then
2038         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2039         if test "$HAVE_M17N_FLT" = "yes"; then
2040           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2041         fi
2042       fi
2043     fi
2044 else
2045     HAVE_XFT=no
2046     HAVE_FREETYPE=no
2047     HAVE_LIBOTF=no
2048     HAVE_M17N_FLT=no
2049 fi
2050 ### End of font-backend (under X11) section.
2051
2052 AC_SUBST(FREETYPE_CFLAGS)
2053 AC_SUBST(FREETYPE_LIBS)
2054 AC_SUBST(FONTCONFIG_CFLAGS)
2055 AC_SUBST(FONTCONFIG_LIBS)
2056 AC_SUBST(LIBOTF_CFLAGS)
2057 AC_SUBST(LIBOTF_LIBS)
2058 AC_SUBST(M17N_FLT_CFLAGS)
2059 AC_SUBST(M17N_FLT_LIBS)
2060
2061 ### Use -lXpm if available, unless `--with-xpm=no'.
2062 HAVE_XPM=no
2063 if test "${HAVE_X11}" = "yes"; then
2064   if test "${with_xpm}" != "no"; then
2065     AC_CHECK_HEADER(X11/xpm.h,
2066       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2067     if test "${HAVE_XPM}" = "yes"; then
2068       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2069       AC_EGREP_CPP(no_return_alloc_pixels,
2070       [#include "X11/xpm.h"
2071 #ifndef XpmReturnAllocPixels
2072 no_return_alloc_pixels
2073 #endif
2074       ], HAVE_XPM=no, HAVE_XPM=yes)
2075
2076       if test "${HAVE_XPM}" = "yes"; then
2077         AC_MSG_RESULT(yes)
2078       else
2079         AC_MSG_RESULT(no)
2080       fi
2081     fi
2082   fi
2083
2084   if test "${HAVE_XPM}" = "yes"; then
2085     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2086   fi
2087 fi
2088
2089 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2090 HAVE_JPEG=no
2091 if test "${HAVE_X11}" = "yes"; then
2092   if test "${with_jpeg}" != "no"; then
2093     dnl Checking for jpeglib.h can lose because of a redefinition of
2094     dnl  HAVE_STDLIB_H.
2095     AC_CHECK_HEADER(jerror.h,
2096       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2097   fi
2098
2099   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2100   if test "${HAVE_JPEG}" = "yes"; then
2101     AC_DEFINE(HAVE_JPEG)
2102     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2103         [#include <jpeglib.h>
2104          version=JPEG_LIB_VERSION
2105 ],
2106         [AC_DEFINE(HAVE_JPEG)],
2107         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2108         HAVE_JPEG=no])
2109   fi
2110 fi
2111
2112 ### Use -lpng if available, unless `--with-png=no'.
2113 HAVE_PNG=no
2114 if test "${HAVE_X11}" = "yes"; then
2115   if test "${with_png}" != "no"; then
2116     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2117     # in /usr/include/libpng.
2118     AC_CHECK_HEADERS(png.h libpng/png.h)
2119     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2120       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2121     fi
2122   fi
2123
2124   if test "${HAVE_PNG}" = "yes"; then
2125     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2126   fi
2127 fi
2128
2129 ### Use -ltiff if available, unless `--with-tiff=no'.
2130 HAVE_TIFF=no
2131 if test "${HAVE_X11}" = "yes"; then
2132   if test "${with_tiff}" != "no"; then
2133     AC_CHECK_HEADER(tiffio.h,
2134       [tifflibs="-lz -lm"
2135       # At least one tiff package requires the jpeg library.
2136       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2137       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2138   fi
2139
2140   if test "${HAVE_TIFF}" = "yes"; then
2141     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2142   fi
2143 fi
2144
2145 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2146 HAVE_GIF=no
2147 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2148   AC_CHECK_HEADER(gif_lib.h,
2149 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2150 # Earlier versions can crash Emacs.
2151     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2152
2153   if test "$HAVE_GIF" = yes; then
2154       ac_gif_lib_name="-lgif"
2155   fi
2156
2157 # If gif_lib.h but no libgif, try libungif.
2158   if test x"$try_libungif" = xyes; then
2159     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2160
2161     if test "$HAVE_GIF" = yes; then
2162       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2163       ac_gif_lib_name="-lungif"
2164     fi
2165   fi
2166
2167   if test "${HAVE_GIF}" = "yes"; then
2168     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2169   fi
2170 fi
2171
2172 dnl Check for required libraries.
2173 if test "${HAVE_X11}" = "yes"; then
2174   MISSING=""
2175   WITH_NO=""
2176   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2177     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2178   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2179     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2180   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2181     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2182   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2183     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2184   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2185     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2186
2187   if test "X${MISSING}" != X; then
2188     AC_MSG_ERROR([The following required libraries were not found:
2189     $MISSING
2190 Maybe some development libraries/packages are missing?
2191 If you don't want to link with them give
2192     $WITH_NO
2193 as options to configure])
2194   fi
2195 fi
2196
2197 ### Use -lgpm if available, unless `--with-gpm=no'.
2198 HAVE_GPM=no
2199 if test "${with_gpm}" != "no"; then
2200   AC_CHECK_HEADER(gpm.h,
2201     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2202 fi
2203
2204 if test "${HAVE_GPM}" = "yes"; then
2205   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2206 fi
2207
2208 dnl Check for malloc/malloc.h on darwin
2209 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2210
2211 ### Use NeXTstep API to implement GUI.
2212 if test "${HAVE_NS}" = "yes"; then
2213   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2214   if test "${NS_IMPL_COCOA}" = "yes"; then
2215     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2216     GNU_OBJC_CFLAGS=
2217   fi
2218   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2219     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2220     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2221   fi
2222   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2223     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2224   fi
2225   # We also have mouse menus.
2226   HAVE_MENUS=yes
2227   OTHER_FILES=ns-app
2228 fi
2229
2230
2231 ### Use session management (-lSM -lICE) if available
2232 HAVE_X_SM=no
2233 if test "${HAVE_X11}" = "yes"; then
2234   AC_CHECK_HEADER(X11/SM/SMlib.h,
2235     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2236
2237   if test "${HAVE_X_SM}" = "yes"; then
2238     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2239     case "$LIBS" in
2240       *-lSM*) ;;
2241       *)      LIBS="-lSM -lICE $LIBS" ;;
2242     esac
2243   fi
2244 fi
2245
2246 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2247 AC_CACHE_CHECK(whether netdb declares h_errno,
2248                emacs_cv_netdb_declares_h_errno,
2249 [AC_TRY_LINK([#include <netdb.h>],
2250   [return h_errno;],
2251   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2252 if test $emacs_cv_netdb_declares_h_errno = yes; then
2253   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2254 fi
2255
2256 AC_FUNC_ALLOCA
2257
2258 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2259 dnl FIXME is there an autoconf test that does the right thing, without
2260 dnl needing to call A_M_E afterwards?
2261 if test x"$ac_cv_func_alloca_works" != xyes; then
2262    AC_MSG_ERROR( [a system implementation of alloca is required] )
2263 fi
2264
2265 # fmod, logb, and frexp are found in -lm on most systems.
2266 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2267 AC_CHECK_LIB(m, sqrt)
2268
2269 # Check for mail-locking functions in a "mail" library.  Probably this should
2270 # have the same check as for liblockfile below.
2271 AC_CHECK_LIB(mail, maillock)
2272 dnl Debian, at least:
2273 AC_CHECK_LIB(lockfile, maillock)
2274 # If we have the shared liblockfile, assume we must use it for mail
2275 # locking (e.g. Debian).  If we couldn't link against liblockfile
2276 # (no liblockfile.a installed), ensure that we don't need to.
2277 if test "$ac_cv_lib_lockfile_maillock" = no; then
2278   dnl This works for files generally, not just executables.
2279   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2280   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2281                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2282   if test $ac_cv_prog_liblockfile = yes; then
2283     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2284 This probably means that movemail could lose mail.
2285 There may be a `development' package to install containing liblockfile.])
2286   else :
2287   fi
2288 fi
2289 AC_CHECK_FUNCS(touchlock)
2290 AC_CHECK_HEADERS(maillock.h)
2291
2292 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2293 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2294 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2295 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2296 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2297 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2298 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2299 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2300 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2301 cfmakeraw cfsetspeed)
2302
2303 AC_CHECK_HEADERS(sys/un.h)
2304
2305 AC_FUNC_MKTIME
2306 if test "$ac_cv_func_working_mktime" = no; then
2307   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2308 fi
2309
2310 AC_FUNC_GETLOADAVG
2311
2312 AC_FUNC_FSEEKO
2313
2314 # Configure getopt.
2315 m4_include([m4/getopt.m4])
2316 gl_GETOPT_IFELSE([
2317   gl_GETOPT_SUBSTITUTE_HEADER
2318   gl_PREREQ_GETOPT
2319   GETOPTOBJS='getopt.o getopt1.o'
2320 ])
2321 AC_SUBST(GETOPTOBJS)
2322
2323 AC_FUNC_GETPGRP
2324
2325 AC_FUNC_STRFTIME
2326
2327 # UNIX98 PTYs.
2328 AC_CHECK_FUNCS(grantpt)
2329
2330 # PTY-related GNU extensions.
2331 AC_CHECK_FUNCS(getpt)
2332
2333 # Check this now, so that we will NOT find the above functions in ncurses.
2334 # That is because we have not set up to link ncurses in lib-src.
2335 # It's better to believe a function is not available
2336 # than to expect to find it in ncurses.
2337 AC_CHECK_LIB(ncurses, tparm)
2338
2339 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2340
2341 resolv=no
2342 AC_TRY_LINK([#include <netinet/in.h>
2343 #include <arpa/nameser.h>
2344 #include <resolv.h>],
2345     [return res_init();],
2346     have_res_init=yes, have_res_init=no)
2347 if test "$have_res_init" = no; then
2348   OLIBS="$LIBS"
2349   LIBS="$LIBS -lresolv"
2350   AC_MSG_CHECKING(for res_init with -lresolv)
2351   AC_TRY_LINK([#include <netinet/in.h>
2352 #include <arpa/nameser.h>
2353 #include <resolv.h>],
2354     [return res_init();],
2355     have_res_init=yes, have_res_init=no)
2356   AC_MSG_RESULT($have_res_init)
2357   if test "$have_res_init" = yes ; then
2358     resolv=yes
2359   fi
2360   LIBS="$OLIBS"
2361 fi
2362
2363 if test "$have_res_init" = yes; then
2364   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2365 fi
2366
2367 # Do we need the Hesiod library to provide the support routines?
2368 if test "$with_hesiod" != no ; then
2369   # Don't set $LIBS here -- see comments above.
2370   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2371      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2372                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2373   if test "$resolv" = yes ; then
2374     RESOLVLIB=-lresolv
2375   else
2376     RESOLVLIB=
2377   fi
2378   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2379         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2380                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2381         :, $RESOLVLIB)])
2382 fi
2383
2384 # Do we need libresolv (due to res_init or Hesiod)?
2385 if test "$resolv" = yes ; then
2386   AC_DEFINE(HAVE_LIBRESOLV, 1,
2387             [Define to 1 if you have the resolv library (-lresolv).])
2388 fi
2389
2390 # These tell us which Kerberos-related libraries to use.
2391 if test "${with_kerberos}" != no; then
2392   AC_CHECK_LIB(com_err, com_err)
2393   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2394   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2395   AC_CHECK_LIB(krb5, krb5_init_context)
2396   if test "${with_kerberos5}" = no; then
2397     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2398                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2399     AC_CHECK_LIB(krb4, krb_get_cred,,
2400                  [AC_CHECK_LIB(krb, krb_get_cred)])
2401   fi
2402
2403   if test "${with_kerberos5}" != no; then
2404     AC_CHECK_HEADERS(krb5.h,
2405       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2406                         [#include <krb5.h>])])
2407   else
2408     AC_CHECK_HEADERS(des.h,,
2409                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2410                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2411     AC_CHECK_HEADERS(krb.h,,
2412                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2413                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2414   fi
2415   AC_CHECK_HEADERS(com_err.h)
2416 fi
2417
2418 # Solaris requires -lintl if you want strerror (which calls dgettext)
2419 # to return localized messages.
2420 AC_CHECK_LIB(intl, dgettext)
2421
2422 AC_MSG_CHECKING(whether localtime caches TZ)
2423 AC_CACHE_VAL(emacs_cv_localtime_cache,
2424 [if test x$ac_cv_func_tzset = xyes; then
2425 AC_TRY_RUN([#include <time.h>
2426 extern char **environ;
2427 unset_TZ ()
2428 {
2429   char **from, **to;
2430   for (to = from = environ; (*to = *from); from++)
2431     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2432       to++;
2433 }
2434 char TZ_GMT0[] = "TZ=GMT0";
2435 char TZ_PST8[] = "TZ=PST8";
2436 main()
2437 {
2438   time_t now = time ((time_t *) 0);
2439   int hour_GMT0, hour_unset;
2440   if (putenv (TZ_GMT0) != 0)
2441     exit (1);
2442   hour_GMT0 = localtime (&now)->tm_hour;
2443   unset_TZ ();
2444   hour_unset = localtime (&now)->tm_hour;
2445   if (putenv (TZ_PST8) != 0)
2446     exit (1);
2447   if (localtime (&now)->tm_hour == hour_GMT0)
2448     exit (1);
2449   unset_TZ ();
2450   if (localtime (&now)->tm_hour != hour_unset)
2451     exit (1);
2452   exit (0);
2453 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2454 [# If we have tzset, assume the worst when cross-compiling.
2455 emacs_cv_localtime_cache=yes])
2456 else
2457         # If we lack tzset, report that localtime does not cache TZ,
2458         # since we can't invalidate the cache if we don't have tzset.
2459         emacs_cv_localtime_cache=no
2460 fi])dnl
2461 AC_MSG_RESULT($emacs_cv_localtime_cache)
2462 if test $emacs_cv_localtime_cache = yes; then
2463   AC_DEFINE(LOCALTIME_CACHE, 1,
2464             [Define to 1 if localtime caches TZ.])
2465 fi
2466
2467 if test "x$HAVE_TIMEVAL" = xyes; then
2468   AC_CHECK_FUNCS(gettimeofday)
2469   if test $ac_cv_func_gettimeofday = yes; then
2470     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2471                    emacs_cv_gettimeofday_two_arguments,
2472     [AC_TRY_COMPILE([
2473 #ifdef TIME_WITH_SYS_TIME
2474 #include <sys/time.h>
2475 #include <time.h>
2476 #else
2477 #ifdef HAVE_SYS_TIME_H
2478 #include <sys/time.h>
2479 #else
2480 #include <time.h>
2481 #endif
2482 #endif],
2483       [struct timeval time;
2484        gettimeofday (&time, 0);],
2485       emacs_cv_gettimeofday_two_arguments=yes,
2486       emacs_cv_gettimeofday_two_arguments=no)])
2487     if test $emacs_cv_gettimeofday_two_arguments = no; then
2488       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2489                 [Define to 1 if gettimeofday accepts only one argument.])
2490     fi
2491   fi
2492 fi
2493
2494 ok_so_far=yes
2495 AC_CHECK_FUNC(socket, , ok_so_far=no)
2496 if test $ok_so_far = yes; then
2497   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2498 fi
2499 if test $ok_so_far = yes; then
2500   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2501 fi
2502 if test $ok_so_far = yes; then
2503 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2504   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2505             [Define to 1 if you have inet sockets.])
2506 fi
2507
2508 AC_CHECK_HEADERS(sys/ioctl.h)
2509
2510 if test -f /usr/lpp/X11/bin/smt.exp; then
2511   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2512             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2513 fi
2514
2515 AC_MSG_CHECKING(whether system supports dynamic ptys)
2516 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2517   AC_MSG_RESULT(yes)
2518   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2519 else
2520   AC_MSG_RESULT(no)
2521 fi
2522
2523 AC_FUNC_FORK
2524
2525 dnl Adapted from Haible's version.
2526 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2527   [AC_TRY_LINK([#include <langinfo.h>],
2528     [char* cs = nl_langinfo(CODESET);],
2529     emacs_cv_langinfo_codeset=yes,
2530     emacs_cv_langinfo_codeset=no)
2531   ])
2532 if test $emacs_cv_langinfo_codeset = yes; then
2533   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2534     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2535 fi
2536
2537 AC_CHECK_TYPES(size_t)
2538
2539 AC_TYPE_MBSTATE_T
2540
2541 dnl Restrict could probably be used effectively other than in regex.c.
2542 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2543   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2544                   emacs_cv_c_restrict=yes,
2545                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2546                                   emacs_cv_c_restrict=__restrict,
2547                                   emacs_cv_c_restrict=no)])])
2548 case "$emacs_cv_c_restrict" in
2549   yes) emacs_restrict=restrict;;
2550   no) emacs_restrict="";;
2551   *) emacs_restrict="$emacs_cv_c_restrict";;
2552 esac
2553 if test "$emacs_restrict" != __restrict; then
2554   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2555     [Define to compiler's equivalent of C99 restrict keyword.
2556      Don't define if equivalent is `__restrict'.])
2557 fi
2558
2559 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2560   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2561                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2562 if test "$emacs_cv_c_restrict_arr" = yes; then
2563   AC_DEFINE(__restrict_arr, __restrict,
2564     [Define to compiler's equivalent of C99 restrict keyword in array
2565      declarations.  Define as empty for no equivalent.])
2566 fi
2567
2568 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2569 dnl how the tty code is related to POSIX and/or other versions of termios.
2570 dnl The following looks like a useful start.
2571 dnl
2572 dnl AC_SYS_POSIX_TERMIOS
2573 dnl if test $ac_cv_sys_posix_termios = yes; then
2574 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2575 dnl                                and macros for terminal control.])
2576 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2577 dnl fi
2578
2579 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2580
2581 # Set up the CFLAGS for real compilation, so we can substitute it.
2582 CFLAGS="$REAL_CFLAGS"
2583 CPPFLAGS="$REAL_CPPFLAGS"
2584
2585 #### Find out which version of Emacs this is.
2586 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2587          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2588 if test x"${version}" = x; then
2589   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2590 fi
2591 if test x"${version}" != x"$PACKAGE_VERSION"; then
2592   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/lisp/version.el'.])
2593 fi
2594
2595 ### Specify what sort of things we'll be editing into Makefile and config.h.
2596 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2597 AC_SUBST(version)
2598 AC_SUBST(configuration)
2599 AC_SUBST(canonical)
2600 AC_SUBST(srcdir)
2601 AC_SUBST(prefix)
2602 AC_SUBST(exec_prefix)
2603 AC_SUBST(bindir)
2604 AC_SUBST(datadir)
2605 AC_SUBST(sharedstatedir)
2606 AC_SUBST(libexecdir)
2607 AC_SUBST(mandir)
2608 AC_SUBST(infodir)
2609 AC_SUBST(lispdir)
2610 AC_SUBST(locallisppath)
2611 AC_SUBST(lisppath)
2612 AC_SUBST(x_default_search_path)
2613 AC_SUBST(etcdir)
2614 AC_SUBST(archlibdir)
2615 AC_SUBST(docdir)
2616 AC_SUBST(bitmapdir)
2617 AC_SUBST(gamedir)
2618 AC_SUBST(gameuser)
2619 AC_SUBST(c_switch_system)
2620 AC_SUBST(c_switch_machine)
2621 AC_SUBST(LD_SWITCH_X_SITE)
2622 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2623 AC_SUBST(C_SWITCH_X_SITE)
2624 AC_SUBST(CFLAGS)
2625 AC_SUBST(X_TOOLKIT_TYPE)
2626 AC_SUBST(machfile)
2627 AC_SUBST(opsysfile)
2628 AC_SUBST(GETLOADAVG_LIBS)
2629 AC_SUBST(ns_appdir)
2630 AC_SUBST(ns_appbindir)
2631 AC_SUBST(ns_appresdir)
2632 AC_SUBST(ns_appsrc)
2633 AC_SUBST(GNUSTEP_MAKEFILES)
2634 AC_SUBST(GNUSTEP_SYSTEM_HEADERS)
2635 AC_SUBST(GNUSTEP_SYSTEM_LIBRARIES)
2636 AC_SUBST(GNU_OBJC_CFLAGS)
2637 AC_SUBST(LIB_SRC_EXTRA_INSTALLABLES)
2638 AC_SUBST(OTHER_FILES)
2639
2640 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2641                    [Define to the canonical Emacs configuration name.])
2642 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2643                    [Define to the options passed to configure.])
2644 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2645                    [Define to the used machine dependent file.])
2646 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2647                    [Define to the used os dependent file.])
2648 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2649 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2650  may need to deal with X Windows.  For instance, if you've defined
2651  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2652  your loader can find on its own, you might want to add "-L/..." or
2653  something similar.])
2654 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2655                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2656                     in case it's needed (for Solaris, for example).])
2657 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2658 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2659  may need to deal with X Windows.  For instance, if you've defined
2660  HAVE_X_WINDOWS above and your X include files aren't in a place
2661  that your compiler can find on its own, you might want to add
2662  "-I/..." or something similar.])
2663 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2664                    [Define to the unexec source file name.])
2665
2666 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2667   AC_DEFINE(HAVE_X_WINDOWS, 1,
2668             [Define to 1 if you want to use the X window system.])
2669 fi
2670 if test "${USE_X_TOOLKIT}" != "none" ; then
2671   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2672   if test "${USE_X_TOOLKIT}" = "LUCID"; then
2673     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2674   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
2675     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2676   fi
2677 fi
2678 if test "${HAVE_X11}" = "yes" ; then
2679   AC_DEFINE(HAVE_X11, 1,
2680             [Define to 1 if you want to use version 11 of X windows.
2681              Otherwise, Emacs expects to use version 10.])
2682 fi
2683 if test "${HAVE_MENUS}" = "yes" ; then
2684   AC_DEFINE(HAVE_MENUS, 1,
2685             [Define to 1 if you have mouse menus.
2686              (This is automatic if you use X, but the option to specify it remains.)
2687              It is also defined with other window systems that support xmenu.c.])
2688 fi
2689 if test "${GNU_MALLOC}" = "yes" ; then
2690   AC_DEFINE(GNU_MALLOC, 1,
2691             [Define to 1 if you want to use the GNU memory allocator.])
2692 fi
2693 if test "${REL_ALLOC}" = "yes" ; then
2694   AC_DEFINE(REL_ALLOC, 1,
2695             [Define REL_ALLOC if you want to use the relocating allocator for
2696              buffer space.])
2697 fi
2698
2699
2700 AH_TOP([/* GNU Emacs site configuration template file.
2701    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2702      2006, 2007, 2008, 2009  Free Software Foundation, Inc.
2703
2704 This file is part of GNU Emacs.
2705
2706 GNU Emacs is free software: you can redistribute it and/or modify
2707 it under the terms of the GNU General Public License as published by
2708 the Free Software Foundation, either version 3 of the License, or
2709 (at your option) any later version.
2710
2711 GNU Emacs is distributed in the hope that it will be useful,
2712 but WITHOUT ANY WARRANTY; without even the implied warranty of
2713 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2714 GNU General Public License for more details.
2715
2716 You should have received a copy of the GNU General Public License
2717 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
2718
2719
2720 /* No code in Emacs #includes config.h twice, but some bits of code
2721    intended to work with other packages as well (like gmalloc.c)
2722    think they can include it as many times as they like.  */
2723 #ifndef EMACS_CONFIG_H
2724 #define EMACS_CONFIG_H
2725 ])dnl
2726
2727 AH_BOTTOM([
2728 /* If we're using X11/Carbon/GNUstep, define some consequences.  */
2729 #if defined(HAVE_X_WINDOWS) || defined(HAVE_NS)
2730 #define HAVE_WINDOW_SYSTEM
2731 #define HAVE_MOUSE
2732 #endif
2733
2734 /* Define AMPERSAND_FULL_NAME if you use the convention
2735    that & in the full name stands for the login id.  */
2736 /* Turned on June 1996 supposing nobody will mind it.  */
2737 #define AMPERSAND_FULL_NAME
2738
2739 /* Define HAVE_SOUND if we have sound support.  We know it works
2740    and compiles only on the specified platforms.   For others,
2741    it probably doesn't make sense to try.  */
2742
2743 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2744 #ifdef HAVE_MACHINE_SOUNDCARD_H
2745 #define HAVE_SOUND 1
2746 #endif
2747 #ifdef HAVE_SYS_SOUNDCARD_H
2748 #define HAVE_SOUND 1
2749 #endif
2750 #ifdef HAVE_SOUNDCARD_H
2751 #define HAVE_SOUND 1
2752 #endif
2753 #ifdef HAVE_ALSA
2754 #define HAVE_SOUND 1
2755 #endif
2756 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2757
2758 /* If using GNU, then support inline function declarations. */
2759 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2760    generally, because even if non-gcc compilers accept `inline', they
2761    may reject `extern inline'.  */
2762 #if defined (__GNUC__) && defined (OPTIMIZE)
2763 #define INLINE __inline__
2764 #else
2765 #define INLINE
2766 #endif
2767
2768 /* `subprocesses' should be defined if you want to
2769    have code for asynchronous subprocesses
2770    (as used in M-x compile and M-x shell).
2771    Only MSDOS does not support this (it overrides
2772    this in its config_opsysfile below).  */
2773
2774 #define subprocesses
2775
2776 /* Include the os and machine dependent files.  */
2777 #include config_opsysfile
2778 #include config_machfile
2779
2780 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
2781   (There is probably a better place to do this, but right now the Cocoa
2782    side does this in s/darwin.h and we cannot
2783    parallel this exactly since GNUstep is multi-OS. */
2784 #ifdef HAVE_NS
2785 # ifdef NS_IMPL_GNUSTEP
2786 /* See also .m.o rule in Makefile.in */
2787 /* FIXME: are all these flags really needed?  Document here why.  */
2788 #  define C_SWITCH_X_SYSTEM -D_REENTRANT -fPIC -fno-strict-aliasing
2789 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
2790 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
2791 #  define SYSTEM_PURESIZE_EXTRA 30000
2792 # endif /* NS_IMPL_GNUSTEP */
2793 #endif /* HAVE_NS */
2794
2795 /* SIGTYPE is the macro we actually use.  */
2796 #ifndef SIGTYPE
2797 #define SIGTYPE RETSIGTYPE
2798 #endif
2799
2800 #ifdef emacs /* Don't do this for lib-src.  */
2801 /* Tell regex.c to use a type compatible with Emacs.  */
2802 #define RE_TRANSLATE_TYPE Lisp_Object
2803 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2804 #ifdef make_number
2805 /* If make_number is a macro, use it.  */
2806 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2807 #else
2808 /* If make_number is a function, avoid it.  */
2809 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2810 #endif
2811 #endif
2812
2813 /* Avoid link-time collision with system mktime if we will use our own.  */
2814 #if ! HAVE_MKTIME || BROKEN_MKTIME
2815 #define mktime emacs_mktime
2816 #endif
2817
2818 #define my_strftime nstrftime   /* for strftime.c */
2819
2820 /* The rest of the code currently tests the CPP symbol BSTRING.
2821    Override any claims made by the system-description files.
2822    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2823 #undef BSTRING
2824 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2825 #define BSTRING
2826 #endif
2827
2828 /* Some of the files of Emacs which are intended for use with other
2829    programs assume that if you have a config.h file, you must declare
2830    the type of getenv.
2831
2832    This declaration shouldn't appear when alloca.s or Makefile.in
2833    includes config.h.  */
2834 #ifndef NOT_C_CODE
2835 extern char *getenv ();
2836 #endif
2837
2838 /* These default definitions are good for almost all machines.
2839    The exceptions override them in m/MACHINE.h.  */
2840
2841 #ifndef BITS_PER_CHAR
2842 #define BITS_PER_CHAR 8
2843 #endif
2844
2845 #ifndef BITS_PER_SHORT
2846 #define BITS_PER_SHORT 16
2847 #endif
2848
2849 /* Note that lisp.h uses this in a preprocessor conditional, so it
2850    would not work to use sizeof.  That being so, we do all of them
2851    without sizeof, for uniformity's sake.  */
2852 #ifndef BITS_PER_INT
2853 #define BITS_PER_INT 32
2854 #endif
2855
2856 #ifndef BITS_PER_LONG
2857 #ifdef _LP64
2858 #define BITS_PER_LONG 64
2859 #else
2860 #define BITS_PER_LONG 32
2861 #endif
2862 #endif
2863
2864 /* Define if the compiler supports function prototypes.  It may do so
2865    but not define __STDC__ (e.g. DEC C by default) or may define it as
2866    zero.  */
2867 #undef PROTOTYPES
2868 /* For mktime.c:  */
2869 #ifndef __P
2870 # if defined PROTOTYPES
2871 #  define __P(args) args
2872 # else
2873 #  define __P(args) ()
2874 # endif  /* GCC.  */
2875 #endif /* __P */
2876
2877 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2878 #ifndef NOT_C_CODE
2879 #ifdef HAVE_STRING_H
2880 #include "string.h"
2881 #endif
2882 #ifdef HAVE_STRINGS_H
2883 #include "strings.h"  /* May be needed for bcopy & al. */
2884 #endif
2885 #ifdef HAVE_STDLIB_H
2886 #include <stdlib.h>
2887 #endif
2888 #ifndef __GNUC__
2889 # ifdef HAVE_ALLOCA_H
2890 #  include <alloca.h>
2891 # else /* AIX files deal with #pragma.  */
2892 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2893 char *alloca ();
2894 #  endif
2895 # endif /* HAVE_ALLOCA_H */
2896 #endif /* __GNUC__ */
2897 #ifndef HAVE_SIZE_T
2898 typedef unsigned size_t;
2899 #endif
2900 #endif /* NOT_C_CODE */
2901
2902 /* Define HAVE_X_I18N if we have usable i18n support.  */
2903
2904 #ifdef HAVE_X11R6
2905 #define HAVE_X_I18N
2906 #elif !defined X11R5_INHIBIT_I18N
2907 #define HAVE_X_I18N
2908 #endif
2909
2910 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2911
2912 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2913 #define HAVE_X11R6_XIM
2914 #endif
2915
2916 #if defined __GNUC__ && (__GNUC__ > 2 \
2917                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2918 #define NO_RETURN       __attribute__ ((__noreturn__))
2919 #else
2920 #define NO_RETURN       /* nothing */
2921 #endif
2922
2923 /* These won't be used automatically yet.  We also need to know, at least,
2924    that the stack is continuous.  */
2925 #ifdef __GNUC__
2926 #  ifndef GC_SETJMP_WORKS
2927   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2928      see NON_SAVING_SETJMP in the target descriptions.  */
2929   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2930      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2931      Fixme: Deal with SVR3.  */
2932 #    define GC_SETJMP_WORKS 1
2933 #  endif
2934 #  ifndef GC_LISP_OBJECT_ALIGNMENT
2935 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2936 #  endif
2937 #endif
2938
2939 #ifndef HAVE_BCOPY
2940 #define bcopy(a,b,s) memcpy (b,a,s)
2941 #endif
2942 #ifndef HAVE_BZERO
2943 #define bzero(a,s) memset (a,0,s)
2944 #endif
2945 #ifndef HAVE_BCMP
2946 #define BCMP memcmp
2947 #endif
2948
2949 #endif /* EMACS_CONFIG_H */
2950
2951 /*
2952 Local Variables:
2953 mode: c
2954 End:
2955 */
2956 ])dnl
2957
2958 #### Report on what we decided to do.
2959 #### Report GTK as a toolkit, even if it doesn't use Xt.
2960 #### It makes printing result more understandable as using GTK sets
2961 #### toolkit_scroll_bars to yes by default.
2962 if test "${HAVE_GTK}" = "yes"; then
2963   USE_X_TOOLKIT=GTK
2964 fi
2965
2966 echo "
2967 Configured for \`${canonical}'.
2968
2969   Where should the build process find the source code?    ${srcdir}
2970   What operating system and machine description files should Emacs use?
2971         \`${opsysfile}' and \`${machfile}'
2972   What compiler should emacs be built with?               ${CC} ${CFLAGS}
2973   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
2974   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
2975   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
2976   What window system should Emacs use?                    ${window_system}
2977   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
2978
2979 if test -n "${x_includes}"; then
2980 echo "  Where do we find X Windows header files?                ${x_includes}"
2981 else
2982 echo "  Where do we find X Windows header files?                Standard dirs"
2983 fi
2984 if test -n "${x_libraries}"; then
2985 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
2986 else
2987 echo "  Where do we find X Windows libraries?                   Standard dirs"
2988 fi
2989
2990 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
2991 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
2992 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
2993 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
2994 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
2995 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
2996 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
2997 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
2998 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
2999 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3000
3001 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3002 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3003 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3004 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3005
3006 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3007 echo
3008
3009 if test $USE_XASSERTS = yes; then
3010    echo "  Compiling with asserts turned on."
3011    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3012 fi
3013
3014 echo
3015
3016 if test "$USE_X_TOOLKIT" = GTK; then
3017   case "$canonical" in
3018   *cygwin*)
3019     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
3020   will probably get a crash on startup.  If this happens, please use another
3021   toolkit for Emacs.  See etc/PROBLEMS for more information."
3022   ;;
3023   esac
3024 fi
3025
3026 if test "$HAVE_NS" = "yes"; then
3027    echo
3028    echo "You must run \"make install\" in order to test the built application.
3029 The installed application will go to nextstep/Emacs.app and can be
3030 run or moved from there."
3031    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3032       echo "The application will be fully self-contained."
3033     else
3034       echo "The lisp resources for the application will be installed under ${prefix}.
3035 You may need to run \"make install\" with sudo.  The application will fail
3036 to run if these resources are not installed."
3037    fi
3038    echo
3039 fi
3040
3041 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3042   echo "D-Bus integration has been tested for GNU/Linux only."
3043   echo
3044 fi
3045
3046
3047 # Remove any trailing slashes in these variables.
3048 [test "${prefix}" != NONE &&
3049   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3050 test "${exec_prefix}" != NONE &&
3051   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3052
3053 # Now get this: Some word that is part of the ${srcdir} directory name
3054 # or the ${configuration} value might, just might, happen to be an
3055 # identifier like `sun4' or `i386' or something, and be predefined by
3056 # the C preprocessor to some helpful value like 1, or maybe the empty
3057 # string.  Needless to say consequent macro substitutions are less
3058 # than conducive to the makefile finding the correct directory.
3059 [cpp_undefs="`echo $srcdir $configuration $canonical |
3060   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3061   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
3062
3063 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3064 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3065 ## from Makefile.c can correctly provide the arg `-traditional' to the
3066 ## C preprocessor.
3067
3068 AC_EGREP_CPP(yes..yes,
3069         [yes..yes],
3070         CPP_NEED_TRADITIONAL=no,
3071         CPP_NEED_TRADITIONAL=yes)
3072
3073 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3074         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3075         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3076         lwlib/Makefile lisp/Makefile leim/Makefile, [
3077
3078 ### Make the necessary directories, if they don't exist.
3079 for dir in etc lisp ; do
3080   test -d ${dir} || mkdir ${dir}
3081 done
3082
3083 # Build src/Makefile from ${srcdir}/src/Makefile.c
3084 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3085 # This must be done after src/config.h is built, since we rely on that file.
3086
3087 echo creating src/epaths.h
3088 ${MAKE-make} epaths-force
3089
3090 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3091 # `..' to `. .'  unless invoked with -traditional
3092
3093 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3094   CPPFLAGS="$CPPFLAGS -traditional"
3095 fi
3096
3097 echo creating lib-src/Makefile
3098 ( cd lib-src
3099   rm -f junk.c junk1.c junk2.c
3100   sed -e '/start of cpp stuff/q' \
3101       < Makefile.c > junk1.c
3102   sed -e '1,/start of cpp stuff/d'\
3103       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3104       < Makefile.c > junk.c
3105   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3106       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3107   cat junk1.c junk2.c > Makefile.new
3108   rm -f junk.c junk1.c junk2.c
3109   chmod 444 Makefile.new
3110   mv -f Makefile.new Makefile
3111 )
3112
3113 echo creating src/Makefile
3114 ( cd src
3115   rm -f junk.c junk1.c junk2.c
3116   sed -e '/start of cpp stuff/q' \
3117       < Makefile.c > junk1.c
3118   sed -e '1,/start of cpp stuff/d'\
3119       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3120       < Makefile.c > junk.c
3121   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3122       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3123   cat junk1.c junk2.c > Makefile.new
3124   rm -f junk.c junk1.c junk2.c
3125   chmod 444 Makefile.new
3126   mv -f Makefile.new Makefile
3127 )
3128
3129 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3130   echo creating src/.gdbinit
3131   echo source $srcdir/src/.gdbinit > src/.gdbinit
3132 fi
3133
3134 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3135
3136 m4_if(dnl       Do not change this comment
3137    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3138 )dnl