lisp/font-core.el

   1 ;;; font-core.el --- Core interface to font-lock
   2
   3 ;; Copyright (C) 1992-2015 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: emacs-devel@gnu.org
   6 ;; Keywords: languages, faces
   7 ;; Package: emacs
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Code:
  25
  26 ;; This variable is used by mode packages that support Font Lock mode by
  27 ;; defining their own keywords to use for `font-lock-keywords'.  (The mode
  28 ;; command should make it buffer-local and set it to provide the set up.)
  29 (defvar font-lock-defaults nil
  30   "Defaults for Font Lock mode specified by the major mode.
  31 Defaults should be of the form:
  32
  33  (KEYWORDS [KEYWORDS-ONLY [CASE-FOLD [SYNTAX-ALIST ...]]])
  34
  35 KEYWORDS may be a symbol (a variable or function whose value is the keywords
  36 to use for fontification) or a list of symbols (specifying different levels
  37 of fontification).
  38
  39 If KEYWORDS-ONLY is non-nil, syntactic fontification (strings and
  40 comments) is not performed.
  41
  42 If CASE-FOLD is non-nil, the case of the keywords is ignored when fontifying.
  43
  44 If SYNTAX-ALIST is non-nil, it should be a list of cons pairs of the form
  45 \(CHAR-OR-STRING . STRING) used to set the local Font Lock syntax table, for
  46 keyword and syntactic fontification (see `modify-syntax-entry').
  47
  48 These item elements are used by Font Lock mode to set the variables
  49 `font-lock-keywords', `font-lock-keywords-only',
  50 `font-lock-keywords-case-fold-search', `font-lock-syntax-table'.
  51
  52 Further item elements are alists of the form (VARIABLE . VALUE) and are in no
  53 particular order.  Each VARIABLE is made buffer-local before set to VALUE.
  54
  55 Currently, appropriate variables include `font-lock-mark-block-function'.
  56 If this is non-nil, it should be a function with no args used to mark any
  57 enclosing block of text, for fontification via \\[font-lock-fontify-block].
  58 Typical values are `mark-defun' for programming modes or `mark-paragraph' for
  59 textual modes (i.e., the mode-dependent function is known to put point and mark
  60 around a text block relevant to that mode).
  61
  62 Other variables include that for syntactic keyword fontification,
  63 `font-lock-syntactic-keywords' and those for buffer-specialized fontification
  64 functions, `font-lock-fontify-buffer-function',
  65 `font-lock-unfontify-buffer-function', `font-lock-fontify-region-function',
  66 `font-lock-unfontify-region-function', and `font-lock-inhibit-thing-lock'.")
  67 ;;;###autoload
  68 (put 'font-lock-defaults 'risky-local-variable t)
  69 (make-variable-buffer-local 'font-lock-defaults)
  70
  71 (defvar font-lock-function 'font-lock-default-function
  72   "A function which is called when `font-lock-mode' is toggled.
  73 It will be passed one argument, which is the current value of
  74 `font-lock-mode'.")
  75
  76 ;; The mode for which font-lock was initialized, or nil if none.
  77 (defvar font-lock-major-mode)
  78
  79 (define-minor-mode font-lock-mode
  80   "Toggle syntax highlighting in this buffer (Font Lock mode).
  81 With a prefix argument ARG, enable Font Lock mode if ARG is
  82 positive, and disable it otherwise.  If called from Lisp, enable
  83 the mode if ARG is omitted or nil.
  84
  85 When Font Lock mode is enabled, text is fontified as you type it:
  86
  87  - Comments are displayed in `font-lock-comment-face';
  88  - Strings are displayed in `font-lock-string-face';
  89  - Certain other expressions are displayed in other faces according to the
  90    value of the variable `font-lock-keywords'.
  91
  92 To customize the faces (colors, fonts, etc.) used by Font Lock for
  93 fontifying different parts of buffer text, use \\[customize-face].
  94
  95 You can enable Font Lock mode in any major mode automatically by turning on in
  96 the major mode's hook.  For example, put in your ~/.emacs:
  97
  98  (add-hook \\='c-mode-hook \\='turn-on-font-lock)
  99
 100 Alternatively, you can use Global Font Lock mode to automagically turn on Font
 101 Lock mode in buffers whose major mode supports it and whose major mode is one
 102 of `font-lock-global-modes'.  For example, put in your ~/.emacs:
 103
 104  (global-font-lock-mode t)
 105
 106 Where major modes support different levels of fontification, you can use
 107 the variable `font-lock-maximum-decoration' to specify which level you
 108 generally prefer.  When you turn Font Lock mode on/off the buffer is
 109 fontified/defontified, though fontification occurs only if the buffer is
 110 less than `font-lock-maximum-size'.
 111
 112 To add your own highlighting for some major mode, and modify the highlighting
 113 selected automatically via the variable `font-lock-maximum-decoration', you can
 114 use `font-lock-add-keywords'.
 115
 116 To fontify a buffer, without turning on Font Lock mode and regardless of buffer
 117 size, you can use \\[font-lock-fontify-buffer].
 118
 119 To fontify a block (the function or paragraph containing point, or a number of
 120 lines around point), perhaps because modification on the current line caused
 121 syntactic change on other lines, you can use \\[font-lock-fontify-block].
 122
 123 You can set your own default settings for some mode, by setting a
 124 buffer local value for `font-lock-defaults', via its mode hook.
 125
 126 The above is the default behavior of `font-lock-mode'; you may specify
 127 your own function which is called when `font-lock-mode' is toggled via
 128 `font-lock-function'. "
 129   nil nil nil
 130   :after-hook (font-lock-initial-fontify)
 131   ;; Don't turn on Font Lock mode if we don't have a display (we're running a
 132   ;; batch job) or if the buffer is invisible (the name starts with a space).
 133   (when (or noninteractive (eq (aref (buffer-name) 0) ?\s))
 134     (setq font-lock-mode nil))
 135   (funcall font-lock-function font-lock-mode)
 136   ;; Arrange to unfontify this buffer if we change major mode later.
 137   (if font-lock-mode
 138       (add-hook 'change-major-mode-hook 'font-lock-change-mode nil t)
 139     (remove-hook 'change-major-mode-hook 'font-lock-change-mode t)))
 140
 141 ;; Get rid of fontification for the old major mode.
 142 ;; We do this when changing major modes.
 143 (defun font-lock-change-mode ()
 144   (font-lock-mode -1))
 145
 146 (defun font-lock-defontify ()
 147   "Clear out all `font-lock-face' properties in current buffer.
 148 A major mode that uses `font-lock-face' properties might want to put
 149 this function onto `change-major-mode-hook'."
 150   (let ((modp (buffer-modified-p))
 151         (inhibit-read-only t))
 152     (save-restriction
 153       (widen)
 154       (remove-list-of-text-properties (point-min) (point-max)
 155                                       '(font-lock-face)))
 156     (restore-buffer-modified-p modp)))
 157
 158 (defvar font-lock-set-defaults)
 159 (defun font-lock-default-function (mode)
 160   ;; Turn on Font Lock mode.
 161   (when mode
 162     (set (make-local-variable 'char-property-alias-alist)
 163          (copy-tree char-property-alias-alist))
 164     ;; Add `font-lock-face' as an alias for the `face' property.
 165     (let ((elt (assq 'face char-property-alias-alist)))
 166       (if elt
 167           (unless (memq 'font-lock-face (cdr elt))
 168             (setcdr elt (nconc (cdr elt) (list 'font-lock-face))))
 169         (push (list 'face 'font-lock-face) char-property-alias-alist))))
 170   ;; Turn off Font Lock mode.
 171   (unless mode
 172     ;; Remove `font-lock-face' as an alias for the `face' property.
 173     (set (make-local-variable 'char-property-alias-alist)
 174          (copy-tree char-property-alias-alist))
 175     (let ((elt (assq 'face char-property-alias-alist)))
 176       (when elt
 177         (setcdr elt (remq 'font-lock-face (cdr elt)))
 178         (when (null (cdr elt))
 179           (setq char-property-alias-alist
 180                 (delq elt char-property-alias-alist))))))
 181
 182   ;; Only do hard work if the mode has specified stuff in
 183   ;; `font-lock-defaults'.
 184   (when (font-lock-specified-p mode)
 185     (font-lock-mode-internal mode)))
 186
 187 (defun turn-on-font-lock ()
 188   "Turn on Font Lock mode (only if the terminal can display it)."
 189   (unless font-lock-mode
 190     (font-lock-mode)))
 191
 192 ;;; Global Font Lock mode.
 193
 194 ;; A few people have hassled in the past for a way to make it easier to turn on
 195 ;; Font Lock mode, without the user needing to know for which modes s/he has to
 196 ;; turn it on, perhaps the same way hilit19.el/hl319.el does.  I've always
 197 ;; balked at that way, as I see it as just re-molding the same problem in
 198 ;; another form.  That is; some person would still have to keep track of which
 199 ;; modes (which may not even be distributed with Emacs) support Font Lock mode.
 200 ;; The list would always be out of date.  And that person might have to be me.
 201
 202 ;; Implementation.
 203 ;;
 204 ;; In a previous discussion the following hack came to mind.  It is a gross
 205 ;; hack, but it generally works.  We use the convention that major modes start
 206 ;; by calling the function `kill-all-local-variables', which in turn runs
 207 ;; functions on the hook variable `change-major-mode-hook'.  We attach our
 208 ;; function `font-lock-change-major-mode' to that hook.  Of course, when this
 209 ;; hook is run, the major mode is in the process of being changed and we do not
 210 ;; know what the final major mode will be.  So, `font-lock-change-major-mode'
 211 ;; only (a) notes the name of the current buffer, and (b) adds our function
 212 ;; `turn-on-font-lock-if-desired' to the hook variables
 213 ;; `after-change-major-mode-hook' and `post-command-hook' (for modes
 214 ;; that do not yet run `after-change-major-mode-hook').  By the time
 215 ;; the functions on the first of these hooks to be run are run, the new major
 216 ;; mode is assumed to be in place.  This way we get a Font Lock function run
 217 ;; when a major mode is turned on, without knowing major modes or their hooks.
 218 ;;
 219 ;; Naturally this requires that major modes run `kill-all-local-variables'
 220 ;; and `after-change-major-mode-hook', as they are supposed to.  For modes
 221 ;; that do not run `after-change-major-mode-hook' yet, `post-command-hook'
 222 ;; takes care of things if the mode is set directly or indirectly by
 223 ;; an interactive command; however, problems can occur if the mode is
 224 ;; set by a timer or process: in that case, proper handling of Font Lock mode
 225 ;; may be delayed until the next interactive command.
 226
 227 ;; User interface.
 228 ;;
 229 ;; Although Global Font Lock mode is a pseudo-mode, I think that the user
 230 ;; interface should conform to the usual Emacs convention for modes, i.e., a
 231 ;; command to toggle the feature (`global-font-lock-mode') with a variable for
 232 ;; finer control of the mode's behavior (`font-lock-global-modes').
 233 ;;
 234 ;; The feature should not be enabled by loading font-lock.el, since other
 235 ;; mechanisms for turning on Font Lock mode, such as M-x font-lock-mode RET or
 236 ;; (add-hook 'c-mode-hook 'turn-on-font-lock), would cause Font Lock mode to be
 237 ;; turned on everywhere.  That would not be intuitive or informative because
 238 ;; loading a file tells you nothing about the feature or how to control it.  It
 239 ;; would also be contrary to the Principle of Least Surprise.  sm.
 240
 241 (defcustom font-lock-global-modes t
 242   "Modes for which Font Lock mode is automagically turned on.
 243 Global Font Lock mode is controlled by the command `global-font-lock-mode'.
 244 If nil, means no modes have Font Lock mode automatically turned on.
 245 If t, all modes that support Font Lock mode have it automatically turned on.
 246 If a list, it should be a list of `major-mode' symbol names for which Font Lock
 247 mode should be automatically turned on.  The sense of the list is negated if it
 248 begins with `not'.  For example:
 249  (c-mode c++-mode)
 250 means that Font Lock mode is turned on for buffers in C and C++ modes only."
 251   :type '(choice (const :tag "none" nil)
 252                  (const :tag "all" t)
 253                  (set :menu-tag "mode specific" :tag "modes"
 254                       :value (not)
 255                       (const :tag "Except" not)
 256                       (repeat :inline t (symbol :tag "mode"))))
 257   :group 'font-lock)
 258
 259 (defun turn-on-font-lock-if-desired ()
 260   (when (cond ((eq font-lock-global-modes t)
 261                t)
 262               ((eq (car-safe font-lock-global-modes) 'not)
 263                (not (memq major-mode (cdr font-lock-global-modes))))
 264               (t (memq major-mode font-lock-global-modes)))
 265     (let (inhibit-quit)
 266       (turn-on-font-lock))))
 267
 268 (define-globalized-minor-mode global-font-lock-mode
 269   font-lock-mode turn-on-font-lock-if-desired
 270   ;; What was this :extra-args thingy for?  --Stef
 271   ;; :extra-args (dummy)
 272   :initialize 'custom-initialize-delay
 273   :init-value (not (or noninteractive emacs-basic-display))
 274   :group 'font-lock
 275   :version "22.1")
 276
 277 ;;; End of Global Font Lock mode.
 278
 279 (provide 'font-core)
 280
 281 ;;; font-core.el ends here