lisp/gnus/yenc.el

   1 ;;; yenc.el --- elisp native yenc decoder
   2
   3 ;; Copyright (C) 2002-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Jesper Harder <harder@ifa.au.dk>
   6 ;; Keywords: yenc news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; Functions for decoding yenc encoded messages.
  26 ;;
  27 ;; Limitations:
  28 ;;
  29 ;; * Does not handle multipart messages.
  30 ;; * No support for external decoders.
  31 ;; * Doesn't check the crc32 checksum (if present).
  32
  33 ;;; Code:
  34
  35 (eval-when-compile (require 'cl))
  36
  37 (defconst yenc-begin-line
  38   "^=ybegin.*$")
  39
  40 (defconst yenc-decoding-vector
  41   [214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230
  42        231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247
  43        248 249 250 251 252 253 254 255 0 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15
  44        16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38
  45        39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61
  46        62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84
  47        85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105
  48        106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122
  49        123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139
  50        140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156
  51        157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173
  52        174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190
  53        191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207
  54        208 209 210 211 212 213])
  55
  56 (defun yenc-first-part-p ()
  57   "Say whether the buffer contains the first part of a yEnc file."
  58   (save-excursion
  59     (goto-char (point-min))
  60     (re-search-forward "^=ybegin part=1 " nil t)))
  61
  62 (defun yenc-last-part-p ()
  63   "Say whether the buffer contains the last part of a yEnc file."
  64   (save-excursion
  65     (goto-char (point-min))
  66     (let (total-size end-size)
  67       (when (re-search-forward "^=ybegin.*size=\\([0-9]+\\)" nil t)
  68         (setq total-size (match-string 1)))
  69       (when (re-search-forward "^=ypart.*end=\\([0-9]+\\)" nil t)
  70         (setq end-size (match-string 1)))
  71       (and total-size
  72            end-size
  73            (string= total-size end-size)))))
  74
  75 ;;;###autoload
  76 (defun yenc-decode-region (start end)
  77   "Yenc decode region between START and END using an internal decoder."
  78   (interactive "r")
  79   (let (work-buffer)
  80     (unwind-protect
  81         (save-excursion
  82           (goto-char start)
  83           (when (re-search-forward yenc-begin-line end t)
  84             (let ((first (match-end 0))
  85                   (header-alist (yenc-parse-line (match-string 0)))
  86                   bytes last footer-alist char)
  87               (when (re-search-forward "^=ypart.*$" end t)
  88                 (setq first (match-end 0)))
  89               (when (re-search-forward "^=yend.*$" end t)
  90                 (setq last (match-beginning 0))
  91                 (setq footer-alist (yenc-parse-line (match-string 0)))
  92                 (setq work-buffer (generate-new-buffer " *yenc-work*"))
  93                 (unless (featurep 'xemacs)
  94                   (with-current-buffer work-buffer (set-buffer-multibyte nil)))
  95                 (while (< first last)
  96                   (setq char (char-after first))
  97                   (cond ((or (eq char ?\r)
  98                              (eq char ?\n)))
  99                         ((eq char ?=)
 100                          (setq char (char-after (incf first)))
 101                          (with-current-buffer work-buffer
 102                            (insert-char (mod (- char 106) 256) 1)))
 103                         (t
 104                          (with-current-buffer work-buffer
 105                            ;;(insert-char (mod (- char 42) 256) 1)
 106                            (insert-char (aref yenc-decoding-vector char) 1))))
 107                   (incf first))
 108                 (setq bytes (buffer-size work-buffer))
 109                 (unless (and (= (cdr (assq 'size header-alist)) bytes)
 110                              (= (cdr (assq 'size footer-alist)) bytes))
 111                   (message "Warning: Size mismatch while decoding."))
 112                 (goto-char start)
 113                 (delete-region start end)
 114                 (insert-buffer-substring work-buffer))))
 115           (and work-buffer (kill-buffer work-buffer))))))
 116
 117 ;;;###autoload
 118 (defun yenc-extract-filename ()
 119   "Extract file name from an yenc header."
 120   (save-excursion
 121     (when (re-search-forward yenc-begin-line nil t)
 122       (cdr (assoc 'name (yenc-parse-line (match-string 0)))))))
 123
 124 (defun yenc-parse-line (str)
 125   "Extract file name and size from STR."
 126   (let (result name)
 127     (when (string-match "^=y.*size=\\([0-9]+\\)" str)
 128       (push (cons 'size (string-to-number (match-string 1 str))) result))
 129     (when (string-match "^=y.*name=\\(.*\\)$" str)
 130       (setq name (match-string 1 str))
 131       ;; Remove trailing white space
 132       (when (string-match " +$" name)
 133         (setq name (substring name 0 (match-beginning 0))))
 134       (push (cons 'name name) result))
 135     result))
 136
 137 (provide 'yenc)
 138
 139 ;;; yenc.el ends here