lisp/descr-text.el

   1 ;;; descr-text.el --- describe text mode  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 1994-1996, 2001-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Boris Goldowsky <boris@gnu.org>
   6 ;; Maintainer: emacs-devel@gnu.org
   7 ;; Keywords: faces, i18n, Unicode, multilingual
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Describe-Text Mode.
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'quail))
  31 (require 'help-mode)
  32
  33 ;;; Describe-Text Utilities.
  34
  35 (defun describe-text-widget (widget)
  36   "Insert text to describe WIDGET in the current buffer."
  37   (insert-text-button
  38    (symbol-name (if (symbolp widget) widget (car widget)))
  39    'action (lambda (&rest _ignore) (widget-browse widget))
  40    'help-echo "mouse-2, RET: browse this widget")
  41   (insert " ")
  42   (insert-text-button
  43    "(widget)Top" 'type 'help-info 'help-args '("(widget)Top")))
  44
  45 (defun describe-text-sexp (sexp)
  46   "Insert a short description of SEXP in the current buffer."
  47   (let ((pp (condition-case signal
  48                 (pp-to-string sexp)
  49               (error (prin1-to-string signal)))))
  50     (when (string-match-p "\n\\'" pp)
  51       (setq pp (substring pp 0 (1- (length pp)))))
  52
  53     (if (and (not (string-match-p "\n" pp))
  54              (<= (length pp) (- (window-width) (current-column))))
  55         (insert pp)
  56       (insert-text-button
  57        "[Show]" 'action (lambda (&rest _ignore)
  58                           (with-output-to-temp-buffer
  59                               "*Pp Eval Output*"
  60                             (princ pp)))
  61        'help-echo "mouse-2, RET: pretty print value in another buffer"))))
  62
  63 (defun describe-property-list (properties)
  64   "Insert a description of PROPERTIES in the current buffer.
  65 PROPERTIES should be a list of overlay or text properties.
  66 The `category', `face' and `font-lock-face' properties are made
  67 into help buttons that call `describe-text-category' or
  68 `describe-face' when pushed."
  69   ;; Sort the properties by the size of their value.
  70   (dolist (elt (sort (let (ret)
  71                        (while properties
  72                          (push (list (pop properties) (pop properties)) ret))
  73                        ret)
  74                      (lambda (a b) (string< (prin1-to-string (nth 0 a) t)
  75                                             (prin1-to-string (nth 0 b) t)))))
  76     (let ((key (nth 0 elt))
  77           (value (nth 1 elt)))
  78       (insert (propertize (format "  %-20s " key)
  79                           'face 'help-argument-name))
  80       (cond ((eq key 'category)
  81              (insert-text-button
  82               (symbol-name value)
  83               'action (lambda (&rest _ignore)
  84                         (describe-text-category value))
  85               'follow-link t
  86               'help-echo "mouse-2, RET: describe this category"))
  87             ((memq key '(face font-lock-face mouse-face))
  88              (insert-text-button
  89               (format "%S" value)
  90               'type 'help-face 'help-args (list value)))
  91             ((widgetp value)
  92              (describe-text-widget value))
  93             (t
  94              (describe-text-sexp value))))
  95     (insert "\n")))
  96 \f
  97 ;;; Describe-Text Commands.
  98
  99 (defun describe-text-category (category)
 100   "Describe a text property category."
 101   (interactive "SCategory: ")
 102   (help-setup-xref (list #'describe-text-category category)
 103                    (called-interactively-p 'interactive))
 104   (with-help-window (help-buffer)
 105     (with-current-buffer standard-output
 106       (insert "Category " (format "%S" category) ":\n\n")
 107       (describe-property-list (symbol-plist category))
 108       (goto-char (point-min)))))
 109
 110 ;;;###autoload
 111 (defun describe-text-properties (pos &optional output-buffer buffer)
 112   "Describe widgets, buttons, overlays, and text properties at POS.
 113 POS is taken to be in BUFFER or in current buffer if nil.
 114 Interactively, describe them for the character after point.
 115 If optional second argument OUTPUT-BUFFER is non-nil,
 116 insert the output into that buffer, and don't initialize or clear it
 117 otherwise."
 118   (interactive "d")
 119   (let ((src-buf (current-buffer)))
 120     (if buffer (set-buffer buffer) (setq buffer (current-buffer)))
 121   (if (>= pos (point-max))
 122       (error "No character follows specified position"))
 123   (if output-buffer
 124       (describe-text-properties-1 pos output-buffer)
 125     (if (not (or (text-properties-at pos) (overlays-at pos)))
 126         (message "This is plain text.")
 127         (with-temp-buffer
 128             (setq output-buffer (current-buffer))
 129             (insert "Text content at position " (format "%d" pos) ":\n\n")
 130           (set-buffer buffer)
 131           (describe-text-properties-1 pos output-buffer)
 132           (set-buffer src-buf)
 133           (help-setup-xref (list 'describe-text-properties pos nil buffer)
 134                            (called-interactively-p 'interactive))
 135           (with-help-window (help-buffer)
 136             (with-current-buffer standard-output
 137               (buffer-swap-text output-buffer)
 138               (goto-char (point-min)))))))))
 139
 140 (defun describe-text-properties-1 (pos output-buffer)
 141   (let* ((properties (text-properties-at pos))
 142          (overlays (overlays-in pos (1+ pos)))
 143          (wid-field (get-char-property pos 'field))
 144          (wid-button (get-char-property pos 'button))
 145          (wid-doc (get-char-property pos 'widget-doc))
 146          ;; If button.el is not loaded, we have no buttons in the text.
 147          (button (and (fboundp 'button-at) (button-at pos)))
 148          (button-type (and button (button-type button)))
 149          (button-label (and button (button-label button)))
 150          (widget (or wid-field wid-button wid-doc)))
 151     (with-current-buffer output-buffer
 152       ;; Widgets
 153       (when (widgetp widget)
 154         (newline)
 155         (insert (cond (wid-field "This is an editable text area")
 156                       (wid-button "This is an active area")
 157                       (wid-doc "This is documentation text")))
 158         (insert " of a ")
 159         (describe-text-widget widget)
 160         (insert ".\n\n"))
 161       ;; Buttons
 162       (when (and button (not (widgetp wid-button)))
 163         (newline)
 164         (insert (format-message "Here is a `%S' button labeled `%s'.\n\n"
 165                                 button-type button-label)))
 166       ;; Overlays
 167       (when overlays
 168         (newline)
 169         (if (eq (length overlays) 1)
 170             (insert "There is an overlay here:\n")
 171           (insert "There are " (format "%d" (length overlays))
 172                          " overlays here:\n"))
 173         (dolist (overlay overlays)
 174           (insert " From " (format "%d" (overlay-start overlay))
 175                          " to " (format "%d" (overlay-end overlay)) "\n")
 176           (describe-property-list (overlay-properties overlay)))
 177         (insert "\n"))
 178       ;; Text properties
 179       (when properties
 180         (newline)
 181         (insert "There are text properties here:\n")
 182         (describe-property-list properties)))))
 183 \f
 184 (defcustom describe-char-unidata-list
 185   '(name old-name general-category decomposition)
 186   "List of Unicode-based character property names shown by `describe-char'."
 187   :group 'mule
 188   :version "23.1"
 189   :type '(choice (const :tag "All properties" t)
 190           (set
 191            (const :tag "Unicode name" name)
 192            (const :tag "Unicode old name" old-name)
 193            (const :tag "Unicode general category " general-category)
 194            (const :tag "Unicode canonical combining class"
 195                   canonical-combining-class)
 196            (const :tag "Unicode bidi class" bidi-class)
 197            (const :tag "Unicode decomposition mapping" decomposition)
 198            (const :tag "Unicode decimal digit value" decimal-digit-value)
 199            (const :tag "Unicode digit value" digit-value)
 200            (const :tag "Unicode numeric value" numeric-value)
 201            (const :tag "Unicode mirrored" mirrored)
 202            (const :tag "Unicode ISO 10646 comment" iso-10646-comment)
 203            (const :tag "Unicode simple uppercase mapping" uppercase)
 204            (const :tag "Unicode simple lowercase mapping" lowercase)
 205            (const :tag "Unicode simple titlecase mapping" titlecase))))
 206
 207 (defcustom describe-char-unicodedata-file nil
 208   "Location of Unicode data file.
 209 This is the UnicodeData.txt file from the Unicode Consortium, used for
 210 diagnostics.  If it is non-nil `describe-char' will print data
 211 looked up from it.  This facility is mostly of use to people doing
 212 multilingual development.
 213
 214 This is a fairly large file, not typically present on GNU systems.
 215 At the time of writing it is at the URL
 216 `http://www.unicode.org/Public/UNIDATA/UnicodeData.txt'."
 217   :group 'mule
 218   :version "22.1"
 219   :type '(choice (const :tag "None" nil)
 220                  file))
 221
 222 (defun describe-char-unicode-data (char)
 223   "Return a list of Unicode data for Unicode CHAR.
 224 Each element is a list of a property description and the property value.
 225 The list is null if CHAR isn't found in `describe-char-unicodedata-file'.
 226 This function is semi-obsolete.  Use `get-char-code-property'."
 227   (when describe-char-unicodedata-file
 228     (unless (file-exists-p describe-char-unicodedata-file)
 229       (error "`unicodedata-file' %s not found" describe-char-unicodedata-file))
 230     (with-current-buffer (get-buffer-create " *Unicode Data*")
 231       (when (zerop (buffer-size))
 232         ;; Don't use -literally in case of DOS line endings.
 233         (insert-file-contents describe-char-unicodedata-file))
 234       (goto-char (point-min))
 235       (let ((hex (format "%04X" char))
 236             found first last)
 237         (if (re-search-forward (concat "^" hex) nil t)
 238             (setq found t)
 239           ;; It's not listed explicitly.  Look for ranges, e.g. CJK
 240           ;; ideographs, and check whether it's in one of them.
 241           (while (and (re-search-forward "^\\([^;]+\\);[^;]+First>;" nil t)
 242                       (>= char (setq first
 243                                      (string-to-number (match-string 1) 16)))
 244                       (progn
 245                         (forward-line 1)
 246                         (looking-at "^\\([^;]+\\);[^;]+Last>;")
 247                         (> char
 248                            (setq last
 249                                  (string-to-number (match-string 1) 16))))))
 250           (if (and (>= char first)
 251                    (<= char last))
 252               (setq found t)))
 253         (if found
 254             (let ((fields (mapcar (lambda (elt)
 255                                     (if (> (length elt) 0)
 256                                         elt))
 257                                   (cdr (split-string
 258                                         (buffer-substring
 259                                          (line-beginning-position)
 260                                          (line-end-position))
 261                                         ";")))))
 262               ;; The length depends on whether the last field was empty.
 263               (unless (or (= 13 (length fields))
 264                           (= 14 (length fields)))
 265                 (error "Invalid contents in %s" describe-char-unicodedata-file))
 266               ;; The field names and values lists are slightly
 267               ;; modified from Mule-UCS unidata.el.
 268               (list
 269                (list "Name" (let ((name (nth 0 fields)))
 270                               ;; Check for <..., First>, <..., Last>
 271                               (if (string-match "\\`\\(<[^,]+\\)," name)
 272                                   (concat (match-string 1 name) ">")
 273                                 name)))
 274                (list "Category"
 275                      (let ((val (nth 1 fields)))
 276                        (or (char-code-property-description
 277                             'general-category (intern val))
 278                            val)))
 279                (list "Combining class"
 280                      (let ((val (nth 2 fields)))
 281                        (or (char-code-property-description
 282                             'canonical-combining-class (intern val))
 283                            val)))
 284                (list "Bidi category"
 285                      (let ((val (nth 3 fields)))
 286                        (or (char-code-property-description
 287                             'bidi-class (intern val))
 288                            val)))
 289                (list
 290                 "Decomposition"
 291                 (if (nth 4 fields)
 292                     (let* ((parts (split-string (nth 4 fields)))
 293                            (info (car parts)))
 294                       (if (string-match "\\`<\\(.+\\)>\\'" info)
 295                           (setq info (match-string 1 info))
 296                         (setq info nil))
 297                       (if info (setq parts (cdr parts)))
 298                       (setq parts (mapconcat
 299                                    (lambda (arg)
 300                                      (string (string-to-number arg 16)))
 301                                    parts " "))
 302                       (concat info (if info " ") parts))))
 303                (list "Decimal digit value"
 304                      (nth 5 fields))
 305                (list "Digit value"
 306                      (nth 6 fields))
 307                (list "Numeric value"
 308                      (nth 7 fields))
 309                (list "Mirrored"
 310                      (if (equal "Y" (nth 8 fields))
 311                          "yes"))
 312                (list "Old name" (nth 9 fields))
 313                (list "ISO 10646 comment" (nth 10 fields))
 314                (list "Uppercase" (and (nth 11 fields)
 315                                       (string (string-to-number
 316                                                (nth 11 fields) 16))))
 317                (list "Lowercase" (and (nth 12 fields)
 318                                       (string (string-to-number
 319                                                (nth 12 fields) 16))))
 320                (list "Titlecase" (and (nth 13 fields)
 321                                       (string (string-to-number
 322                                                (nth 13 fields) 16)))))))))))
 323
 324 ;; Not defined on builds without X, but behind display-graphic-p.
 325 (declare-function internal-char-font "font.c" (position &optional ch))
 326
 327 ;; Return information about how CHAR is displayed at the buffer
 328 ;; position POS.  If the selected frame is on a graphic display,
 329 ;; return a string "FONT-DRIVER:FONT-NAME (GLYPH-CODE)" where:
 330 ;;   FONT-DRIVER is the font-driver name,
 331 ;;   FONT-NAME is the font name,
 332 ;;   GLYPH-CODE is a hexadigit string representing the glyph-ID.
 333 ;; Otherwise, return a string describing the terminal codes for the
 334 ;; character.
 335 (defun describe-char-display (pos char)
 336   (if (display-graphic-p (selected-frame))
 337       (let ((char-font-info (internal-char-font pos char)))
 338         (if char-font-info
 339             (let ((type (font-get (car char-font-info) :type))
 340                   (name (font-xlfd-name (car char-font-info)))
 341                   (code (cdr char-font-info)))
 342                (if (integerp code)
 343                    (format "%s:%s (#x%02X)" type name code)
 344                  (format "%s:%s (#x%04X%04X)"
 345                          type name (car code) (cdr code))))))
 346     (let* ((charset (get-text-property pos 'charset))
 347            (coding (or (terminal-coding-system) 'us-ascii))
 348            (encoded (encode-coding-char char coding charset)))
 349       (if encoded
 350           (encoded-string-description encoded coding)))))
 351
 352 \f
 353 ;; Return a string of CH with composition for padding on both sides.
 354 ;; It is displayed without overlapping with the left/right columns.
 355 (defsubst describe-char-padded-string (ch)
 356   (if (and (display-multi-font-p)
 357            (internal-char-font nil ch))
 358       (compose-string (string ch) 0 1 (format "\t%c\t" ch))
 359     (string ch)))
 360
 361 ;; Return a nicely formatted list of categories; extended category
 362 ;; description is added to the category name as a tooltip
 363 (defsubst describe-char-categories (category-set)
 364   (let ((mnemonics (category-set-mnemonics category-set)))
 365     (unless (eq mnemonics "")
 366       (list (mapconcat
 367              (lambda (x)
 368                (let* ((c (category-docstring x))
 369                       (doc (if (string-match "\\`\\(.*?\\)\n" c)
 370                                (propertize (match-string 1 c)
 371                                            'help-echo
 372                                            (substring c (1+ (match-end 1))))
 373                              c)))
 374                  (format "%c:%s" x doc)))
 375              mnemonics ", ")))))
 376
 377 (declare-function quail-find-key "quail" (char))
 378
 379 ;;;###autoload
 380 (defun describe-char (pos &optional buffer)
 381   "Describe position POS (interactively, point) and the char after POS.
 382 POS is taken to be in BUFFER, or the current buffer if BUFFER is nil.
 383 The information is displayed in buffer `*Help*'.
 384
 385 The position information includes POS; the total size of BUFFER; the
 386 region limits, if narrowed; the column number; and the horizontal
 387 scroll amount, if the buffer is horizontally scrolled.
 388
 389 The character information includes the character code; charset and
 390 code points in it; syntax; category; how the character is encoded in
 391 BUFFER and in BUFFER's file; character composition information (if
 392 relevant); the font and font glyphs used to display the character;
 393 the character's canonical name and other properties defined by the
 394 Unicode Data Base; and widgets, buttons, overlays, and text properties
 395 relevant to POS."
 396   (interactive "d")
 397   (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 398   (let ((src-buf (current-buffer)))
 399     (set-buffer buffer)
 400     (if (>= pos (point-max))
 401         (error "No character follows specified position"))
 402     (let* ((char (char-after pos))
 403            (eight-bit-p (and (not enable-multibyte-characters) (>= char 128)))
 404            (charset (if eight-bit-p 'eight-bit
 405                       (or (get-text-property pos 'charset)
 406                           (char-charset char))))
 407            (composition (find-composition pos nil nil t))
 408            (component-chars nil)
 409            (display-table (or (window-display-table)
 410                               buffer-display-table
 411                               standard-display-table))
 412            (disp-vector (and display-table (aref display-table char)))
 413            (multibyte-p enable-multibyte-characters)
 414            (overlays (mapcar (lambda (o) (overlay-properties o))
 415                              (overlays-at pos)))
 416            (char-description (if (not multibyte-p)
 417                                  (single-key-description char)
 418                                (if (< char 128)
 419                                    (single-key-description char)
 420                                  (string-to-multibyte
 421                                   (char-to-string char)))))
 422            (text-props-desc
 423             (let ((tmp-buf (generate-new-buffer " *text-props*")))
 424               (unwind-protect
 425                   (progn
 426                     (describe-text-properties pos tmp-buf)
 427                     (with-current-buffer tmp-buf (buffer-string)))
 428                 (kill-buffer tmp-buf))))
 429            item-list max-width code)
 430
 431       (if multibyte-p
 432           (or (setq code (encode-char char charset))
 433               (setq charset (char-charset char)
 434                     code (encode-char char charset)))
 435         (setq code char))
 436       (cond
 437        ;; Append a PDF character to left-to-right directional
 438        ;; embeddings and overrides, to prevent potential messup of the
 439        ;; following text.
 440        ((memq char '(?\x202a ?\x202d))
 441         (setq char-description
 442               (concat char-description
 443                       (propertize (string ?\x202c) 'invisible t))))
 444        ;; Append a PDF character followed by LRM to right-to-left
 445        ;; directional embeddings and overrides, to prevent potential
 446        ;; messup of the following numerical text.
 447        ((memq char '(?\x202b ?\x202e))
 448         (setq char-description
 449               (concat char-description
 450                       (propertize (string ?\x202c ?\x200e) 'invisible t))))
 451        ;; Append a PDI character to directional isolate initiators, to
 452        ;; prevent potential messup of the following numerical text
 453        ((memq char '(?\x2066 ?\x2067 ?\x2068))
 454         (setq char-description
 455               (concat char-description
 456                       (propertize (string ?\x2069) 'invisible t))))
 457        ;; Append a LRM character to any strong character to avoid
 458        ;; messing up the numerical codepoint.
 459        ((memq (get-char-code-property char 'bidi-class) '(R AL))
 460         (setq char-description
 461               (concat char-description
 462                       (propertize (string ?\x200e) 'invisible t)))))
 463       (when composition
 464         ;; When the composition is trivial (i.e. composed only with the
 465         ;; current character itself without any alternate characters),
 466         ;; we don't show the composition information.  Otherwise, store
 467         ;; two descriptive strings in the first two elements of
 468         ;; COMPOSITION.
 469         (or (catch 'tag
 470               (let ((from (car composition))
 471                     (to (nth 1 composition))
 472                     (components (nth 2 composition))
 473                     ch)
 474                 (if (and (vectorp components) (vectorp (aref components 0)))
 475                     (let ((idx (- pos from))
 476                           (nglyphs (lgstring-glyph-len components))
 477                           (i 0) j glyph glyph-from)
 478                       ;; COMPONENTS is a gstring.  Find a grapheme
 479                       ;; cluster containing the current character.
 480                       (while (and (< i nglyphs)
 481                                   (setq glyph (lgstring-glyph components i))
 482                                   (< (lglyph-to glyph) idx))
 483                         (setq i (1+ i)))
 484                       (if (or (not glyph) (= i nglyphs))
 485                           ;; The composition is broken.
 486                           (throw 'tag nil))
 487                       (setq glyph-from (lglyph-from glyph)
 488                             to (+ from (lglyph-to glyph) 1)
 489                             from (+ from glyph-from)
 490                             j i)
 491                       (while (and (< j nglyphs)
 492                                   (setq glyph (lgstring-glyph components j))
 493                                   (= (lglyph-from glyph) glyph-from))
 494                         (setq j (1+ j)))
 495                       (if (and (= to (1+ from))
 496                                (= i (1- j))
 497                                (setq glyph (lgstring-glyph components i))
 498                                (= char (lglyph-char glyph)))
 499                           ;; The composition is trivial.
 500                           (throw 'tag nil))
 501                       (nconc composition (list i (1- j))))
 502                   (dotimes (i (length components))
 503                     (if (integerp (setq ch (aref components i)))
 504                         (push (cons ch (describe-char-display pos ch))
 505                               component-chars)))
 506                   (setq component-chars (nreverse component-chars)))
 507                 (if (< from pos)
 508                     (if (< (1+ pos) to)
 509                         (setcar composition
 510                                 (concat
 511                                  " with the surrounding characters \""
 512                                  (mapconcat 'describe-char-padded-string
 513                                             (buffer-substring from pos) "")
 514                                  "\" and \""
 515                                  (mapconcat 'describe-char-padded-string
 516                                             (buffer-substring (1+ pos) to) "")
 517                                  "\""))
 518                       (setcar composition
 519                               (concat
 520                                " with the preceding character(s) \""
 521                                (mapconcat 'describe-char-padded-string
 522                                           (buffer-substring from pos) "")
 523                                "\"")))
 524                   (if (< (1+ pos) to)
 525                       (setcar composition
 526                               (concat
 527                                " with the following character(s) \""
 528                                (mapconcat 'describe-char-padded-string
 529                                           (buffer-substring (1+ pos) to) "")
 530                                "\""))
 531                     (setcar composition nil)))
 532                 (setcar (cdr composition)
 533                         (format "composed to form \"%s\" (see below)"
 534                                 (buffer-substring from to)))))
 535             (setq composition nil)))
 536
 537       (setq item-list
 538             `(("position"
 539                ,(let* ((beg      (point-min))
 540                        (end      (point-max))
 541                        (total    (buffer-size))
 542                        (percent  (round (* 100.0 (1- pos)) (max total 1)))
 543                        (hscroll  (if (= (window-hscroll) 0)
 544                                      ""
 545                                    (format ", Hscroll: %d" (window-hscroll))))
 546                        (col      (current-column)))
 547                   (if (or (/= beg 1)  (/= end (1+ total)))
 548                       (format "%d of %d (%d%%), restriction: <%d-%d>, column: %d%s"
 549                               pos total percent beg end col hscroll)
 550                     (if (= pos end)
 551                         (format "%d of %d (EOB), column: %d%s" pos total col hscroll)
 552                       (format "%d of %d (%d%%), column: %d%s"
 553                               pos total percent col hscroll)))))
 554               ("character"
 555                ,(format "%s (displayed as %s) (codepoint %d, #o%o, #x%x)"
 556                         char-description
 557                         (apply 'propertize char-description
 558                                (text-properties-at pos))
 559                         char char char))
 560               ("preferred charset"
 561                ,`(insert-text-button
 562                   ,(symbol-name charset)
 563                   'type 'help-character-set 'help-args '(,charset))
 564                ,(format "(%s)" (charset-description charset)))
 565               ("code point in charset"
 566                ,(let ((str (if (integerp code)
 567                                (format (if (< code 256) "0x%02X" "0x%04X")
 568                                        code)
 569                              (format "0x%04X%04X" (car code) (cdr code)))))
 570                   (if (<= (charset-dimension charset) 2)
 571                       `(insert-text-button
 572                         ,str
 573                         'action (lambda (&rest ignore)
 574                                   (list-charset-chars ',charset)
 575                                   (with-selected-window
 576                                       (get-buffer-window "*Character List*" 0)
 577                                     (goto-char (point-min))
 578                                     (forward-line 2) ;Skip the header.
 579                                     (let ((case-fold-search nil))
 580                                       (if (search-forward
 581                                            ,(char-to-string char) nil t)
 582                                           (goto-char (match-beginning 0))))))
 583                         'follow-link t
 584                         'help-echo
 585                         "mouse-2, RET: show this character in its character set")
 586                     str)))
 587               ,@(let ((script (aref char-script-table char)))
 588                   (if script
 589                       (list (list "script" (symbol-name script)))))
 590               ("syntax"
 591                ,(let ((syntax (syntax-after pos)))
 592                   (with-temp-buffer
 593                     (internal-describe-syntax-value syntax)
 594                     (buffer-string))))
 595               ("category"
 596                ,@(if (not eight-bit-p)
 597                      (let ((category-set (char-category-set char)))
 598                        (if category-set
 599                            (describe-char-categories category-set)
 600                          '("-- none --")))))
 601               ("to input"
 602                ,@(if (not eight-bit-p)
 603                      (let ((key-list (and (eq input-method-function
 604                                               'quail-input-method)
 605                                           (quail-find-key char))))
 606                        (if (consp key-list)
 607                            (list "type"
 608                                  (concat "\""
 609                                          (mapconcat 'identity
 610                                                     key-list "\" or \"")
 611                                          "\"")
 612                                  "with"
 613                                  `(insert-text-button
 614                                    ,current-input-method
 615                                    'type 'help-input-method
 616                                    'help-args '(,current-input-method))
 617                                  "input method")
 618                          (list
 619                           (let ((name
 620                                  (or (get-char-code-property char 'name)
 621                                      (get-char-code-property char 'old-name))))
 622                             (if (and name (assoc-string name (ucs-names)))
 623                                 (format
 624                                  "type \"C-x 8 RET %x\" or \"C-x 8 RET %s\""
 625                                  char name)
 626                               (format "type \"C-x 8 RET %x\"" char))))))))
 627               ("buffer code"
 628                ,(if multibyte-p
 629                     (encoded-string-description
 630                      (string-as-unibyte (char-to-string char)) nil)
 631                   (format "#x%02X" char)))
 632               ("file code"
 633                ,@(if multibyte-p
 634                      (let* ((coding buffer-file-coding-system)
 635                             (encoded (encode-coding-char char coding charset)))
 636                        (if encoded
 637                            (list (encoded-string-description encoded coding)
 638                                  (format "(encoded by coding system %S)"
 639                                          coding))
 640                          (list "not encodable by coding system"
 641                                (symbol-name coding))))
 642                    (list (format "#x%02X" char))))
 643               ("display"
 644                ,(cond
 645                  (disp-vector
 646                   (setq disp-vector (copy-sequence disp-vector))
 647                   (dotimes (i (length disp-vector))
 648                     (aset disp-vector i
 649                           (cons (aref disp-vector i)
 650                                 (describe-char-display
 651                                  pos (glyph-char (aref disp-vector i))))))
 652                   (format "by display table entry [%s] (see below)"
 653                           (mapconcat
 654                            (lambda (x)
 655                              (format "?%c" (glyph-char (car x))))
 656                            disp-vector " ")))
 657                  (composition
 658                   (cadr composition))
 659                  (t
 660                   (let ((display (describe-char-display pos char)))
 661                     (if (display-graphic-p (selected-frame))
 662                         (if display
 663                             (concat "by this font (glyph code)\n    " display)
 664                           "no font available")
 665                       (if display
 666                           (format "terminal code %s" display)
 667                         "not encodable for terminal"))))))
 668               ,@(let ((face
 669                        (if (not (or disp-vector composition))
 670                            (cond
 671                             ((and show-trailing-whitespace
 672                                   (save-excursion (goto-char pos)
 673                                                   (looking-at-p "[ \t]+$")))
 674                              'trailing-whitespace)
 675                             ((and nobreak-char-display char (eq char '#xa0))
 676                              'nobreak-space)
 677                             ((and nobreak-char-display char
 678                                   (memq char '(#xad #x2010 #x2011)))
 679                              'escape-glyph)
 680                             ((and (< char 32) (not (memq char '(9 10))))
 681                              'escape-glyph)))))
 682                   (if face (list (list "hardcoded face"
 683                                        `(insert-text-button ;FIXME: Wrap in lambda!
 684                                          ,(symbol-name face)
 685                                          'type 'help-face
 686                                          'help-args '(,face))))))
 687               ,@(if (not eight-bit-p)
 688                     (let ((unicodedata (describe-char-unicode-data char)))
 689                       (if unicodedata
 690                           (cons (list "Unicode data" "") unicodedata))))))
 691       (setq max-width (apply 'max (mapcar (lambda (x)
 692                                             (if (cadr x) (length (car x)) 0))
 693                                           item-list)))
 694       (set-buffer src-buf)
 695       (help-setup-xref (list 'describe-char pos buffer)
 696                        (called-interactively-p 'interactive))
 697       (with-help-window (help-buffer)
 698         (with-current-buffer standard-output
 699           (set-buffer-multibyte multibyte-p)
 700           (let ((formatter (format "%%%ds:" max-width)))
 701             (dolist (elt item-list)
 702               (when (cadr elt)
 703                 (insert (format formatter (car elt)))
 704                 (dolist (clm (cdr elt))
 705                   (cond ((eq (car-safe clm) 'insert-text-button)
 706                          (insert " ")
 707                          (eval clm))
 708                         ((not (zerop (length clm)))
 709                          (insert " " clm))))
 710                 (insert "\n"))))
 711
 712           (when overlays
 713             (save-excursion
 714               (goto-char (point-min))
 715               (re-search-forward "(displayed as ")
 716               (let ((end (+ (point) (length char-description))))
 717                 (mapc (lambda (props)
 718                         (let ((o (make-overlay (point) end)))
 719                           (while props
 720                             (overlay-put o (car props) (nth 1 props))
 721                             (setq props (cddr props)))))
 722                       overlays))))
 723
 724           (when disp-vector
 725             (insert
 726              "\nThe display table entry is displayed by ")
 727             (insert "these fonts (glyph codes):\n")
 728             (dotimes (i (length disp-vector))
 729               (insert (glyph-char (car (aref disp-vector i))) ?:
 730                       (propertize " " 'display '(space :align-to 5))
 731                       (or (cdr (aref disp-vector i)) "-- no font --")
 732                       "\n")
 733               (let ((face (glyph-face (car (aref disp-vector i)))))
 734                 (when face
 735                   (insert (propertize " " 'display '(space :align-to 5))
 736                           "face: ")
 737                   (insert (format-message "`%s'\n" face))))))
 738
 739           (when composition
 740             (insert "\nComposed")
 741             (if (car composition)
 742                 (insert (car composition)))
 743             (if (and (vectorp (nth 2 composition))
 744                      (vectorp (aref (nth 2 composition) 0)))
 745                 (let* ((gstring (nth 2 composition))
 746                        (font (lgstring-font gstring))
 747                        (from (nth 3 composition))
 748                        (to (nth 4 composition))
 749                        glyph)
 750                   (if (fontp font)
 751                       (progn
 752                         (insert " using this font:\n  "
 753                                 (symbol-name (font-get font :type))
 754                                 ?:
 755                                 (aref (query-font font) 0)
 756                                 "\nby these glyphs:\n")
 757                         (while (and (<= from to)
 758                                     (setq glyph (lgstring-glyph gstring from)))
 759                           (insert (format "  %S\n" glyph))
 760                           (setq from (1+ from))))
 761                     (insert " by these characters:\n")
 762                     (while (and (<= from to)
 763                                 (setq glyph (lgstring-glyph gstring from)))
 764                       (insert (format " %c (#x%x)\n"
 765                                       (lglyph-char glyph) (lglyph-char glyph)))
 766                       (setq from (1+ from)))))
 767               (insert " by the rule:\n\t(")
 768               (let ((first t))
 769                 (mapc (lambda (x)
 770                         (if first (setq first nil)
 771                           (insert " "))
 772                         (if (consp x) (insert (format "%S" x))
 773                           (if (= x ?\t) (insert (single-key-description x))
 774                             (insert ??)
 775                             (insert (describe-char-padded-string x)))))
 776                       (nth 2 composition)))
 777               (insert  ")\nThe component character(s) are displayed by ")
 778               (if (display-graphic-p (selected-frame))
 779                   (progn
 780                     (insert "these fonts (glyph codes):")
 781                     (dolist (elt component-chars)
 782                       (if (/= (car elt) ?\t)
 783                           (insert "\n "
 784                                   (describe-char-padded-string (car elt))
 785                                   ?:
 786                                   (propertize " "
 787                                               'display '(space :align-to 5))
 788                                   (or (cdr elt) "-- no font --")))))
 789                 (insert "these terminal codes:")
 790                 (dolist (elt component-chars)
 791                   (insert "\n  " (car elt) ":"
 792                           (propertize " " 'display '(space :align-to 4))
 793                           (or (cdr elt) "-- not encodable --"))))
 794               (insert (substitute-command-keys
 795                        "\nSee the variable `reference-point-alist' for ")
 796                       "the meaning of the rule.\n")))
 797
 798           (unless eight-bit-p
 799             (insert (if (not describe-char-unidata-list)
 800                         "\nCharacter code properties are not shown: "
 801                       "\nCharacter code properties: "))
 802             (insert-text-button
 803              "customize what to show"
 804              'action (lambda (&rest _ignore)
 805                        (customize-variable
 806                         'describe-char-unidata-list))
 807              'follow-link t)
 808             (insert "\n")
 809             (dolist (elt
 810                      (cond ((eq describe-char-unidata-list t)
 811                             (nreverse (mapcar 'car char-code-property-alist)))
 812                            ((< char 32)
 813                             ;; Temporary fix (2016-05-22): The
 814                             ;; decomposition item for \n corrupts the
 815                             ;; display on a Linux virtual terminal.
 816                             ;; (Bug #23594).
 817                             (remq 'decomposition describe-char-unidata-list))
 818                            (t describe-char-unidata-list)))
 819               (let ((val (get-char-code-property char elt))
 820                     description)
 821                 (when val
 822                   (setq description (char-code-property-description elt val))
 823                   (insert (if description
 824                               (format "  %s: %s (%s)\n" elt val description)
 825                             (format "  %s: %s\n" elt val)))))))
 826
 827           (if text-props-desc (insert text-props-desc))
 828           (setq buffer-read-only t))))))
 829
 830 (define-obsolete-function-alias 'describe-char-after 'describe-char "22.1")
 831
 832 ;;; Describe-Char-ElDoc
 833
 834 (defun describe-char-eldoc--truncate (name width)
 835   "Truncate NAME at white spaces such that it is no longer than WIDTH.
 836
 837 Split NAME on white space character and return string with as
 838 many leading words of NAME as possible without exceeding WIDTH
 839 characters.  If NAME consists of white space characters only,
 840 return an empty string.  Three dots (\"...\") are appended to
 841 returned string if some of the words from NAME have been omitted.
 842
 843 NB: Function may return string longer than WIDTH if name consists
 844 of a single word, or it's first word is longer than WIDTH
 845 characters."
 846   (let ((words (split-string name)))
 847     (if words
 848         (let ((last words))
 849           (setq width (- width (length (car words))))
 850           (while (and (cdr last)
 851                       (<= (+ (length (cadr last)) (if (cddr last) 4 1)) width))
 852             (setq last (cdr last))
 853             (setq width (- width (length (car last)) 1)))
 854           (let ((ellipsis (and (cdr last) "...")))
 855             (setcdr last nil)
 856             (concat (mapconcat 'identity words " ") ellipsis)))
 857       "")))
 858
 859 (defun describe-char-eldoc--format (ch &optional width)
 860   "Format a description for character CH which is no more than WIDTH characters.
 861
 862 Full description message has a \"U+HEX: NAME (GC: GENERAL-CATEGORY)\"
 863 format where:
 864 - HEX is a hexadecimal codepoint of the character (zero-padded to at
 865   least four digits),
 866 - NAME is name of the character.
 867 - GC is a two-letter abbreviation of the general-category of the
 868   character, and
 869 - GENERAL-CATEGORY is full name of the general-category of the
 870   character.
 871
 872 If WIDTH is non-nil some elements of the description may be
 873 omitted to accommodate the length restriction.  Under certain
 874 condition, the function may return string longer than WIDTH, see
 875 `describe-char-eldoc--truncate'."
 876   (let ((name (get-char-code-property ch 'name)))
 877     (when name
 878       (let* ((code (propertize (format "U+%04X" ch)
 879                                'face 'font-lock-constant-face))
 880              (gc (get-char-code-property ch 'general-category))
 881              (gc-desc (char-code-property-description 'general-category gc)))
 882
 883         (unless (or (not width) (<= (length name) width))
 884           (setq name (describe-char-eldoc--truncate name width)))
 885         (setq name (concat (substring name 0 1) (downcase (substring name 1))))
 886         (setq name (propertize name 'face 'font-lock-variable-name-face))
 887
 888         (setq gc (propertize (symbol-name gc) 'face 'font-lock-comment-face))
 889         (when gc-desc
 890           (setq gc-desc (propertize gc-desc 'face 'font-lock-comment-face)))
 891
 892         (let ((lcode    (length code))
 893               (lname    (length name))
 894               (lgc      (length gc))
 895               (lgc-desc (and gc-desc (length gc-desc))))
 896           (cond
 897            ((and gc-desc
 898                  (or (not width) (<= (+ lcode lname lgc lgc-desc 7) width)))
 899             (concat code ": " name " (" gc ": " gc-desc ")"))
 900            ((and gc-desc (<= (+ lcode lname lgc-desc 5) width))
 901             (concat code ": " name " (" gc-desc ")"))
 902            ((or (not width) (<= (+ lcode lname lgc 5) width))
 903             (concat code ": " name " (" gc ")"))
 904            ((<= (+ lname lgc 3) width)
 905             (concat name " (" gc ")"))
 906            (t name)))))))
 907
 908 ;;;###autoload
 909 (defun describe-char-eldoc ()
 910   "Return a description of character at point for use by ElDoc mode.
 911
 912 Return nil if character at point is a printable ASCII
 913 character (i.e. codepoint between 32 and 127 inclusively).
 914 Otherwise return a description formatted by
 915 `describe-char-eldoc--format' function taking into account value
 916 of `eldoc-echo-area-use-multiline-p' variable and width of
 917 minibuffer window for width limit.
 918
 919 This function is meant to be used as a value of
 920 `eldoc-documentation-function' variable."
 921   (let ((ch (following-char)))
 922     (when (and (not (zerop ch)) (or (< ch 32) (> ch 127)))
 923       (describe-char-eldoc--format
 924        ch
 925        (unless (eq eldoc-echo-area-use-multiline-p t)
 926          (1- (window-width (minibuffer-window))))))))
 927
 928 (provide 'descr-text)
 929
 930 ;;; descr-text.el ends here