lisp/button.el

   1 ;;; button.el --- clickable buttons
   2 ;;
   3 ;; Copyright (C) 2001, 2002, 2003, 2004, 2005,
   4 ;;   2006, 2007 Free Software Foundation, Inc.
   5 ;;
   6 ;; Author: Miles Bader <miles@gnu.org>
   7 ;; Keywords: extensions
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15 ;;
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20 ;;
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27 ;;
  28 ;; This package defines functions for inserting and manipulating
  29 ;; clickable buttons in Emacs buffers, such as might be used for help
  30 ;; hyperlinks, etc.
  31 ;;
  32 ;; In some ways it duplicates functionality also offered by the
  33 ;; `widget' package, but the button package has the advantage that it
  34 ;; is (1) much faster, (2) much smaller, and (3) much, much, simpler
  35 ;; (the code, that is, not the interface).
  36 ;;
  37 ;; Buttons can either use overlays, in which case the button is
  38 ;; represented by the overlay itself, or text-properties, in which case
  39 ;; the button is represented by a marker or buffer-position pointing
  40 ;; somewhere in the button.  In the latter case, no markers into the
  41 ;; buffer are retained, which is important for speed if there are are
  42 ;; extremely large numbers of buttons.
  43 ;;
  44 ;; Using `define-button-type' to define default properties for buttons
  45 ;; is not necessary, but it is is encouraged, since doing so makes the
  46 ;; resulting code clearer and more efficient.
  47 ;;
  48
  49 ;;; Code:
  50
  51 \f
  52 ;; Globals
  53
  54 ;; Use color for the MS-DOS port because it doesn't support underline.
  55 (defface button '((((type pc) (class color))
  56                    (:foreground "lightblue"))
  57                   (t :underline t))
  58   "Default face used for buttons."
  59   :group 'basic-faces)
  60
  61 ;;;###autoload
  62 (defvar button-map
  63   (let ((map (make-sparse-keymap)))
  64     (define-key map "\r" 'push-button)
  65     (define-key map [mouse-2] 'push-button)
  66     map)
  67   "Keymap used by buttons.")
  68
  69 ;;;###autoload
  70 (defvar button-buffer-map
  71   (let ((map (make-sparse-keymap)))
  72     (define-key map [?\t] 'forward-button)
  73     (define-key map "\e\t" 'backward-button)
  74     (define-key map [backtab] 'backward-button)
  75     map)
  76   "Keymap useful for buffers containing buttons.
  77 Mode-specific keymaps may want to use this as their parent keymap.")
  78
  79 ;; Default properties for buttons
  80 (put 'default-button 'face 'button)
  81 (put 'default-button 'mouse-face 'highlight)
  82 (put 'default-button 'keymap button-map)
  83 (put 'default-button 'type 'button)
  84 ;; action may be either a function to call, or a marker to go to
  85 (put 'default-button 'action 'ignore)
  86 (put 'default-button 'help-echo "mouse-2, RET: Push this button")
  87 ;; Make overlay buttons go away if their underlying text is deleted.
  88 (put 'default-button 'evaporate t)
  89 ;; Prevent insertions adjacent to the text-property buttons from
  90 ;; inheriting its properties.
  91 (put 'default-button 'rear-nonsticky t)
  92
  93 ;; A `category-symbol' property for the default button type
  94 (put 'button 'button-category-symbol 'default-button)
  95
  96 \f
  97 ;; Button types (which can be used to hold default properties for buttons)
  98
  99 ;; Because button-type properties are inherited by buttons using the
 100 ;; special `category' property (implemented by both overlays and
 101 ;; text-properties), we need to store them on a symbol to which the
 102 ;; `category' properties can point.  Instead of using the symbol that's
 103 ;; the name of each button-type, however, we use a separate symbol (with
 104 ;; `-button' appended, and uninterned) to store the properties.  This is
 105 ;; to avoid name clashes.
 106
 107 ;; [this is an internal function]
 108 (defsubst button-category-symbol (type)
 109   "Return the symbol used by button-type TYPE to store properties.
 110 Buttons inherit them by setting their `category' property to that symbol."
 111   (or (get type 'button-category-symbol)
 112       (error "Unknown button type `%s'" type)))
 113
 114 ;;;###autoload
 115 (defun define-button-type (name &rest properties)
 116   "Define a `button type' called NAME.
 117 The remaining arguments form a sequence of PROPERTY VALUE pairs,
 118 specifying properties to use as defaults for buttons with this type
 119 \(a button's type may be set by giving it a `type' property when
 120 creating the button, using the :type keyword argument).
 121
 122 In addition, the keyword argument :supertype may be used to specify a
 123 button-type from which NAME inherits its default property values
 124 \(however, the inheritance happens only when NAME is defined; subsequent
 125 changes to a supertype are not reflected in its subtypes)."
 126   (let ((catsym (make-symbol (concat (symbol-name name) "-button")))
 127         (super-catsym
 128          (button-category-symbol
 129           (or (plist-get properties 'supertype)
 130               (plist-get properties :supertype)
 131               'button))))
 132     ;; Provide a link so that it's easy to find the real symbol.
 133     (put name 'button-category-symbol catsym)
 134     ;; Initialize NAME's properties using the global defaults.
 135     (let ((default-props (symbol-plist super-catsym)))
 136       (while default-props
 137         (put catsym (pop default-props) (pop default-props))))
 138     ;; Add NAME as the `type' property, which will then be returned as
 139     ;; the type property of individual buttons.
 140     (put catsym 'type name)
 141     ;; Add the properties in PROPERTIES to the real symbol.
 142     (while properties
 143       (let ((prop (pop properties)))
 144         (when (eq prop :supertype)
 145           (setq prop 'supertype))
 146         (put catsym prop (pop properties))))
 147     ;; Make sure there's a `supertype' property
 148     (unless (get catsym 'supertype)
 149       (put catsym 'supertype 'button))
 150     name))
 151
 152 (defun button-type-put (type prop val)
 153   "Set the button-type TYPE's PROP property to VAL."
 154   (put (button-category-symbol type) prop val))
 155
 156 (defun button-type-get (type prop)
 157   "Get the property of button-type TYPE named PROP."
 158   (get (button-category-symbol type) prop))
 159
 160 (defun button-type-subtype-p (type supertype)
 161   "Return t if button-type TYPE is a subtype of SUPERTYPE."
 162   (or (eq type supertype)
 163       (and type
 164            (button-type-subtype-p (button-type-get type 'supertype)
 165                                   supertype))))
 166
 167 \f
 168 ;; Button properties and other attributes
 169
 170 (defun button-start (button)
 171   "Return the position at which BUTTON starts."
 172   (if (overlayp button)
 173       (overlay-start button)
 174     ;; Must be a text-property button.
 175     (or (previous-single-property-change (1+ button) 'button)
 176         (point-min))))
 177
 178 (defun button-end (button)
 179   "Return the position at which BUTTON ends."
 180   (if (overlayp button)
 181       (overlay-end button)
 182     ;; Must be a text-property button.
 183     (or (next-single-property-change button 'button)
 184         (point-max))))
 185
 186 (defun button-get (button prop)
 187   "Get the property of button BUTTON named PROP."
 188   (if (overlayp button)
 189       (overlay-get button prop)
 190     ;; Must be a text-property button.
 191     (get-text-property button prop)))
 192
 193 (defun button-put (button prop val)
 194   "Set BUTTON's PROP property to VAL."
 195   ;; Treat some properties specially.
 196   (cond ((memq prop '(type :type))
 197          ;; We translate a `type' property a `category' property, since
 198          ;; that's what's actually used by overlays/text-properties for
 199          ;; inheriting properties.
 200          (setq prop 'category)
 201          (setq val (button-category-symbol val)))
 202         ((eq prop 'category)
 203          ;; Disallow updating the `category' property directly.
 204          (error "Button `category' property may not be set directly")))
 205   ;; Add the property.
 206   (if (overlayp button)
 207       (overlay-put button prop val)
 208     ;; Must be a text-property button.
 209     (put-text-property
 210      (or (previous-single-property-change (1+ button) 'button)
 211          (point-min))
 212      (or (next-single-property-change button 'button)
 213          (point-max))
 214      prop val)))
 215
 216 (defsubst button-activate (button &optional use-mouse-action)
 217   "Call BUTTON's action property.
 218 If USE-MOUSE-ACTION is non-nil, invoke the button's mouse-action
 219 instead of its normal action; if the button has no mouse-action,
 220 the normal action is used instead."
 221   (let ((action (or (and use-mouse-action (button-get button 'mouse-action))
 222                     (button-get button 'action))))
 223     (if (markerp action)
 224         (save-selected-window
 225           (select-window (display-buffer (marker-buffer action)))
 226           (goto-char action)
 227           (recenter 0))
 228       (funcall action button))))
 229
 230 (defun button-label (button)
 231   "Return BUTTON's text label."
 232   (buffer-substring-no-properties (button-start button) (button-end button)))
 233
 234 (defsubst button-type (button)
 235   "Return BUTTON's button-type."
 236   (button-get button 'type))
 237
 238 (defun button-has-type-p (button type)
 239   "Return t if BUTTON has button-type TYPE, or one of TYPE's subtypes."
 240   (button-type-subtype-p (button-get button 'type) type))
 241
 242 \f
 243 ;; Creating overlay buttons
 244
 245 ;;;###autoload
 246 (defun make-button (beg end &rest properties)
 247   "Make a button from BEG to END in the current buffer.
 248 The remaining arguments form a sequence of PROPERTY VALUE pairs,
 249 specifying properties to add to the button.
 250 In addition, the keyword argument :type may be used to specify a
 251 button-type from which to inherit other properties; see
 252 `define-button-type'.
 253
 254 Also see `make-text-button', `insert-button'."
 255   (let ((overlay (make-overlay beg end nil t nil)))
 256     (while properties
 257       (button-put overlay (pop properties) (pop properties)))
 258     ;; Put a pointer to the button in the overlay, so it's easy to get
 259     ;; when we don't actually have a reference to the overlay.
 260     (overlay-put overlay 'button overlay)
 261     ;; If the user didn't specify a type, use the default.
 262     (unless (overlay-get overlay 'category)
 263       (overlay-put overlay 'category 'default-button))
 264     ;; OVERLAY is the button, so return it
 265     overlay))
 266
 267 ;;;###autoload
 268 (defun insert-button (label &rest properties)
 269   "Insert a button with the label LABEL.
 270 The remaining arguments form a sequence of PROPERTY VALUE pairs,
 271 specifying properties to add to the button.
 272 In addition, the keyword argument :type may be used to specify a
 273 button-type from which to inherit other properties; see
 274 `define-button-type'.
 275
 276 Also see `insert-text-button', `make-button'."
 277   (apply #'make-button
 278          (prog1 (point) (insert label))
 279          (point)
 280          properties))
 281
 282 \f
 283 ;; Creating text-property buttons
 284
 285 ;;;###autoload
 286 (defun make-text-button (beg end &rest properties)
 287   "Make a button from BEG to END in the current buffer.
 288 The remaining arguments form a sequence of PROPERTY VALUE pairs,
 289 specifying properties to add to the button.
 290 In addition, the keyword argument :type may be used to specify a
 291 button-type from which to inherit other properties; see
 292 `define-button-type'.
 293
 294 This function is like `make-button', except that the button is actually
 295 part of the text instead of being a property of the buffer.  Creating
 296 large numbers of buttons can also be somewhat faster using
 297 `make-text-button'.
 298
 299 Also see `insert-text-button'."
 300   (let ((type-entry
 301          (or (plist-member properties 'type)
 302              (plist-member properties :type))))
 303     ;; Disallow setting the `category' property directly.
 304     (when (plist-get properties 'category)
 305       (error "Button `category' property may not be set directly"))
 306     (if (null type-entry)
 307         ;; The user didn't specify a `type' property, use the default.
 308         (setq properties (cons 'category (cons 'default-button properties)))
 309       ;; The user did specify a `type' property.  Translate it into a
 310       ;; `category' property, which is what's actually used by
 311       ;; text-properties for inheritance.
 312       (setcar type-entry 'category)
 313       (setcar (cdr type-entry)
 314               (button-category-symbol (car (cdr type-entry))))))
 315   ;; Now add all the text properties at once
 316   (add-text-properties beg end
 317                        ;; Each button should have a non-eq `button'
 318                        ;; property so that next-single-property-change can
 319                        ;; detect boundaries reliably.
 320                        (cons 'button (cons (list t) properties)))
 321   ;; Return something that can be used to get at the button.
 322   beg)
 323
 324 ;;;###autoload
 325 (defun insert-text-button (label &rest properties)
 326   "Insert a button with the label LABEL.
 327 The remaining arguments form a sequence of PROPERTY VALUE pairs,
 328 specifying properties to add to the button.
 329 In addition, the keyword argument :type may be used to specify a
 330 button-type from which to inherit other properties; see
 331 `define-button-type'.
 332
 333 This function is like `insert-button', except that the button is
 334 actually part of the text instead of being a property of the buffer.
 335 Creating large numbers of buttons can also be somewhat faster using
 336 `insert-text-button'.
 337
 338 Also see `make-text-button'."
 339   (apply #'make-text-button
 340          (prog1 (point) (insert label))
 341          (point)
 342          properties))
 343
 344 \f
 345 ;; Finding buttons in a buffer
 346
 347 (defun button-at (pos)
 348   "Return the button at position POS in the current buffer, or nil."
 349   (let ((button (get-char-property pos 'button)))
 350     (if (or (overlayp button) (null button))
 351         button
 352       ;; Must be a text-property button; return a marker pointing to it.
 353       (copy-marker pos t))))
 354
 355 (defun next-button (pos &optional count-current)
 356   "Return the next button after position POS in the current buffer.
 357 If COUNT-CURRENT is non-nil, count any button at POS in the search,
 358 instead of starting at the next button."
 359     (unless count-current
 360       ;; Search for the next button boundary.
 361       (setq pos (next-single-char-property-change pos 'button)))
 362     (and (< pos (point-max))
 363          (or (button-at pos)
 364              ;; We must have originally been on a button, and are now in
 365              ;; the inter-button space.  Recurse to find a button.
 366              (next-button pos))))
 367
 368 (defun previous-button (pos &optional count-current)
 369   "Return the previous button before position POS in the current buffer.
 370 If COUNT-CURRENT is non-nil, count any button at POS in the search,
 371 instead of starting at the next button."
 372   (let ((button (button-at pos)))
 373     (if button
 374         (if count-current
 375             button
 376           ;; We started out on a button, so move to its start and look
 377           ;; for the previous button boundary.
 378           (setq pos (previous-single-char-property-change
 379                      (button-start button) 'button))
 380           (let ((new-button (button-at pos)))
 381             (if new-button
 382                 ;; We are in a button again; this can happen if there
 383                 ;; are adjacent buttons (or at bob).
 384                 (unless (= pos (button-start button)) new-button)
 385               ;; We are now in the space between buttons.
 386               (previous-button pos))))
 387       ;; We started out in the space between buttons.
 388       (setq pos (previous-single-char-property-change pos 'button))
 389       (or (button-at pos)
 390           (and (> pos (point-min))
 391                (button-at (1- pos)))))))
 392
 393 \f
 394 ;; User commands
 395
 396 (defun push-button (&optional pos use-mouse-action)
 397   "Perform the action specified by a button at location POS.
 398 POS may be either a buffer position or a mouse-event.  If
 399 USE-MOUSE-ACTION is non-nil, invoke the button's mouse-action
 400 instead of its normal action; if the button has no mouse-action,
 401 the normal action is used instead.  The action may be either a
 402 function to call or a marker to display.
 403 POS defaults to point, except when `push-button' is invoked
 404 interactively as the result of a mouse-event, in which case, the
 405 mouse event is used.
 406 If there's no button at POS, do nothing and return nil, otherwise
 407 return t."
 408   (interactive
 409    (list (if (integerp last-command-event) (point) last-command-event)))
 410   (if (and (not (integerp pos)) (eventp pos))
 411       ;; POS is a mouse event; switch to the proper window/buffer
 412       (let ((posn (event-start pos)))
 413         (with-current-buffer (window-buffer (posn-window posn))
 414           (push-button (posn-point posn) t)))
 415     ;; POS is just normal position
 416     (let ((button (button-at (or pos (point)))))
 417       (if (not button)
 418           nil
 419         (button-activate button use-mouse-action)
 420         t))))
 421
 422 (defun forward-button (n &optional wrap display-message)
 423   "Move to the Nth next button, or Nth previous button if N is negative.
 424 If N is 0, move to the start of any button at point.
 425 If WRAP is non-nil, moving past either end of the buffer continues from the
 426 other end.
 427 If DISPLAY-MESSAGE is non-nil, the button's help-echo string is displayed.
 428 Any button with a non-nil `skip' property is skipped over.
 429 Returns the button found."
 430   (interactive "p\nd\nd")
 431   (let (button)
 432     (if (zerop n)
 433         ;; Move to start of current button
 434         (if (setq button (button-at (point)))
 435             (goto-char (button-start button)))
 436       ;; Move to Nth next button
 437       (let ((iterator (if (> n 0) #'next-button #'previous-button))
 438             (wrap-start (if (> n 0) (point-min) (point-max))))
 439         (setq n (abs n))
 440         (setq button t)                 ; just to start the loop
 441         (while (and (> n 0) button)
 442           (setq button (funcall iterator (point)))
 443           (when (and (not button) wrap)
 444             (setq button (funcall iterator wrap-start t)))
 445           (when button
 446             (goto-char (button-start button))
 447             (unless (button-get button 'skip)
 448               (setq n (1- n)))))))
 449     (if (null button)
 450         (error (if wrap "No buttons!" "No more buttons"))
 451       (let ((msg (and display-message (button-get button 'help-echo))))
 452         (when msg
 453           (message "%s" msg)))
 454       button)))
 455
 456 (defun backward-button (n &optional wrap display-message)
 457   "Move to the Nth previous button, or Nth next button if N is negative.
 458 If N is 0, move to the start of any button at point.
 459 If WRAP is non-nil, moving past either end of the buffer continues from the
 460 other end.
 461 If DISPLAY-MESSAGE is non-nil, the button's help-echo string is displayed.
 462 Any button with a non-nil `skip' property is skipped over.
 463 Returns the button found."
 464   (interactive "p\nd\nd")
 465   (forward-button (- n) wrap display-message))
 466
 467
 468 (provide 'button)
 469
 470 ;;; arch-tag: 5f2c7627-413b-4097-b282-630f89d9c5e9
 471 ;;; button.el ends here