lisp/complete.el

   1 ;;; complete.el --- partial completion mechanism plus other goodies
   2
   3 ;; Copyright (C) 1990, 1991, 1992, 1993, 1999, 2000
   4 ;;  Free Software Foundation, Inc.
   5
   6 ;; Author: Dave Gillespie <daveg@synaptics.com>
   7 ;; Keywords: abbrev convenience
   8 ;; Special thanks to Hallvard Furuseth for his many ideas and contributions.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Extended completion for the Emacs minibuffer.
  30 ;;
  31 ;; The basic idea is that the command name or other completable text is
  32 ;; divided into words and each word is completed separately, so that
  33 ;; "M-x p-b" expands to "M-x print-buffer".  If the entry is ambiguous
  34 ;; each word is completed as much as possible and then the cursor is
  35 ;; left at the first position where typing another letter will resolve
  36 ;; the ambiguity.
  37 ;;
  38 ;; Word separators for this purpose are hyphen, space, and period.
  39 ;; These would most likely occur in command names, Info menu items,
  40 ;; and file names, respectively.  But all word separators are treated
  41 ;; alike at all times.
  42 ;;
  43 ;; This completion package replaces the old-style completer's key
  44 ;; bindings for TAB, SPC, RET, and `?'.  The old completer is still
  45 ;; available on the Meta versions of those keys.  If you set
  46 ;; PC-meta-flag to nil, the old completion keys will be left alone
  47 ;; and the partial completer will use the Meta versions of the keys.
  48
  49
  50 ;; Usage:  M-x partial-completion-mode.  During completable minibuffer entry,
  51 ;;
  52 ;;     TAB    means to do a partial completion;
  53 ;;     SPC    means to do a partial complete-word;
  54 ;;     RET    means to do a partial complete-and-exit;
  55 ;;     ?      means to do a partial completion-help.
  56 ;;
  57 ;; If you set PC-meta-flag to nil, then TAB, SPC, RET, and ? perform
  58 ;; original Emacs completions, and M-TAB etc. do partial completion.
  59 ;; To do this, put the command,
  60 ;;
  61 ;;       (setq PC-meta-flag nil)
  62 ;;
  63 ;; in your .emacs file.  To load partial completion automatically, put
  64 ;;
  65 ;;       (partial-completion-mode t)
  66 ;;
  67 ;; in your .emacs file, too.  Things will be faster if you byte-compile
  68 ;; this file when you install it.
  69 ;;
  70 ;; As an extra feature, in cases where RET would not normally
  71 ;; complete (such as `C-x b'), the M-RET key will always do a partial
  72 ;; complete-and-exit.  Thus `C-x b f.c RET' will select or create a
  73 ;; buffer called "f.c", but `C-x b f.c M-RET' will select the existing
  74 ;; buffer whose name matches that pattern (perhaps "filing.c").
  75 ;; (PC-meta-flag does not affect this behavior; M-RET used to be
  76 ;; undefined in this situation.)
  77 ;;
  78 ;; The regular M-TAB (lisp-complete-symbol) command also supports
  79 ;; partial completion in this package.
  80
  81 ;; In addition, this package includes a feature for accessing include
  82 ;; files.  For example, `C-x C-f <sys/time.h> RET' reads the file
  83 ;; /usr/include/sys/time.h.  The variable PC-include-file-path is a
  84 ;; list of directories in which to search for include files.  Completion
  85 ;; is supported in include file names.
  86
  87
  88 ;;; Code:
  89
  90 (defgroup partial-completion nil
  91   "Partial Completion of items."
  92   :prefix "pc-"
  93   :group 'minibuffer
  94   :group 'convenience)
  95
  96 (defcustom PC-first-char 'find-file
  97   "*Control how the first character of a string is to be interpreted.
  98 If nil, the first character of a string is not taken literally if it is a word
  99 delimiter, so that \".e\" matches \"*.e*\".
 100 If t, the first character of a string is always taken literally even if it is a
 101 word delimiter, so that \".e\" matches \".e*\".
 102 If non-nil and non-t, the first character is taken literally only for file name
 103 completion."
 104   :type '(choice (const :tag "delimiter" nil)
 105                  (const :tag "literal" t)
 106                  (other :tag "find-file" find-file))
 107   :group 'partial-completion)
 108
 109 (defcustom PC-meta-flag t
 110   "*If non-nil, TAB means PC completion and M-TAB means normal completion.
 111 Otherwise, TAB means normal completion and M-TAB means Partial Completion."
 112   :type 'boolean
 113   :group 'partial-completion)
 114
 115 (defcustom PC-word-delimiters "-_. "
 116   "*A string of characters treated as word delimiters for completion.
 117 Some arcane rules:
 118 If `]' is in this string, it must come first.
 119 If `^' is in this string, it must not come first.
 120 If `-' is in this string, it must come first or right after `]'.
 121 In other words, if S is this string, then `[S]' must be a legal Emacs regular
 122 expression (not containing character ranges like `a-z')."
 123   :type 'string
 124   :group 'partial-completion)
 125
 126 (defcustom PC-include-file-path '("/usr/include" "/usr/local/include")
 127   "*A list of directories in which to look for include files.
 128 If nil, means use the colon-separated path in the variable $INCPATH instead."
 129   :type '(repeat directory)
 130   :group 'partial-completion)
 131
 132 (defcustom PC-disable-includes nil
 133   "*If non-nil, include-file support in \\[find-file] is disabled."
 134   :type 'boolean
 135   :group 'partial-completion)
 136
 137 (defvar PC-default-bindings t
 138   "If non-nil, default partial completion key bindings are suppressed.")
 139
 140 (defvar PC-env-vars-alist nil
 141   "A list of the environment variable names and values.")
 142
 143 \f
 144 (defvar PC-old-read-file-name-internal nil)
 145
 146 (defun PC-bindings (bind)
 147   (let ((completion-map minibuffer-local-completion-map)
 148         (must-match-map minibuffer-local-must-match-map))
 149     (cond ((not bind)
 150            ;; These bindings are the default bindings.  It would be better to
 151            ;; restore the previous bindings.
 152            (define-key completion-map "\t"      'minibuffer-complete)
 153            (define-key completion-map " "       'minibuffer-complete-word)
 154            (define-key completion-map "?"       'minibuffer-completion-help)
 155
 156            (define-key must-match-map "\t"      'minibuffer-complete)
 157            (define-key must-match-map " "       'minibuffer-complete-word)
 158            (define-key must-match-map "\r"      'minibuffer-complete-and-exit)
 159            (define-key must-match-map "\n"      'minibuffer-complete-and-exit)
 160            (define-key must-match-map "?"       'minibuffer-completion-help)
 161
 162            (define-key global-map "\e\t"        'complete-symbol))
 163           (PC-default-bindings
 164            (define-key completion-map "\t"      'PC-complete)
 165            (define-key completion-map " "       'PC-complete-word)
 166            (define-key completion-map "?"       'PC-completion-help)
 167
 168            (define-key completion-map "\e\t"    'PC-complete)
 169            (define-key completion-map "\e "     'PC-complete-word)
 170            (define-key completion-map "\e\r"    'PC-force-complete-and-exit)
 171            (define-key completion-map "\e\n"    'PC-force-complete-and-exit)
 172            (define-key completion-map "\e?"     'PC-completion-help)
 173
 174            (define-key must-match-map "\t"      'PC-complete)
 175            (define-key must-match-map " "       'PC-complete-word)
 176            (define-key must-match-map "\r"      'PC-complete-and-exit)
 177            (define-key must-match-map "\n"      'PC-complete-and-exit)
 178            (define-key must-match-map "?"       'PC-completion-help)
 179
 180            (define-key must-match-map "\e\t"    'PC-complete)
 181            (define-key must-match-map "\e "     'PC-complete-word)
 182            (define-key must-match-map "\e\r"    'PC-complete-and-exit)
 183            (define-key must-match-map "\e\n"    'PC-complete-and-exit)
 184            (define-key must-match-map "\e?"     'PC-completion-help)
 185
 186            (define-key global-map "\e\t"        'PC-lisp-complete-symbol)))))
 187
 188 ;;;###autoload
 189 (define-minor-mode partial-completion-mode
 190   "Toggle Partial Completion mode.
 191 With prefix ARG, turn Partial Completion mode on if ARG is positive.
 192
 193 When Partial Completion mode is enabled, TAB (or M-TAB if `PC-meta-flag' is
 194 nil) is enhanced so that if some string is divided into words and each word is
 195 delimited by a character in `PC-word-delimiters', partial words are completed
 196 as much as possible and `*' characters are treated likewise in file names.
 197
 198 For example, M-x p-c-m expands to M-x partial-completion-mode since no other
 199 command begins with that sequence of characters, and
 200 \\[find-file] f_b.c TAB might complete to foo_bar.c if that file existed and no
 201 other file in that directory begin with that sequence of characters.
 202
 203 Unless `PC-disable-includes' is non-nil, the `<...>' sequence is interpreted
 204 specially in \\[find-file].  For example,
 205 \\[find-file] <sys/time.h> RET finds the file `/usr/include/sys/time.h'.
 206 See also the variable `PC-include-file-path'."
 207   :global t :group 'partial-completion
 208   ;; Deal with key bindings...
 209   (PC-bindings partial-completion-mode)
 210   ;; Deal with include file feature...
 211   (cond ((not partial-completion-mode)
 212          (remove-hook 'find-file-not-found-hooks 'PC-look-for-include-file))
 213         ((not PC-disable-includes)
 214          (add-hook 'find-file-not-found-hooks 'PC-look-for-include-file)))
 215   ;; ... with some underhand redefining.
 216   (cond ((and (not partial-completion-mode)
 217               (functionp PC-old-read-file-name-internal))
 218          (fset 'read-file-name-internal PC-old-read-file-name-internal))
 219         ((and (not PC-disable-includes) (not PC-old-read-file-name-internal))
 220          (setq PC-old-read-file-name-internal
 221                (symbol-function 'read-file-name-internal))
 222          (fset 'read-file-name-internal
 223                'PC-read-include-file-name-internal)))
 224     (when (and partial-completion-mode (null PC-env-vars-alist))
 225       (setq PC-env-vars-alist
 226             (mapcar (lambda (string)
 227                       (let ((d (string-match "=" string)))
 228                         (cons (concat "$" (substring string 0 d))
 229                               (and d (substring string (1+ d))))))
 230                     process-environment))))
 231
 232 \f
 233 (defun PC-complete ()
 234   "Like minibuffer-complete, but allows \"b--di\"-style abbreviations.
 235 For example, \"M-x b--di\" would match `byte-recompile-directory', or any
 236 name which consists of three or more words, the first beginning with \"b\"
 237 and the third beginning with \"di\".
 238
 239 The pattern \"b--d\" is ambiguous for `byte-recompile-directory' and
 240 `beginning-of-defun', so this would produce a list of completions
 241 just like when normal Emacs completions are ambiguous.
 242
 243 Word-delimiters for the purposes of Partial Completion are \"-\", \"_\",
 244 \".\", and SPC."
 245   (interactive)
 246   (if (PC-was-meta-key)
 247       (minibuffer-complete)
 248     ;; If the previous command was not this one,
 249     ;; never scroll, always retry completion.
 250     (or (eq last-command this-command)
 251         (setq minibuffer-scroll-window nil))
 252     (let ((window minibuffer-scroll-window))
 253       ;; If there's a fresh completion window with a live buffer,
 254       ;; and this command is repeated, scroll that window.
 255       (if (and window (window-buffer window)
 256                (buffer-name (window-buffer window)))
 257           (save-excursion
 258             (set-buffer (window-buffer window))
 259             (if (pos-visible-in-window-p (point-max) window)
 260                 (set-window-start window (point-min) nil)
 261               (scroll-other-window)))
 262         (PC-do-completion nil)))))
 263
 264
 265 (defun PC-complete-word ()
 266   "Like `minibuffer-complete-word', but allows \"b--di\"-style abbreviations.
 267 See `PC-complete' for details.
 268 This can be bound to other keys, like `-' and `.', if you wish."
 269   (interactive)
 270   (if (eq (PC-was-meta-key) PC-meta-flag)
 271       (if (eq last-command-char ? )
 272           (minibuffer-complete-word)
 273         (self-insert-command 1))
 274     (self-insert-command 1)
 275     (if (eobp)
 276         (PC-do-completion 'word))))
 277
 278
 279 (defun PC-complete-space ()
 280   "Like `minibuffer-complete-word', but allows \"b--di\"-style abbreviations.
 281 See `PC-complete' for details.
 282 This is suitable for binding to other keys which should act just like SPC."
 283   (interactive)
 284   (if (eq (PC-was-meta-key) PC-meta-flag)
 285       (minibuffer-complete-word)
 286     (insert " ")
 287     (if (eobp)
 288         (PC-do-completion 'word))))
 289
 290
 291 (defun PC-complete-and-exit ()
 292   "Like `minibuffer-complete-and-exit', but allows \"b--di\"-style abbreviations.
 293 See `PC-complete' for details."
 294   (interactive)
 295   (if (eq (PC-was-meta-key) PC-meta-flag)
 296       (minibuffer-complete-and-exit)
 297     (PC-do-complete-and-exit)))
 298
 299 (defun PC-force-complete-and-exit ()
 300   "Like `minibuffer-complete-and-exit', but allows \"b--di\"-style abbreviations.
 301 See `PC-complete' for details."
 302   (interactive)
 303   (let ((minibuffer-completion-confirm nil))
 304     (PC-do-complete-and-exit)))
 305
 306 (defun PC-do-complete-and-exit ()
 307   (if (= (point-max) (minibuffer-prompt-end))  ; Duplicate the "bug" that Info-menu relies on...
 308       (exit-minibuffer)
 309     (let ((flag (PC-do-completion 'exit)))
 310       (and flag
 311            (if (or (eq flag 'complete)
 312                    (not minibuffer-completion-confirm))
 313                (exit-minibuffer)
 314              (PC-temp-minibuffer-message " [Confirm]"))))))
 315
 316
 317 (defun PC-completion-help ()
 318   "Like `minibuffer-completion-help', but allows \"b--di\"-style abbreviations.
 319 See `PC-complete' for details."
 320   (interactive)
 321   (if (eq (PC-was-meta-key) PC-meta-flag)
 322       (minibuffer-completion-help)
 323     (PC-do-completion 'help)))
 324
 325 (defun PC-was-meta-key ()
 326   (or (/= (length (this-command-keys)) 1)
 327       (let ((key (aref (this-command-keys) 0)))
 328         (if (integerp key)
 329             (>= key 128)
 330           (not (null (memq 'meta (event-modifiers key))))))))
 331
 332
 333 (defvar PC-ignored-extensions 'empty-cache)
 334 (defvar PC-delims 'empty-cache)
 335 (defvar PC-ignored-regexp nil)
 336 (defvar PC-word-failed-flag nil)
 337 (defvar PC-delim-regex nil)
 338 (defvar PC-ndelims-regex nil)
 339 (defvar PC-delims-list nil)
 340
 341 (defvar PC-completion-as-file-name-predicate
 342   (function
 343    (lambda ()
 344      (memq minibuffer-completion-table
 345            '(read-file-name-internal read-directory-name-internal))))
 346    "A function testing whether a minibuffer completion now will work filename-style.
 347 The function takes no arguments, and typically looks at the value
 348 of `minibuffer-completion-table' and the minibuffer contents.")
 349
 350 (defun PC-do-completion (&optional mode beg end)
 351   (or beg (setq beg (minibuffer-prompt-end)))
 352   (or end (setq end (point-max)))
 353   (let* ((table minibuffer-completion-table)
 354          (pred minibuffer-completion-predicate)
 355          (filename (funcall PC-completion-as-file-name-predicate))
 356          (dirname nil)
 357          (dirlength 0)
 358          (str (buffer-substring beg end))
 359          (incname (and filename (string-match "<\\([^\"<>]*\\)>?$" str)))
 360          (ambig nil)
 361          basestr
 362          env-on
 363          regex
 364          p offset
 365          (poss nil)
 366          helpposs
 367          (case-fold-search completion-ignore-case))
 368
 369     ;; Check if buffer contents can already be considered complete
 370     (if (and (eq mode 'exit)
 371              (PC-is-complete-p str table pred))
 372         'complete
 373
 374       ;; Do substitutions in directory names
 375       (and filename
 376            (setq basestr (or (file-name-directory str) ""))
 377            (setq dirlength (length basestr))
 378            ;; Do substitutions in directory names
 379            (setq p (substitute-in-file-name basestr))
 380            (not (string-equal basestr p))
 381            (setq str (concat p (file-name-nondirectory str)))
 382            (progn
 383              (delete-region beg end)
 384              (insert str)
 385              (setq end (+ beg (length str)))))
 386
 387       ;; Prepare various delimiter strings
 388       (or (equal PC-word-delimiters PC-delims)
 389           (setq PC-delims PC-word-delimiters
 390                 PC-delim-regex (concat "[" PC-delims "]")
 391                 PC-ndelims-regex (concat "[^" PC-delims "]*")
 392                 PC-delims-list (append PC-delims nil)))
 393
 394       ;; Add wildcards if necessary
 395       (let ((dir (file-name-directory str))
 396             (file (file-name-nondirectory str)))
 397         (while (and (stringp dir) (not (file-directory-p dir)))
 398           (setq dir (directory-file-name dir))
 399           (setq file (concat (replace-regexp-in-string
 400                               PC-delim-regex "*\\&"
 401                               (file-name-nondirectory dir))
 402                              "*/" file))
 403           (setq dir (file-name-directory dir)))
 404         (setq str (concat dir file)))
 405
 406       ;; Look for wildcard expansions in directory name
 407       (and filename
 408            (string-match "\\*.*/" str)
 409            (let ((pat str)
 410                  files)
 411              (setq p (1+ (string-match "/[^/]*\\'" pat)))
 412              (while (setq p (string-match PC-delim-regex pat p))
 413                (setq pat (concat (substring pat 0 p)
 414                                  "*"
 415                                  (substring pat p))
 416                      p (+ p 2)))
 417              (setq files (PC-expand-many-files (concat pat "*")))
 418              (if files
 419                  (let ((dir (file-name-directory (car files)))
 420                        (p files))
 421                    (while (and (setq p (cdr p))
 422                                (equal dir (file-name-directory (car p)))))
 423                    (if p
 424                        (setq filename nil table nil pred nil
 425                              ambig t)
 426                      (delete-region beg end)
 427                      (setq str (concat dir (file-name-nondirectory str)))
 428                      (insert str)
 429                      (setq end (+ beg (length str)))))
 430                (setq filename nil table nil pred nil))))
 431
 432       ;; Strip directory name if appropriate
 433       (if filename
 434           (if incname
 435               (setq basestr (substring str incname)
 436                     dirname (substring str 0 incname))
 437             (setq basestr (file-name-nondirectory str)
 438                   dirname (file-name-directory str))
 439             ;; Make sure str is consistent with its directory and basename
 440             ;; parts.  This is important on DOZe'NT systems when str only
 441             ;; includes a drive letter, like in "d:".
 442             (setq str (concat dirname basestr)))
 443         (setq basestr str))
 444
 445       ;; Convert search pattern to a standard regular expression
 446       (setq regex (regexp-quote basestr)
 447             offset (if (and (> (length regex) 0)
 448                             (not (eq (aref basestr 0) ?\*))
 449                             (or (eq PC-first-char t)
 450                                 (and PC-first-char filename))) 1 0)
 451             p offset)
 452       (while (setq p (string-match PC-delim-regex regex p))
 453         (if (eq (aref regex p) ? )
 454             (setq regex (concat (substring regex 0 p)
 455                                 PC-ndelims-regex
 456                                 PC-delim-regex
 457                                 (substring regex (1+ p)))
 458                   p (+ p (length PC-ndelims-regex) (length PC-delim-regex)))
 459           (let ((bump (if (memq (aref regex p)
 460                                 '(?$ ?^ ?\. ?* ?+ ?? ?[ ?] ?\\))
 461                           -1 0)))
 462             (setq regex (concat (substring regex 0 (+ p bump))
 463                                 PC-ndelims-regex
 464                                 (substring regex (+ p bump)))
 465                   p (+ p (length PC-ndelims-regex) 1)))))
 466       (setq p 0)
 467       (if filename
 468           (while (setq p (string-match "\\\\\\*" regex p))
 469             (setq regex (concat (substring regex 0 p)
 470                                 "[^/]*"
 471                                 (substring regex (+ p 2))))))
 472       ;;(setq the-regex regex)
 473       (setq regex (concat "\\`" regex))
 474
 475       (and (> (length basestr) 0)
 476            (= (aref basestr 0) ?$)
 477            (setq env-on t
 478                  table PC-env-vars-alist
 479                  pred nil))
 480
 481       ;; Find an initial list of possible completions
 482       (if (not (setq p (string-match (concat PC-delim-regex
 483                                              (if filename "\\|\\*" ""))
 484                                      str
 485                                      (+ (length dirname) offset))))
 486
 487           ;; Minibuffer contains no hyphens -- simple case!
 488           (setq poss (all-completions (if env-on
 489                                           basestr str)
 490                                       table
 491                                       pred))
 492
 493         ;; Use all-completions to do an initial cull.  This is a big win,
 494         ;; since all-completions is written in C!
 495         (let ((compl (all-completions (if env-on
 496                                           (file-name-nondirectory (substring str 0 p))
 497                                         (substring str 0 p))
 498                                         table
 499                                         pred)))
 500           (setq p compl)
 501           (while p
 502             (and (string-match regex (car p))
 503                  (progn
 504                    (set-text-properties 0 (length (car p)) '() (car p))
 505                    (setq poss (cons (car p) poss))))
 506             (setq p (cdr p)))))
 507
 508       ;; Now we have a list of possible completions
 509       (cond
 510
 511        ;; No valid completions found
 512        ((null poss)
 513         (if (and (eq mode 'word)
 514                  (not PC-word-failed-flag))
 515             (let ((PC-word-failed-flag t))
 516               (delete-backward-char 1)
 517               (PC-do-completion 'word))
 518           (beep)
 519           (PC-temp-minibuffer-message (if ambig
 520                                           " [Ambiguous dir name]"
 521                                         (if (eq mode 'help)
 522                                             " [No completions]"
 523                                           " [No match]")))
 524           nil))
 525
 526        ;; More than one valid completion found
 527        ((or (cdr (setq helpposs poss))
 528             (memq mode '(help word)))
 529
 530         ;; Handle completion-ignored-extensions
 531         (and filename
 532              (not (eq mode 'help))
 533              (let ((p2 poss))
 534
 535                ;; Build a regular expression representing the extensions list
 536                (or (equal completion-ignored-extensions PC-ignored-extensions)
 537                    (setq PC-ignored-regexp
 538                          (concat "\\("
 539                                  (mapconcat
 540                                   'regexp-quote
 541                                   (setq PC-ignored-extensions
 542                                         completion-ignored-extensions)
 543                                   "\\|")
 544                                  "\\)\\'")))
 545
 546                ;; Check if there are any without an ignored extension.
 547                ;; Also ignore `.' and `..'.
 548                (setq p nil)
 549                (while p2
 550                  (or (string-match PC-ignored-regexp (car p2))
 551                      (string-match "\\(\\`\\|/\\)[.][.]?/?\\'" (car p2))
 552                      (setq p (cons (car p2) p)))
 553                  (setq p2 (cdr p2)))
 554
 555                ;; If there are "good" names, use them
 556                (and p (setq poss p))))
 557
 558         ;; Is the actual string one of the possible completions?
 559         (setq p (and (not (eq mode 'help)) poss))
 560         (while (and p
 561                     (not (string-equal (car p) basestr)))
 562           (setq p (cdr p)))
 563         (and p (null mode)
 564              (PC-temp-minibuffer-message " [Complete, but not unique]"))
 565         (if (and p
 566                  (not (and (null mode)
 567                            (eq this-command last-command))))
 568             t
 569
 570           ;; If ambiguous, try for a partial completion
 571           (let ((improved nil)
 572                 prefix
 573                 (pt nil)
 574                 (skip "\\`"))
 575
 576             ;; Check if next few letters are the same in all cases
 577             (if (and (not (eq mode 'help))
 578                      (setq prefix (try-completion "" (mapcar 'list poss))))
 579                 (let ((first t) i)
 580                   (if (eq mode 'word)
 581                       (setq prefix (PC-chop-word prefix basestr)))
 582                   (goto-char (+ beg (length dirname)))
 583                   (while (and (progn
 584                                 (setq i 0)
 585                                 (while (< i (length prefix))
 586                                   (if (and (< (point) end)
 587                                            (eq (aref prefix i)
 588                                                (following-char)))
 589                                       (forward-char 1)
 590                                     (if (and (< (point) end)
 591                                              (or (and (looking-at " ")
 592                                                       (memq (aref prefix i)
 593                                                             PC-delims-list))
 594                                                  (eq (downcase (aref prefix i))
 595                                                      (downcase
 596                                                       (following-char)))))
 597                                         (progn
 598                                           (delete-char 1)
 599                                           (setq end (1- end)))
 600                                       (and filename (looking-at "\\*")
 601                                            (progn
 602                                              (delete-char 1)
 603                                              (setq end (1- end))))
 604                                       (setq improved t))
 605                                     (insert (substring prefix i (1+ i)))
 606                                     (setq end (1+ end)))
 607                                   (setq i (1+ i)))
 608                                 (or pt (equal (point) beg)
 609                                     (setq pt (point)))
 610                                 (looking-at PC-delim-regex))
 611                               (setq skip (concat skip
 612                                                  (regexp-quote prefix)
 613                                                  PC-ndelims-regex)
 614                                     prefix (try-completion
 615                                             ""
 616                                             (mapcar
 617                                              (function
 618                                               (lambda (x)
 619                                                 (list
 620                                                  (and (string-match skip x)
 621                                                       (substring
 622                                                        x
 623                                                        (match-end 0))))))
 624                                              poss)))
 625                               (or (> i 0) (> (length prefix) 0))
 626                               (or (not (eq mode 'word))
 627                                   (and first (> (length prefix) 0)
 628                                        (setq first nil
 629                                              prefix (substring prefix 0 1))))))
 630                   (goto-char (if (eq mode 'word) end
 631                                (or pt beg)))))
 632
 633             (if (and (eq mode 'word)
 634                      (not PC-word-failed-flag))
 635
 636                 (if improved
 637
 638                     ;; We changed it... would it be complete without the space?
 639                     (if (PC-is-complete-p (buffer-substring 1 (1- end))
 640                                           table pred)
 641                         (delete-region (1- end) end)))
 642
 643               (if improved
 644
 645                   ;; We changed it... enough to be complete?
 646                   (and (eq mode 'exit)
 647                        (PC-is-complete-p (field-string) table pred))
 648
 649                 ;; If totally ambiguous, display a list of completions
 650                 (if (or (eq completion-auto-help t)
 651                         (and completion-auto-help
 652                              (eq last-command this-command))
 653                         (eq mode 'help))
 654                     (with-output-to-temp-buffer "*Completions*"
 655                       (display-completion-list (sort helpposs 'string-lessp))
 656                       (save-excursion
 657                         (set-buffer standard-output)
 658                         ;; Record which part of the buffer we are completing
 659                         ;; so that choosing a completion from the list
 660                         ;; knows how much old text to replace.
 661                         (setq completion-base-size dirlength)))
 662                   (PC-temp-minibuffer-message " [Next char not unique]"))
 663                 nil)))))
 664
 665        ;; Only one possible completion
 666        (t
 667         (if (and (equal basestr (car poss))
 668                  (not (and env-on filename)))
 669             (if (null mode)
 670                 (PC-temp-minibuffer-message " [Sole completion]"))
 671           (delete-region beg end)
 672           (insert (format "%s"
 673                           (if filename
 674                               (substitute-in-file-name (concat dirname (car poss)))
 675                             (car poss)))))
 676         t)))))
 677
 678
 679 (defun PC-is-complete-p (str table pred)
 680   (let ((res (if (listp table)
 681                  (assoc str table)
 682                (if (vectorp table)
 683                    (or (equal str "nil")   ; heh, heh, heh
 684                        (intern-soft str table))
 685                  (funcall table str pred 'lambda)))))
 686     (and res
 687          (or (not pred)
 688              (and (not (listp table)) (not (vectorp table)))
 689              (funcall pred res))
 690          res)))
 691
 692 (defun PC-chop-word (new old)
 693   (let ((i -1)
 694         (j -1))
 695     (while (and (setq i (string-match PC-delim-regex old (1+ i)))
 696                 (setq j (string-match PC-delim-regex new (1+ j)))))
 697     (if (and j
 698              (or (not PC-word-failed-flag)
 699                  (setq j (string-match PC-delim-regex new (1+ j)))))
 700         (substring new 0 (1+ j))
 701       new)))
 702
 703 (defvar PC-not-minibuffer nil)
 704
 705 (defun PC-temp-minibuffer-message (message)
 706   "A Lisp version of `temp_minibuffer_message' from minibuf.c."
 707   (cond (PC-not-minibuffer
 708          (message message)
 709          (sit-for 2)
 710          (message ""))
 711         ((fboundp 'temp-minibuffer-message)
 712          (temp-minibuffer-message message))
 713         (t
 714          (let ((point-max (point-max)))
 715            (save-excursion
 716              (goto-char point-max)
 717              (insert message))
 718            (let ((inhibit-quit t))
 719              (sit-for 2)
 720              (delete-region point-max (point-max))
 721              (when quit-flag
 722                (setq quit-flag nil
 723                      unread-command-events '(7))))))))
 724
 725
 726 (defun PC-lisp-complete-symbol ()
 727   "Perform completion on Lisp symbol preceding point.
 728 That symbol is compared against the symbols that exist
 729 and any additional characters determined by what is there
 730 are inserted.
 731 If the symbol starts just after an open-parenthesis,
 732 only symbols with function definitions are considered.
 733 Otherwise, all symbols with function definitions, values
 734 or properties are considered."
 735   (interactive)
 736   (let* ((end (point))
 737          (buffer-syntax (syntax-table))
 738          (beg (unwind-protect
 739                   (save-excursion
 740                     (if lisp-mode-syntax-table
 741                         (set-syntax-table lisp-mode-syntax-table))
 742                     (backward-sexp 1)
 743                     (while (= (char-syntax (following-char)) ?\')
 744                       (forward-char 1))
 745                     (point))
 746                 (set-syntax-table buffer-syntax)))
 747          (minibuffer-completion-table obarray)
 748          (minibuffer-completion-predicate
 749           (if (eq (char-after (1- beg)) ?\()
 750               'fboundp
 751             (function (lambda (sym)
 752                         (or (boundp sym) (fboundp sym)
 753                             (symbol-plist sym))))))
 754          (PC-not-minibuffer t))
 755     (PC-do-completion nil beg end)))
 756
 757 (defun PC-complete-as-file-name ()
 758    "Perform completion on file names preceding point.
 759  Environment vars are converted to their values."
 760    (interactive)
 761    (let* ((end (point))
 762           (beg (if (re-search-backward "[^\\][ \t\n\"\`\'][^ \t\n\"\`\']"
 763                                        (point-min) t)
 764                    (+ (point) 2)
 765                    (point-min)))
 766           (minibuffer-completion-table 'read-file-name-internal)
 767           (minibuffer-completion-predicate "")
 768           (PC-not-minibuffer t))
 769      (goto-char end)
 770      (PC-do-completion nil beg end)))
 771
 772 ;;; Use the shell to do globbing.
 773 ;;; This could now use file-expand-wildcards instead.
 774
 775 (defun PC-expand-many-files (name)
 776   (save-excursion
 777     (set-buffer (generate-new-buffer " *Glob Output*"))
 778     (erase-buffer)
 779     (shell-command (concat "echo " name) t)
 780     (goto-char (point-min))
 781     (if (looking-at ".*No match")
 782         nil
 783       (insert "(\"")
 784       (while (search-forward " " nil t)
 785         (delete-backward-char 1)
 786         (insert "\" \""))
 787       (goto-char (point-max))
 788       (delete-backward-char 1)
 789       (insert "\")")
 790       (goto-char (point-min))
 791       (let ((files (read (current-buffer))) (p nil))
 792         (kill-buffer (current-buffer))
 793         (or (equal completion-ignored-extensions PC-ignored-extensions)
 794             (setq PC-ignored-regexp
 795                   (concat "\\("
 796                           (mapconcat
 797                            'regexp-quote
 798                            (setq PC-ignored-extensions
 799                                  completion-ignored-extensions)
 800                            "\\|")
 801                           "\\)\\'")))
 802         (setq p nil)
 803         (while files
 804           (or (string-match PC-ignored-regexp (car files))
 805               (setq p (cons (car files) p)))
 806           (setq files (cdr files)))
 807         p))))
 808
 809 ;;; Facilities for loading C header files.  This is independent from the
 810 ;;; main completion code.  See also the variable `PC-include-file-path'
 811 ;;; at top of this file.
 812
 813 (defun PC-look-for-include-file ()
 814   (if (string-match "[\"<]\\([^\"<>]*\\)[\">]?$" (buffer-file-name))
 815       (let ((name (substring (buffer-file-name)
 816                              (match-beginning 1) (match-end 1)))
 817             (punc (aref (buffer-file-name) (match-beginning 0)))
 818             (path nil)
 819             new-buf)
 820         (kill-buffer (current-buffer))
 821         (if (equal name "")
 822             (save-excursion
 823               (set-buffer (car (buffer-list)))
 824               (save-excursion
 825                 (beginning-of-line)
 826                 (if (looking-at
 827                      "[ \t]*#[ \t]*include[ \t]+[<\"]\\(.+\\)[>\"][ \t]*[\n/]")
 828                     (setq name (buffer-substring (match-beginning 1)
 829                                                  (match-end 1))
 830                           punc (char-after (1- (match-beginning 1))))
 831                   ;; Suggested by Frank Siebenlist:
 832                   (if (or (looking-at
 833                            "[ \t]*([ \t]*load[ \t]+\"\\([^\"]+\\)\"")
 834                           (looking-at
 835                            "[ \t]*([ \t]*load-library[ \t]+\"\\([^\"]+\\)\"")
 836                           (looking-at
 837                            "[ \t]*([ \t]*require[ \t]+'\\([^\t )]+\\)[\t )]"))
 838                       (progn
 839                         (setq name (buffer-substring (match-beginning 1)
 840                                                      (match-end 1))
 841                               punc ?\<
 842                               path load-path)
 843                         (if (string-match "\\.elc$" name)
 844                             (setq name (substring name 0 -1))
 845                           (or (string-match "\\.el$" name)
 846                               (setq name (concat name ".el")))))
 847                     (error "Not on an #include line"))))))
 848         (or (string-match "\\.[[:alnum:]]+$" name)
 849             (setq name (concat name ".h")))
 850         (if (eq punc ?\<)
 851             (let ((path (or path (PC-include-file-path))))
 852               (while (and path
 853                           (not (file-exists-p
 854                                 (concat (file-name-as-directory (car path))
 855                                         name))))
 856                 (setq path (cdr path)))
 857               (if path
 858                   (setq name (concat (file-name-as-directory (car path)) name))
 859                 (error "No such include file: <%s>" name)))
 860           (let ((dir (save-excursion
 861                        (set-buffer (car (buffer-list)))
 862                        default-directory)))
 863             (if (file-exists-p (concat dir name))
 864                 (setq name (concat dir name))
 865               (error "No such include file: `%s'" name))))
 866         (setq new-buf (get-file-buffer name))
 867         (if new-buf
 868             ;; no need to verify last-modified time for this!
 869             (set-buffer new-buf)
 870           (setq new-buf (create-file-buffer name))
 871           (set-buffer new-buf)
 872           (erase-buffer)
 873           (insert-file-contents name t))
 874         ;; Returning non-nil with the new buffer current
 875         ;; is sufficient to tell find-file to use it.
 876         t)
 877     nil))
 878
 879 (defun PC-include-file-path ()
 880   (or PC-include-file-path
 881       (let ((env (getenv "INCPATH"))
 882             (path nil)
 883             pos)
 884         (or env (error "No include file path specified"))
 885         (while (setq pos (string-match ":[^:]+$" env))
 886           (setq path (cons (substring env (1+ pos)) path)
 887                 env (substring env 0 pos)))
 888         path)))
 889
 890 ;;; This is adapted from lib-complete.el, by Mike Williams.
 891 (defun PC-include-file-all-completions (file search-path &optional full)
 892   "Return all completions for FILE in any directory on SEARCH-PATH.
 893 If optional third argument FULL is non-nil, returned pathnames should be
 894 absolute rather than relative to some directory on the SEARCH-PATH."
 895   (setq search-path
 896         (mapcar (lambda (dir)
 897                   (if dir (file-name-as-directory dir) default-directory))
 898                 search-path))
 899   (if (file-name-absolute-p file)
 900       ;; It's an absolute file name, so don't need search-path
 901       (progn
 902         (setq file (expand-file-name file))
 903         (file-name-all-completions
 904          (file-name-nondirectory file) (file-name-directory file)))
 905     (let ((subdir (file-name-directory file))
 906           (ndfile (file-name-nondirectory file))
 907           file-lists)
 908       ;; Append subdirectory part to each element of search-path
 909       (if subdir
 910           (setq search-path
 911                 (mapcar (lambda (dir) (concat dir subdir))
 912                         search-path)
 913                 file ))
 914       ;; Make list of completions in each directory on search-path
 915       (while search-path
 916         (let* ((dir (car search-path))
 917                (subdir (if full dir subdir)))
 918           (if (file-directory-p dir)
 919               (progn
 920                 (setq file-lists
 921                       (cons
 922                        (mapcar (lambda (file) (concat subdir file))
 923                                (file-name-all-completions ndfile
 924                                                           (car search-path)))
 925                        file-lists))))
 926           (setq search-path (cdr search-path))))
 927       ;; Compress out duplicates while building complete list (slloooow!)
 928       (let ((sorted (sort (apply 'nconc file-lists)
 929                           (lambda (x y) (not (string-lessp x y)))))
 930             compressed)
 931         (while sorted
 932           (if (equal (car sorted) (car compressed)) nil
 933             (setq compressed (cons (car sorted) compressed)))
 934           (setq sorted (cdr sorted)))
 935         compressed))))
 936
 937 (defun PC-read-include-file-name-internal (string dir action)
 938   (if (string-match "<\\([^\"<>]*\\)>?$" string)
 939       (let* ((name (substring string (match-beginning 1) (match-end 1)))
 940              (str2 (substring string (match-beginning 0)))
 941              (completion-table
 942               (mapcar (function (lambda (x) (list (format "<%s>" x))))
 943                       (PC-include-file-all-completions
 944                        name (PC-include-file-path)))))
 945         (cond
 946          ((not completion-table) nil)
 947          ((eq action nil) (try-completion str2 completion-table nil))
 948          ((eq action t) (all-completions str2 completion-table nil))
 949          ((eq action 'lambda)
 950           (eq (try-completion str2 completion-table nil) t))))
 951     (funcall PC-old-read-file-name-internal string dir action)))
 952 \f
 953
 954 (provide 'complete)
 955
 956 ;;; complete.el ends here