lisp/ibuf-ext.el

   1 ;;; ibuf-ext.el --- extensions for ibuffer
   2
   3 ;; Copyright (C) 2000, 2001, 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   4
   5 ;; Author: Colin Walters <walters@verbum.org>
   6 ;; Maintainer: John Paul Wallington <jpw@gnu.org>
   7 ;; Created: 2 Dec 2001
   8 ;; Keywords: buffer, convenience
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; This program is free software; you can redistribute it and/or
  13 ;; modify it under the terms of the GNU General Public License as
  14 ;; published by the Free Software Foundation; either version 2, or (at
  15 ;; your option) any later version.
  16
  17 ;; This program is distributed in the hope that it will be useful, but
  18 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20 ;; General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with this program ; see the file COPYING.  If not, write to
  24 ;; the Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; These functions should be automatically loaded when called, but you
  30 ;; can explicity (require 'ibuf-ext) in your ~/.emacs to have them
  31 ;; preloaded.
  32
  33 ;;; Code:
  34
  35 (require 'ibuffer)
  36
  37 (eval-when-compile
  38   (require 'ibuf-macs)
  39   (require 'cl))
  40
  41 ;;; Utility functions
  42 (defun ibuffer-delete-alist (key alist)
  43   "Delete all entries in ALIST that have a key equal to KEY."
  44   (let (entry)
  45     (while (setq entry (assoc key alist))
  46       (setq alist (delete entry alist)))
  47     alist))
  48
  49 ;; borrowed from Gnus
  50 (defun ibuffer-remove-duplicates (list)
  51   "Return a copy of LIST with duplicate elements removed."
  52   (let ((new nil)
  53         (tail list))
  54     (while tail
  55       (or (member (car tail) new)
  56           (setq new (cons (car tail) new)))
  57       (setq tail (cdr tail)))
  58     (nreverse new)))
  59
  60 (defun ibuffer-split-list (ibuffer-split-list-fn ibuffer-split-list-elts)
  61   (let ((hip-crowd nil)
  62         (lamers nil))
  63     (dolist (ibuffer-split-list-elt ibuffer-split-list-elts)
  64       (if (funcall ibuffer-split-list-fn ibuffer-split-list-elt)
  65           (push ibuffer-split-list-elt hip-crowd)
  66         (push ibuffer-split-list-elt lamers)))
  67     ;; Too bad Emacs Lisp doesn't have multiple values.
  68     (list (nreverse hip-crowd) (nreverse lamers))))
  69
  70 (defcustom ibuffer-never-show-predicates nil
  71   "A list of predicates (a regexp or function) for buffers not to display.
  72 If a regexp, then it will be matched against the buffer's name.
  73 If a function, it will be called with the buffer as an argument, and
  74 should return non-nil if this buffer should not be shown."
  75   :type '(repeat (choice regexp function))
  76   :group 'ibuffer)
  77
  78 (defcustom ibuffer-always-show-predicates nil
  79   "A list of predicates (a regexp or function) for buffers to always display.
  80 If a regexp, then it will be matched against the buffer's name.
  81 If a function, it will be called with the buffer as an argument, and
  82 should return non-nil if this buffer should be shown.
  83 Note that buffers matching one of these predicates will be shown
  84 regardless of any active filters in this buffer."
  85   :type '(repeat (choice regexp function))
  86   :group 'ibuffer)
  87
  88 (defvar ibuffer-tmp-hide-regexps nil
  89   "A list of regexps which should match buffer names to not show.")
  90
  91 (defvar ibuffer-tmp-show-regexps nil
  92   "A list of regexps which should match buffer names to always show.")
  93
  94 (defvar ibuffer-auto-mode nil
  95   "If non-nil, Ibuffer auto-mode should be enabled for this buffer.
  96 Do not set this variable directly!  Use the function
  97 `ibuffer-auto-mode' instead.")
  98
  99 (defvar ibuffer-auto-buffers-changed nil)
 100
 101 (defcustom ibuffer-saved-filters '(("gnus"
 102                                     ((or (mode . message-mode)
 103                                          (mode . mail-mode)
 104                                          (mode . gnus-group-mode)
 105                                          (mode . gnus-summary-mode)
 106                                          (mode . gnus-article-mode))))
 107                                    ("programming"
 108                                     ((or (mode . emacs-lisp-mode)
 109                                          (mode . cperl-mode)
 110                                          (mode . c-mode)
 111                                          (mode . java-mode)
 112                                          (mode . idl-mode)
 113                                          (mode . lisp-mode)))))
 114
 115   "An alist of filter qualifiers to switch between.
 116
 117 This variable should look like ((\"STRING\" QUALIFIERS)
 118                                 (\"STRING\" QUALIFIERS) ...), where
 119 QUALIFIERS is a list of the same form as
 120 `ibuffer-filtering-qualifiers'.
 121 See also the variables `ibuffer-filtering-qualifiers',
 122 `ibuffer-filtering-alist', and the functions
 123 `ibuffer-switch-to-saved-filters', `ibuffer-save-filters'."
 124   :type '(repeat sexp)
 125   :group 'ibuffer)
 126
 127 (defvar ibuffer-filtering-qualifiers nil
 128   "A list like (SYMBOL . QUALIFIER) which filters the current buffer list.
 129 See also `ibuffer-filtering-alist'.")
 130
 131 ;; This is now frobbed by `define-ibuffer-filter'.
 132 (defvar ibuffer-filtering-alist nil
 133   "An alist of (SYMBOL DESCRIPTION FUNCTION) which describes a filter.
 134
 135 You most likely do not want to modify this variable directly; see
 136 `define-ibuffer-filter'.
 137
 138 SYMBOL is the symbolic name of the filter.  DESCRIPTION is used when
 139 displaying information to the user.  FUNCTION is given a buffer and
 140 the value of the qualifier, and returns non-nil if and only if the
 141 buffer should be displayed.")
 142
 143 (defcustom ibuffer-filter-format-alist nil
 144   "An alist which has special formats used when a filter is active.
 145 The contents of this variable should look like:
 146  ((FILTER (FORMAT FORMAT ...)) (FILTER (FORMAT FORMAT ...)) ...)
 147
 148 For example, suppose that when you add a filter for buffers whose
 149 major mode is `emacs-lisp-mode', you only want to see the mark and the
 150 name of the buffer.  You could accomplish that by adding:
 151  (mode ((mark \" \" name)))
 152 to this variable."
 153   :type '(repeat (list :tag "Association" (symbol :tag "Filter")
 154                        (list :tag "Formats" (repeat (sexp :tag "Format")))))
 155   :group 'ibuffer)
 156
 157 (defvar ibuffer-cached-filter-formats nil)
 158 (defvar ibuffer-compiled-filter-formats nil)
 159
 160 (defvar ibuffer-filter-groups nil
 161   "A list like ((\"NAME\" ((SYMBOL . QUALIFIER) ...) ...) which groups buffers.
 162 The SYMBOL should be one from `ibuffer-filtering-alist'.
 163 The QUALIFIER should be the same as QUALIFIER in
 164 `ibuffer-filtering-qualifiers'.")
 165
 166 (defcustom ibuffer-show-empty-filter-groups t
 167   "If non-nil, then show the names of filter groups which are empty."
 168   :type 'boolean
 169   :group 'ibuffer)
 170
 171 (defcustom ibuffer-saved-filter-groups nil
 172   "An alist of filtering groups to switch between.
 173
 174 This variable should look like ((\"STRING\" QUALIFIERS)
 175                                 (\"STRING\" QUALIFIERS) ...), where
 176 QUALIFIERS is a list of the same form as
 177 `ibuffer-filtering-qualifiers'.
 178
 179 See also the variables `ibuffer-filter-groups',
 180 `ibuffer-filtering-qualifiers', `ibuffer-filtering-alist', and the
 181 functions `ibuffer-switch-to-saved-filter-group',
 182 `ibuffer-save-filter-group'."
 183   :type '(repeat sexp)
 184   :group 'ibuffer)
 185
 186 (defvar ibuffer-hidden-filter-groups nil
 187   "A list of filtering groups which are currently hidden.")
 188
 189 (defvar ibuffer-filter-group-kill-ring nil)
 190
 191 (defcustom ibuffer-old-time 72
 192   "The number of hours before a buffer is considered \"old\"."
 193   :type '(choice (const :tag "72 hours (3 days)" 72)
 194                  (const :tag "48 hours (2 days)" 48)
 195                  (const :tag "24 hours (1 day)" 24)
 196                  (integer :tag "hours"))
 197   :group 'ibuffer)
 198
 199 (defcustom ibuffer-save-with-custom t
 200   "If non-nil, then use Custom to save interactively changed variables.
 201 Currently, this only applies to `ibuffer-saved-filters' and
 202 `ibuffer-saved-filter-groups'."
 203   :type 'boolean
 204   :group 'ibuffer)
 205
 206 (defun ibuffer-ext-visible-p (buf all &optional ibuffer-buf)
 207   (or
 208    (ibuffer-buf-matches-predicates buf ibuffer-tmp-show-regexps)
 209    (and (not
 210          (or
 211           (ibuffer-buf-matches-predicates buf ibuffer-tmp-hide-regexps)
 212           (ibuffer-buf-matches-predicates buf ibuffer-never-show-predicates)))
 213         (or all
 214             (not
 215              (ibuffer-buf-matches-predicates buf ibuffer-maybe-show-predicates)))
 216         (or ibuffer-view-ibuffer
 217             (and ibuffer-buf
 218                  (not (eq ibuffer-buf buf))))
 219         (or
 220          (ibuffer-included-in-filters-p buf ibuffer-filtering-qualifiers)
 221          (ibuffer-buf-matches-predicates buf ibuffer-always-show-predicates)))))
 222
 223 (defun ibuffer-auto-update-changed ()
 224   (when ibuffer-auto-buffers-changed
 225     (setq ibuffer-auto-buffers-changed nil)
 226     (mapcar #'(lambda (buf)
 227                 (ignore-errors
 228                   (with-current-buffer buf
 229                     (when (and ibuffer-auto-mode
 230                                (eq major-mode 'ibuffer-mode))
 231                       (ibuffer-update nil t)))))
 232             (buffer-list))))
 233
 234 ;;;###autoload
 235 (defun ibuffer-auto-mode (&optional arg)
 236   "Toggle use of Ibuffer's auto-update facility.
 237 With numeric ARG, enable auto-update if and only if ARG is positive."
 238   (interactive)
 239   (unless (eq major-mode 'ibuffer-mode)
 240     (error "This buffer is not in Ibuffer mode"))
 241   (set (make-local-variable 'ibuffer-auto-mode)
 242        (if arg
 243            (plusp arg)
 244          (not ibuffer-auto-mode)))
 245   (defadvice get-buffer-create (after ibuffer-notify-create activate)
 246     (setq ibuffer-auto-buffers-changed t))
 247   (defadvice kill-buffer (after ibuffer-notify-kill activate)
 248     (setq ibuffer-auto-buffers-changed t))
 249   (add-hook 'post-command-hook 'ibuffer-auto-update-changed)
 250   (ibuffer-update-mode-name))
 251
 252 ;;;###autoload
 253 (defun ibuffer-mouse-filter-by-mode (event)
 254   "Enable or disable filtering by the major mode chosen via mouse."
 255   (interactive "e")
 256   (ibuffer-interactive-filter-by-mode event))
 257
 258 ;;;###autoload
 259 (defun ibuffer-interactive-filter-by-mode (event-or-point)
 260   "Enable or disable filtering by the major mode at point."
 261   (interactive "d")
 262   (if (eventp event-or-point)
 263       (mouse-set-point event-or-point)
 264     (goto-char event-or-point))
 265   (let ((buf (ibuffer-current-buffer)))
 266     (if (assq 'mode ibuffer-filtering-qualifiers)
 267         (setq ibuffer-filtering-qualifiers
 268               (ibuffer-delete-alist 'mode ibuffer-filtering-qualifiers))
 269       (ibuffer-push-filter (cons 'mode
 270                                 (with-current-buffer buf
 271                                   major-mode)))))
 272   (ibuffer-update nil t))
 273
 274 ;;;###autoload
 275 (defun ibuffer-mouse-toggle-filter-group (event)
 276   "Toggle the display status of the filter group chosen with the mouse."
 277   (interactive "e")
 278   (ibuffer-toggle-filter-group-1 (save-excursion
 279                                    (mouse-set-point event)
 280                                    (point))))
 281
 282 ;;;###autoload
 283 (defun ibuffer-toggle-filter-group ()
 284   "Toggle the display status of the filter group on this line."
 285   (interactive)
 286   (ibuffer-toggle-filter-group-1 (point)))
 287
 288 (defun ibuffer-toggle-filter-group-1 (posn)
 289   (let ((name (get-text-property posn 'ibuffer-filter-group-name)))
 290     (unless (stringp name)
 291       (error "No filtering group name present"))
 292     (if (member name ibuffer-hidden-filter-groups)
 293         (setq ibuffer-hidden-filter-groups
 294               (delete name ibuffer-hidden-filter-groups))
 295       (push name ibuffer-hidden-filter-groups))
 296     (ibuffer-update nil t)))
 297
 298 ;;;###autoload
 299 (defun ibuffer-forward-filter-group (&optional count)
 300   "Move point forwards by COUNT filtering groups."
 301   (interactive "P")
 302   (unless count
 303     (setq count 1))
 304   (when (> count 0)
 305     (when (get-text-property (point) 'ibuffer-filter-group-name)
 306       (goto-char (next-single-property-change
 307                   (point) 'ibuffer-filter-group-name
 308                   nil (point-max))))
 309     (goto-char (next-single-property-change
 310                 (point) 'ibuffer-filter-group-name
 311                 nil (point-max)))
 312     (ibuffer-forward-filter-group (1- count)))
 313   (ibuffer-forward-line 0))
 314
 315 ;;;###autoload
 316 (defun ibuffer-backward-filter-group (&optional count)
 317   "Move point backwards by COUNT filtering groups."
 318   (interactive "P")
 319   (unless count
 320     (setq count 1))
 321   (when (> count 0)
 322     (when (get-text-property (point) 'ibuffer-filter-group-name)
 323       (goto-char (previous-single-property-change
 324                   (point) 'ibuffer-filter-group-name
 325                   nil (point-min))))
 326     (goto-char (previous-single-property-change
 327                 (point) 'ibuffer-filter-group-name
 328                 nil (point-min)))
 329     (ibuffer-backward-filter-group (1- count)))
 330   (when (= (point) (point-min))
 331     (goto-char (point-max))
 332     (ibuffer-backward-filter-group 1))
 333   (ibuffer-forward-line 0))
 334
 335 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe "ibuf-ext.el")
 336 (define-ibuffer-op shell-command-pipe (command)
 337   "Pipe the contents of each marked buffer to shell command COMMAND."
 338   (:interactive "sPipe to shell command: "
 339    :opstring "Shell command executed on"
 340    :modifier-p nil)
 341   (shell-command-on-region
 342    (point-min) (point-max) command
 343    (get-buffer-create "* ibuffer-shell-output*")))
 344
 345 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe-replace "ibuf-ext.el")
 346 (define-ibuffer-op shell-command-pipe-replace (command)
 347   "Replace the contents of marked buffers with output of pipe to COMMAND."
 348   (:interactive "sPipe to shell command (replace): "
 349    :opstring "Buffer contents replaced in"
 350    :active-opstring "replace buffer contents in"
 351    :dangerous t
 352    :modifier-p t)
 353   (with-current-buffer buf
 354     (shell-command-on-region (point-min) (point-max)
 355                              command nil t)))
 356
 357 ;;;###autoload (autoload 'ibuffer-do-shell-command-file "ibuf-ext.el")
 358 (define-ibuffer-op shell-command-file (command)
 359   "Run shell command COMMAND separately on files of marked buffers."
 360   (:interactive "sShell command on buffer's file: "
 361    :opstring "Shell command executed on"
 362    :modifier-p nil)
 363   (shell-command (concat command " "
 364                          (shell-quote-argument
 365                           (if buffer-file-name
 366                               buffer-file-name
 367                             (make-temp-file
 368                              (substring (buffer-name) 0 (min 10 (length (buffer-name))))))))))
 369
 370 ;;;###autoload (autoload 'ibuffer-do-eval "ibuf-ext.el")
 371 (define-ibuffer-op eval (form)
 372   "Evaluate FORM in each of the buffers.
 373 Does not display the buffer during evaluation. See
 374 `ibuffer-do-view-and-eval' for that."
 375   (:interactive "xEval in buffers (form): "
 376    :opstring "evaluated in"
 377    :modifier-p :maybe)
 378   (eval form))
 379
 380 ;;;###autoload (autoload 'ibuffer-do-view-and-eval "ibuf-ext.el")
 381 (define-ibuffer-op view-and-eval (form)
 382   "Evaluate FORM while displaying each of the marked buffers.
 383 To evaluate a form without viewing the buffer, see `ibuffer-do-eval'."
 384   (:interactive "xEval viewing buffers (form): "
 385    :opstring "evaluated in"
 386    :complex t
 387    :modifier-p :maybe)
 388   (let ((ibuffer-buf (current-buffer)))
 389     (unwind-protect
 390         (progn
 391           (switch-to-buffer buf)
 392           (eval form))
 393       (switch-to-buffer ibuffer-buf))))
 394
 395 ;;;###autoload (autoload 'ibuffer-do-rename-uniquely "ibuf-ext.el")
 396 (define-ibuffer-op rename-uniquely ()
 397   "Rename marked buffers as with `rename-uniquely'."
 398   (:opstring "renamed"
 399    :modifier-p t)
 400   (rename-uniquely))
 401
 402 ;;;###autoload (autoload 'ibuffer-do-revert "ibuf-ext.el")
 403 (define-ibuffer-op revert ()
 404   "Revert marked buffers as with `revert-buffer'."
 405   (:dangerous t
 406    :opstring "reverted"
 407    :active-opstring "revert"
 408    :modifier-p :maybe)
 409   (revert-buffer t t))
 410
 411 ;;;###autoload (autoload 'ibuffer-do-replace-regexp "ibuf-ext.el")
 412 (define-ibuffer-op replace-regexp (from-str to-str)
 413   "Perform a `replace-regexp' in marked buffers."
 414   (:interactive
 415    (let* ((from-str (read-from-minibuffer "Replace regexp: "))
 416           (to-str (read-from-minibuffer (concat "Replace " from-str
 417                                                 " with: "))))
 418      (list from-str to-str))
 419    :opstring "replaced in"
 420    :complex t
 421    :modifier-p :maybe)
 422   (save-window-excursion
 423     (switch-to-buffer buf)
 424     (save-excursion
 425       (goto-char (point-min))
 426       (let ((case-fold-search ibuffer-case-fold-search))
 427         (while (re-search-forward from-str nil t)
 428           (replace-match to-str))))
 429     t))
 430
 431 ;;;###autoload (autoload 'ibuffer-do-query-replace "ibuf-ext.el")
 432 (define-ibuffer-op query-replace (&rest args)
 433   "Perform a `query-replace' in marked buffers."
 434   (:interactive
 435    (query-replace-read-args "Query replace" t t)
 436    :opstring "replaced in"
 437    :complex t
 438    :modifier-p :maybe)
 439   (save-window-excursion
 440     (switch-to-buffer buf)
 441     (save-excursion
 442       (let ((case-fold-search ibuffer-case-fold-search))
 443         (goto-char (point-min))
 444         (apply #'query-replace args)))
 445     t))
 446
 447 ;;;###autoload (autoload 'ibuffer-do-query-replace-regexp "ibuf-ext.el")
 448 (define-ibuffer-op query-replace-regexp (&rest args)
 449   "Perform a `query-replace-regexp' in marked buffers."
 450   (:interactive
 451    (query-replace-read-args "Query replace regexp" t t)
 452    :opstring "replaced in"
 453    :complex t
 454    :modifier-p :maybe)
 455   (save-window-excursion
 456     (switch-to-buffer buf)
 457     (save-excursion
 458       (let ((case-fold-search ibuffer-case-fold-search))
 459         (goto-char (point-min))
 460         (apply #'query-replace-regexp args)))
 461     t))
 462
 463 ;;;###autoload (autoload 'ibuffer-do-print "ibuf-ext.el")
 464 (define-ibuffer-op print ()
 465   "Print marked buffers as with `print-buffer'."
 466   (:opstring "printed"
 467    :modifier-p nil)
 468   (print-buffer))
 469
 470 ;;;###autoload
 471 (defun ibuffer-included-in-filters-p (buf filters)
 472   (not
 473    (memq nil ;; a filter will return nil if it failed
 474          (mapcar
 475           ;; filter should be like (TYPE . QUALIFIER), or
 476           ;; (or (TYPE . QUALIFIER) (TYPE . QUALIFIER) ...)
 477           #'(lambda (qual)
 478               (ibuffer-included-in-filter-p buf qual))
 479           filters))))
 480
 481 (defun ibuffer-included-in-filter-p (buf filter)
 482   (if (eq (car filter) 'not)
 483       (not (ibuffer-included-in-filter-p-1 buf (cdr filter)))
 484     (ibuffer-included-in-filter-p-1 buf filter)))
 485
 486 (defun ibuffer-included-in-filter-p-1 (buf filter)
 487   (not
 488    (not
 489     (case (car filter)
 490       (or
 491        (memq t (mapcar #'(lambda (x)
 492                            (ibuffer-included-in-filter-p buf x))
 493                        (cdr filter))))
 494       (saved
 495        (let ((data
 496               (assoc (cdr filter)
 497                      ibuffer-saved-filters)))
 498          (unless data
 499            (ibuffer-filter-disable)
 500            (error "Unknown saved filter %s" (cdr filter)))
 501          (ibuffer-included-in-filters-p buf (cadr data))))
 502       (t
 503        (let ((filterdat (assq (car filter)
 504                               ibuffer-filtering-alist)))
 505          ;; filterdat should be like (TYPE DESCRIPTION FUNC)
 506          ;; just a sanity check
 507         (unless filterdat
 508           (ibuffer-filter-disable)
 509           (error "Undefined filter %s" (car filter)))
 510         (not
 511          (not
 512           (funcall (caddr filterdat)
 513                    buf
 514                    (cdr filter))))))))))
 515
 516 (defun ibuffer-generate-filter-groups (bmarklist)
 517   (let ((filter-group-alist (append ibuffer-filter-groups
 518                                        (list (cons "Default" nil)))))
 519 ;;     (dolist (hidden ibuffer-hidden-filter-groups)
 520 ;;       (setq filter-group-alist (ibuffer-delete-alist
 521 ;;                                 hidden filter-group-alist)))
 522     (let ((vec (make-vector (length filter-group-alist) nil))
 523           (i 0))
 524       (dolist (filtergroup filter-group-alist)
 525         (let ((filterset (cdr filtergroup)))
 526           (multiple-value-bind (hip-crowd lamers)
 527               (ibuffer-split-list (lambda (bufmark)
 528                                     (ibuffer-included-in-filters-p (car bufmark)
 529                                                                    filterset))
 530                                   bmarklist)
 531             (aset vec i hip-crowd)
 532             (incf i)
 533             (setq bmarklist lamers))))
 534       (let ((ret nil))
 535         (dotimes (j i ret)
 536           (push (cons (car (nth j filter-group-alist))
 537                       (aref vec j))
 538                 ret))))))
 539
 540 ;;;###autoload
 541 (defun ibuffer-filters-to-filter-group (name)
 542   "Make the current filters into a filtering group."
 543   (interactive "sName for filtering group: ")
 544   (when (null ibuffer-filtering-qualifiers)
 545     (error "No filters in effect"))
 546   (push (cons name ibuffer-filtering-qualifiers) ibuffer-filter-groups)
 547   (ibuffer-filter-disable))
 548
 549 ;;;###autoload
 550 (defun ibuffer-set-filter-groups-by-mode ()
 551   "Set the current filter groups to filter by mode."
 552   (interactive)
 553   (setq ibuffer-filter-groups
 554         (mapcar (lambda (mode)
 555                   (cons (format "%s" mode) `((mode . ,mode))))
 556                 (let ((modes
 557                        (ibuffer-remove-duplicates
 558                         (mapcar (lambda (buf)
 559                                   (with-current-buffer buf major-mode))
 560                                 (buffer-list)))))
 561                   (if ibuffer-view-ibuffer
 562                       modes
 563                     (delq 'ibuffer-mode modes)))))
 564   (ibuffer-update nil t))
 565
 566 ;;;###autoload
 567 (defun ibuffer-pop-filter-group ()
 568   "Remove the first filter group."
 569   (interactive)
 570   (when (null ibuffer-filter-groups)
 571     (error "No filter groups active"))
 572   (setq ibuffer-hidden-filter-groups
 573         (delete (pop ibuffer-filter-groups)
 574                 ibuffer-hidden-filter-groups))
 575   (ibuffer-update nil t))
 576
 577 (defun ibuffer-read-filter-group-name (msg &optional nodefault noerror)
 578   (when (and (not noerror) (null ibuffer-filter-groups))
 579     (error "No filter groups active"))
 580   (let ((groups (mapcar #'car ibuffer-filter-groups)))
 581     (completing-read msg (if nodefault
 582                              groups
 583                            (cons "Default" groups))
 584                      nil t)))
 585
 586 ;;;###autoload
 587 (defun ibuffer-decompose-filter-group (group)
 588   "Decompose the filter group GROUP into active filters."
 589   (interactive
 590    (list (ibuffer-read-filter-group-name "Decompose filter group: " t)))
 591   (let ((data (cdr (assoc group ibuffer-filter-groups))))
 592     (setq ibuffer-filter-groups (ibuffer-delete-alist
 593                                  group ibuffer-filter-groups)
 594           ibuffer-filtering-qualifiers data))
 595   (ibuffer-update nil t))
 596
 597 ;;;###autoload
 598 (defun ibuffer-clear-filter-groups ()
 599   "Remove all filter groups."
 600   (interactive)
 601   (setq ibuffer-filter-groups nil
 602         ibuffer-hidden-filter-groups nil)
 603   (ibuffer-update nil t))
 604
 605 (defun ibuffer-current-filter-groups-with-position ()
 606   (save-excursion
 607     (goto-char (point-min))
 608     (let ((pos nil)
 609           (result nil))
 610       (while (and (not (eobp))
 611                   (setq pos (next-single-property-change
 612                              (point) 'ibuffer-filter-group-name)))
 613         (goto-char pos)
 614         (push (cons (get-text-property (point) 'ibuffer-filter-group-name)
 615                     pos)
 616               result)
 617         (goto-char (next-single-property-change
 618                     pos 'ibuffer-filter-group-name)))
 619       (nreverse result))))
 620
 621 ;;;###autoload
 622 (defun ibuffer-jump-to-filter-group (name)
 623   "Move point to the filter group whose name is NAME."
 624   (interactive
 625    (list (ibuffer-read-filter-group-name "Jump to filter group: ")))
 626   (ibuffer-aif (assoc name (ibuffer-current-filter-groups-with-position))
 627       (goto-char (cdr it))
 628     (error "No filter group with name %s" name)))
 629
 630 ;;;###autoload
 631 (defun ibuffer-kill-filter-group (name)
 632   "Kill the filter group named NAME.
 633 The group will be added to `ibuffer-filter-group-kill-ring'."
 634   (interactive (list (ibuffer-read-filter-group-name "Kill filter group: " t)))
 635   (when (equal name "Default")
 636     (error "Can't kill default filter group"))
 637   (ibuffer-aif (assoc name ibuffer-filter-groups)
 638       (progn
 639         (push (copy-tree it) ibuffer-filter-group-kill-ring)
 640         (setq ibuffer-filter-groups (ibuffer-delete-alist
 641                                      name ibuffer-filter-groups))
 642         (setq ibuffer-hidden-filter-groups
 643               (delete name ibuffer-hidden-filter-groups)))
 644     (error "No filter group with name \"%s\"" name))
 645   (ibuffer-update nil t))
 646
 647 ;;;###autoload
 648 (defun ibuffer-kill-line (&optional arg interactive-p)
 649   "Kill the filter group at point.
 650 See also `ibuffer-kill-filter-group'."
 651   (interactive "P\np")
 652   (ibuffer-aif (save-excursion
 653                  (ibuffer-forward-line 0)
 654                  (get-text-property (point) 'ibuffer-filter-group-name))
 655       (progn
 656         (ibuffer-kill-filter-group it))
 657       (funcall (if interactive-p #'call-interactively #'funcall)
 658                #'kill-line arg)))
 659
 660 (defun ibuffer-insert-filter-group-before (newgroup group)
 661   (let* ((found nil)
 662          (pos (let ((groups (mapcar #'car ibuffer-filter-groups))
 663                     (res 0))
 664                 (while groups
 665                   (if (equal (car groups) group)
 666                       (setq found t
 667                             groups nil)
 668                     (incf res)
 669                     (setq groups (cdr groups))))
 670                 res)))
 671     (cond ((not found)
 672            (setq ibuffer-filter-groups
 673                  (nconc ibuffer-filter-groups (list newgroup))))
 674           ((zerop pos)
 675            (push newgroup ibuffer-filter-groups))
 676           (t
 677            (let ((cell (nthcdr pos ibuffer-filter-groups)))
 678              (setf (cdr cell) (cons (car cell) (cdr cell)))
 679              (setf (car cell) newgroup))))))
 680
 681 ;;;###autoload
 682 (defun ibuffer-yank ()
 683   "Yank the last killed filter group before group at point."
 684   (interactive)
 685   (ibuffer-yank-filter-group
 686    (or (get-text-property (point) 'ibuffer-filter-group-name)
 687        (get-text-property (point) 'ibuffer-filter-group)
 688        (error "No filter group at point"))))
 689
 690 ;;;###autoload
 691 (defun ibuffer-yank-filter-group (name)
 692   "Yank the last killed filter group before group named NAME."
 693   (interactive (list (ibuffer-read-filter-group-name
 694                         "Yank filter group before group: ")))
 695   (unless ibuffer-filter-group-kill-ring
 696     (error "The Ibuffer filter group kill-ring is empty"))
 697   (save-excursion
 698     (ibuffer-forward-line 0)
 699     (ibuffer-insert-filter-group-before (pop ibuffer-filter-group-kill-ring)
 700                                         name))
 701   (ibuffer-update nil t))
 702
 703 ;;;###autoload
 704 (defun ibuffer-save-filter-groups (name groups)
 705   "Save all active filter groups GROUPS as NAME.
 706 They are added to `ibuffer-saved-filter-groups'.  Interactively,
 707 prompt for NAME, and use the current filters."
 708   (interactive
 709    (if (null ibuffer-filter-groups)
 710        (error "No filter groups active")
 711      (list
 712       (read-from-minibuffer "Save current filter groups as: ")
 713       ibuffer-filter-groups)))
 714   (ibuffer-aif (assoc name ibuffer-saved-filter-groups)
 715       (setcdr it groups)
 716     (push (cons name groups) ibuffer-saved-filter-groups))
 717   (ibuffer-maybe-save-stuff)
 718   (ibuffer-update-mode-name))
 719
 720 ;;;###autoload
 721 (defun ibuffer-delete-saved-filter-groups (name)
 722   "Delete saved filter groups with NAME.
 723 They are removed from `ibuffer-saved-filter-groups'."
 724   (interactive
 725    (list
 726     (if (null ibuffer-saved-filter-groups)
 727         (error "No saved filter groups")
 728       (completing-read "Delete saved filter group: "
 729                        ibuffer-saved-filter-groups nil t))))
 730   (setq ibuffer-saved-filter-groups
 731         (ibuffer-delete-alist name ibuffer-saved-filter-groups))
 732   (ibuffer-maybe-save-stuff)
 733   (ibuffer-update nil t))
 734
 735 ;;;###autoload
 736 (defun ibuffer-switch-to-saved-filter-groups (name)
 737   "Set this buffer's filter groups to saved version with NAME.
 738 The value from `ibuffer-saved-filters' is used.
 739 If prefix argument ADD is non-nil, then add the saved filters instead
 740 of replacing the current filters."
 741   (interactive
 742    (list
 743     (if (null ibuffer-saved-filter-groups)
 744         (error "No saved filters")
 745       (completing-read "Switch to saved filter group: "
 746                        ibuffer-saved-filter-groups nil t))))
 747   (setq ibuffer-filter-groups (cdr (assoc name ibuffer-saved-filter-groups))
 748         ibuffer-hidden-filter-groups nil)
 749   (ibuffer-update nil t))
 750
 751 ;;;###autoload
 752 (defun ibuffer-filter-disable ()
 753   "Disable all filters currently in effect in this buffer."
 754   (interactive)
 755   (setq ibuffer-filtering-qualifiers nil)
 756   (let ((buf (ibuffer-current-buffer)))
 757     (ibuffer-update nil t)
 758     (when buf
 759       (ibuffer-jump-to-buffer (buffer-name buf)))))
 760
 761 ;;;###autoload
 762 (defun ibuffer-pop-filter ()
 763   "Remove the top filter in this buffer."
 764   (interactive)
 765   (when (null ibuffer-filtering-qualifiers)
 766     (error "No filters in effect"))
 767   (pop ibuffer-filtering-qualifiers)
 768   (let ((buf (ibuffer-current-buffer)))
 769     (ibuffer-update nil t)
 770     (when buf
 771       (ibuffer-jump-to-buffer (buffer-name buf)))))
 772
 773 (defun ibuffer-push-filter (qualifier)
 774   "Add QUALIFIER to `ibuffer-filtering-qualifiers'."
 775   (push qualifier ibuffer-filtering-qualifiers))
 776
 777 ;;;###autoload
 778 (defun ibuffer-decompose-filter ()
 779   "Separate the top compound filter (OR, NOT, or SAVED) in this buffer.
 780
 781 This means that the topmost filter on the filtering stack, which must
 782 be a complex filter like (OR [name: foo] [mode: bar-mode]), will be
 783 turned into two separate filters [name: foo] and [mode: bar-mode]."
 784   (interactive)
 785   (when (null ibuffer-filtering-qualifiers)
 786     (error "No filters in effect"))
 787   (let ((lim (pop ibuffer-filtering-qualifiers)))
 788     (case (car lim)
 789       (or
 790        (setq ibuffer-filtering-qualifiers (append
 791                                           (cdr lim)
 792                                           ibuffer-filtering-qualifiers)))
 793       (saved
 794        (let ((data
 795               (assoc (cdr lim)
 796                      ibuffer-saved-filters)))
 797          (unless data
 798            (ibuffer-filter-disable)
 799            (error "Unknown saved filter %s" (cdr lim)))
 800          (setq ibuffer-filtering-qualifiers (append
 801                                             (cadr data)
 802                                             ibuffer-filtering-qualifiers))))
 803       (not
 804        (push (cdr lim)
 805              ibuffer-filtering-qualifiers))
 806       (t
 807        (error "Filter type %s is not compound" (car lim)))))
 808   (ibuffer-update nil t))
 809
 810 ;;;###autoload
 811 (defun ibuffer-exchange-filters ()
 812   "Exchange the top two filters on the stack in this buffer."
 813   (interactive)
 814   (when (< (length ibuffer-filtering-qualifiers)
 815            2)
 816     (error "Need two filters to exchange"))
 817   (let ((first (pop ibuffer-filtering-qualifiers))
 818         (second (pop ibuffer-filtering-qualifiers)))
 819     (push first ibuffer-filtering-qualifiers)
 820     (push second ibuffer-filtering-qualifiers))
 821   (ibuffer-update nil t))
 822
 823 ;;;###autoload
 824 (defun ibuffer-negate-filter ()
 825   "Negate the sense of the top filter in the current buffer."
 826   (interactive)
 827   (when (null ibuffer-filtering-qualifiers)
 828     (error "No filters in effect"))
 829   (let ((lim (pop ibuffer-filtering-qualifiers)))
 830     (push (if (eq (car lim) 'not)
 831               (cdr lim)
 832             (cons 'not lim))
 833           ibuffer-filtering-qualifiers))
 834   (ibuffer-update nil t))
 835
 836 ;;;###autoload
 837 (defun ibuffer-or-filter (&optional reverse)
 838   "Replace the top two filters in this buffer with their logical OR.
 839 If optional argument REVERSE is non-nil, instead break the top OR
 840 filter into parts."
 841   (interactive "P")
 842   (if reverse
 843       (progn
 844         (when (or (null ibuffer-filtering-qualifiers)
 845                   (not (eq 'or (caar ibuffer-filtering-qualifiers))))
 846           (error "Top filter is not an OR"))
 847         (let ((lim (pop ibuffer-filtering-qualifiers)))
 848           (setq ibuffer-filtering-qualifiers
 849                 (nconc (cdr lim) ibuffer-filtering-qualifiers))))
 850     (when (< (length ibuffer-filtering-qualifiers) 2)
 851       (error "Need two filters to OR"))
 852     ;; If the second filter is an OR, just add to it.
 853     (let ((first (pop ibuffer-filtering-qualifiers))
 854           (second (pop ibuffer-filtering-qualifiers)))
 855       (if (eq 'or (car second))
 856           (push (nconc (list 'or first) (cdr second))
 857                 ibuffer-filtering-qualifiers)
 858         (push (list 'or first second)
 859               ibuffer-filtering-qualifiers))))
 860   (ibuffer-update nil t))
 861
 862 (defun ibuffer-maybe-save-stuff ()
 863   (when ibuffer-save-with-custom
 864     (if (fboundp 'customize-save-variable)
 865         (progn
 866           (customize-save-variable 'ibuffer-saved-filters
 867                                    ibuffer-saved-filters)
 868           (customize-save-variable 'ibuffer-saved-filter-groups
 869                                    ibuffer-saved-filter-groups))
 870       (message "Not saved permanently: Customize not available"))))
 871
 872 ;;;###autoload
 873 (defun ibuffer-save-filters (name filters)
 874   "Save FILTERS in this buffer with name NAME in `ibuffer-saved-filters'.
 875 Interactively, prompt for NAME, and use the current filters."
 876   (interactive
 877    (if (null ibuffer-filtering-qualifiers)
 878        (error "No filters currently in effect")
 879      (list
 880       (read-from-minibuffer "Save current filters as: ")
 881       ibuffer-filtering-qualifiers)))
 882   (ibuffer-aif (assoc name ibuffer-saved-filters)
 883       (setcdr it filters)
 884     (push (list name filters) ibuffer-saved-filters))
 885   (ibuffer-maybe-save-stuff)
 886   (ibuffer-update-mode-name))
 887
 888 ;;;###autoload
 889 (defun ibuffer-delete-saved-filters (name)
 890   "Delete saved filters with NAME from `ibuffer-saved-filters'."
 891   (interactive
 892    (list
 893     (if (null ibuffer-saved-filters)
 894         (error "No saved filters")
 895       (completing-read "Delete saved filters: "
 896                        ibuffer-saved-filters nil t))))
 897   (setq ibuffer-saved-filters
 898         (ibuffer-delete-alist name ibuffer-saved-filters))
 899   (ibuffer-maybe-save-stuff)
 900   (ibuffer-update nil t))
 901
 902 ;;;###autoload
 903 (defun ibuffer-add-saved-filters (name)
 904   "Add saved filters from `ibuffer-saved-filters' to this buffer's filters."
 905   (interactive
 906    (list
 907     (if (null ibuffer-saved-filters)
 908         (error "No saved filters")
 909       (completing-read "Add saved filters: "
 910                        ibuffer-saved-filters nil t))))
 911   (push (cons 'saved name) ibuffer-filtering-qualifiers)
 912   (ibuffer-update nil t))
 913
 914 ;;;###autoload
 915 (defun ibuffer-switch-to-saved-filters (name)
 916   "Set this buffer's filters to filters with NAME from `ibuffer-saved-filters'.
 917 If prefix argument ADD is non-nil, then add the saved filters instead
 918 of replacing the current filters."
 919   (interactive
 920    (list
 921     (if (null ibuffer-saved-filters)
 922         (error "No saved filters")
 923       (completing-read "Switch to saved filters: "
 924                        ibuffer-saved-filters nil t))))
 925   (setq ibuffer-filtering-qualifiers (list (cons 'saved name)))
 926   (ibuffer-update nil t))
 927
 928 (defun ibuffer-format-filter-group-data (filter)
 929   (if (equal filter "Default")
 930       ""
 931     (concat "Filter:" (mapconcat #'ibuffer-format-qualifier
 932                                  (cdr (assq filter ibuffer-filter-groups))
 933                                  " "))))
 934
 935 (defun ibuffer-format-qualifier (qualifier)
 936   (if (eq (car-safe qualifier) 'not)
 937       (concat " [NOT" (ibuffer-format-qualifier-1 (cdr qualifier)) "]")
 938     (ibuffer-format-qualifier-1 qualifier)))
 939
 940 (defun ibuffer-format-qualifier-1 (qualifier)
 941   (case (car qualifier)
 942     (saved
 943      (concat " [filter: " (cdr qualifier) "]"))
 944     (or
 945      (concat " [OR" (mapconcat #'ibuffer-format-qualifier
 946                                (cdr qualifier) "") "]"))
 947     (t
 948      (let ((type (assq (car qualifier) ibuffer-filtering-alist)))
 949        (unless qualifier
 950          (error "Ibuffer: bad qualifier %s" qualifier))
 951        (concat " [" (cadr type) ": " (format "%s]" (cdr qualifier)))))))
 952
 953
 954 (defun ibuffer-list-buffer-modes ()
 955   "Create an alist of buffer modes currently in use.
 956 The list returned will be of the form (\"MODE-NAME\" . MODE-SYMBOL)."
 957   (let ((bufs (buffer-list))
 958         (modes)
 959         (this-mode))
 960     (while bufs
 961       (setq this-mode
 962             (with-current-buffer
 963                 (car bufs)
 964               major-mode)
 965             bufs (cdr bufs))
 966       (add-to-list
 967        'modes
 968        `(,(symbol-name this-mode) .
 969          ,this-mode)))
 970     modes))
 971
 972
 973 ;;; Extra operation definitions
 974
 975 ;;;###autoload (autoload 'ibuffer-filter-by-mode "ibuf-ext.el")
 976 (define-ibuffer-filter mode
 977   "Toggle current view to buffers with major mode QUALIFIER."
 978   (:description "major mode"
 979    :reader
 980    (intern
 981     (completing-read "Filter by major mode: " obarray
 982                      #'(lambda (e)
 983                          (string-match "-mode$"
 984                                        (symbol-name e)))
 985                      t
 986                      (let ((buf (ibuffer-current-buffer)))
 987                        (if (and buf (buffer-live-p buf))
 988                            (with-current-buffer buf
 989                              (symbol-name major-mode))
 990                          "")))))
 991   (eq qualifier (with-current-buffer buf major-mode)))
 992
 993 ;;;###autoload (autoload 'ibuffer-filter-by-used-mode "ibuf-ext.el")
 994 (define-ibuffer-filter used-mode
 995   "Toggle current view to buffers with major mode QUALIFIER.
 996 Called interactively, this function allows selection of modes
 997 currently used by buffers."
 998   (:description "major mode in use"
 999                 :reader
1000                 (intern
1001                  (completing-read "Filter by major mode: "
1002                                   (ibuffer-list-buffer-modes)
1003                                   nil
1004                                   t
1005                                   (let ((buf (ibuffer-current-buffer)))
1006                                     (if (and buf (buffer-live-p buf))
1007                                         (with-current-buffer buf
1008                                           (symbol-name major-mode))
1009                                       "")))))
1010   (eq qualifier (with-current-buffer buf major-mode)))
1011
1012 ;;;###autoload (autoload 'ibuffer-filter-by-name "ibuf-ext.el")
1013 (define-ibuffer-filter name
1014   "Toggle current view to buffers with name matching QUALIFIER."
1015   (:description "buffer name"
1016    :reader (read-from-minibuffer "Filter by name (regexp): "))
1017   (string-match qualifier (buffer-name buf)))
1018
1019 ;;;###autoload (autoload 'ibuffer-filter-by-filename "ibuf-ext.el")
1020 (define-ibuffer-filter filename
1021   "Toggle current view to buffers with filename matching QUALIFIER."
1022   (:description "filename"
1023    :reader (read-from-minibuffer "Filter by filename (regexp): "))
1024   (ibuffer-awhen (with-current-buffer buf
1025                    (or buffer-file-name
1026                        (and (boundp 'dired-directory)
1027                             (if (stringp dired-directory)
1028                                 dired-directory
1029                               (car dired-directory))
1030                             (expand-file-name dired-directory))))
1031     (string-match qualifier it)))
1032
1033 ;;;###autoload (autoload 'ibuffer-filter-by-size-gt  "ibuf-ext.el")
1034 (define-ibuffer-filter size-gt
1035   "Toggle current view to buffers with size greater than QUALIFIER."
1036   (:description "size greater than"
1037    :reader
1038    (string-to-number (read-from-minibuffer "Filter by size greater than: ")))
1039   (> (with-current-buffer buf (buffer-size))
1040      qualifier))
1041
1042 ;;;###autoload (autoload 'ibuffer-filter-by-size-lt  "ibuf-ext.el")
1043 (define-ibuffer-filter size-lt
1044    "Toggle current view to buffers with size less than QUALIFIER."
1045   (:description "size less than"
1046    :reader
1047    (string-to-number (read-from-minibuffer "Filter by size less than: ")))
1048   (< (with-current-buffer buf (buffer-size))
1049      qualifier))
1050
1051 ;;;###autoload (autoload 'ibuffer-filter-by-content "ibuf-ext.el")
1052 (define-ibuffer-filter content
1053    "Toggle current view to buffers whose contents match QUALIFIER."
1054   (:description "content"
1055    :reader (read-from-minibuffer "Filter by content (regexp): "))
1056   (with-current-buffer buf
1057     (save-excursion
1058       (goto-char (point-min))
1059       (re-search-forward qualifier nil t))))
1060
1061 ;;;###autoload (autoload 'ibuffer-filter-by-predicate "ibuf-ext.el")
1062 (define-ibuffer-filter predicate
1063    "Toggle current view to buffers for which QUALIFIER returns non-nil."
1064   (:description "predicate"
1065    :reader (read-minibuffer "Filter by predicate (form): "))
1066   (with-current-buffer buf
1067     (eval qualifier)))
1068
1069 ;;; Sorting
1070
1071 ;;;###autoload
1072 (defun ibuffer-toggle-sorting-mode ()
1073   "Toggle the current sorting mode.
1074 Default sorting modes are:
1075  Recency - the last time the buffer was viewed
1076  Name - the name of the buffer
1077  Major Mode - the name of the major mode of the buffer
1078  Size - the size of the buffer"
1079   (interactive)
1080   (let ((modes (mapcar 'car ibuffer-sorting-functions-alist)))
1081     (add-to-list 'modes 'recency)
1082     (setq modes (sort modes 'string-lessp))
1083     (let ((next (or (car-safe (cdr-safe (memq ibuffer-sorting-mode modes)))
1084                     (car modes))))
1085       (setq ibuffer-sorting-mode next)
1086       (message "Sorting by %s" next)))
1087   (ibuffer-redisplay t))
1088
1089 ;;;###autoload
1090 (defun ibuffer-invert-sorting ()
1091   "Toggle whether or not sorting is in reverse order."
1092   (interactive)
1093   (setq ibuffer-sorting-reversep (not ibuffer-sorting-reversep))
1094   (message "Sorting order %s"
1095            (if ibuffer-sorting-reversep
1096                "reversed"
1097              "normal"))
1098   (ibuffer-redisplay t))
1099
1100 ;;;###autoload (autoload 'ibuffer-do-sort-by-major-mode "ibuf-ext.el")
1101 (define-ibuffer-sorter major-mode
1102   "Sort the buffers by major modes.
1103 Ordering is lexicographic."
1104   (:description "major mode")
1105   (string-lessp (downcase
1106                  (symbol-name (with-current-buffer
1107                                   (car a)
1108                                 major-mode)))
1109                 (downcase
1110                  (symbol-name (with-current-buffer
1111                                   (car b)
1112                                 major-mode)))))
1113
1114 ;;;###autoload (autoload 'ibuffer-do-sort-by-mode-name "ibuf-ext.el")
1115 (define-ibuffer-sorter mode-name
1116   "Sort the buffers by their mode name.
1117 Ordering is lexicographic."
1118   (:description "major mode name")
1119   (string-lessp (downcase
1120                   (with-current-buffer
1121                       (car a)
1122                     mode-name))
1123                 (downcase
1124                  (with-current-buffer
1125                      (car b)
1126                    mode-name))))
1127
1128 ;;;###autoload (autoload 'ibuffer-do-sort-by-alphabetic "ibuf-ext.el")
1129 (define-ibuffer-sorter alphabetic
1130   "Sort the buffers by their names.
1131 Ordering is lexicographic."
1132   (:description "buffer name")
1133   (string-lessp
1134    (buffer-name (car a))
1135    (buffer-name (car b))))
1136
1137 ;;;###autoload (autoload 'ibuffer-do-sort-by-size "ibuf-ext.el")
1138 (define-ibuffer-sorter size
1139  "Sort the buffers by their size."
1140   (:description "size")
1141   (< (with-current-buffer (car a)
1142        (buffer-size))
1143      (with-current-buffer (car b)
1144        (buffer-size))))
1145
1146 ;;; Functions to emulate bs.el
1147
1148 ;;;###autoload
1149 (defun ibuffer-bs-show ()
1150   "Emulate `bs-show' from the bs.el package."
1151   (interactive)
1152   (ibuffer t "*Ibuffer-bs*" '((filename . ".*")) nil t)
1153   (define-key (current-local-map) "a" 'ibuffer-bs-toggle-all))
1154
1155 (defun ibuffer-bs-toggle-all ()
1156   "Emulate `bs-toggle-show-all' from the bs.el package."
1157   (interactive)
1158   (if ibuffer-filtering-qualifiers
1159       (ibuffer-pop-filter)
1160     (progn (ibuffer-push-filter '(filename . ".*"))
1161            (ibuffer-update nil t))))
1162
1163 ;;; Handy functions
1164
1165 ;;;###autoload
1166 (defun ibuffer-add-to-tmp-hide (regexp)
1167   "Add REGEXP to `ibuffer-tmp-hide-regexps'.
1168 This means that buffers whose name matches REGEXP will not be shown
1169 for this Ibuffer session."
1170   (interactive
1171    (list
1172     (read-from-minibuffer "Never show buffers matching: "
1173                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1174   (push regexp ibuffer-tmp-hide-regexps))
1175
1176 ;;;###autoload
1177 (defun ibuffer-add-to-tmp-show (regexp)
1178   "Add REGEXP to `ibuffer-tmp-show-regexps'.
1179 This means that buffers whose name matches REGEXP will always be shown
1180 for this Ibuffer session."
1181   (interactive
1182    (list
1183     (read-from-minibuffer "Always show buffers matching: "
1184                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1185   (push regexp ibuffer-tmp-show-regexps))
1186
1187 ;;;###autoload
1188 (defun ibuffer-forward-next-marked (&optional count mark direction)
1189   "Move forward by COUNT marked buffers (default 1).
1190
1191 If MARK is non-nil, it should be a character denoting the type of mark
1192 to move by.  The default is `ibuffer-marked-char'.
1193
1194 If DIRECTION is non-nil, it should be an integer; negative integers
1195 mean move backwards, non-negative integers mean move forwards."
1196   (interactive "P")
1197   (unless count
1198     (setq count 1))
1199   (unless mark
1200     (setq mark ibuffer-marked-char))
1201   (unless direction
1202     (setq direction 1))
1203   ;; Skip the title
1204   (ibuffer-forward-line 0)
1205   (let ((opos (point))
1206         curmark)
1207     (ibuffer-forward-line direction)
1208     (while (not (or (= (point) opos)
1209                     (eq (setq curmark (ibuffer-current-mark))
1210                         mark)))
1211       (ibuffer-forward-line direction))
1212     (when (and (= (point) opos)
1213                (not (eq (ibuffer-current-mark) mark)))
1214       (error "No buffers with mark %c" mark))))
1215
1216 ;;;###autoload
1217 (defun ibuffer-backwards-next-marked (&optional count mark)
1218    "Move backwards by COUNT marked buffers (default 1).
1219
1220 If MARK is non-nil, it should be a character denoting the type of mark
1221 to move by.  The default is `ibuffer-marked-char'."
1222    (interactive "P")
1223    (ibuffer-forward-next-marked count mark -1))
1224
1225 ;;;###autoload
1226 (defun ibuffer-do-kill-lines ()
1227   "Hide all of the currently marked lines."
1228   (interactive)
1229   (if (= (ibuffer-count-marked-lines) 0)
1230       (message "No buffers marked; use 'm' to mark a buffer")
1231     (let ((count
1232            (ibuffer-map-marked-lines
1233             #'(lambda (buf mark)
1234                 'kill))))
1235       (message "Killed %s lines" count))))
1236
1237 ;;;###autoload
1238 (defun ibuffer-jump-to-buffer (name)
1239   "Move point to the buffer whose name is NAME.
1240
1241 If called interactively, prompt for a buffer name and go to the
1242 corresponding line in the Ibuffer buffer.  If said buffer is in a
1243 hidden group filter, open it.
1244
1245 If `ibuffer-jump-offer-only-visible-buffers' is non-nil, only offer
1246 visible buffers in the completion list.  Calling the command with
1247 a prefix argument reverses the meaning of that variable."
1248   (interactive (list
1249                 (let ((only-visible ibuffer-jump-offer-only-visible-buffers))
1250                   (when current-prefix-arg
1251                     (setq only-visible (not only-visible)))
1252                   (if only-visible
1253                       (let ((table (mapcar #'(lambda (x)
1254                                                (buffer-name (car x)))
1255                                            (ibuffer-current-state-list))))
1256                         (when (null table)
1257                           (error "No buffers!"))
1258                         (completing-read "Jump to buffer: "
1259                                          table nil t))
1260                     (read-buffer "Jump to buffer: " nil t)))))
1261   (when (not (string= "" name))
1262     (let (buf-point)
1263       ;; Blindly search for our buffer: it is very likely that it is
1264       ;; not in a hidden filter group.
1265       (ibuffer-map-lines #'(lambda (buf marks)
1266                              (when (string= (buffer-name buf) name)
1267                                (setq buf-point (point))
1268                                nil))
1269                          t nil)
1270       (when (and
1271              (null buf-point)
1272              (not (null ibuffer-hidden-filter-groups)))
1273         ;; We did not find our buffer.  It must be in a hidden filter
1274         ;; group, so go through all hidden filter groups to find it.
1275         (catch 'found
1276           (dolist (group ibuffer-hidden-filter-groups)
1277             (ibuffer-jump-to-filter-group group)
1278             (ibuffer-toggle-filter-group)
1279             (ibuffer-map-lines #'(lambda (buf marks)
1280                                    (when (string= (buffer-name buf) name)
1281                                      (setq buf-point (point))
1282                                      nil))
1283                                t group)
1284             (if buf-point
1285                 (throw 'found nil)
1286               (ibuffer-toggle-filter-group)))))
1287       (if (null buf-point)
1288           ;; Still not found even though we expanded all hidden filter
1289           ;; groups: that must be because it's hidden by predicate:
1290           ;; we won't bother trying to display it.
1291           (error "No buffer with name %s" name)
1292         (goto-char buf-point)))))
1293
1294 ;;;###autoload
1295 (defun ibuffer-diff-with-file ()
1296   "View the differences between this buffer and its associated file.
1297 This requires the external program \"diff\" to be in your `exec-path'."
1298   (interactive)
1299   (let ((buf (ibuffer-current-buffer)))
1300     (unless (buffer-live-p buf)
1301       (error "Buffer %s has been killed" buf))
1302     (diff-buffer-with-file buf)))
1303
1304 ;;;###autoload
1305 (defun ibuffer-copy-filename-as-kill (&optional arg)
1306   "Copy filenames of marked buffers into the kill ring.
1307
1308 The names are separated by a space.
1309 If a buffer has no filename, it is ignored.
1310
1311 With no prefix arg, use the filename sans its directory of each marked file.
1312 With a zero prefix arg, use the complete filename of each marked file.
1313 With \\[universal-argument], use the filename of each marked file relative
1314 to `ibuffer-default-directory' iff non-nil, otherwise `default-directory'.
1315
1316 You can then feed the file name(s) to other commands with \\[yank]."
1317   (interactive "p")
1318   (if (zerop (ibuffer-count-marked-lines))
1319       (message "No buffers marked; use 'm' to mark a buffer")
1320     (let ((ibuffer-copy-filename-as-kill-result "")
1321           (type (cond ((zerop arg)
1322                        'full)
1323                       ((= arg 4)
1324                        'relative)
1325                       (t
1326                        'name))))
1327       (ibuffer-map-marked-lines
1328        #'(lambda (buf mark)
1329            (setq ibuffer-copy-filename-as-kill-result
1330                  (concat ibuffer-copy-filename-as-kill-result
1331                          (let ((name (buffer-file-name buf)))
1332                            (if name
1333                                (case type
1334                                  (full
1335                                   name)
1336                                  (relative
1337                                   (file-relative-name
1338                                    name (or ibuffer-default-directory
1339                                             default-directory)))
1340                                  (t
1341                                   (file-name-nondirectory name)))
1342                              ""))
1343                          " "))))
1344       (kill-new ibuffer-copy-filename-as-kill-result))))
1345
1346 (defun ibuffer-mark-on-buffer (func &optional ibuffer-mark-on-buffer-mark group)
1347   (let ((count
1348          (ibuffer-map-lines
1349           #'(lambda (buf mark)
1350               (when (funcall func buf)
1351                 (ibuffer-set-mark-1 (or ibuffer-mark-on-buffer-mark
1352                                         ibuffer-marked-char))
1353                 t))
1354           nil
1355           group)))
1356     (ibuffer-redisplay t)
1357     (message "Marked %s buffers" count)))
1358
1359 ;;;###autoload
1360 (defun ibuffer-mark-by-name-regexp (regexp)
1361   "Mark all buffers whose name matches REGEXP."
1362   (interactive "sMark by name (regexp): ")
1363   (ibuffer-mark-on-buffer
1364    #'(lambda (buf)
1365        (string-match regexp (buffer-name buf)))))
1366
1367 ;;;###autoload
1368 (defun ibuffer-mark-by-mode-regexp (regexp)
1369   "Mark all buffers whose major mode matches REGEXP."
1370   (interactive "sMark by major mode (regexp): ")
1371   (ibuffer-mark-on-buffer
1372    #'(lambda (buf)
1373        (with-current-buffer buf
1374          (string-match regexp mode-name)))))
1375
1376 ;;;###autoload
1377 (defun ibuffer-mark-by-file-name-regexp (regexp)
1378   "Mark all buffers whose file name matches REGEXP."
1379   (interactive "sMark by file name (regexp): ")
1380   (ibuffer-mark-on-buffer
1381    #'(lambda (buf)
1382        (let ((name (or (buffer-file-name buf)
1383                        (with-current-buffer buf
1384                          (and
1385                           (boundp 'dired-directory)
1386                           (stringp dired-directory)
1387                           dired-directory)))))
1388          (when name
1389            (string-match regexp name))))))
1390
1391 ;;;###autoload
1392 (defun ibuffer-mark-by-mode (mode)
1393   "Mark all buffers whose major mode equals MODE."
1394   (interactive
1395    (list (intern (completing-read "Mark by major mode: " obarray
1396                                   #'(lambda (e)
1397                                       ;; kind of a hack...
1398                                       (and (fboundp e)
1399                                            (string-match "-mode$"
1400                                                          (symbol-name e))))
1401                                   t
1402                                   (let ((buf (ibuffer-current-buffer)))
1403                                     (if (and buf (buffer-live-p buf))
1404                                         (with-current-buffer buf
1405                                           (cons (symbol-name major-mode)
1406                                                 0))
1407                                       ""))))))
1408   (ibuffer-mark-on-buffer
1409    #'(lambda (buf)
1410        (with-current-buffer buf
1411          (eq major-mode mode)))))
1412
1413 ;;;###autoload
1414 (defun ibuffer-mark-modified-buffers ()
1415   "Mark all modified buffers."
1416   (interactive)
1417   (ibuffer-mark-on-buffer
1418    #'(lambda (buf) (buffer-modified-p buf))))
1419
1420 ;;;###autoload
1421 (defun ibuffer-mark-unsaved-buffers ()
1422   "Mark all modified buffers that have an associated file."
1423   (interactive)
1424   (ibuffer-mark-on-buffer
1425    #'(lambda (buf) (and (with-current-buffer buf buffer-file-name)
1426                         (buffer-modified-p buf)))))
1427
1428 ;;;###autoload
1429 (defun ibuffer-mark-dissociated-buffers ()
1430   "Mark all buffers whose associated file does not exist."
1431   (interactive)
1432   (ibuffer-mark-on-buffer
1433    #'(lambda (buf)
1434        (with-current-buffer buf
1435          (or
1436           (and buffer-file-name
1437                (not (file-exists-p buffer-file-name)))
1438           (and (eq major-mode 'dired-mode)
1439                (boundp 'dired-directory)
1440                (stringp dired-directory)
1441                (not (file-exists-p (file-name-directory dired-directory)))))))))
1442
1443 ;;;###autoload
1444 (defun ibuffer-mark-help-buffers ()
1445   "Mark buffers like *Help*, *Apropos*, *Info*."
1446   (interactive)
1447   (ibuffer-mark-on-buffer
1448    #'(lambda (buf)
1449        (with-current-buffer buf
1450          (memq major-mode ibuffer-help-buffer-modes)))))
1451
1452 ;;;###autoload
1453 (defun ibuffer-mark-old-buffers ()
1454   "Mark buffers which have not been viewed in `ibuffer-old-time' days."
1455   (interactive)
1456   (ibuffer-mark-on-buffer
1457    #'(lambda (buf)
1458        (with-current-buffer buf
1459          ;; hacked from midnight.el
1460          (when buffer-display-time
1461            (let* ((tm (current-time))
1462                   (now (+ (* (float (ash 1 16)) (car tm))
1463                           (float (cadr tm)) (* 0.0000001 (caddr tm))))
1464                   (then (+ (* (float (ash 1 16))
1465                               (car buffer-display-time))
1466                            (float (cadr buffer-display-time))
1467                            (* 0.0000001 (caddr buffer-display-time)))))
1468              (> (- now then) (* 60 60 ibuffer-old-time))))))))
1469
1470 ;;;###autoload
1471 (defun ibuffer-mark-special-buffers ()
1472   "Mark all buffers whose name begins and ends with '*'."
1473   (interactive)
1474   (ibuffer-mark-on-buffer
1475    #'(lambda (buf) (string-match "^\\*.+\\*$"
1476                                  (buffer-name buf)))))
1477
1478 ;;;###autoload
1479 (defun ibuffer-mark-read-only-buffers ()
1480   "Mark all read-only buffers."
1481   (interactive)
1482   (ibuffer-mark-on-buffer
1483    #'(lambda (buf)
1484        (with-current-buffer buf
1485          buffer-read-only))))
1486
1487 ;;;###autoload
1488 (defun ibuffer-mark-dired-buffers ()
1489   "Mark all `dired' buffers."
1490   (interactive)
1491   (ibuffer-mark-on-buffer
1492    #'(lambda (buf)
1493        (with-current-buffer buf
1494          (eq major-mode 'dired-mode)))))
1495
1496 ;;;###autoload
1497 (defun ibuffer-do-occur (regexp &optional nlines)
1498   "View lines which match REGEXP in all marked buffers.
1499 Optional argument NLINES says how many lines of context to display: it
1500 defaults to one."
1501   (interactive (occur-read-primary-args))
1502   (if (or (not (integerp nlines))
1503           (< nlines 0))
1504       (setq nlines 0))
1505   (when (zerop (ibuffer-count-marked-lines))
1506     (ibuffer-set-mark ibuffer-marked-char))
1507   (let ((ibuffer-do-occur-bufs nil))
1508     ;; Accumulate a list of marked buffers
1509     (ibuffer-map-marked-lines
1510      #'(lambda (buf mark)
1511          (push buf ibuffer-do-occur-bufs)))
1512     (occur-1 regexp nlines ibuffer-do-occur-bufs)))
1513
1514 (provide 'ibuf-ext)
1515
1516 ;;; arch-tag: 9af21953-deda-4c30-b76d-f81d9128e76d
1517 ;;; ibuf-ext.el ends here