lisp/gnus/nnspool.el

   1 ;;; nnspool.el --- spool access for GNU Emacs
   2
   3 ;; Copyright (C) 1988-1990, 1993-1998, 2000-2011
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   7 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   8 ;; Keywords: news
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'nnheader)
  30 (require 'nntp)
  31 (require 'nnoo)
  32 (eval-when-compile (require 'cl))
  33
  34 (nnoo-declare nnspool)
  35
  36 (defvoo nnspool-inews-program news-inews-program
  37   "Program to post news.
  38 This is most commonly `inews' or `injnews'.")
  39
  40 (defvoo nnspool-inews-switches '("-h" "-S")
  41   "Switches for nnspool-request-post to pass to `inews' for posting news.
  42 If you are using Cnews, you probably should set this variable to nil.")
  43
  44 (defvoo nnspool-spool-directory
  45     (file-name-as-directory (if (boundp 'news-directory)
  46                                 (symbol-value 'news-directory)
  47                               news-path))
  48   "Local news spool directory.")
  49
  50 (defvoo nnspool-nov-directory (concat nnspool-spool-directory "over.view/")
  51   "Local news nov directory.")
  52
  53 (defvoo nnspool-lib-dir
  54     (if (file-exists-p "/usr/lib/news/active")
  55         "/usr/lib/news/"
  56       "/var/lib/news/")
  57   "Where the local news library files are stored.")
  58
  59 (defvoo nnspool-active-file (concat nnspool-lib-dir "active")
  60   "Local news active file.")
  61
  62 (defvoo nnspool-newsgroups-file (concat nnspool-lib-dir "newsgroups")
  63   "Local news newsgroups file.")
  64
  65 (defvoo nnspool-distributions-file (concat nnspool-lib-dir "distribs.pat")
  66   "Local news distributions file.")
  67
  68 (defvoo nnspool-history-file (concat nnspool-lib-dir "history")
  69   "Local news history file.")
  70
  71 (defvoo nnspool-active-times-file (concat nnspool-lib-dir "active.times")
  72   "Local news active date file.")
  73
  74 (defvoo nnspool-large-newsgroup 50
  75   "The number of articles which indicates a large newsgroup.
  76 If the number of articles is greater than the value, verbose
  77 messages will be shown to indicate the current status.")
  78
  79 (defvoo nnspool-nov-is-evil nil
  80   "Non-nil means that nnspool will never return NOV lines instead of headers.")
  81
  82 (defconst nnspool-sift-nov-with-sed nil
  83   "If non-nil, use sed to get the relevant portion from the overview file.
  84 If nil, nnspool will load the entire file into a buffer and process it
  85 there.")
  86
  87 (defvoo nnspool-rejected-article-hook nil
  88   "*A hook that will be run when an article has been rejected by the server.")
  89
  90 (defvoo nnspool-file-coding-system nnheader-file-coding-system
  91   "Coding system for nnspool.")
  92
  93 \f
  94
  95 (defconst nnspool-version "nnspool 2.0"
  96   "Version numbers of this version of NNSPOOL.")
  97
  98 (defvoo nnspool-current-directory nil
  99   "Current news group directory.")
 100
 101 (defvoo nnspool-current-group nil)
 102 (defvoo nnspool-status-string "")
 103
 104 \f
 105 ;;; Interface functions.
 106
 107 (nnoo-define-basics nnspool)
 108
 109 (deffoo nnspool-retrieve-headers (articles &optional group server fetch-old)
 110   "Retrieve the headers of ARTICLES."
 111   (with-current-buffer nntp-server-buffer
 112     (erase-buffer)
 113     (when (nnspool-possibly-change-directory group)
 114       (let* ((number (length articles))
 115              (count 0)
 116              (default-directory nnspool-current-directory)
 117              (do-message (and (numberp nnspool-large-newsgroup)
 118                               (> number nnspool-large-newsgroup)))
 119              (nnheader-file-coding-system nnspool-file-coding-system)
 120              file beg article ag)
 121         (if (and (numberp (car articles))
 122                  (nnspool-retrieve-headers-with-nov articles fetch-old))
 123             ;; We successfully retrieved the NOV headers.
 124             'nov
 125           ;; No NOV headers here, so we do it the hard way.
 126           (while (setq article (pop articles))
 127             (if (stringp article)
 128                 ;; This is a Message-ID.
 129                 (setq ag (nnspool-find-id article)
 130                       file (and ag (nnspool-article-pathname
 131                                     (car ag) (cdr ag)))
 132                       article (cdr ag))
 133               ;; This is an article in the current group.
 134               (setq file (int-to-string article)))
 135             ;; Insert the head of the article.
 136             (when (and file
 137                        (file-exists-p file))
 138               (insert "221 ")
 139               (princ article (current-buffer))
 140               (insert " Article retrieved.\n")
 141               (setq beg (point))
 142               (inline (nnheader-insert-head file))
 143               (goto-char beg)
 144               (if (search-forward "\n\n" nil t)
 145                   (progn
 146                     (forward-char -1)
 147                     (insert ".\n"))
 148                 (goto-char (point-max))
 149                 (if (bolp)
 150                     (insert ".\n")
 151                   (insert "\n.\n")))
 152               (delete-region (point) (point-max)))
 153
 154             (and do-message
 155                  (zerop (% (incf count) 20))
 156                  (nnheader-message 5 "nnspool: Receiving headers... %d%%"
 157                                    (/ (* count 100) number))))
 158
 159           (when do-message
 160             (nnheader-message 5 "nnspool: Receiving headers...done"))
 161
 162           ;; Fold continuation lines.
 163           (nnheader-fold-continuation-lines)
 164           'headers)))))
 165
 166 (deffoo nnspool-open-server (server &optional defs)
 167   (nnoo-change-server 'nnspool server defs)
 168   (cond
 169    ((not (file-exists-p nnspool-spool-directory))
 170     (nnspool-close-server)
 171     (nnheader-report 'nnspool "Spool directory doesn't exist: %s"
 172                      nnspool-spool-directory))
 173    ((not (file-directory-p
 174           (directory-file-name
 175            (file-truename nnspool-spool-directory))))
 176     (nnspool-close-server)
 177     (nnheader-report 'nnspool "Not a directory: %s" nnspool-spool-directory))
 178    ((not (file-exists-p nnspool-active-file))
 179     (nnheader-report 'nnspool "The active file doesn't exist: %s"
 180                      nnspool-active-file))
 181    (t
 182     (nnheader-report 'nnspool "Opened server %s using directory %s"
 183                      server nnspool-spool-directory)
 184     t)))
 185
 186 (deffoo nnspool-request-article (id &optional group server buffer)
 187   "Select article by message ID (or number)."
 188   (nnspool-possibly-change-directory group)
 189   (let ((nntp-server-buffer (or buffer nntp-server-buffer))
 190         file ag)
 191     (if (stringp id)
 192         ;; This is a Message-ID.
 193         (when (setq ag (nnspool-find-id id))
 194           (setq file (nnspool-article-pathname (car ag) (cdr ag))))
 195       (setq file (nnspool-article-pathname nnspool-current-group id)))
 196     (and file
 197          (file-exists-p file)
 198          (not (file-directory-p file))
 199          (save-excursion (nnspool-find-file file))
 200          ;; We return the article number and group name.
 201          (if (numberp id)
 202              (cons nnspool-current-group id)
 203            ag))))
 204
 205 (deffoo nnspool-request-body (id &optional group server)
 206   "Select article body by message ID (or number)."
 207   (nnspool-possibly-change-directory group)
 208   (let ((res (nnspool-request-article id)))
 209     (when res
 210       (with-current-buffer nntp-server-buffer
 211         (goto-char (point-min))
 212         (when (search-forward "\n\n" nil t)
 213           (delete-region (point-min) (point)))
 214         res))))
 215
 216 (deffoo nnspool-request-head (id &optional group server)
 217   "Select article head by message ID (or number)."
 218   (nnspool-possibly-change-directory group)
 219   (let ((res (nnspool-request-article id)))
 220     (when res
 221       (with-current-buffer nntp-server-buffer
 222         (goto-char (point-min))
 223         (when (search-forward "\n\n" nil t)
 224           (delete-region (1- (point)) (point-max)))
 225         (nnheader-fold-continuation-lines)))
 226     res))
 227
 228 (deffoo nnspool-request-group (group &optional server dont-check info)
 229   "Select news GROUP."
 230   (let ((pathname (nnspool-article-pathname group))
 231         dir)
 232     (if (not (file-directory-p pathname))
 233         (nnheader-report
 234          'nnspool "Invalid group name (no such directory): %s" group)
 235       (setq nnspool-current-directory pathname)
 236       (nnheader-report 'nnspool "Selected group %s" group)
 237       (if dont-check
 238           (progn
 239             (nnheader-report 'nnspool "Selected group %s" group)
 240             t)
 241         ;; Yes, completely empty spool directories *are* possible.
 242         ;; Fix by Sudish Joseph <joseph@cis.ohio-state.edu>
 243         (when (setq dir (directory-files pathname nil "^[0-9]+$" t))
 244           (setq dir (sort (mapcar 'string-to-number dir) '<)))
 245         (if dir
 246             (nnheader-insert
 247              "211 %d %d %d %s\n" (length dir) (car dir)
 248              (car (last dir)) group)
 249           (nnheader-report 'nnspool "Empty group %s" group)
 250           (nnheader-insert "211 0 0 0 %s\n" group))))))
 251
 252 (deffoo nnspool-request-type (group &optional article)
 253   'news)
 254
 255 (deffoo nnspool-close-group (group &optional server)
 256   t)
 257
 258 (deffoo nnspool-request-list (&optional server)
 259   "List active newsgroups."
 260   (save-excursion
 261     (or (nnspool-find-file nnspool-active-file)
 262         (nnheader-report 'nnspool (nnheader-file-error nnspool-active-file)))))
 263
 264 (deffoo nnspool-request-list-newsgroups (&optional server)
 265   "List newsgroups (defined in NNTP2)."
 266   (save-excursion
 267     (or (nnspool-find-file nnspool-newsgroups-file)
 268         (nnheader-report 'nnspool (nnheader-file-error
 269                                    nnspool-newsgroups-file)))))
 270
 271 (deffoo nnspool-request-list-distributions (&optional server)
 272   "List distributions (defined in NNTP2)."
 273   (save-excursion
 274     (or (nnspool-find-file nnspool-distributions-file)
 275         (nnheader-report 'nnspool (nnheader-file-error
 276                                    nnspool-distributions-file)))))
 277
 278 ;; Suggested by Hallvard B Furuseth <h.b.furuseth@usit.uio.no>.
 279 (deffoo nnspool-request-newgroups (date &optional server)
 280   "List groups created after DATE."
 281   (if (nnspool-find-file nnspool-active-times-file)
 282       (save-excursion
 283         ;; Find the last valid line.
 284         (goto-char (point-max))
 285         (while (and (not (looking-at
 286                           "\\([^ ]+\\) +\\([0-9]+\\)[0-9][0-9][0-9] "))
 287                     (zerop (forward-line -1))))
 288         ;; We require nnheader which requires gnus-util.
 289         (let ((seconds (gnus-float-time (date-to-time date)))
 290               groups)
 291           ;; Go through lines and add the latest groups to a list.
 292           (while (and (looking-at "\\([^ ]+\\) +[0-9]+ ")
 293                       (progn
 294                         ;; We insert a .0 to make the list reader
 295                         ;; interpret the number as a float.  It is far
 296                         ;; too big to be stored in a lisp integer.
 297                         (goto-char (1- (match-end 0)))
 298                         (insert ".0")
 299                         (> (progn
 300                              (goto-char (match-end 1))
 301                              (read (current-buffer)))
 302                            seconds))
 303                       (push (buffer-substring
 304                              (match-beginning 1) (match-end 1))
 305                             groups)
 306                       (zerop (forward-line -1))))
 307           (erase-buffer)
 308           (dolist (group groups)
 309             (insert group " 0 0 y\n")))
 310         t)
 311     nil))
 312
 313 (deffoo nnspool-request-post (&optional server)
 314   "Post a new news in current buffer."
 315   (save-excursion
 316     (let* ((process-connection-type nil) ; t bugs out on Solaris
 317            (inews-buffer (generate-new-buffer " *nnspool post*"))
 318            (proc
 319             (condition-case err
 320                 (apply 'start-process "*nnspool inews*" inews-buffer
 321                        nnspool-inews-program nnspool-inews-switches)
 322               (error
 323                (nnheader-report 'nnspool "inews error: %S" err)))))
 324       (if (not proc)
 325           ;; The inews program failed.
 326           ()
 327         (nnheader-report 'nnspool "")
 328         (set-process-sentinel proc 'nnspool-inews-sentinel)
 329         (mm-with-unibyte-current-buffer
 330           (process-send-region proc (point-min) (point-max)))
 331         ;; We slap a condition-case around this, because the process may
 332         ;; have exited already...
 333         (ignore-errors
 334           (process-send-eof proc))
 335         t))))
 336
 337
 338 \f
 339 ;;; Internal functions.
 340
 341 (defun nnspool-inews-sentinel (proc status)
 342   (with-current-buffer (process-buffer proc)
 343     (goto-char (point-min))
 344     (if (or (zerop (buffer-size))
 345             (search-forward "spooled" nil t))
 346         (kill-buffer (current-buffer))
 347       ;; Make status message by folding lines.
 348       (while (re-search-forward "[ \t\n]+" nil t)
 349         (replace-match " " t t))
 350       (nnheader-report 'nnspool "%s" (buffer-string))
 351       (nnheader-message 5 "nnspool: %s" nnspool-status-string)
 352       (ding)
 353       (run-hooks 'nnspool-rejected-article-hook))))
 354
 355 (defun nnspool-retrieve-headers-with-nov (articles &optional fetch-old)
 356   (if (or gnus-nov-is-evil nnspool-nov-is-evil)
 357       nil
 358     (let ((nov (nnheader-group-pathname
 359                 nnspool-current-group nnspool-nov-directory ".overview"))
 360           (arts articles)
 361           (nnheader-file-coding-system nnspool-file-coding-system)
 362           last)
 363       (if (not (file-exists-p nov))
 364           ()
 365         (with-current-buffer nntp-server-buffer
 366           (erase-buffer)
 367           (if nnspool-sift-nov-with-sed
 368               (nnspool-sift-nov-with-sed articles nov)
 369             (nnheader-insert-file-contents nov)
 370             (if (and fetch-old
 371                      (not (numberp fetch-old)))
 372                 t                       ; We want all the headers.
 373               (ignore-errors
 374                 ;; Delete unwanted NOV lines.
 375                 (nnheader-nov-delete-outside-range
 376                  (if fetch-old (max 1 (- (car articles) fetch-old))
 377                    (car articles))
 378                  (car (last articles)))
 379                 ;; If the buffer is empty, this wasn't very successful.
 380                 (unless (zerop (buffer-size))
 381                   ;; We check what the last article number was.
 382                   ;; The NOV file may be out of sync with the articles
 383                   ;; in the group.
 384                   (forward-line -1)
 385                   (setq last (read (current-buffer)))
 386                   (if (= last (car articles))
 387                       ;; Yup, it's all there.
 388                       t
 389                     ;; Perhaps not.  We try to find the missing articles.
 390                     (while (and arts
 391                                 (<= last (car arts)))
 392                       (pop arts))
 393                     ;; The articles in `arts' are missing from the buffer.
 394                     (mapc 'nnspool-insert-nov-head arts)
 395                     t))))))))))
 396
 397 (defun nnspool-insert-nov-head (article)
 398   "Read the head of ARTICLE, convert to NOV headers, and insert."
 399   (save-excursion
 400     (let ((cur (current-buffer))
 401           buf)
 402       (setq buf (nnheader-set-temp-buffer " *nnspool head*"))
 403       (when (nnheader-insert-head
 404              (nnspool-article-pathname nnspool-current-group article))
 405         (nnheader-insert-article-line article)
 406         (goto-char (point-min))
 407         (let ((headers (nnheader-parse-head)))
 408           (set-buffer cur)
 409           (goto-char (point-max))
 410           (nnheader-insert-nov headers)))
 411       (kill-buffer buf))))
 412
 413 (defun nnspool-sift-nov-with-sed (articles file)
 414   (let ((first (car articles))
 415         (last (car (last articles))))
 416     (call-process "awk" nil t nil
 417                   (format "BEGIN {firstmsg=%d; lastmsg=%d;}\n $1 >= firstmsg && $1 <= lastmsg {print;}"
 418                           (1- first) (1+ last))
 419                   file)))
 420
 421 ;; Fixed by fdc@cliwe.ping.de (Frank D. Cringle).
 422 ;; Find out what group an article identified by a Message-ID is in.
 423 (defun nnspool-find-id (id)
 424   (with-temp-buffer
 425     (ignore-errors
 426       (call-process "grep" nil t nil (regexp-quote id) nnspool-history-file))
 427     (goto-char (point-min))
 428     (when (looking-at "<[^>]+>[ \t]+[-0-9~]+[ \t]+\\([^ /\t\n]+\\)/\\([0-9]+\\)[ \t\n]")
 429       (cons (match-string 1) (string-to-number (match-string 2))))))
 430
 431 (defun nnspool-find-file (file)
 432   "Insert FILE in server buffer safely."
 433   (set-buffer nntp-server-buffer)
 434   (erase-buffer)
 435   (condition-case ()
 436       (let ((coding-system-for-read nnspool-file-coding-system))
 437         (mm-insert-file-contents file)
 438         t)
 439     (file-error nil)))
 440
 441 (defun nnspool-possibly-change-directory (group)
 442   (if (not group)
 443       t
 444     (let ((pathname (nnspool-article-pathname group)))
 445       (if (file-directory-p pathname)
 446           (setq nnspool-current-directory pathname
 447                 nnspool-current-group group)
 448         (nnheader-report 'nnspool "No such newsgroup: %s" group)))))
 449
 450 (defun nnspool-article-pathname (group &optional article)
 451   "Find the file name for GROUP."
 452   (nnheader-group-pathname group nnspool-spool-directory article))
 453
 454 (provide 'nnspool)
 455
 456 ;;; nnspool.el ends here