lisp/calculator.el

   1 ;;; calculator.el --- a [not so] simple calculator for Emacs
   2
   3 ;; Copyright (C) 1998, 2000-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Eli Barzilay <eli@barzilay.org>
   6 ;; Keywords: tools, convenience
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;;=====================================================================
  24 ;;; Commentary:
  25 ;;
  26 ;; A calculator for Emacs.
  27 ;; Why should you reach for your mouse to get xcalc (calc.exe, gcalc or
  28 ;; whatever), when you have Emacs running already?
  29 ;;
  30 ;; If this is not part of your Emacs distribution, then simply bind
  31 ;; `calculator' to a key and make it an autoloaded function, e.g.:
  32 ;;   (autoload 'calculator "calculator"
  33 ;;     "Run the Emacs calculator." t)
  34 ;;   (global-set-key [(control return)] 'calculator)
  35 ;;
  36 ;; Written by Eli Barzilay: Maze is Life!  eli@barzilay.org
  37 ;;                                         http://www.barzilay.org/
  38 ;;
  39 ;; For latest version, check
  40 ;;     http://www.barzilay.org/misc/calculator.el
  41 ;;
  42
  43 ;;; History:
  44 ;; I hate history.
  45
  46 ;;;=====================================================================
  47 ;;; Customization:
  48
  49 (defgroup calculator nil
  50   "Simple Emacs calculator."
  51   :prefix "calculator"
  52   :version "21.1"
  53   :group 'tools
  54   :group 'applications)
  55
  56 (defcustom calculator-electric-mode nil
  57   "Run `calculator' electrically, in the echo area.
  58 Electric mode saves some place but changes the way you interact with the
  59 calculator."
  60   :type  'boolean
  61   :group 'calculator)
  62
  63 (defcustom calculator-use-menu t
  64   "Make `calculator' create a menu.
  65 Note that this requires easymenu.  Must be set before loading."
  66   :type  'boolean
  67   :group 'calculator)
  68
  69 (defcustom calculator-bind-escape nil
  70   "If non-nil, set escape to exit the calculator."
  71   :type  'boolean
  72   :group 'calculator)
  73
  74 (defcustom calculator-unary-style 'postfix
  75   "Value is either 'prefix or 'postfix.
  76 This determines the default behavior of unary operators."
  77   :type    '(choice (const prefix) (const postfix))
  78   :group   'calculator)
  79
  80 (defcustom calculator-prompt "Calc=%s> "
  81   "The prompt used by the Emacs calculator.
  82 It should contain a \"%s\" somewhere that will indicate the i/o radices;
  83 this will be a two-character string as described in the documentation
  84 for `calculator-mode'."
  85   :type  'string
  86   :group 'calculator)
  87
  88 (defcustom calculator-number-digits 3
  89   "The calculator's number of digits used for standard display.
  90 Used by the `calculator-standard-display' function - it will use the
  91 format string \"%.NC\" where this number is N and C is a character given
  92 at runtime."
  93   :type  'integer
  94   :group 'calculator)
  95
  96 (defcustom calculator-radix-grouping-mode t
  97   "Use digit grouping in radix output mode.
  98 If this is set, chunks of `calculator-radix-grouping-digits' characters
  99 will be separated by `calculator-radix-grouping-separator' when in radix
 100 output mode is active (determined by `calculator-output-radix')."
 101   :type  'boolean
 102   :group 'calculator)
 103
 104 (defcustom calculator-radix-grouping-digits 4
 105   "The number of digits used for grouping display in radix modes.
 106 See `calculator-radix-grouping-mode'."
 107   :type  'integer
 108   :group 'calculator)
 109
 110 (defcustom calculator-radix-grouping-separator "'"
 111   "The separator used in radix grouping display.
 112 See `calculator-radix-grouping-mode'."
 113   :type  'string
 114   :group 'calculator)
 115
 116 (defcustom calculator-remove-zeros t
 117   "Non-nil value means delete all redundant zero decimal digits.
 118 If this value is not t, and not nil, redundant zeros are removed except
 119 for one and if it is nil, nothing is removed.
 120 Used by the `calculator-remove-zeros' function."
 121   :type  '(choice (const t) (const leave-decimal) (const nil))
 122   :group 'calculator)
 123
 124 (defcustom calculator-displayer '(std ?n)
 125   "A displayer specification for numerical values.
 126 This is the displayer used to show all numbers in an expression.  Result
 127 values will be displayed according to the first element of
 128 `calculator-displayers'.
 129
 130 The displayer is a symbol, a string or an expression.  A symbol should
 131 be the name of a one-argument function, a string is used with a single
 132 argument and an expression will be evaluated with the variable `num'
 133 bound to whatever should be displayed.  If it is a function symbol, it
 134 should be able to handle special symbol arguments, currently 'left and
 135 'right which will be sent by special keys to modify display parameters
 136 associated with the displayer function (for example to change the number
 137 of digits displayed).
 138
 139 An exception to the above is the case of the list (std C) where C is a
 140 character, in this case the `calculator-standard-displayer' function
 141 will be used with this character for a format string."
 142   :group 'calculator)
 143
 144 (defcustom calculator-displayers
 145   '(((std ?n) "Standard display, decimal point or scientific")
 146     (calculator-eng-display "Eng display")
 147     ((std ?f) "Standard display, decimal point")
 148     ((std ?e) "Standard display, scientific")
 149     ("%S"     "Emacs printer"))
 150   "A list of displayers.
 151 Each element is a list of a displayer and a description string.  The
 152 first element is the one which is currently used, this is for the display
 153 of result values not values in expressions.  A displayer specification
 154 is the same as the values that can be stored in `calculator-displayer'.
 155
 156 `calculator-rotate-displayer' rotates this list."
 157   :type  'sexp
 158   :group 'calculator)
 159
 160 (defcustom calculator-paste-decimals t
 161   "If non-nil, convert pasted integers so they have a decimal point.
 162 This makes it possible to paste big integers since they will be read as
 163 floats, otherwise the Emacs reader will fail on them."
 164   :type  'boolean
 165   :group 'calculator)
 166
 167 (defcustom calculator-copy-displayer nil
 168   "If non-nil, this is any value that can be used for
 169 `calculator-displayer', to format a string before copying it with
 170 `calculator-copy'.  If nil, then `calculator-displayer's normal value is
 171 used."
 172   :type  'boolean
 173   :group 'calculator)
 174
 175 (defcustom calculator-2s-complement nil
 176   "If non-nil, show negative numbers in 2s complement in radix modes.
 177 Otherwise show as a negative number."
 178   :type  'boolean
 179   :group 'calculator)
 180
 181 (defcustom calculator-mode-hook nil
 182   "List of hook functions for `calculator-mode' to run.
 183 Note: if `calculator-electric-mode' is on, then this hook will get
 184 activated in the minibuffer - in that case it should not do much more
 185 than local key settings and other effects that will change things
 186 outside the scope of calculator related code."
 187   :type  'hook
 188   :group 'calculator)
 189
 190 (defcustom calculator-user-registers nil
 191   "An association list of user-defined register bindings.
 192 Each element in this list is a list of a character and a number that
 193 will be stored in that character's register.
 194
 195 For example, use this to define the golden ratio number:
 196   (setq calculator-user-registers '((?g .  1.61803398875)))
 197 before you load calculator."
 198   :type  '(repeat (cons character number))
 199   :set   (lambda (_ val)
 200            (and (boundp 'calculator-registers)
 201                 (setq calculator-registers
 202                       (append val calculator-registers)))
 203            (setq calculator-user-registers val))
 204   :group 'calculator)
 205
 206 (defcustom calculator-user-operators nil
 207   "A list of additional operators.
 208 This is a list in the same format as specified in the documentation for
 209 `calculator-operators', that you can use to bind additional calculator
 210 operators.  It is probably not a good idea to modify this value with
 211 `customize' since it is too complex...
 212
 213 Examples:
 214
 215 * A very simple one, adding a postfix \"x-to-y\" conversion keys, using
 216   t as a prefix key:
 217
 218   (setq calculator-user-operators
 219         '((\"tf\" cl-to-fr (+ 32 (/ (* X 9) 5)) 1)
 220           (\"tc\" fr-to-cl (/ (* (- X 32) 5) 9) 1)
 221           (\"tp\" kg-to-lb (/ X 0.453592)       1)
 222           (\"tk\" lb-to-kg (* X 0.453592)       1)
 223           (\"tF\" mt-to-ft (/ X 0.3048)         1)
 224           (\"tM\" ft-to-mt (* X 0.3048)         1)))
 225
 226 * Using a function-like form is very simple, X for an argument (Y the
 227   second in case of a binary operator), TX is a truncated version of X
 228   and F does a recursive call, Here is a [very inefficient] Fibonacci
 229   number calculation:
 230
 231   (add-to-list 'calculator-user-operators
 232                '(\"F\" fib (if (<= TX 1)
 233                          1
 234                          (+ (F (- TX 1)) (F (- TX 2)))) 0))
 235
 236   Note that this will be either postfix or prefix, according to
 237   `calculator-unary-style'."
 238   :type  '(repeat (list string symbol sexp integer integer))
 239   :group 'calculator)
 240
 241 ;;;=====================================================================
 242 ;;; Code:
 243
 244 ;;;---------------------------------------------------------------------
 245 ;;; Variables
 246
 247 (defvar calculator-initial-operators
 248   '(;; "+"/"-" have keybindings of themselves, not calculator-ops
 249     ("=" =     identity        1 -1)
 250     (nobind "+" +  +           2  4)
 251     (nobind "-" -  -           2  4)
 252     (nobind "+" +  +          -1  9)
 253     (nobind "-" -  -          -1  9)
 254     ("(" \(    identity       -1 -1)
 255     (")" \)    identity       +1 10)
 256     ;; normal keys
 257     ("|"  or   (logior TX TY)  2  2)
 258     ("#"  xor  (logxor TX TY)  2  2)
 259     ("&"  and  (logand TX TY)  2  3)
 260     ("*"  *    *               2  5)
 261     ("/"  /    /               2  5)
 262     ("\\" div  (/ TX TY)       2  5)
 263     ("%"  rem  (% TX TY)       2  5)
 264     ("L"  log  log             2  6)
 265     ("S"  sin  (sin DX)        x  6)
 266     ("C"  cos  (cos DX)        x  6)
 267     ("T"  tan  (tan DX)        x  6)
 268     ("IS" asin (D (asin X))    x  6)
 269     ("IC" acos (D (acos X))    x  6)
 270     ("IT" atan (D (atan X))    x  6)
 271     ("Q"  sqrt sqrt            x  7)
 272     ("^"  ^    calculator-expt 2  7)
 273     ("!"  !    calculator-fact x  7)
 274     (";"  1/   (/ 1 X)         1  7)
 275     ("_"  -    -               1  8)
 276     ("~"  ~    (lognot TX)     x  8)
 277     (">"  repR calculator-repR 1  8)
 278     ("<"  repL calculator-repL 1  8)
 279     ("v"  avg  (/ (apply '+ L) (length L)) 0 8)
 280     ("l"  tot  (apply '+ L)    0 8)
 281     )
 282   "A list of initial operators.
 283 This is a list in the same format as `calculator-operators'.  Whenever
 284 `calculator' starts, it looks at the value of this variable, and if it
 285 is not empty, its contents is prepended to `calculator-operators' and
 286 the appropriate key bindings are made.
 287
 288 This variable is then reset to nil.  Don't use this if you want to add
 289 user-defined operators, use `calculator-user-operators' instead.")
 290
 291 (defvar calculator-operators nil
 292   "The calculator operators, each a list with:
 293
 294 1. The key that is bound to for this operation (usually a string);
 295
 296 2. The displayed symbol for this function;
 297
 298 3. The function symbol, or a form that uses the variables `X' and `Y',
 299    (if it is a binary operator), `TX' and `TY' (truncated integer
 300    versions), `DX' (converted to radians if degrees mode is on), `D'
 301    (function for converting radians to degrees if deg mode is on), `L'
 302    (list of saved values), `F' (function for recursive iteration calls)
 303    and evaluates to the function value - these variables are capital;
 304
 305 4. The function's arity, optional, one of: 2 => binary, -1 => prefix
 306    unary, +1 => postfix unary, 0 => a 0-arg operator func, non-number =>
 307    postfix/prefix as determined by `calculator-unary-style' (the
 308    default);
 309
 310 5. The function's precedence - should be in the range of 1 (lowest) to
 311    9 (highest) (optional, defaults to 1);
 312
 313 It it possible have a unary prefix version of a binary operator if it
 314 comes later in this list.  If the list begins with the symbol 'nobind,
 315 then no key binding will take place - this is only useful for predefined
 316 keys.
 317
 318 Use `calculator-user-operators' to add operators to this list, see its
 319 documentation for an example.")
 320
 321 (defvar calculator-stack nil
 322   "Stack contents - operations and operands.")
 323
 324 (defvar calculator-curnum nil
 325   "Current number being entered (as a string).")
 326
 327 (defvar calculator-stack-display nil
 328   "Cons of the stack and its string representation.")
 329
 330 (defvar calculator-char-radix
 331   '((?D . nil) (?B . bin) (?O . oct) (?H . hex) (?X . hex))
 332   "A table to convert input characters to corresponding radix symbols.")
 333
 334 (defvar calculator-output-radix nil
 335   "The mode for display, one of: nil (decimal), 'bin, 'oct or 'hex.")
 336
 337 (defvar calculator-input-radix nil
 338   "The mode for input, one of: nil (decimal), 'bin, 'oct or 'hex.")
 339
 340 (defvar calculator-deg nil
 341   "Non-nil if trig functions operate on degrees instead of radians.")
 342
 343 (defvar calculator-saved-list nil
 344   "A list of saved values collected.")
 345
 346 (defvar calculator-saved-ptr 0
 347   "The pointer to the current saved number.")
 348
 349 (defvar calculator-add-saved nil
 350   "Bound to t when a value should be added to the saved-list.")
 351
 352 (defvar calculator-display-fragile nil
 353   "When non-nil, we see something that the next digit should replace.")
 354
 355 (defvar calculator-buffer nil
 356   "The current calculator buffer.")
 357
 358 (defvar calculator-eng-extra nil
 359   "Internal value used by `calculator-eng-display'.")
 360
 361 (defvar calculator-eng-tmp-show nil
 362   "Internal value used by `calculator-eng-display'.")
 363
 364 (defvar calculator-last-opXY nil
 365   "The last binary operation and its arguments.
 366 Used for repeating operations in calculator-repR/L.")
 367
 368 (defvar calculator-registers ; use user-bindings first
 369   (append calculator-user-registers
 370           (list (cons ?e float-e) (cons ?p float-pi)))
 371   "The association list of calculator register values.")
 372
 373 (defvar calculator-saved-global-map nil
 374   "Saved global key map.")
 375
 376 (defvar calculator-restart-other-mode nil
 377   "Used to hack restarting with the electric mode changed.")
 378
 379 ;;;---------------------------------------------------------------------
 380 ;;; Key bindings
 381
 382 (defvar calculator-mode-map
 383   (let ((map (make-sparse-keymap)))
 384     (suppress-keymap map t)
 385     (define-key map "i" nil)
 386     (define-key map "o" nil)
 387     (let ((p
 388            '((calculator-open-paren  "[")
 389              (calculator-close-paren "]")
 390              (calculator-op-or-exp   "+" "-" [kp-add] [kp-subtract])
 391              (calculator-digit       "0" "1" "2" "3" "4" "5" "6" "7" "8"
 392                                      "9" "a" "b" "c" "d" "f"
 393                                      [kp-0] [kp-1] [kp-2] [kp-3] [kp-4]
 394                                      [kp-5] [kp-6] [kp-7] [kp-8] [kp-9])
 395              (calculator-op          [kp-divide] [kp-multiply])
 396              (calculator-decimal     "." [kp-decimal])
 397              (calculator-exp         "e")
 398              (calculator-dec/deg-mode "D")
 399              (calculator-set-register "s")
 400              (calculator-get-register "g")
 401              (calculator-radix-mode        "H" "X" "O" "B")
 402              (calculator-radix-input-mode  "id" "ih" "ix" "io" "ib"
 403                                            "iD" "iH" "iX" "iO" "iB")
 404              (calculator-radix-output-mode "od" "oh" "ox" "oo" "ob"
 405                                            "oD" "oH" "oX" "oO" "oB")
 406              (calculator-rotate-displayer      "'")
 407              (calculator-rotate-displayer-back "\"")
 408              (calculator-displayer-prev        "{")
 409              (calculator-displayer-next        "}")
 410              (calculator-saved-up      [up] [?\C-p])
 411              (calculator-saved-down    [down] [?\C-n])
 412              (calculator-quit          "q" [?\C-g])
 413              (calculator-enter         [enter] [linefeed] [kp-enter]
 414                                        [return] [?\r] [?\n])
 415              (calculator-save-on-list  " " [space])
 416              (calculator-clear-saved   [?\C-c] [(control delete)])
 417              (calculator-save-and-quit [(control return)]
 418                                        [(control kp-enter)])
 419              (calculator-paste         [insert] [(shift insert)]
 420                                        [paste] [mouse-2] [?\C-y])
 421              (calculator-clear         [delete] [?\C-?] [?\C-d])
 422              (calculator-help          [?h] [??] [f1] [help])
 423              (calculator-copy          [(control insert)] [copy])
 424              (calculator-backspace     [backspace])
 425              )))
 426       (while p
 427         ;; reverse the keys so first defs come last - makes the more
 428         ;; sensible bindings visible in the menu
 429         (let ((func (car (car p))) (keys (reverse (cdr (car p)))))
 430           (while keys
 431             (define-key map (car keys) func)
 432             (setq keys (cdr keys))))
 433         (setq p (cdr p))))
 434     (if calculator-bind-escape
 435       (progn (define-key map [?\e] 'calculator-quit)
 436              (define-key map [escape] 'calculator-quit))
 437       (define-key map [?\e ?\e ?\e] 'calculator-quit))
 438     ;; make C-h work in text-mode
 439     (or window-system (define-key map [?\C-h] 'calculator-backspace))
 440     ;; set up a menu
 441     (if (and calculator-use-menu (not (boundp 'calculator-menu)))
 442       (let ((radix-selectors
 443              (mapcar (lambda (x)
 444                        `([,(nth 0 x)
 445                           (calculator-radix-mode ,(nth 2 x))
 446                           :style radio
 447                           :keys ,(nth 2 x)
 448                           :selected
 449                           (and
 450                            (eq calculator-input-radix ',(nth 1 x))
 451                            (eq calculator-output-radix ',(nth 1 x)))]
 452                          [,(concat (nth 0 x) " Input")
 453                           (calculator-radix-input-mode ,(nth 2 x))
 454                           :keys ,(concat "i" (downcase (nth 2 x)))
 455                           :style radio
 456                           :selected
 457                           (eq calculator-input-radix ',(nth 1 x))]
 458                          [,(concat (nth 0 x) " Output")
 459                           (calculator-radix-output-mode ,(nth 2 x))
 460                           :keys ,(concat "o" (downcase (nth 2 x)))
 461                           :style radio
 462                           :selected
 463                           (eq calculator-output-radix ',(nth 1 x))]))
 464                      '(("Decimal"     nil "D")
 465                        ("Binary"      bin "B")
 466                        ("Octal"       oct "O")
 467                        ("Hexadecimal" hex "H"))))
 468             (op (lambda (name key)
 469                   `[,name (calculator-op ,key) :keys ,key])))
 470         (easy-menu-define
 471           calculator-menu map "Calculator menu."
 472           `("Calculator"
 473             ["Help"
 474              (let ((last-command 'calculator-help)) (calculator-help))
 475              :keys "?"]
 476             "---"
 477             ["Copy"  calculator-copy]
 478             ["Paste" calculator-paste]
 479             "---"
 480             ["Electric mode"
 481              (progn (calculator-quit)
 482                     (setq calculator-restart-other-mode t)
 483                     (run-with-timer 0.1 nil (lambda () (message nil)))
 484                     ;; the message from the menu will be visible,
 485                     ;; couldn't make it go away...
 486                     (calculator))
 487              :active (not calculator-electric-mode)]
 488             ["Normal mode"
 489              (progn (setq calculator-restart-other-mode t)
 490                     (calculator-quit))
 491              :active calculator-electric-mode]
 492             "---"
 493             ("Functions"
 494              ,(funcall op "Repeat-right" ">")
 495              ,(funcall op "Repeat-left"  "<")
 496              "------General------"
 497              ,(funcall op "Reciprocal"   ";")
 498              ,(funcall op "Log"          "L")
 499              ,(funcall op "Square-root"  "Q")
 500              ,(funcall op "Factorial"    "!")
 501              "------Trigonometric------"
 502              ,(funcall op "Sinus"        "S")
 503              ,(funcall op "Cosine"       "C")
 504              ,(funcall op "Tangent"      "T")
 505              ,(funcall op "Inv-Sinus"    "IS")
 506              ,(funcall op "Inv-Cosine"   "IC")
 507              ,(funcall op "Inv-Tangent"  "IT")
 508              "------Bitwise------"
 509              ,(funcall op "Or"           "|")
 510              ,(funcall op "Xor"          "#")
 511              ,(funcall op "And"          "&")
 512              ,(funcall op "Not"          "~"))
 513             ("Saved List"
 514              ["Eval+Save"      calculator-save-on-list]
 515              ["Prev number"    calculator-saved-up]
 516              ["Next number"    calculator-saved-down]
 517              ["Delete current" calculator-clear
 518               :active (and calculator-display-fragile
 519                            calculator-saved-list
 520                            (= (car calculator-stack)
 521                               (nth calculator-saved-ptr
 522                                    calculator-saved-list)))]
 523              ["Delete all" calculator-clear-saved]
 524              "---"
 525              ,(funcall op "List-total"   "l")
 526              ,(funcall op "List-average" "v"))
 527             ("Registers"
 528              ["Get register" calculator-get-register]
 529              ["Set register" calculator-set-register])
 530             ("Modes"
 531              ["Radians"
 532               (progn
 533                 (and (or calculator-input-radix calculator-output-radix)
 534                      (calculator-radix-mode "D"))
 535                 (and calculator-deg (calculator-dec/deg-mode)))
 536               :keys "D"
 537               :style radio
 538               :selected (not (or calculator-input-radix
 539                                  calculator-output-radix
 540                                  calculator-deg))]
 541              ["Degrees"
 542               (progn
 543                 (and (or calculator-input-radix calculator-output-radix)
 544                      (calculator-radix-mode "D"))
 545                 (or calculator-deg (calculator-dec/deg-mode)))
 546               :keys "D"
 547               :style radio
 548               :selected (and calculator-deg
 549                              (not (or calculator-input-radix
 550                                       calculator-output-radix)))]
 551              "---"
 552              ,@(mapcar 'car radix-selectors)
 553              ("Separate I/O"
 554               ,@(mapcar (lambda (x) (nth 1 x)) radix-selectors)
 555               "---"
 556               ,@(mapcar (lambda (x) (nth 2 x)) radix-selectors)))
 557             ("Decimal Display"
 558              ,@(mapcar (lambda (d)
 559                          (vector (cadr d)
 560                                  ;; Note: inserts actual object here
 561                                  `(calculator-rotate-displayer ',d)))
 562                        calculator-displayers)
 563              "---"
 564              ["Change Prev Display" calculator-displayer-prev]
 565              ["Change Next Display" calculator-displayer-next])
 566             "---"
 567             ["Copy+Quit" calculator-save-and-quit]
 568             ["Quit"      calculator-quit]))))
 569     map)
 570   "The calculator key map.")
 571
 572 ;;;---------------------------------------------------------------------
 573 ;;; Startup and mode stuff
 574
 575 (define-derived-mode calculator-mode fundamental-mode "Calculator"
 576   ;; this help is also used as the major help screen
 577   "A [not so] simple calculator for Emacs.
 578
 579 This calculator is used in the same way as other popular calculators
 580 like xcalc or calc.exe - but using an Emacs interface.
 581
 582 Expressions are entered using normal infix notation, parens are used as
 583 normal.  Unary functions are usually postfix, but some depends on the
 584 value of `calculator-unary-style' (if the style for an operator below is
 585 specified, then it is fixed, otherwise it depends on this variable).
 586 `+' and `-' can be used as either binary operators or prefix unary
 587 operators.  Numbers can be entered with exponential notation using `e',
 588 except when using a non-decimal radix mode for input (in this case `e'
 589 will be the hexadecimal digit).  If the result of a calculation is too
 590 large (out of range for Emacs), the value of \"inf\" is returned.
 591
 592 Here are the editing keys:
 593 * `RET' `='      evaluate the current expression
 594 * `C-insert'     copy the whole current expression to the `kill-ring'
 595 * `C-return'     evaluate, save result the `kill-ring' and exit
 596 * `insert'       paste a number if the one was copied (normally)
 597 * `delete' `C-d' clear last argument or whole expression (hit twice)
 598 * `backspace'    delete a digit or a previous expression element
 599 * `h' `?'        pop-up a quick reference help
 600 * `ESC' `q'      exit (`ESC' can be used if `calculator-bind-escape' is
 601                  non-nil, otherwise use three consecutive `ESC's)
 602
 603 These operators are pre-defined:
 604 * `+' `-' `*' `/' the common binary operators
 605 * `\\' `%'         integer division and reminder
 606 * `_' `;'         postfix unary negation and reciprocal
 607 * `^' `L'         binary operators for x^y and log(x) in base y
 608 * `Q' `!'         unary square root and factorial
 609 * `S' `C' `T'     unary trigonometric operators - sin, cos and tan
 610 * `|' `#' `&' `~' bitwise operators - or, xor, and, not
 611
 612 The trigonometric functions can be inverted if prefixed with an `I', see
 613 below for the way to use degrees instead of the default radians.
 614
 615 Two special postfix unary operators are `>' and `<': whenever a binary
 616 operator is performed, it is remembered along with its arguments; then
 617 `>' (`<') will apply the same operator with the same right (left)
 618 argument.
 619
 620 hex/oct/bin modes can be set for input and for display separately.
 621 Another toggle-able mode is for using degrees instead of radians for
 622 trigonometric functions.
 623 The keys to switch modes are (`X' is shortcut for `H'):
 624 * `D'             switch to all-decimal mode, or toggle degrees/radians
 625 * `B' `O' `H' `X' binary/octal/hexadecimal modes for input & display
 626 * `i' `o'         followed by one of `D' `B' `O' `H' `X' (case
 627                   insensitive) sets only the input or display radix mode
 628 The prompt indicates the current modes:
 629 * \"D=\": degrees mode;
 630 * \"?=\": (? is B/O/H) this is the radix for both input and output;
 631 * \"=?\": (? is B/O/H) the display radix (when input is decimal);
 632 * \"??\": (? is D/B/O/H) 1st char for input radix, 2nd for display.
 633
 634 Also, the quote key can be used to switch display modes for decimal
 635 numbers (double-quote rotates back), and the two brace characters
 636 \(\"{\" and \"}\" change display parameters that these displayers use (if
 637 they handle such).  If output is using any radix mode, then these keys
 638 toggle digit grouping mode and the chunk size.
 639
 640 Values can be saved for future reference in either a list of saved
 641 values, or in registers.
 642
 643 The list of saved values is useful for statistics operations on some
 644 collected data.  It is possible to navigate in this list, and if the
 645 value shown is the current one on the list, an indication is displayed
 646 as \"[N]\" if this is the last number and there are N numbers, or
 647 \"[M/N]\" if the M-th value is shown.
 648 * `SPC'            evaluate the current value as usual, but also adds
 649                    the result to the list of saved values
 650 * `l' `v'          computes total / average of saved values
 651 * `up' `C-p'       browse to the previous value in the list
 652 * `down' `C-n'     browse to the next value in the list
 653 * `delete' `C-d'   remove current value from the list (if it is on it)
 654 * `C-delete' `C-c' delete the whole list
 655
 656 Registers are variable-like place-holders for values:
 657 * `s' followed by a character attach the current value to that character
 658 * `g' followed by a character fetches the attached value
 659
 660 There are many variables that can be used to customize the calculator.
 661 Some interesting customization variables are:
 662 * `calculator-electric-mode'  use only the echo-area electrically.
 663 * `calculator-unary-style'    set most unary ops to pre/postfix style.
 664 * `calculator-user-registers' to define user-preset registers.
 665 * `calculator-user-operators' to add user-defined operators.
 666 See the documentation for these variables, and \"calculator.el\" for
 667 more information.
 668
 669 \\{calculator-mode-map}")
 670
 671 (declare-function Electric-command-loop "electric"
 672                   (return-tag &optional prompt inhibit-quitting
 673                               loop-function loop-state))
 674
 675 ;;;###autoload
 676 (defun calculator ()
 677   "Run the Emacs calculator.
 678 See the documentation for `calculator-mode' for more information."
 679   (interactive)
 680   (if calculator-restart-other-mode
 681     (setq calculator-electric-mode (not calculator-electric-mode)))
 682   (if calculator-initial-operators
 683     (progn (calculator-add-operators calculator-initial-operators)
 684            (setq calculator-initial-operators nil)
 685            ;; don't change this since it is a customization variable,
 686            ;; its set function will add any new operators
 687            (calculator-add-operators calculator-user-operators)))
 688   (setq calculator-buffer (get-buffer-create "*calculator*"))
 689   (if calculator-electric-mode
 690     (save-window-excursion
 691       (progn (require 'electric) (message nil)) ; hide load message
 692       (let (old-g-map old-l-map (echo-keystrokes 0)
 693             (garbage-collection-messages nil)) ; no gc msg when electric
 694         (set-window-buffer (minibuffer-window) calculator-buffer)
 695         (select-window (minibuffer-window))
 696         (calculator-reset)
 697         (calculator-update-display)
 698         (setq old-l-map (current-local-map))
 699         (setq old-g-map (current-global-map))
 700         (setq calculator-saved-global-map (current-global-map))
 701         (use-local-map nil)
 702         (use-global-map calculator-mode-map)
 703         (run-hooks 'calculator-mode-hook)
 704         (unwind-protect
 705             (catch 'calculator-done
 706               (Electric-command-loop
 707                'calculator-done
 708                ;; can't use 'noprompt, bug in electric.el
 709                (lambda () 'noprompt)
 710                nil
 711                (lambda (x y) (calculator-update-display))))
 712           (and calculator-buffer
 713                (catch 'calculator-done (calculator-quit)))
 714           (use-local-map old-l-map)
 715           (use-global-map old-g-map))))
 716     (progn
 717       (cond
 718         ((not (get-buffer-window calculator-buffer))
 719          (let ((window-min-height 2))
 720            ;; maybe leave two lines for our window because of the
 721            ;; normal `raised' mode line
 722            (select-window
 723             (split-window-below
 724              ;; If the mode line might interfere with the calculator
 725              ;; buffer, use 3 lines instead.
 726              (if (and (fboundp 'face-attr-construct)
 727                       (let* ((dh (plist-get (face-attr-construct 'default) :height))
 728                              (mf (face-attr-construct 'mode-line))
 729                              (mh (plist-get mf :height)))
 730                         ;; If the mode line is shorter than the default,
 731                         ;; stick with 2 lines.  (It may be necessary to
 732                         ;; check how much shorter.)
 733                         (and
 734                          (not
 735                           (or (and (integerp dh)
 736                                    (integerp mh)
 737                                    (< mh dh))
 738                               (and (numberp mh)
 739                                    (not (integerp mh))
 740                                    (< mh 1))))
 741                          (or
 742                           ;; If the mode line is taller than the default,
 743                           ;; use 3 lines.
 744                           (and (integerp dh)
 745                                (integerp mh)
 746                                (> mh dh))
 747                           (and (numberp mh)
 748                                (not (integerp mh))
 749                                (> mh 1))
 750                           ;; If the mode line has a box with non-negative line-width,
 751                           ;; use 3 lines.
 752                           (let* ((bx (plist-get mf :box))
 753                                  (lh (plist-get bx :line-width)))
 754                             (and bx
 755                                  (or
 756                                   (not lh)
 757                                   (> lh 0))))
 758                           ;; If the mode line has an overline, use 3 lines.
 759                           (plist-get (face-attr-construct 'mode-line) :overline)))))
 760                -3 -2)))
 761            (switch-to-buffer calculator-buffer)))
 762         ((not (eq (current-buffer) calculator-buffer))
 763          (select-window (get-buffer-window calculator-buffer))))
 764       (calculator-mode)
 765       (setq buffer-read-only t)
 766       (calculator-reset)
 767       (message "Hit `?' For a quick help screen.")))
 768   (if (and calculator-restart-other-mode calculator-electric-mode)
 769     (calculator)))
 770
 771 (defun calculator-message (string &rest arguments)
 772   "Same as `message', but special handle of electric mode."
 773   (apply 'message string arguments)
 774   (if calculator-electric-mode
 775     (progn (sit-for 1) (message nil))))
 776
 777 ;;;---------------------------------------------------------------------
 778 ;;; Operators
 779
 780 (defun calculator-op-arity (op)
 781   "Return OP's arity, 2, +1 or -1."
 782   (let ((arity (or (nth 3 op) 'x)))
 783     (if (numberp arity)
 784       arity
 785       (if (eq calculator-unary-style 'postfix) +1 -1))))
 786
 787 (defun calculator-op-prec (op)
 788   "Return OP's precedence for reducing when inserting into the stack.
 789 Defaults to 1."
 790   (or (nth 4 op) 1))
 791
 792 (defun calculator-add-operators (more-ops)
 793   "This function handles operator addition.
 794 Adds MORE-OPS to `calculator-operator', called initially to handle
 795 `calculator-initial-operators' and `calculator-user-operators'."
 796   (let ((added-ops nil))
 797     (while more-ops
 798       (or (eq (car (car more-ops)) 'nobind)
 799           (let ((i -1) (key (car (car more-ops))))
 800             ;; make sure the key is undefined, so it's easy to define
 801             ;; prefix keys
 802             (while (< (setq i (1+ i)) (length key))
 803               (or (keymapp
 804                    (lookup-key calculator-mode-map
 805                                (substring key 0 (1+ i))))
 806                   (progn
 807                     (define-key
 808                       calculator-mode-map (substring key 0 (1+ i)) nil)
 809                     (setq i (length key)))))
 810             (define-key calculator-mode-map key 'calculator-op)))
 811       (setq added-ops (cons (if (eq (car (car more-ops)) 'nobind)
 812                               (cdr (car more-ops))
 813                               (car more-ops))
 814                             added-ops))
 815       (setq more-ops (cdr more-ops)))
 816     ;; added-ops come first, but in correct order
 817     (setq calculator-operators
 818           (append (nreverse added-ops) calculator-operators))))
 819
 820 ;;;---------------------------------------------------------------------
 821 ;;; Display stuff
 822
 823 (defun calculator-reset ()
 824   "Reset calculator variables."
 825   (or calculator-restart-other-mode
 826       (setq calculator-stack           nil
 827             calculator-curnum          nil
 828             calculator-stack-display   nil
 829             calculator-display-fragile nil))
 830   (setq calculator-restart-other-mode nil)
 831   (calculator-update-display))
 832
 833 (defun calculator-get-prompt ()
 834   "Return a string to display.
 835 The string is set not to exceed the screen width."
 836   (let* ((calculator-prompt
 837           (format calculator-prompt
 838                   (cond
 839                     ((or calculator-output-radix calculator-input-radix)
 840                      (if (eq calculator-output-radix
 841                              calculator-input-radix)
 842                        (concat
 843                         (char-to-string
 844                          (car (rassq calculator-output-radix
 845                                      calculator-char-radix)))
 846                         "=")
 847                        (concat
 848                         (if calculator-input-radix
 849                           (char-to-string
 850                            (car (rassq calculator-input-radix
 851                                        calculator-char-radix)))
 852                           "=")
 853                         (char-to-string
 854                          (car (rassq calculator-output-radix
 855                                      calculator-char-radix))))))
 856                     (calculator-deg "D=")
 857                     (t "=="))))
 858          (prompt
 859           (concat calculator-prompt
 860                   (cdr calculator-stack-display)
 861                   (cond (calculator-curnum
 862                          ;; number being typed
 863                          (concat calculator-curnum "_"))
 864                         ((and (= 1 (length calculator-stack))
 865                               calculator-display-fragile)
 866                          ;; only the result is shown, next number will
 867                          ;; restart
 868                          nil)
 869                         (t
 870                          ;; waiting for a number or an operator
 871                          "?"))))
 872          (trim (- (length prompt) (1- (window-width)))))
 873     (if (<= trim 0)
 874       prompt
 875       (concat calculator-prompt
 876               (substring prompt (+ trim (length calculator-prompt)))))))
 877
 878 (defun calculator-string-to-number (str)
 879   "Convert the given STR to a number, according to the value of
 880 `calculator-input-radix'."
 881   (if calculator-input-radix
 882     (let ((radix
 883            (cdr (assq calculator-input-radix
 884                       '((bin . 2) (oct . 8) (hex . 16)))))
 885           (i -1) (value 0) (new-value 0))
 886       ;; assume mostly valid input (e.g., characters in range)
 887       (while (< (setq i (1+ i)) (length str))
 888         (setq new-value
 889               (let* ((ch (upcase (aref str i)))
 890                      (n (cond ((< ch ?0)  nil)
 891                               ((<= ch ?9) (- ch ?0))
 892                               ((< ch ?A)  nil)
 893                               ((<= ch ?Z) (- ch (- ?A 10)))
 894                               (t          nil))))
 895                 (if (and n (<= 0 n) (< n radix))
 896                   (+ n (* radix value))
 897                   (progn
 898                     (calculator-message
 899                      "Warning: Ignoring bad input character `%c'." ch)
 900                     (sit-for 1)
 901                     value))))
 902         (if (if (< new-value 0) (> value 0) (< value 0))
 903           (calculator-message "Warning: Overflow in input."))
 904         (setq value new-value))
 905       value)
 906     (car (read-from-string
 907           (cond ((equal "." str) "0.0")
 908                 ((string-match "[eE][+-]?$" str) (concat str "0"))
 909                 ((string-match "\\.[0-9]\\|[eE]" str) str)
 910                 ((string-match "\\." str)
 911                  ;; do this because Emacs reads "23." as an integer
 912                  (concat str "0"))
 913                 ((stringp str) (concat str ".0"))
 914                 (t "0.0"))))))
 915
 916 (defun calculator-curnum-value ()
 917   "Get the numeric value of the displayed number string as a float."
 918   (calculator-string-to-number calculator-curnum))
 919
 920 (defun calculator-rotate-displayer (&optional new-disp)
 921   "Switch to the next displayer on the `calculator-displayers' list.
 922 Can be called with an optional argument NEW-DISP to force rotation to
 923 that argument.
 924 If radix output mode is active, toggle digit grouping."
 925   (interactive)
 926   (cond
 927     (calculator-output-radix
 928      (setq calculator-radix-grouping-mode
 929            (not calculator-radix-grouping-mode))
 930      (calculator-message
 931       "Digit grouping mode %s."
 932       (if calculator-radix-grouping-mode "ON" "OFF")))
 933     (t
 934      (setq calculator-displayers
 935            (if (and new-disp (memq new-disp calculator-displayers))
 936              (let ((tmp nil))
 937                (while (not (eq (car calculator-displayers) new-disp))
 938                  (setq tmp (cons (car calculator-displayers) tmp))
 939                  (setq calculator-displayers
 940                        (cdr calculator-displayers)))
 941                (setq calculator-displayers
 942                      (nconc calculator-displayers (nreverse tmp))))
 943              (nconc (cdr calculator-displayers)
 944                     (list (car calculator-displayers)))))
 945      (calculator-message
 946       "Using %s." (cadr (car calculator-displayers)))))
 947   (calculator-enter))
 948
 949 (defun calculator-rotate-displayer-back ()
 950   "Like `calculator-rotate-displayer', but rotates modes back.
 951 If radix output mode is active, toggle digit grouping."
 952   (interactive)
 953   (calculator-rotate-displayer (car (last calculator-displayers))))
 954
 955 (defun calculator-displayer-prev ()
 956   "Send the current displayer function a 'left argument.
 957 This is used to modify display arguments (if the current displayer
 958 function supports this).
 959 If radix output mode is active, increase the grouping size."
 960   (interactive)
 961   (if calculator-output-radix
 962     (progn (setq calculator-radix-grouping-digits
 963                  (1+ calculator-radix-grouping-digits))
 964            (calculator-enter))
 965     (and (car calculator-displayers)
 966          (let ((disp (caar calculator-displayers)))
 967            (cond
 968              ((symbolp disp) (funcall disp 'left))
 969              ((and (consp disp) (eq 'std (car disp)))
 970               (calculator-standard-displayer 'left (cadr disp))))))))
 971
 972 (defun calculator-displayer-next ()
 973   "Send the current displayer function a 'right argument.
 974 This is used to modify display arguments (if the current displayer
 975 function supports this).
 976 If radix output mode is active, decrease the grouping size."
 977   (interactive)
 978   (if calculator-output-radix
 979     (progn (setq calculator-radix-grouping-digits
 980                  (max 2 (1- calculator-radix-grouping-digits)))
 981            (calculator-enter))
 982     (and (car calculator-displayers)
 983          (let ((disp (caar calculator-displayers)))
 984            (cond
 985              ((symbolp disp) (funcall disp 'right))
 986              ((and (consp disp) (eq 'std (car disp)))
 987               (calculator-standard-displayer 'right (cadr disp))))))))
 988
 989 (defun calculator-remove-zeros (numstr)
 990   "Get a number string NUMSTR and remove unnecessary zeros.
 991 The behavior of this function is controlled by
 992 `calculator-remove-zeros'."
 993   (cond ((and (eq calculator-remove-zeros t)
 994               (string-match "\\.0+\\([eE][+-]?[0-9]*\\)?$" numstr))
 995          ;; remove all redundant zeros leaving an integer
 996          (if (match-beginning 1)
 997            (concat (substring numstr 0 (match-beginning 0))
 998                    (match-string 1 numstr))
 999            (substring numstr 0 (match-beginning 0))))
1000         ((and calculator-remove-zeros
1001               (string-match
1002                "\\..\\([0-9]*[1-9]\\)?\\(0+\\)\\([eE][+-]?[0-9]*\\)?$"
1003                numstr))
1004          ;; remove zeros, except for first after the "."
1005          (if (match-beginning 3)
1006            (concat (substring numstr 0 (match-beginning 2))
1007                    (match-string 3 numstr))
1008            (substring numstr 0 (match-beginning 2))))
1009         (t numstr)))
1010
1011 (defun calculator-standard-displayer (num char)
1012   "Standard display function, used to display NUM.
1013 Its behavior is determined by `calculator-number-digits' and the given
1014 CHAR argument (both will be used to compose a format string).  If the
1015 char is \"n\" then this function will choose one between %f or %e, this
1016 is a work around %g jumping to exponential notation too fast.
1017
1018 The special 'left and 'right symbols will make it change the current
1019 number of digits displayed (`calculator-number-digits').
1020
1021 It will also remove redundant zeros from the result."
1022   (if (symbolp num)
1023     (cond ((eq num 'left)
1024            (and (> calculator-number-digits 0)
1025                 (setq calculator-number-digits
1026                       (1- calculator-number-digits))
1027                 (calculator-enter)))
1028           ((eq num 'right)
1029            (setq calculator-number-digits
1030                  (1+ calculator-number-digits))
1031            (calculator-enter)))
1032     (let ((str (if (zerop num)
1033                  "0"
1034                  (format
1035                   (concat "%."
1036                           (number-to-string calculator-number-digits)
1037                           (if (eq char ?n)
1038                             (let ((n (abs num)))
1039                               (if (or (< n 0.001) (> n 1e8)) "e" "f"))
1040                             (string char)))
1041                   num))))
1042       (calculator-remove-zeros str))))
1043
1044 (defun calculator-eng-display (num)
1045   "Display NUM in engineering notation.
1046 The number of decimal digits used is controlled by
1047 `calculator-number-digits', so to change it at runtime you have to use
1048 the 'left or 'right when one of the standard modes is used."
1049   (if (symbolp num)
1050     (cond ((eq num 'left)
1051            (setq calculator-eng-extra
1052                  (if calculator-eng-extra
1053                    (1+ calculator-eng-extra)
1054                    1))
1055            (let ((calculator-eng-tmp-show t)) (calculator-enter)))
1056           ((eq num 'right)
1057            (setq calculator-eng-extra
1058                  (if calculator-eng-extra
1059                    (1- calculator-eng-extra)
1060                    -1))
1061            (let ((calculator-eng-tmp-show t)) (calculator-enter))))
1062     (let ((exp 0))
1063       (and (not (= 0 num))
1064            (progn
1065              (while (< (abs num) 1.0)
1066                (setq num (* num 1000.0)) (setq exp (- exp 3)))
1067              (while (> (abs num) 999.0)
1068                (setq num (/ num 1000.0)) (setq exp (+ exp 3)))
1069              (and calculator-eng-tmp-show
1070                   (not (= 0 calculator-eng-extra))
1071                   (let ((i calculator-eng-extra))
1072                     (while (> i 0)
1073                       (setq num (* num 1000.0)) (setq exp (- exp 3))
1074                       (setq i (1- i)))
1075                     (while (< i 0)
1076                       (setq num (/ num 1000.0)) (setq exp (+ exp 3))
1077                       (setq i (1+ i)))))))
1078       (or calculator-eng-tmp-show (setq calculator-eng-extra nil))
1079       (let ((str (format (concat "%." (number-to-string
1080                                        calculator-number-digits)
1081                                  "f")
1082                          num)))
1083         (concat (let ((calculator-remove-zeros
1084                        ;; make sure we don't leave integers
1085                        (and calculator-remove-zeros 'x)))
1086                   (calculator-remove-zeros str))
1087                 "e" (number-to-string exp))))))
1088
1089 (defun calculator-number-to-string (num)
1090   "Convert NUM to a displayable string."
1091   (cond
1092     ((and (numberp num) calculator-output-radix)
1093      ;; print with radix - for binary I convert the octal number
1094      (let ((str (format (if (eq calculator-output-radix 'hex) "%x" "%o")
1095                         (calculator-truncate
1096                          (if calculator-2s-complement num (abs num))))))
1097        (if (eq calculator-output-radix 'bin)
1098          (let ((i -1) (s ""))
1099            (while (< (setq i (1+ i)) (length str))
1100              (setq s
1101                    (concat s
1102                            (cdr (assq (aref str i)
1103                                       '((?0 . "000") (?1 . "001")
1104                                         (?2 . "010") (?3 . "011")
1105                                         (?4 . "100") (?5 . "101")
1106                                         (?6 . "110") (?7 . "111")))))))
1107            (string-match "^0*\\(.+\\)" s)
1108            (setq str (match-string 1 s))))
1109        (if calculator-radix-grouping-mode
1110          (let ((d (/ (length str) calculator-radix-grouping-digits))
1111                (r (% (length str) calculator-radix-grouping-digits)))
1112            (while (>= (setq d (1- d)) (if (zerop r) 1 0))
1113              (let ((i (+ r (* d calculator-radix-grouping-digits))))
1114                (setq str (concat (substring str 0 i)
1115                                  calculator-radix-grouping-separator
1116                                  (substring str i)))))))
1117        (upcase
1118         (if (and (not calculator-2s-complement) (< num 0))
1119           (concat "-" str)
1120           str))))
1121     ((and (numberp num) calculator-displayer)
1122      (cond
1123        ((stringp calculator-displayer)
1124         (format calculator-displayer num))
1125        ((symbolp calculator-displayer)
1126         (funcall calculator-displayer num))
1127        ((and (consp calculator-displayer)
1128              (eq 'std (car calculator-displayer)))
1129         (calculator-standard-displayer num (cadr calculator-displayer)))
1130        ((listp calculator-displayer)
1131         (eval calculator-displayer))
1132        (t (prin1-to-string num t))))
1133     ;; operators are printed here
1134     (t (prin1-to-string (nth 1 num) t))))
1135
1136 (defun calculator-update-display (&optional force)
1137   "Update the display.
1138 If optional argument FORCE is non-nil, don't use the cached string."
1139   (set-buffer calculator-buffer)
1140   ;; update calculator-stack-display
1141   (if (or force
1142           (not (eq (car calculator-stack-display) calculator-stack)))
1143     (setq calculator-stack-display
1144           (cons calculator-stack
1145                 (if calculator-stack
1146                   (concat
1147                    (let ((calculator-displayer
1148                           (if (and calculator-displayers
1149                                    (= 1 (length calculator-stack)))
1150                             ;; customizable display for a single value
1151                             (caar calculator-displayers)
1152                             calculator-displayer)))
1153                      (mapconcat 'calculator-number-to-string
1154                                 (reverse calculator-stack)
1155                                 " "))
1156                    " "
1157                    (and calculator-display-fragile
1158                         calculator-saved-list
1159                         (= (car calculator-stack)
1160                            (nth calculator-saved-ptr
1161                                 calculator-saved-list))
1162                         (if (= 0 calculator-saved-ptr)
1163                           (format "[%s]" (length calculator-saved-list))
1164                           (format "[%s/%s]"
1165                                   (- (length calculator-saved-list)
1166                                      calculator-saved-ptr)
1167                                   (length calculator-saved-list)))))
1168                   ""))))
1169   (let ((inhibit-read-only t))
1170     (erase-buffer)
1171     (insert (calculator-get-prompt)))
1172   (set-buffer-modified-p nil)
1173   (if calculator-display-fragile
1174     (goto-char (1+ (length calculator-prompt)))
1175     (goto-char (1- (point)))))
1176
1177 ;;;---------------------------------------------------------------------
1178 ;;; Stack computations
1179
1180 (defun calculator-reduce-stack (prec)
1181   "Reduce the stack using top operator.
1182 PREC is a precedence - reduce everything with higher precedence."
1183   (while
1184       (cond
1185         ((and (cdr (cdr calculator-stack))         ; have three values
1186               (consp   (nth 0 calculator-stack))   ; two operators & num
1187               (numberp (nth 1 calculator-stack))
1188               (consp   (nth 2 calculator-stack))
1189               (eq '\) (nth 1 (nth 0 calculator-stack)))
1190               (eq '\( (nth 1 (nth 2 calculator-stack))))
1191          ;; reduce "... ( x )" --> "... x"
1192          (setq calculator-stack
1193                (cons (nth 1 calculator-stack)
1194                      (nthcdr 3 calculator-stack)))
1195          ;; another iteration
1196          t)
1197         ((and (cdr (cdr calculator-stack))         ; have three values
1198               (numberp (nth 0 calculator-stack))   ; two nums & operator
1199               (consp   (nth 1 calculator-stack))
1200               (numberp (nth 2 calculator-stack))
1201               (= 2 (calculator-op-arity            ; binary operator
1202                     (nth 1 calculator-stack)))
1203               (<= prec                             ; with higher prec.
1204                   (calculator-op-prec (nth 1 calculator-stack))))
1205          ;; reduce "... x op y" --> "... r", r is the result
1206          (setq calculator-stack
1207                (cons (calculator-funcall
1208                       (nth 2 (nth 1 calculator-stack))
1209                       (nth 2 calculator-stack)
1210                       (nth 0 calculator-stack))
1211                      (nthcdr 3 calculator-stack)))
1212          ;; another iteration
1213          t)
1214         ((and (>= (length calculator-stack) 2)     ; have two values
1215               (numberp (nth 0 calculator-stack))   ; number & operator
1216               (consp   (nth 1 calculator-stack))
1217               (= -1 (calculator-op-arity           ; prefix-unary op
1218                      (nth 1 calculator-stack)))
1219               (<= prec                             ; with higher prec.
1220                   (calculator-op-prec (nth 1 calculator-stack))))
1221          ;; reduce "... op x" --> "... r" for prefix op
1222          (setq calculator-stack
1223                (cons (calculator-funcall
1224                       (nth 2 (nth 1 calculator-stack))
1225                       (nth 0 calculator-stack))
1226                      (nthcdr 2 calculator-stack)))
1227          ;; another iteration
1228          t)
1229         ((and (cdr calculator-stack)               ; have two values
1230               (consp   (nth 0 calculator-stack))   ; operator & number
1231               (numberp (nth 1 calculator-stack))
1232               (= +1 (calculator-op-arity           ; postfix-unary op
1233                      (nth 0 calculator-stack)))
1234               (<= prec                             ; with higher prec.
1235                   (calculator-op-prec (nth 0 calculator-stack))))
1236          ;; reduce "... x op" --> "... r" for postfix op
1237          (setq calculator-stack
1238                (cons (calculator-funcall
1239                       (nth 2 (nth 0 calculator-stack))
1240                       (nth 1 calculator-stack))
1241                      (nthcdr 2 calculator-stack)))
1242          ;; another iteration
1243          t)
1244         ((and calculator-stack                     ; have one value
1245               (consp (nth 0 calculator-stack))     ; an operator
1246               (= 0 (calculator-op-arity            ; 0-ary op
1247                     (nth 0 calculator-stack))))
1248          ;; reduce "... op" --> "... r" for 0-ary op
1249          (setq calculator-stack
1250                (cons (calculator-funcall
1251                       (nth 2 (nth 0 calculator-stack)))
1252                      (nthcdr 1 calculator-stack)))
1253          ;; another iteration
1254          t)
1255         ((and (cdr calculator-stack)               ; have two values
1256               (numberp (nth 0 calculator-stack))   ; both numbers
1257               (numberp (nth 1 calculator-stack)))
1258          ;; get rid of redundant numbers:
1259          ;;   reduce "... y x" --> "... x"
1260          ;; needed for 0-ary ops that puts more values
1261          (setcdr calculator-stack (cdr (cdr calculator-stack))))
1262         (t ;; no more iterations
1263            nil))))
1264
1265 (defun calculator-funcall (f &optional X Y)
1266   "If F is a symbol, evaluate (F X Y).
1267 Otherwise, it should be a list, evaluate it with X, Y bound to the
1268 arguments."
1269   ;; remember binary ops for calculator-repR/L
1270   (if Y (setq calculator-last-opXY (list f X Y)))
1271   (condition-case nil
1272       ;; there used to be code here that returns 0 if the result was
1273       ;; smaller than calculator-epsilon (1e-15).  I don't think this is
1274       ;; necessary now.
1275       (if (symbolp f)
1276         (cond ((and X Y) (funcall f X Y))
1277               (X         (funcall f X))
1278               (t         (funcall f)))
1279         ;; f is an expression
1280         (let* ((__f__ f) ; so we can get this value below...
1281                (TX (calculator-truncate X))
1282                (TY (and Y (calculator-truncate Y)))
1283                (DX (if calculator-deg (/ (* X pi) 180) X))
1284                (L  calculator-saved-list)
1285                (Fbound (fboundp 'F))
1286                (Fsave  (and Fbound (symbol-function 'F)))
1287                (Dbound (fboundp 'D))
1288                (Dsave  (and Dbound (symbol-function 'D))))
1289           ;; a shortened version of flet
1290           (fset 'F (function
1291                     (lambda (&optional x y)
1292                       (calculator-funcall __f__ x y))))
1293           (fset 'D (function
1294                     (lambda (x)
1295                       (if calculator-deg (/ (* x 180) float-pi) x))))
1296           (unwind-protect (eval f)
1297             (if Fbound (fset 'F Fsave) (fmakunbound 'F))
1298             (if Dbound (fset 'D Dsave) (fmakunbound 'D)))))
1299     (error 0)))
1300
1301 ;;;---------------------------------------------------------------------
1302 ;;; Input interaction
1303
1304 (defun calculator-last-input (&optional keys)
1305   "Last char (or event or event sequence) that was read.
1306 Optional string argument KEYS will force using it as the keys entered."
1307   (let ((inp (or keys (this-command-keys))))
1308     (if (or (stringp inp) (not (arrayp inp)))
1309       inp
1310       ;; this translates kp-x to x and [tries to] create a string to
1311       ;; lookup operators
1312       (let* ((i -1) (converted-str (make-string (length inp) ? )) k)
1313         ;; converts an array to a string the ops lookup with keypad
1314         ;; input
1315         (while (< (setq i (1+ i)) (length inp))
1316           (setq k (aref inp i))
1317           ;; if Emacs will someday have a event-key, then this would
1318           ;; probably be modified anyway
1319           (and (if (fboundp 'key-press-event-p) (key-press-event-p k))
1320                (if (fboundp 'event-key)
1321                    (and (event-key k) (setq k (event-key k)))))
1322           ;; assume all symbols are translatable with an ascii-character
1323           (and (symbolp k)
1324                (setq k (or (get k 'ascii-character) ? )))
1325           (aset converted-str i k))
1326         converted-str))))
1327
1328 (defun calculator-clear-fragile (&optional op)
1329   "Clear the fragile flag if it was set, then maybe reset all.
1330 OP is the operator (if any) that caused this call."
1331   (if (and calculator-display-fragile
1332            (or (not op)
1333                (= -1 (calculator-op-arity op))
1334                (= 0 (calculator-op-arity op))))
1335     ;; reset if last calc finished, and now get a num or prefix or 0-ary
1336     ;; op
1337     (calculator-reset))
1338   (setq calculator-display-fragile nil))
1339
1340 (defun calculator-digit ()
1341   "Enter a single digit."
1342   (interactive)
1343   (let ((inp (aref (calculator-last-input) 0)))
1344     (if (and (or calculator-display-fragile
1345                  (not (numberp (car calculator-stack))))
1346              (cond
1347                ((not calculator-input-radix)     (<= inp ?9))
1348                ((eq calculator-input-radix 'bin) (<= inp ?1))
1349                ((eq calculator-input-radix 'oct) (<= inp ?7))
1350                (t t)))
1351       ;; enter digit if starting a new computation or have an op on the
1352       ;; stack
1353       (progn
1354         (calculator-clear-fragile)
1355         (let ((digit (upcase (char-to-string inp))))
1356           (if (equal calculator-curnum "0")
1357             (setq calculator-curnum nil))
1358           (setq calculator-curnum
1359                 (concat (or calculator-curnum "") digit)))
1360         (calculator-update-display)))))
1361
1362 (defun calculator-decimal ()
1363   "Enter a decimal period."
1364   (interactive)
1365   (if (and (not calculator-input-radix)
1366            (or calculator-display-fragile
1367                (not (numberp (car calculator-stack))))
1368            (not (and calculator-curnum
1369                      (string-match "[.eE]" calculator-curnum))))
1370     ;; enter the period on the same condition as a digit, only if no
1371     ;; period or exponent entered yet
1372     (progn
1373       (calculator-clear-fragile)
1374       (setq calculator-curnum (concat (or calculator-curnum "0") "."))
1375       (calculator-update-display))))
1376
1377 (defun calculator-exp ()
1378   "Enter an `E' exponent character, or a digit in hex input mode."
1379   (interactive)
1380   (if calculator-input-radix
1381     (calculator-digit)
1382     (if (and (or calculator-display-fragile
1383                  (not (numberp (car calculator-stack))))
1384              (not (and calculator-curnum
1385                        (string-match "[eE]" calculator-curnum))))
1386       ;; same condition as above, also no E so far
1387       (progn
1388         (calculator-clear-fragile)
1389         (setq calculator-curnum (concat (or calculator-curnum "1") "e"))
1390         (calculator-update-display)))))
1391
1392 (defun calculator-op (&optional keys)
1393   "Enter an operator on the stack, doing all necessary reductions.
1394 Optional string argument KEYS will force using it as the keys entered."
1395   (interactive)
1396   (catch 'op-error
1397     (let* ((last-inp (calculator-last-input keys))
1398            (op (assoc last-inp calculator-operators)))
1399       (calculator-clear-fragile op)
1400       (if (and calculator-curnum (/= (calculator-op-arity op) 0))
1401         (setq calculator-stack
1402               (cons (calculator-curnum-value) calculator-stack)))
1403       (setq calculator-curnum nil)
1404       (if (and (= 2 (calculator-op-arity op))
1405                (not (and calculator-stack
1406                          (numberp (nth 0 calculator-stack)))))
1407         ;; we have a binary operator but no number - search for a prefix
1408         ;; version
1409         (let ((rest-ops calculator-operators))
1410           (while (not (equal last-inp (car (car rest-ops))))
1411             (setq rest-ops (cdr rest-ops)))
1412           (setq op (assoc last-inp (cdr rest-ops)))
1413           (if (not (and op (= -1 (calculator-op-arity op))))
1414             ;;(error "Binary operator without a first operand")
1415             (progn
1416               (calculator-message
1417                "Binary operator without a first operand")
1418               (throw 'op-error nil)))))
1419       (calculator-reduce-stack
1420        (cond ((eq (nth 1 op) '\() 10)
1421              ((eq (nth 1 op) '\)) 0)
1422              (t (calculator-op-prec op))))
1423       (if (or (and (= -1 (calculator-op-arity op))
1424                    (numberp (car calculator-stack)))
1425               (and (/= (calculator-op-arity op) -1)
1426                    (/= (calculator-op-arity op) 0)
1427                    (not (numberp (car calculator-stack)))))
1428         ;;(error "Unterminated expression")
1429         (progn
1430           (calculator-message "Unterminated expression")
1431           (throw 'op-error nil)))
1432       (setq calculator-stack (cons op calculator-stack))
1433       (calculator-reduce-stack (calculator-op-prec op))
1434       (and (= (length calculator-stack) 1)
1435            (numberp (nth 0 calculator-stack))
1436            ;; the display is fragile if it contains only one number
1437            (setq calculator-display-fragile t)
1438            ;; add number to the saved-list
1439            calculator-add-saved
1440            (if (= 0 calculator-saved-ptr)
1441              (setq calculator-saved-list
1442                    (cons (car calculator-stack) calculator-saved-list))
1443              (let ((p (nthcdr (1- calculator-saved-ptr)
1444                               calculator-saved-list)))
1445                (setcdr p (cons (car calculator-stack) (cdr p))))))
1446       (calculator-update-display))))
1447
1448 (defun calculator-op-or-exp ()
1449   "Either enter an operator or a digit.
1450 Used with +/- for entering them as digits in numbers like 1e-3 (there is
1451 no need for negative numbers since these are handled by unary operators)."
1452   (interactive)
1453   (if (and (not calculator-display-fragile)
1454            calculator-curnum
1455            (string-match "[eE]$" calculator-curnum))
1456     (calculator-digit)
1457     (calculator-op)))
1458
1459 ;;;---------------------------------------------------------------------
1460 ;;; Input/output modes (not display)
1461
1462 (defun calculator-dec/deg-mode ()
1463   "Set decimal mode for display & input, if decimal, toggle deg mode."
1464   (interactive)
1465   (if calculator-curnum
1466     (setq calculator-stack
1467           (cons (calculator-curnum-value) calculator-stack)))
1468   (setq calculator-curnum nil)
1469   (if (or calculator-input-radix calculator-output-radix)
1470     (progn (setq calculator-input-radix nil)
1471            (setq calculator-output-radix nil))
1472     ;; already decimal - toggle degrees mode
1473     (setq calculator-deg (not calculator-deg)))
1474   (calculator-update-display t))
1475
1476 (defun calculator-radix-mode (&optional keys)
1477   "Set input and display radix modes.
1478 Optional string argument KEYS will force using it as the keys entered."
1479   (interactive)
1480   (calculator-radix-input-mode keys)
1481   (calculator-radix-output-mode keys))
1482
1483 (defun calculator-radix-input-mode (&optional keys)
1484   "Set input radix modes.
1485 Optional string argument KEYS will force using it as the keys entered."
1486   (interactive)
1487   (if calculator-curnum
1488     (setq calculator-stack
1489           (cons (calculator-curnum-value) calculator-stack)))
1490   (setq calculator-curnum nil)
1491   (setq calculator-input-radix
1492         (let ((inp (calculator-last-input keys)))
1493           (cdr (assq (upcase (aref inp (1- (length inp))))
1494                      calculator-char-radix))))
1495   (calculator-update-display))
1496
1497 (defun calculator-radix-output-mode (&optional keys)
1498   "Set display radix modes.
1499 Optional string argument KEYS will force using it as the keys entered."
1500   (interactive)
1501   (if calculator-curnum
1502     (setq calculator-stack
1503           (cons (calculator-curnum-value) calculator-stack)))
1504   (setq calculator-curnum nil)
1505   (setq calculator-output-radix
1506         (let ((inp (calculator-last-input keys)))
1507           (cdr (assq (upcase (aref inp (1- (length inp))))
1508                      calculator-char-radix))))
1509   (calculator-update-display t))
1510
1511 ;;;---------------------------------------------------------------------
1512 ;;; Saved values list
1513
1514 (defun calculator-save-on-list ()
1515   "Evaluate current expression, put result on the saved values list."
1516   (interactive)
1517   (let ((calculator-add-saved t)) ; marks the result to be added
1518     (calculator-enter)))
1519
1520 (defun calculator-clear-saved ()
1521   "Clear the list of saved values in `calculator-saved-list'."
1522   (interactive)
1523   (setq calculator-saved-list nil)
1524   (setq calculator-saved-ptr 0)
1525   (calculator-update-display t))
1526
1527 (defun calculator-saved-move (n)
1528   "Go N elements up the list of saved values."
1529   (interactive)
1530   (and calculator-saved-list
1531        (or (null calculator-stack) calculator-display-fragile)
1532        (progn
1533          (setq calculator-saved-ptr
1534                (max (min (+ n calculator-saved-ptr)
1535                          (length calculator-saved-list))
1536                     0))
1537          (if (nth calculator-saved-ptr calculator-saved-list)
1538            (setq calculator-stack
1539                  (list (nth calculator-saved-ptr calculator-saved-list))
1540                  calculator-display-fragile t)
1541            (calculator-reset))
1542          (calculator-update-display))))
1543
1544 (defun calculator-saved-up ()
1545   "Go up the list of saved values."
1546   (interactive)
1547   (calculator-saved-move +1))
1548
1549 (defun calculator-saved-down ()
1550   "Go down the list of saved values."
1551   (interactive)
1552   (calculator-saved-move -1))
1553
1554 ;;;---------------------------------------------------------------------
1555 ;;; Misc functions
1556
1557 (defun calculator-open-paren ()
1558   "Equivalents of `(' use this."
1559   (interactive)
1560   (calculator-op "("))
1561
1562 (defun calculator-close-paren ()
1563   "Equivalents of `)' use this."
1564   (interactive)
1565   (calculator-op ")"))
1566
1567 (defun calculator-enter ()
1568   "Evaluate current expression."
1569   (interactive)
1570   (calculator-op "="))
1571
1572 (defun calculator-backspace ()
1573   "Backward delete a single digit or a stack element."
1574   (interactive)
1575   (if calculator-curnum
1576     (setq calculator-curnum
1577           (if (> (length calculator-curnum) 1)
1578             (substring calculator-curnum
1579                        0 (1- (length calculator-curnum)))
1580             nil))
1581     (setq calculator-stack (cdr calculator-stack)))
1582   (calculator-update-display))
1583
1584 (defun calculator-clear ()
1585   "Clear current number."
1586   (interactive)
1587   (setq calculator-curnum nil)
1588   (cond
1589     ;; if the current number is from the saved-list - remove it
1590     ((and calculator-display-fragile
1591           calculator-saved-list
1592           (= (car calculator-stack)
1593              (nth calculator-saved-ptr calculator-saved-list)))
1594      (if (= 0 calculator-saved-ptr)
1595        (setq calculator-saved-list (cdr calculator-saved-list))
1596        (let ((p (nthcdr (1- calculator-saved-ptr)
1597                         calculator-saved-list)))
1598          (setcdr p (cdr (cdr p)))
1599          (setq calculator-saved-ptr (1- calculator-saved-ptr))))
1600      (if calculator-saved-list
1601        (setq calculator-stack
1602              (list (nth calculator-saved-ptr calculator-saved-list)))
1603        (calculator-reset)))
1604     ;; reset if fragile or double clear
1605     ((or calculator-display-fragile (eq last-command this-command))
1606      (calculator-reset)))
1607   (calculator-update-display))
1608
1609 (defun calculator-copy ()
1610   "Copy current number to the `kill-ring'."
1611   (interactive)
1612   (let ((calculator-displayer
1613          (or calculator-copy-displayer calculator-displayer))
1614         (calculator-displayers
1615          (if calculator-copy-displayer nil calculator-displayers)))
1616     (calculator-enter)
1617     ;; remove trailing spaces and an index
1618     (let ((s (cdr calculator-stack-display)))
1619       (and s
1620            (if (string-match "^\\([^ ]+\\) *\\(\\[[0-9/]+\\]\\)? *$" s)
1621              (setq s (match-string 1 s)))
1622            (kill-new s)))))
1623
1624 (defun calculator-set-register (reg)
1625   "Set a register value for REG."
1626   (interactive "cRegister to store into: ")
1627   (let* ((as  (assq reg calculator-registers))
1628          (val (progn (calculator-enter) (car calculator-stack))))
1629     (if as
1630       (setcdr as val)
1631       (setq calculator-registers
1632             (cons (cons reg val) calculator-registers)))
1633     (calculator-message "[%c] := %S" reg val)))
1634
1635 (defun calculator-put-value (val)
1636   "Paste VAL as if entered.
1637 Used by `calculator-paste' and `get-register'."
1638   (if (and (numberp val)
1639            ;; (not calculator-curnum)
1640            (or calculator-display-fragile
1641                (not (numberp (car calculator-stack)))))
1642     (progn
1643       (calculator-clear-fragile)
1644       (setq calculator-curnum (let ((calculator-displayer "%S"))
1645                                 (calculator-number-to-string val)))
1646       (calculator-update-display))))
1647
1648 (defun calculator-paste ()
1649   "Paste a value from the `kill-ring'."
1650   (interactive)
1651   (calculator-put-value
1652    (let ((str (replace-regexp-in-string
1653                "^ *\\(.+[^ ]\\) *$" "\\1" (current-kill 0))))
1654      (and (not calculator-input-radix)
1655           calculator-paste-decimals
1656           (string-match "\\([0-9]+\\)\\(\\.[0-9]+\\)?\\(e[0-9]+\\)?"
1657                         str)
1658           (or (match-string 1 str)
1659               (match-string 2 str)
1660               (match-string 3 str))
1661           (setq str (concat (or (match-string 1 str) "0")
1662                             (or (match-string 2 str) ".0")
1663                             (or (match-string 3 str) ""))))
1664      (condition-case nil (calculator-string-to-number str)
1665        (error nil)))))
1666
1667 (defun calculator-get-register (reg)
1668   "Get a value from a register REG."
1669   (interactive "cRegister to get value from: ")
1670   (calculator-put-value (cdr (assq reg calculator-registers))))
1671
1672 (declare-function electric-describe-mode "ehelp" ())
1673
1674 (defun calculator-help ()
1675   ;; this is used as the quick reference screen you get with `h'
1676   "Quick reference:
1677 * numbers/operators/parens/./e - enter expressions
1678   + - * / \\(div) %(rem) _(-X,postfix) ;(1/X,postfix) ^(exp) L(og)
1679   Q(sqrt) !(fact) S(in) C(os) T(an) |(or) #(xor) &(and) ~(not)
1680 * >/< repeats last binary operation with its 2nd (1st) arg as postfix op
1681 * I inverses next trig function        * '/\"/{} - display/display args
1682 * D         - switch to all-decimal, or toggle deg/rad mode
1683 * B/O/H/X   - binary/octal/hex mode for i/o (X is a shortcut for H)
1684 * i/o       - prefix for d/b/o/x - set only input/output modes
1685 * enter/=   - evaluate current expr.   * s/g      - set/get a register
1686 * space     - evaluate & save on list  * l/v      - list total/average
1687 * up/down/C-p/C-n - browse saved       * C-delete - clear all saved
1688 * C-insert  - copy whole expr.         * C-return - evaluate, copy, exit
1689 * insert    - paste a number           * backspace- delete backwards
1690 * delete    - clear argument or list value or whole expression (twice)
1691 * escape/q  - exit."
1692   (interactive)
1693   (if (eq last-command 'calculator-help)
1694     (let ((mode-name "Calculator")
1695           (major-mode 'calculator-mode)
1696           (g-map (current-global-map))
1697           (win (selected-window)))
1698       (require 'ehelp)
1699       (if calculator-electric-mode
1700         (use-global-map calculator-saved-global-map))
1701       (if (or (not calculator-electric-mode)
1702               ;; XEmacs has a problem with electric-describe-mode
1703               (featurep 'xemacs))
1704           (describe-mode)
1705         (electric-describe-mode))
1706       (if calculator-electric-mode
1707         (use-global-map g-map))
1708       (select-window win) ; these are for XEmacs (also below)
1709       (message nil))
1710     (let ((one (one-window-p t))
1711           (win (selected-window))
1712           (help-buf (get-buffer-create "*Help*")))
1713       (save-window-excursion
1714         (with-output-to-temp-buffer "*Help*"
1715           (princ (documentation 'calculator-help)))
1716         (if one
1717           (shrink-window-if-larger-than-buffer
1718            (get-buffer-window help-buf)))
1719         (message
1720          "`%s' again for more help, any other key continues normally."
1721          (calculator-last-input))
1722         (select-window win)
1723         (sit-for 360))
1724       (select-window win))))
1725
1726 (defun calculator-quit ()
1727   "Quit calculator."
1728   (interactive)
1729   (set-buffer calculator-buffer)
1730   (let ((inhibit-read-only t)) (erase-buffer))
1731   (if (not calculator-electric-mode)
1732     (progn
1733       (condition-case nil
1734           (while (get-buffer-window calculator-buffer)
1735             (delete-window (get-buffer-window calculator-buffer)))
1736         (error nil))
1737       (kill-buffer calculator-buffer)))
1738   (setq calculator-buffer nil)
1739   (message "Calculator done.")
1740   (if calculator-electric-mode (throw 'calculator-done nil)))
1741
1742 (defun calculator-save-and-quit ()
1743   "Quit the calculator, saving the result on the `kill-ring'."
1744   (interactive)
1745   (calculator-enter)
1746   (calculator-copy)
1747   (calculator-quit))
1748
1749 (defun calculator-repR (x)
1750   "Repeat the last binary operation with its second argument and X.
1751 To use this, apply a binary operator (evaluate it), then call this."
1752   (if calculator-last-opXY
1753     ;; avoid rebinding calculator-last-opXY
1754     (let ((calculator-last-opXY calculator-last-opXY))
1755       (calculator-funcall
1756        (car calculator-last-opXY) x (nth 2 calculator-last-opXY)))
1757     x))
1758
1759 (defun calculator-repL (x)
1760   "Repeat the last binary operation with its first argument and X.
1761 To use this, apply a binary operator (evaluate it), then call this."
1762   (if calculator-last-opXY
1763     ;; avoid rebinding calculator-last-opXY
1764     (let ((calculator-last-opXY calculator-last-opXY))
1765       (calculator-funcall
1766        (car calculator-last-opXY) (nth 1 calculator-last-opXY) x))
1767     x))
1768
1769 (defun calculator-integer-p (x)
1770   "Non-nil if X is equal to an integer."
1771   (condition-case nil
1772       (= x (ftruncate x))
1773     (error nil)))
1774
1775 (defun calculator-expt (x y)
1776   "Compute X^Y, dealing with errors appropriately."
1777   (condition-case
1778       nil
1779       (expt x y)
1780     (domain-error 0.0e+NaN)
1781     (range-error
1782      (cond
1783       ((and (< x 1.0) (> x -1.0))
1784        ;; For small x, the range error comes from large y.
1785        0.0)
1786       ((and (> x 0.0) (< y 0.0))
1787        ;; For large positive x and negative y, the range error
1788        ;; comes from large negative y.
1789        0.0)
1790       ((and (> x 0.0) (> y 0.0))
1791        ;; For large positive x and positive y, the range error
1792        ;; comes from large y.
1793        1.0e+INF)
1794       ;; For the rest, x must be large and negative.
1795       ;; The range errors come from large integer y.
1796       ((< y 0.0)
1797        0.0)
1798       ((eq (logand (truncate y) 1) 1)   ; expansion of cl `oddp'
1799        ;; If y is odd
1800        -1.0e+INF)
1801       (t
1802        ;;
1803        1.0e+INF)))
1804     (error 0.0e+NaN)))
1805
1806 (defun calculator-fact (x)
1807   "Simple factorial of X."
1808   (if (and (>= x 0)
1809            (calculator-integer-p x))
1810       (if (= (calculator-expt (/ x 3.0) x) 1.0e+INF)
1811           1.0e+INF
1812         (let ((r (if (<= x 10) 1 1.0)))
1813           (while (> x 0)
1814             (setq r (* r (truncate x)))
1815             (setq x (1- x)))
1816           (+ 0.0 r)))
1817     (if (= x 1.0e+INF)
1818         x
1819       0.0e+NaN)))
1820
1821 (defun calculator-truncate (n)
1822   "Truncate N, return 0 in case of overflow."
1823   (condition-case nil (truncate n) (error 0)))
1824
1825
1826 (provide 'calculator)
1827
1828 ;;; calculator.el ends here