lisp/ibuf-ext.el

   1 ;;; ibuf-ext.el --- extensions for ibuffer
   2
   3 ;; Copyright (C) 2000-2012  Free Software Foundation, Inc.
   4
   5 ;; Author: Colin Walters <walters@verbum.org>
   6 ;; Maintainer: John Paul Wallington <jpw@gnu.org>
   7 ;; Created: 2 Dec 2001
   8 ;; Keywords: buffer, convenience
   9 ;; Package: ibuffer
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; These functions should be automatically loaded when called, but you
  29 ;; can explicitly (require 'ibuf-ext) in your ~/.emacs to have them
  30 ;; preloaded.
  31
  32 ;;; Code:
  33
  34 (require 'ibuffer)
  35
  36 (eval-when-compile
  37   (require 'ibuf-macs)
  38   (require 'cl-lib))
  39
  40 ;;; Utility functions
  41 (defun ibuffer-delete-alist (key alist)
  42   "Delete all entries in ALIST that have a key equal to KEY."
  43   (let (entry)
  44     (while (setq entry (assoc key alist))
  45       (setq alist (delete entry alist)))
  46     alist))
  47
  48 ;; borrowed from Gnus
  49 (defun ibuffer-remove-duplicates (list)
  50   "Return a copy of LIST with duplicate elements removed."
  51   (let ((new nil)
  52         (tail list))
  53     (while tail
  54       (or (member (car tail) new)
  55           (setq new (cons (car tail) new)))
  56       (setq tail (cdr tail)))
  57     (nreverse new)))
  58
  59 (defun ibuffer-split-list (ibuffer-split-list-fn ibuffer-split-list-elts)
  60   (let ((hip-crowd nil)
  61         (lamers nil))
  62     (dolist (ibuffer-split-list-elt ibuffer-split-list-elts)
  63       (if (funcall ibuffer-split-list-fn ibuffer-split-list-elt)
  64           (push ibuffer-split-list-elt hip-crowd)
  65         (push ibuffer-split-list-elt lamers)))
  66     ;; Too bad Emacs Lisp doesn't have multiple values.
  67     (list (nreverse hip-crowd) (nreverse lamers))))
  68
  69 (defcustom ibuffer-never-show-predicates nil
  70   "A list of predicates (a regexp or function) for buffers not to display.
  71 If a regexp, then it will be matched against the buffer's name.
  72 If a function, it will be called with the buffer as an argument, and
  73 should return non-nil if this buffer should not be shown."
  74   :type '(repeat (choice regexp function))
  75   :require 'ibuf-ext
  76   :group 'ibuffer)
  77
  78 (defcustom ibuffer-always-show-predicates nil
  79   "A list of predicates (a regexp or function) for buffers to always display.
  80 If a regexp, then it will be matched against the buffer's name.
  81 If a function, it will be called with the buffer as an argument, and
  82 should return non-nil if this buffer should be shown.
  83 Note that buffers matching one of these predicates will be shown
  84 regardless of any active filters in this buffer."
  85   :type '(repeat (choice regexp function))
  86   :group 'ibuffer)
  87
  88 (defvar ibuffer-tmp-hide-regexps nil
  89   "A list of regexps which should match buffer names to not show.")
  90
  91 (defvar ibuffer-tmp-show-regexps nil
  92   "A list of regexps which should match buffer names to always show.")
  93
  94 (defvar ibuffer-auto-buffers-changed nil)
  95
  96 (defcustom ibuffer-saved-filters '(("gnus"
  97                                     ((or (mode . message-mode)
  98                                          (mode . mail-mode)
  99                                          (mode . gnus-group-mode)
 100                                          (mode . gnus-summary-mode)
 101                                          (mode . gnus-article-mode))))
 102                                    ("programming"
 103                                     ((or (mode . emacs-lisp-mode)
 104                                          (mode . cperl-mode)
 105                                          (mode . c-mode)
 106                                          (mode . java-mode)
 107                                          (mode . idl-mode)
 108                                          (mode . lisp-mode)))))
 109
 110   "An alist of filter qualifiers to switch between.
 111
 112 This variable should look like ((\"STRING\" QUALIFIERS)
 113                                 (\"STRING\" QUALIFIERS) ...), where
 114 QUALIFIERS is a list of the same form as
 115 `ibuffer-filtering-qualifiers'.
 116 See also the variables `ibuffer-filtering-qualifiers',
 117 `ibuffer-filtering-alist', and the functions
 118 `ibuffer-switch-to-saved-filters', `ibuffer-save-filters'."
 119   :type '(repeat sexp)
 120   :group 'ibuffer)
 121
 122 (defvar ibuffer-filtering-qualifiers nil
 123   "A list like (SYMBOL . QUALIFIER) which filters the current buffer list.
 124 See also `ibuffer-filtering-alist'.")
 125
 126 ;; This is now frobbed by `define-ibuffer-filter'.
 127 (defvar ibuffer-filtering-alist nil
 128   "An alist of (SYMBOL DESCRIPTION FUNCTION) which describes a filter.
 129
 130 You most likely do not want to modify this variable directly; see
 131 `define-ibuffer-filter'.
 132
 133 SYMBOL is the symbolic name of the filter.  DESCRIPTION is used when
 134 displaying information to the user.  FUNCTION is given a buffer and
 135 the value of the qualifier, and returns non-nil if and only if the
 136 buffer should be displayed.")
 137
 138 (defcustom ibuffer-filter-format-alist nil
 139   "An alist which has special formats used when a filter is active.
 140 The contents of this variable should look like:
 141  ((FILTER (FORMAT FORMAT ...)) (FILTER (FORMAT FORMAT ...)) ...)
 142
 143 For example, suppose that when you add a filter for buffers whose
 144 major mode is `emacs-lisp-mode', you only want to see the mark and the
 145 name of the buffer.  You could accomplish that by adding:
 146  (mode ((mark \" \" name)))
 147 to this variable."
 148   :type '(repeat (list :tag "Association" (symbol :tag "Filter")
 149                        (list :tag "Formats" (repeat (sexp :tag "Format")))))
 150   :group 'ibuffer)
 151
 152 (defvar ibuffer-cached-filter-formats nil)
 153 (defvar ibuffer-compiled-filter-formats nil)
 154
 155 (defvar ibuffer-filter-groups nil
 156   "A list like ((\"NAME\" ((SYMBOL . QUALIFIER) ...) ...) which groups buffers.
 157 The SYMBOL should be one from `ibuffer-filtering-alist'.
 158 The QUALIFIER should be the same as QUALIFIER in
 159 `ibuffer-filtering-qualifiers'.")
 160
 161 (defcustom ibuffer-show-empty-filter-groups t
 162   "If non-nil, then show the names of filter groups which are empty."
 163   :type 'boolean
 164   :group 'ibuffer)
 165
 166 (defcustom ibuffer-saved-filter-groups nil
 167   "An alist of filtering groups to switch between.
 168
 169 This variable should look like ((\"STRING\" QUALIFIERS)
 170                                 (\"STRING\" QUALIFIERS) ...), where
 171 QUALIFIERS is a list of the same form as
 172 `ibuffer-filtering-qualifiers'.
 173
 174 See also the variables `ibuffer-filter-groups',
 175 `ibuffer-filtering-qualifiers', `ibuffer-filtering-alist', and the
 176 functions `ibuffer-switch-to-saved-filter-groups',
 177 `ibuffer-save-filter-groups'."
 178   :type '(repeat sexp)
 179   :group 'ibuffer)
 180
 181 (defvar ibuffer-hidden-filter-groups nil
 182   "A list of filtering groups which are currently hidden.")
 183
 184 (defvar ibuffer-filter-group-kill-ring nil)
 185
 186 (defcustom ibuffer-old-time 72
 187   "The number of hours before a buffer is considered \"old\"."
 188   :type '(choice (const :tag "72 hours (3 days)" 72)
 189                  (const :tag "48 hours (2 days)" 48)
 190                  (const :tag "24 hours (1 day)" 24)
 191                  (integer :tag "hours"))
 192   :group 'ibuffer)
 193
 194 (defcustom ibuffer-save-with-custom t
 195   "If non-nil, then use Custom to save interactively changed variables.
 196 Currently, this only applies to `ibuffer-saved-filters' and
 197 `ibuffer-saved-filter-groups'."
 198   :type 'boolean
 199   :group 'ibuffer)
 200
 201 (defun ibuffer-ext-visible-p (buf all &optional ibuffer-buf)
 202   (or
 203    (ibuffer-buf-matches-predicates buf ibuffer-tmp-show-regexps)
 204    (and (not
 205          (or
 206           (ibuffer-buf-matches-predicates buf ibuffer-tmp-hide-regexps)
 207           (ibuffer-buf-matches-predicates buf ibuffer-never-show-predicates)))
 208         (or all
 209             (not
 210              (ibuffer-buf-matches-predicates buf ibuffer-maybe-show-predicates)))
 211         (or ibuffer-view-ibuffer
 212             (and ibuffer-buf
 213                  (not (eq ibuffer-buf buf))))
 214         (or
 215          (ibuffer-included-in-filters-p buf ibuffer-filtering-qualifiers)
 216          (ibuffer-buf-matches-predicates buf ibuffer-always-show-predicates)))))
 217
 218 ;;;###autoload
 219 (define-minor-mode ibuffer-auto-mode
 220   "Toggle use of Ibuffer's auto-update facility (Ibuffer Auto mode).
 221 With a prefix argument ARG, enable Ibuffer Auto mode if ARG is
 222 positive, and disable it otherwise.  If called from Lisp, enable
 223 the mode if ARG is omitted or nil."
 224   nil nil nil
 225   (unless (derived-mode-p 'ibuffer-mode)
 226     (error "This buffer is not in Ibuffer mode"))
 227   (frame-or-buffer-changed-p 'ibuffer-auto-buffers-changed) ; Initialize state vector
 228   (add-hook 'post-command-hook 'ibuffer-auto-update-changed))
 229
 230 (defun ibuffer-auto-update-changed ()
 231   (when (frame-or-buffer-changed-p 'ibuffer-auto-buffers-changed)
 232     (dolist (buf (buffer-list))
 233       (ignore-errors
 234         (with-current-buffer buf
 235           (when (and ibuffer-auto-mode
 236                      (derived-mode-p 'ibuffer-mode))
 237             (ibuffer-update nil t)))))))
 238
 239 ;;;###autoload
 240 (defun ibuffer-mouse-filter-by-mode (event)
 241   "Enable or disable filtering by the major mode chosen via mouse."
 242   (interactive "e")
 243   (ibuffer-interactive-filter-by-mode event))
 244
 245 ;;;###autoload
 246 (defun ibuffer-interactive-filter-by-mode (event-or-point)
 247   "Enable or disable filtering by the major mode at point."
 248   (interactive "d")
 249   (if (eventp event-or-point)
 250       (posn-set-point (event-end event-or-point))
 251     (goto-char event-or-point))
 252   (let ((buf (ibuffer-current-buffer)))
 253     (if (assq 'mode ibuffer-filtering-qualifiers)
 254         (setq ibuffer-filtering-qualifiers
 255               (ibuffer-delete-alist 'mode ibuffer-filtering-qualifiers))
 256       (ibuffer-push-filter (cons 'mode (buffer-local-value 'major-mode buf)))))
 257   (ibuffer-update nil t))
 258
 259 ;;;###autoload
 260 (defun ibuffer-mouse-toggle-filter-group (event)
 261   "Toggle the display status of the filter group chosen with the mouse."
 262   (interactive "e")
 263   (ibuffer-toggle-filter-group-1 (save-excursion
 264                                    (mouse-set-point event)
 265                                    (point))))
 266
 267 ;;;###autoload
 268 (defun ibuffer-toggle-filter-group ()
 269   "Toggle the display status of the filter group on this line."
 270   (interactive)
 271   (ibuffer-toggle-filter-group-1 (point)))
 272
 273 (defun ibuffer-toggle-filter-group-1 (posn)
 274   (let ((name (get-text-property posn 'ibuffer-filter-group-name)))
 275     (unless (stringp name)
 276       (error "No filtering group name present"))
 277     (if (member name ibuffer-hidden-filter-groups)
 278         (setq ibuffer-hidden-filter-groups
 279               (delete name ibuffer-hidden-filter-groups))
 280       (push name ibuffer-hidden-filter-groups))
 281     (ibuffer-update nil t)))
 282
 283 ;;;###autoload
 284 (defun ibuffer-forward-filter-group (&optional count)
 285   "Move point forwards by COUNT filtering groups."
 286   (interactive "P")
 287   (unless count
 288     (setq count 1))
 289   (when (> count 0)
 290     (when (get-text-property (point) 'ibuffer-filter-group-name)
 291       (goto-char (next-single-property-change
 292                   (point) 'ibuffer-filter-group-name
 293                   nil (point-max))))
 294     (goto-char (next-single-property-change
 295                 (point) 'ibuffer-filter-group-name
 296                 nil (point-max)))
 297     (ibuffer-forward-filter-group (1- count)))
 298   (ibuffer-forward-line 0))
 299
 300 ;;;###autoload
 301 (defun ibuffer-backward-filter-group (&optional count)
 302   "Move point backwards by COUNT filtering groups."
 303   (interactive "P")
 304   (unless count
 305     (setq count 1))
 306   (when (> count 0)
 307     (when (get-text-property (point) 'ibuffer-filter-group-name)
 308       (goto-char (previous-single-property-change
 309                   (point) 'ibuffer-filter-group-name
 310                   nil (point-min))))
 311     (goto-char (previous-single-property-change
 312                 (point) 'ibuffer-filter-group-name
 313                 nil (point-min)))
 314     (ibuffer-backward-filter-group (1- count)))
 315   (when (= (point) (point-min))
 316     (goto-char (point-max))
 317     (ibuffer-backward-filter-group 1))
 318   (ibuffer-forward-line 0))
 319
 320 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe "ibuf-ext")
 321 (define-ibuffer-op shell-command-pipe (command)
 322   "Pipe the contents of each marked buffer to shell command COMMAND."
 323   (:interactive "sPipe to shell command: "
 324    :opstring "Shell command executed on"
 325    :modifier-p nil)
 326   (shell-command-on-region
 327    (point-min) (point-max) command
 328    (get-buffer-create "* ibuffer-shell-output*")))
 329
 330 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe-replace "ibuf-ext")
 331 (define-ibuffer-op shell-command-pipe-replace (command)
 332   "Replace the contents of marked buffers with output of pipe to COMMAND."
 333   (:interactive "sPipe to shell command (replace): "
 334    :opstring "Buffer contents replaced in"
 335    :active-opstring "replace buffer contents in"
 336    :dangerous t
 337    :modifier-p t)
 338   (with-current-buffer buf
 339     (shell-command-on-region (point-min) (point-max)
 340                              command nil t)))
 341
 342 ;;;###autoload (autoload 'ibuffer-do-shell-command-file "ibuf-ext")
 343 (define-ibuffer-op shell-command-file (command)
 344   "Run shell command COMMAND separately on files of marked buffers."
 345   (:interactive "sShell command on buffer's file: "
 346    :opstring "Shell command executed on"
 347    :modifier-p nil)
 348   (shell-command (concat command " "
 349                          (shell-quote-argument
 350                           (if buffer-file-name
 351                               buffer-file-name
 352                             (make-temp-file
 353                              (substring (buffer-name) 0 (min 10 (length (buffer-name))))))))))
 354
 355 ;;;###autoload (autoload 'ibuffer-do-eval "ibuf-ext")
 356 (define-ibuffer-op eval (form)
 357   "Evaluate FORM in each of the buffers.
 358 Does not display the buffer during evaluation. See
 359 `ibuffer-do-view-and-eval' for that."
 360   (:interactive
 361    (list
 362     (read-from-minibuffer
 363      "Eval in buffers (form): "
 364      nil read-expression-map t 'read-expression-history))
 365    :opstring "evaluated in"
 366    :modifier-p :maybe)
 367   (eval form))
 368
 369 ;;;###autoload (autoload 'ibuffer-do-view-and-eval "ibuf-ext")
 370 (define-ibuffer-op view-and-eval (form)
 371   "Evaluate FORM while displaying each of the marked buffers.
 372 To evaluate a form without viewing the buffer, see `ibuffer-do-eval'."
 373   (:interactive
 374    (list
 375     (read-from-minibuffer
 376      "Eval viewing in buffers (form): "
 377      nil read-expression-map t 'read-expression-history))
 378    :opstring "evaluated in"
 379    :complex t
 380    :modifier-p :maybe)
 381   (let ((ibuffer-buf (current-buffer)))
 382     (unwind-protect
 383         (progn
 384           (switch-to-buffer buf)
 385           (eval form))
 386       (switch-to-buffer ibuffer-buf))))
 387
 388 ;;;###autoload (autoload 'ibuffer-do-rename-uniquely "ibuf-ext")
 389 (define-ibuffer-op rename-uniquely ()
 390   "Rename marked buffers as with `rename-uniquely'."
 391   (:opstring "renamed"
 392    :modifier-p t)
 393   (rename-uniquely))
 394
 395 ;;;###autoload (autoload 'ibuffer-do-revert "ibuf-ext")
 396 (define-ibuffer-op revert ()
 397   "Revert marked buffers as with `revert-buffer'."
 398   (:dangerous t
 399    :opstring "reverted"
 400    :active-opstring "revert"
 401    :modifier-p :maybe)
 402   (revert-buffer t t))
 403
 404 ;;;###autoload (autoload 'ibuffer-do-isearch "ibuf-ext")
 405 (define-ibuffer-op ibuffer-do-isearch ()
 406   "Perform a `isearch-forward' in marked buffers."
 407   (:interactive ()
 408    :opstring "searched in"
 409    :complex t
 410    :modifier-p :maybe)
 411   (multi-isearch-buffers (ibuffer-get-marked-buffers)))
 412
 413 ;;;###autoload (autoload 'ibuffer-do-isearch-regexp "ibuf-ext")
 414 (define-ibuffer-op ibuffer-do-isearch-regexp ()
 415   "Perform a `isearch-forward-regexp' in marked buffers."
 416   (:interactive ()
 417    :opstring "searched regexp in"
 418    :complex t
 419    :modifier-p :maybe)
 420   (multi-isearch-buffers-regexp (ibuffer-get-marked-buffers)))
 421
 422 ;;;###autoload (autoload 'ibuffer-do-replace-regexp "ibuf-ext")
 423 (define-ibuffer-op replace-regexp (from-str to-str)
 424   "Perform a `replace-regexp' in marked buffers."
 425   (:interactive
 426    (let* ((from-str (read-from-minibuffer "Replace regexp: "))
 427           (to-str (read-from-minibuffer (concat "Replace " from-str
 428                                                 " with: "))))
 429      (list from-str to-str))
 430    :opstring "replaced in"
 431    :complex t
 432    :modifier-p :maybe)
 433   (save-window-excursion
 434     (switch-to-buffer buf)
 435     (save-excursion
 436       (goto-char (point-min))
 437       (let ((case-fold-search ibuffer-case-fold-search))
 438         (while (re-search-forward from-str nil t)
 439           (replace-match to-str))))
 440     t))
 441
 442 ;;;###autoload (autoload 'ibuffer-do-query-replace "ibuf-ext")
 443 (define-ibuffer-op query-replace (&rest args)
 444   "Perform a `query-replace' in marked buffers."
 445   (:interactive
 446    (query-replace-read-args "Query replace" t t)
 447    :opstring "replaced in"
 448    :complex t
 449    :modifier-p :maybe)
 450   (save-window-excursion
 451     (switch-to-buffer buf)
 452     (save-excursion
 453       (let ((case-fold-search ibuffer-case-fold-search))
 454         (goto-char (point-min))
 455         (apply #'query-replace args)))
 456     t))
 457
 458 ;;;###autoload (autoload 'ibuffer-do-query-replace-regexp "ibuf-ext")
 459 (define-ibuffer-op query-replace-regexp (&rest args)
 460   "Perform a `query-replace-regexp' in marked buffers."
 461   (:interactive
 462    (query-replace-read-args "Query replace regexp" t t)
 463    :opstring "replaced in"
 464    :complex t
 465    :modifier-p :maybe)
 466   (save-window-excursion
 467     (switch-to-buffer buf)
 468     (save-excursion
 469       (let ((case-fold-search ibuffer-case-fold-search))
 470         (goto-char (point-min))
 471         (apply #'query-replace-regexp args)))
 472     t))
 473
 474 ;;;###autoload (autoload 'ibuffer-do-print "ibuf-ext")
 475 (define-ibuffer-op print ()
 476   "Print marked buffers as with `print-buffer'."
 477   (:opstring "printed"
 478    :modifier-p nil)
 479   (print-buffer))
 480
 481 ;;;###autoload
 482 (defun ibuffer-included-in-filters-p (buf filters)
 483   (not
 484    (memq nil ;; a filter will return nil if it failed
 485          (mapcar
 486           ;; filter should be like (TYPE . QUALIFIER), or
 487           ;; (or (TYPE . QUALIFIER) (TYPE . QUALIFIER) ...)
 488           #'(lambda (qual)
 489               (ibuffer-included-in-filter-p buf qual))
 490           filters))))
 491
 492 (defun ibuffer-included-in-filter-p (buf filter)
 493   (if (eq (car filter) 'not)
 494       (not (ibuffer-included-in-filter-p-1 buf (cdr filter)))
 495     (ibuffer-included-in-filter-p-1 buf filter)))
 496
 497 (defun ibuffer-included-in-filter-p-1 (buf filter)
 498   (not
 499    (not
 500     (pcase (car filter)
 501       (`or
 502        (memq t (mapcar #'(lambda (x)
 503                            (ibuffer-included-in-filter-p buf x))
 504                        (cdr filter))))
 505       (`saved
 506        (let ((data
 507               (assoc (cdr filter)
 508                      ibuffer-saved-filters)))
 509          (unless data
 510            (ibuffer-filter-disable t)
 511            (error "Unknown saved filter %s" (cdr filter)))
 512          (ibuffer-included-in-filters-p buf (cadr data))))
 513       (_
 514        (pcase-let ((`(,_type ,_desc ,func)
 515                     (assq (car filter) ibuffer-filtering-alist)))
 516          (unless func
 517            (ibuffer-filter-disable t)
 518            (error "Undefined filter %s" (car filter)))
 519          (funcall func buf (cdr filter))))))))
 520
 521 (defun ibuffer-generate-filter-groups (bmarklist &optional noempty nodefault)
 522   (let ((filter-group-alist (if nodefault
 523                                 ibuffer-filter-groups
 524                               (append ibuffer-filter-groups
 525                                       (list (cons "Default" nil))))))
 526 ;;     (dolist (hidden ibuffer-hidden-filter-groups)
 527 ;;       (setq filter-group-alist (ibuffer-delete-alist
 528 ;;                                 hidden filter-group-alist)))
 529     (let ((vec (make-vector (length filter-group-alist) nil))
 530           (i 0))
 531       (dolist (filtergroup filter-group-alist)
 532         (let ((filterset (cdr filtergroup)))
 533           (cl-multiple-value-bind (hip-crowd lamers)
 534               (cl-values-list
 535                (ibuffer-split-list (lambda (bufmark)
 536                                      (ibuffer-included-in-filters-p (car bufmark)
 537                                                                     filterset))
 538                                    bmarklist))
 539             (aset vec i hip-crowd)
 540             (cl-incf i)
 541             (setq bmarklist lamers))))
 542       (let (ret)
 543         (dotimes (j i ret)
 544           (let ((bufs (aref vec j)))
 545             (unless (and noempty (null bufs))
 546               (push (cons (car (nth j filter-group-alist))
 547                           bufs)
 548                     ret))))))))
 549
 550 ;;;###autoload
 551 (defun ibuffer-filters-to-filter-group (name)
 552   "Make the current filters into a filtering group."
 553   (interactive "sName for filtering group: ")
 554   (when (null ibuffer-filtering-qualifiers)
 555     (error "No filters in effect"))
 556   (push (cons name ibuffer-filtering-qualifiers) ibuffer-filter-groups)
 557   (ibuffer-filter-disable))
 558
 559 ;;;###autoload
 560 (defun ibuffer-set-filter-groups-by-mode ()
 561   "Set the current filter groups to filter by mode."
 562   (interactive)
 563   (setq ibuffer-filter-groups
 564         (mapcar (lambda (mode)
 565                   (cons (format "%s" mode) `((mode . ,mode))))
 566                 (let ((modes
 567                        (ibuffer-remove-duplicates
 568                         (mapcar (lambda (buf)
 569                                   (buffer-local-value 'major-mode buf))
 570                                 (buffer-list)))))
 571                   (if ibuffer-view-ibuffer
 572                       modes
 573                     (delq 'ibuffer-mode modes)))))
 574   (ibuffer-update nil t))
 575
 576 ;;;###autoload
 577 (defun ibuffer-pop-filter-group ()
 578   "Remove the first filter group."
 579   (interactive)
 580   (when (null ibuffer-filter-groups)
 581     (error "No filter groups active"))
 582   (setq ibuffer-hidden-filter-groups
 583         (delete (pop ibuffer-filter-groups)
 584                 ibuffer-hidden-filter-groups))
 585   (ibuffer-update nil t))
 586
 587 (defun ibuffer-read-filter-group-name (msg &optional nodefault noerror)
 588   (when (and (not noerror) (null ibuffer-filter-groups))
 589     (error "No filter groups active"))
 590   ;; `ibuffer-generate-filter-groups' returns all non-hidden filter
 591   ;; groups, possibly excluding empty groups or Default.
 592   ;; We add `ibuffer-hidden-filter-groups' to the list, excluding
 593   ;; Default if necessary.
 594   (completing-read msg (nconc
 595                         (ibuffer-generate-filter-groups
 596                          (ibuffer-current-state-list)
 597                          (not ibuffer-show-empty-filter-groups)
 598                          nodefault)
 599                         (if nodefault
 600                             (remove "Default" ibuffer-hidden-filter-groups)
 601                           ibuffer-hidden-filter-groups))
 602                    nil t))
 603
 604 ;;;###autoload
 605 (defun ibuffer-decompose-filter-group (group)
 606   "Decompose the filter group GROUP into active filters."
 607   (interactive
 608    (list (ibuffer-read-filter-group-name "Decompose filter group: " t)))
 609   (let ((data (cdr (assoc group ibuffer-filter-groups))))
 610     (setq ibuffer-filter-groups (ibuffer-delete-alist
 611                                  group ibuffer-filter-groups)
 612           ibuffer-filtering-qualifiers data))
 613   (ibuffer-update nil t))
 614
 615 ;;;###autoload
 616 (defun ibuffer-clear-filter-groups ()
 617   "Remove all filter groups."
 618   (interactive)
 619   (setq ibuffer-filter-groups nil
 620         ibuffer-hidden-filter-groups nil)
 621   (ibuffer-update nil t))
 622
 623 (defun ibuffer-current-filter-groups-with-position ()
 624   (save-excursion
 625     (goto-char (point-min))
 626     (let ((pos nil)
 627           (result nil))
 628       (while (and (not (eobp))
 629                   (setq pos (next-single-property-change
 630                              (point) 'ibuffer-filter-group-name)))
 631         (goto-char pos)
 632         (push (cons (get-text-property (point) 'ibuffer-filter-group-name)
 633                     pos)
 634               result)
 635         (goto-char (next-single-property-change
 636                     pos 'ibuffer-filter-group-name)))
 637       (nreverse result))))
 638
 639 ;;;###autoload
 640 (defun ibuffer-jump-to-filter-group (name)
 641   "Move point to the filter group whose name is NAME."
 642   (interactive
 643    (list (ibuffer-read-filter-group-name "Jump to filter group: ")))
 644   (ibuffer-aif (assoc name (ibuffer-current-filter-groups-with-position))
 645       (goto-char (cdr it))
 646     (error "No filter group with name %s" name)))
 647
 648 ;;;###autoload
 649 (defun ibuffer-kill-filter-group (name)
 650   "Kill the filter group named NAME.
 651 The group will be added to `ibuffer-filter-group-kill-ring'."
 652   (interactive (list (ibuffer-read-filter-group-name "Kill filter group: " t)))
 653   (when (equal name "Default")
 654     (error "Can't kill default filter group"))
 655   (ibuffer-aif (assoc name ibuffer-filter-groups)
 656       (progn
 657         (push (copy-tree it) ibuffer-filter-group-kill-ring)
 658         (setq ibuffer-filter-groups (ibuffer-delete-alist
 659                                      name ibuffer-filter-groups))
 660         (setq ibuffer-hidden-filter-groups
 661               (delete name ibuffer-hidden-filter-groups)))
 662     (error "No filter group with name \"%s\"" name))
 663   (ibuffer-update nil t))
 664
 665 ;;;###autoload
 666 (defun ibuffer-kill-line (&optional arg interactive-p)
 667   "Kill the filter group at point.
 668 See also `ibuffer-kill-filter-group'."
 669   (interactive "P\np")
 670   (ibuffer-aif (save-excursion
 671                  (ibuffer-forward-line 0)
 672                  (get-text-property (point) 'ibuffer-filter-group-name))
 673       (progn
 674         (ibuffer-kill-filter-group it))
 675       (funcall (if interactive-p #'call-interactively #'funcall)
 676                #'kill-line arg)))
 677
 678 (defun ibuffer-insert-filter-group-before (newgroup group)
 679   (let* ((found nil)
 680          (pos (let ((groups (mapcar #'car ibuffer-filter-groups))
 681                     (res 0))
 682                 (while groups
 683                   (if (equal (car groups) group)
 684                       (setq found t
 685                             groups nil)
 686                     (cl-incf res)
 687                     (setq groups (cdr groups))))
 688                 res)))
 689     (cond ((not found)
 690            (setq ibuffer-filter-groups
 691                  (nconc ibuffer-filter-groups (list newgroup))))
 692           ((zerop pos)
 693            (push newgroup ibuffer-filter-groups))
 694           (t
 695            (let ((cell (nthcdr pos ibuffer-filter-groups)))
 696              (setf (cdr cell) (cons (car cell) (cdr cell)))
 697              (setf (car cell) newgroup))))))
 698
 699 ;;;###autoload
 700 (defun ibuffer-yank ()
 701   "Yank the last killed filter group before group at point."
 702   (interactive)
 703   (ibuffer-yank-filter-group
 704    (or (get-text-property (point) 'ibuffer-filter-group-name)
 705        (get-text-property (point) 'ibuffer-filter-group)
 706        (error "No filter group at point"))))
 707
 708 ;;;###autoload
 709 (defun ibuffer-yank-filter-group (name)
 710   "Yank the last killed filter group before group named NAME."
 711   (interactive (list (ibuffer-read-filter-group-name
 712                         "Yank filter group before group: ")))
 713   (unless ibuffer-filter-group-kill-ring
 714     (error "The Ibuffer filter group kill-ring is empty"))
 715   (save-excursion
 716     (ibuffer-forward-line 0)
 717     (ibuffer-insert-filter-group-before (pop ibuffer-filter-group-kill-ring)
 718                                         name))
 719   (ibuffer-update nil t))
 720
 721 ;;;###autoload
 722 (defun ibuffer-save-filter-groups (name groups)
 723   "Save all active filter groups GROUPS as NAME.
 724 They are added to `ibuffer-saved-filter-groups'.  Interactively,
 725 prompt for NAME, and use the current filters."
 726   (interactive
 727    (if (null ibuffer-filter-groups)
 728        (error "No filter groups active")
 729      (list
 730       (read-from-minibuffer "Save current filter groups as: ")
 731       ibuffer-filter-groups)))
 732   (ibuffer-aif (assoc name ibuffer-saved-filter-groups)
 733       (setcdr it groups)
 734     (push (cons name groups) ibuffer-saved-filter-groups))
 735   (ibuffer-maybe-save-stuff))
 736
 737 ;;;###autoload
 738 (defun ibuffer-delete-saved-filter-groups (name)
 739   "Delete saved filter groups with NAME.
 740 They are removed from `ibuffer-saved-filter-groups'."
 741   (interactive
 742    (list
 743     (if (null ibuffer-saved-filter-groups)
 744         (error "No saved filter groups")
 745       (completing-read "Delete saved filter group: "
 746                        ibuffer-saved-filter-groups nil t))))
 747   (setq ibuffer-saved-filter-groups
 748         (ibuffer-delete-alist name ibuffer-saved-filter-groups))
 749   (ibuffer-maybe-save-stuff)
 750   (ibuffer-update nil t))
 751
 752 ;;;###autoload
 753 (defun ibuffer-switch-to-saved-filter-groups (name)
 754   "Set this buffer's filter groups to saved version with NAME.
 755 The value from `ibuffer-saved-filter-groups' is used."
 756   (interactive
 757    (list
 758     (if (null ibuffer-saved-filter-groups)
 759         (error "No saved filters")
 760       (completing-read "Switch to saved filter group: "
 761                        ibuffer-saved-filter-groups nil t))))
 762   (setq ibuffer-filter-groups (cdr (assoc name ibuffer-saved-filter-groups))
 763         ibuffer-hidden-filter-groups nil)
 764   (ibuffer-update nil t))
 765
 766 ;;;###autoload
 767 (defun ibuffer-filter-disable (&optional delete-filter-groups)
 768   "Disable all filters currently in effect in this buffer.
 769 With optional arg DELETE-FILTER-GROUPS non-nil, delete all filter
 770 group definitions by setting `ibuffer-filter-groups' to nil."
 771   (interactive)
 772   (setq ibuffer-filtering-qualifiers nil)
 773   (if delete-filter-groups
 774       (setq ibuffer-filter-groups nil))
 775   (let ((buf (ibuffer-current-buffer)))
 776     (ibuffer-update nil t)
 777     (when buf
 778       (ibuffer-jump-to-buffer (buffer-name buf)))))
 779
 780 ;;;###autoload
 781 (defun ibuffer-pop-filter ()
 782   "Remove the top filter in this buffer."
 783   (interactive)
 784   (when (null ibuffer-filtering-qualifiers)
 785     (error "No filters in effect"))
 786   (pop ibuffer-filtering-qualifiers)
 787   (let ((buf (ibuffer-current-buffer)))
 788     (ibuffer-update nil t)
 789     (when buf
 790       (ibuffer-jump-to-buffer (buffer-name buf)))))
 791
 792 (defun ibuffer-push-filter (qualifier)
 793   "Add QUALIFIER to `ibuffer-filtering-qualifiers'."
 794   (push qualifier ibuffer-filtering-qualifiers))
 795
 796 ;;;###autoload
 797 (defun ibuffer-decompose-filter ()
 798   "Separate the top compound filter (OR, NOT, or SAVED) in this buffer.
 799
 800 This means that the topmost filter on the filtering stack, which must
 801 be a complex filter like (OR [name: foo] [mode: bar-mode]), will be
 802 turned into two separate filters [name: foo] and [mode: bar-mode]."
 803   (interactive)
 804   (when (null ibuffer-filtering-qualifiers)
 805     (error "No filters in effect"))
 806   (let ((lim (pop ibuffer-filtering-qualifiers)))
 807     (pcase (car lim)
 808       (`or
 809        (setq ibuffer-filtering-qualifiers (append
 810                                           (cdr lim)
 811                                           ibuffer-filtering-qualifiers)))
 812       (`saved
 813        (let ((data
 814               (assoc (cdr lim)
 815                      ibuffer-saved-filters)))
 816          (unless data
 817            (ibuffer-filter-disable)
 818            (error "Unknown saved filter %s" (cdr lim)))
 819          (setq ibuffer-filtering-qualifiers (append
 820                                             (cadr data)
 821                                             ibuffer-filtering-qualifiers))))
 822       (`not
 823        (push (cdr lim)
 824              ibuffer-filtering-qualifiers))
 825       (_
 826        (error "Filter type %s is not compound" (car lim)))))
 827   (ibuffer-update nil t))
 828
 829 ;;;###autoload
 830 (defun ibuffer-exchange-filters ()
 831   "Exchange the top two filters on the stack in this buffer."
 832   (interactive)
 833   (when (< (length ibuffer-filtering-qualifiers)
 834            2)
 835     (error "Need two filters to exchange"))
 836   (let ((first (pop ibuffer-filtering-qualifiers))
 837         (second (pop ibuffer-filtering-qualifiers)))
 838     (push first ibuffer-filtering-qualifiers)
 839     (push second ibuffer-filtering-qualifiers))
 840   (ibuffer-update nil t))
 841
 842 ;;;###autoload
 843 (defun ibuffer-negate-filter ()
 844   "Negate the sense of the top filter in the current buffer."
 845   (interactive)
 846   (when (null ibuffer-filtering-qualifiers)
 847     (error "No filters in effect"))
 848   (let ((lim (pop ibuffer-filtering-qualifiers)))
 849     (push (if (eq (car lim) 'not)
 850               (cdr lim)
 851             (cons 'not lim))
 852           ibuffer-filtering-qualifiers))
 853   (ibuffer-update nil t))
 854
 855 ;;;###autoload
 856 (defun ibuffer-or-filter (&optional reverse)
 857   "Replace the top two filters in this buffer with their logical OR.
 858 If optional argument REVERSE is non-nil, instead break the top OR
 859 filter into parts."
 860   (interactive "P")
 861   (if reverse
 862       (progn
 863         (when (or (null ibuffer-filtering-qualifiers)
 864                   (not (eq 'or (caar ibuffer-filtering-qualifiers))))
 865           (error "Top filter is not an OR"))
 866         (let ((lim (pop ibuffer-filtering-qualifiers)))
 867           (setq ibuffer-filtering-qualifiers
 868                 (nconc (cdr lim) ibuffer-filtering-qualifiers))))
 869     (when (< (length ibuffer-filtering-qualifiers) 2)
 870       (error "Need two filters to OR"))
 871     ;; If the second filter is an OR, just add to it.
 872     (let ((first (pop ibuffer-filtering-qualifiers))
 873           (second (pop ibuffer-filtering-qualifiers)))
 874       (if (eq 'or (car second))
 875           (push (nconc (list 'or first) (cdr second))
 876                 ibuffer-filtering-qualifiers)
 877         (push (list 'or first second)
 878               ibuffer-filtering-qualifiers))))
 879   (ibuffer-update nil t))
 880
 881 (defun ibuffer-maybe-save-stuff ()
 882   (when ibuffer-save-with-custom
 883     (if (fboundp 'customize-save-variable)
 884         (progn
 885           (customize-save-variable 'ibuffer-saved-filters
 886                                    ibuffer-saved-filters)
 887           (customize-save-variable 'ibuffer-saved-filter-groups
 888                                    ibuffer-saved-filter-groups))
 889       (message "Not saved permanently: Customize not available"))))
 890
 891 ;;;###autoload
 892 (defun ibuffer-save-filters (name filters)
 893   "Save FILTERS in this buffer with name NAME in `ibuffer-saved-filters'.
 894 Interactively, prompt for NAME, and use the current filters."
 895   (interactive
 896    (if (null ibuffer-filtering-qualifiers)
 897        (error "No filters currently in effect")
 898      (list
 899       (read-from-minibuffer "Save current filters as: ")
 900       ibuffer-filtering-qualifiers)))
 901   (ibuffer-aif (assoc name ibuffer-saved-filters)
 902       (setcdr it filters)
 903     (push (list name filters) ibuffer-saved-filters))
 904   (ibuffer-maybe-save-stuff))
 905
 906 ;;;###autoload
 907 (defun ibuffer-delete-saved-filters (name)
 908   "Delete saved filters with NAME from `ibuffer-saved-filters'."
 909   (interactive
 910    (list
 911     (if (null ibuffer-saved-filters)
 912         (error "No saved filters")
 913       (completing-read "Delete saved filters: "
 914                        ibuffer-saved-filters nil t))))
 915   (setq ibuffer-saved-filters
 916         (ibuffer-delete-alist name ibuffer-saved-filters))
 917   (ibuffer-maybe-save-stuff)
 918   (ibuffer-update nil t))
 919
 920 ;;;###autoload
 921 (defun ibuffer-add-saved-filters (name)
 922   "Add saved filters from `ibuffer-saved-filters' to this buffer's filters."
 923   (interactive
 924    (list
 925     (if (null ibuffer-saved-filters)
 926         (error "No saved filters")
 927       (completing-read "Add saved filters: "
 928                        ibuffer-saved-filters nil t))))
 929   (push (cons 'saved name) ibuffer-filtering-qualifiers)
 930   (ibuffer-update nil t))
 931
 932 ;;;###autoload
 933 (defun ibuffer-switch-to-saved-filters (name)
 934   "Set this buffer's filters to filters with NAME from `ibuffer-saved-filters'."
 935   (interactive
 936    (list
 937     (if (null ibuffer-saved-filters)
 938         (error "No saved filters")
 939       (completing-read "Switch to saved filters: "
 940                        ibuffer-saved-filters nil t))))
 941   (setq ibuffer-filtering-qualifiers (list (cons 'saved name)))
 942   (ibuffer-update nil t))
 943
 944 (defun ibuffer-format-filter-group-data (filter)
 945   (if (equal filter "Default")
 946       ""
 947     (concat "Filter:" (mapconcat #'ibuffer-format-qualifier
 948                                  (cdr (assq filter ibuffer-filter-groups))
 949                                  " "))))
 950
 951 (defun ibuffer-format-qualifier (qualifier)
 952   (if (eq (car-safe qualifier) 'not)
 953       (concat " [NOT" (ibuffer-format-qualifier-1 (cdr qualifier)) "]")
 954     (ibuffer-format-qualifier-1 qualifier)))
 955
 956 (defun ibuffer-format-qualifier-1 (qualifier)
 957   (pcase (car qualifier)
 958     (`saved
 959      (concat " [filter: " (cdr qualifier) "]"))
 960     (`or
 961      (concat " [OR" (mapconcat #'ibuffer-format-qualifier
 962                                (cdr qualifier) "") "]"))
 963     (_
 964      (let ((type (assq (car qualifier) ibuffer-filtering-alist)))
 965        (unless qualifier
 966          (error "Ibuffer: bad qualifier %s" qualifier))
 967        (concat " [" (cadr type) ": " (format "%s]" (cdr qualifier)))))))
 968
 969
 970 (defun ibuffer-list-buffer-modes (&optional include-parents)
 971   "Create a completion table of buffer modes currently in use.
 972 If INCLUDE-PARENTS is non-nil then include parent modes."
 973   (let ((modes))
 974     (dolist (buf (buffer-list))
 975       (let ((this-mode (buffer-local-value 'major-mode buf)))
 976         (while (and this-mode (not (memq this-mode modes)))
 977           (push this-mode modes)
 978           (setq this-mode (and include-parents
 979                                (get this-mode 'derived-mode-parent))))))
 980     (mapcar #'symbol-name modes)))
 981
 982
 983 ;;; Extra operation definitions
 984
 985 ;;;###autoload (autoload 'ibuffer-filter-by-mode "ibuf-ext")
 986 (define-ibuffer-filter mode
 987   "Toggle current view to buffers with major mode QUALIFIER."
 988   (:description "major mode"
 989    :reader
 990    (let* ((buf (ibuffer-current-buffer))
 991           (default (if (and buf (buffer-live-p buf))
 992                        (symbol-name (buffer-local-value
 993                                      'major-mode buf)))))
 994      (intern
 995       (completing-read
 996        (if default
 997            (format "Filter by major mode (default %s): " default)
 998          "Filter by major mode: ")
 999        obarray
1000        #'(lambda (e)
1001            (string-match "-mode\\'" (symbol-name e)))
1002        t nil nil default))))
1003   (eq qualifier (buffer-local-value 'major-mode buf)))
1004
1005 ;;;###autoload (autoload 'ibuffer-filter-by-used-mode "ibuf-ext")
1006 (define-ibuffer-filter used-mode
1007   "Toggle current view to buffers with major mode QUALIFIER.
1008 Called interactively, this function allows selection of modes
1009 currently used by buffers."
1010   (:description "major mode in use"
1011    :reader
1012    (let* ((buf (ibuffer-current-buffer))
1013           (default (if (and buf (buffer-live-p buf))
1014                        (symbol-name (buffer-local-value
1015                                      'major-mode buf)))))
1016      (intern
1017       (completing-read
1018        (if default
1019            (format "Filter by major mode (default %s): " default)
1020          "Filter by major mode: ")
1021        (ibuffer-list-buffer-modes) nil t nil nil default))))
1022   (eq qualifier (buffer-local-value 'major-mode buf)))
1023
1024 ;;;###autoload (autoload 'ibuffer-filter-by-derived-mode "ibuf-ext")
1025 (define-ibuffer-filter derived-mode
1026     "Toggle current view to buffers whose major mode inherits from QUALIFIER."
1027   (:description "derived mode"
1028                 :reader
1029                 (intern
1030                  (completing-read "Filter by derived mode: "
1031                                   (ibuffer-list-buffer-modes t)
1032                                   nil t)))
1033   (with-current-buffer buf (derived-mode-p qualifier)))
1034
1035 ;;;###autoload (autoload 'ibuffer-filter-by-name "ibuf-ext")
1036 (define-ibuffer-filter name
1037   "Toggle current view to buffers with name matching QUALIFIER."
1038   (:description "buffer name"
1039    :reader (read-from-minibuffer "Filter by name (regexp): "))
1040   (string-match qualifier (buffer-name buf)))
1041
1042 ;;;###autoload (autoload 'ibuffer-filter-by-filename "ibuf-ext")
1043 (define-ibuffer-filter filename
1044   "Toggle current view to buffers with filename matching QUALIFIER."
1045   (:description "filename"
1046    :reader (read-from-minibuffer "Filter by filename (regexp): "))
1047   (ibuffer-awhen (buffer-local-value 'buffer-file-name buf)
1048     (string-match qualifier it)))
1049
1050 ;;;###autoload (autoload 'ibuffer-filter-by-size-gt  "ibuf-ext")
1051 (define-ibuffer-filter size-gt
1052   "Toggle current view to buffers with size greater than QUALIFIER."
1053   (:description "size greater than"
1054    :reader
1055    (string-to-number (read-from-minibuffer "Filter by size greater than: ")))
1056   (> (with-current-buffer buf (buffer-size))
1057      qualifier))
1058
1059 ;;;###autoload (autoload 'ibuffer-filter-by-size-lt  "ibuf-ext")
1060 (define-ibuffer-filter size-lt
1061    "Toggle current view to buffers with size less than QUALIFIER."
1062   (:description "size less than"
1063    :reader
1064    (string-to-number (read-from-minibuffer "Filter by size less than: ")))
1065   (< (with-current-buffer buf (buffer-size))
1066      qualifier))
1067
1068 ;;;###autoload (autoload 'ibuffer-filter-by-content "ibuf-ext")
1069 (define-ibuffer-filter content
1070    "Toggle current view to buffers whose contents match QUALIFIER."
1071   (:description "content"
1072    :reader (read-from-minibuffer "Filter by content (regexp): "))
1073   (with-current-buffer buf
1074     (save-excursion
1075       (goto-char (point-min))
1076       (re-search-forward qualifier nil t))))
1077
1078 ;;;###autoload (autoload 'ibuffer-filter-by-predicate "ibuf-ext")
1079 (define-ibuffer-filter predicate
1080    "Toggle current view to buffers for which QUALIFIER returns non-nil."
1081   (:description "predicate"
1082    :reader (read-minibuffer "Filter by predicate (form): "))
1083   (with-current-buffer buf
1084     (eval qualifier)))
1085
1086 ;;; Sorting
1087
1088 ;;;###autoload
1089 (defun ibuffer-toggle-sorting-mode ()
1090   "Toggle the current sorting mode.
1091 Default sorting modes are:
1092  Recency - the last time the buffer was viewed
1093  Name - the name of the buffer
1094  Major Mode - the name of the major mode of the buffer
1095  Size - the size of the buffer"
1096   (interactive)
1097   (let ((modes (mapcar 'car ibuffer-sorting-functions-alist)))
1098     (add-to-list 'modes 'recency)
1099     (setq modes (sort modes 'string-lessp))
1100     (let ((next (or (car-safe (cdr-safe (memq ibuffer-sorting-mode modes)))
1101                     (car modes))))
1102       (setq ibuffer-sorting-mode next)
1103       (message "Sorting by %s" next)))
1104   (ibuffer-redisplay t))
1105
1106 ;;;###autoload
1107 (defun ibuffer-invert-sorting ()
1108   "Toggle whether or not sorting is in reverse order."
1109   (interactive)
1110   (setq ibuffer-sorting-reversep (not ibuffer-sorting-reversep))
1111   (message "Sorting order %s"
1112            (if ibuffer-sorting-reversep
1113                "reversed"
1114              "normal"))
1115   (ibuffer-redisplay t))
1116
1117 ;;;###autoload (autoload 'ibuffer-do-sort-by-major-mode "ibuf-ext")
1118 (define-ibuffer-sorter major-mode
1119   "Sort the buffers by major modes.
1120 Ordering is lexicographic."
1121   (:description "major mode")
1122   (string-lessp (downcase
1123                  (symbol-name (buffer-local-value 'major-mode (car a))))
1124                 (downcase
1125                  (symbol-name (buffer-local-value 'major-mode (car b))))))
1126
1127 ;;;###autoload (autoload 'ibuffer-do-sort-by-mode-name "ibuf-ext")
1128 (define-ibuffer-sorter mode-name
1129   "Sort the buffers by their mode name.
1130 Ordering is lexicographic."
1131   (:description "major mode name")
1132   (string-lessp (downcase
1133                  (with-current-buffer
1134                      (car a)
1135                    (format-mode-line mode-name)))
1136                 (downcase
1137                  (with-current-buffer
1138                      (car b)
1139                    (format-mode-line mode-name)))))
1140
1141 ;;;###autoload (autoload 'ibuffer-do-sort-by-alphabetic "ibuf-ext")
1142 (define-ibuffer-sorter alphabetic
1143   "Sort the buffers by their names.
1144 Ordering is lexicographic."
1145   (:description "buffer name")
1146   (string-lessp
1147    (buffer-name (car a))
1148    (buffer-name (car b))))
1149
1150 ;;;###autoload (autoload 'ibuffer-do-sort-by-size "ibuf-ext")
1151 (define-ibuffer-sorter size
1152  "Sort the buffers by their size."
1153   (:description "size")
1154   (< (with-current-buffer (car a)
1155        (buffer-size))
1156      (with-current-buffer (car b)
1157        (buffer-size))))
1158
1159 ;;;###autoload (autoload 'ibuffer-do-sort-by-filename/process "ibuf-ext")
1160 (define-ibuffer-sorter filename/process
1161  "Sort the buffers by their file name/process name."
1162   (:description "file name")
1163   (string-lessp
1164    ;; FIXME: For now just compare the file name and the process name
1165    ;; (if it exists).  Is there a better way to do this?
1166    (or (buffer-file-name (car a))
1167        (let ((pr-a (get-buffer-process (car a))))
1168          (and (processp pr-a) (process-name pr-a))))
1169    (or (buffer-file-name (car b))
1170        (let ((pr-b (get-buffer-process (car b))))
1171          (and (processp pr-b) (process-name pr-b))))))
1172
1173 ;;; Functions to emulate bs.el
1174
1175 ;;;###autoload
1176 (defun ibuffer-bs-show ()
1177   "Emulate `bs-show' from the bs.el package."
1178   (interactive)
1179   (ibuffer t "*Ibuffer-bs*" '((filename . ".*")) nil t)
1180   (define-key (current-local-map) "a" 'ibuffer-bs-toggle-all))
1181
1182 (defun ibuffer-bs-toggle-all ()
1183   "Emulate `bs-toggle-show-all' from the bs.el package."
1184   (interactive)
1185   (if ibuffer-filtering-qualifiers
1186       (ibuffer-pop-filter)
1187     (progn (ibuffer-push-filter '(filename . ".*"))
1188            (ibuffer-update nil t))))
1189
1190 ;;; Handy functions
1191
1192 ;;;###autoload
1193 (defun ibuffer-add-to-tmp-hide (regexp)
1194   "Add REGEXP to `ibuffer-tmp-hide-regexps'.
1195 This means that buffers whose name matches REGEXP will not be shown
1196 for this Ibuffer session."
1197   (interactive
1198    (list
1199     (read-from-minibuffer "Never show buffers matching: "
1200                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1201   (push regexp ibuffer-tmp-hide-regexps))
1202
1203 ;;;###autoload
1204 (defun ibuffer-add-to-tmp-show (regexp)
1205   "Add REGEXP to `ibuffer-tmp-show-regexps'.
1206 This means that buffers whose name matches REGEXP will always be shown
1207 for this Ibuffer session."
1208   (interactive
1209    (list
1210     (read-from-minibuffer "Always show buffers matching: "
1211                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1212   (push regexp ibuffer-tmp-show-regexps))
1213
1214 ;;;###autoload
1215 (defun ibuffer-forward-next-marked (&optional count mark direction)
1216   "Move forward by COUNT marked buffers (default 1).
1217
1218 If MARK is non-nil, it should be a character denoting the type of mark
1219 to move by.  The default is `ibuffer-marked-char'.
1220
1221 If DIRECTION is non-nil, it should be an integer; negative integers
1222 mean move backwards, non-negative integers mean move forwards."
1223   (interactive "P")
1224   (unless count
1225     (setq count 1))
1226   (unless mark
1227     (setq mark ibuffer-marked-char))
1228   (unless direction
1229     (setq direction 1))
1230   ;; Skip the title
1231   (ibuffer-forward-line 0)
1232   (let ((opos (point)))
1233     (ibuffer-forward-line direction)
1234     (while (not (or (= (point) opos)
1235                     (eq (ibuffer-current-mark) mark)))
1236       (ibuffer-forward-line direction))
1237     (when (and (= (point) opos)
1238                (not (eq (ibuffer-current-mark) mark)))
1239       (error "No buffers with mark %c" mark))))
1240
1241 ;;;###autoload
1242 (defun ibuffer-backwards-next-marked (&optional count mark)
1243    "Move backwards by COUNT marked buffers (default 1).
1244
1245 If MARK is non-nil, it should be a character denoting the type of mark
1246 to move by.  The default is `ibuffer-marked-char'."
1247    (interactive "P")
1248    (ibuffer-forward-next-marked count mark -1))
1249
1250 ;;;###autoload
1251 (defun ibuffer-do-kill-lines ()
1252   "Hide all of the currently marked lines."
1253   (interactive)
1254   (if (= (ibuffer-count-marked-lines) 0)
1255       (message "No buffers marked; use 'm' to mark a buffer")
1256     (let ((count
1257            (ibuffer-map-marked-lines
1258             #'(lambda (_buf _mark)
1259                 'kill))))
1260       (message "Killed %s lines" count))))
1261
1262 ;;;###autoload
1263 (defun ibuffer-jump-to-buffer (name)
1264   "Move point to the buffer whose name is NAME.
1265
1266 If called interactively, prompt for a buffer name and go to the
1267 corresponding line in the Ibuffer buffer.  If said buffer is in a
1268 hidden group filter, open it.
1269
1270 If `ibuffer-jump-offer-only-visible-buffers' is non-nil, only offer
1271 visible buffers in the completion list.  Calling the command with
1272 a prefix argument reverses the meaning of that variable."
1273   (interactive (list
1274                 (let ((only-visible ibuffer-jump-offer-only-visible-buffers))
1275                   (when current-prefix-arg
1276                     (setq only-visible (not only-visible)))
1277                   (if only-visible
1278                       (let ((table (mapcar #'(lambda (x)
1279                                                (buffer-name (car x)))
1280                                            (ibuffer-current-state-list))))
1281                         (when (null table)
1282                           (error "No buffers!"))
1283                         (completing-read "Jump to buffer: "
1284                                          table nil t))
1285                     (read-buffer "Jump to buffer: " nil t)))))
1286   (when (not (string= "" name))
1287     (let (buf-point)
1288       ;; Blindly search for our buffer: it is very likely that it is
1289       ;; not in a hidden filter group.
1290       (ibuffer-map-lines #'(lambda (buf _marks)
1291                              (when (string= (buffer-name buf) name)
1292                                (setq buf-point (point))
1293                                nil))
1294                          t nil)
1295       (when (and
1296              (null buf-point)
1297              (not (null ibuffer-hidden-filter-groups)))
1298         ;; We did not find our buffer.  It must be in a hidden filter
1299         ;; group, so go through all hidden filter groups to find it.
1300         (catch 'found
1301           (dolist (group ibuffer-hidden-filter-groups)
1302             (ibuffer-jump-to-filter-group group)
1303             (ibuffer-toggle-filter-group)
1304             (ibuffer-map-lines #'(lambda (buf _marks)
1305                                    (when (string= (buffer-name buf) name)
1306                                      (setq buf-point (point))
1307                                      nil))
1308                                t group)
1309             (if buf-point
1310                 (throw 'found nil)
1311               (ibuffer-toggle-filter-group)))))
1312       (if (null buf-point)
1313           ;; Still not found even though we expanded all hidden filter
1314           ;; groups: that must be because it's hidden by predicate:
1315           ;; we won't bother trying to display it.
1316           (error "No buffer with name %s" name)
1317         (goto-char buf-point)))))
1318
1319 (declare-function diff-sentinel "diff"
1320                   (code &optional old-temp-file new-temp-file))
1321
1322 (defun ibuffer-diff-buffer-with-file-1 (buffer)
1323   (let ((bufferfile (buffer-local-value 'buffer-file-name buffer))
1324         (tempfile (make-temp-file "buffer-content-")))
1325     (when bufferfile
1326       (unwind-protect
1327           (progn
1328             (with-current-buffer buffer
1329               (write-region nil nil tempfile nil 'nomessage))
1330             (let* ((old (expand-file-name bufferfile))
1331                    (new (expand-file-name tempfile))
1332                    (oldtmp (file-local-copy old))
1333                    (newtmp (file-local-copy new))
1334                    (switches diff-switches)
1335                    (command
1336                     (mapconcat
1337                      'identity
1338                      `(,diff-command
1339                        ;; Use explicitly specified switches
1340                        ,@(if (listp switches) switches (list switches))
1341                        ,@(if (or old new)
1342                              (list "-L" (shell-quote-argument old)
1343                                    "-L" (shell-quote-argument
1344                                          (format "Buffer %s" (buffer-name buffer)))))
1345                        ,(shell-quote-argument (or oldtmp old))
1346                        ,(shell-quote-argument (or newtmp new)))
1347                      " ")))
1348               (let ((inhibit-read-only t))
1349                 (insert command "\n")
1350                 (diff-sentinel
1351                  (call-process shell-file-name nil
1352                                (current-buffer) nil
1353                                shell-command-switch command))
1354                 (insert "\n")))))
1355       (sit-for 0)
1356       (when (file-exists-p tempfile)
1357         (delete-file tempfile)))))
1358
1359 ;;;###autoload
1360 (defun ibuffer-diff-with-file ()
1361   "View the differences between marked buffers and their associated files.
1362 If no buffers are marked, use buffer at point.
1363 This requires the external program \"diff\" to be in your `exec-path'."
1364   (interactive)
1365   (require 'diff)
1366   (let ((marked-bufs (ibuffer-get-marked-buffers)))
1367     (when (null marked-bufs)
1368       (setq marked-bufs (list (ibuffer-current-buffer t))))
1369     (with-current-buffer (get-buffer-create "*Ibuffer Diff*")
1370       (setq buffer-read-only nil)
1371       (buffer-disable-undo (current-buffer))
1372       (erase-buffer)
1373       (buffer-enable-undo (current-buffer))
1374       (diff-mode)
1375       (dolist (buf marked-bufs)
1376         (unless (buffer-live-p buf)
1377           (error "Buffer %s has been killed" buf))
1378         (ibuffer-diff-buffer-with-file-1 buf))
1379       (setq buffer-read-only t)))
1380   (switch-to-buffer "*Ibuffer Diff*"))
1381
1382 ;;;###autoload
1383 (defun ibuffer-copy-filename-as-kill (&optional arg)
1384   "Copy filenames of marked buffers into the kill ring.
1385
1386 The names are separated by a space.
1387 If a buffer has no filename, it is ignored.
1388
1389 With no prefix arg, use the filename sans its directory of each marked file.
1390 With a zero prefix arg, use the complete filename of each marked file.
1391 With \\[universal-argument], use the filename of each marked file relative
1392 to `ibuffer-default-directory' if non-nil, otherwise `default-directory'.
1393
1394 You can then feed the file name(s) to other commands with \\[yank]."
1395   (interactive "p")
1396   (if (zerop (ibuffer-count-marked-lines))
1397       (message "No buffers marked; use 'm' to mark a buffer")
1398     (let ((ibuffer-copy-filename-as-kill-result "")
1399           (type (cond ((zerop arg)
1400                        'full)
1401                       ((= arg 4)
1402                        'relative)
1403                       (t
1404                        'name))))
1405       (ibuffer-map-marked-lines
1406        #'(lambda (buf _mark)
1407            (setq ibuffer-copy-filename-as-kill-result
1408                  (concat ibuffer-copy-filename-as-kill-result
1409                          (let ((name (buffer-file-name buf)))
1410                            (if name
1411                                (pcase type
1412                                  (`full
1413                                   name)
1414                                  (`relative
1415                                   (file-relative-name
1416                                    name (or ibuffer-default-directory
1417                                             default-directory)))
1418                                  (_
1419                                   (file-name-nondirectory name)))
1420                              ""))
1421                          " "))))
1422       (kill-new ibuffer-copy-filename-as-kill-result))))
1423
1424 (defun ibuffer-mark-on-buffer (func &optional ibuffer-mark-on-buffer-mark group)
1425   (let ((count
1426          (ibuffer-map-lines
1427           #'(lambda (buf _mark)
1428               (when (funcall func buf)
1429                 (ibuffer-set-mark-1 (or ibuffer-mark-on-buffer-mark
1430                                         ibuffer-marked-char))
1431                 t))
1432           nil
1433           group)))
1434     (ibuffer-redisplay t)
1435     (unless (eq ibuffer-mark-on-buffer-mark ?\s)
1436       (message "Marked %s buffers" count))))
1437
1438 ;;;###autoload
1439 (defun ibuffer-mark-by-name-regexp (regexp)
1440   "Mark all buffers whose name matches REGEXP."
1441   (interactive "sMark by name (regexp): ")
1442   (ibuffer-mark-on-buffer
1443    #'(lambda (buf)
1444        (string-match regexp (buffer-name buf)))))
1445
1446 ;;;###autoload
1447 (defun ibuffer-mark-by-mode-regexp (regexp)
1448   "Mark all buffers whose major mode matches REGEXP."
1449   (interactive "sMark by major mode (regexp): ")
1450   (ibuffer-mark-on-buffer
1451    #'(lambda (buf)
1452        (with-current-buffer buf
1453          (string-match regexp (format-mode-line mode-name nil nil buf))))))
1454
1455 ;;;###autoload
1456 (defun ibuffer-mark-by-file-name-regexp (regexp)
1457   "Mark all buffers whose file name matches REGEXP."
1458   (interactive "sMark by file name (regexp): ")
1459   (ibuffer-mark-on-buffer
1460    #'(lambda (buf)
1461        (let ((name (or (buffer-file-name buf)
1462                        (with-current-buffer buf
1463                          (and
1464                           (boundp 'dired-directory)
1465                           (stringp dired-directory)
1466                           dired-directory)))))
1467          (when name
1468            (string-match regexp name))))))
1469
1470 ;;;###autoload
1471 (defun ibuffer-mark-by-mode (mode)
1472   "Mark all buffers whose major mode equals MODE."
1473   (interactive
1474    (let* ((buf (ibuffer-current-buffer))
1475           (default (if (and buf (buffer-live-p buf))
1476                        (symbol-name (buffer-local-value
1477                                      'major-mode buf)))))
1478      (list (intern
1479             (completing-read
1480              (if default
1481                  (format "Mark by major mode (default %s): " default)
1482                "Mark by major mode: ")
1483              (ibuffer-list-buffer-modes) nil t nil nil default)))))
1484   (ibuffer-mark-on-buffer
1485    #'(lambda (buf)
1486        (eq (buffer-local-value 'major-mode buf) mode))))
1487
1488 ;;;###autoload
1489 (defun ibuffer-mark-modified-buffers ()
1490   "Mark all modified buffers."
1491   (interactive)
1492   (ibuffer-mark-on-buffer
1493    #'(lambda (buf) (buffer-modified-p buf))))
1494
1495 ;;;###autoload
1496 (defun ibuffer-mark-unsaved-buffers ()
1497   "Mark all modified buffers that have an associated file."
1498   (interactive)
1499   (ibuffer-mark-on-buffer
1500    #'(lambda (buf) (and (buffer-local-value 'buffer-file-name buf)
1501                         (buffer-modified-p buf)))))
1502
1503 ;;;###autoload
1504 (defun ibuffer-mark-dissociated-buffers ()
1505   "Mark all buffers whose associated file does not exist."
1506   (interactive)
1507   (ibuffer-mark-on-buffer
1508    #'(lambda (buf)
1509        (with-current-buffer buf
1510          (or
1511           (and buffer-file-name
1512                (not (file-exists-p buffer-file-name)))
1513           (and (eq major-mode 'dired-mode)
1514                (boundp 'dired-directory)
1515                (stringp dired-directory)
1516                (not (file-exists-p (file-name-directory dired-directory)))))))))
1517
1518 ;;;###autoload
1519 (defun ibuffer-mark-help-buffers ()
1520   "Mark buffers like *Help*, *Apropos*, *Info*."
1521   (interactive)
1522   (ibuffer-mark-on-buffer
1523    #'(lambda (buf)
1524        (with-current-buffer buf
1525          (memq major-mode ibuffer-help-buffer-modes)))))
1526
1527 ;;;###autoload
1528 (defun ibuffer-mark-compressed-file-buffers ()
1529   "Mark buffers whose associated file is compressed."
1530   (interactive)
1531   (ibuffer-mark-on-buffer
1532    #'(lambda (buf)
1533        (with-current-buffer buf
1534          (and buffer-file-name
1535               (string-match ibuffer-compressed-file-name-regexp
1536                            buffer-file-name))))))
1537
1538 ;;;###autoload
1539 (defun ibuffer-mark-old-buffers ()
1540   "Mark buffers which have not been viewed in `ibuffer-old-time' hours."
1541   (interactive)
1542   (ibuffer-mark-on-buffer
1543    #'(lambda (buf)
1544        (with-current-buffer buf
1545          ;; hacked from midnight.el
1546          (when buffer-display-time
1547            (let* ((now (float-time))
1548                   (then (float-time buffer-display-time)))
1549              (> (- now then) (* 60 60 ibuffer-old-time))))))))
1550
1551 ;;;###autoload
1552 (defun ibuffer-mark-special-buffers ()
1553   "Mark all buffers whose name begins and ends with '*'."
1554   (interactive)
1555   (ibuffer-mark-on-buffer
1556    #'(lambda (buf) (string-match "^\\*.+\\*$"
1557                                  (buffer-name buf)))))
1558
1559 ;;;###autoload
1560 (defun ibuffer-mark-read-only-buffers ()
1561   "Mark all read-only buffers."
1562   (interactive)
1563   (ibuffer-mark-on-buffer
1564    #'(lambda (buf) (buffer-local-value 'buffer-read-only buf))))
1565
1566 ;;;###autoload
1567 (defun ibuffer-mark-dired-buffers ()
1568   "Mark all `dired' buffers."
1569   (interactive)
1570   (ibuffer-mark-on-buffer
1571    #'(lambda (buf) (eq (buffer-local-value 'major-mode buf) 'dired-mode))))
1572
1573 ;;;###autoload
1574 (defun ibuffer-do-occur (regexp &optional nlines)
1575   "View lines which match REGEXP in all marked buffers.
1576 Optional argument NLINES says how many lines of context to display: it
1577 defaults to one."
1578   (interactive (occur-read-primary-args))
1579   (if (or (not (integerp nlines))
1580           (< nlines 0))
1581       (setq nlines 0))
1582   (when (zerop (ibuffer-count-marked-lines))
1583     (ibuffer-set-mark ibuffer-marked-char))
1584   (let ((ibuffer-do-occur-bufs nil))
1585     ;; Accumulate a list of marked buffers
1586     (ibuffer-map-marked-lines
1587      #'(lambda (buf _mark)
1588          (push buf ibuffer-do-occur-bufs)))
1589     (occur-1 regexp nlines ibuffer-do-occur-bufs)))
1590
1591 (provide 'ibuf-ext)
1592
1593 ;; Local Variables:
1594 ;; generated-autoload-file: "ibuffer.el"
1595 ;; End:
1596
1597 ;;; ibuf-ext.el ends here