lisp/mail/mail-utils.el

   1 ;;; mail-utils.el --- utility functions used both by rmail and rnews
   2
   3 ;; Copyright (C) 1985 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: mail, news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Utility functions for mail and netnews handling.  These handle fine
  28 ;; points of header parsing.
  29
  30 ;;; Code:
  31
  32 ;;; We require lisp-mode to make sure that lisp-mode-syntax-table has
  33 ;;; been initialized.
  34 (require 'lisp-mode)
  35
  36 ;;;###autoload
  37 (defcustom mail-use-rfc822 nil "\
  38 *If non-nil, use a full, hairy RFC822 parser on mail addresses.
  39 Otherwise, (the default) use a smaller, somewhat faster, and
  40 often correct parser."
  41   :type 'boolean
  42   :group 'mail)
  43
  44 ;; Returns t if file FILE is an Rmail file.
  45 ;;;###autoload
  46 (defun mail-file-babyl-p (file)
  47   (let ((buf (generate-new-buffer " *rmail-file-p*")))
  48     (unwind-protect
  49         (save-excursion
  50           (set-buffer buf)
  51           (insert-file-contents file nil 0 100)
  52           (looking-at "BABYL OPTIONS:"))
  53       (kill-buffer buf))))
  54
  55 (defun mail-string-delete (string start end)
  56   "Returns a string containing all of STRING except the part
  57 from START (inclusive) to END (exclusive)."
  58   (if (null end) (substring string 0 start)
  59     (concat (substring string 0 start)
  60             (substring string end nil))))
  61
  62 ;;;###autoload
  63 (defun mail-quote-printable (string &optional wrapper)
  64   "Convert a string to the \"quoted printable\" Q encoding.
  65 If the optional argument WRAPPER is non-nil,
  66 we add the wrapper characters =?ISO-8859-1?Q?....?=."
  67   (let ((i 0) (result ""))
  68     (save-match-data
  69       (while (string-match "[?=\"\200-\377]" string i)
  70         (setq result
  71               (concat result (substring string i (match-beginning 0))
  72                       (upcase (format "=%02x"
  73                                       (aref string (match-beginning 0))))))
  74         (setq i (match-end 0)))
  75       (if wrapper
  76           (concat "=?ISO-8859-1?Q?"
  77                   result (substring string i)
  78                   "?=")
  79         (concat result (substring string i))))))
  80
  81 (defun mail-unquote-printable-hexdigit (char)
  82   (if (>= char ?A)
  83       (+ (- char ?A) 10)
  84     (- char ?0)))
  85
  86 ;;;###autoload
  87 (defun mail-unquote-printable (string &optional wrapper)
  88   "Undo the \"quoted printable\" encoding.
  89 If the optional argument WRAPPER is non-nil,
  90 we expect to find and remove the wrapper characters =?ISO-8859-1?Q?....?=."
  91   (save-match-data
  92     (and wrapper
  93          (string-match "\\`=\\?ISO-8859-1\\?Q\\?\\([^?]*\\)\\?" string)
  94          (setq string (match-string 1 string)))
  95     (let ((i 0) strings)
  96       (while (string-match "=\\(..\\|\n\\)" string i)
  97         (setq strings (cons (substring string i (match-beginning 0)) strings))
  98         (unless (= (aref string (match-beginning 1)) ?\n)
  99           (setq strings
 100                 (cons (make-string 1
 101                                    (+ (* 16 (mail-unquote-printable-hexdigit
 102                                              (aref string (match-beginning 1))))
 103                                       (mail-unquote-printable-hexdigit
 104                                        (aref string (1+ (match-beginning 1))))))
 105                       strings)))
 106         (setq i (match-end 0)))
 107       (apply 'concat (nreverse (cons (substring string i) strings))))))
 108
 109 ;;;###autoload
 110 (defun mail-unquote-printable-region (beg end &optional wrapper)
 111   "Undo the \"quoted printable\" encoding in buffer from BEG to END.
 112 If the optional argument WRAPPER is non-nil,
 113 we expect to find and remove the wrapper characters =?ISO-8859-1?Q?....?=."
 114   (interactive "r\nP")
 115   (save-match-data
 116     (save-excursion
 117       (save-restriction
 118         (narrow-to-region beg end)
 119         (goto-char (point-min))
 120         (when (and wrapper
 121                    (looking-at "\\`=\\?ISO-8859-1\\?Q\\?\\([^?]*\\)\\?"))
 122           (delete-region (match-end 1) end)
 123           (delete-region (point) (match-beginning 1)))
 124         (while (re-search-forward "=\\(..\\|\n\\)" nil t)
 125           (goto-char (match-end 0))
 126           (replace-match
 127            (if (= (char-after (match-beginning 1)) ?\n)
 128                ""
 129              (make-string 1
 130                           (+ (* 16 (mail-unquote-printable-hexdigit
 131                                     (char-after (match-beginning 1))))
 132                              (mail-unquote-printable-hexdigit
 133                               (char-after (1+ (match-beginning 1)))))))
 134            t t))))))
 135
 136 (defun mail-strip-quoted-names (address)
 137   "Delete comments and quoted strings in an address list ADDRESS.
 138 Also delete leading/trailing whitespace and replace FOO <BAR> with just BAR.
 139 Return a modified address list."
 140   (if (null address)
 141       nil
 142     (if mail-use-rfc822
 143         (progn (require 'rfc822)
 144                (mapconcat 'identity (rfc822-addresses address) ", "))
 145       (let (pos)
 146
 147        ;; Detect nested comments.
 148        (if (string-match "[ \t]*(\\([^)\\]\\|\\\\.\\|\\\\\n\\)*(" address)
 149            ;; Strip nested comments.
 150            (with-current-buffer (get-buffer-create " *temp*")
 151              (erase-buffer)
 152              (insert address)
 153              (set-syntax-table lisp-mode-syntax-table)
 154              (goto-char 1)
 155              (while (search-forward "(" nil t)
 156                (forward-char -1)
 157                (skip-chars-backward " \t")
 158                (delete-region (point)
 159                               (save-excursion
 160                                 (condition-case ()
 161                                     (forward-sexp 1)
 162                                   (error (goto-char (point-max))))
 163                                   (point))))
 164              (setq address (buffer-string))
 165              (erase-buffer))
 166          ;; Strip non-nested comments an easier way.
 167          (while (setq pos (string-match
 168                             ;; This doesn't hack rfc822 nested comments
 169                             ;;  `(xyzzy (foo) whinge)' properly.  Big deal.
 170                             "[ \t]*(\\([^)\\]\\|\\\\.\\|\\\\\n\\)*)"
 171                             address))
 172            (setq address (replace-match "" nil nil address 0))))
 173
 174        ;; strip surrounding whitespace
 175        (string-match "\\`[ \t\n]*" address)
 176        (setq address (substring address
 177                                 (match-end 0)
 178                                 (string-match "[ \t\n]*\\'" address
 179                                               (match-end 0))))
 180
 181        ;; strip `quoted' names (This is supposed to hack `"Foo Bar" <bar@host>')
 182        (setq pos 0)
 183        (while (setq pos (string-match
 184                           "\\([ \t]?\\)\\([ \t]*\"\\([^\"\\]\\|\\\\.\\|\\\\\n\\)*\"[ \t\n]*\\)"
 185                           address pos))
 186          ;; If the next thing is "@", we have "foo bar"@host.  Leave it.
 187          (if (and (> (length address) (match-end 0))
 188                   (= (aref address (match-end 0)) ?@))
 189              (setq pos (match-end 0))
 190            ;; Otherwise discard the "..." part.
 191            (setq address (replace-match "" nil nil address 2))))
 192        ;; If this address contains <...>, replace it with just
 193        ;; the part between the <...>.
 194        (while (setq pos (string-match "\\(,\\s-*\\|\\`\\)\\([^,]*<\\([^>,:]*\\)>[^,]*\\)\\(\\s-*,\\|\\'\\)"
 195                                       address))
 196          (setq address (replace-match (match-string 3 address)
 197                                       nil nil address 2)))
 198        address))))
 199
 200 ; rmail-dont-reply-to-names is defined in loaddefs
 201 (defun rmail-dont-reply-to (userids)
 202   "Returns string of mail addresses USERIDS sans any recipients
 203 that start with matches for `rmail-dont-reply-to-names'.
 204 Usenet paths ending in an element that matches are removed also."
 205   (if (null rmail-dont-reply-to-names)
 206       (setq rmail-dont-reply-to-names
 207             (concat (if rmail-default-dont-reply-to-names
 208                         (concat rmail-default-dont-reply-to-names "\\|")
 209                         "")
 210                     (concat (regexp-quote (user-login-name))
 211                             "\\>"))))
 212   (let ((match (concat "\\(^\\|,\\)[ \t\n]*"
 213                        ;; Can anyone figure out what this is for?
 214                        ;; Is it an obsolete remnant of another way of
 215                        ;; handling Foo Bar <foo@machine>?
 216                        "\\([^,\n]*[!<]\\|\\)"
 217                        "\\("
 218                              rmail-dont-reply-to-names
 219                        "\\|"
 220                              ;; Include the human name that precedes <foo@bar>.
 221                              "\\([^\,.<\"]\\|\"[^\"]*\"\\)*"
 222                              "<\\(" rmail-dont-reply-to-names "\\)"
 223                        "\\)[^,]*"))
 224         (case-fold-search t)
 225         pos epos)
 226     (while (and (setq pos (string-match match userids pos))
 227                 (> (length userids) 0))
 228       ;; If there's a match, it starts at the beginning of the string,
 229       ;; or with `,'.  We must delete from that position to the
 230       ;; end of the user-id which starts at match-beginning 2.
 231       (let (inside-quotes quote-pos last-quote-pos)
 232         (save-match-data
 233           (while (and (setq quote-pos (string-match "\"" userids quote-pos))
 234                       (< quote-pos pos))
 235             (setq last-quote-pos quote-pos)
 236             (setq quote-pos (1+ quote-pos))
 237             (setq inside-quotes (not inside-quotes))))
 238         (if inside-quotes
 239             (if (string-match "\"" userids pos)
 240                 (setq pos (string-match "\"" userids pos))
 241               ;; If the open-quote has no close-quote,
 242               ;; delete the open-quote to get something well-defined.
 243               ;; This case is not valid, but it can happen if things
 244               ;; are weird elsewhere.
 245               (setq userids (replace-match "" nil nil userids))
 246               (setq userids (concat (substring userids 0 last-quote-pos)
 247                                     (substring userids (1+ last-quote-pos))))
 248               (setq pos (1- pos)))
 249           (setq userids (replace-match "" nil nil userids)))))
 250     ;; get rid of any trailing commas
 251     (if (setq pos (string-match "[ ,\t\n]*\\'" userids))
 252         (setq userids (substring userids 0 pos)))
 253     ;; remove leading spaces. they bother me.
 254     (if (string-match "\\(\\s \\|,\\)*" userids)
 255         (substring userids (match-end 0))
 256       userids)))
 257
 258 \f
 259 ;;;###autoload
 260 (defun mail-fetch-field (field-name &optional last all list)
 261   "Return the value of the header field whose type is FIELD-NAME.
 262 The buffer is expected to be narrowed to just the header of the message.
 263 If second arg LAST is non-nil, use the last field of type FIELD-NAME.
 264 If third arg ALL is non-nil, concatenate all such fields with commas between.
 265 If 4th arg LIST is non-nil, return a list of all such fields."
 266   (save-excursion
 267     (goto-char (point-min))
 268     (let ((case-fold-search t)
 269           (name (concat "^" (regexp-quote field-name) "[ \t]*:[ \t]*")))
 270       (if (or all list)
 271           (let ((value (if all "")))
 272             (while (re-search-forward name nil t)
 273               (let ((opoint (point)))
 274                 (while (progn (forward-line 1)
 275                               (looking-at "[ \t]")))
 276                 ;; Back up over newline, then trailing spaces or tabs
 277                 (forward-char -1)
 278                 (skip-chars-backward " \t" opoint)
 279                 (if list
 280                     (setq value (cons (buffer-substring-no-properties
 281                                        opoint (point))
 282                                       value))
 283                   (setq value (concat value
 284                                       (if (string= value "") "" ", ")
 285                                       (buffer-substring-no-properties
 286                                        opoint (point)))))))
 287             (if list
 288                 value
 289               (and (not (string= value "")) value)))
 290         (if (re-search-forward name nil t)
 291             (progn
 292               (if last (while (re-search-forward name nil t)))
 293               (let ((opoint (point)))
 294                 (while (progn (forward-line 1)
 295                               (looking-at "[ \t]")))
 296                 ;; Back up over newline, then trailing spaces or tabs
 297                 (forward-char -1)
 298                 (skip-chars-backward " \t" opoint)
 299                 (buffer-substring-no-properties opoint (point)))))))))
 300 \f
 301 ;; Parse a list of tokens separated by commas.
 302 ;; It runs from point to the end of the visible part of the buffer.
 303 ;; Whitespace before or after tokens is ignored,
 304 ;; but whitespace within tokens is kept.
 305 (defun mail-parse-comma-list ()
 306   (let (accumulated
 307         beg)
 308     (skip-chars-forward " \t\n")
 309     (while (not (eobp))
 310       (setq beg (point))
 311       (skip-chars-forward "^,")
 312       (skip-chars-backward " \t\n")
 313       (setq accumulated
 314             (cons (buffer-substring-no-properties beg (point))
 315                   accumulated))
 316       (skip-chars-forward "^,")
 317       (skip-chars-forward ", \t\n"))
 318     accumulated))
 319
 320 (defun mail-comma-list-regexp (labels)
 321   (let (pos)
 322     (setq pos (or (string-match "[^ \t]" labels) 0))
 323     ;; Remove leading and trailing whitespace.
 324     (setq labels (substring labels pos (string-match "[ \t]*$" labels pos)))
 325     ;; Change each comma to \|, and flush surrounding whitespace.
 326     (while (setq pos (string-match "[ \t]*,[ \t]*" labels))
 327       (setq labels
 328             (concat (substring labels 0 pos)
 329                     "\\|"
 330                     (substring labels (match-end 0))))))
 331   labels)
 332 \f
 333 (defun mail-rfc822-time-zone (time)
 334   (let* ((sec (or (car (current-time-zone time)) 0))
 335          (absmin (/ (abs sec) 60)))
 336     (format "%c%02d%02d" (if (< sec 0) ?- ?+) (/ absmin 60) (% absmin 60))))
 337
 338 (defun mail-rfc822-date ()
 339   (let* ((time (current-time))
 340          (s (current-time-string time)))
 341     (string-match "[^ ]+ +\\([^ ]+\\) +\\([^ ]+\\) \\([^ ]+\\) \\([^ ]+\\)" s)
 342     (concat (substring s (match-beginning 2) (match-end 2)) " "
 343             (substring s (match-beginning 1) (match-end 1)) " "
 344             (substring s (match-beginning 4) (match-end 4)) " "
 345             (substring s (match-beginning 3) (match-end 3)) " "
 346             (mail-rfc822-time-zone time))))
 347
 348 (provide 'mail-utils)
 349
 350 ;;; mail-utils.el ends here