lisp/org/org-mhe.el

   1 ;;; org-mhe.el --- Support for links to MH-E messages from within Org-mode
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   4
   5 ;; Author: Thomas Baumann <thomas dot baumann at ch dot tum dot de>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 6.02b
   9 ;;
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  27 ;;
  28 ;;; Commentary:
  29
  30 ;; This file implements links to MH-E messages from within Org-mode.
  31 ;; Org-mode loads this module by default - if this is not what you want,
  32 ;; configure the variable `org-modules'.
  33
  34 ;;; Code:
  35
  36 (require 'org)
  37
  38 ;; Customization variables
  39
  40 (defcustom org-mhe-search-all-folders nil
  41   "Non-nil means the search for the mh-message may extend to all folders.
  42 When non-nil, the search for a message will extend to all other
  43 folders if it cannot be found in the folder given in the link.
  44 Searching all folders may be slow with the default pick based
  45 search but is very efficient with one of the other search engines
  46 supported by MH-E."
  47   :group 'org-link-follow
  48   :type 'boolean)
  49
  50 ;; Declare external functions and variables
  51 (declare-function mh-display-msg "mh-show" (msg-num folder-name))
  52 (declare-function mh-find-path "mh-utils" ())
  53 (declare-function mh-get-header-field "mh-utils" (field))
  54 (declare-function mh-get-msg-num "mh-utils" (error-if-no-message))
  55 (declare-function mh-header-display "mh-show" ())
  56 (declare-function mh-index-previous-folder "mh-search" ())
  57 (declare-function mh-normalize-folder-name "mh-utils"
  58                   (folder &optional empty-string-okay dont-remove-trailing-slash
  59                           return-nil-if-folder-empty))
  60 (declare-function mh-search "mh-search"
  61                   (folder search-regexp &optional redo-search-flag
  62                           window-config))
  63 (declare-function mh-search-choose "mh-search" (&optional searcher))
  64 (declare-function mh-show "mh-show" (&optional message redisplay-flag))
  65 (declare-function mh-show-buffer-message-number "mh-comp" (&optional buffer))
  66 (declare-function mh-show-header-display "mh-show" t t)
  67 (declare-function mh-show-msg "mh-show" (msg))
  68 (declare-function mh-show-show "mh-show" t t)
  69 (declare-function mh-visit-folder "mh-folder" (folder &optional
  70                                                       range index-data))
  71 (defvar mh-progs)
  72 (defvar mh-current-folder)
  73 (defvar mh-show-folder-buffer)
  74 (defvar mh-index-folder)
  75 (defvar mh-searcher)
  76
  77 ;; Install the link type
  78 (org-add-link-type "mhe" 'org-mhe-open)
  79 (add-hook 'org-store-link-functions 'org-mhe-store-link)
  80
  81 ;; Implementation
  82 (defun org-mhe-store-link ()
  83   "Store a link to an MH-E folder or message."
  84   (when (or (equal major-mode 'mh-folder-mode)
  85             (equal major-mode 'mh-show-mode))
  86     (let ((from (org-mhe-get-header "From:"))
  87           (to (org-mhe-get-header "To:"))
  88           (message-id (org-mhe-get-header "Message-Id:"))
  89           (subject (org-mhe-get-header "Subject:"))
  90           link desc)
  91       (org-store-link-props :type "mh" :from from :to to
  92                             :subject subject :message-id message-id)
  93       (setq desc (org-email-link-description))
  94       (setq link (org-make-link "mhe:" (org-mhe-get-message-real-folder) "#"
  95                                 (org-remove-angle-brackets message-id)))
  96       (org-add-link-props :link link :description desc)
  97       link)))
  98
  99 (defun org-mhe-open (path)
 100   "Follow an MH-E message link specified by PATH."
 101   (let (folder article)
 102     (if (not (string-match "\\`\\([^#]+\\)\\(#\\(.*\\)\\)?" path))
 103         (error "Error in MH-E link"))
 104     (setq folder (match-string 1 path)
 105           article (match-string 3 path))
 106     (org-mhe-follow-link folder article)))
 107
 108 ;;; mh-e integration based on planner-mode
 109 (defun org-mhe-get-message-real-folder ()
 110   "Return the name of the real folder for the current message.
 111 So if you use sequences, it will now work."
 112   (save-excursion
 113     (let* ((folder
 114             (if (equal major-mode 'mh-folder-mode)
 115                 mh-current-folder
 116               ;; Refer to the show buffer
 117               mh-show-folder-buffer))
 118            (end-index
 119             (if (boundp 'mh-index-folder)
 120                 (min (length mh-index-folder) (length folder))))
 121            )
 122       ;; a simple test on mh-index-data does not work, because
 123       ;; mh-index-data is always nil in a show buffer.
 124       (if (and (boundp 'mh-index-folder)
 125                (string= mh-index-folder (substring folder 0 end-index)))
 126           (if (equal major-mode 'mh-show-mode)
 127               (save-window-excursion
 128                 (let (pop-up-frames)
 129                   (when (buffer-live-p (get-buffer folder))
 130                     (progn
 131                       (pop-to-buffer folder)
 132                       (org-mhe-get-message-folder-from-index)
 133                       )
 134                     )))
 135             (org-mhe-get-message-folder-from-index)
 136             )
 137         folder
 138         )
 139       )))
 140
 141 (defun org-mhe-get-message-folder-from-index ()
 142   "Return the name of the message folder in a index folder buffer."
 143   (save-excursion
 144     (mh-index-previous-folder)
 145     (re-search-forward "^\\(+.*\\)$" nil t)
 146     (message "%s" (match-string 1))))
 147
 148 (defun org-mhe-get-message-folder ()
 149   "Return the name of the current message folder.
 150 Be careful if you use sequences."
 151   (save-excursion
 152     (if (equal major-mode 'mh-folder-mode)
 153         mh-current-folder
 154       ;; Refer to the show buffer
 155       mh-show-folder-buffer)))
 156
 157 (defun org-mhe-get-message-num ()
 158   "Return the number of the current message.
 159 Be careful if you use sequences."
 160   (save-excursion
 161     (if (equal major-mode 'mh-folder-mode)
 162         (mh-get-msg-num nil)
 163       ;; Refer to the show buffer
 164       (mh-show-buffer-message-number))))
 165
 166 (defun org-mhe-get-header (header)
 167   "Return the field for HEADER of the message in folder mode.
 168 This will create a show buffer for the corresponding message.  If
 169 you have a better idea of how to do this then please let us know."
 170   (let* ((folder (org-mhe-get-message-folder))
 171          (num (org-mhe-get-message-num))
 172          (buffer (get-buffer-create (concat "show-" folder)))
 173          (header-field))
 174   (with-current-buffer buffer
 175     (mh-display-msg num folder)
 176     (if (equal major-mode 'mh-folder-mode)
 177         (mh-header-display)
 178       (mh-show-header-display))
 179     (set-buffer buffer)
 180     (setq header-field (mh-get-header-field header))
 181     (if (equal major-mode 'mh-folder-mode)
 182         (mh-show)
 183       (mh-show-show))
 184     header-field)))
 185
 186 (defun org-mhe-follow-link (folder article)
 187   "Follow an MH-E link to FOLDER and ARTICLE.
 188 If ARTICLE is nil FOLDER is shown.  If the configuration variable
 189 `org-mhe-search-all-folders' is t and `mh-searcher' is pick,
 190 ARTICLE is searched in all folders.  Indexed searches (swish++,
 191 namazu, and others supported by MH-E) will always search in all
 192 folders."
 193   (require 'mh-e)
 194   (require 'mh-search)
 195   (require 'mh-utils)
 196   (mh-find-path)
 197   (if (not article)
 198       (mh-visit-folder (mh-normalize-folder-name folder))
 199     (setq article (org-add-angle-brackets article))
 200     (mh-search-choose)
 201     (if (equal mh-searcher 'pick)
 202         (progn
 203           (mh-search folder (list "--message-id" article))
 204           (when (and org-mhe-search-all-folders
 205                      (not (org-mhe-get-message-real-folder)))
 206             (kill-this-buffer)
 207             (mh-search "+" (list "--message-id" article))))
 208       (mh-search "+" article))
 209     (if (org-mhe-get-message-real-folder)
 210         (mh-show-msg 1)
 211       (kill-this-buffer)
 212       (error "Message not found"))))
 213
 214 (provide 'org-mhe)
 215
 216 ;;; org-mhe.el ends here