lisp/disp-table.el

   1 ;;; disp-table.el --- functions for dealing with char tables.
   2
   3 ;; Copyright (C) 1987, 1994, 1995, 1999 Free Software Foundation, Inc.
   4
   5 ;; Author: Erik Naggum <erik@naggum.no>
   6 ;; Based on a previous version by Howard Gayle
   7 ;; Maintainer: FSF
   8 ;; Keywords: i18n
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Code:
  28
  29 (put 'display-table 'char-table-extra-slots 6)
  30
  31 ;;;###autoload
  32 (defun make-display-table ()
  33   "Return a new, empty display table."
  34   (make-char-table 'display-table nil))
  35
  36 (or standard-display-table
  37     (setq standard-display-table (make-display-table)))
  38
  39 ;;; Display-table slot names.  The property value says which slot.
  40
  41 (put 'truncation 'display-table-slot 0)
  42 (put 'wrap 'display-table-slot 1)
  43 (put 'escape 'display-table-slot 2)
  44 (put 'control 'display-table-slot 3)
  45 (put 'selective-display 'display-table-slot 4)
  46 (put 'vertical-border 'display-table-slot 5)
  47
  48 ;;;###autoload
  49 (defun display-table-slot (display-table slot)
  50   "Return the value of the extra slot in DISPLAY-TABLE named SLOT.
  51 SLOT may be a number from 0 to 5 inclusive, or a slot name (symbol).
  52 Valid symbols are `truncation', `wrap', `escape', `control',
  53 `selective-display', and `vertical-border'."
  54   (let ((slot-number
  55          (if (numberp slot) slot
  56            (or (get slot 'display-table-slot)
  57                (error "Invalid display-table slot name: %s" slot)))))
  58     (char-table-extra-slot display-table slot-number)))
  59
  60 ;;;###autoload
  61 (defun set-display-table-slot (display-table slot value)
  62   "Set the value of the extra slot in DISPLAY-TABLE named SLOT to VALUE.
  63 SLOT may be a number from 0 to 5 inclusive, or a name (symbol).
  64 Valid symbols are `truncation', `wrap', `escape', `control',
  65 `selective-display', and `vertical-border'."
  66   (let ((slot-number
  67          (if (numberp slot) slot
  68            (or (get slot 'display-table-slot)
  69                (error "Invalid display-table slot name: %s" slot)))))
  70     (set-char-table-extra-slot display-table slot-number value)))
  71
  72 ;;;###autoload
  73 (defun describe-display-table (dt)
  74   "Describe the display table DT in a help buffer."
  75   (with-output-to-temp-buffer "*Help*"
  76     (princ "\nTruncation glyph: ")
  77     (prin1 (display-table-slot dt 'truncation))
  78     (princ "\nWrap glyph: ")
  79     (prin1 (display-table-slot dt 'wrap))
  80     (princ "\nEscape glyph: ")
  81     (prin1 (display-table-slot dt 'escape))
  82     (princ "\nCtrl glyph: ")
  83     (prin1 (display-table-slot dt 'control))
  84     (princ "\nSelective display glyph sequence: ")
  85     (prin1 (display-table-slot dt 'selective-display))
  86     (princ "\nVertical window border glyph: ")
  87     (prin1 (display-table-slot dt 'vertical-border))
  88     (princ "\nCharacter display glyph sequences:\n")
  89     (save-excursion
  90       (set-buffer standard-output)
  91       (let ((vector (make-vector 256 nil))
  92             (i 0))
  93         (while (< i 256)
  94           (aset vector i (aref dt i))
  95           (setq i (1+ i)))
  96         (describe-vector vector))
  97       (help-mode))
  98     (print-help-return-message)))
  99
 100 ;;;###autoload
 101 (defun describe-current-display-table ()
 102   "Describe the display table in use in the selected window and buffer."
 103   (interactive)
 104   (let ((disptab (or (window-display-table (selected-window))
 105                      buffer-display-table
 106                      standard-display-table)))
 107     (if disptab
 108         (describe-display-table disptab)
 109       (message "No display table"))))
 110
 111 ;;;###autoload
 112 (defun standard-display-8bit (l h)
 113   "Display characters in the range L to H literally."
 114   (while (<= l h)
 115     (if (and (>= l ?\ ) (< l 127))
 116         (aset standard-display-table l nil)
 117       (aset standard-display-table l (vector l)))
 118     (setq l (1+ l))))
 119
 120 ;;;###autoload
 121 (defun standard-display-default (l h)
 122   "Display characters in the range L to H using the default notation."
 123   (while (<= l h)
 124     (if (and (>= l ?\ ) (char-valid-p l))
 125         (aset standard-display-table l nil))
 126     (setq l (1+ l))))
 127
 128 ;; This function does NOT take terminal-dependent escape sequences.
 129 ;; For that, you need to go through create-glyph.  Use one of the
 130 ;; other functions below, or roll your own.
 131 ;;;###autoload
 132 (defun standard-display-ascii (c s)
 133   "Display character C using printable string S."
 134   (aset standard-display-table c (vconcat s)))
 135
 136 ;;;###autoload
 137 (defun standard-display-g1 (c sc)
 138   "Display character C as character SC in the g1 character set.
 139 This function assumes that your terminal uses the SO/SI characters;
 140 it is meaningless for an X frame."
 141   (if (memq window-system '(x w32))
 142       (error "Cannot use string glyphs in a windowing system"))
 143   (aset standard-display-table c
 144         (vector (create-glyph (concat "\016" (char-to-string sc) "\017")))))
 145
 146 ;;;###autoload
 147 (defun standard-display-graphic (c gc)
 148   "Display character C as character GC in graphics character set.
 149 This function assumes VT100-compatible escapes; it is meaningless for an
 150 X frame."
 151   (if (memq window-system '(x w32))
 152       (error "Cannot use string glyphs in a windowing system"))
 153   (aset standard-display-table c
 154         (vector (create-glyph (concat "\e(0" (char-to-string gc) "\e(B")))))
 155
 156 ;;;###autoload
 157 (defun standard-display-underline (c uc)
 158   "Display character C as character UC plus underlining."
 159   (aset standard-display-table c
 160         (vector
 161          (if window-system
 162              (logior uc (lsh (face-id 'underline) 19))
 163            (create-glyph (concat "\e[4m" (char-to-string uc) "\e[m"))))))
 164
 165 ;;;###autoload
 166 (defun create-glyph (string)
 167   "Allocate a glyph code to display by sending STRING to the terminal."
 168   (if (= (length glyph-table) 65536)
 169       (error "No free glyph codes remain"))
 170   ;; Don't use slots that correspond to ASCII characters.
 171   (if (= (length glyph-table) 32)
 172       (setq glyph-table (vconcat glyph-table (make-vector 224 nil))))
 173   (setq glyph-table (vconcat glyph-table (list string)))
 174   (1- (length glyph-table)))
 175
 176 ;;;###autoload
 177 (defun standard-display-european (arg)
 178   "Semi-obsolete way to toggle display of ISO 8859 European characters.
 179
 180 This function is semi-obsolete; if you want to do your editing with
 181 unibyte characters, it is better to `set-language-environment' coupled
 182 with either the `--unibyte' option or the EMACS_UNIBYTE environment
 183 variable, or else customize `enable-multibyte-characters'.
 184
 185 With prefix argument, this command enables European character display
 186 if arg is positive, disables it otherwise.  Otherwise, it toggles
 187 European character display.
 188
 189 When this mode is enabled, characters in the range of 160 to 255
 190 display not as octal escapes, but as accented characters.  Codes 146
 191 and 160 display as apostrophe and space, even though they are not the
 192 ASCII codes for apostrophe and space.
 193
 194 Enabling European character display with this command noninteractively
 195 from Lisp code also selects Latin-1 as the language environment, and
 196 selects unibyte mode for all Emacs buffers \(both existing buffers and
 197 those created subsequently).  This provides increased compatibility
 198 for users who call this function in `.emacs'."
 199
 200   (if (or (<= (prefix-numeric-value arg) 0)
 201           (and (null arg)
 202                (char-table-p standard-display-table)
 203                ;; Test 161, because 160 displays as a space.
 204                (equal (aref standard-display-table 161) [161])))
 205       (progn
 206         (standard-display-default 160 255)
 207         (unless (or (memq window-system '(x w32))
 208                     (interactive-p))
 209           (and (terminal-coding-system)
 210                (set-terminal-coding-system nil))))
 211     ;; If the user does this explicitly from Lisp (as in .emacs),
 212     ;; turn off multibyte chars for more compatibility.
 213     (unless (interactive-p)
 214       (setq-default enable-multibyte-characters nil)
 215       (mapcar (lambda (buffer)
 216                 (with-current-buffer buffer
 217                   (if enable-multibyte-characters
 218                       (set-buffer-multibyte nil))))
 219               (buffer-list)))
 220     ;; If the user does this explicitly,
 221     ;; switch to Latin-1 language environment
 222     ;; unless some other has been specified.
 223     (unless (interactive-p)
 224       (if (equal current-language-environment "English")
 225           (set-language-environment "latin-1")))
 226     (unless (or noninteractive (memq window-system '(x w32))
 227                 (interactive-p))
 228       ;; Send those codes literally to a character-based terminal.
 229       ;; If we are using single-byte characters,
 230       ;; it doesn't matter which coding system we use.
 231       (set-terminal-coding-system
 232        (let ((c (intern (downcase current-language-environment))))
 233          (if (coding-system-p c) c 'latin-1))))
 234     (standard-display-european-internal)))
 235
 236 (provide 'disp-table)
 237
 238 ;;; disp-table.el ends here