| blob | 5a02beda097d767496680f6b04922cfa2b1da6e9 |
1 dnl Autoconf script for GNU Emacs
2 dnl To rebuild the `configure' script from this, execute the command
3 dnl autoconf
4 dnl in the directory containing this script.
5 dnl
6 dnl Copyright (C) 1994, 95, 96, 1999, 2000, 01, 02, 03, 2004
7 dnl Free Software Foundation, Inc.
8 dnl
9 dnl This file is part of GNU Emacs.
10 dnl
11 dnl GNU Emacs is free software; you can redistribute it and/or modify
12 dnl it under the terms of the GNU General Public License as published by
13 dnl the Free Software Foundation; either version 2, or (at your option)
14 dnl any later version.
15 dnl
16 dnl GNU Emacs is distributed in the hope that it will be useful,
17 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
18 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
19 dnl GNU General Public License for more details.
20 dnl
21 dnl You should have received a copy of the GNU General Public License
22 dnl along with GNU Emacs; see the file COPYING. If not, write to the
23 dnl Free Software Foundation, Inc., 59 Temple Place - Suite 330,
24 dnl Boston, MA 02111-1307, USA.
26 AC_PREREQ(2.54)dnl
27 AC_INIT(src/lisp.h)
28 AC_CONFIG_HEADER(src/config.h:src/config.in)
30 dnl Support for --program-prefix, --program-suffix and
31 dnl --program-transform-name options
32 AC_ARG_PROGRAM
34 lispdir='${datadir}/emacs/${version}/lisp'
35 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
36 '${datadir}/emacs/site-lisp:${datadir}/emacs/${version}/leim'
37 lisppath='${locallisppath}:${lispdir}'
38 etcdir='${datadir}/emacs/${version}/etc'
39 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
40 docdir='${datadir}/emacs/${version}/etc'
41 gamedir='${localstatedir}/games/emacs'
43 gameuser=games
45 AC_ARG_WITH(gcc,
46 [ --without-gcc don't use GCC to compile Emacs if GCC is found])
47 AC_ARG_WITH(pop,
48 [ --without-pop don't support POP mail retrieval with movemail],
49 [if test "$withval" = yes; then
50 AC_DEFINE(MAIL_USE_POP)
51 else :
52 fi],
53 AC_DEFINE(MAIL_USE_POP))
54 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
55 AC_ARG_WITH(kerberos,
56 [ --with-kerberos support Kerberos-authenticated POP],
57 [AC_DEFINE(KERBEROS)])
58 AH_TEMPLATE(KERBEROS,
59 [Define to support Kerberos-authenticated POP mail retrieval.])dnl
60 AC_ARG_WITH(kerberos5,
61 [ --with-kerberos5 support Kerberos version 5 authenticated POP],
62 [if test "${with_kerberos5+set}" = set; then
63 if test "${with_kerberos+set}" != set; then
64 with_kerberos=yes
65 AC_DEFINE(KERBEROS)
66 fi
67 fi
68 AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])])
69 AC_ARG_WITH(hesiod,
70 [ --with-hesiod support Hesiod to get the POP server host],
71 [AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])])
73 AC_ARG_WITH(sound,
74 [ --without-sound don't compile with sound support])
76 dnl This should be the last --with option, because --with-x is
77 dnl added later on when we find the path of X, and it's best to
78 dnl keep them together visually.
79 AC_ARG_WITH(x-toolkit,
80 [ --with-x-toolkit=KIT use an X toolkit
81 (KIT = yes/lucid/athena/motif/gtk/no)],
82 [ case "${withval}" in
83 y | ye | yes ) val=athena ;;
84 n | no ) val=no ;;
85 l | lu | luc | luci | lucid ) val=lucid ;;
86 a | at | ath | athe | athen | athena ) val=athena ;;
87 m | mo | mot | moti | motif ) val=motif ;;
88 g | gt | gtk ) val=gtk ;;
89 dnl These don't currently work.
90 dnl o | op | ope | open | open- | open-l | open-lo \
91 dnl | open-loo | open-look ) val=open-look ;;
92 * )
93 dnl AC_MSG_ERROR([the `--with-x-toolkit' option is supposed to have a value
94 dnl which is `yes', `no', `lucid', `athena', `motif' or `open-look'.])
95 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid\;
96 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
97 Currently, `yes', `athena' and `lucid' are synonyms.])
98 ;;
99 esac
100 with_x_toolkit=$val
101 ])
102 AC_ARG_WITH(xpm,
103 [ --with-xpm use -lXpm for displaying XPM images])
104 AC_ARG_WITH(jpeg,
105 [ --with-jpeg use -ljpeg for displaying JPEG images])
106 AC_ARG_WITH(tiff,
107 [ --with-tiff use -ltiff for displaying TIFF images])
108 AC_ARG_WITH(gif,
109 [ --with-gif use -lungif for displaying GIF images])
110 AC_ARG_WITH(png,
111 [ --with-png use -lpng for displaying PNG images])
112 AC_ARG_WITH(gtk,
113 [ --with-gtk use GTK (same as --with-x-toolkit=gtk)])
114 AC_ARG_WITH(pkg-config-prog,
115 [ --with-pkg-config-prog Path to pkg-config to use for finding GTK])
116 AC_ARG_WITH(toolkit-scroll-bars,
117 [ --without-toolkit-scroll-bars
118 don't use Motif or Xaw3d scroll bars])
119 AC_ARG_WITH(xim,
120 [ --without-xim don't use X11 XIM])
121 AC_ARG_WITH(carbon,
122 [ --without-carbon don't use Carbon GUI on Mac OS X])
123 AC_ARG_ENABLE(carbon-app,
124 [[ --enable-carbon-app[=DIR] [DIR=/Application]
125 specify install directory for Emacs.app on Mac OS X]],
126 [ carbon_appdir_x=${enableval}])
128 AC_ARG_ENABLE(maintainer-mode,
129 [ --enable-maintainer-mode enable make rules and dependencies not useful
130 (and sometimes confusing) to the casual installer],
131 USE_MAINTAINER_MODE=$enableval,
132 USE_MAINTAINER_MODE=no)
133 if test $USE_MAINTAINER_MODE = yes; then
134 MAINT=
135 else
136 MAINT=#
137 fi
138 AC_SUBST(MAINT)
140 #### Make srcdir absolute, if it isn't already. It's important to
141 #### avoid running the path through pwd unnecessarily, since pwd can
142 #### give you automounter prefixes, which can go away. We do all this
143 #### so Emacs can find its files when run uninstalled.
144 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
145 unset CDPATH
146 case "${srcdir}" in
147 /* ) ;;
148 . )
149 ## We may be able to use the $PWD environment variable to make this
150 ## absolute. But sometimes PWD is inaccurate.
151 ## Note: we used to use ${PWD} at the end instead of `pwd`,
152 ## but that tested only for a well-formed and valid PWD,
153 ## it did not object when PWD was well-formed and valid but just wrong.
154 if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`" ;
155 then
156 srcdir="$PWD"
157 else
158 srcdir="`(cd ${srcdir}; pwd)`"
159 fi
160 ;;
161 * ) srcdir="`(cd ${srcdir}; pwd)`" ;;
162 esac
164 #### Check if the source directory already has a configured system in it.
165 if test `pwd` != `(cd ${srcdir} && pwd)` \
166 && test -f "${srcdir}/src/config.h" ; then
167 AC_MSG_WARN([[The directory tree `${srcdir}' is being used
168 as a build directory right now; it has been configured in its own
169 right. To configure in another directory as well, you MUST
170 use GNU make. If you do not have GNU make, then you must
171 now do `make distclean' in ${srcdir},
172 and then run $0 again.]])
173 fi
175 #### Given the configuration name, set machfile and opsysfile to the
176 #### names of the m/*.h and s/*.h files we should use.
178 ### Canonicalize the configuration name.
180 AC_CANONICAL_HOST
181 canonical=$host
182 configuration=${host_alias-$host}
184 dnl This used to use changequote, but, apart from `changequote is evil'
185 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
186 dnl the great gob of text. Thus it's not processed for possible expansion.
187 dnl Just make sure the brackets remain balanced.
188 dnl
189 dnl Since Emacs can't find matching pairs of quotes, boundaries are
190 dnl indicated by comments.
191 dnl quotation begins
192 [
194 ### If you add support for a new configuration, add code to this
195 ### switch statement to recognize your configuration name and select
196 ### the appropriate operating system and machine description files.
198 ### You would hope that you could choose an m/*.h file pretty much
199 ### based on the machine portion of the configuration name, and an s-
200 ### file based on the operating system portion. However, it turns out
201 ### that each m/*.h file is pretty manufacturer-specific - for
202 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
203 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
204 ### machines. So we basically have to have a special case for each
205 ### configuration name.
206 ###
207 ### As far as handling version numbers on operating systems is
208 ### concerned, make sure things will fail in a fixable way. If
209 ### /etc/MACHINES doesn't say anything about version numbers, be
210 ### prepared to handle anything reasonably. If version numbers
211 ### matter, be sure /etc/MACHINES says something about it.
212 ###
213 ### Eric Raymond says we should accept strings like "sysvr4" to mean
214 ### "System V Release 4"; he writes, "The old convention encouraged
215 ### confusion between `system' and `release' levels'."
217 machine='' opsys='' unported=no
218 case "${canonical}" in
220 ## FreeBSD ports
221 *-*-freebsd* )
222 opsys=freebsd
223 case "${canonical}" in
224 alpha*-*-freebsd*) machine=alpha ;;
225 i[3456]86-*-freebsd*) machine=intel386 ;;
226 esac
227 ;;
229 ## NetBSD ports
230 *-*-netbsd* )
231 opsys=netbsd
232 if test -f /usr/lib/crti.o; then]
233 dnl The close and open brackets here are because this section is quoted --
234 dnl see the `changequote' comment above.
235 AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
236 [ fi
238 case "${canonical}" in
239 alpha*-*-netbsd*) machine=alpha ;;
240 i[3456]86-*-netbsd*) machine=intel386 ;;
241 m68k-*-netbsd*)
242 # This is somewhat bogus.
243 machine=hp9000s300 ;;
244 powerpc-apple-netbsd*) machine=macppc ;;
245 mips-*-netbsd*) machine=pmax ;;
246 mipsel-*-netbsd*) machine=pmax ;;
247 mipseb-*-netbsd*) machine=pmax ;;
248 ns32k-*-netbsd*) machine=ns32000 ;;
249 powerpc-*-netbsd*) machine=macppc ;;
250 sparc*-*-netbsd*) machine=sparc ;;
251 vax-*-netbsd*) machine=vax ;;
252 arm-*-netbsd*) machine=arm ;;
253 esac
254 ;;
256 ## OpenBSD ports
257 *-*-openbsd* )
258 opsys=openbsd
259 case "${canonical}" in
260 alpha*-*-openbsd*) machine=alpha ;;
261 i386-*-openbsd*) machine=intel386 ;;
262 m68k-*-openbsd*) machine=hp9000s300 ;;
263 mipsel-*-openbsd*) machine=pmax ;;
264 ns32k-*-openbsd*) machine=ns32000 ;;
265 sparc-*-openbsd*) machine=sparc ;;
266 vax-*-openbsd*) machine=vax ;;
267 esac
268 ;;
270 ## Acorn RISCiX:
271 arm-acorn-riscix1.1* )
272 machine=acorn opsys=riscix1-1
273 ;;
274 arm-acorn-riscix1.2* | arm-acorn-riscix )
275 ## This name is riscix12 instead of riscix1.2
276 ## to avoid a file name conflict on MSDOS.
277 machine=acorn opsys=riscix12
278 ;;
280 ## BSDI ports
281 *-*-bsdi* )
282 opsys=bsdi
283 case "${canonical}" in
284 i[345]86-*-bsdi*) machine=intel386 ;;
285 sparc-*-bsdi*) machine=sparc ;;
286 powerpc-*-bsdi*) machine=macppc ;;
287 esac
288 case "${canonical}" in
289 *-*-bsd386* | *-*-bsdi1* ) opsys=bsd386 ;;
290 *-*-bsdi2.0* ) opsys=bsdos2 ;;
291 *-*-bsdi2* ) opsys=bsdos2-1 ;;
292 *-*-bsdi3* ) opsys=bsdos3 ;;
293 *-*-bsdi[45]* ) opsys=bsdos4 ;;
294 esac
295 ;;
297 ## Alliant machines
298 ## Strictly speaking, we need the version of the alliant operating
299 ## system to choose the right machine file, but currently the
300 ## configuration name doesn't tell us enough to choose the right
301 ## one; we need to give alliants their own operating system name to
302 ## do this right. When someone cares, they can help us.
303 fx80-alliant-* )
304 machine=alliant4 opsys=bsd4-2
305 ;;
306 i860-alliant-* )
307 machine=alliant-2800 opsys=bsd4-3
308 ;;
310 ## Alpha (DEC) machines.
311 alpha*-dec-osf* )
312 machine=alpha opsys=osf1
313 # This is needed to find X11R6.1 libraries for certain tests.
314 NON_GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
315 GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
316 # NON_GNU_CPP is necessary on 5.0 to avoid mangling src/Makefile
317 # due to non-traditional preprocessing with the current compiler
318 # defaults. OSF 4 can also have that compiler version, and there
319 # seems always to have been a usable /usr/bin/cpp.
320 NON_GNU_CPP=/usr/bin/cpp
321 case "${canonical}" in
322 alpha*-dec-osf[5-9]*)
323 opsys=osf5-0 ;;
324 esac
325 ;;
327 alpha*-*-linux-gnu* )
328 machine=alpha opsys=gnu-linux
329 ;;
331 arm*-*-linux-gnu* )
332 machine=arm opsys=gnu-linux
333 ;;
335 ppc-*-linux | \
336 powerpc-*-linux* )
337 machine=macppc opsys=gnu-linux
338 ;;
340 ## Altos 3068
341 m68*-altos-sysv* )
342 machine=altos opsys=usg5-2
343 ;;
345 ## Amdahl UTS
346 580-amdahl-sysv* )
347 machine=amdahl opsys=usg5-2-2
348 ;;
350 ## Apollo, Domain/OS
351 m68*-apollo-* )
352 machine=apollo opsys=bsd4-3
353 ;;
355 ## AT&T 3b2, 3b5, 3b15, 3b20
356 we32k-att-sysv* )
357 machine=att3b opsys=usg5-2-2
358 ;;
360 ## AT&T 3b1 - The Mighty Unix PC!
361 m68*-att-sysv* )
362 machine=7300 opsys=usg5-2-2
363 ;;
365 ## Bull dpx20
366 rs6000-bull-bosx* )
367 machine=ibmrs6000 opsys=aix3-2
368 ;;
370 ## Bull dpx2
371 m68*-bull-sysv3* )
372 machine=dpx2 opsys=usg5-3
373 ;;
375 ## Bull sps7
376 m68*-bull-sysv2* )
377 machine=sps7 opsys=usg5-2
378 ;;
380 ## CCI 5/32, 6/32 -- see "Tahoe".
382 ## Celerity
383 ## I don't know what configuration name to use for this; config.sub
384 ## doesn't seem to know anything about it. Hey, Celerity users, get
385 ## in touch with us!
386 celerity-celerity-bsd* )
387 machine=celerity opsys=bsd4-2
388 ;;
390 ## Clipper
391 ## What operating systems does this chip run that Emacs has been
392 ## tested on?
393 clipper-* )
394 machine=clipper
395 ## We'll use the catch-all code at the bottom to guess the
396 ## operating system.
397 ;;
399 ## Compaq Nonstop
400 mips-compaq-nonstopux* )
401 machine=nonstopux opsys=nonstopux
402 ;;
404 ## Convex
405 *-convex-bsd* | *-convex-convexos* )
406 machine=convex opsys=bsd4-3
407 ## Prevents spurious white space in makefiles - d.m.cooke@larc.nasa.gov
408 NON_GNU_CPP="cc -E -P"
409 ;;
411 ## Cubix QBx/386
412 i[3456]86-cubix-sysv* )
413 machine=intel386 opsys=usg5-3
414 ;;
416 ## Cydra 5
417 cydra*-cydrome-sysv* )
418 machine=cydra5 opsys=usg5-3
419 ;;
421 ## Data General AViiON Machines
422 ## DG changed naming conventions with the release of 5.4.4.10, they
423 ## dropped the initial 5.4 but left the intervening R. Because of the
424 ## R this shouldn't conflict with older versions of the OS (which I
425 ## think were named like dgux4.*). In addition, DG new AViiONs series
426 ## uses either Motorola M88k or Intel Pentium CPUs.
427 m88k-dg-dguxR4.* | m88k-dg-dgux4* )
428 machine=aviion opsys=dgux4
429 ;;
430 m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
431 ## This name is dgux5-4-3 instead of dgux5-4r3
432 ## to avoid a file name conflict on MSDOS.
433 machine=aviion opsys=dgux5-4-3
434 ;;
435 m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
436 machine=aviion opsys=dgux5-4r2
437 ;;
438 m88k-dg-dgux* )
439 machine=aviion opsys=dgux
440 ;;
442 ## Data General AViiON Intel (x86) Machines
443 ## Exists from 5.4.3 (current i586-dg-dguxR4.11)
444 ## Ehud Karni, 1998-may-30, ehud@unix.simonwiesel.co.il
445 i[345]86-dg-dguxR4* )
446 machine=aviion-intel opsys=dgux4
447 ;;
449 ## DECstations
450 mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
451 machine=pmax opsys=bsd4-2
452 ;;
453 mips-dec-ultrix4.[12]* | mips-dec-bsd* )
454 machine=pmax opsys=bsd4-3
455 ;;
456 mips-dec-ultrix* )
457 machine=pmax opsys=ultrix4-3
458 ;;
459 mips-dec-osf* )
460 machine=pmax opsys=osf1
461 ;;
462 mips-dec-mach_bsd4.3* )
463 machine=pmax opsys=mach-bsd4-3
464 ;;
466 ## Motorola Delta machines
467 m68k-motorola-sysv* | m68000-motorola-sysv* )
468 machine=delta opsys=usg5-3
469 if test -z "`type gnucc | grep 'not found'`"
470 then
471 if test -s /etc/167config
472 then CC="gnucc -m68040"
473 else CC="gnucc -m68881"
474 fi
475 else
476 if test -z "`type gcc | grep 'not found'`"
477 then CC=gcc
478 else CC=cc
479 fi
480 fi
481 ;;
482 m88k-motorola-sysv4* )
483 # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
484 # needs POSIX_SIGNALS and therefore needs usg5-4-2.
485 # I hope there are not other 4.0 versions for this machine
486 # which really need usg5-4 instead.
487 machine=delta88k opsys=usg5-4-2
488 ;;
489 m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
490 machine=delta88k opsys=usg5-3
491 ;;
493 ## Dual machines
494 m68*-dual-sysv* )
495 machine=dual opsys=usg5-2
496 ;;
497 m68*-dual-uniplus* )
498 machine=dual opsys=unipl5-2
499 ;;
501 ## Elxsi 6400
502 elxsi-elxsi-sysv* )
503 machine=elxsi opsys=usg5-2
504 ;;
506 ## Encore machines
507 ns16k-encore-bsd* )
508 machine=ns16000 opsys=umax
509 ;;
511 ## The GEC 63 - apparently, this port isn't really finished yet.
512 # I'm sure we finished off the last of the machines, though. -- fx
514 ## Gould Power Node and NP1
515 pn-gould-bsd4.2* )
516 machine=gould opsys=bsd4-2
517 ;;
518 pn-gould-bsd4.3* )
519 machine=gould opsys=bsd4-3
520 ;;
521 np1-gould-bsd* )
522 machine=gould-np1 opsys=bsd4-3
523 ;;
525 ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
526 ## as far as Emacs is concerned).
527 m88k-harris-cxux* )
528 # Build needs to be different on 7.0 and later releases
529 case "`uname -r`" in
530 [56].[0-9] ) machine=nh4000 opsys=cxux ;;
531 [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
532 esac
533 NON_GNU_CPP="/lib/cpp"
534 ;;
535 ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
536 m68k-harris-cxux* )
537 machine=nh3000 opsys=cxux
538 ;;
539 ## Harris power pc NightHawk running Power UNIX (Series 6000)
540 powerpc-harris-powerunix )
541 machine=nh6000 opsys=powerunix
542 NON_GNU_CPP="cc -Xo -E -P"
543 ;;
544 ## SR2001/SR2201 running HI-UX/MPP
545 hppa1.1-hitachi-hiuxmpp* )
546 machine=sr2k opsys=hiuxmpp
547 ;;
548 hppa1.1-hitachi-hiuxwe2* )
549 machine=sr2k opsys=hiuxwe2
550 ;;
551 ## Honeywell XPS100
552 xps*-honeywell-sysv* )
553 machine=xps100 opsys=usg5-2
554 ;;
556 ## HP 9000 series 200 or 300
557 m68*-hp-bsd* )
558 machine=hp9000s300 opsys=bsd4-3
559 ;;
560 ## HP/UX 7, 8, 9, and 10 are supported on these machines.
561 m68*-hp-hpux* )
562 case "`uname -r`" in
563 ## Someone's system reports A.B8.05 for this.
564 ## I wonder what other possibilities there are.
565 *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
566 *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
567 *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
568 *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
569 *) machine=hp9000s300 opsys=hpux ;;
570 esac
571 ;;
573 ## HP 9000 series 700 and 800, running HP/UX
574 hppa*-hp-hpux7* )
575 machine=hp800 opsys=hpux
576 ;;
577 hppa*-hp-hpux8* )
578 machine=hp800 opsys=hpux8
579 ;;
580 hppa*-hp-hpux9shr* )
581 machine=hp800 opsys=hpux9shr
582 ;;
583 hppa*-hp-hpux9* )
584 machine=hp800 opsys=hpux9
585 ;;
586 hppa*-hp-hpux10.2* )
587 machine=hp800 opsys=hpux10-20
588 ;;
589 hppa*-hp-hpux10* )
590 machine=hp800 opsys=hpux10
591 ;;
592 hppa*-hp-hpux1[1-9]* )
593 machine=hp800 opsys=hpux11
594 ;;
596 hppa*-*-linux-gnu* )
597 machine=hp800 opsys=gnu-linux
598 ;;
600 ## HP 9000 series 700 and 800, running HP/UX
601 hppa*-hp-hpux* )
602 ## Cross-compilation? Nah!
603 case "`uname -r`" in
604 ## Someone's system reports A.B8.05 for this.
605 ## I wonder what other possibilities there are.
606 *.B8.* ) machine=hp800 opsys=hpux8 ;;
607 *.08.* ) machine=hp800 opsys=hpux8 ;;
608 *.09.* ) machine=hp800 opsys=hpux9 ;;
609 *) machine=hp800 opsys=hpux10 ;;
610 esac
611 ;;
612 hppa*-*-nextstep* )
613 machine=hp800 opsys=nextstep
614 ;;
616 ## Orion machines
617 orion-orion-bsd* )
618 machine=orion opsys=bsd4-2
619 ;;
620 clipper-orion-bsd* )
621 machine=orion105 opsys=bsd4-2
622 ;;
624 ## IBM machines
625 i[3456]86-ibm-aix1.1* )
626 machine=ibmps2-aix opsys=usg5-2-2
627 ;;
628 i[3456]86-ibm-aix1.[23]* | i[3456]86-ibm-aix* )
629 machine=ibmps2-aix opsys=usg5-3
630 ;;
631 i370-ibm-aix*)
632 machine=ibm370aix opsys=usg5-3
633 ;;
634 s390-*-linux-gnu* )
635 machine=ibms390 opsys=gnu-linux
636 ;;
637 rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1* )
638 machine=ibmrs6000 opsys=aix3-1
639 ;;
640 rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
641 machine=ibmrs6000 opsys=aix3-2-5
642 ;;
643 rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1* )
644 machine=ibmrs6000 opsys=aix4-1
645 ;;
646 rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2* )
647 machine=ibmrs6000 opsys=aix4-2
648 ;;
649 rs6000-ibm-aix5* | powerpc-ibm-aix5* )
650 machine=ibmrs6000 opsys=aix4-2
651 ;;
652 rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0* )
653 machine=ibmrs6000 opsys=aix4
654 ;;
655 rs6000-ibm-aix4* | powerpc-ibm-aix4* )
656 machine=ibmrs6000 opsys=aix4-1
657 ;;
658 rs6000-ibm-aix* | powerpc-ibm-aix* )
659 machine=ibmrs6000 opsys=aix3-2
660 ;;
661 romp-ibm-bsd4.3* )
662 machine=ibmrt opsys=bsd4-3
663 ;;
664 romp-ibm-bsd4.2* )
665 machine=ibmrt opsys=bsd4-2
666 ;;
667 romp-ibm-aos4.3* )
668 machine=ibmrt opsys=bsd4-3
669 ;;
670 romp-ibm-aos4.2* )
671 machine=ibmrt opsys=bsd4-2
672 ;;
673 romp-ibm-aos* )
674 machine=ibmrt opsys=bsd4-3
675 ;;
676 romp-ibm-bsd* )
677 machine=ibmrt opsys=bsd4-3
678 ;;
679 romp-ibm-aix* )
680 machine=ibmrt-aix opsys=usg5-2-2
681 ;;
683 ## Integrated Solutions `Optimum V'
684 m68*-isi-bsd4.2* )
685 machine=isi-ov opsys=bsd4-2
686 ;;
687 m68*-isi-bsd4.3* )
688 machine=isi-ov opsys=bsd4-3
689 ;;
691 ## Intel 386 machines where we do care about the manufacturer
692 i[3456]86-intsys-sysv* )
693 machine=is386 opsys=usg5-2-2
694 ;;
696 ## Prime EXL
697 i[3456]86-prime-sysv* )
698 machine=i386 opsys=usg5-3
699 ;;
701 ## Sequent Symmetry running Dynix
702 i[3456]86-sequent-bsd* )
703 machine=symmetry opsys=bsd4-3
704 ;;
706 ## Sequent Symmetry running ptx 4, which is a modified SVR4.
707 i[3456]86-sequent-ptx4* | i[3456]86-sequent-sysv4* )
708 machine=sequent-ptx opsys=ptx4
709 NON_GNU_CPP=/lib/cpp
710 ;;
712 ## Sequent Symmetry running DYNIX/ptx
713 ## Use the old cpp rather than the newer ANSI one.
714 i[3456]86-sequent-ptx* )
715 machine=sequent-ptx opsys=ptx
716 NON_GNU_CPP="/lib/cpp"
717 ;;
719 ## ncr machine running svr4.3.
720 i[3456]86-ncr-sysv4.3 )
721 machine=ncr386 opsys=usg5-4-3
722 ;;
724 ## Unspecified sysv on an ncr machine defaults to svr4.2.
725 ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
726 i[3456]86-ncr-sysv* )
727 machine=ncr386 opsys=usg5-4-2
728 ;;
730 ## Intel Paragon OSF/1
731 i860-intel-osf1* )
732 machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
733 ;;
735 ## Intel 860
736 i860-*-sysv4* )
737 machine=i860 opsys=usg5-4
738 NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
739 NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
740 ;;
742 ## Macintosh PowerPC
743 powerpc*-*-linux-gnu* )
744 machine=macppc opsys=gnu-linux
745 ;;
747 ## Masscomp machines
748 m68*-masscomp-rtu* )
749 machine=masscomp opsys=rtu
750 ;;
752 ## Megatest machines
753 m68*-megatest-bsd* )
754 machine=mega68 opsys=bsd4-2
755 ;;
757 ## Workstations sold by MIPS
758 ## This is not necessarily all workstations using the MIPS processor -
759 ## Irises are produced by SGI, and DECstations by DEC.
761 ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
762 ## and usg5-2-2 and bsd4-3 as possible OS files. The only guidance
763 ## it gives for choosing between the alternatives seems to be "Use
764 ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
765 ## the BSD world." I'll assume that these are instructions for
766 ## handling two odd situations, and that every other situation
767 ## should use mips.h and usg5-2-2, they being listed first.
768 mips-mips-usg* )
769 machine=mips4
770 ## Fall through to the general code at the bottom to decide on the OS.
771 ;;
772 mips-mips-riscos4* )
773 machine=mips4 opsys=bsd4-3
774 NON_GNU_CC="cc -systype bsd43"
775 NON_GNU_CPP="cc -systype bsd43 -E"
776 ;;
777 mips-mips-riscos5* )
778 machine=mips4 opsys=riscos5
779 NON_GNU_CC="cc -systype bsd43"
780 NON_GNU_CPP="cc -systype bsd43 -E"
781 ;;
782 mips-mips-bsd* )
783 machine=mips opsys=bsd4-3
784 ;;
785 mips-mips-* )
786 machine=mips opsys=usg5-2-2
787 ;;
789 ## NeXT
790 m68*-next-* | m68k-*-nextstep* )
791 machine=m68k opsys=nextstep
792 ;;
794 ## The complete machine from National Semiconductor
795 ns32k-ns-genix* )
796 machine=ns32000 opsys=usg5-2
797 ;;
799 ## NCR machines
800 m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
801 machine=tower32 opsys=usg5-2-2
802 ;;
803 m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
804 machine=tower32v3 opsys=usg5-3
805 ;;
807 ## NEC EWS4800
808 mips-nec-sysv4*)
809 machine=ews4800 opsys=ux4800
810 ;;
812 ## Nixdorf Targon 31
813 m68*-nixdorf-sysv* )
814 machine=targon31 opsys=usg5-2-2
815 ;;
817 ## Nu (TI or LMI)
818 m68*-nu-sysv* )
819 machine=nu opsys=usg5-2
820 ;;
822 ## Plexus
823 m68*-plexus-sysv* )
824 machine=plexus opsys=usg5-2
825 ;;
827 ## Pyramid machines
828 ## I don't really have any idea what sort of processor the Pyramid has,
829 ## so I'm assuming it is its own architecture.
830 pyramid-pyramid-bsd* )
831 machine=pyramid opsys=bsd4-2
832 ;;
834 ## Sequent Balance
835 ns32k-sequent-bsd4.2* )
836 machine=sequent opsys=bsd4-2
837 ;;
838 ns32k-sequent-bsd4.3* )
839 machine=sequent opsys=bsd4-3
840 ;;
842 ## Siemens Nixdorf
843 mips-siemens-sysv* | mips-sni-sysv*)
844 machine=mips-siemens opsys=usg5-4
845 NON_GNU_CC=/usr/ccs/bin/cc
846 NON_GNU_CPP=/usr/ccs/lib/cpp
847 ;;
849 ## Silicon Graphics machines
850 ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
851 m68*-sgi-iris3.5* )
852 machine=irist opsys=iris3-5
853 ;;
854 m68*-sgi-iris3.6* | m68*-sgi-iris*)
855 machine=irist opsys=iris3-6
856 ;;
857 ## Iris 4D
858 mips-sgi-irix3* )
859 machine=iris4d opsys=irix3-3
860 ;;
861 mips-sgi-irix4* )
862 machine=iris4d opsys=irix4-0
863 ;;
864 mips-sgi-irix6.5 )
865 machine=iris4d opsys=irix6-5
866 # Without defining _LANGUAGE_C, things get masked out in the headers
867 # so that, for instance, grepping for `free' in stdlib.h fails and
868 # AC_HEADER_STD_C fails. (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
869 NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
870 NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
871 ;;
872 mips-sgi-irix6* )
873 machine=iris4d opsys=irix6-0
874 # It's not clear whether -D_LANGUAGE_C is necessary as it is for 6.5,
875 # but presumably it does no harm.
876 NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
877 # -32 probably isn't necessary in later v.6s -- anyone know which?
878 NON_GCC_TEST_OPTIONS=-32
879 ;;
880 mips-sgi-irix5.[01]* )
881 machine=iris4d opsys=irix5-0
882 ;;
883 mips-sgi-irix5* | mips-sgi-irix* )
884 machine=iris4d opsys=irix5-2
885 ;;
887 ## SONY machines
888 m68*-sony-bsd4.2* )
889 machine=news opsys=bsd4-2
890 ;;
891 m68*-sony-bsd4.3* )
892 machine=news opsys=bsd4-3
893 ;;
894 m68*-sony-newsos3* | m68*-sony-news3*)
895 machine=news opsys=bsd4-3
896 ;;
897 mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
898 machine=news-risc opsys=bsd4-3
899 ;;
900 mips-sony-newsos6* )
901 machine=news-r6 opsys=newsos6
902 ;;
903 mips-sony-news* )
904 machine=news-risc opsys=newsos5
905 ;;
907 ## Stride
908 m68*-stride-sysv* )
909 machine=stride opsys=usg5-2
910 ;;
912 ## Suns
913 sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
914 machine=sparc opsys=gnu-linux
915 ;;
917 *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
918 | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
919 | rs6000-*-solaris2*)
920 case "${canonical}" in
921 m68*-sunos1* ) machine=sun1 ;;
922 m68*-sunos2* ) machine=sun2 ;;
923 m68* ) machine=sun3 ;;
924 i[3456]86-sun-sunos[34]* ) machine=sun386 ;;
925 i[3456]86-*-* ) machine=intel386 ;;
926 powerpcle* ) machine=powerpcle ;;
927 powerpc* | rs6000* ) machine=ibmrs6000 ;;
928 sparc* ) machine=sparc ;;
929 * ) unported=yes ;;
930 esac
931 case "${canonical}" in
932 ## The Sun386 didn't get past 4.0.
933 i[3456]86-*-sunos4 ) opsys=sunos4-0 ;;
934 *-sunos4.0* ) opsys=sunos4-0 ;;
935 *-sunos4.1.[3-9]*noshare )
936 ## This name is sunos413 instead of sunos4-1-3
937 ## to avoid a file name conflict on MSDOS.
938 opsys=sunos413
939 NON_GNU_CPP=/usr/lib/cpp
940 NON_GCC_TEST_OPTIONS=-Bstatic
941 GCC_TEST_OPTIONS=-static
942 ;;
943 *-sunos4.1.[3-9]* | *-sunos4shr*)
944 opsys=sunos4shr
945 NON_GNU_CPP=/usr/lib/cpp
946 ;;
947 *-sunos4* | *-sunos )
948 opsys=sunos4-1
949 NON_GCC_TEST_OPTIONS=-Bstatic
950 GCC_TEST_OPTIONS=-static
951 ;;
952 *-sunos5.3* | *-solaris2.3* )
953 opsys=sol2-3
954 NON_GNU_CPP=/usr/ccs/lib/cpp
955 ;;
956 *-sunos5.4* | *-solaris2.4* )
957 opsys=sol2-4
958 NON_GNU_CPP=/usr/ccs/lib/cpp
959 RANLIB="ar -ts"
960 ;;
961 *-sunos5.5* | *-solaris2.5* )
962 opsys=sol2-5
963 NON_GNU_CPP=/usr/ccs/lib/cpp
964 RANLIB="ar -ts"
965 ;;
966 *-sunos5.6* | *-solaris2.6* )
967 opsys=sol2-6
968 NON_GNU_CPP=/usr/ccs/lib/cpp
969 RANLIB="ar -ts"
970 ;;
971 *-sunos5* | *-solaris* )
972 opsys=sol2-6
973 NON_GNU_CPP=/usr/ccs/lib/cpp
974 ;;
975 * ) opsys=bsd4-2 ;;
976 esac
977 ## Watch out for a compiler that we know will not work.
978 case "${canonical}" in
979 *-solaris* | *-sunos5* )
980 if [ "x$CC" = x/usr/ucb/cc ]; then
981 ## /usr/ucb/cc doesn't work;
982 ## we should find some other compiler that does work.
983 unset CC
984 fi
985 ;;
986 *) ;;
987 esac
988 ;;
989 sparc-*-nextstep* )
990 machine=sparc opsys=nextstep
991 ;;
993 ## Tadpole 68k
994 m68*-tadpole-sysv* )
995 machine=tad68k opsys=usg5-3
996 ;;
998 ## Tahoe machines
999 tahoe-tahoe-bsd4.2* )
1000 machine=tahoe opsys=bsd4-2
1001 ;;
1002 tahoe-tahoe-bsd4.3* )
1003 machine=tahoe opsys=bsd4-3
1004 ;;
1006 ## Tandem Integrity S2
1007 mips-tandem-sysv* )
1008 machine=tandem-s2 opsys=usg5-3
1009 ;;
1011 ## Tektronix XD88
1012 m88k-tektronix-sysv3* )
1013 machine=tekxd88 opsys=usg5-3
1014 ;;
1016 ## Tektronix 16000 box (6130?)
1017 ns16k-tektronix-bsd* )
1018 machine=ns16000 opsys=bsd4-2
1019 ;;
1020 ## Tektronix 4300
1021 ## src/m/tek4300.h hints that this is a m68k machine.
1022 m68*-tektronix-bsd* )
1023 machine=tek4300 opsys=bsd4-3
1024 ;;
1026 ## Titan P2 or P3
1027 ## We seem to have lost the machine-description file titan.h!
1028 titan-titan-sysv* )
1029 machine=titan opsys=usg5-3
1030 ;;
1032 ## Ustation E30 (SS5E)
1033 m68*-unisys-uniplus* )
1034 machine=ustation opsystem=unipl5-2
1035 ;;
1037 ## Vaxen.
1038 vax-dec-* )
1039 machine=vax
1040 case "${canonical}" in
1041 *-bsd4.1* ) opsys=bsd4-1 ;;
1042 *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* ) opsys=bsd4-2 ;;
1043 *-bsd4.3* | *-ultrix* ) opsys=bsd4-3 ;;
1044 *-sysv[01]* | *-sysvr[01]* ) opsys=usg5-0 ;;
1045 *-sysv2* | *-sysvr2* ) opsys=usg5-2 ;;
1046 *-vms* ) opsys=vms ;;
1047 * ) unported=yes
1048 esac
1049 ;;
1051 ## Whitechapel MG1
1052 ns16k-whitechapel-* )
1053 machine=mg1
1054 ## We don't know what sort of OS runs on these; we'll let the
1055 ## operating system guessing code below try.
1056 ;;
1058 ## Wicat
1059 m68*-wicat-sysv* )
1060 machine=wicat opsys=usg5-2
1061 ;;
1063 ## IA-64
1064 ia64*-*-linux* )
1065 machine=ia64 opsys=gnu-linux
1066 ;;
1068 ## Intel 386 machines where we don't care about the manufacturer
1069 i[3456]86-*-* )
1070 machine=intel386
1071 case "${canonical}" in
1072 *-cygwin ) opsys=cygwin ;;
1073 *-lynxos* ) opsys=lynxos ;;
1074 *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
1075 *-isc2.2* ) opsys=isc2-2 ;;
1076 *-isc4.0* ) opsys=isc4-0 ;;
1077 *-isc4.* ) opsys=isc4-1
1078 GCC_TEST_OPTIONS=-posix
1079 NON_GCC_TEST_OPTIONS=-Xp
1080 ;;
1081 *-isc* ) opsys=isc3-0 ;;
1082 *-esix5* ) opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
1083 *-esix* ) opsys=esix ;;
1084 *-xenix* ) opsys=xenix ;;
1085 *-linux-gnu* ) opsys=gnu-linux ;;
1086 *-sco3.2v4* ) opsys=sco4 ; NON_GNU_CPP=/lib/cpp ;;
1087 *-sco3.2v5* ) opsys=sco5
1088 NON_GNU_CPP=/lib/cpp
1089 # Prevent -belf from being passed to $CPP.
1090 # /lib/cpp does not accept it.
1091 OVERRIDE_CPPFLAGS=" "
1092 ;;
1093 *-sysv4.2uw* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1094 *-sysv5uw* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1095 *-sysv5OpenUNIX* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1096 *-386bsd* ) opsys=386bsd ;;
1097 *-nextstep* ) opsys=nextstep ;;
1098 ## Otherwise, we'll fall through to the generic opsys code at the bottom.
1099 esac
1100 ;;
1102 ## m68k Linux-based GNU system
1103 m68k-*-linux-gnu* )
1104 machine=m68k opsys=gnu-linux
1105 ;;
1107 ## Mips Linux-based GNU system
1108 mips-*-linux-gnu* | mipsel-*-linux-gnu* )
1109 machine=mips opsys=gnu-linux
1110 ;;
1112 ## UXP/DS
1113 sparc-fujitsu-sysv4* )
1114 machine=sparc opsys=uxpds
1115 NON_GNU_CPP=/usr/ccs/lib/cpp
1116 RANLIB="ar -ts"
1117 ;;
1119 ## UXP/V
1120 f301-fujitsu-uxpv4.1)
1121 machine=f301 opsys=uxpv
1122 ;;
1124 ## Darwin / Mac OS X
1125 powerpc-apple-darwin* )
1126 machine=powermac opsys=darwin
1127 # Define CPP as follows to make autoconf work correctly.
1128 CPP="${CC-cc} -E -no-cpp-precomp"
1129 # Use fink packages if available.
1130 if test -d /sw/include && test -d /sw/lib; then
1131 GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
1132 CPP="${CPP} ${GCC_TEST_OPTIONS}"
1133 NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
1134 fi
1135 ;;
1137 ## AMD x86-64 Linux-based GNU system
1138 x86_64-*-linux-gnu* )
1139 machine=amdx86-64 opsys=gnu-linux
1140 ;;
1142 * )
1143 unported=yes
1144 ;;
1145 esac
1147 ### If the code above didn't choose an operating system, just choose
1148 ### an operating system based on the configuration name. You really
1149 ### only want to use this when you have no idea what the right
1150 ### operating system is; if you know what operating systems a machine
1151 ### runs, it's cleaner to make it explicit in the case statement
1152 ### above.
1153 if test x"${opsys}" = x; then
1154 case "${canonical}" in
1155 *-gnu* ) opsys=gnu ;;
1156 *-bsd4.[01] ) opsys=bsd4-1 ;;
1157 *-bsd4.2 ) opsys=bsd4-2 ;;
1158 *-bsd4.3 ) opsys=bsd4-3 ;;
1159 *-sysv0 | *-sysvr0 ) opsys=usg5-0 ;;
1160 *-sysv2 | *-sysvr2 ) opsys=usg5-2 ;;
1161 *-sysv2.2 | *-sysvr2.2 ) opsys=usg5-2-2 ;;
1162 *-sysv3* | *-sysvr3* ) opsys=usg5-3 ;;
1163 *-sysv4.2uw* ) opsys=unixware ;;
1164 *-sysv5uw* ) opsys=unixware ;;
1165 *-sysv5OpenUNIX* ) opsys=unixware ;;
1166 *-sysv4.1* | *-sysvr4.1* )
1167 NON_GNU_CPP=/usr/lib/cpp
1168 opsys=usg5-4 ;;
1169 *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
1170 if [ x$NON_GNU_CPP = x ]; then
1171 if [ -f /usr/ccs/lib/cpp ]; then
1172 NON_GNU_CPP=/usr/ccs/lib/cpp
1173 else
1174 NON_GNU_CPP=/lib/cpp
1175 fi
1176 fi
1177 opsys=usg5-4-2 ;;
1178 *-sysv4* | *-sysvr4* ) opsys=usg5-4 ;;
1179 * )
1180 unported=yes
1181 ;;
1182 esac
1183 fi
1185 ]
1186 dnl quotation ends
1188 if test $unported = yes; then
1189 AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
1190 Check `etc/MACHINES' for recognized configuration names.])
1191 fi
1193 machfile="m/${machine}.h"
1194 opsysfile="s/${opsys}.h"
1197 #### Choose a compiler.
1198 test -n "$CC" && cc_specified=yes
1200 # Save the value of CFLAGS that the user specified.
1201 SPECIFIED_CFLAGS="$CFLAGS"
1203 case ${with_gcc} in
1204 "yes" ) CC="gcc" GCC=yes ;;
1205 "no" ) : ${CC=cc} ;;
1206 * )
1207 esac
1208 AC_PROG_CC
1210 # On Suns, sometimes $CPP names a directory.
1211 if test -n "$CPP" && test -d "$CPP"; then
1212 CPP=
1213 fi
1215 #### Some systems specify a CPP to use unless we are using GCC.
1216 #### Now that we know whether we are using GCC, we can decide whether
1217 #### to use that one.
1218 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
1219 then
1220 CPP="$NON_GNU_CPP"
1221 fi
1223 #### Some systems specify a CC to use unless we are using GCC.
1224 #### Now that we know whether we are using GCC, we can decide whether
1225 #### to use that one.
1226 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
1227 test x$cc_specified != xyes
1228 then
1229 CC="$NON_GNU_CC"
1230 fi
1232 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
1233 then
1234 CC="$CC $GCC_TEST_OPTIONS"
1235 fi
1237 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
1238 then
1239 CC="$CC $NON_GCC_TEST_OPTIONS"
1240 fi
1242 #### Some other nice autoconf tests.
1244 dnl checks for programs
1245 AC_PROG_LN_S
1246 AC_PROG_CPP
1247 AC_PROG_INSTALL
1248 if test "x$RANLIB" = x; then
1249 AC_PROG_RANLIB
1250 fi
1251 AC_PATH_PROG(INSTALL_INFO, install-info)
1252 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
1253 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
1255 dnl Add our options to ac_link now, after it is set up.
1257 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
1258 then
1259 ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1260 fi
1262 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
1263 then
1264 ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1265 fi
1267 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1268 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1269 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
1270 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
1271 dnl if not built to support GNU ld.
1273 late_LDFLAGS=$LDFLAGS
1274 if test "$GCC" = yes; then
1275 LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
1276 else
1277 LDFLAGS="$LDFLAGS -znocombreloc"
1278 fi
1280 AC_MSG_CHECKING([For -znocombreloc])
1281 AC_LINK_IFELSE([main(){return 0;}],
1282 [AC_MSG_RESULT(yes)],
1283 LDFLAGS=$late_LDFLAGS
1284 [AC_MSG_RESULT(no)])
1286 dnl checks for Unix variants
1287 AC_AIX
1290 #### Extract some information from the operating system and machine files.
1292 AC_CHECKING([the machine- and system-dependent files to find out
1293 - which libraries the lib-src programs will want, and
1294 - whether the GNU malloc routines are usable])
1296 ### First figure out CFLAGS (which we use for running the compiler here)
1297 ### and REAL_CFLAGS (which we use for real compilation).
1298 ### The two are the same except on a few systems, where they are made
1299 ### different to work around various lossages. For example,
1300 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
1301 ### as implying static linking.
1303 ### If the CFLAGS env var is specified, we use that value
1304 ### instead of the default.
1306 ### It's not important that this name contain the PID; you can't run
1307 ### two configures in the same directory and have anything work
1308 ### anyway.
1309 tempcname="conftest.c"
1311 echo '
1312 #include "'${srcdir}'/src/'${opsysfile}'"
1313 #include "'${srcdir}'/src/'${machfile}'"
1314 #ifndef LIBS_MACHINE
1315 #define LIBS_MACHINE
1316 #endif
1317 #ifndef LIBS_SYSTEM
1318 #define LIBS_SYSTEM
1319 #endif
1320 #ifndef C_SWITCH_SYSTEM
1321 #define C_SWITCH_SYSTEM
1322 #endif
1323 #ifndef C_SWITCH_MACHINE
1324 #define C_SWITCH_MACHINE
1325 #endif
1326 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1327 configure___ c_switch_system=C_SWITCH_SYSTEM
1328 configure___ c_switch_machine=C_SWITCH_MACHINE
1330 #ifndef LIB_X11_LIB
1331 #define LIB_X11_LIB -lX11
1332 #endif
1334 #ifndef LIBX11_MACHINE
1335 #define LIBX11_MACHINE
1336 #endif
1338 #ifndef LIBX11_SYSTEM
1339 #define LIBX11_SYSTEM
1340 #endif
1341 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1343 #ifdef UNEXEC
1344 configure___ unexec=UNEXEC
1345 #else
1346 configure___ unexec=unexec.o
1347 #endif
1349 #ifdef SYSTEM_MALLOC
1350 configure___ system_malloc=yes
1351 #else
1352 configure___ system_malloc=no
1353 #endif
1355 #ifdef USE_MMAP_FOR_BUFFERS
1356 configure___ use_mmap_for_buffers=yes
1357 #else
1358 configure___ use_mmap_for_buffers=no
1359 #endif
1361 #ifndef C_DEBUG_SWITCH
1362 #define C_DEBUG_SWITCH -g
1363 #endif
1365 #ifndef C_OPTIMIZE_SWITCH
1366 #ifdef __GNUC__
1367 #define C_OPTIMIZE_SWITCH -O2
1368 #else
1369 #define C_OPTIMIZE_SWITCH -O
1370 #endif
1371 #endif
1373 #ifndef LD_SWITCH_MACHINE
1374 #define LD_SWITCH_MACHINE
1375 #endif
1377 #ifndef LD_SWITCH_SYSTEM
1378 #define LD_SWITCH_SYSTEM
1379 #endif
1381 #ifndef LD_SWITCH_X_SITE_AUX
1382 #define LD_SWITCH_X_SITE_AUX
1383 #endif
1385 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1386 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1388 #ifdef THIS_IS_CONFIGURE
1390 /* Get the CFLAGS for tests in configure. */
1391 #ifdef __GNUC__
1392 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1393 #else
1394 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1395 #endif
1397 #else /* not THIS_IS_CONFIGURE */
1399 /* Get the CFLAGS for real compilation. */
1400 #ifdef __GNUC__
1401 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1402 #else
1403 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1404 #endif
1406 #endif /* not THIS_IS_CONFIGURE */
1407 ' > ${tempcname}
1409 # The value of CPP is a quoted variable reference, so we need to do this
1410 # to get its actual value...
1411 CPP=`eval "echo $CPP"`
1412 [eval `${CPP} -Isrc ${tempcname} \
1413 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1414 if test "x$SPECIFIED_CFLAGS" = x; then
1415 eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1416 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1417 else
1418 REAL_CFLAGS="$CFLAGS"
1419 fi]
1420 rm ${tempcname}
1422 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1424 ### Make sure subsequent tests use flags consistent with the build flags.
1426 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1427 CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1428 else
1429 CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1430 fi
1432 dnl For AC_FUNC_GETLOADAVG, at least:
1433 AC_CONFIG_LIBOBJ_DIR(src)
1435 AC_GNU_SOURCE
1437 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1438 AC_SYS_LARGEFILE
1440 if test "${with_sound}" != "no"; then
1441 # Sound support for GNU/Linux and the free BSDs.
1442 AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1443 # Emulation library used on NetBSD.
1444 AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1445 AC_SUBST(LIBSOUND)
1446 fi
1448 dnl checks for header files
1449 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1450 linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1451 termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1452 sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h)
1454 AC_MSG_CHECKING(if personality LINUX32 can be set)
1455 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1456 emacs_cv_personality_linux32=yes,
1457 emacs_cv_personality_linux32=no)
1458 AC_MSG_RESULT($emacs_cv_personality_linux32)
1460 if test $emacs_cv_personality_linux32 = yes; then
1461 AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1462 [Define to 1 if personality LINUX32 can be set.])
1463 fi
1465 dnl On Solaris 8 there's a compilation warning for term.h because
1466 dnl it doesn't define `bool'.
1467 AC_CHECK_HEADERS(term.h, , , -)
1468 AC_HEADER_STDC
1469 AC_HEADER_TIME
1470 AC_CHECK_DECLS([sys_siglist])
1471 if test $ac_cv_have_decl_sys_siglist != yes; then
1472 # For Tru64, at least:
1473 AC_CHECK_DECLS([__sys_siglist])
1474 if test $ac_cv_have_decl___sys_siglist = yes; then
1475 AC_DEFINE(sys_siglist, __sys_siglist,
1476 [Define to any substitute for sys_siglist.])
1477 fi
1478 fi
1479 AC_HEADER_SYS_WAIT
1481 dnl Some systems have utime.h but don't declare the struct anyplace.
1482 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1483 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1484 #include <sys/time.h>
1485 #include <time.h>
1486 #else
1487 #ifdef HAVE_SYS_TIME_H
1488 #include <sys/time.h>
1489 #else
1490 #include <time.h>
1491 #endif
1492 #endif
1493 #ifdef HAVE_UTIME_H
1494 #include <utime.h>
1495 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1496 emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1497 if test $emacs_cv_struct_utimbuf = yes; then
1498 AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1499 fi
1501 dnl checks for typedefs
1502 AC_TYPE_SIGNAL
1504 dnl Check for speed_t typedef.
1505 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1506 [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1507 emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1508 if test $emacs_cv_speed_t = yes; then
1509 AC_DEFINE(HAVE_SPEED_T, 1,
1510 [Define to 1 if `speed_t' is declared by <termios.h>.])
1511 fi
1513 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1514 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1515 #include <sys/time.h>
1516 #include <time.h>
1517 #else
1518 #ifdef HAVE_SYS_TIME_H
1519 #include <sys/time.h>
1520 #else
1521 #include <time.h>
1522 #endif
1523 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1524 emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1525 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1526 if test $emacs_cv_struct_timeval = yes; then
1527 AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1528 fi
1530 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1531 AC_TRY_COMPILE([#include <math.h>],
1532 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1533 emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1534 HAVE_EXCEPTION=$emacs_cv_struct_exception
1535 if test $emacs_cv_struct_exception != yes; then
1536 AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1537 fi
1539 AC_CHECK_HEADERS(sys/socket.h)
1540 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1541 #if HAVE_SYS_SOCKET_H
1542 #include <sys/socket.h>
1543 #endif])
1545 dnl checks for structure members
1546 AC_STRUCT_TM
1547 AC_STRUCT_TIMEZONE
1548 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1549 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1550 [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1551 [#include <time.h>])
1552 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1553 struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1554 struct ifreq.ifr_addr], , ,
1555 [AC_INCLUDES_DEFAULT
1556 #if HAVE_SYS_SOCKET_H
1557 #include <sys/socket.h>
1558 #endif
1559 #if HAVE_NET_IF_H
1560 #include <net/if.h>
1561 #endif])
1563 dnl checks for compiler characteristics
1565 dnl Testing __STDC__ to determine prototype support isn't good enough.
1566 dnl DEC C, for instance, doesn't define it with default options, and
1567 dnl is used on 64-bit systems (OSF Alphas). Similarly for volatile
1568 dnl and void *.
1569 AC_C_PROTOTYPES
1570 AC_C_VOLATILE
1571 AC_C_CONST
1572 dnl This isn't useful because we can't turn on use of `inline' unless
1573 dnl the compiler groks `extern inline'.
1574 dnl AC_C_INLINE
1575 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1576 [AC_TRY_COMPILE(, [void * foo;],
1577 emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1578 if test $emacs_cv_void_star = yes; then
1579 AC_DEFINE(POINTER_TYPE, void)
1580 else
1581 AC_DEFINE(POINTER_TYPE, char)
1582 fi
1583 AH_TEMPLATE(POINTER_TYPE,
1584 [Define as `void' if your compiler accepts `void *'; otherwise
1585 define as `char'.])dnl
1589 dnl This could be used for targets which can have both byte sexes.
1590 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1591 dnl AC_C_BIGENDIAN
1593 dnl check for Make feature
1594 AC_PROG_MAKE_SET
1596 dnl checks for operating system services
1597 AC_SYS_LONG_FILE_NAMES
1599 #### Choose a window system.
1601 AC_PATH_X
1602 if test "$no_x" = yes; then
1603 window_system=none
1604 else
1605 window_system=x11
1606 fi
1608 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1609 LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1610 LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1611 x_default_search_path=""
1612 for x_library in `echo ${x_libraries} | sed -e "s/:/ /g"`; do
1613 x_search_path="\
1614 ${x_library}/X11/%L/%T/%N%C%S:\
1615 ${x_library}/X11/%l/%T/%N%C%S:\
1616 ${x_library}/X11/%T/%N%C%S:\
1617 ${x_library}/X11/%L/%T/%N%S:\
1618 ${x_library}/X11/%l/%T/%N%S:\
1619 ${x_library}/X11/%T/%N%S"
1620 if test x"${x_default_search_path}" = x; then
1621 x_default_search_path=${x_search_path}
1622 else
1623 x_default_search_path="${x_search_path}:${x_default_search_path}"
1624 fi
1625 done
1626 fi
1627 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1628 C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1629 fi
1631 if test x"${x_includes}" = x; then
1632 bitmapdir=/usr/include/X11/bitmaps
1633 else
1634 # accumulate include directories that have X11 bitmap subdirectories
1635 bmd_acc="dummyval"
1636 for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1637 if test -d "${bmd}/X11/bitmaps"; then
1638 bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1639 fi
1640 if test -d "${bmd}/bitmaps"; then
1641 bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1642 fi
1643 done
1644 if test ${bmd_acc} != "dummyval"; then
1645 bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1646 fi
1647 fi
1649 case "${window_system}" in
1650 x11 )
1651 HAVE_X_WINDOWS=yes
1652 HAVE_X11=yes
1653 case "${with_x_toolkit}" in
1654 athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1655 motif ) USE_X_TOOLKIT=MOTIF ;;
1656 dnl open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
1657 gtk ) with_gtk=yes
1658 dnl Dont set this for GTK. A lot of tests below assumes Xt when
1659 dnl USE_X_TOOLKIT is set.
1660 USE_X_TOOLKIT=none ;;
1661 no ) USE_X_TOOLKIT=none ;;
1662 dnl If user did not say whether to use a toolkit,
1663 dnl make this decision later: use the toolkit if we have X11R5 or newer.
1664 * ) USE_X_TOOLKIT=maybe ;;
1665 esac
1666 ;;
1667 none )
1668 HAVE_X_WINDOWS=no
1669 HAVE_X11=no
1670 USE_X_TOOLKIT=none
1671 ;;
1672 esac
1674 ### If we're using X11, we should use the X menu package.
1675 HAVE_MENUS=no
1676 case ${HAVE_X11} in
1677 yes ) HAVE_MENUS=yes ;;
1678 esac
1680 if test "${opsys}" = "hpux9"; then
1681 case "${x_libraries}" in
1682 *X11R4* )
1683 opsysfile="s/hpux9-x11r4.h"
1684 ;;
1685 esac
1686 fi
1688 if test "${opsys}" = "hpux9shr"; then
1689 case "${x_libraries}" in
1690 *X11R4* )
1691 opsysfile="s/hpux9shxr4.h"
1692 ;;
1693 esac
1694 fi
1696 ### Compute the unexec source name from the object name.
1697 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1699 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1700 # Assume not, until told otherwise.
1701 GNU_MALLOC=yes
1702 doug_lea_malloc=yes
1703 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1704 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1705 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1706 emacs_cv_var___after_morecore_hook,
1707 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1708 emacs_cv_var___after_morecore_hook=yes,
1709 emacs_cv_var___after_morecore_hook=no)])
1710 if test $emacs_cv_var___after_morecore_hook = no; then
1711 doug_lea_malloc=no
1712 fi
1713 if test "${system_malloc}" = "yes"; then
1714 GNU_MALLOC=no
1715 GNU_MALLOC_reason="
1716 (The GNU allocators don't work with this system configuration.)"
1717 fi
1718 if test "$doug_lea_malloc" = "yes" ; then
1719 if test "$GNU_MALLOC" = yes ; then
1720 GNU_MALLOC_reason="
1721 (Using Doug Lea's new malloc from the GNU C Library.)"
1722 fi
1723 AC_DEFINE(DOUG_LEA_MALLOC, 1,
1724 [Define to 1 if you are using the GNU C Library.])
1725 fi
1727 if test x"${REL_ALLOC}" = x; then
1728 REL_ALLOC=${GNU_MALLOC}
1729 fi
1731 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1732 dnl the system configuration file (s/*.h) to turn the use of mmap
1733 dnl in the relocating allocator on.
1735 AC_FUNC_MMAP
1736 if test $use_mmap_for_buffers = yes; then
1737 REL_ALLOC=no
1738 fi
1740 LIBS="$libsrc_libs $LIBS"
1742 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1743 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1744 AC_CHECK_LIB(dnet, dnet_ntoa)
1745 dnl This causes -lresolv to get used in subsequent tests,
1746 dnl which causes failures on some systems such as HPUX 9.
1747 dnl AC_CHECK_LIB(resolv, gethostbyname)
1749 dnl FIXME replace main with a function we actually want from this library.
1750 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1752 AC_CHECK_LIB(pthreads, cma_open)
1754 AC_MSG_CHECKING(for XFree86 in /usr/X386)
1755 if test -d /usr/X386/include; then
1756 HAVE_XFREE386=yes
1757 : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1758 else
1759 HAVE_XFREE386=no
1760 fi
1761 AC_MSG_RESULT($HAVE_XFREE386)
1763 dnl Check for need for bigtoc support on IBM AIX
1765 case ${host_os} in
1766 aix*)
1767 AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1768 case $GCC in
1769 yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1770 *) gdb_cv_bigtoc=-bbigtoc ;;
1771 esac
1773 LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1774 AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1775 ])
1776 ;;
1777 esac
1779 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1780 # used for the tests that follow. We set them back to REAL_CFLAGS and
1781 # REAL_CPPFLAGS later on.
1783 REAL_CPPFLAGS="$CPPFLAGS"
1785 if test "${HAVE_X11}" = "yes"; then
1786 DEFS="$C_SWITCH_X_SITE $DEFS"
1787 LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1788 LIBS="$LIBX $LIBS"
1789 CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1790 CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1792 # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1793 # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1794 # but it's more convenient here to set LD_RUN_PATH
1795 # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1796 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1797 LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1798 export LD_RUN_PATH
1799 fi
1801 if test "${opsys}" = "gnu-linux"; then
1802 AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1803 AC_TRY_LINK([],
1804 [XOpenDisplay ("foo");],
1805 [xlinux_first_failure=no],
1806 [xlinux_first_failure=yes])
1807 if test "${xlinux_first_failure}" = "yes"; then
1808 OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1809 OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1810 OLD_CPPFLAGS="$CPPFLAGS"
1811 OLD_LIBS="$LIBS"
1812 LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1813 C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1814 CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1815 LIBS="$LIBS -b i486-linuxaout"
1816 AC_TRY_LINK([],
1817 [XOpenDisplay ("foo");],
1818 [xlinux_second_failure=no],
1819 [xlinux_second_failure=yes])
1820 if test "${xlinux_second_failure}" = "yes"; then
1821 # If we get the same failure with -b, there is no use adding -b.
1822 # So take it out. This plays safe.
1823 LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1824 C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1825 CPPFLAGS="$OLD_CPPFLAGS"
1826 LIBS="$OLD_LIBS"
1827 AC_MSG_RESULT(no)
1828 else
1829 AC_MSG_RESULT(yes)
1830 fi
1831 else
1832 AC_MSG_RESULT(no)
1833 fi
1834 fi
1836 # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1837 # header files included from there.
1838 AC_MSG_CHECKING(for Xkb)
1839 AC_TRY_LINK([#include <X11/Xlib.h>
1840 #include <X11/XKBlib.h>],
1841 [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1842 emacs_xkb=yes, emacs_xkb=no)
1843 AC_MSG_RESULT($emacs_xkb)
1844 if test $emacs_xkb = yes; then
1845 AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1846 fi
1848 AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1849 XScreenNumberOfScreen XSetWMProtocols)
1850 fi
1852 if test "${window_system}" = "x11"; then
1853 AC_MSG_CHECKING(X11 version 6)
1854 AC_CACHE_VAL(emacs_cv_x11_version_6,
1855 [AC_TRY_LINK([#include <X11/Xlib.h>],
1856 [#if XlibSpecificationRelease < 6
1857 fail;
1858 #endif
1859 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1860 if test $emacs_cv_x11_version_6 = yes; then
1861 AC_MSG_RESULT(6 or newer)
1862 AC_DEFINE(HAVE_X11R6, 1,
1863 [Define to 1 if you have the X11R6 or newer version of Xlib.])
1864 else
1865 AC_MSG_RESULT(before 6)
1866 fi
1867 fi
1869 if test "${window_system}" = "x11"; then
1870 AC_MSG_CHECKING(X11 version 5)
1871 AC_CACHE_VAL(emacs_cv_x11_version_5,
1872 [AC_TRY_LINK([#include <X11/Xlib.h>],
1873 [#if XlibSpecificationRelease < 5
1874 fail;
1875 #endif
1876 ], emacs_cv_x11_version_5=yes, emacs_cv_x11_version_5=no)])
1877 if test $emacs_cv_x11_version_5 = yes; then
1878 AC_MSG_RESULT(5 or newer)
1879 HAVE_X11R5=yes
1880 AC_DEFINE(HAVE_X11R5, 1,
1881 [Define to 1 if you have the X11R5 or newer version of Xlib.])
1882 else
1883 HAVE_X11R5=no
1884 AC_MSG_RESULT(before 5)
1885 fi
1886 fi
1888 dnl This function defintion taken from Gnome 2.0
1889 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1890 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1891 dnl also defines GSTUFF_PKG_ERRORS on error
1892 AC_DEFUN([PKG_CHECK_MODULES], [
1893 succeeded=no
1895 if test -z "$PKG_CONFIG"; then
1896 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1897 fi
1899 if test "$PKG_CONFIG" = "no" ; then
1900 echo "*** The pkg-config script could not be found. Make sure it is"
1901 echo "*** in your path, or give the full path to pkg-config with"
1902 echo "*** the PKG_CONFIG environment variable or --with-pkg-config-prog."
1903 echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
1904 else
1905 PKG_CONFIG_MIN_VERSION=0.9.0
1906 if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1907 AC_MSG_CHECKING(for $2)
1909 if $PKG_CONFIG --exists "$2" ; then
1910 AC_MSG_RESULT(yes)
1911 succeeded=yes
1913 AC_MSG_CHECKING($1_CFLAGS)
1914 $1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
1915 AC_MSG_RESULT($$1_CFLAGS)
1917 AC_MSG_CHECKING($1_LIBS)
1918 $1_LIBS=`$PKG_CONFIG --libs "$2"`
1919 AC_MSG_RESULT($$1_LIBS)
1920 else
1921 $1_CFLAGS=""
1922 $1_LIBS=""
1923 ## If we have a custom action on failure, don't print errors, but
1924 ## do set a variable so people can do so.
1925 $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1926 ifelse([$4], ,echo $$1_PKG_ERRORS,)
1927 fi
1929 AC_SUBST($1_CFLAGS)
1930 AC_SUBST($1_LIBS)
1931 else
1932 echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1933 echo "*** See http://www.freedesktop.org/software/pkgconfig"
1934 fi
1935 fi
1937 if test $succeeded = yes; then
1938 ifelse([$3], , :, [$3])
1939 else
1940 ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1941 fi
1942 ])
1944 HAVE_GTK=no
1945 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "gtk"; then
1946 if test "$USE_X_TOOLKIT" != "none" && test "$USE_X_TOOLKIT" != "maybe"; then
1947 AC_MSG_ERROR([Conflicting options, --with-gtk is incompatible with --with-x-toolkit=${with_x_toolkit}]);
1948 fi
1949 GLIB_REQUIRED=2.0.1
1950 GTK_REQUIRED=2.0.1
1951 GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1953 dnl Check if --with-pkg-config-prog has been given.
1954 if test "X${with_pkg_config_prog}" != X; then
1955 PKG_CONFIG="${with_pkg_config_prog}"
1956 fi
1957 dnl Checks for libraries.
1958 PKG_CHECK_MODULES(GTK, $GTK_MODULES)
1959 AC_SUBST(GTK_CFLAGS)
1960 AC_SUBST(GTK_LIBS)
1961 C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1962 CFLAGS="$CFLAGS $GTK_CFLAGS"
1963 LIBS="$GTK_LIBS $LIBS"
1964 HAVE_GTK=yes
1965 AC_DEFINE(HAVE_GTK, 1, [Define to 1 if using GTK.])
1966 USE_X_TOOLKIT=none
1968 dnl GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1969 dnl a lot if #ifdef:s, say we have toolkit scrollbars.
1970 if test "$with_toolkit_scroll_bars" != no; then
1971 with_toolkit_scroll_bars=yes
1972 fi
1974 dnl Check if we can use multiple displays with this GTK version.
1975 dnl If gdk_display_open exists, assume all others are there also.
1976 HAVE_GTK_MULTIDISPLAY=no
1977 AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1978 if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1979 AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1980 [Define to 1 if GTK can handle more than one display.])
1981 fi
1982 dnl Check if we have the old file selection dialog.
1983 dnl If gdk_display_open exists, assume all others are there also.
1984 HAVE_GTK_FILE_SELECTION=no
1985 AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes)
1987 dnl Check if we have the new file chooser dialog
1988 dnl If gdk_display_open exists, assume all others are there also.
1989 HAVE_GTK_FILE_CHOOSER=no
1990 AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes)
1992 if test "$HAVE_GTK_FILE_SELECTION" = yes \
1993 && test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1994 AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1995 [Define to 1 if GTK has both file selection and chooser dialog.])
1996 fi
1997 fi
1999 dnl Do not put whitespace before the #include statements below.
2000 dnl Older compilers (eg sunos4 cc) choke on it.
2001 if test x"${USE_X_TOOLKIT}" = xmaybe; then
2002 if test x"${HAVE_X11R5}" = xyes; then
2003 AC_MSG_CHECKING(X11 version 5 with Xaw)
2004 AC_CACHE_VAL(emacs_cv_x11_version_5_with_xaw,
2005 [AC_TRY_LINK([
2006 #include <X11/Intrinsic.h>
2007 #include <X11/Xaw/Simple.h>],
2008 [],
2009 emacs_cv_x11_version_5_with_xaw=yes,
2010 emacs_cv_x11_version_5_with_xaw=no)])
2011 if test $emacs_cv_x11_version_5_with_xaw = yes; then
2012 AC_MSG_RESULT([5 or newer, with Xaw; use toolkit by default])
2013 USE_X_TOOLKIT=LUCID
2014 else
2015 AC_MSG_RESULT(before 5 or no Xaw; do not use toolkit by default)
2016 USE_X_TOOLKIT=none
2017 fi
2018 else
2019 USE_X_TOOLKIT=none
2020 fi
2021 fi
2023 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2025 if test "${USE_X_TOOLKIT}" != "none"; then
2026 AC_MSG_CHECKING(X11 toolkit version)
2027 AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2028 [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2029 [#if XtSpecificationRelease < 6
2030 fail;
2031 #endif
2032 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2033 HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2034 if test $emacs_cv_x11_toolkit_version_6 = yes; then
2035 AC_MSG_RESULT(6 or newer)
2036 AC_DEFINE(HAVE_X11XTR6, 1,
2037 [Define to 1 if you have the X11R6 or newer version of Xt.])
2038 else
2039 AC_MSG_RESULT(before 6)
2040 fi
2042 dnl If using toolkit, check whether libXmu.a exists.
2043 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2044 OLDLIBS="$LIBS"
2045 if test x$HAVE_X11XTR6 = xyes; then
2046 LIBS="-lXt -lSM -lICE $LIBS"
2047 else
2048 LIBS="-lXt $LIBS"
2049 fi
2050 AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2051 test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2052 fi
2054 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2055 if test "${HAVE_X11}" = "yes"; then
2056 if test "${USE_X_TOOLKIT}" != "none"; then
2057 AC_CHECK_LIB(Xext, XShapeQueryExtension)
2058 fi
2059 fi
2061 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2062 AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2063 # We put this in CFLAGS temporarily to precede other -I options
2064 # that might be in CFLAGS temporarily.
2065 # We put this in CPPFLAGS where it precedes the other -I options.
2066 OLD_CPPFLAGS=$CPPFLAGS
2067 OLD_CFLAGS=$CFLAGS
2068 CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2069 CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2070 [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2071 [int x = 5;],
2072 emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2073 if test $emacs_cv_lesstif = yes; then
2074 # Make sure this -I option remains in CPPFLAGS after it is set
2075 # back to REAL_CPPFLAGS.
2076 # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2077 # have those other -I options anyway. Ultimately, having this
2078 # directory ultimately in CPPFLAGS will be enough.
2079 REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2080 LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2081 else
2082 CFLAGS=$OLD_CFLAGS
2083 CPPFLAGS=$OLD_CPPFLAGS
2084 fi
2085 AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2086 [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2087 [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2088 int x = 5;
2089 #else
2090 Motif version prior to 2.1.
2091 #endif],
2092 emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2093 HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
2094 if test $emacs_cv_motif_version_2_1 = yes; then
2095 HAVE_LIBXP=no
2096 AC_DEFINE(HAVE_MOTIF_2_1, 1,
2097 [Define to 1 if you have Motif 2.1 or newer.])
2098 AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
2099 if test ${HAVE_LIBXP} = yes; then
2100 AC_DEFINE(HAVE_LIBXP, 1,
2101 [Define to 1 if you have the Xp library (-lXp).])
2102 fi
2103 fi
2104 fi
2106 ### Is -lXaw3d available?
2107 HAVE_XAW3D=no
2108 if test "${HAVE_X11}" = "yes"; then
2109 if test "${USE_X_TOOLKIT}" != "none"; then
2110 dnl Fixme: determine what Scrollbar.h needs to avoid compilation
2111 dnl errors from the test without the `-'.
2112 AC_CHECK_HEADER(X11/Xaw3d/Scrollbar.h,
2113 [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb, HAVE_XAW3D=yes)], , -)
2114 if test "${HAVE_XAW3D}" = "yes"; then
2115 AC_DEFINE(HAVE_XAW3D, 1,
2116 [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2117 fi
2118 fi
2119 fi
2121 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2122 dnl using Motif or Xaw3d is available, and unless
2123 dnl --with-toolkit-scroll-bars=no was specified.
2125 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2126 [Define to 1 if we should use toolkit scroll bars.])dnl
2127 USE_TOOLKIT_SCROLL_BARS=no
2128 if test "${with_toolkit_scroll_bars}" != "no"; then
2129 if test "${USE_X_TOOLKIT}" != "none"; then
2130 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2131 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2132 HAVE_XAW3D=no
2133 USE_TOOLKIT_SCROLL_BARS=yes
2134 elif test "${HAVE_XAW3D}" = "yes"; then
2135 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2136 USE_TOOLKIT_SCROLL_BARS=yes
2137 fi
2138 elif test "${HAVE_GTK}" = "yes"; then
2139 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2140 USE_TOOLKIT_SCROLL_BARS=yes
2141 fi
2142 fi
2144 dnl See if XIM is available.
2145 AC_TRY_COMPILE([
2146 #include <X11/Xlib.h>
2147 #include <X11/Xresource.h>],
2148 [XIMProc callback;],
2149 HAVE_XIM=yes
2150 AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available]),
2151 HAVE_XIM=no)
2153 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2155 if test "${with_xim}" != "no"; then
2156 AC_DEFINE(USE_XIM, 1,
2157 [Define to 1 if we should use XIM, if it is available.])
2158 fi
2161 if test "${HAVE_XIM}" != "no"; then
2162 late_CFLAGS=$CFLAGS
2163 if test "$GCC" = yes; then
2164 CFLAGS="$CFLAGS --pedantic-errors"
2165 fi
2166 AC_TRY_COMPILE([
2167 #include <X11/Xlib.h>
2168 #include <X11/Xresource.h>],
2169 [Display *display;
2170 XrmDatabase db;
2171 char *res_name;
2172 char *res_class;
2173 XIMProc callback;
2174 XPointer *client_data;
2175 #ifndef __GNUC__
2176 /* If we're not using GCC, it's probably not XFree86, and this is
2177 probably right, but we can't use something like --pedantic-errors. */
2178 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2179 char*, XIMProc, XPointer*);
2180 #endif
2181 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2182 client_data);],
2183 [emacs_cv_arg6_star=yes])
2184 AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2185 [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2186 either XPointer or XPointer*.])dnl
2187 if test "$emacs_cv_arg6_star" = yes; then
2188 AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2189 else
2190 AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2191 fi
2192 CFLAGS=$late_CFLAGS
2193 fi
2195 ### Use -lXpm if available, unless `--with-xpm=no'.
2196 HAVE_XPM=no
2197 if test "${HAVE_X11}" = "yes"; then
2198 if test "${with_xpm}" != "no"; then
2199 AC_CHECK_HEADER(X11/xpm.h,
2200 AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11))
2201 if test "${HAVE_XPM}" = "yes"; then
2202 AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2203 AC_EGREP_CPP(no_return_alloc_pixels,
2204 [#include "X11/xpm.h"
2205 #ifndef XpmReturnAllocPixels
2206 no_return_alloc_pixels
2207 #endif
2208 ], HAVE_XPM=no, HAVE_XPM=yes)
2210 if test "${HAVE_XPM}" = "yes"; then
2211 AC_MSG_RESULT(yes)
2212 else
2213 AC_MSG_RESULT(no)
2214 fi
2215 fi
2216 fi
2218 if test "${HAVE_XPM}" = "yes"; then
2219 AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2220 fi
2221 fi
2223 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2224 HAVE_JPEG=no
2225 if test "${HAVE_X11}" = "yes"; then
2226 if test "${with_jpeg}" != "no"; then
2227 dnl Checking for jpeglib.h can lose because of a redefinition of
2228 dnl HAVE_STDLIB_H.
2229 AC_CHECK_HEADER(jerror.h,
2230 AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes))
2231 fi
2233 AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2234 if test "${HAVE_JPEG}" = "yes"; then
2235 AC_DEFINE(HAVE_JPEG)
2236 AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2237 [#include <jpeglib.h>
2238 version=JPEG_LIB_VERSION
2239 ],
2240 AC_DEFINE(HAVE_JPEG),
2241 [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2242 HAVE_JPEG=no])
2243 fi
2244 fi
2246 ### Use -lpng if available, unless `--with-png=no'.
2247 HAVE_PNG=no
2248 if test "${HAVE_X11}" = "yes"; then
2249 if test "${with_png}" != "no"; then
2250 # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2251 # in /usr/include/libpng.
2252 AC_CHECK_HEADERS(png.h libpng/png.h)
2253 if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2254 AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2255 fi
2256 fi
2258 if test "${HAVE_PNG}" = "yes"; then
2259 AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2260 fi
2261 fi
2263 ### Use -ltiff if available, unless `--with-tiff=no'.
2264 HAVE_TIFF=no
2265 if test "${HAVE_X11}" = "yes"; then
2266 if test "${with_tiff}" != "no"; then
2267 AC_CHECK_HEADER(tiffio.h,
2268 tifflibs="-lz -lm"
2269 # At least one tiff package requires the jpeg library.
2270 if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2271 AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs))
2272 fi
2274 if test "${HAVE_TIFF}" = "yes"; then
2275 AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2276 fi
2277 fi
2279 ### Use -lgif if available, unless `--with-gif=no'.
2280 HAVE_GIF=no
2281 if test "${HAVE_X11}" = "yes"; then
2282 if test "${with_gif}" != "no"; then
2283 AC_CHECK_HEADER(gif_lib.h,
2284 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2285 # Earlier versions can crash Emacs.
2286 AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes))
2287 fi
2289 if test "${HAVE_GIF}" = "yes"; then
2290 AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have the ungif library (-lungif).])
2291 fi
2292 fi
2294 ### Use Mac OS X Carbon API to implement GUI.
2295 HAVE_CARBON=no
2296 if test "${with_carbon}" != "no"; then
2297 AC_CHECK_HEADER(Carbon/Carbon.h, HAVE_CARBON=yes)
2298 fi
2300 dnl Check for malloc/malloc.h on darwin
2301 AC_CHECK_HEADER(malloc/malloc.h, AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.]))
2303 if test "${HAVE_CARBON}" = "yes"; then
2304 AC_DEFINE(HAVE_CARBON, 1, [Define to 1 if you are using the Carbon API on Mac OS X.])
2305 window_system=mac
2306 ## Specify the install directory
2307 carbon_appdir=
2308 if test "${carbon_appdir_x}" != ""; then
2309 case ${carbon_appdir_x} in
2310 y | ye | yes) carbon_appdir=/Applications ;;
2311 * ) carbon_appdir=${carbon_appdir_x} ;;
2312 esac
2313 fi
2314 # We also have mouse menus.
2315 HAVE_MENUS=yes
2316 fi
2318 ### Use session management (-lSM -lICE) if available
2319 HAVE_X_SM=no
2320 if test "${HAVE_X11}" = "yes"; then
2321 AC_CHECK_HEADER(X11/SM/SMlib.h,
2322 AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE))
2324 if test "${HAVE_X_SM}" = "yes"; then
2325 AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2326 case "$LIBS" in
2327 *-lSM*) ;;
2328 *) LIBS="-lSM -lICE $LIBS" ;;
2329 esac
2330 fi
2331 fi
2333 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2334 AC_CACHE_CHECK(whether netdb declares h_errno,
2335 emacs_cv_netdb_declares_h_errno,
2336 [AC_TRY_LINK([#include <netdb.h>],
2337 [return h_errno;],
2338 emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2339 if test $emacs_cv_netdb_declares_h_errno = yes; then
2340 AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2341 fi
2343 AC_FUNC_ALLOCA
2345 # fmod, logb, and frexp are found in -lm on most systems.
2346 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2347 AC_CHECK_LIB(m, sqrt)
2349 # Check for mail-locking functions in a "mail" library. Probably this should
2350 # have the same check as for liblockfile below.
2351 AC_CHECK_LIB(mail, maillock)
2352 dnl Debian, at least:
2353 AC_CHECK_LIB(lockfile, maillock)
2354 # If we have the shared liblockfile, assume we must use it for mail
2355 # locking (e.g. Debian). If we couldn't link against liblockfile
2356 # (no liblockfile.a installed), ensure that we don't need to.
2357 if test "$ac_cv_lib_lockfile_maillock" = no; then
2358 dnl This works for files generally, not just executables.
2359 dnl Should we look elsewhere for it? Maybe examine /etc/ld.so.conf?
2360 AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2361 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2362 if test $ac_cv_prog_liblockfile = yes; then
2363 AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2364 This probably means that movemail could lose mail.
2365 There may be a `development' package to install containing liblockfile.])
2366 else :
2367 fi
2368 fi
2369 AC_CHECK_FUNCS(touchlock)
2370 AC_CHECK_HEADERS(maillock.h)
2372 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2373 rename closedir mkdir rmdir sysinfo getrusage \
2374 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime res_init setsid \
2375 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2376 utimes setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2377 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2378 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2379 gai_strerror mkstemp getline getdelim mremap memmove fsync bzero \
2380 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign)
2382 AC_CHECK_HEADERS(sys/un.h)
2384 AC_FUNC_MKTIME
2385 if test "$ac_cv_func_working_mktime" = no; then
2386 AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2387 fi
2389 AC_FUNC_GETLOADAVG
2391 AC_FUNC_FSEEKO
2393 AC_FUNC_GETPGRP
2395 AC_FUNC_STRFTIME
2397 # UNIX98 PTYs.
2398 AC_CHECK_FUNCS(grantpt)
2400 # PTY-related GNU extensions.
2401 AC_CHECK_FUNCS(getpt)
2403 # Check this now, so that we will NOT find the above functions in ncurses.
2404 # That is because we have not set up to link ncurses in lib-src.
2405 # It's better to believe a function is not available
2406 # than to expect to find it in ncurses.
2407 AC_CHECK_LIB(ncurses, tparm)
2409 # Do we need the Hesiod library to provide the support routines?
2410 if test "$with_hesiod" = yes ; then
2411 # Don't set $LIBS here -- see comments above.
2412 resolv=no
2413 AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2414 [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2415 [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2416 if test "$resolv" = yes ; then
2417 RESOLVLIB=-lresolv
2418 AC_DEFINE(HAVE_LIBRESOLV, 1,
2419 [Define to 1 if you have the resolv library (-lresolv).])
2420 else
2421 RESOLVLIB=
2422 fi
2423 AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2424 AC_DEFINE(HAVE_LIBHESIOD, 1,
2425 [Define to 1 if you have the hesiod library (-lhesiod).]),
2426 :, $RESOLVLIB)])
2427 fi
2429 # These tell us which Kerberos-related libraries to use.
2430 if test "${with_kerberos+set}" = set; then
2431 AC_CHECK_LIB(com_err, com_err)
2432 AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2433 AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2434 AC_CHECK_LIB(krb5, krb5_init_context)
2435 if test "${with_kerberos5+set}" != set; then
2436 AC_CHECK_LIB(des425, des_cbc_encrypt,,
2437 AC_CHECK_LIB(des, des_cbc_encrypt))
2438 AC_CHECK_LIB(krb4, krb_get_cred,,
2439 AC_CHECK_LIB(krb, krb_get_cred))
2440 fi
2442 if test "${with_kerberos5+set}" = set; then
2443 AC_CHECK_HEADERS(krb5.h)
2444 else
2445 AC_CHECK_HEADERS(des.h,,
2446 [AC_CHECK_HEADERS(kerberosIV/des.h,,
2447 [AC_CHECK_HEADERS(kerberos/des.h)])])
2448 AC_CHECK_HEADERS(krb.h,,
2449 [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2450 [AC_CHECK_HEADERS(kerberos/krb.h)])])
2451 fi
2452 AC_CHECK_HEADERS(com_err.h)
2453 fi
2455 # Solaris requires -lintl if you want strerror (which calls dgettext)
2456 # to return localized messages.
2457 AC_CHECK_LIB(intl, dgettext)
2459 AC_MSG_CHECKING(whether localtime caches TZ)
2460 AC_CACHE_VAL(emacs_cv_localtime_cache,
2461 [if test x$ac_cv_func_tzset = xyes; then
2462 AC_TRY_RUN([#include <time.h>
2463 extern char **environ;
2464 unset_TZ ()
2465 {
2466 char **from, **to;
2467 for (to = from = environ; (*to = *from); from++)
2468 if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2469 to++;
2470 }
2471 char TZ_GMT0[] = "TZ=GMT0";
2472 char TZ_PST8[] = "TZ=PST8";
2473 main()
2474 {
2475 time_t now = time ((time_t *) 0);
2476 int hour_GMT0, hour_unset;
2477 if (putenv (TZ_GMT0) != 0)
2478 exit (1);
2479 hour_GMT0 = localtime (&now)->tm_hour;
2480 unset_TZ ();
2481 hour_unset = localtime (&now)->tm_hour;
2482 if (putenv (TZ_PST8) != 0)
2483 exit (1);
2484 if (localtime (&now)->tm_hour == hour_GMT0)
2485 exit (1);
2486 unset_TZ ();
2487 if (localtime (&now)->tm_hour != hour_unset)
2488 exit (1);
2489 exit (0);
2490 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2491 [# If we have tzset, assume the worst when cross-compiling.
2492 emacs_cv_localtime_cache=yes])
2493 else
2494 # If we lack tzset, report that localtime does not cache TZ,
2495 # since we can't invalidate the cache if we don't have tzset.
2496 emacs_cv_localtime_cache=no
2497 fi])dnl
2498 AC_MSG_RESULT($emacs_cv_localtime_cache)
2499 if test $emacs_cv_localtime_cache = yes; then
2500 AC_DEFINE(LOCALTIME_CACHE, 1,
2501 [Define to 1 if localtime caches TZ.])
2502 fi
2504 if test "x$HAVE_TIMEVAL" = xyes; then
2505 AC_CHECK_FUNCS(gettimeofday)
2506 if test $ac_cv_func_gettimeofday = yes; then
2507 AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2508 emacs_cv_gettimeofday_two_arguments,
2509 [AC_TRY_COMPILE([
2510 #ifdef TIME_WITH_SYS_TIME
2511 #include <sys/time.h>
2512 #include <time.h>
2513 #else
2514 #ifdef HAVE_SYS_TIME_H
2515 #include <sys/time.h>
2516 #else
2517 #include <time.h>
2518 #endif
2519 #endif],
2520 [struct timeval time;
2521 gettimeofday (&time, 0);],
2522 emacs_cv_gettimeofday_two_arguments=yes,
2523 emacs_cv_gettimeofday_two_arguments=no)])
2524 if test $emacs_cv_gettimeofday_two_arguments = no; then
2525 AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2526 [Define to 1 if gettimeofday accepts only one argument.])
2527 fi
2528 fi
2529 fi
2531 # This defines (or not) HAVE_TZNAME and HAVE_TM_ZONE.
2532 AC_STRUCT_TIMEZONE
2534 dnl Note that AC_STRUCT_TIMEZONE doesn't do what you might expect.
2535 if test "$ac_cv_func_gettimeofday" = yes; then
2536 AC_CACHE_CHECK([for struct timezone], emacs_cv_struct_timezone,
2537 [AC_TRY_COMPILE([#include <sys/time.h>],
2538 [struct timezone tz;],
2539 dnl It may be that we can't call gettimeofday with a non-null pointer,
2540 dnl even though we have struct timezone (e.g. HPUX). In that case
2541 dnl we'll lie about struct timezone.
2542 [AC_TRY_RUN([
2543 #ifdef TIME_WITH_SYS_TIME
2544 #include <sys/time.h>
2545 #include <time.h>
2546 #else
2547 #ifdef HAVE_SYS_TIME_H
2548 #include <sys/time.h>
2549 #else
2550 #include <time.h>
2551 #endif
2552 #endif
2553 main () {
2554 struct timeval time;
2555 struct timezone dummy;
2556 exit (gettimeofday (&time, &dummy));
2557 }],
2558 emacs_cv_struct_timezone=yes,
2559 emacs_cv_struct_timezone=no, emacs_cv_struct_timezone=yes)],
2560 emacs_cv_struct_timezone=no)])
2561 fi
2563 ok_so_far=yes
2564 AC_CHECK_FUNC(socket, , ok_so_far=no)
2565 if test $ok_so_far = yes; then
2566 AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2567 fi
2568 if test $ok_so_far = yes; then
2569 AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2570 fi
2571 if test $ok_so_far = yes; then
2572 dnl Fixme: Not used. Should this be HAVE_SOCKETS?
2573 AC_DEFINE(HAVE_INET_SOCKETS, 1,
2574 [Define to 1 if you have inet sockets.])
2575 fi
2577 AC_CHECK_HEADERS(sys/ioctl.h)
2579 if test -f /usr/lpp/X11/bin/smt.exp; then
2580 AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2581 [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2582 fi
2584 AC_MSG_CHECKING(whether system supports dynamic ptys)
2585 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2586 AC_MSG_RESULT(yes)
2587 AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2588 else
2589 AC_MSG_RESULT(no)
2590 fi
2592 AC_FUNC_FORK
2594 dnl Adapted from Haible's version.
2595 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2596 [AC_TRY_LINK([#include <langinfo.h>],
2597 [char* cs = nl_langinfo(CODESET);],
2598 emacs_cv_langinfo_codeset=yes,
2599 emacs_cv_langinfo_codeset=no)
2600 ])
2601 if test $emacs_cv_langinfo_codeset = yes; then
2602 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2603 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2604 fi
2606 AC_CHECK_TYPES(size_t)
2608 AC_TYPE_MBSTATE_T
2610 dnl Restrict could probably be used effectively other than in regex.c.
2611 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2612 [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2613 emacs_cv_c_restrict=yes,
2614 [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2615 emacs_cv_c_restrict=__restrict,
2616 emacs_cv_c_restrict=no)])])
2617 case "$emacs_cv_c_restrict" in
2618 yes) emacs_restrict=restrict;;
2619 no) emacs_restrict="";;
2620 *) emacs_restrict="$emacs_cv_c_restrict";;
2621 esac
2622 if test "$emacs_restrict" != __restrict; then
2623 AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2624 [Define to compiler's equivalent of C99 restrict keyword.
2625 Don't define if equivalent is `__restrict'.])
2626 fi
2628 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2629 [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2630 emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2631 if test "$emacs_cv_c_restrict_arr" = yes; then
2632 AC_DEFINE(__restrict_arr, __restrict,
2633 [Define to compiler's equivalent of C99 restrict keyword in array
2634 declarations. Define as empty for no equivalent.])
2635 fi
2637 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2638 dnl how the tty code is related to POSIX and/or other versions of termios.
2639 dnl The following looks like a useful start.
2640 dnl
2641 dnl AC_SYS_POSIX_TERMIOS
2642 dnl if test $ac_cv_sys_posix_termios = yes; then
2643 dnl AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2644 dnl and macros for terminal control.])
2645 dnl AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2646 dnl fi
2648 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used. (Needs libobj replacement.)
2650 # Set up the CFLAGS for real compilation, so we can substitute it.
2651 CFLAGS="$REAL_CFLAGS"
2652 CPPFLAGS="$REAL_CPPFLAGS"
2654 #### Find out which version of Emacs this is.
2655 [version=`grep 'defconst[ ]*emacs-version' ${srcdir}/lisp/version.el \
2656 | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2657 if test x"${version}" = x; then
2658 AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2659 fi
2661 ### Specify what sort of things we'll be editing into Makefile and config.h.
2662 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2663 AC_SUBST(version)
2664 AC_SUBST(configuration)
2665 AC_SUBST(canonical)
2666 AC_SUBST(srcdir)
2667 AC_SUBST(prefix)
2668 AC_SUBST(exec_prefix)
2669 AC_SUBST(bindir)
2670 AC_SUBST(datadir)
2671 AC_SUBST(sharedstatedir)
2672 AC_SUBST(libexecdir)
2673 AC_SUBST(mandir)
2674 AC_SUBST(infodir)
2675 AC_SUBST(lispdir)
2676 AC_SUBST(locallisppath)
2677 AC_SUBST(lisppath)
2678 AC_SUBST(x_default_search_path)
2679 AC_SUBST(etcdir)
2680 AC_SUBST(archlibdir)
2681 AC_SUBST(docdir)
2682 AC_SUBST(bitmapdir)
2683 AC_SUBST(gamedir)
2684 AC_SUBST(gameuser)
2685 AC_SUBST(c_switch_system)
2686 AC_SUBST(c_switch_machine)
2687 AC_SUBST(LD_SWITCH_X_SITE)
2688 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2689 AC_SUBST(C_SWITCH_X_SITE)
2690 AC_SUBST(CFLAGS)
2691 AC_SUBST(X_TOOLKIT_TYPE)
2692 AC_SUBST(machfile)
2693 AC_SUBST(opsysfile)
2694 AC_SUBST(GETLOADAVG_LIBS)
2695 AC_SUBST(carbon_appdir)
2697 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "${canonical}",
2698 [Define to the canonical Emacs configuration name.])
2699 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2700 [Define to the options passed to configure.])
2701 AC_DEFINE_UNQUOTED(config_machfile, "${machfile}",
2702 [Define to the used machine dependent file.])
2703 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2704 [Define to the used os dependent file.])
2705 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2706 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2707 may need to deal with X Windows. For instance, if you've defined
2708 HAVE_X_WINDOWS above and your X libraries aren't in a place that
2709 your loader can find on its own, you might want to add "-L/..." or
2710 something similar.])
2711 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2712 [Define LD_SWITCH_X_SITE_AUX with an -R option
2713 in case it's needed (for Solaris, for example).])
2714 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE, ${C_SWITCH_X_SITE},
2715 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2716 may need to deal with X Windows. For instance, if you've defined
2717 HAVE_X_WINDOWS above and your X include files aren't in a place
2718 that your compiler can find on its own, you might want to add
2719 "-I/..." or something similar.])
2720 AC_DEFINE_UNQUOTED(UNEXEC_SRC, ${UNEXEC_SRC},
2721 [Define to the unexec source file name.])
2723 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2724 AC_DEFINE(HAVE_X_WINDOWS, 1,
2725 [Define to 1 if you want to use the X window system.])
2726 fi
2727 if test "${USE_X_TOOLKIT}" != "none" ; then
2728 AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2729 fi
2730 if test "${HAVE_X11}" = "yes" ; then
2731 AC_DEFINE(HAVE_X11, 1,
2732 [Define to 1 if you want to use version 11 of X windows.
2733 Otherwise, Emacs expects to use version 10.])
2734 fi
2735 if test "${HAVE_XFREE386}" = "yes" ; then
2736 AC_DEFINE(HAVE_XFREE386, 1, [Define to 1 if you're using XFree386.])
2737 fi
2738 if test "${HAVE_MENUS}" = "yes" ; then
2739 AC_DEFINE(HAVE_MENUS, 1,
2740 [Define to 1 if you have mouse menus.
2741 (This is automatic if you use X, but the option to specify it remains.)
2742 It is also defined with other window systems that support xmenu.c.])
2743 fi
2744 if test "${GNU_MALLOC}" = "yes" ; then
2745 AC_DEFINE(GNU_MALLOC, 1,
2746 [Define to 1 if you want to use the GNU memory allocator.])
2747 fi
2748 if test "${REL_ALLOC}" = "yes" ; then
2749 AC_DEFINE(REL_ALLOC, 1,
2750 [Define REL_ALLOC if you want to use the relocating allocator for
2751 buffer space.])
2752 fi
2754 AH_TOP([/* GNU Emacs site configuration template file.
2755 Copyright (C) 1988, 93, 94, 99, 2000, 2002 Free Software Foundation, Inc.
2757 This file is part of GNU Emacs.
2759 GNU Emacs is free software; you can redistribute it and/or modify
2760 it under the terms of the GNU General Public License as published by
2761 the Free Software Foundation; either version 2, or (at your option)
2762 any later version.
2764 GNU Emacs is distributed in the hope that it will be useful,
2765 but WITHOUT ANY WARRANTY; without even the implied warranty of
2766 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
2767 GNU General Public License for more details.
2769 You should have received a copy of the GNU General Public License
2770 along with GNU Emacs; see the file COPYING. If not, write to the
2771 Free Software Foundation, Inc., 59 Temple Place - Suite 330,
2772 Boston, MA 02111-1307, USA. */
2775 /* No code in Emacs #includes config.h twice, but some bits of code
2776 intended to work with other packages as well (like gmalloc.c)
2777 think they can include it as many times as they like. */
2778 #ifndef EMACS_CONFIG_H
2779 #define EMACS_CONFIG_H
2780 ])dnl
2782 AH_BOTTOM([
2783 /* If we're using any sort of window system, define some consequences. */
2784 #ifdef HAVE_X_WINDOWS
2785 #define HAVE_WINDOW_SYSTEM
2786 #define MULTI_KBOARD
2787 #define HAVE_MOUSE
2788 #endif
2790 /* If we're using the Carbon API on Mac OS X, define a few more
2791 variables as well. */
2792 #ifdef HAVE_CARBON
2793 #define HAVE_WINDOW_SYSTEM
2794 #define HAVE_MOUSE
2795 #endif
2797 /* Define USER_FULL_NAME to return a string
2798 that is the user's full name.
2799 It can assume that the variable `pw'
2800 points to the password file entry for this user.
2802 At some sites, the pw_gecos field contains
2803 the user's full name. If neither this nor any other
2804 field contains the right thing, use pw_name,
2805 giving the user's login name, since that is better than nothing. */
2806 #define USER_FULL_NAME pw->pw_gecos
2808 /* Define AMPERSAND_FULL_NAME if you use the convention
2809 that & in the full name stands for the login id. */
2810 /* Turned on June 1996 supposing nobody will mind it. */
2811 #define AMPERSAND_FULL_NAME
2813 /* We have blockinput.h. */
2814 #define DO_BLOCK_INPUT
2816 /* Define HAVE_SOUND if we have sound support. We know it works
2817 and compiles only on the specified platforms. For others,
2818 it probably doesn't make sense to try. */
2820 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2821 #ifdef HAVE_MACHINE_SOUNDCARD_H
2822 #define HAVE_SOUND 1
2823 #endif
2824 #ifdef HAVE_SYS_SOUNDCARD_H
2825 #define HAVE_SOUND 1
2826 #endif
2827 #ifdef HAVE_SOUNDCARD_H
2828 #define HAVE_SOUND 1
2829 #endif
2830 #endif /* __FreeBSD__ || __NetBSD__ || __linux__ */
2832 /* If using GNU, then support inline function declarations. */
2833 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2834 generally, because even if non-gcc compilers accept `inline', they
2835 may reject `extern inline'. */
2836 #ifdef __GNUC__
2837 #define INLINE __inline__
2838 #else
2839 #define INLINE
2840 #endif
2842 /* Include the os and machine dependent files. */
2843 #include config_opsysfile
2844 #include config_machfile
2846 /* Load in the conversion definitions if this system
2847 needs them and the source file being compiled has not
2848 said to inhibit this. There should be no need for you
2849 to alter these lines. */
2851 #ifdef SHORTNAMES
2852 #ifndef NO_SHORTNAMES
2853 #include "../shortnames/remap.h"
2854 #endif /* not NO_SHORTNAMES */
2855 #endif /* SHORTNAMES */
2857 /* If no remapping takes place, static variables cannot be dumped as
2858 pure, so don't worry about the `static' keyword. */
2859 #ifdef NO_REMAP
2860 #undef static
2861 #endif
2863 /* Define `subprocesses' should be defined if you want to
2864 have code for asynchronous subprocesses
2865 (as used in M-x compile and M-x shell).
2866 These do not work for some USG systems yet;
2867 for the ones where they work, the s/SYSTEM.h file defines this flag. */
2869 #ifndef VMS
2870 #ifndef USG
2871 /* #define subprocesses */
2872 #endif
2873 #endif
2875 /* SIGTYPE is the macro we actually use. */
2876 #ifndef SIGTYPE
2877 #define SIGTYPE RETSIGTYPE
2878 #endif
2880 #ifdef emacs /* Don't do this for lib-src. */
2881 /* Tell regex.c to use a type compatible with Emacs. */
2882 #define RE_TRANSLATE_TYPE Lisp_Object
2883 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2884 #define RE_TRANSLATE_P(TBL) (XFASTINT (TBL) != 0)
2885 #endif
2887 /* Avoid link-time collision with system mktime if we will use our own. */
2888 #if ! HAVE_MKTIME || BROKEN_MKTIME
2889 #define mktime emacs_mktime
2890 #endif
2892 #define my_strftime nstrftime /* for strftime.c */
2894 /* The rest of the code currently tests the CPP symbol BSTRING.
2895 Override any claims made by the system-description files.
2896 Note that on some SCO version it is possible to have bcopy and not bcmp. */
2897 #undef BSTRING
2898 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2899 #define BSTRING
2900 #endif
2902 /* Some of the files of Emacs which are intended for use with other
2903 programs assume that if you have a config.h file, you must declare
2904 the type of getenv.
2906 This declaration shouldn't appear when alloca.s or Makefile.in
2907 includes config.h. */
2908 #ifndef NOT_C_CODE
2909 extern char *getenv ();
2910 #endif
2912 /* These default definitions are good for almost all machines.
2913 The exceptions override them in m/MACHINE.h. */
2915 #ifndef BITS_PER_CHAR
2916 #define BITS_PER_CHAR 8
2917 #endif
2919 #ifndef BITS_PER_SHORT
2920 #define BITS_PER_SHORT 16
2921 #endif
2923 /* Note that lisp.h uses this in a preprocessor conditional, so it
2924 would not work to use sizeof. That being so, we do all of them
2925 without sizeof, for uniformity's sake. */
2926 #ifndef BITS_PER_INT
2927 #define BITS_PER_INT 32
2928 #endif
2930 #ifndef BITS_PER_LONG
2931 #ifdef _LP64
2932 #define BITS_PER_LONG 64
2933 #else
2934 #define BITS_PER_LONG 32
2935 #endif
2936 #endif
2938 /* Define if the compiler supports function prototypes. It may do so
2939 but not define __STDC__ (e.g. DEC C by default) or may define it as
2940 zero. */
2941 #undef PROTOTYPES
2942 /* For mktime.c: */
2943 #ifndef __P
2944 # if defined PROTOTYPES
2945 # define __P(args) args
2946 # else
2947 # define __P(args) ()
2948 # endif /* GCC. */
2949 #endif /* __P */
2951 /* Don't include "string.h" or <stdlib.h> in non-C code. */
2952 #ifndef NOT_C_CODE
2953 #ifdef HAVE_STRING_H
2954 #include "string.h"
2955 #endif
2956 #ifdef HAVE_STRINGS_H
2957 #include "strings.h" /* May be needed for bcopy & al. */
2958 #endif
2959 #ifdef HAVE_STDLIB_H
2960 #include <stdlib.h>
2961 #endif
2962 #ifndef __GNUC__
2963 # ifdef HAVE_ALLOCA_H
2964 # include <alloca.h>
2965 # else /* AIX files deal with #pragma. */
2966 # ifndef alloca /* predefined by HP cc +Olibcalls */
2967 char *alloca ();
2968 # endif
2969 # endif /* HAVE_ALLOCA_H */
2970 #endif /* __GNUC__ */
2971 #ifndef HAVE_SIZE_T
2972 typedef unsigned size_t;
2973 #endif
2974 #endif /* NOT_C_CODE */
2976 /* Define HAVE_X_I18N if we have usable i18n support. */
2978 #ifdef HAVE_X11R6
2979 #define HAVE_X_I18N
2980 #elif defined HAVE_X11R5 && !defined X11R5_INHIBIT_I18N
2981 #define HAVE_X_I18N
2982 #endif
2984 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support. */
2986 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2987 #define HAVE_X11R6_XIM
2988 #endif
2990 /* Should we enable expensive run-time checking of data types? */
2991 #undef ENABLE_CHECKING
2993 #if defined __GNUC__ && (__GNUC__ > 2 \
2994 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2995 #define NO_RETURN __attribute__ ((__noreturn__))
2996 #else
2997 #define NO_RETURN /* nothing */
2998 #endif
3000 /* These won't be used automatically yet. We also need to know, at least,
3001 that the stack is continuous. */
3002 #ifdef __GNUC__
3003 # ifndef GC_SETJMP_WORKS
3004 /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
3005 see NON_SAVING_SETJMP in the target descriptions. */
3006 /* Exceptions (see NON_SAVING_SETJMP in target description) are ns32k,
3007 SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
3008 Fixme: Deal with ns32k, SVR3. */
3009 # define GC_SETJMP_WORKS 1
3010 # endif
3011 # ifndef GC_LISP_OBJECT_ALIGNMENT
3012 # define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3013 # endif
3014 #endif
3016 #ifndef HAVE_BCOPY
3017 #define bcopy(a,b,s) memcpy (b,a,s)
3018 #endif
3019 #ifndef HAVE_BZERO
3020 #define bzero(a,s) memset (a,0,s)
3021 #endif
3022 #ifndef HAVE_BCMP
3023 #define BCMP memcmp
3024 #endif
3026 #endif /* EMACS_CONFIG_H */
3028 /*
3029 Local Variables:
3030 mode: c
3031 End:
3032 */
3033 ])dnl
3035 #### Report on what we decided to do.
3036 #### Report GTK as a toolkit, even if it doesn't use Xt.
3037 #### It makes printing result more understandable as using GTK sets
3038 #### toolkit_scroll_bars to yes by default.
3039 if test "${HAVE_GTK}" = "yes"; then
3040 USE_X_TOOLKIT=GTK
3041 fi
3043 echo "
3044 Configured for \`${canonical}'.
3046 Where should the build process find the source code? ${srcdir}
3047 What operating system and machine description files should Emacs use?
3048 \`${opsysfile}' and \`${machfile}'
3049 What compiler should emacs be built with? ${CC} ${CFLAGS}
3050 Should Emacs use the GNU version of malloc? ${GNU_MALLOC}${GNU_MALLOC_reason}
3051 Should Emacs use a relocating allocator for buffers? ${REL_ALLOC}
3052 Should Emacs use mmap(2) for buffer allocation? $use_mmap_for_buffers
3053 What window system should Emacs use? ${window_system}
3054 What toolkit should Emacs use? ${USE_X_TOOLKIT}"
3056 if test -n "${x_includes}"; then
3057 echo " Where do we find X Windows header files? ${x_includes}"
3058 else
3059 echo " Where do we find X Windows header files? Standard dirs"
3060 fi
3061 if test -n "${x_libraries}"; then
3062 echo " Where do we find X Windows libraries? ${x_libraries}"
3063 else
3064 echo " Where do we find X Windows libraries? Standard dirs"
3065 fi
3067 echo " Does Emacs use -lXaw3d? ${HAVE_XAW3D}"
3068 echo " Does Emacs use -lXpm? ${HAVE_XPM}"
3069 echo " Does Emacs use -ljpeg? ${HAVE_JPEG}"
3070 echo " Does Emacs use -ltiff? ${HAVE_TIFF}"
3071 echo " Does Emacs use -lungif? ${HAVE_GIF}"
3072 echo " Does Emacs use -lpng? ${HAVE_PNG}"
3073 echo " Does Emacs use X toolkit scroll bars? ${USE_TOOLKIT_SCROLL_BARS}"
3074 echo
3076 if test "$emacs_cv_randomheap" = warn; then
3077 AC_MSG_WARN([
3078 **********************************************************************
3080 Heap start address is randomized and no workaround is known.
3081 Emacs will probably dump core when temacs is run in the build phase.
3082 Maybe exec-shield is turned on. Read about exec-shield in `etc/PROBLEMS'
3083 for further information.
3085 **********************************************************************
3086 ])
3087 fi
3089 # Remove any trailing slashes in these variables.
3090 [test "${prefix}" != NONE &&
3091 prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3092 test "${exec_prefix}" != NONE &&
3093 exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3095 ## Check if the C preprocessor will convert `..' to `. .'. If so, set
3096 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3097 ## from Makefile.c can correctly provide the arg `-traditional' to the
3098 ## C preprocessor.
3100 AC_EGREP_CPP(yes..yes,
3101 [yes..yes],
3102 CPP_NEED_TRADITIONAL=no,
3103 CPP_NEED_TRADITIONAL=yes)
3105 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3106 man/Makefile lwlib/Makefile src/Makefile.c:src/Makefile.in \
3107 lisp/Makefile lispref/Makefile lispintro/Makefile leim/Makefile, [
3109 ### Make the necessary directories, if they don't exist.
3110 for dir in etc lisp ; do
3111 test -d ${dir} || mkdir ${dir}
3112 done
3114 # Build src/Makefile from ${srcdir}/src/Makefile.c
3115 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3116 # This must be done after src/config.h is built, since we rely on that file.
3118 # Now get this: Some word that is part of the ${srcdir} directory name
3119 # or the ${configuration} value might, just might, happen to be an
3120 # identifier like `sun4' or `i386' or something, and be predefined by
3121 # the C preprocessor to some helpful value like 1, or maybe the empty
3122 # string. Needless to say consequent macro substitutions are less
3123 # than conducive to the makefile finding the correct directory.
3124 [undefs="`echo $top_srcdir $configuration $canonical |
3125 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/ *$//' \
3126 -e 's/ */ -U/g' -e 's/-U[0-9][^ ]*//g' \
3127 `"]
3129 echo creating src/epaths.h
3130 ${MAKE-make} epaths-force
3132 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3133 # `..' to `. .' unless invoked with -traditional
3135 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3136 CPPFLAGS="$CPPFLAGS -traditional"
3137 fi
3139 echo creating lib-src/Makefile
3140 ( cd lib-src
3141 rm -f junk.c junk1.c junk2.c
3142 sed -e '/start of cpp stuff/q' \
3143 < Makefile.c > junk1.c
3144 sed -e '1,/start of cpp stuff/d'\
3145 -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3146 < Makefile.c > junk.c
3147 $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3148 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
3149 cat junk1.c junk2.c > Makefile.new
3150 rm -f junk.c junk1.c junk2.c
3151 chmod 444 Makefile.new
3152 mv -f Makefile.new Makefile
3153 )
3155 echo creating src/Makefile
3156 ( cd src
3157 rm -f junk.c junk1.c junk2.c
3158 sed -e '/start of cpp stuff/q' \
3159 < Makefile.c > junk1.c
3160 sed -e '1,/start of cpp stuff/d'\
3161 -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3162 < Makefile.c > junk.c
3163 $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3164 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
3165 cat junk1.c junk2.c > Makefile.new
3166 rm -f junk.c junk1.c junk2.c
3167 chmod 444 Makefile.new
3168 mv -f Makefile.new Makefile
3169 )
3171 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3172 echo creating src/.gdbinit
3173 echo source $srcdir/src/.gdbinit > src/.gdbinit
3174 fi
3176 # This is how we know whether to re-run configure in certain cases.
3177 touch src/config.stamp
3179 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS"])
3181 m4_if(dnl Do not change this comment
3182 arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3183 )dnl