lisp/fast-lock.el

   1 ;;; fast-lock.el --- Automagic text properties caching for fast Font Lock mode.
   2
   3 ;; Copyright (C) 1994, 1995, 1996 Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Marshall <simon@gnu.ai.mit.edu>
   6 ;; Keywords: faces files
   7 ;; Version: 3.11
   8
   9 ;;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Lazy Lock mode is a Font Lock support mode.
  29 ;; It makes visiting a file in Font Lock mode faster by restoring its face text
  30 ;; properties from automatically saved associated Font Lock cache files.
  31 ;;
  32 ;; See caveats and feedback below.
  33 ;; See also the lazy-lock package.  (But don't use the two at the same time!)
  34
  35 ;; Installation:
  36 ;;
  37 ;; Put in your ~/.emacs:
  38 ;;
  39 ;; (setq font-lock-support-mode 'fast-lock-mode)
  40 ;;
  41 ;; Start up a new Emacs and use font-lock as usual (except that you can use the
  42 ;; so-called "gaudier" fontification regexps on big files without frustration).
  43 ;;
  44 ;; When you visit a file (which has `font-lock-mode' enabled) that has a
  45 ;; corresponding Font Lock cache file associated with it, the Font Lock cache
  46 ;; will be loaded from that file instead of being generated by Font Lock code.
  47
  48 ;; Caveats:
  49 ;;
  50 ;; A cache will be saved when visiting a compressed file using crypt++, but not
  51 ;; be read.  This is a "feature"/"consequence"/"bug" of crypt++.
  52 ;;
  53 ;; Version control packages are likely to stamp all over file modification
  54 ;; times.  Therefore the act of checking out may invalidate a cache.
  55 \f
  56 ;; History:
  57 ;;
  58 ;; 0.02--1.00:
  59 ;; - Changed name from turbo-prop to fast-lock.  Automagic for font-lock only
  60 ;; - Made `fast-lock-mode' a minor mode, like G. Dinesh Dutt's fss-mode
  61 ;; 1.00--1.01:
  62 ;; - Turn on `fast-lock-mode' only if `buffer-file-name' or `interactive-p'
  63 ;; - Made `fast-lock-file-name' use `buffer-name' if `buffer-file-name' is nil
  64 ;; - Moved save-all conditions to `fast-lock-save-cache'
  65 ;; - Added `fast-lock-save-text-properties' to `kill-buffer-hook'
  66 ;; 1.01--2.00: complete rewrite---not worth the space to document
  67 ;; - Changed structure of text properties cache and threw out file mod checks
  68 ;; 2.00--2.01:
  69 ;; - Made `condition-case' forms understand `quit'.
  70 ;; - Made `fast-lock' require `font-lock'
  71 ;; - Made `fast-lock-cache-name' chase links (from Ben Liblit)
  72 ;; 2.01--3.00:
  73 ;; - Changed structure of cache to include `font-lock-keywords' (from rms)
  74 ;; - Changed `fast-lock-cache-mechanisms' to `fast-lock-cache-directories'
  75 ;; - Removed `fast-lock-read-others'
  76 ;; - Made `fast-lock-read-cache' ignore cache owner
  77 ;; - Made `fast-lock-save-cache-external' create cache directory
  78 ;; - Made `fast-lock-save-cache-external' save `font-lock-keywords'
  79 ;; - Made `fast-lock-cache-data' check `font-lock-keywords'
  80 ;; 3.00--3.01: incorporated port of 2.00 to Lucid, made by Barry Warsaw
  81 ;; - Package now provides itself
  82 ;; - Lucid: Use `font-lock-any-extents-p' for `font-lock-any-properties-p'
  83 ;; - Lucid: Use `list-faces' for `face-list'
  84 ;; - Lucid: Added `set-text-properties'
  85 ;; - Lucid: Made `turn-on-fast-lock' pass 1 not t to `fast-lock-mode'
  86 ;; - Removed test for `fast-lock-mode' from `fast-lock-read-cache'
  87 ;; - Lucid: Added Lucid-specific `fast-lock-get-face-properties'
  88 ;; 3.01--3.02: now works with Lucid Emacs, thanks to Barry Warsaw
  89 ;; - Made `fast-lock-cache-name' map ":" to ";" for OS/2 (from Serganova Vera)
  90 ;; - Made `fast-lock-cache-name' use abbreviated file name (from Barry Warsaw)
  91 ;; - Lucid: Separated handlers for `error' and `quit' for `condition-case'
  92 ;; 3.02--3.03:
  93 ;; - Changed `fast-lock-save-cache-external' to `fast-lock-save-cache-data'
  94 ;; - Lucid: Added Lucid-specific `fast-lock-set-face-properties'
  95 ;; 3.03--3.04:
  96 ;; - Corrected `subrp' test of Lucid code
  97 ;; - Replaced `font-lock-any-properties-p' with `text-property-not-all'
  98 ;; - Lucid: Made `fast-lock-set-face-properties' put `text-prop' on extents
  99 ;; - Made `fast-lock-cache-directories' a regexp alist (from Colin Rafferty)
 100 ;; - Made `fast-lock-cache-directory' to return a usable cache file directory
 101 ;; 3.04--3.05:
 102 ;; - Lucid: Fix for XEmacs 19.11 `text-property-not-all'
 103 ;; - Replaced `subrp' test of Lucid code with `emacs-version' `string-match'
 104 ;; - Made `byte-compile-warnings' omit `unresolved' on compilation
 105 ;; - Made `fast-lock-save-cache-data' use a buffer (from Rick Sladkey)
 106 ;; - Reverted to old `fast-lock-get-face-properties' (from Rick Sladkey)
 107 ;; 3.05--3.06: incorporated hack of 3.03, made by Jonathan Stigelman (Stig)
 108 ;; - Reverted to 3.04 version of `fast-lock-get-face-properties'
 109 ;; - XEmacs: Removed `list-faces' `defalias'
 110 ;; - Made `fast-lock-mode' and `turn-on-fast-lock' succeed `autoload' cookies
 111 ;; - Added `fast-lock-submit-bug-report'
 112 ;; - Renamed `fast-lock-save-size' to `fast-lock-minimum-size'
 113 ;; - Made `fast-lock-save-cache' output a message if no save ever attempted
 114 ;; - Made `fast-lock-save-cache-data' output a message if save attempted
 115 ;; - Made `fast-lock-cache-data' output a message if load attempted
 116 ;; - Made `fast-lock-save-cache-data' do `condition-case' not `unwind-protect'
 117 ;; - Made `fast-lock-save-cache' and `fast-lock-read-cache' return nothing
 118 ;; - Made `fast-lock-save-cache' check `buffer-modified-p' (Stig)
 119 ;; - Added `fast-lock-save-events'
 120 ;; - Added `fast-lock-after-save-hook' to `after-save-hook' (Stig)
 121 ;; - Added `fast-lock-kill-buffer-hook' to `kill-buffer-hook'
 122 ;; - Changed `fast-lock-save-caches' to `fast-lock-kill-emacs-hook'
 123 ;; - Added `fast-lock-kill-emacs-hook' to `kill-emacs-hook'
 124 ;; - Made `fast-lock-save-cache' check `verify-visited-file-modtime' (Stig)
 125 ;; - Made `visited-file-modtime' be the basis of the timestamp (Stig)
 126 ;; - Made `fast-lock-save-cache-1' and `fast-lock-cache-data' use/reformat it
 127 ;; - Added `fast-lock-cache-filename' to keep track of the cache file name
 128 ;; - Added `fast-lock-after-fontify-buffer'
 129 ;; - Added `fast-lock-save-faces' list of faces to save (idea from Stig/Tibor)
 130 ;; - Made `fast-lock-get-face-properties' functions use it
 131 ;; - XEmacs: Made `fast-lock-set-face-properties' do extents the Font Lock way
 132 ;; - XEmacs: Removed fix for `text-property-not-all' (19.11 support dropped)
 133 ;; - Made `fast-lock-mode' ensure `font-lock-mode' is on
 134 ;; - Made `fast-lock-save-cache' do `cdr-safe' not `cdr' (from Dave Foster)
 135 ;; - Made `fast-lock-save-cache' do `set-buffer' first (from Dave Foster)
 136 ;; - Made `fast-lock-save-cache' loop until saved or quit (from Georg Nikodym)
 137 ;; - Made `fast-lock-cache-data' check `buffer-modified-p'
 138 ;; - Made `fast-lock-cache-data' do `font-lock-compile-keywords' if necessary
 139 ;; - XEmacs: Made `font-lock-compile-keywords' `defalias'
 140 ;; 3.06--3.07:
 141 ;; - XEmacs: Add `fast-lock-after-fontify-buffer' to the Font Lock hook
 142 ;; - Made `fast-lock-cache-name' explain the use of `directory-abbrev-alist'
 143 ;; - Made `fast-lock-mode' use `buffer-file-truename' not `buffer-file-name'
 144 ;; 3.07--3.08:
 145 ;; - Made `fast-lock-read-cache' set `fast-lock-cache-filename'
 146 ;; 3.08--3.09:
 147 ;; - Made `fast-lock-save-cache' cope if `fast-lock-minimum-size' is an a list
 148 ;; - Made `fast-lock-mode' respect the value of `font-lock-inhibit-thing-lock'
 149 ;; - Added `fast-lock-after-unfontify-buffer'
 150 ;; 3.09--3.10:
 151 ;; - Rewrite for Common Lisp macros
 152 ;; - Made fast-lock.el barf on a crap 8+3 pseudo-OS (Eli Zaretskii help)
 153 ;; - XEmacs: Made `add-minor-mode' succeed `autoload' cookie
 154 ;; - XEmacs: Made `fast-lock-save-faces' default to `font-lock-face-list'
 155 ;; - Made `fast-lock-save-cache' use `font-lock-value-in-major-mode'
 156 ;; - Wrap with `save-buffer-state' (Ray Van Tassle report)
 157 ;; - Made `fast-lock-mode' wrap `font-lock-support-mode'
 158 ;; 3.10--3.11:
 159 ;; - Made `fast-lock-get-face-properties' cope with face lists
 160 ;; - Added `fast-lock-verbose'
 161 ;; - XEmacs: Add `font-lock-value-in-major-mode' if necessary
 162 ;; - Removed `fast-lock-submit-bug-report' and bade farewell
 163 \f
 164 ;;; Code:
 165
 166 (require 'font-lock)
 167
 168 ;; Make sure fast-lock.el is supported.
 169 (if (and (eq system-type 'ms-dos) (not (msdos-long-file-names)))
 170     (error "`fast-lock' was written for long file name systems"))
 171
 172 (eval-when-compile
 173   ;;
 174   ;; We don't do this at the top-level as we only use non-autoloaded macros.
 175   (require 'cl)
 176   ;;
 177   ;; I prefer lazy code---and lazy mode.
 178   (setq byte-compile-dynamic t byte-compile-dynamic-docstrings t)
 179   ;; But, we make sure that the code is as zippy as can be.
 180   (setq byte-optimize t)
 181   ;;
 182   ;; We use this to preserve or protect things when modifying text properties.
 183   (defmacro save-buffer-state (varlist &rest body)
 184     "Bind variables according to VARLIST and eval BODY restoring buffer state."
 185     (` (let* ((,@ (append varlist
 186                    '((modified (buffer-modified-p))
 187                      (inhibit-read-only t) (buffer-undo-list t)
 188                      before-change-functions after-change-functions
 189                      deactivate-mark buffer-file-name buffer-file-truename))))
 190          (,@ body)
 191          (when (and (not modified) (buffer-modified-p))
 192            (set-buffer-modified-p nil)))))
 193   (put 'save-buffer-state 'lisp-indent-function 1)
 194   ;;
 195   ;; We use this to verify that a face should be saved.
 196   (defmacro fast-lock-save-facep (face)
 197     "Return non-nil if FACE is one of `fast-lock-save-faces'."
 198     (` (or (null fast-lock-save-faces)
 199            (if (symbolp (, face))
 200                (memq (, face) fast-lock-save-faces)
 201              (let ((faces (, face)))
 202                (while (unless (memq (car faces) fast-lock-save-faces)
 203                         (setq faces (cdr faces))))
 204                faces))))))
 205
 206 ;(defun fast-lock-submit-bug-report ()
 207 ;  "Submit via mail a bug report on fast-lock.el."
 208 ;  (interactive)
 209 ;  (let ((reporter-prompt-for-summary-p t))
 210 ;    (reporter-submit-bug-report "simon@gnu.ai.mit.edu" "fast-lock 3.11"
 211 ;     '(fast-lock-cache-directories fast-lock-minimum-size
 212 ;       fast-lock-save-others fast-lock-save-events fast-lock-save-faces
 213 ;       fast-lock-verbose)
 214 ;     nil nil
 215 ;     (concat "Hi Si.,
 216 ;
 217 ;I want to report a bug.  I've read the `Bugs' section of `Info' on Emacs, so I
 218 ;know how to make a clear and unambiguous report.  To reproduce the bug:
 219 ;
 220 ;Start a fresh editor via `" invocation-name " -no-init-file -no-site-file'.
 221 ;In the `*scratch*' buffer, evaluate:"))))
 222
 223 (defvar fast-lock-mode nil)
 224 (defvar fast-lock-cache-timestamp nil)  ; for saving/reading
 225 (defvar fast-lock-cache-filename nil)   ; for deleting
 226 \f
 227 ;; User Variables:
 228
 229 (defgroup fast-lock nil
 230   "Automagic text properties caching for fast Font Lock mode"
 231   :group 'faces)
 232
 233
 234 (defcustom fast-lock-cache-directories '("." "~/.emacs-flc")
 235 ; - `internal', keep each file's Font Lock cache file in the same file.
 236 ; - `external', keep each file's Font Lock cache file in the same directory.
 237   "*Directories in which Font Lock cache files are saved and read.
 238 Each item should be either DIR or a cons pair of the form (REGEXP . DIR) where
 239 DIR is a directory name (relative or absolute) and REGEXP is a regexp.
 240
 241 An attempt will be made to save or read Font Lock cache files using these items
 242 until one succeeds (i.e., until a readable or writable one is found).  If an
 243 item contains REGEXP, DIR is used only if the buffer file name matches REGEXP.
 244 For example:
 245
 246  (let ((home (expand-file-name (abbreviate-file-name (file-truename \"~/\")))))
 247    (list (cons (concat \"^\" (regexp-quote home)) \".\") \"~/.emacs-flc\"))
 248     =>
 249  ((\"^/your/true/home/directory/\" . \".\") \"~/.emacs-flc\")
 250
 251 would cause a file's current directory to be used if the file is under your
 252 home directory hierarchy, or otherwise the absolute directory `~/.emacs-flc'."
 253   :type '(repeat (choice (cons regexp directory) directory))
 254   :group 'fast-lock)
 255
 256 (defcustom fast-lock-minimum-size (* 25 1024)
 257   "*Minimum size of a buffer for cached fontification.
 258 Only buffers more than this can have associated Font Lock cache files saved.
 259 If nil, means cache files are never created.
 260 If a list, each element should be a cons pair of the form (MAJOR-MODE . SIZE),
 261 where MAJOR-MODE is a symbol or t (meaning the default).  For example:
 262  ((c-mode . 25600) (c++-mode . 25600) (rmail-mode . 1048576))
 263 means that the minimum size is 25K for buffers in C or C++ modes, one megabyte
 264 for buffers in Rmail mode, and size is irrelevant otherwise."
 265   :type '(choice (integer :tag "Size") (repeat (cons (symbol :tag "Major Mode")
 266                                                     (integer :tag "Size"))))
 267   :group 'fast-lock)
 268
 269 (defcustom fast-lock-save-events '(kill-buffer kill-emacs)
 270   "*Events under which caches will be saved.
 271 Valid events are `save-buffer', `kill-buffer' and `kill-emacs'.
 272 If concurrent editing sessions use the same associated cache file for a file's
 273 buffer, then you should add `save-buffer' to this list."
 274   :type '(set (const kill-buffer) (const save-buffer) (const kill-emacs))
 275   :group 'fast-lock)
 276
 277 (defcustom fast-lock-save-others t
 278   "*If non-nil, save Font Lock cache files irrespective of file owner.
 279 If nil, means only buffer files known to be owned by you can have associated
 280 Font Lock cache files saved.  Ownership may be unknown for networked files."
 281   :type 'boolean
 282   :group 'fast-lock)
 283
 284 (defvar fast-lock-save-faces
 285   (when (save-match-data (string-match "XEmacs" (emacs-version)))
 286     ;; XEmacs uses extents for everything, so we have to pick the right ones.
 287     font-lock-face-list)
 288   "Faces that will be saved in a Font Lock cache file.
 289 If nil, means information for all faces will be saved.")
 290
 291 (defcustom fast-lock-verbose font-lock-verbose
 292   "*If non-nil, means show status messages for cache processing.
 293 If a number, only buffers greater than this size have processing messages."
 294   :type '(choice integer boolean)
 295   :group 'fast-lock)
 296 \f
 297 ;; User Functions:
 298
 299 ;;;###autoload
 300 (defun fast-lock-mode (&optional arg)
 301   "Toggle Fast Lock mode.
 302 With arg, turn Fast Lock mode on if and only if arg is positive and the buffer
 303 is associated with a file.  Enable it automatically in your `~/.emacs' by:
 304
 305  (setq font-lock-support-mode 'fast-lock-mode)
 306
 307 If Fast Lock mode is enabled, and the current buffer does not contain any text
 308 properties, any associated Font Lock cache is used if its timestamp matches the
 309 buffer's file, and its `font-lock-keywords' match those that you are using.
 310
 311 Font Lock caches may be saved:
 312 - When you save the file's buffer.
 313 - When you kill an unmodified file's buffer.
 314 - When you exit Emacs, for all unmodified or saved buffers.
 315 Depending on the value of `fast-lock-save-events'.
 316 See also the commands `fast-lock-read-cache' and `fast-lock-save-cache'.
 317
 318 Use \\[font-lock-fontify-buffer] to fontify the buffer if the cache is bad.
 319
 320 Various methods of control are provided for the Font Lock cache.  In general,
 321 see variable `fast-lock-cache-directories' and function `fast-lock-cache-name'.
 322 For saving, see variables `fast-lock-minimum-size', `fast-lock-save-events',
 323 `fast-lock-save-others' and `fast-lock-save-faces'."
 324   (interactive "P")
 325   ;; Only turn on if we are visiting a file.  We could use `buffer-file-name',
 326   ;; but many packages temporarily wrap that to nil when doing their own thing.
 327   (set (make-local-variable 'fast-lock-mode)
 328        (and buffer-file-truename
 329             (not (memq 'fast-lock-mode font-lock-inhibit-thing-lock))
 330             (if arg (> (prefix-numeric-value arg) 0) (not fast-lock-mode))))
 331   (if (and fast-lock-mode (not font-lock-mode))
 332       ;; Turned on `fast-lock-mode' rather than `font-lock-mode'.
 333       (let ((font-lock-support-mode 'fast-lock-mode))
 334         (font-lock-mode t))
 335     ;; Let's get down to business.
 336     (set (make-local-variable 'fast-lock-cache-timestamp) nil)
 337     (set (make-local-variable 'fast-lock-cache-filename) nil)
 338     (when (and fast-lock-mode (not font-lock-fontified))
 339       (fast-lock-read-cache))))
 340
 341 (defun fast-lock-read-cache ()
 342   "Read the Font Lock cache for the current buffer.
 343
 344 The following criteria must be met for a Font Lock cache file to be read:
 345 - Fast Lock mode must be turned on in the buffer.
 346 - The buffer must not be modified.
 347 - The buffer's `font-lock-keywords' must match the cache's.
 348 - The buffer file's timestamp must match the cache's.
 349 - Criteria imposed by `fast-lock-cache-directories'.
 350
 351 See `fast-lock-mode'."
 352   (interactive)
 353   (let ((directories fast-lock-cache-directories)
 354         (modified (buffer-modified-p)) (inhibit-read-only t)
 355         (fontified font-lock-fontified))
 356     (set (make-local-variable 'font-lock-fontified) nil)
 357     ;; Keep trying directories until fontification is turned off.
 358     (while (and directories (not font-lock-fontified))
 359       (let ((directory (fast-lock-cache-directory (car directories) nil)))
 360         (condition-case nil
 361             (when directory
 362               (setq fast-lock-cache-filename (fast-lock-cache-name directory))
 363               (when (file-readable-p fast-lock-cache-filename)
 364                 (load fast-lock-cache-filename t t t)))
 365           (error nil) (quit nil))
 366         (setq directories (cdr directories))))
 367     ;; Unset `fast-lock-cache-filename', and restore `font-lock-fontified', if
 368     ;; we don't use a cache.  (Note that `fast-lock-cache-data' sets the value
 369     ;; of `fast-lock-cache-timestamp'.)
 370     (set-buffer-modified-p modified)
 371     (unless font-lock-fontified
 372       (setq fast-lock-cache-filename nil font-lock-fontified fontified))))
 373
 374 (defun fast-lock-save-cache (&optional buffer)
 375   "Save the Font Lock cache of BUFFER or the current buffer.
 376
 377 The following criteria must be met for a Font Lock cache file to be saved:
 378 - Fast Lock mode must be turned on in the buffer.
 379 - The event must be one of `fast-lock-save-events'.
 380 - The buffer must be at least `fast-lock-minimum-size' bytes long.
 381 - The buffer file must be owned by you, or `fast-lock-save-others' must be t.
 382 - The buffer must contain at least one `face' text property.
 383 - The buffer must not be modified.
 384 - The buffer file's timestamp must be the same as the file's on disk.
 385 - The on disk file's timestamp must be different than the buffer's cache.
 386 - Criteria imposed by `fast-lock-cache-directories'.
 387
 388 See `fast-lock-mode'."
 389   (interactive)
 390   (save-excursion
 391     (when buffer
 392       (set-buffer buffer))
 393     (let ((min-size (font-lock-value-in-major-mode fast-lock-minimum-size))
 394           (file-timestamp (visited-file-modtime)) (saved nil))
 395       (when (and fast-lock-mode
 396              ;;
 397              ;; "Only save if the buffer matches the file, the file has
 398              ;; changed, and it was changed by the current emacs session."
 399              ;;
 400              ;; Only save if the buffer is not modified,
 401              ;; (i.e., so we don't save for something not on disk)
 402              (not (buffer-modified-p))
 403              ;; and the file's timestamp is the same as the buffer's,
 404              ;; (i.e., someone else hasn't written the file in the meantime)
 405              (verify-visited-file-modtime (current-buffer))
 406              ;; and the file's timestamp is different from the cache's.
 407              ;; (i.e., a save has occurred since the cache was read)
 408              (not (equal fast-lock-cache-timestamp file-timestamp))
 409              ;;
 410              ;; Only save if user's restrictions are satisfied.
 411              (and min-size (>= (buffer-size) min-size))
 412              (or fast-lock-save-others
 413                  (eq (user-uid) (nth 2 (file-attributes buffer-file-name))))
 414              ;;
 415              ;; Only save if there are `face' properties to save.
 416              (text-property-not-all (point-min) (point-max) 'face nil))
 417         ;;
 418         ;; Try each directory until we manage to save or the user quits.
 419         (let ((directories fast-lock-cache-directories))
 420           (while (and directories (memq saved '(nil error)))
 421             (let* ((dir (fast-lock-cache-directory (car directories) t))
 422                    (file (and dir (fast-lock-cache-name dir))))
 423               (when (and file (file-writable-p file))
 424                 (setq saved (fast-lock-save-cache-1 file file-timestamp)))
 425               (setq directories (cdr directories)))))))))
 426
 427 ;;;###autoload
 428 (defun turn-on-fast-lock ()
 429   "Unconditionally turn on Fast Lock mode."
 430   (fast-lock-mode t))
 431 \f
 432 ;;; API Functions:
 433
 434 (defun fast-lock-after-fontify-buffer ()
 435   ;; Delete the Font Lock cache file used to restore fontification, if any.
 436   (when fast-lock-cache-filename
 437     (if (file-writable-p fast-lock-cache-filename)
 438         (delete-file fast-lock-cache-filename)
 439       (message "File %s font lock cache cannot be deleted" (buffer-name))))
 440   ;; Flag so that a cache will be saved later even if the file is never saved.
 441   (setq fast-lock-cache-timestamp nil))
 442
 443 (defalias 'fast-lock-after-unfontify-buffer
 444   'ignore)
 445 \f
 446 ;; Miscellaneous Functions:
 447
 448 (defun fast-lock-save-cache-after-save-file ()
 449   ;; Do `fast-lock-save-cache' if `save-buffer' is on `fast-lock-save-events'.
 450   (when (memq 'save-buffer fast-lock-save-events)
 451     (fast-lock-save-cache)))
 452
 453 (defun fast-lock-save-cache-before-kill-buffer ()
 454   ;; Do `fast-lock-save-cache' if `kill-buffer' is on `fast-lock-save-events'.
 455   (when (memq 'kill-buffer fast-lock-save-events)
 456     (fast-lock-save-cache)))
 457
 458 (defun fast-lock-save-caches-before-kill-emacs ()
 459   ;; Do `fast-lock-save-cache's if `kill-emacs' is on `fast-lock-save-events'.
 460   (when (memq 'kill-emacs fast-lock-save-events)
 461     (mapcar 'fast-lock-save-cache (buffer-list))))
 462
 463 (defun fast-lock-cache-directory (directory create)
 464   "Return usable directory based on DIRECTORY.
 465 Returns nil if the directory does not exist, or, if CREATE non-nil, cannot be
 466 created.  DIRECTORY may be a string or a cons pair of the form (REGEXP . DIR).
 467 See `fast-lock-cache-directories'."
 468   (let ((dir
 469          (cond ((not buffer-file-name)
 470                 ;; Should never be nil, but `crypt++' screws it up.
 471                 nil)
 472                ((stringp directory)
 473                 ;; Just a directory.
 474                 directory)
 475                (t
 476                 ;; A directory iff the file name matches the regexp.
 477                 (let ((bufile (expand-file-name buffer-file-truename))
 478                       (case-fold-search nil))
 479                   (when (save-match-data (string-match (car directory) bufile))
 480                     (cdr directory)))))))
 481     (cond ((not dir)
 482            nil)
 483           ((file-accessible-directory-p dir)
 484            dir)
 485           (create
 486            (condition-case nil
 487                (progn (make-directory dir t) dir)
 488              (error nil))))))
 489
 490 ;; If you are wondering why we only hash if the directory is not ".", rather
 491 ;; than if `file-name-absolute-p', it is because if we just appended ".flc" for
 492 ;; relative cache directories (that are not ".") then it is possible that more
 493 ;; than one file would have the same cache name in that directory, if the luser
 494 ;; made a link from one relative cache directory to another.  (Phew!)
 495 (defun fast-lock-cache-name (directory)
 496   "Return full cache path name using caching DIRECTORY.
 497 If DIRECTORY is `.', the path is the buffer file name appended with `.flc'.
 498 Otherwise, the path name is constructed from DIRECTORY and the buffer's true
 499 abbreviated file name, with all `/' characters in the name replaced with `#'
 500 characters, and appended with `.flc'.
 501
 502 If the same file has different cache path names when edited on different
 503 machines, e.g., on one machine the cache file name has the prefix `#home',
 504 perhaps due to automount, try putting in your `~/.emacs' something like:
 505
 506  (setq directory-abbrev-alist (cons '(\"^/home/\" . \"/\") directory-abbrev-alist))
 507
 508 Emacs automagically removes the common `/tmp_mnt' automount prefix by default.
 509
 510 See `fast-lock-cache-directory'."
 511   (if (string-equal directory ".")
 512       (concat buffer-file-name ".flc")
 513     (let* ((bufile (expand-file-name buffer-file-truename))
 514            (chars-alist
 515             (if (eq system-type 'emx)
 516                 '((?/ . (?#)) (?# . (?# ?#)) (?: . (?\;)) (?\; . (?\; ?\;)))
 517               '((?/ . (?#)) (?# . (?# ?#)))))
 518            (mapchars
 519             (function (lambda (c) (or (cdr (assq c chars-alist)) (list c))))))
 520       (concat
 521        (file-name-as-directory (expand-file-name directory))
 522        (mapconcat 'char-to-string (apply 'append (mapcar mapchars bufile)) "")
 523        ".flc"))))
 524 \f
 525 ;; Font Lock Cache Processing Functions:
 526
 527 (defun fast-lock-save-cache-1 (file timestamp)
 528   ;; Save the FILE with the TIMESTAMP as:
 529   ;; (fast-lock-cache-data Version=2 TIMESTAMP font-lock-keywords PROPERTIES).
 530   ;; Returns non-nil if a save was attempted to a writable cache file.
 531   (let ((tpbuf (generate-new-buffer " *fast-lock*"))
 532         (verbose (if (numberp fast-lock-verbose)
 533                      (> (buffer-size) fast-lock-verbose)
 534                    fast-lock-verbose))
 535         (saved t))
 536     (if verbose (message "Saving %s font lock cache..." (buffer-name)))
 537     (condition-case nil
 538         (save-excursion
 539           (print (list 'fast-lock-cache-data 2
 540                        (list 'quote timestamp)
 541                        (list 'quote font-lock-keywords)
 542                        (list 'quote (fast-lock-get-face-properties)))
 543                  tpbuf)
 544           (set-buffer tpbuf)
 545           (write-region (point-min) (point-max) file nil 'quietly)
 546           (setq fast-lock-cache-timestamp timestamp
 547                 fast-lock-cache-filename file))
 548       (error (setq saved 'error)) (quit (setq saved 'quit)))
 549     (kill-buffer tpbuf)
 550     (if verbose (message "Saving %s font lock cache...%s" (buffer-name)
 551                          (cond ((eq saved 'error) "failed")
 552                                ((eq saved 'quit) "aborted")
 553                                (t "done"))))
 554     ;; We return non-nil regardless of whether a failure occurred.
 555     saved))
 556
 557 (defun fast-lock-cache-data (version timestamp keywords properties
 558                              &rest ignored)
 559   ;; Change from (HIGH LOW) for back compatibility.  Remove for version 3!
 560   (when (consp (cdr-safe timestamp))
 561     (setcdr timestamp (nth 1 timestamp)))
 562   ;; Compile KEYWORDS and `font-lock-keywords' in case one is and one isn't.
 563   (let ((current font-lock-keywords))
 564     (setq keywords (font-lock-compile-keywords keywords)
 565           font-lock-keywords (font-lock-compile-keywords current)))
 566   ;; Use the Font Lock cache PROPERTIES if we're using cache VERSION format 2,
 567   ;; the current buffer's file timestamp matches the TIMESTAMP, and the current
 568   ;; buffer's font-lock-keywords are the same as KEYWORDS.
 569   (let ((buf-timestamp (visited-file-modtime))
 570         (verbose (if (numberp fast-lock-verbose)
 571                      (> (buffer-size) fast-lock-verbose)
 572                    fast-lock-verbose))
 573         (loaded t))
 574     (if (or (/= version 2)
 575             (buffer-modified-p)
 576             (not (equal timestamp buf-timestamp))
 577             (not (equal keywords font-lock-keywords)))
 578         (setq loaded nil)
 579       (if verbose (message "Loading %s font lock cache..." (buffer-name)))
 580       (condition-case nil
 581           (fast-lock-set-face-properties properties)
 582         (error (setq loaded 'error)) (quit (setq loaded 'quit)))
 583       (if verbose (message "Loading %s font lock cache...%s" (buffer-name)
 584                            (cond ((eq loaded 'error) "failed")
 585                                  ((eq loaded 'quit) "aborted")
 586                                  (t "done")))))
 587     (setq font-lock-fontified (eq loaded t)
 588           fast-lock-cache-timestamp (and (eq loaded t) timestamp))))
 589 \f
 590 ;; Text Properties Processing Functions:
 591
 592 ;; This is fast, but fails if adjacent characters have different `face' text
 593 ;; properties.  Maybe that's why I dropped it in the first place?
 594 ;(defun fast-lock-get-face-properties ()
 595 ;  "Return a list of all `face' text properties in the current buffer.
 596 ;Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 597 ;where VALUE is a `face' property value and STARTx and ENDx are positions."
 598 ;  (save-restriction
 599 ;    (widen)
 600 ;    (let ((start (text-property-not-all (point-min) (point-max) 'face nil))
 601 ;         (limit (point-max)) end properties value cell)
 602 ;      (while start
 603 ;       (setq end (next-single-property-change start 'face nil limit)
 604 ;             value (get-text-property start 'face))
 605 ;       ;; Make, or add to existing, list of regions with same `face'.
 606 ;       (if (setq cell (assq value properties))
 607 ;           (setcdr cell (cons start (cons end (cdr cell))))
 608 ;         (setq properties (cons (list value start end) properties)))
 609 ;       (setq start (next-single-property-change end 'face)))
 610 ;      properties)))
 611
 612 ;; This is slow, but copes if adjacent characters have different `face' text
 613 ;; properties, but fails if they are lists.
 614 ;(defun fast-lock-get-face-properties ()
 615 ;  "Return a list of all `face' text properties in the current buffer.
 616 ;Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 617 ;where VALUE is a `face' property value and STARTx and ENDx are positions.
 618 ;Only those `face' VALUEs in `fast-lock-save-faces' are returned."
 619 ;  (save-restriction
 620 ;    (widen)
 621 ;    (let ((faces (or fast-lock-save-faces (face-list))) (limit (point-max))
 622 ;         properties regions face start end)
 623 ;      (while faces
 624 ;       (setq face (car faces) faces (cdr faces) regions () end (point-min))
 625 ;       ;; Make a list of start/end regions with `face' property face.
 626 ;       (while (setq start (text-property-any end limit 'face face))
 627 ;         (setq end (or (text-property-not-all start limit 'face face) limit)
 628 ;               regions (cons start (cons end regions))))
 629 ;       ;; Add `face' face's regions, if any, to properties.
 630 ;       (when regions
 631 ;         (push (cons face regions) properties)))
 632 ;      properties)))
 633
 634 (defun fast-lock-get-face-properties ()
 635   "Return a list of all `face' text properties in the current buffer.
 636 Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 637 where VALUE is a `face' property value and STARTx and ENDx are positions."
 638   (save-restriction
 639     (widen)
 640     (let ((start (text-property-not-all (point-min) (point-max) 'face nil))
 641           end properties value cell)
 642       (while start
 643         (setq end (next-single-property-change start 'face nil (point-max))
 644               value (get-text-property start 'face))
 645         ;; Make, or add to existing, list of regions with same `face'.
 646         (cond ((setq cell (assoc value properties))
 647                (setcdr cell (cons start (cons end (cdr cell)))))
 648               ((fast-lock-save-facep value)
 649                (push (list value start end) properties)))
 650         (setq start (text-property-not-all end (point-max) 'face nil)))
 651       properties)))
 652
 653 (defun fast-lock-set-face-properties (properties)
 654   "Set all `face' text properties to PROPERTIES in the current buffer.
 655 Any existing `face' text properties are removed first.
 656 See `fast-lock-get-face-properties' for the format of PROPERTIES."
 657   (save-buffer-state (plist regions)
 658     (save-restriction
 659       (widen)
 660       (font-lock-unfontify-region (point-min) (point-max))
 661       (while properties
 662         (setq plist (list 'face (car (car properties)))
 663               regions (cdr (car properties))
 664               properties (cdr properties))
 665         ;; Set the `face' property for each start/end region.
 666         (while regions
 667           (set-text-properties (nth 0 regions) (nth 1 regions) plist)
 668           (setq regions (nthcdr 2 regions)))))))
 669 \f
 670 ;; Functions for XEmacs:
 671
 672 (when (save-match-data (string-match "XEmacs" (emacs-version)))
 673   ;;
 674   ;; It would be better to use XEmacs' `map-extents' over extents with a
 675   ;; `font-lock' property, but `face' properties are on different extents.
 676   (defun fast-lock-get-face-properties ()
 677     "Return a list of all `face' text properties in the current buffer.
 678 Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 679 where VALUE is a `face' property value and STARTx and ENDx are positions.
 680 Only those `face' VALUEs in `fast-lock-save-faces' are returned."
 681     (save-restriction
 682       (widen)
 683       (let ((properties ()) cell)
 684         (map-extents
 685          (function (lambda (extent ignore)
 686             (let ((value (extent-face extent)))
 687               ;; We're only interested if it's one of `fast-lock-save-faces'.
 688               (when (and value (fast-lock-save-facep value))
 689                 (let ((start (extent-start-position extent))
 690                       (end (extent-end-position extent)))
 691                   ;; Make or add to existing list of regions with the same
 692                   ;; `face' property value.
 693                   (if (setq cell (assoc value properties))
 694                       (setcdr cell (cons start (cons end (cdr cell))))
 695                     (push (list value start end) properties))))
 696               ;; Return nil to keep `map-extents' going.
 697               nil))))
 698         properties)))
 699   ;;
 700   ;; Make extents just like XEmacs' font-lock.el does.
 701   (defun fast-lock-set-face-properties (properties)
 702     "Set all `face' text properties to PROPERTIES in the current buffer.
 703 Any existing `face' text properties are removed first.
 704 See `fast-lock-get-face-properties' for the format of PROPERTIES."
 705     (save-restriction
 706       (widen)
 707       (font-lock-unfontify-region (point-min) (point-max))
 708       (while properties
 709         (let ((face (car (car properties)))
 710               (regions (cdr (car properties))))
 711           ;; Set the `face' property, etc., for each start/end region.
 712           (while regions
 713             (font-lock-set-face (nth 0 regions) (nth 1 regions) face)
 714             (setq regions (nthcdr 2 regions)))
 715           (setq properties (cdr properties))))))
 716   ;;
 717   ;; XEmacs 19.12 font-lock.el's `font-lock-fontify-buffer' runs a hook.
 718   (add-hook 'font-lock-after-fontify-buffer-hook
 719             'fast-lock-after-fontify-buffer))
 720
 721 (unless (boundp 'font-lock-inhibit-thing-lock)
 722   (defvar font-lock-inhibit-thing-lock nil
 723     "List of Font Lock mode related modes that should not be turned on."))
 724
 725 (unless (fboundp 'font-lock-value-in-major-mode)
 726   (defun font-lock-value-in-major-mode (alist)
 727     ;; Return value in ALIST for `major-mode'.
 728     (if (consp alist)
 729         (cdr (or (assq major-mode alist) (assq t alist)))
 730       alist)))
 731
 732 (unless (fboundp 'font-lock-compile-keywords)
 733   (defalias 'font-lock-compile-keywords 'identity))
 734 \f
 735 ;; Install ourselves:
 736
 737 (add-hook 'after-save-hook 'fast-lock-save-cache-after-save-file)
 738 (add-hook 'kill-buffer-hook 'fast-lock-save-cache-before-kill-buffer)
 739 (add-hook 'kill-emacs-hook 'fast-lock-save-caches-before-kill-emacs)
 740
 741 ;;;###autoload
 742 (if (fboundp 'add-minor-mode) (add-minor-mode 'fast-lock-mode nil))
 743 ;;;###dont-autoload
 744 (unless (assq 'fast-lock-mode minor-mode-alist)
 745   (setq minor-mode-alist (append minor-mode-alist '((fast-lock-mode nil)))))
 746
 747 ;; Provide ourselves:
 748
 749 (provide 'fast-lock)
 750
 751 ;;; fast-lock.el ends here