lisp/help-fns.el

   1 ;;; help-fns.el --- Complex help functions
   2
   3 ;; Copyright (C) 1985, 1986, 1993, 1994, 1998, 1999, 2000, 2001, 2002,
   4 ;;   2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
   5 ;;   Free Software Foundation, Inc.
   6
   7 ;; Maintainer: FSF
   8 ;; Keywords: help, internal
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This file contains those help commands which are complicated, and
  28 ;; which may not be used in every session.  For example
  29 ;; `describe-function' will probably be heavily used when doing elisp
  30 ;; programming, but not if just editing C files.  Simpler help commands
  31 ;; are in help.el
  32
  33 ;;; Code:
  34
  35 ;; Functions
  36
  37 ;;;###autoload
  38 (defun describe-function (function)
  39   "Display the full documentation of FUNCTION (a symbol)."
  40   (interactive
  41    (let ((fn (function-called-at-point))
  42          (enable-recursive-minibuffers t)
  43          val)
  44      (setq val (completing-read (if fn
  45                                     (format "Describe function (default %s): " fn)
  46                                   "Describe function: ")
  47                                 obarray 'fboundp t nil nil
  48                                 (and fn (symbol-name fn))))
  49      (list (if (equal val "")
  50                fn (intern val)))))
  51   (if (null function)
  52       (message "You didn't specify a function")
  53     (help-setup-xref (list #'describe-function function)
  54                      (called-interactively-p 'interactive))
  55     (save-excursion
  56       (with-help-window (help-buffer)
  57         (prin1 function)
  58         ;; Use " is " instead of a colon so that
  59         ;; it is easier to get out the function name using forward-sexp.
  60         (princ " is ")
  61         (describe-function-1 function)
  62         (with-current-buffer standard-output
  63           ;; Return the text we displayed.
  64           (buffer-string))))))
  65
  66 (defun help-split-fundoc (docstring def)
  67   "Split a function DOCSTRING into the actual doc and the usage info.
  68 Return (USAGE . DOC) or nil if there's no usage info.
  69 DEF is the function whose usage we're looking for in DOCSTRING."
  70   ;; Functions can get the calling sequence at the end of the doc string.
  71   ;; In cases where `function' has been fset to a subr we can't search for
  72   ;; function's name in the doc string so we use `fn' as the anonymous
  73   ;; function name instead.
  74   (when (and docstring (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring))
  75     (cons (format "(%s%s"
  76                   ;; Replace `fn' with the actual function name.
  77                   (if (consp def) "anonymous" def)
  78                   (match-string 1 docstring))
  79           (substring docstring 0 (match-beginning 0)))))
  80
  81 (defun help-add-fundoc-usage (docstring arglist)
  82   "Add the usage info to DOCSTRING.
  83 If DOCSTRING already has a usage info, then just return it unchanged.
  84 The usage info is built from ARGLIST.  DOCSTRING can be nil.
  85 ARGLIST can also be t or a string of the form \"(FUN ARG1 ARG2 ...)\"."
  86   (unless (stringp docstring) (setq docstring "Not documented"))
  87   (if (or (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring) (eq arglist t))
  88       docstring
  89     (concat docstring
  90             (if (string-match "\n?\n\\'" docstring)
  91                 (if (< (- (match-end 0) (match-beginning 0)) 2) "\n" "")
  92               "\n\n")
  93             (if (and (stringp arglist)
  94                      (string-match "\\`([^ ]+\\(.*\\))\\'" arglist))
  95                 (concat "(fn" (match-string 1 arglist) ")")
  96               (format "%S" (help-make-usage 'fn arglist))))))
  97
  98 (defun help-function-arglist (def)
  99   ;; Handle symbols aliased to other symbols.
 100   (if (and (symbolp def) (fboundp def)) (setq def (indirect-function def)))
 101   ;; If definition is a macro, find the function inside it.
 102   (if (eq (car-safe def) 'macro) (setq def (cdr def)))
 103   (cond
 104    ((byte-code-function-p def) (aref def 0))
 105    ((eq (car-safe def) 'lambda) (nth 1 def))
 106    ((and (eq (car-safe def) 'autoload) (not (eq (nth 4 def) 'keymap)))
 107     "[Arg list not available until function definition is loaded.]")
 108    (t t)))
 109
 110 (defun help-make-usage (function arglist)
 111   (cons (if (symbolp function) function 'anonymous)
 112         (mapcar (lambda (arg)
 113                   (if (not (symbolp arg))
 114                       (if (and (consp arg) (symbolp (car arg)))
 115                           ;; CL style default values for optional args.
 116                           (cons (intern (upcase (symbol-name (car arg))))
 117                                 (cdr arg))
 118                         arg)
 119                     (let ((name (symbol-name arg)))
 120                       (if (string-match "\\`&" name) arg
 121                         (intern (upcase name))))))
 122                 arglist)))
 123
 124 ;; Could be this, if we make symbol-file do the work below.
 125 ;; (defun help-C-file-name (subr-or-var kind)
 126 ;;   "Return the name of the C file where SUBR-OR-VAR is defined.
 127 ;; KIND should be `var' for a variable or `subr' for a subroutine."
 128 ;;   (symbol-file (if (symbolp subr-or-var) subr-or-var
 129 ;;               (subr-name subr-or-var))
 130 ;;             (if (eq kind 'var) 'defvar 'defun)))
 131 ;;;###autoload
 132 (defun help-C-file-name (subr-or-var kind)
 133   "Return the name of the C file where SUBR-OR-VAR is defined.
 134 KIND should be `var' for a variable or `subr' for a subroutine."
 135   (let ((docbuf (get-buffer-create " *DOC*"))
 136         (name (if (eq 'var kind)
 137                   (concat "V" (symbol-name subr-or-var))
 138                 (concat "F" (subr-name subr-or-var)))))
 139     (with-current-buffer docbuf
 140       (goto-char (point-min))
 141       (if (eobp)
 142           (insert-file-contents-literally
 143            (expand-file-name internal-doc-file-name doc-directory)))
 144       (let ((file (catch 'loop
 145                     (while t
 146                       (let ((pnt (search-forward (concat "\x1f" name "\n"))))
 147                         (re-search-backward "\x1fS\\(.*\\)")
 148                         (let ((file (match-string 1)))
 149                           (if (member file build-files)
 150                               (throw 'loop file)
 151                             (goto-char pnt))))))))
 152         (if (string-match "^ns.*\\(\\.o\\|obj\\)\\'" file)
 153             (setq file (replace-match ".m" t t file 1))
 154           (if (string-match "\\.\\(o\\|obj\\)\\'" file)
 155               (setq file (replace-match ".c" t t file))))
 156         (if (string-match "\\.\\(c\\|m\\)\\'" file)
 157             (concat "src/" file)
 158           file)))))
 159
 160 (defcustom help-downcase-arguments nil
 161   "If non-nil, argument names in *Help* buffers are downcased."
 162   :type 'boolean
 163   :group 'help
 164   :version "23.2")
 165
 166 (defun help-highlight-arg (arg)
 167   "Highlight ARG as an argument name for a *Help* buffer.
 168 Return ARG in face `help-argument-name'; ARG is also downcased
 169 if the variable `help-downcase-arguments' is non-nil."
 170   (propertize (if help-downcase-arguments (downcase arg) arg)
 171               'face 'help-argument-name))
 172
 173 (defun help-do-arg-highlight (doc args)
 174   (with-syntax-table (make-syntax-table emacs-lisp-mode-syntax-table)
 175     (modify-syntax-entry ?\- "w")
 176     (dolist (arg args doc)
 177       (setq doc (replace-regexp-in-string
 178                  ;; This is heuristic, but covers all common cases
 179                  ;; except ARG1-ARG2
 180                  (concat "\\<"                   ; beginning of word
 181                          "\\(?:[a-z-]*-\\)?"     ; for xxx-ARG
 182                          "\\("
 183                          (regexp-quote arg)
 184                          "\\)"
 185                          "\\(?:es\\|s\\|th\\)?"  ; for ARGth, ARGs
 186                          "\\(?:-[a-z0-9-]+\\)?"  ; for ARG-xxx, ARG-n
 187                          "\\(?:-[{([<`\"].*?\\)?"; for ARG-{x}, (x), <x>, [x], `x'
 188                          "\\>")                  ; end of word
 189                  (help-highlight-arg arg)
 190                  doc t t 1)))))
 191
 192 (defun help-highlight-arguments (usage doc &rest args)
 193   (when usage
 194     (with-temp-buffer
 195       (insert usage)
 196       (goto-char (point-min))
 197       (let ((case-fold-search nil)
 198             (next (not (or args (looking-at "\\["))))
 199             (opt nil))
 200         ;; Make a list of all arguments
 201         (skip-chars-forward "^ ")
 202         (while next
 203           (or opt (not (looking-at " &")) (setq opt t))
 204           (if (not (re-search-forward " \\([\\[(]*\\)\\([^] &)\.]+\\)" nil t))
 205               (setq next nil)
 206             (setq args (cons (match-string 2) args))
 207             (when (and opt (string= (match-string 1) "("))
 208               ;; A pesky CL-style optional argument with default value,
 209               ;; so let's skip over it
 210               (search-backward "(")
 211               (goto-char (scan-sexps (point) 1)))))
 212         ;; Highlight aguments in the USAGE string
 213         (setq usage (help-do-arg-highlight (buffer-string) args))
 214         ;; Highlight arguments in the DOC string
 215         (setq doc (and doc (help-do-arg-highlight doc args))))))
 216   ;; Return value is like the one from help-split-fundoc, but highlighted
 217   (cons usage doc))
 218
 219 ;; The following function was compiled from the former functions
 220 ;; `describe-simplify-lib-file-name' and `find-source-lisp-file' with
 221 ;; some excerpts from `describe-function-1' and `describe-variable'.
 222 ;; The only additional twists provided are (1) locate the defining file
 223 ;; for autoloaded functions, and (2) give preference to files in the
 224 ;; "install directory" (directories found via `load-path') rather than
 225 ;; to files in the "compile directory" (directories found by searching
 226 ;; the loaddefs.el file).  We autoload it because it's also used by
 227 ;; `describe-face' (instead of `describe-simplify-lib-file-name').
 228
 229 ;;;###autoload
 230 (defun find-lisp-object-file-name (object type)
 231   "Guess the file that defined the Lisp object OBJECT, of type TYPE.
 232 OBJECT should be a symbol associated with a function, variable, or face;
 233   alternatively, it can be a function definition.
 234 If TYPE is `defvar', search for a variable definition.
 235 If TYPE is `defface', search for a face definition.
 236 If TYPE is the value returned by `symbol-function' for a function symbol,
 237  search for a function definition.
 238
 239 The return value is the absolute name of a readable file where OBJECT is
 240 defined.  If several such files exist, preference is given to a file
 241 found via `load-path'.  The return value can also be `C-source', which
 242 means that OBJECT is a function or variable defined in C.  If no
 243 suitable file is found, return nil."
 244   (let* ((autoloaded (eq (car-safe type) 'autoload))
 245          (file-name (or (and autoloaded (nth 1 type))
 246                         (symbol-file
 247                          object (if (memq type (list 'defvar 'defface))
 248                                     type
 249                                   'defun)))))
 250     (cond
 251      (autoloaded
 252       ;; An autoloaded function: Locate the file since `symbol-function'
 253       ;; has only returned a bare string here.
 254       (setq file-name
 255             (locate-file file-name load-path '(".el" ".elc") 'readable)))
 256      ((and (stringp file-name)
 257            (string-match "[.]*loaddefs.el\\'" file-name))
 258       ;; An autoloaded variable or face.  Visit loaddefs.el in a buffer
 259       ;; and try to extract the defining file.  The following form is
 260       ;; from `describe-function-1' and `describe-variable'.
 261       (let ((location
 262              (condition-case nil
 263                  (find-function-search-for-symbol object nil file-name)
 264                (error nil))))
 265         (when (cdr location)
 266           (with-current-buffer (car location)
 267             (goto-char (cdr location))
 268             (when (re-search-backward
 269                    "^;;; Generated autoloads from \\(.*\\)" nil t)
 270               (setq file-name
 271                     (locate-file
 272                      (file-name-sans-extension
 273                       (match-string-no-properties 1))
 274                      load-path '(".el" ".elc") 'readable))))))))
 275
 276     (cond
 277      ((and (not file-name) (subrp type))
 278       ;; A built-in function.  The form is from `describe-function-1'.
 279       (if (get-buffer " *DOC*")
 280           (help-C-file-name type 'subr)
 281         'C-source))
 282      ((and (not file-name) (symbolp object)
 283            (integerp (get object 'variable-documentation)))
 284       ;; A variable defined in C.  The form is from `describe-variable'.
 285       (if (get-buffer " *DOC*")
 286           (help-C-file-name object 'var)
 287         'C-source))
 288      ((not (stringp file-name))
 289       ;; If we don't have a file-name string by now, we lost.
 290       nil)
 291      ((let ((lib-name
 292              (if (string-match "[.]elc\\'" file-name)
 293                  (substring-no-properties file-name 0 -1)
 294                file-name)))
 295         ;; When the Elisp source file can be found in the install
 296         ;; directory return the name of that file - `file-name' should
 297         ;; have become an absolute file name ny now.
 298         (or (and (file-readable-p lib-name) lib-name)
 299             ;; The library might be compressed.
 300             (and (file-readable-p (concat lib-name ".gz")) lib-name))))
 301      ((let* ((lib-name (file-name-nondirectory file-name))
 302              ;; The next form is from `describe-simplify-lib-file-name'.
 303              (file-name
 304               ;; Try converting the absolute file name to a library
 305               ;; name, convert that back to a file name and see if we
 306               ;; get the original one.  If so, they are equivalent.
 307               (if (equal file-name (locate-file lib-name load-path '("")))
 308                   (if (string-match "[.]elc\\'" lib-name)
 309                       (substring-no-properties lib-name 0 -1)
 310                     lib-name)
 311                 file-name))
 312              ;; The next three forms are from `find-source-lisp-file'.
 313              (elc-file (locate-file
 314                         (concat file-name
 315                                 (if (string-match "\\.el\\'" file-name)
 316                                     "c"
 317                                   ".elc"))
 318                         load-path nil 'readable))
 319              (str (when elc-file
 320                     (with-temp-buffer
 321                       (insert-file-contents-literally elc-file nil 0 256)
 322                       (buffer-string))))
 323              (src-file (and str
 324                             (string-match ";;; from file \\(.*\\.el\\)" str)
 325                             (match-string 1 str))))
 326         (and src-file (file-readable-p src-file) src-file))))))
 327
 328 (declare-function ad-get-advice-info "advice" (function))
 329
 330 ;;;###autoload
 331 (defun describe-function-1 (function)
 332   (let* ((advised (and (symbolp function) (featurep 'advice)
 333                        (ad-get-advice-info function)))
 334          ;; If the function is advised, use the symbol that has the
 335          ;; real definition, if that symbol is already set up.
 336          (real-function
 337           (or (and advised
 338                    (let ((origname (cdr (assq 'origname advised))))
 339                      (and (fboundp origname) origname)))
 340               function))
 341          ;; Get the real definition.
 342          (def (if (symbolp real-function)
 343                   (symbol-function real-function)
 344                 function))
 345          file-name string
 346          (beg (if (commandp def) "an interactive " "a "))
 347          (pt1 (with-current-buffer (help-buffer) (point)))
 348          errtype)
 349     (setq string
 350           (cond ((or (stringp def)
 351                      (vectorp def))
 352                  "a keyboard macro")
 353                 ((subrp def)
 354                  (if (eq 'unevalled (cdr (subr-arity def)))
 355                      (concat beg "special form")
 356                    (concat beg "built-in function")))
 357                 ((byte-code-function-p def)
 358                  (concat beg "compiled Lisp function"))
 359                 ((symbolp def)
 360                  (while (and (fboundp def)
 361                              (symbolp (symbol-function def)))
 362                    (setq def (symbol-function def)))
 363                  ;; Handle (defalias 'foo 'bar), where bar is undefined.
 364                  (or (fboundp def) (setq errtype 'alias))
 365                  (format "an alias for `%s'" def))
 366                 ((eq (car-safe def) 'lambda)
 367                  (concat beg "Lisp function"))
 368                 ((eq (car-safe def) 'macro)
 369                  "a Lisp macro")
 370                 ((eq (car-safe def) 'autoload)
 371                  (format "%s autoloaded %s"
 372                          (if (commandp def) "an interactive" "an")
 373                          (if (eq (nth 4 def) 'keymap) "keymap"
 374                            (if (nth 4 def) "Lisp macro" "Lisp function"))))
 375                 ((keymapp def)
 376                  (let ((is-full nil)
 377                        (elts (cdr-safe def)))
 378                    (while elts
 379                      (if (char-table-p (car-safe elts))
 380                          (setq is-full t
 381                                elts nil))
 382                      (setq elts (cdr-safe elts)))
 383                    (if is-full
 384                        "a full keymap"
 385                      "a sparse keymap")))
 386                 (t "")))
 387     (princ string)
 388     (if (eq errtype 'alias)
 389         (princ ",\nwhich is not defined.  Please make a bug report.")
 390       (with-current-buffer standard-output
 391         (save-excursion
 392           (save-match-data
 393             (when (re-search-backward "alias for `\\([^`']+\\)'" nil t)
 394               (help-xref-button 1 'help-function def)))))
 395
 396       (setq file-name (find-lisp-object-file-name function def))
 397       (when file-name
 398         (princ " in `")
 399         ;; We used to add .el to the file name,
 400         ;; but that's completely wrong when the user used load-file.
 401         (princ (if (eq file-name 'C-source)
 402                    "C source code"
 403                  (file-name-nondirectory file-name)))
 404         (princ "'")
 405         ;; Make a hyperlink to the library.
 406         (with-current-buffer standard-output
 407           (save-excursion
 408             (re-search-backward "`\\([^`']+\\)'" nil t)
 409             (help-xref-button 1 'help-function-def function file-name))))
 410       (princ ".")
 411       (with-current-buffer (help-buffer)
 412         (fill-region-as-paragraph (save-excursion (goto-char pt1) (forward-line 0) (point))
 413                                   (point)))
 414       (terpri)(terpri)
 415       (when (commandp function)
 416         (let ((pt2 (with-current-buffer (help-buffer) (point)))
 417               (remapped (command-remapping function)))
 418           (unless (memq remapped '(ignore undefined))
 419             (let ((keys (where-is-internal
 420                          (or remapped function) overriding-local-map nil nil))
 421                   non-modified-keys)
 422               (if (and (eq function 'self-insert-command)
 423                        (vectorp (car-safe keys))
 424                        (consp (aref (car keys) 0)))
 425                   (princ "It is bound to many ordinary text characters.\n")
 426                 ;; Which non-control non-meta keys run this command?
 427                 (dolist (key keys)
 428                   (if (member (event-modifiers (aref key 0)) '(nil (shift)))
 429                       (push key non-modified-keys)))
 430                 (when remapped
 431                   (princ "It is remapped to `")
 432                   (princ (symbol-name remapped))
 433                   (princ "'"))
 434
 435                 (when keys
 436                   (princ (if remapped ", which is bound to " "It is bound to "))
 437                   ;; If lots of ordinary text characters run this command,
 438                   ;; don't mention them one by one.
 439                   (if (< (length non-modified-keys) 10)
 440                       (princ (mapconcat 'key-description keys ", "))
 441                     (dolist (key non-modified-keys)
 442                       (setq keys (delq key keys)))
 443                     (if keys
 444                         (progn
 445                           (princ (mapconcat 'key-description keys ", "))
 446                           (princ ", and many ordinary text characters"))
 447                       (princ "many ordinary text characters"))))
 448                 (when (or remapped keys non-modified-keys)
 449                   (princ ".")
 450                   (terpri)))))
 451
 452           (with-current-buffer (help-buffer)
 453             (fill-region-as-paragraph pt2 (point))
 454             (unless (looking-back "\n\n")
 455               (terpri)))))
 456       ;; Note that list* etc do not get this property until
 457       ;; cl-hack-byte-compiler runs, after bytecomp is loaded.
 458       (when (and (symbolp function)
 459                  (eq (get function 'byte-compile)
 460                      'cl-byte-compile-compiler-macro))
 461         (princ "This function has a compiler macro")
 462         (let ((lib (get function 'compiler-macro-file)))
 463           (when (stringp lib)
 464             (princ (format " in `%s'" lib))
 465             (with-current-buffer standard-output
 466               (save-excursion
 467                 (re-search-backward "`\\([^`']+\\)'" nil t)
 468                 (help-xref-button 1 'help-function-cmacro function lib)))))
 469         (princ ".\n\n"))
 470       (let* ((advertised (gethash def advertised-signature-table t))
 471              (arglist (if (listp advertised)
 472                           advertised (help-function-arglist def)))
 473              (doc (documentation function))
 474              (usage (help-split-fundoc doc function)))
 475         (with-current-buffer standard-output
 476           ;; If definition is a keymap, skip arglist note.
 477           (unless (keymapp function)
 478             (if usage (setq doc (cdr usage)))
 479             (let* ((use (cond
 480                          ((and usage (not (listp advertised))) (car usage))
 481                          ((listp arglist)
 482                           (format "%S" (help-make-usage function arglist)))
 483                          ((stringp arglist) arglist)
 484                          ;; Maybe the arglist is in the docstring of a symbol
 485                          ;; this one is aliased to.
 486                          ((let ((fun real-function))
 487                             (while (and (symbolp fun)
 488                                         (setq fun (symbol-function fun))
 489                                         (not (setq usage (help-split-fundoc
 490                                                           (documentation fun)
 491                                                           function)))))
 492                             usage)
 493                           (car usage))
 494                          ((or (stringp def)
 495                               (vectorp def))
 496                           (format "\nMacro: %s" (format-kbd-macro def)))
 497                          (t "[Missing arglist.  Please make a bug report.]")))
 498                    (high (help-highlight-arguments use doc)))
 499               (let ((fill-begin (point)))
 500                 (insert (car high) "\n")
 501                 (fill-region fill-begin (point)))
 502               (setq doc (cdr high))))
 503           (let* ((obsolete (and
 504                             ;; function might be a lambda construct.
 505                             (symbolp function)
 506                             (get function 'byte-obsolete-info)))
 507                  (use (car obsolete)))
 508             (when obsolete
 509               (princ "\nThis function is obsolete")
 510               (when (nth 2 obsolete)
 511                 (insert (format " since %s" (nth 2 obsolete))))
 512               (insert (cond ((stringp use) (concat ";\n" use))
 513                             (use (format ";\nuse `%s' instead." use))
 514                             (t "."))
 515                       "\n"))
 516             (insert "\n"
 517                     (or doc "Not documented."))))))))
 518
 519 \f
 520 ;; Variables
 521
 522 ;;;###autoload
 523 (defun variable-at-point (&optional any-symbol)
 524   "Return the bound variable symbol found at or before point.
 525 Return 0 if there is no such symbol.
 526 If ANY-SYMBOL is non-nil, don't insist the symbol be bound."
 527   (with-syntax-table emacs-lisp-mode-syntax-table
 528     (or (condition-case ()
 529             (save-excursion
 530               (or (not (zerop (skip-syntax-backward "_w")))
 531                   (eq (char-syntax (following-char)) ?w)
 532                   (eq (char-syntax (following-char)) ?_)
 533                   (forward-sexp -1))
 534               (skip-chars-forward "'")
 535               (let ((obj (read (current-buffer))))
 536                 (and (symbolp obj) (boundp obj) obj)))
 537           (error nil))
 538         (let* ((str (find-tag-default))
 539                (sym (if str (intern-soft str))))
 540           (if (and sym (or any-symbol (boundp sym)))
 541               sym
 542             (save-match-data
 543               (when (and str (string-match "\\`\\W*\\(.*?\\)\\W*\\'" str))
 544                 (setq sym (intern-soft (match-string 1 str)))
 545                 (and (or any-symbol (boundp sym)) sym)))))
 546         0)))
 547
 548 (defun describe-variable-custom-version-info (variable)
 549   (let ((custom-version (get variable 'custom-version))
 550         (cpv (get variable 'custom-package-version))
 551         (output nil))
 552     (if custom-version
 553         (setq output
 554               (format "This variable was introduced, or its default value was changed, in\nversion %s of Emacs.\n"
 555                       custom-version))
 556       (when cpv
 557         (let* ((package (car-safe cpv))
 558                (version (if (listp (cdr-safe cpv))
 559                             (car (cdr-safe cpv))
 560                           (cdr-safe cpv)))
 561                (pkg-versions (assq package customize-package-emacs-version-alist))
 562                (emacsv (cdr (assoc version pkg-versions))))
 563           (if (and package version)
 564               (setq output
 565                     (format (concat "This variable was introduced, or its default value was changed, in\nversion %s of the %s package"
 566                                     (if emacsv
 567                                         (format " that is part of Emacs %s" emacsv))
 568                                     ".\n")
 569                             version package))))))
 570     output))
 571
 572 ;;;###autoload
 573 (defun describe-variable (variable &optional buffer frame)
 574   "Display the full documentation of VARIABLE (a symbol).
 575 Returns the documentation as a string, also.
 576 If VARIABLE has a buffer-local value in BUFFER or FRAME
 577 \(default to the current buffer and current frame),
 578 it is displayed along with the global value."
 579   (interactive
 580    (let ((v (variable-at-point))
 581          (enable-recursive-minibuffers t)
 582          val)
 583      (setq val (completing-read (if (symbolp v)
 584                                     (format
 585                                      "Describe variable (default %s): " v)
 586                                   "Describe variable: ")
 587                                 obarray
 588                                 (lambda (vv)
 589                                   (or (get vv 'variable-documentation)
 590                                       (and (boundp vv) (not (keywordp vv)))))
 591                                 t nil nil
 592                                 (if (symbolp v) (symbol-name v))))
 593      (list (if (equal val "")
 594                v (intern val)))))
 595   (let (file-name)
 596     (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 597     (unless (frame-live-p frame) (setq frame (selected-frame)))
 598     (if (not (symbolp variable))
 599         (message "You did not specify a variable")
 600       (save-excursion
 601         (let ((valvoid (not (with-current-buffer buffer (boundp variable))))
 602               val val-start-pos locus)
 603           ;; Extract the value before setting up the output buffer,
 604           ;; in case `buffer' *is* the output buffer.
 605           (unless valvoid
 606             (with-selected-frame frame
 607               (with-current-buffer buffer
 608                 (setq val (symbol-value variable)
 609                       locus (variable-binding-locus variable)))))
 610           (help-setup-xref (list #'describe-variable variable buffer)
 611                            (called-interactively-p 'interactive))
 612           (with-help-window (help-buffer)
 613             (with-current-buffer buffer
 614               (prin1 variable)
 615               (setq file-name (find-lisp-object-file-name variable 'defvar))
 616
 617               (if file-name
 618                   (progn
 619                     (princ " is a variable defined in `")
 620                     (princ (if (eq file-name 'C-source)
 621                                "C source code"
 622                              (file-name-nondirectory file-name)))
 623                     (princ "'.\n")
 624                     (with-current-buffer standard-output
 625                       (save-excursion
 626                         (re-search-backward "`\\([^`']+\\)'" nil t)
 627                         (help-xref-button 1 'help-variable-def
 628                                           variable file-name)))
 629                     (if valvoid
 630                         (princ "It is void as a variable.")
 631                       (princ "Its ")))
 632                 (if valvoid
 633                     (princ " is void as a variable.")
 634                   (princ "'s "))))
 635             (unless valvoid
 636               (with-current-buffer standard-output
 637                 (setq val-start-pos (point))
 638                 (princ "value is ")
 639                 (let ((from (point)))
 640                   (terpri)
 641                   (pp val)
 642                   (if (< (point) (+ 68 (line-beginning-position 0)))
 643                       (delete-region from (1+ from))
 644                     (delete-region (1- from) from)))))
 645             (terpri)
 646             (when locus
 647               (if (bufferp locus)
 648                   (princ (format "%socal in buffer %s; "
 649                                  (if (get variable 'permanent-local)
 650                                      "Permanently l" "L")
 651                                  (buffer-name)))
 652                 (princ (format "It is a frame-local variable; ")))
 653               (if (not (default-boundp variable))
 654                   (princ "globally void")
 655                 (let ((val (default-value variable)))
 656                   (with-current-buffer standard-output
 657                     (princ "global value is ")
 658                     (terpri)
 659                     ;; Fixme: pp can take an age if you happen to
 660                     ;; ask for a very large expression.  We should
 661                     ;; probably print it raw once and check it's a
 662                     ;; sensible size before prettyprinting.  -- fx
 663                     (let ((from (point)))
 664                       (pp val)
 665                       ;; See previous comment for this function.
 666                       ;; (help-xref-on-pp from (point))
 667                       (if (< (point) (+ from 20))
 668                           (delete-region (1- from) from))))))
 669               (terpri))
 670
 671             ;; If the value is large, move it to the end.
 672             (with-current-buffer standard-output
 673               (when (> (count-lines (point-min) (point-max)) 10)
 674                 ;; Note that setting the syntax table like below
 675                 ;; makes forward-sexp move over a `'s' at the end
 676                 ;; of a symbol.
 677                 (set-syntax-table emacs-lisp-mode-syntax-table)
 678                 (goto-char val-start-pos)
 679                 ;; The line below previously read as
 680                 ;; (delete-region (point) (progn (end-of-line) (point)))
 681                 ;; which suppressed display of the buffer local value for
 682                 ;; large values.
 683                 (when (looking-at "value is") (replace-match ""))
 684                 (save-excursion
 685                   (insert "\n\nValue:")
 686                   (set (make-local-variable 'help-button-cache)
 687                        (point-marker)))
 688                 (insert "value is shown ")
 689                 (insert-button "below"
 690                                'action help-button-cache
 691                                'follow-link t
 692                                'help-echo "mouse-2, RET: show value")
 693                 (insert ".\n")))
 694             (terpri)
 695
 696             (let* ((alias (condition-case nil
 697                               (indirect-variable variable)
 698                             (error variable)))
 699                    (obsolete (get variable 'byte-obsolete-variable))
 700                    (use (car obsolete))
 701                    (safe-var (get variable 'safe-local-variable))
 702                    (doc (or (documentation-property variable 'variable-documentation)
 703                             (documentation-property alias 'variable-documentation)))
 704                    (extra-line nil))
 705               ;; Add a note for variables that have been make-var-buffer-local.
 706               (when (and (local-variable-if-set-p variable)
 707                          (or (not (local-variable-p variable))
 708                              (with-temp-buffer
 709                                (local-variable-if-set-p variable))))
 710                 (setq extra-line t)
 711                 (princ "  Automatically becomes buffer-local when set in any fashion.\n"))
 712
 713               ;; Mention if it's an alias
 714               (unless (eq alias variable)
 715                 (setq extra-line t)
 716                 (princ (format "  This variable is an alias for `%s'.\n" alias)))
 717
 718               (when obsolete
 719                 (setq extra-line t)
 720                 (princ "  This variable is obsolete")
 721                 (if (cdr obsolete) (princ (format " since %s" (cdr obsolete))))
 722                 (princ (cond ((stringp use) (concat ";\n  " use))
 723                              (use (format ";\n  use `%s' instead." (car obsolete)))
 724                              (t ".")))
 725                 (terpri))
 726
 727               (when (member (cons variable val) file-local-variables-alist)
 728                 (setq extra-line t)
 729                 (if (member (cons variable val) dir-local-variables-alist)
 730                     (let ((file (and (buffer-file-name)
 731                                      (not (file-remote-p (buffer-file-name)))
 732                                      (dir-locals-find-file (buffer-file-name)))))
 733                       (princ "  This variable is a directory local variable")
 734                       (when file
 735                         (princ (concat "\n  from the file \""
 736                                        (if (consp file)
 737                                            (car file)
 738                                          file)
 739                                        "\"")))
 740                       (princ ".\n"))
 741                   (princ "  This variable is a file local variable.\n")))
 742
 743               (when (memq variable ignored-local-variables)
 744                 (setq extra-line t)
 745                 (princ "  This variable is ignored when used as a file local \
 746 variable.\n"))
 747
 748               ;; Can be both risky and safe, eg auto-fill-function.
 749               (when (risky-local-variable-p variable)
 750                 (setq extra-line t)
 751                 (princ "  This variable is potentially risky when used as a \
 752 file local variable.\n")
 753                 (when (assq variable safe-local-variable-values)
 754                   (princ "  However, you have added it to \
 755 `safe-local-variable-values'.\n")))
 756
 757               (when safe-var
 758                 (setq extra-line t)
 759                 (princ "  This variable is safe as a file local variable ")
 760                 (princ "if its value\n  satisfies the predicate ")
 761                 (princ (if (byte-code-function-p safe-var)
 762                            "which is byte-compiled expression.\n"
 763                          (format "`%s'.\n" safe-var))))
 764
 765               (if extra-line (terpri))
 766               (princ "Documentation:\n")
 767               (with-current-buffer standard-output
 768                 (insert (or doc "Not documented as a variable."))))
 769
 770             ;; Make a link to customize if this variable can be customized.
 771             (when (custom-variable-p variable)
 772               (let ((customize-label "customize"))
 773                 (terpri)
 774                 (terpri)
 775                 (princ (concat "You can " customize-label " this variable."))
 776                 (with-current-buffer standard-output
 777                   (save-excursion
 778                     (re-search-backward
 779                      (concat "\\(" customize-label "\\)") nil t)
 780                     (help-xref-button 1 'help-customize-variable variable))))
 781               ;; Note variable's version or package version
 782               (let ((output (describe-variable-custom-version-info variable)))
 783                 (when output
 784                   (terpri)
 785                   (terpri)
 786                   (princ output))))
 787
 788             (with-current-buffer standard-output
 789               ;; Return the text we displayed.
 790               (buffer-string))))))))
 791
 792
 793 ;;;###autoload
 794 (defun describe-syntax (&optional buffer)
 795   "Describe the syntax specifications in the syntax table of BUFFER.
 796 The descriptions are inserted in a help buffer, which is then displayed.
 797 BUFFER defaults to the current buffer."
 798   (interactive)
 799   (setq buffer (or buffer (current-buffer)))
 800   (help-setup-xref (list #'describe-syntax buffer)
 801                    (called-interactively-p 'interactive))
 802   (with-help-window (help-buffer)
 803     (let ((table (with-current-buffer buffer (syntax-table))))
 804       (with-current-buffer standard-output
 805         (describe-vector table 'internal-describe-syntax-value)
 806         (while (setq table (char-table-parent table))
 807           (insert "\nThe parent syntax table is:")
 808           (describe-vector table 'internal-describe-syntax-value))))))
 809
 810 (defun help-describe-category-set (value)
 811   (insert (cond
 812            ((null value) "default")
 813            ((char-table-p value) "deeper char-table ...")
 814            (t (condition-case err
 815                   (category-set-mnemonics value)
 816                 (error "invalid"))))))
 817
 818 ;;;###autoload
 819 (defun describe-categories (&optional buffer)
 820   "Describe the category specifications in the current category table.
 821 The descriptions are inserted in a buffer, which is then displayed.
 822 If BUFFER is non-nil, then describe BUFFER's category table instead.
 823 BUFFER should be a buffer or a buffer name."
 824   (interactive)
 825   (setq buffer (or buffer (current-buffer)))
 826   (help-setup-xref (list #'describe-categories buffer)
 827                    (called-interactively-p 'interactive))
 828   (with-help-window (help-buffer)
 829     (let* ((table (with-current-buffer buffer (category-table)))
 830            (docs (char-table-extra-slot table 0)))
 831       (if (or (not (vectorp docs)) (/= (length docs) 95))
 832           (error "Invalid first extra slot in this category table\n"))
 833       (with-current-buffer standard-output
 834         (insert "Legend of category mnemonics (see the tail for the longer description)\n")
 835         (let ((pos (point)) (items 0) lines n)
 836           (dotimes (i 95)
 837             (if (aref docs i) (setq items (1+ items))))
 838           (setq lines (1+ (/ (1- items) 4)))
 839           (setq n 0)
 840           (dotimes (i 95)
 841             (let ((elt (aref docs i)))
 842               (when elt
 843                 (string-match ".*" elt)
 844                 (setq elt (match-string 0 elt))
 845                 (if (>= (length elt) 17)
 846                     (setq elt (concat (substring elt 0 14) "...")))
 847                 (if (< (point) (point-max))
 848                     (move-to-column (* 20 (/ n lines)) t))
 849                 (insert (+ i ?\s) ?: elt)
 850                 (if (< (point) (point-max))
 851                     (forward-line 1)
 852                   (insert "\n"))
 853                 (setq n (1+ n))
 854                 (if (= (% n lines) 0)
 855                     (goto-char pos))))))
 856         (goto-char (point-max))
 857         (insert "\n"
 858                 "character(s)\tcategory mnemonics\n"
 859                 "------------\t------------------")
 860         (describe-vector table 'help-describe-category-set)
 861         (insert "Legend of category mnemonics:\n")
 862         (dotimes (i 95)
 863           (let ((elt (aref docs i)))
 864             (when elt
 865               (if (string-match "\n" elt)
 866                   (setq elt (substring elt (match-end 0))))
 867               (insert (+ i ?\s) ": " elt "\n"))))
 868         (while (setq table (char-table-parent table))
 869           (insert "\nThe parent category table is:")
 870           (describe-vector table 'help-describe-category-set))))))
 871
 872 (provide 'help-fns)
 873
 874 ;; arch-tag: 9e10331c-ae81-4d13-965d-c4819aaab0b3
 875 ;;; help-fns.el ends here