lisp/xml.el

   1 ;;; xml.el --- XML parser
   2
   3 ;; Copyright (C) 2000, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Emmanuel Briot  <briot@gnat.com>
   6 ;; Maintainer: Emmanuel Briot <briot@gnat.com>
   7 ;; Keywords: xml
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This file contains a full XML parser. It parses a file, and returns a list
  29 ;; that can be used internally by any other lisp file.
  30 ;; See some example in todo.el
  31
  32 ;;; FILE FORMAT
  33
  34 ;; It does not parse the DTD, if present in the XML file, but knows how to
  35 ;; ignore it. The XML file is assumed to be well-formed. In case of error, the
  36 ;; parsing stops and the XML file is shown where the parsing stopped.
  37 ;;
  38 ;; It also knows how to ignore comments, as well as the special ?xml? tag
  39 ;; in the XML file.
  40 ;;
  41 ;; The XML file should have the following format:
  42 ;;    <node1 attr1="name1" attr2="name2" ...>value
  43 ;;       <node2 attr3="name3" attr4="name4">value2</node2>
  44 ;;       <node3 attr5="name5" attr6="name6">value3</node3>
  45 ;;    </node1>
  46 ;; Of course, the name of the nodes and attributes can be anything. There can
  47 ;; be any number of attributes (or none), as well as any number of children
  48 ;; below the nodes.
  49 ;;
  50 ;; There can be only top level node, but with any number of children below.
  51
  52 ;;; LIST FORMAT
  53
  54 ;; The functions `xml-parse-file' and `xml-parse-tag' return a list with
  55 ;; the following format:
  56 ;;
  57 ;;    xml-list   ::= (node node ...)
  58 ;;    node       ::= (tag_name attribute-list . child_node_list)
  59 ;;    child_node_list ::= child_node child_node ...
  60 ;;    child_node ::= node | string
  61 ;;    tag_name   ::= string
  62 ;;    attribute_list ::= (("attribute" . "value") ("attribute" . "value") ...)
  63 ;;                       | nil
  64 ;;    string     ::= "..."
  65 ;;
  66 ;; Some macros are provided to ease the parsing of this list
  67
  68 ;;; Code:
  69
  70 ;;*******************************************************************
  71 ;;**
  72 ;;**  Macros to parse the list
  73 ;;**
  74 ;;*******************************************************************
  75
  76 (defsubst xml-node-name (node)
  77   "Return the tag associated with NODE.
  78 The tag is a lower-case symbol."
  79   (car node))
  80
  81 (defsubst xml-node-attributes (node)
  82   "Return the list of attributes of NODE.
  83 The list can be nil."
  84   (nth 1 node))
  85
  86 (defsubst xml-node-children (node)
  87   "Return the list of children of NODE.
  88 This is a list of nodes, and it can be nil."
  89   (cddr node))
  90
  91 (defun xml-get-children (node child-name)
  92   "Return the children of NODE whose tag is CHILD-NAME.
  93 CHILD-NAME should be a lower case symbol."
  94   (let ((match ()))
  95     (dolist (child (xml-node-children node))
  96       (if child
  97           (if (equal (xml-node-name child) child-name)
  98               (push child match))))
  99     (nreverse match)))
 100
 101 (defun xml-get-attribute (node attribute)
 102   "Get from NODE the value of ATTRIBUTE.
 103 An empty string is returned if the attribute was not found."
 104   (if (xml-node-attributes node)
 105       (let ((value (assoc attribute (xml-node-attributes node))))
 106         (if value
 107             (cdr value)
 108           ""))
 109     ""))
 110
 111 ;;*******************************************************************
 112 ;;**
 113 ;;**  Creating the list
 114 ;;**
 115 ;;*******************************************************************
 116
 117 (defun xml-parse-file (file &optional parse-dtd)
 118   "Parse the well-formed XML FILE.
 119 If FILE is already edited, this will keep the buffer alive.
 120 Returns the top node with all its children.
 121 If PARSE-DTD is non-nil, the DTD is parsed rather than skipped."
 122   (let ((keep))
 123     (if (get-file-buffer file)
 124         (progn
 125           (set-buffer (get-file-buffer file))
 126           (setq keep (point)))
 127       (find-file file))
 128
 129     (let ((xml (xml-parse-region (point-min)
 130                                  (point-max)
 131                                  (current-buffer)
 132                                  parse-dtd)))
 133       (if keep
 134           (goto-char keep)
 135         (kill-buffer (current-buffer)))
 136       xml)))
 137
 138 (defun xml-parse-region (beg end &optional buffer parse-dtd)
 139   "Parse the region from BEG to END in BUFFER.
 140 If BUFFER is nil, it defaults to the current buffer.
 141 Returns the XML list for the region, or raises an error if the region
 142 is not a well-formed XML file.
 143 If PARSE-DTD is non-nil, the DTD is parsed rather than skipped,
 144 and returned as the first element of the list"
 145   (let (xml result dtd)
 146     (save-excursion
 147       (if buffer
 148           (set-buffer buffer))
 149       (goto-char beg)
 150       (while (< (point) end)
 151         (if (search-forward "<" end t)
 152             (progn
 153               (forward-char -1)
 154               (if (null xml)
 155                   (progn
 156                     (setq result (xml-parse-tag end parse-dtd))
 157                     (cond
 158                      ((null result))
 159                      ((listp (car result))
 160                       (setq dtd (car result))
 161                       (add-to-list 'xml (cdr result)))
 162                      (t
 163                       (add-to-list 'xml result))))
 164
 165                 ;;  translation of rule [1] of XML specifications
 166                 (error "XML files can have only one toplevel tag")))
 167           (goto-char end)))
 168       (if parse-dtd
 169           (cons dtd (reverse xml))
 170         (reverse xml)))))
 171
 172
 173 (defun xml-parse-tag (end &optional parse-dtd)
 174   "Parse the tag that is just in front of point.
 175 The end tag must be found before the position END in the current buffer.
 176 If PARSE-DTD is non-nil, the DTD of the document, if any, is parsed and
 177 returned as the first element in the list.
 178 Returns one of:
 179    - a list : the matching node
 180    - nil    : the point is not looking at a tag.
 181    - a cons cell: the first element is the DTD, the second is the node"
 182   (cond
 183    ;; Processing instructions (like the <?xml version="1.0"?> tag at the
 184    ;; beginning of a document)
 185    ((looking-at "<\\?")
 186     (search-forward "?>" end)
 187     (goto-char (- (re-search-forward "[^ \t\n\r]") 1))
 188     (xml-parse-tag end))
 189    ;;  Character data (CDATA) sections, in which no tag should be interpreted
 190    ((looking-at "<!\\[CDATA\\[")
 191     (let ((pos (match-end 0)))
 192       (unless (search-forward "]]>" end t)
 193         (error "CDATA section does not end anywhere in the document"))
 194       (buffer-substring-no-properties pos (match-beginning 0))))
 195    ;;  DTD for the document
 196    ((looking-at "<!DOCTYPE")
 197     (let (dtd)
 198       (if parse-dtd
 199           (setq dtd (xml-parse-dtd end))
 200         (xml-skip-dtd end))
 201       (goto-char (- (re-search-forward "[^ \t\n\r]") 1))
 202       (if dtd
 203           (cons dtd (xml-parse-tag end))
 204         (xml-parse-tag end))))
 205    ;;  skip comments
 206    ((looking-at "<!--")
 207     (search-forward "-->" end)
 208     nil)
 209    ;;  end tag
 210    ((looking-at "</")
 211     '())
 212    ;;  opening tag
 213    ((looking-at "<\\([^/> \t\n\r]+\\)")
 214     (goto-char (match-end 1))
 215     (let* ((case-fold-search nil) ;; XML is case-sensitive.
 216            (node-name (match-string 1))
 217            ;; Parse the attribute list.
 218            (children (list (xml-parse-attlist end) (intern node-name)))
 219            pos)
 220
 221       ;; is this an empty element ?
 222       (if (looking-at "/[ \t\n\r]*>")
 223           (progn
 224             (forward-char 2)
 225             (nreverse (cons '("") children)))
 226
 227         ;; is this a valid start tag ?
 228         (if (eq (char-after) ?>)
 229             (progn
 230               (forward-char 1)
 231               ;;  Now check that we have the right end-tag. Note that this
 232               ;;  one might contain spaces after the tag name
 233               (while (not (looking-at (concat "</" node-name "[ \t\n\r]*>")))
 234                 (cond
 235                  ((looking-at "</")
 236                   (error (concat
 237                           "XML: invalid syntax -- invalid end tag (expecting "
 238                           node-name
 239                           ") at pos " (number-to-string (point)))))
 240                  ((= (char-after) ?<)
 241                   (let ((tag (xml-parse-tag end)))
 242                     (when tag
 243                       (push tag children))))
 244                  (t
 245                   (setq pos (point))
 246                   (search-forward "<" end)
 247                   (forward-char -1)
 248                   (let ((string (buffer-substring-no-properties pos (point)))
 249                         (pos 0))
 250
 251                     ;; Clean up the string.  As per XML
 252                     ;; specifications, the XML processor should
 253                     ;; always pass the whole string to the
 254                     ;; application.  But \r's should be replaced:
 255                     ;; http://www.w3.org/TR/2000/REC-xml-20001006#sec-line-ends
 256                     (while (string-match "\r\n?" string pos)
 257                       (setq string (replace-match "\n" t t string))
 258                       (setq pos (1+ (match-beginning 0))))
 259
 260                     (setq string (xml-substitute-special string))
 261                     (setq children
 262                           (if (stringp (car children))
 263                               ;; The two strings were separated by a comment.
 264                               (cons (concat (car children) string)
 265                                     (cdr children))
 266                             (cons string children)))))))
 267               (goto-char (match-end 0))
 268               (if (> (point) end)
 269                   (error "XML: End tag for %s not found before end of region"
 270                          node-name))
 271               (nreverse children))
 272
 273           ;;  This was an invalid start tag
 274           (error "XML: Invalid attribute list")
 275           ))))
 276    (t ;; This is not a tag.
 277     (error "XML: Invalid character"))
 278    ))
 279
 280 (defun xml-parse-attlist (end)
 281   "Return the attribute-list that point is looking at.
 282 The search for attributes end at the position END in the current buffer.
 283 Leaves the point on the first non-blank character after the tag."
 284   (let ((attlist ())
 285         start-pos name)
 286     (goto-char (- (re-search-forward "[^ \t\n\r]") 1))
 287     (while (looking-at "\\([a-zA-Z_:][-a-zA-Z0-9._:]*\\)[ \t\n\r]*=[ \t\n\r]*")
 288       (setq name (intern (match-string 1)))
 289       (goto-char (match-end 0))
 290
 291       ;; See also: http://www.w3.org/TR/2000/REC-xml-20001006#AVNormalize
 292
 293       ;; Do we have a string between quotes (or double-quotes),
 294       ;;  or a simple word ?
 295       (if (looking-at "\"\\([^\"]*\\)\"")
 296           (setq start-pos (match-beginning 0))
 297         (if (looking-at "'\\([^']*\\)'")
 298             (setq start-pos (match-beginning 0))
 299           (error "XML: Attribute values must be given between quotes")))
 300
 301       ;; Each attribute must be unique within a given element
 302       (if (assoc name attlist)
 303           (error "XML: each attribute must be unique within an element"))
 304
 305       ;; Multiple whitespace characters should be replaced with a single one
 306       ;; in the attributes
 307       (let ((string (match-string-no-properties 1))
 308             (pos 0))
 309         (while (string-match "[ \t\n\r]+" string pos)
 310           (setq string (replace-match " " t nil string))
 311           (setq pos (1+ (match-beginning 0))))
 312         (push (cons name (xml-substitute-special string)) attlist))
 313
 314       (goto-char start-pos)
 315       (if (looking-at "\"\\([^\"]*\\)\"")
 316           (goto-char (match-end 0))
 317         (if (looking-at "'\\([^']*\\)'")
 318             (goto-char (match-end 0))))
 319
 320       (goto-char (- (re-search-forward "[^ \t\n\r]") 1))
 321       (if (> (point) end)
 322           (error "XML: end of attribute list not found before end of region")))
 323     (nreverse attlist)))
 324
 325 ;;*******************************************************************
 326 ;;**
 327 ;;**  The DTD (document type declaration)
 328 ;;**  The following functions know how to skip or parse the DTD of
 329 ;;**  a document
 330 ;;**
 331 ;;*******************************************************************
 332
 333 (defun xml-skip-dtd (end)
 334   "Skip the DTD that point is looking at.
 335 The DTD must end before the position END in the current buffer.
 336 The point must be just before the starting tag of the DTD.
 337 This follows the rule [28] in the XML specifications."
 338   (forward-char (length "<!DOCTYPE"))
 339   (if (looking-at "[ \t\n\r]*>")
 340       (error "XML: invalid DTD (excepting name of the document)"))
 341   (condition-case nil
 342       (progn
 343         (forward-word 1)
 344         (goto-char (- (re-search-forward "[ \t\n\r]") 1))
 345         (goto-char (- (re-search-forward "[^ \t\n\r]") 1))
 346         (if (looking-at "\\[")
 347             (re-search-forward "\\][ \t\n\r]*>" end)
 348           (search-forward ">" end)))
 349     (error (error "XML: No end to the DTD"))))
 350
 351 (defun xml-parse-dtd (end)
 352   "Parse the DTD that point is looking at.
 353 The DTD must end before the position END in the current buffer."
 354   (forward-char (length "<!DOCTYPE"))
 355   (goto-char (- (re-search-forward "[^ \t\n\r]") 1))
 356   (if (looking-at ">")
 357       (error "XML: invalid DTD (excepting name of the document)"))
 358
 359   ;;  Get the name of the document
 360   (looking-at "\\sw+")
 361   (let ((dtd (list (match-string-no-properties 0) 'dtd))
 362         type element end-pos)
 363     (goto-char (match-end 0))
 364
 365     (goto-char (- (re-search-forward "[^ \t\n\r]") 1))
 366
 367     ;;  External DTDs => don't know how to handle them yet
 368     (if (looking-at "SYSTEM")
 369         (error "XML: Don't know how to handle external DTDs"))
 370
 371     (if (not (= (char-after) ?\[))
 372         (error "XML: Unknown declaration in the DTD"))
 373
 374     ;;  Parse the rest of the DTD
 375     (forward-char 1)
 376     (while (and (not (looking-at "[ \t\n\r]*\\]"))
 377                 (<= (point) end))
 378       (cond
 379
 380        ;;  Translation of rule [45] of XML specifications
 381        ((looking-at
 382          "[ \t\n\r]*<!ELEMENT[ \t\n\r]+\\([a-zA-Z0-9.%;]+\\)[ \t\n\r]+\\([^>]+\\)>")
 383
 384         (setq element (intern (match-string-no-properties 1))
 385               type    (match-string-no-properties 2))
 386         (setq end-pos (match-end 0))
 387
 388         ;;  Translation of rule [46] of XML specifications
 389         (cond
 390          ((string-match "^EMPTY[ \t\n\r]*$" type)     ;; empty declaration
 391           (setq type 'empty))
 392          ((string-match "^ANY[ \t\n\r]*$" type)       ;; any type of contents
 393           (setq type 'any))
 394          ((string-match "^(\\(.*\\))[ \t\n\r]*$" type) ;; children ([47])
 395           (setq type (xml-parse-elem-type (match-string-no-properties 1 type))))
 396          ((string-match "^%[^;]+;[ \t\n\r]*$" type)   ;; substitution
 397           nil)
 398          (t
 399           (error "XML: Invalid element type in the DTD")))
 400
 401         ;;  rule [45]: the element declaration must be unique
 402         (if (assoc element dtd)
 403             (error "XML: elements declaration must be unique in a DTD (<%s>)"
 404                    (symbol-name element)))
 405
 406         ;;  Store the element in the DTD
 407         (push (list element type) dtd)
 408         (goto-char end-pos))
 409
 410
 411        (t
 412         (error "XML: Invalid DTD item"))
 413        )
 414       )
 415
 416     ;;  Skip the end of the DTD
 417     (search-forward ">" end)
 418     (nreverse dtd)))
 419
 420
 421 (defun xml-parse-elem-type (string)
 422   "Convert a STRING for an element type into an elisp structure."
 423
 424   (let (elem modifier)
 425     (if (string-match "(\\([^)]+\\))\\([+*?]?\\)" string)
 426         (progn
 427           (setq elem     (match-string 1 string)
 428                 modifier (match-string 2 string))
 429           (if (string-match "|" elem)
 430               (setq elem (cons 'choice
 431                                (mapcar 'xml-parse-elem-type
 432                                        (split-string elem "|"))))
 433             (if (string-match "," elem)
 434                 (setq elem (cons 'seq
 435                                  (mapcar 'xml-parse-elem-type
 436                                          (split-string elem ","))))
 437               )))
 438       (if (string-match "[ \t\n\r]*\\([^+*?]+\\)\\([+*?]?\\)" string)
 439           (setq elem     (match-string 1 string)
 440                 modifier (match-string 2 string))))
 441
 442     (if (and (stringp elem) (string= elem "#PCDATA"))
 443         (setq elem 'pcdata))
 444
 445     (cond
 446      ((string= modifier "+")
 447       (list '+ elem))
 448      ((string= modifier "*")
 449       (list '* elem))
 450      ((string= modifier "?")
 451       (list '\? elem))
 452      (t
 453       elem))))
 454
 455 ;;*******************************************************************
 456 ;;**
 457 ;;**  Converting code points to strings
 458 ;;**
 459 ;;*******************************************************************
 460
 461 (defun xml-ucs-to-string (codepoint)
 462   "Return a string representation of CODEPOINT.  If it can't be
 463 converted, return '?'."
 464   (cond ((boundp 'decode-char)
 465          (char-to-string (decode-char 'ucs codepoint)))
 466         ((and (< codepoint 128)
 467               (> codepoint 31))
 468          (char-to-string codepoint))
 469         (t "?"))) ; FIXME: There's gotta be a better way to
 470                   ; designate an unknown character.
 471
 472 ;;*******************************************************************
 473 ;;**
 474 ;;**  Substituting special XML sequences
 475 ;;**
 476 ;;*******************************************************************
 477
 478 (defun xml-substitute-special (string)
 479   "Return STRING, after subsituting special XML sequences."
 480   (while (string-match "&lt;" string)
 481     (setq string (replace-match "<"  t nil string)))
 482   (while (string-match "&gt;" string)
 483     (setq string (replace-match ">"  t nil string)))
 484   (while (string-match "&apos;" string)
 485     (setq string (replace-match "'"  t nil string)))
 486   (while (string-match "&quot;" string)
 487     (setq string (replace-match "\"" t nil string)))
 488   (while (string-match "&#\\([0-9]+\\);" string)
 489     (setq string (replace-match (xml-ucs-to-string
 490                                  (string-to-number
 491                                   (match-string-no-properties 1 string)))
 492                                 t nil string)))
 493   (while (string-match "&#x\\([0-9a-fA-F]+\\);" string)
 494     (setq string (replace-match (xml-ucs-to-string
 495                                  (string-to-number
 496                                   (match-string-no-properties 1 string)
 497                                   16))
 498                                 t nil string)))
 499
 500   ;; This goes last so it doesn't confuse the matches above.
 501   (while (string-match "&amp;" string)
 502     (setq string (replace-match "&"  t nil string)))
 503   string)
 504
 505 ;;*******************************************************************
 506 ;;**
 507 ;;**  Printing a tree.
 508 ;;**  This function is intended mainly for debugging purposes.
 509 ;;**
 510 ;;*******************************************************************
 511
 512 (defun xml-debug-print (xml)
 513   (dolist (node xml)
 514     (xml-debug-print-internal node "")))
 515
 516 (defun xml-debug-print-internal (xml indent-string)
 517   "Outputs the XML tree in the current buffer.
 518 The first line indented with INDENT-STRING."
 519   (let ((tree xml)
 520         attlist)
 521     (insert indent-string "<" (symbol-name (xml-node-name tree)))
 522
 523     ;;  output the attribute list
 524     (setq attlist (xml-node-attributes tree))
 525     (while attlist
 526       (insert " ")
 527       (insert (symbol-name (caar attlist)) "=\"" (cdar attlist) "\"")
 528       (setq attlist (cdr attlist)))
 529
 530     (insert ">")
 531
 532     (setq tree (xml-node-children tree))
 533
 534     ;;  output the children
 535     (dolist (node tree)
 536       (cond
 537        ((listp node)
 538         (insert "\n")
 539         (xml-debug-print-internal node (concat indent-string "  ")))
 540        ((stringp node) (insert node))
 541        (t
 542         (error "Invalid XML tree"))))
 543
 544     (insert "\n" indent-string
 545             "</" (symbol-name (xml-node-name xml)) ">")))
 546
 547 (provide 'xml)
 548
 549 ;;; xml.el ends here