lisp/progmodes/asm-mode.el

   1 ;;; asm-mode.el --- mode for editing assembler code
   2
   3 ;; Copyright (C) 1991, 2003 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric S. Raymond <esr@snark.thyrsus.com>
   6 ;; Maintainer: FSF
   7 ;; Keywords: tools, languages
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This mode was written by Eric S. Raymond <esr@snark.thyrsus.com>,
  29 ;; inspired by an earlier asm-mode by Martin Neitzel.
  30
  31 ;; This minor mode is based on text mode.  It defines a private abbrev table
  32 ;; that can be used to save abbrevs for assembler mnemonics.  It binds just
  33 ;; five keys:
  34 ;;
  35 ;;      TAB             tab to next tab stop
  36 ;;      :               outdent preceding label, tab to tab stop
  37 ;;      comment char    place or move comment
  38 ;;                      asm-comment-char specifies which character this is;
  39 ;;                      you can use a different character in different
  40 ;;                      Asm mode buffers.
  41 ;;      C-j, C-m        newline and tab to tab stop
  42 ;;
  43 ;; Code is indented to the first tab stop level.
  44
  45 ;; This mode runs two hooks:
  46 ;;   1) An asm-mode-set-comment-hook before the part of the initialization
  47 ;; depending on asm-comment-char, and
  48 ;;   2) an asm-mode-hook at the end of initialization.
  49
  50 ;;; Code:
  51
  52 (defgroup asm nil
  53   "Mode for editing assembler code."
  54   :group 'languages)
  55
  56 (defcustom asm-comment-char ?\;
  57   "*The comment-start character assumed by Asm mode."
  58   :type 'character
  59   :group 'asm)
  60
  61 (defvar asm-mode-syntax-table
  62   (let ((st (make-syntax-table)))
  63     (modify-syntax-entry ?\n ">" st)
  64     (modify-syntax-entry ?/  ". 14b" st)
  65     (modify-syntax-entry ?*  ". 23b" st)
  66     st)
  67   "Syntax table used while in Asm mode.")
  68
  69 (defvar asm-mode-abbrev-table nil
  70   "Abbrev table used while in Asm mode.")
  71 (define-abbrev-table 'asm-mode-abbrev-table ())
  72
  73 (defvar asm-mode-map
  74   (let ((map (make-sparse-keymap)))
  75     ;; Note that the comment character isn't set up until asm-mode is called.
  76     (define-key map ":"         'asm-colon)
  77     (define-key map "\C-c;"     'comment-region)
  78     (define-key map "\C-j"      'newline-and-indent)
  79     (define-key map "\C-m"      'newline-and-indent)
  80     map)
  81   "Keymap for Asm mode.")
  82
  83 (defconst asm-font-lock-keywords
  84  '(("^\\(\\(\\sw\\|\\s_\\)+\\)\\>:?[ \t]*\\(\\sw+\\(\\.\\sw+\\)*\\)?"
  85     (1 font-lock-function-name-face) (3 font-lock-keyword-face nil t))
  86    ("^\\((\\sw+)\\)?\\s +\\(\\(\\sw\\|\\s_\\)+\\(\\.\\sw+\\)*\\)"
  87     2 font-lock-keyword-face))
  88  "Additional expressions to highlight in Assembler mode.")
  89
  90 ;;;###autoload
  91 (defun asm-mode ()
  92   "Major mode for editing typical assembler code.
  93 Features a private abbrev table and the following bindings:
  94
  95 \\[asm-colon]\toutdent a preceding label, tab to next tab stop.
  96 \\[tab-to-tab-stop]\ttab to next tab stop.
  97 \\[asm-newline]\tnewline, then tab to next tab stop.
  98 \\[asm-comment]\tsmart placement of assembler comments.
  99
 100 The character used for making comments is set by the variable
 101 `asm-comment-char' (which defaults to `?\\;').
 102
 103 Alternatively, you may set this variable in `asm-mode-set-comment-hook',
 104 which is called near the beginning of mode initialization.
 105
 106 Turning on Asm mode runs the hook `asm-mode-hook' at the end of initialization.
 107
 108 Special commands:
 109 \\{asm-mode-map}"
 110   (interactive)
 111   (kill-all-local-variables)
 112   (setq mode-name "Assembler")
 113   (setq major-mode 'asm-mode)
 114   (setq local-abbrev-table asm-mode-abbrev-table)
 115   (make-local-variable 'font-lock-defaults)
 116   (setq font-lock-defaults '(asm-font-lock-keywords))
 117   (set (make-local-variable 'indent-line-function) 'asm-indent-line)
 118   ;; Stay closer to the old TAB behavior (was tab-to-tab-stop).
 119   (set (make-local-variable 'tab-always-indent) nil)
 120
 121   (run-hooks 'asm-mode-set-comment-hook)
 122   ;; Make our own local child of asm-mode-map
 123   ;; so we can define our own comment character.
 124   (use-local-map (nconc (make-sparse-keymap) asm-mode-map))
 125   (local-set-key (vector asm-comment-char) 'asm-comment)
 126   (set-syntax-table (make-syntax-table asm-mode-syntax-table))
 127   (modify-syntax-entry  asm-comment-char "<")
 128
 129   (make-local-variable 'comment-start)
 130   (setq comment-start (string asm-comment-char))
 131   (make-local-variable 'comment-add)
 132   (setq comment-add 1)
 133   (make-local-variable 'comment-start-skip)
 134   (setq comment-start-skip "\\(?:\\s<+\\|/\\*+\\)[ \t]*")
 135   (make-local-variable 'comment-end-skip)
 136   (setq comment-end-skip "[ \t]*\\(\\s>\\|\\*+/\\)")
 137   (make-local-variable 'comment-end)
 138   (setq comment-end "")
 139   (setq fill-prefix "\t")
 140   (run-mode-hooks 'asm-mode-hook))
 141
 142 (defun asm-indent-line ()
 143   "Auto-indent the current line."
 144   (interactive)
 145   (let* ((savep (point))
 146          (indent (condition-case nil
 147                      (save-excursion
 148                        (forward-line 0)
 149                        (skip-chars-forward " \t")
 150                        (if (>= (point) savep) (setq savep nil))
 151                        (max (asm-calculate-indentation) 0))
 152                    (error 0))))
 153     (if savep
 154         (save-excursion (indent-line-to indent))
 155       (indent-line-to indent))))
 156
 157 (defun asm-calculate-indentation ()
 158   (or
 159    ;; Flush labels to the left margin.
 160    (and (looking-at "\\(\\sw\\|\\s_\\)+:") 0)
 161    ;; Same thing for `;;;' comments.
 162    (and (looking-at "\\s<\\s<\\s<") 0)
 163    ;; Simple `;' comments go to the comment-column.
 164    (and (looking-at "\\s<\\(\\S<\\|\\'\\)") comment-column)
 165    ;; The rest goes at the first tab stop.
 166    (or (car tab-stop-list) tab-width)))
 167
 168 (defun asm-colon ()
 169   "Insert a colon; if it follows a label, delete the label's indentation."
 170   (interactive)
 171   (let ((labelp nil))
 172     (save-excursion
 173       (skip-syntax-backward "w_")
 174       (skip-syntax-backward " ")
 175       (if (setq labelp (bolp)) (delete-horizontal-space)))
 176     (call-interactively 'self-insert-command)
 177     (when labelp
 178       (delete-horizontal-space)
 179       (tab-to-tab-stop))))
 180
 181 ;; Obsolete since Emacs-21.4.
 182 (defalias 'asm-newline 'newline-and-indent)
 183
 184 (defun asm-comment ()
 185   "Convert an empty comment to a `larger' kind, or start a new one.
 186 These are the known comment classes:
 187
 188    1 -- comment to the right of the code (at the comment-column)
 189    2 -- comment on its own line, indented like code
 190    3 -- comment on its own line, beginning at the left-most column.
 191
 192 Suggested usage:  while writing your code, trigger asm-comment
 193 repeatedly until you are satisfied with the kind of comment."
 194   (interactive)
 195   (comment-normalize-vars)
 196   (let (comempty comment)
 197     (save-excursion
 198       (beginning-of-line)
 199       (setq comment (comment-search-forward (line-end-position) t))
 200       (setq comempty (looking-at "[ \t]*$")))
 201
 202   (cond
 203
 204    ;; Blank line?  Then start comment at code indent level.
 205    ;; Just like `comment-dwim'.  -stef
 206    ((save-excursion (beginning-of-line) (looking-at "^[ \t]*$"))
 207     (indent-according-to-mode)
 208     (insert asm-comment-char asm-comment-char ?\ ))
 209
 210    ;; Nonblank line w/o comment => start a comment at comment-column.
 211    ;; Also: point before the comment => jump inside.
 212    ((or (null comment) (< (point) comment))
 213     (indent-for-comment))
 214
 215    ;; Flush-left or non-empty comment present => just insert character.
 216    ((or (not comempty) (save-excursion (goto-char comment) (bolp)))
 217     (insert asm-comment-char))
 218
 219    ;; Empty code-level comment => upgrade to next comment level.
 220    ((save-excursion (goto-char comment) (skip-chars-backward " \t") (bolp))
 221     (goto-char comment)
 222     (insert asm-comment-char)
 223     (indent-for-comment))
 224
 225    ;; Empty comment ends non-empty code line => new comment above.
 226    (t
 227     (goto-char comment)
 228     (skip-chars-backward " \t")
 229     (delete-region (point) (line-end-position))
 230     (beginning-of-line) (insert "\n") (backward-char)
 231     (asm-comment)))))
 232
 233 (provide 'asm-mode)
 234
 235 ;;; asm-mode.el ends here