lisp/gnus/gnus-eform.el

   1 ;;; gnus-eform.el --- a mode for editing forms for Gnus
   2
   3 ;; Copyright (C) 1996-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'gnus)
  28 (require 'gnus-win)
  29
  30 ;;;
  31 ;;; Editing forms
  32 ;;;
  33
  34 (defgroup gnus-edit-form nil
  35   "A mode for editing forms."
  36   :group 'gnus)
  37
  38 (defcustom gnus-edit-form-mode-hook nil
  39   "Hook run in `gnus-edit-form-mode' buffers."
  40   :group 'gnus-edit-form
  41   :type 'hook)
  42
  43 (defcustom gnus-edit-form-menu-hook nil
  44   "Hook run when creating menus in `gnus-edit-form-mode' buffers."
  45   :group 'gnus-edit-form
  46   :type 'hook)
  47
  48 ;;; Internal variables
  49
  50 (defvar gnus-edit-form-buffer "*Gnus edit form*")
  51 (defvar gnus-edit-form-done-function nil)
  52
  53 (defvar gnus-edit-form-mode-map nil)
  54 (unless gnus-edit-form-mode-map
  55   (setq gnus-edit-form-mode-map (make-sparse-keymap))
  56   (set-keymap-parent gnus-edit-form-mode-map emacs-lisp-mode-map)
  57   (gnus-define-keys gnus-edit-form-mode-map
  58     "\C-c\C-c" gnus-edit-form-done
  59     "\C-c\C-k" gnus-edit-form-exit))
  60
  61 (defun gnus-edit-form-make-menu-bar ()
  62   (unless (boundp 'gnus-edit-form-menu)
  63     (easy-menu-define
  64      gnus-edit-form-menu gnus-edit-form-mode-map ""
  65      '("Edit Form"
  66        ["Exit and save changes" gnus-edit-form-done t]
  67        ["Exit" gnus-edit-form-exit t]))
  68     (gnus-run-hooks 'gnus-edit-form-menu-hook)))
  69
  70 (define-derived-mode gnus-edit-form-mode fundamental-mode "Edit Form"
  71   "Major mode for editing forms.
  72 It is a slightly enhanced emacs-lisp-mode.
  73
  74 \\{gnus-edit-form-mode-map}"
  75   (when (gnus-visual-p 'group-menu 'menu)
  76     (gnus-edit-form-make-menu-bar))
  77   (make-local-variable 'gnus-edit-form-done-function)
  78   (make-local-variable 'gnus-prev-winconf))
  79
  80 (defun gnus-edit-form (form documentation exit-func &optional layout)
  81   "Edit FORM in a new buffer.
  82 Call EXIT-FUNC on exit.  Display DOCUMENTATION in the beginning
  83 of the buffer.
  84 The optional LAYOUT overrides the `edit-form' window layout."
  85   (let ((winconf (current-window-configuration)))
  86     (set-buffer (gnus-get-buffer-create gnus-edit-form-buffer))
  87     (gnus-configure-windows (or layout 'edit-form))
  88     (gnus-edit-form-mode)
  89     (setq gnus-prev-winconf winconf)
  90     (setq gnus-edit-form-done-function exit-func)
  91     (erase-buffer)
  92     (insert documentation)
  93     (unless (bolp)
  94       (insert "\n"))
  95     (goto-char (point-min))
  96     (while (not (eobp))
  97       (insert ";;; ")
  98       (forward-line 1))
  99     (insert (substitute-command-keys
 100              ";; Type `C-c C-c' after you've finished editing.\n"))
 101     (insert "\n")
 102     (let ((p (point)))
 103       (gnus-pp form)
 104       (insert "\n")
 105       (goto-char p))))
 106
 107 (defun gnus-edit-form-done ()
 108   "Update changes and kill the current buffer."
 109   (interactive)
 110   (goto-char (point-min))
 111   (let ((form (condition-case nil
 112                   (read (current-buffer))
 113                 (end-of-file nil)))
 114         (func gnus-edit-form-done-function))
 115     (gnus-edit-form-exit)
 116     (funcall func form)))
 117
 118 (defun gnus-edit-form-exit ()
 119   "Kill the current buffer."
 120   (interactive)
 121   (let ((winconf gnus-prev-winconf))
 122     (kill-buffer (current-buffer))
 123     (set-window-configuration winconf)))
 124
 125 (provide 'gnus-eform)
 126
 127 ;;; gnus-eform.el ends here