lisp/emacs-lisp/debug.el

   1 ;;; debug.el --- debuggers and related commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1986, 1994, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: lisp, tools, maint
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This is a major mode documented in the Emacs Lisp manual.
  27
  28 ;;; Code:
  29
  30 (require 'button)
  31
  32 (defgroup debugger nil
  33   "Debuggers and related commands for Emacs."
  34   :prefix "debugger-"
  35   :group 'debug)
  36
  37 (defcustom debugger-mode-hook nil
  38   "Hooks run when `debugger-mode' is turned on."
  39   :type 'hook
  40   :group 'debugger
  41   :version "20.3")
  42
  43 (defcustom debugger-batch-max-lines 40
  44   "Maximum lines to show in debugger buffer in a noninteractive Emacs.
  45 When the debugger is entered and Emacs is running in batch mode,
  46 if the backtrace text has more than this many lines,
  47 the middle is discarded, and just the beginning and end are displayed."
  48   :type 'integer
  49   :group 'debugger
  50   :version "21.1")
  51
  52 (defvar debug-function-list nil
  53   "List of functions currently set for debug on entry.")
  54
  55 (defvar debugger-step-after-exit nil
  56   "Non-nil means \"single-step\" after the debugger exits.")
  57
  58 (defvar debugger-value nil
  59   "This is the value for the debugger to return, when it returns.")
  60
  61 (defvar debugger-old-buffer nil
  62   "This is the buffer that was current when the debugger was entered.")
  63
  64 (defvar debugger-previous-backtrace nil
  65   "The contents of the previous backtrace (including text properties).
  66 This is to optimize `debugger-make-xrefs'.")
  67
  68 (defvar debugger-outer-match-data)
  69 (defvar debugger-outer-load-read-function)
  70 (defvar debugger-outer-overriding-local-map)
  71 (defvar debugger-outer-overriding-terminal-local-map)
  72 (defvar debugger-outer-track-mouse)
  73 (defvar debugger-outer-last-command)
  74 (defvar debugger-outer-this-command)
  75 ;; unread-command-char is obsolete,
  76 ;; but we still save and restore it
  77 ;; in case some user program still tries to set it.
  78 (defvar debugger-outer-unread-command-char)
  79 (defvar debugger-outer-unread-command-events)
  80 (defvar debugger-outer-unread-post-input-method-events)
  81 (defvar debugger-outer-last-input-event)
  82 (defvar debugger-outer-last-command-event)
  83 (defvar debugger-outer-last-nonmenu-event)
  84 (defvar debugger-outer-last-event-frame)
  85 (defvar debugger-outer-standard-input)
  86 (defvar debugger-outer-standard-output)
  87 (defvar debugger-outer-inhibit-redisplay)
  88 (defvar debugger-outer-cursor-in-echo-area)
  89 (defvar debugger-will-be-back nil
  90   "Non-nil if we expect to get back in the debugger soon.")
  91
  92 (defvar inhibit-debug-on-entry nil
  93   "Non-nil means that debug-on-entry is disabled.")
  94
  95 (defvar debugger-jumping-flag nil
  96   "Non-nil means that debug-on-entry is disabled.
  97 This variable is used by `debugger-jump', `debugger-step-through',
  98 and `debugger-reenable' to temporarily disable debug-on-entry.")
  99
 100 (defvar inhibit-trace)                  ;Not yet implemented.
 101
 102 ;;;###autoload
 103 (setq debugger 'debug)
 104 ;;;###autoload
 105 (defun debug (&rest debugger-args)
 106   "Enter debugger.  To return, type \\<debugger-mode-map>`\\[debugger-continue]'.
 107 Arguments are mainly for use when this is called from the internals
 108 of the evaluator.
 109
 110 You may call with no args, or you may pass nil as the first arg and
 111 any other args you like.  In that case, the list of args after the
 112 first will be printed into the backtrace buffer."
 113   (interactive)
 114   (if inhibit-redisplay
 115       ;; Don't really try to enter debugger within an eval from redisplay.
 116       debugger-value
 117     (unless noninteractive
 118       (message "Entering debugger..."))
 119     (let (debugger-value
 120           (debug-on-error nil)
 121           (debug-on-quit nil)
 122           (debugger-buffer (get-buffer-create "*Backtrace*"))
 123           (debugger-old-buffer (current-buffer))
 124           (debugger-step-after-exit nil)
 125           (debugger-will-be-back nil)
 126           ;; Don't keep reading from an executing kbd macro!
 127           (executing-kbd-macro nil)
 128           ;; Save the outer values of these vars for the `e' command
 129           ;; before we replace the values.
 130           (debugger-outer-match-data (match-data))
 131           (debugger-outer-load-read-function load-read-function)
 132           (debugger-outer-overriding-local-map overriding-local-map)
 133           (debugger-outer-overriding-terminal-local-map
 134            overriding-terminal-local-map)
 135           (debugger-outer-track-mouse track-mouse)
 136           (debugger-outer-last-command last-command)
 137           (debugger-outer-this-command this-command)
 138           (debugger-outer-unread-command-char
 139            (with-no-warnings unread-command-char))
 140           (debugger-outer-unread-command-events unread-command-events)
 141           (debugger-outer-unread-post-input-method-events
 142            unread-post-input-method-events)
 143           (debugger-outer-last-input-event last-input-event)
 144           (debugger-outer-last-command-event last-command-event)
 145           (debugger-outer-last-nonmenu-event last-nonmenu-event)
 146           (debugger-outer-last-event-frame last-event-frame)
 147           (debugger-outer-standard-input standard-input)
 148           (debugger-outer-standard-output standard-output)
 149           (debugger-outer-inhibit-redisplay inhibit-redisplay)
 150           (debugger-outer-cursor-in-echo-area cursor-in-echo-area)
 151           (debugger-with-timeout-suspend (with-timeout-suspend)))
 152       ;; Set this instead of binding it, so that `q'
 153       ;; will not restore it.
 154       (setq overriding-terminal-local-map nil)
 155       ;; Don't let these magic variables affect the debugger itself.
 156       (let ((last-command nil) this-command track-mouse
 157             (inhibit-trace t)
 158             (inhibit-debug-on-entry t)
 159             unread-command-events
 160             unread-post-input-method-events
 161             last-input-event last-command-event last-nonmenu-event
 162             last-event-frame
 163             overriding-local-map
 164             load-read-function
 165             ;; If we are inside a minibuffer, allow nesting
 166             ;; so that we don't get an error from the `e' command.
 167             (enable-recursive-minibuffers
 168              (or enable-recursive-minibuffers (> (minibuffer-depth) 0)))
 169             (standard-input t) (standard-output t)
 170             inhibit-redisplay
 171             (cursor-in-echo-area nil))
 172         (unwind-protect
 173             (save-excursion
 174               (save-window-excursion
 175                 (with-no-warnings
 176                   (setq unread-command-char -1))
 177                 (when (eq (car debugger-args) 'debug)
 178                   ;; Skip the frames for backtrace-debug, byte-code,
 179                   ;; and implement-debug-on-entry.
 180                   (backtrace-debug 4 t)
 181                   ;; Place an extra debug-on-exit for macro's.
 182                   (when (eq 'lambda (car-safe (cadr (backtrace-frame 4))))
 183                     (backtrace-debug 5 t)))
 184                 (pop-to-buffer debugger-buffer)
 185                 (debugger-mode)
 186                 (debugger-setup-buffer debugger-args)
 187                 (when noninteractive
 188                   ;; If the backtrace is long, save the beginning
 189                   ;; and the end, but discard the middle.
 190                   (when (> (count-lines (point-min) (point-max))
 191                            debugger-batch-max-lines)
 192                     (goto-char (point-min))
 193                     (forward-line (/ 2 debugger-batch-max-lines))
 194                     (let ((middlestart (point)))
 195                       (goto-char (point-max))
 196                       (forward-line (- (/ 2 debugger-batch-max-lines)
 197                                        debugger-batch-max-lines))
 198                       (delete-region middlestart (point)))
 199                     (insert "...\n"))
 200                   (goto-char (point-min))
 201                   (message "%s" (buffer-string))
 202                   (kill-emacs -1))
 203                 (message "")
 204                 (let ((standard-output nil)
 205                       (buffer-read-only t))
 206                   (message "")
 207                   ;; Make sure we unbind buffer-read-only in the right buffer.
 208                   (save-excursion
 209                     (recursive-edit)))))
 210           ;; Kill or at least neuter the backtrace buffer, so that users
 211           ;; don't try to execute debugger commands in an invalid context.
 212           (if (get-buffer-window debugger-buffer 0)
 213               ;; Still visible despite the save-window-excursion?  Maybe it
 214               ;; it's in a pop-up frame.  It would be annoying to delete and
 215               ;; recreate it every time the debugger stops, so instead we'll
 216               ;; erase it (and maybe hide it) but keep it alive.
 217               (with-current-buffer debugger-buffer
 218                 (erase-buffer)
 219                 (fundamental-mode)
 220                 (with-selected-window (get-buffer-window debugger-buffer 0)
 221                   (when (and (window-dedicated-p (selected-window))
 222                              (not debugger-will-be-back))
 223                     ;; If the window is not dedicated, burying the buffer
 224                     ;; will mean that the frame created for it is left
 225                     ;; around showing some random buffer, and next time we
 226                     ;; pop to the debugger buffer we'll create yet
 227                     ;; another frame.
 228                     ;; If debugger-will-be-back is non-nil, the frame
 229                     ;; would need to be de-iconified anyway immediately
 230                     ;; after when we re-enter the debugger, so iconifying it
 231                     ;; here would cause flashing.
 232                     ;; Drew Adams is not happy with this: he wants to frame
 233                     ;; to be left at the top-level, still working on how
 234                     ;; best to do that.
 235                     (bury-buffer))))
 236             (kill-buffer debugger-buffer))
 237           (with-timeout-unsuspend debugger-with-timeout-suspend)
 238           (set-match-data debugger-outer-match-data)))
 239       ;; Put into effect the modified values of these variables
 240       ;; in case the user set them with the `e' command.
 241       (setq load-read-function debugger-outer-load-read-function)
 242       (setq overriding-local-map debugger-outer-overriding-local-map)
 243       (setq overriding-terminal-local-map
 244             debugger-outer-overriding-terminal-local-map)
 245       (setq track-mouse debugger-outer-track-mouse)
 246       (setq last-command debugger-outer-last-command)
 247       (setq this-command debugger-outer-this-command)
 248       (with-no-warnings
 249         (setq unread-command-char debugger-outer-unread-command-char))
 250       (setq unread-command-events debugger-outer-unread-command-events)
 251       (setq unread-post-input-method-events
 252             debugger-outer-unread-post-input-method-events)
 253       (setq last-input-event debugger-outer-last-input-event)
 254       (setq last-command-event debugger-outer-last-command-event)
 255       (setq last-nonmenu-event debugger-outer-last-nonmenu-event)
 256       (setq last-event-frame debugger-outer-last-event-frame)
 257       (setq standard-input debugger-outer-standard-input)
 258       (setq standard-output debugger-outer-standard-output)
 259       (setq inhibit-redisplay debugger-outer-inhibit-redisplay)
 260       (setq cursor-in-echo-area debugger-outer-cursor-in-echo-area)
 261       (setq debug-on-next-call debugger-step-after-exit)
 262       debugger-value)))
 263 \f
 264 (defun debugger-setup-buffer (debugger-args)
 265   "Initialize the `*Backtrace*' buffer for entry to the debugger.
 266 That buffer should be current already."
 267   (setq buffer-read-only nil)
 268   (erase-buffer)
 269   (set-buffer-multibyte t)              ;Why was it nil ?  -stef
 270   (setq buffer-undo-list t)
 271   (let ((standard-output (current-buffer))
 272         (print-escape-newlines t)
 273         (print-level 8)
 274         (print-length 50))
 275     (backtrace))
 276   (goto-char (point-min))
 277   (delete-region (point)
 278                  (progn
 279                    (search-forward "\n  debug(")
 280                    (forward-line (if (eq (car debugger-args) 'debug)
 281                                      2  ; Remove implement-debug-on-entry frame.
 282                                    1))
 283                    (point)))
 284   (insert "Debugger entered")
 285   ;; lambda is for debug-on-call when a function call is next.
 286   ;; debug is for debug-on-entry function called.
 287   (cond ((memq (car debugger-args) '(lambda debug))
 288          (insert "--entering a function:\n"))
 289         ;; Exiting a function.
 290         ((eq (car debugger-args) 'exit)
 291          (insert "--returning value: ")
 292          (setq debugger-value (nth 1 debugger-args))
 293          (prin1 debugger-value (current-buffer))
 294          (insert ?\n)
 295          (delete-char 1)
 296          (insert ? )
 297          (beginning-of-line))
 298         ;; Debugger entered for an error.
 299         ((eq (car debugger-args) 'error)
 300          (insert "--Lisp error: ")
 301          (prin1 (nth 1 debugger-args) (current-buffer))
 302          (insert ?\n))
 303         ;; debug-on-call, when the next thing is an eval.
 304         ((eq (car debugger-args) t)
 305          (insert "--beginning evaluation of function call form:\n"))
 306         ;; User calls debug directly.
 307         (t
 308          (insert ": ")
 309          (prin1 (if (eq (car debugger-args) 'nil)
 310                     (cdr debugger-args) debugger-args)
 311                 (current-buffer))
 312          (insert ?\n)))
 313   ;; After any frame that uses eval-buffer,
 314   ;; insert a line that states the buffer position it's reading at.
 315   (save-excursion
 316     (let ((tem eval-buffer-list))
 317       (while (and tem
 318                   (re-search-forward "^  eval-\\(buffer\\|region\\)(" nil t))
 319         (end-of-line)
 320         (insert (format "  ; Reading at buffer position %d"
 321                         ;; This will get the wrong result
 322                         ;; if there are two nested eval-region calls
 323                         ;; for the same buffer.  That's not a very useful case.
 324                         (with-current-buffer (car tem)
 325                           (point))))
 326         (pop tem))))
 327   (debugger-make-xrefs))
 328
 329 (defun debugger-make-xrefs (&optional buffer)
 330   "Attach cross-references to function names in the `*Backtrace*' buffer."
 331   (interactive "b")
 332   (with-current-buffer (or buffer (current-buffer))
 333     (setq buffer (current-buffer))
 334     (let ((inhibit-read-only t)
 335           (old-end (point-min)) (new-end (point-min)))
 336       ;; If we saved an old backtrace, find the common part
 337       ;; between the new and the old.
 338       ;; Compare line by line, starting from the end,
 339       ;; because that's the part that is likely to be unchanged.
 340       (if debugger-previous-backtrace
 341           (let (old-start new-start (all-match t))
 342             (goto-char (point-max))
 343             (with-temp-buffer
 344               (insert debugger-previous-backtrace)
 345               (while (and all-match (not (bobp)))
 346                 (setq old-end (point))
 347                 (forward-line -1)
 348                 (setq old-start (point))
 349                 (with-current-buffer buffer
 350                   (setq new-end (point))
 351                   (forward-line -1)
 352                   (setq new-start (point)))
 353                 (if (not (zerop
 354                           (let ((case-fold-search nil))
 355                             (compare-buffer-substrings
 356                              (current-buffer) old-start old-end
 357                              buffer new-start new-end))))
 358                     (setq all-match nil))))
 359             ;; Now new-end is the position of the start of the
 360             ;; unchanged part in the current buffer, and old-end is
 361             ;; the position of that same text in the saved old
 362             ;; backtrace.  But we must subtract (point-min) since strings are
 363             ;; indexed in origin 0.
 364
 365             ;; Replace the unchanged part of the backtrace
 366             ;; with the text from debugger-previous-backtrace,
 367             ;; since that already has the proper xrefs.
 368             ;; With this optimization, we only need to scan
 369             ;; the changed part of the backtrace.
 370             (delete-region new-end (point-max))
 371             (goto-char (point-max))
 372             (insert (substring debugger-previous-backtrace
 373                                (- old-end (point-min))))
 374             ;; Make the unchanged part of the backtrace inaccessible
 375             ;; so it won't be scanned.
 376             (narrow-to-region (point-min) new-end)))
 377
 378       ;; Scan the new part of the backtrace, inserting xrefs.
 379       (goto-char (point-min))
 380       (while (progn
 381                (goto-char (+ (point) 2))
 382                (skip-syntax-forward "^w_")
 383                (not (eobp)))
 384         (let* ((beg (point))
 385                (end (progn (skip-syntax-forward "w_") (point)))
 386                (sym (intern-soft (buffer-substring-no-properties
 387                                   beg end)))
 388                (file (and sym (symbol-file sym 'defun))))
 389           (when file
 390             (goto-char beg)
 391             ;; help-xref-button needs to operate on something matched
 392             ;; by a regexp, so set that up for it.
 393             (re-search-forward "\\(\\sw\\|\\s_\\)+")
 394             (help-xref-button 0 'help-function-def sym file)))
 395         (forward-line 1))
 396       (widen))
 397     (setq debugger-previous-backtrace (buffer-string))))
 398 \f
 399 (defun debugger-step-through ()
 400   "Proceed, stepping through subexpressions of this expression.
 401 Enter another debugger on next entry to eval, apply or funcall."
 402   (interactive)
 403   (setq debugger-step-after-exit t)
 404   (setq debugger-jumping-flag t)
 405   (setq debugger-will-be-back t)
 406   (add-hook 'post-command-hook 'debugger-reenable)
 407   (message "Proceeding, will debug on next eval or call.")
 408   (exit-recursive-edit))
 409
 410 (defun debugger-continue ()
 411   "Continue, evaluating this expression without stopping."
 412   (interactive)
 413   (unless debugger-may-continue
 414     (error "Cannot continue"))
 415   (message "Continuing.")
 416   (save-excursion
 417     ;; Check to see if we've flagged some frame for debug-on-exit, in which
 418     ;; case we'll probably come back to the debugger soon.
 419     (goto-char (point-min))
 420     (if (re-search-forward "^\\* " nil t)
 421         (setq debugger-will-be-back t)))
 422   (exit-recursive-edit))
 423
 424 (defun debugger-return-value (val)
 425   "Continue, specifying value to return.
 426 This is only useful when the value returned from the debugger
 427 will be used, such as in a debug on exit from a frame."
 428   (interactive "XReturn value (evaluated): ")
 429   (setq debugger-value val)
 430   (princ "Returning " t)
 431   (prin1 debugger-value)
 432   (save-excursion
 433     ;; Check to see if we've flagged some frame for debug-on-exit, in which
 434     ;; case we'll probably come back to the debugger soon.
 435     (goto-char (point-min))
 436     (if (re-search-forward "^\\* " nil t)
 437         (setq debugger-will-be-back t)))
 438   (exit-recursive-edit))
 439
 440 (defun debugger-jump ()
 441   "Continue to exit from this frame, with all debug-on-entry suspended."
 442   (interactive)
 443   (debugger-frame)
 444   (setq debugger-jumping-flag t)
 445   (add-hook 'post-command-hook 'debugger-reenable)
 446   (message "Continuing through this frame")
 447   (setq debugger-will-be-back t)
 448   (exit-recursive-edit))
 449
 450 (defun debugger-reenable ()
 451   "Turn all debug-on-entry functions back on.
 452 This function is put on `post-command-hook' by `debugger-jump' and
 453 removes itself from that hook."
 454   (setq debugger-jumping-flag nil)
 455   (remove-hook 'post-command-hook 'debugger-reenable))
 456
 457 (defun debugger-frame-number ()
 458   "Return number of frames in backtrace before the one point points at."
 459   (save-excursion
 460     (beginning-of-line)
 461     (let ((opoint (point))
 462           (count 0))
 463       (while (not (eq (cadr (backtrace-frame count)) 'debug))
 464         (setq count (1+ count)))
 465       ;; Skip implement-debug-on-entry frame.
 466       (when (eq 'implement-debug-on-entry (cadr (backtrace-frame (1+ count))))
 467         (setq count (1+ count)))
 468       (goto-char (point-min))
 469       (when (looking-at "Debugger entered--\\(Lisp error\\|returning value\\):")
 470         (goto-char (match-end 0))
 471         (forward-sexp 1))
 472       (forward-line 1)
 473       (while (progn
 474                (forward-char 2)
 475                (if (= (following-char) ?\()
 476                    (forward-sexp 1)
 477                  (forward-sexp 2))
 478                (forward-line 1)
 479                (<= (point) opoint))
 480         (if (looking-at " *;;;")
 481             (forward-line 1))
 482         (setq count (1+ count)))
 483       count)))
 484
 485 (defun debugger-frame ()
 486   "Request entry to debugger when this frame exits.
 487 Applies to the frame whose line point is on in the backtrace."
 488   (interactive)
 489   (save-excursion
 490     (beginning-of-line)
 491     (if (looking-at " *;;;\\|[a-z]")
 492         (error "This line is not a function call")))
 493   (beginning-of-line)
 494   (backtrace-debug (debugger-frame-number) t)
 495   (if (= (following-char) ? )
 496       (let ((inhibit-read-only t))
 497         (delete-char 1)
 498         (insert ?*)))
 499   (beginning-of-line))
 500
 501 (defun debugger-frame-clear ()
 502   "Do not enter debugger when this frame exits.
 503 Applies to the frame whose line point is on in the backtrace."
 504   (interactive)
 505   (save-excursion
 506     (beginning-of-line)
 507     (if (looking-at " *;;;\\|[a-z]")
 508         (error "This line is not a function call")))
 509   (beginning-of-line)
 510   (backtrace-debug (debugger-frame-number) nil)
 511   (if (= (following-char) ?*)
 512       (let ((inhibit-read-only t))
 513         (delete-char 1)
 514         (insert ? )))
 515   (beginning-of-line))
 516
 517 (put 'debugger-env-macro 'lisp-indent-function 0)
 518 (defmacro debugger-env-macro (&rest body)
 519   "Run BODY in original environment."
 520   `(save-excursion
 521     (if (null (buffer-name debugger-old-buffer))
 522         ;; old buffer deleted
 523         (setq debugger-old-buffer (current-buffer)))
 524     (set-buffer debugger-old-buffer)
 525     (let ((load-read-function debugger-outer-load-read-function)
 526           (overriding-terminal-local-map
 527            debugger-outer-overriding-terminal-local-map)
 528           (overriding-local-map debugger-outer-overriding-local-map)
 529           (track-mouse debugger-outer-track-mouse)
 530           (last-command debugger-outer-last-command)
 531           (this-command debugger-outer-this-command)
 532           (unread-command-events debugger-outer-unread-command-events)
 533           (unread-post-input-method-events
 534            debugger-outer-unread-post-input-method-events)
 535           (last-input-event debugger-outer-last-input-event)
 536           (last-command-event debugger-outer-last-command-event)
 537           (last-nonmenu-event debugger-outer-last-nonmenu-event)
 538           (last-event-frame debugger-outer-last-event-frame)
 539           (standard-input debugger-outer-standard-input)
 540           (standard-output debugger-outer-standard-output)
 541           (inhibit-redisplay debugger-outer-inhibit-redisplay)
 542           (cursor-in-echo-area debugger-outer-cursor-in-echo-area))
 543       (set-match-data debugger-outer-match-data)
 544       (prog1
 545           (let ((save-ucc (with-no-warnings unread-command-char)))
 546             (unwind-protect
 547                 (progn
 548                   (with-no-warnings
 549                     (setq unread-command-char debugger-outer-unread-command-char))
 550                   (prog1 (progn ,@body)
 551                     (with-no-warnings
 552                       (setq debugger-outer-unread-command-char unread-command-char))))
 553               (with-no-warnings
 554                 (setq unread-command-char save-ucc))))
 555         (setq debugger-outer-match-data (match-data))
 556         (setq debugger-outer-load-read-function load-read-function)
 557         (setq debugger-outer-overriding-terminal-local-map
 558               overriding-terminal-local-map)
 559         (setq debugger-outer-overriding-local-map overriding-local-map)
 560         (setq debugger-outer-track-mouse track-mouse)
 561         (setq debugger-outer-last-command last-command)
 562         (setq debugger-outer-this-command this-command)
 563         (setq debugger-outer-unread-command-events unread-command-events)
 564         (setq debugger-outer-unread-post-input-method-events
 565               unread-post-input-method-events)
 566         (setq debugger-outer-last-input-event last-input-event)
 567         (setq debugger-outer-last-command-event last-command-event)
 568         (setq debugger-outer-last-nonmenu-event last-nonmenu-event)
 569         (setq debugger-outer-last-event-frame last-event-frame)
 570         (setq debugger-outer-standard-input standard-input)
 571         (setq debugger-outer-standard-output standard-output)
 572         (setq debugger-outer-inhibit-redisplay inhibit-redisplay)
 573         (setq debugger-outer-cursor-in-echo-area cursor-in-echo-area)
 574         ))))
 575
 576 (defun debugger-eval-expression (exp)
 577   "Eval an expression, in an environment like that outside the debugger."
 578   (interactive
 579    (list (read-from-minibuffer "Eval: "
 580                                nil read-expression-map t
 581                                'read-expression-history)))
 582   (debugger-env-macro (eval-expression exp)))
 583 \f
 584 (defvar debugger-mode-map
 585   (let ((map (make-keymap))
 586         (menu-map (make-sparse-keymap)))
 587     (set-keymap-parent map button-buffer-map)
 588     (suppress-keymap map)
 589     (define-key map "-" 'negative-argument)
 590     (define-key map "b" 'debugger-frame)
 591     (define-key map "c" 'debugger-continue)
 592     (define-key map "j" 'debugger-jump)
 593     (define-key map "r" 'debugger-return-value)
 594     (define-key map "u" 'debugger-frame-clear)
 595     (define-key map "d" 'debugger-step-through)
 596     (define-key map "l" 'debugger-list-functions)
 597     (define-key map "h" 'describe-mode)
 598     (define-key map "q" 'top-level)
 599     (define-key map "e" 'debugger-eval-expression)
 600     (define-key map " " 'next-line)
 601     (define-key map "R" 'debugger-record-expression)
 602     (define-key map "\C-m" 'debug-help-follow)
 603     (define-key map [mouse-2] 'push-button)
 604     (define-key map [menu-bar debugger] (cons "Debugger" menu-map))
 605     (define-key menu-map [deb-top]
 606       '(menu-item "Quit" top-level
 607                   :help "Quit debugging and return to top level"))
 608     (define-key menu-map [deb-s0] '("--"))
 609     (define-key menu-map [deb-descr]
 610       '(menu-item "Describe Debugger Mode" describe-mode
 611                   :help "Display documentation for debugger-mode"))
 612     (define-key menu-map [deb-hfol]
 613       '(menu-item "Help Follow" debug-help-follow
 614                   :help "Follow cross-reference"))
 615     (define-key menu-map [deb-nxt]
 616       '(menu-item "Next Line" next-line
 617                   :help "Move cursor down"))
 618     (define-key menu-map [deb-s1] '("--"))
 619     (define-key menu-map [deb-lfunc]
 620       '(menu-item "List debug on entry functions" debugger-list-functions
 621                   :help "Display a list of all the functions now set to debug on entry"))
 622     (define-key menu-map [deb-fclear]
 623       '(menu-item "Cancel debug frame" debugger-frame-clear
 624                   :help "Do not enter debugger when this frame exits"))
 625     (define-key menu-map [deb-frame]
 626       '(menu-item "Debug frame" debugger-frame
 627                   :help "Request entry to debugger when this frame exits"))
 628     (define-key menu-map [deb-s2] '("--"))
 629     (define-key menu-map [deb-ret]
 630       '(menu-item "Return value..." debugger-return-value
 631                   :help "Continue, specifying value to return."))
 632     (define-key menu-map [deb-rec]
 633       '(menu-item "Display and Record Expression" debugger-record-expression
 634                   :help "Display a variable's value and record it in `*Backtrace-record*' buffer"))
 635     (define-key menu-map [deb-eval]
 636       '(menu-item "Eval Expression..." debugger-eval-expression
 637                   :help "Eval an expression, in an environment like that outside the debugger"))
 638     (define-key menu-map [deb-jump]
 639       '(menu-item "Jump" debugger-jump
 640                   :help "Continue to exit from this frame, with all debug-on-entry suspended"))
 641     (define-key menu-map [deb-cont]
 642       '(menu-item "Continue" debugger-continue
 643                   :help "Continue, evaluating this expression without stopping"))
 644     (define-key menu-map [deb-step]
 645       '(menu-item "Step through" debugger-step-through
 646                   :help "Proceed, stepping through subexpressions of this expression"))
 647     map))
 648
 649 (put 'debugger-mode 'mode-class 'special)
 650
 651 (defun debugger-mode ()
 652   "Mode for backtrace buffers, selected in debugger.
 653 \\<debugger-mode-map>
 654 A line starts with `*' if exiting that frame will call the debugger.
 655 Type \\[debugger-frame] or \\[debugger-frame-clear] to set or remove the `*'.
 656
 657 When in debugger due to frame being exited,
 658 use the \\[debugger-return-value] command to override the value
 659 being returned from that frame.
 660
 661 Use \\[debug-on-entry] and \\[cancel-debug-on-entry] to control
 662 which functions will enter the debugger when called.
 663
 664 Complete list of commands:
 665 \\{debugger-mode-map}"
 666   (kill-all-local-variables)
 667   (setq major-mode 'debugger-mode)
 668   (setq mode-name "Debugger")
 669   (setq truncate-lines t)
 670   (set-syntax-table emacs-lisp-mode-syntax-table)
 671   (use-local-map debugger-mode-map)
 672   (run-mode-hooks 'debugger-mode-hook))
 673 \f
 674 (defcustom debugger-record-buffer "*Debugger-record*"
 675   "Buffer name for expression values, for \\[debugger-record-expression]."
 676   :type 'string
 677   :group 'debugger
 678   :version "20.3")
 679
 680 (defun debugger-record-expression  (exp)
 681   "Display a variable's value and record it in `*Backtrace-record*' buffer."
 682   (interactive
 683    (list (read-from-minibuffer
 684           "Record Eval: "
 685           nil
 686           read-expression-map t
 687           'read-expression-history)))
 688   (let* ((buffer (get-buffer-create debugger-record-buffer))
 689          (standard-output buffer))
 690     (princ (format "Debugger Eval (%s): " exp))
 691     (princ (debugger-eval-expression exp))
 692     (terpri))
 693
 694   (with-current-buffer (get-buffer debugger-record-buffer)
 695     (message "%s"
 696              (buffer-substring (line-beginning-position 0)
 697                                (line-end-position 0)))))
 698
 699 (declare-function help-xref-interned "help-mode" (symbol))
 700
 701 (defun debug-help-follow (&optional pos)
 702   "Follow cross-reference at POS, defaulting to point.
 703
 704 For the cross-reference format, see `help-make-xrefs'."
 705   (interactive "d")
 706   (require 'help-mode)
 707   ;; Ideally we'd just do (call-interactively 'help-follow) except that this
 708   ;; assumes we're already in a *Help* buffer and reuses it, so it ends up
 709   ;; incorrectly "reusing" the *Backtrace* buffer to show the help info.
 710   (unless pos
 711     (setq pos (point)))
 712   (unless (push-button pos)
 713     ;; check if the symbol under point is a function or variable
 714     (let ((sym
 715            (intern
 716             (save-excursion
 717               (goto-char pos) (skip-syntax-backward "w_")
 718               (buffer-substring (point)
 719                                 (progn (skip-syntax-forward "w_")
 720                                        (point)))))))
 721       (when (or (boundp sym) (fboundp sym) (facep sym))
 722         (help-xref-interned sym)))))
 723 \f
 724 ;; When you change this, you may also need to change the number of
 725 ;; frames that the debugger skips.
 726 (defun implement-debug-on-entry ()
 727   "Conditionally call the debugger.
 728 A call to this function is inserted by `debug-on-entry' to cause
 729 functions to break on entry."
 730   (if (or inhibit-debug-on-entry debugger-jumping-flag)
 731       nil
 732     (funcall debugger 'debug)))
 733
 734 (defun debugger-special-form-p (symbol)
 735   "Return whether SYMBOL is a special form."
 736   (and (fboundp symbol)
 737        (subrp (symbol-function symbol))
 738        (eq (cdr (subr-arity (symbol-function symbol))) 'unevalled)))
 739
 740 ;;;###autoload
 741 (defun debug-on-entry (function)
 742   "Request FUNCTION to invoke debugger each time it is called.
 743
 744 When called interactively, prompt for FUNCTION in the minibuffer.
 745
 746 This works by modifying the definition of FUNCTION.  If you tell the
 747 debugger to continue, FUNCTION's execution proceeds.  If FUNCTION is a
 748 normal function or a macro written in Lisp, you can also step through
 749 its execution.  FUNCTION can also be a primitive that is not a special
 750 form, in which case stepping is not possible.  Break-on-entry for
 751 primitive functions only works when that function is called from Lisp.
 752
 753 Use \\[cancel-debug-on-entry] to cancel the effect of this command.
 754 Redefining FUNCTION also cancels it."
 755   (interactive
 756    (let ((fn (function-called-at-point)) val)
 757      (when (debugger-special-form-p fn)
 758        (setq fn nil))
 759      (setq val (completing-read
 760                 (if fn
 761                     (format "Debug on entry to function (default %s): " fn)
 762                   "Debug on entry to function: ")
 763                 obarray
 764                 #'(lambda (symbol)
 765                     (and (fboundp symbol)
 766                          (not (debugger-special-form-p symbol))))
 767                 t nil nil (symbol-name fn)))
 768      (list (if (equal val "") fn (intern val)))))
 769   (when (debugger-special-form-p function)
 770     (error "Function %s is a special form" function))
 771   (if (or (symbolp (symbol-function function))
 772           (subrp (symbol-function function)))
 773       ;; The function is built-in or aliased to another function.
 774       ;; Create a wrapper in which we can add the debug call.
 775       (fset function `(lambda (&rest debug-on-entry-args)
 776                         ,(interactive-form (symbol-function function))
 777                         (apply ',(symbol-function function)
 778                                debug-on-entry-args)))
 779     (when (eq (car-safe (symbol-function function)) 'autoload)
 780       ;; The function is autoloaded.  Load its real definition.
 781       (load (cadr (symbol-function function)) nil noninteractive nil t))
 782     (when (or (not (consp (symbol-function function)))
 783               (and (eq (car (symbol-function function)) 'macro)
 784                    (not (consp (cdr (symbol-function function))))))
 785       ;; The function is byte-compiled.  Create a wrapper in which
 786       ;; we can add the debug call.
 787       (debug-convert-byte-code function)))
 788   (unless (consp (symbol-function function))
 789     (error "Definition of %s is not a list" function))
 790   (fset function (debug-on-entry-1 function t))
 791   (unless (memq function debug-function-list)
 792     (push function debug-function-list))
 793   function)
 794
 795 ;;;###autoload
 796 (defun cancel-debug-on-entry (&optional function)
 797   "Undo effect of \\[debug-on-entry] on FUNCTION.
 798 If FUNCTION is nil, cancel debug-on-entry for all functions.
 799 When called interactively, prompt for FUNCTION in the minibuffer.
 800 To specify a nil argument interactively, exit with an empty minibuffer."
 801   (interactive
 802    (list (let ((name
 803                 (completing-read
 804                  "Cancel debug on entry to function (default all functions): "
 805                  (mapcar 'symbol-name debug-function-list) nil t)))
 806            (when name
 807              (unless (string= name "")
 808                (intern name))))))
 809   (if (and function
 810            (not (string= function ""))) ; Pre 22.1 compatibility test.
 811       (progn
 812         (let ((defn (debug-on-entry-1 function nil)))
 813           (condition-case nil
 814               (when (and (equal (nth 1 defn) '(&rest debug-on-entry-args))
 815                          (eq (car (nth 3 defn)) 'apply))
 816                 ;; `defn' is a wrapper introduced in debug-on-entry.
 817                 ;; Get rid of it since we don't need it any more.
 818                 (setq defn (nth 1 (nth 1 (nth 3 defn)))))
 819             (error nil))
 820           (fset function defn))
 821         (setq debug-function-list (delq function debug-function-list))
 822         function)
 823     (message "Cancelling debug-on-entry for all functions")
 824     (mapcar 'cancel-debug-on-entry debug-function-list)))
 825
 826 (defun debug-convert-byte-code (function)
 827   (let* ((defn (symbol-function function))
 828          (macro (eq (car-safe defn) 'macro)))
 829     (when macro (setq defn (cdr defn)))
 830     (unless (consp defn)
 831       ;; Assume a compiled code object.
 832       (let* ((contents (append defn nil))
 833              (body
 834               (list (list 'byte-code (nth 1 contents)
 835                           (nth 2 contents) (nth 3 contents)))))
 836         (if (nthcdr 5 contents)
 837             (setq body (cons (list 'interactive (nth 5 contents)) body)))
 838         (if (nth 4 contents)
 839             ;; Use `documentation' here, to get the actual string,
 840             ;; in case the compiled function has a reference
 841             ;; to the .elc file.
 842             (setq body (cons (documentation function) body)))
 843         (setq defn (cons 'lambda (cons (car contents) body))))
 844       (when macro (setq defn (cons 'macro defn)))
 845       (fset function defn))))
 846
 847 (defun debug-on-entry-1 (function flag)
 848   (let* ((defn (symbol-function function))
 849          (tail defn))
 850     (when (eq (car-safe tail) 'macro)
 851       (setq tail (cdr tail)))
 852     (if (not (eq (car-safe tail) 'lambda))
 853         ;; Only signal an error when we try to set debug-on-entry.
 854         ;; When we try to clear debug-on-entry, we are now done.
 855         (when flag
 856           (error "%s is not a user-defined Lisp function" function))
 857       (setq tail (cdr tail))
 858       ;; Skip the docstring.
 859       (when (and (stringp (cadr tail)) (cddr tail))
 860         (setq tail (cdr tail)))
 861       ;; Skip the interactive form.
 862       (when (eq 'interactive (car-safe (cadr tail)))
 863         (setq tail (cdr tail)))
 864       (unless (eq flag (equal (cadr tail) '(implement-debug-on-entry)))
 865         ;; Add/remove debug statement as needed.
 866         (if flag
 867             (setcdr tail (cons '(implement-debug-on-entry) (cdr tail)))
 868           (setcdr tail (cddr tail)))))
 869     defn))
 870
 871 (defun debugger-list-functions ()
 872   "Display a list of all the functions now set to debug on entry."
 873   (interactive)
 874   (require 'help-mode)
 875   (help-setup-xref '(debugger-list-functions)
 876                    (called-interactively-p 'interactive))
 877   (with-output-to-temp-buffer (help-buffer)
 878     (with-current-buffer standard-output
 879       (if (null debug-function-list)
 880           (princ "No debug-on-entry functions now\n")
 881         (princ "Functions set to debug on entry:\n\n")
 882         (dolist (fun debug-function-list)
 883           (make-text-button (point) (progn (prin1 fun) (point))
 884                             'type 'help-function
 885                             'help-args (list fun))
 886           (terpri))
 887         (terpri)
 888         (princ "Note: if you have redefined a function, then it may no longer\n")
 889         (princ "be set to debug on entry, even if it is in the list.")))))
 890
 891 (provide 'debug)
 892
 893 ;; arch-tag: b6ec7047-f801-4103-9c63-d69322db9d3b
 894 ;;; debug.el ends here