lisp/gnus/nnmh.el

   1 ;;; nnmh.el --- mhspool access for Gnus
   2
   3 ;; Copyright (C) 1995-2018 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   7 ;; Keywords: news, mail
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Based on nnspool.el by Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>.
  27 ;; For an overview of what the interface functions do, please see the
  28 ;; Gnus sources.
  29
  30 ;;; Code:
  31
  32 (require 'nnheader)
  33 (require 'nnmail)
  34 (require 'gnus-start)
  35 (require 'nnoo)
  36
  37 (nnoo-declare nnmh)
  38
  39 (defvoo nnmh-directory message-directory
  40   "Mail spool directory.")
  41
  42 (defvoo nnmh-get-new-mail t
  43   "If non-nil, nnmh will check the incoming mail file and split the mail.")
  44
  45 (defvoo nnmh-prepare-save-mail-hook nil
  46   "Hook run narrowed to an article before saving.")
  47
  48 (defvoo nnmh-be-safe nil
  49   "If non-nil, nnmh will check all articles to make sure whether they are new or not.
  50 Go through the .nnmh-articles file and compare with the actual
  51 articles in this folder.  The articles that are \"new\" will be marked
  52 as unread by Gnus.")
  53
  54 \f
  55
  56 (defconst nnmh-version "nnmh 1.0"
  57   "nnmh version.")
  58
  59 (defvoo nnmh-current-directory nil
  60   "Current news group directory.")
  61
  62 (defvoo nnmh-status-string "")
  63 (defvoo nnmh-group-alist nil)
  64 ;; Don't even think about setting this variable.  It does not exist.
  65 ;; Forget about it.  Uh-huh.  Nope.  Nobody here.  It's only bound
  66 ;; dynamically by certain functions in nndraft.
  67 (defvar nnmh-allow-delete-final nil)
  68
  69 \f
  70
  71 ;;; Interface functions.
  72
  73 (nnoo-define-basics nnmh)
  74
  75 (deffoo nnmh-retrieve-headers (articles &optional newsgroup server fetch-old)
  76   (with-current-buffer nntp-server-buffer
  77     (erase-buffer)
  78     (let* ((file nil)
  79            (number (length articles))
  80            (large (and (numberp nnmail-large-newsgroup)
  81                        (> number nnmail-large-newsgroup)))
  82            (count 0)
  83            (file-name-coding-system nnmail-pathname-coding-system)
  84            beg article)
  85       (nnmh-possibly-change-directory newsgroup server)
  86       ;; We don't support fetching by Message-ID.
  87       (if (stringp (car articles))
  88           'headers
  89         (while articles
  90           (when (and (file-exists-p
  91                       (setq file (concat (file-name-as-directory
  92                                           nnmh-current-directory)
  93                                          (int-to-string
  94                                           (setq article (pop articles))))))
  95                      (not (file-directory-p file)))
  96             (insert (format "221 %d Article retrieved.\n" article))
  97             (setq beg (point))
  98             (nnheader-insert-head file)
  99             (goto-char beg)
 100             (if (search-forward "\n\n" nil t)
 101                 (forward-char -1)
 102               (goto-char (point-max))
 103               (insert "\n\n"))
 104             (insert ".\n")
 105             (delete-region (point) (point-max)))
 106           (setq count (1+ count))
 107
 108           (and large
 109                (zerop (% count 20))
 110                (nnheader-message 5 "nnmh: Receiving headers... %d%%"
 111                                  (floor (* count 100.0) number))))
 112
 113         (when large
 114           (nnheader-message 5 "nnmh: Receiving headers...done"))
 115
 116         (nnheader-fold-continuation-lines)
 117         'headers))))
 118
 119 (deffoo nnmh-open-server (server &optional defs)
 120   (nnoo-change-server 'nnmh server defs)
 121   (when (not (file-exists-p nnmh-directory))
 122     (condition-case ()
 123         (make-directory nnmh-directory t)
 124       (error t)))
 125   (cond
 126    ((not (file-exists-p nnmh-directory))
 127     (nnmh-close-server)
 128     (nnheader-report 'nnmh "Couldn't create directory: %s" nnmh-directory))
 129    ((not (file-directory-p (file-truename nnmh-directory)))
 130     (nnmh-close-server)
 131     (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory))
 132    (t
 133     (nnheader-report 'nnmh "Opened server %s using directory %s"
 134                      server nnmh-directory)
 135     t)))
 136
 137 (deffoo nnmh-request-article (id &optional newsgroup server buffer)
 138   (nnmh-possibly-change-directory newsgroup server)
 139   (let ((file (if (stringp id)
 140                   nil
 141                 (concat nnmh-current-directory (int-to-string id))))
 142         (file-name-coding-system nnmail-pathname-coding-system)
 143         (nntp-server-buffer (or buffer nntp-server-buffer)))
 144     (and (stringp file)
 145          (file-exists-p file)
 146          (not (file-directory-p file))
 147          (save-excursion (nnmail-find-file file))
 148          (string-to-number (file-name-nondirectory file)))))
 149
 150 (deffoo nnmh-request-group (group &optional server dont-check info)
 151   (nnheader-init-server-buffer)
 152   (nnmh-possibly-change-directory group server)
 153   (let ((pathname (nnmail-group-pathname group nnmh-directory))
 154         (file-name-coding-system nnmail-pathname-coding-system)
 155         dir)
 156     (cond
 157      ((not (file-directory-p pathname))
 158       (nnheader-report
 159        'nnmh "Can't select group (no such directory): %s" group))
 160      (t
 161       (setq nnmh-current-directory pathname)
 162       (and nnmh-get-new-mail
 163            nnmh-be-safe
 164            (nnmh-update-gnus-unreads group))
 165       (cond
 166        (dont-check
 167         (nnheader-report 'nnmh "Selected group %s" group)
 168         t)
 169        (t
 170         ;; Re-scan the directory if it's on a foreign system.
 171         (nnheader-re-read-dir pathname)
 172         (setq dir
 173               (sort
 174                (mapcar 'string-to-number
 175                        (directory-files pathname nil "^[0-9]+$" t))
 176                '<))
 177         (cond
 178          (dir
 179           (setq nnmh-group-alist
 180                 (delq (assoc group nnmh-group-alist) nnmh-group-alist))
 181           (push (list group (cons (car dir) (car (last dir))))
 182                 nnmh-group-alist)
 183           (nnheader-report 'nnmh "Selected group %s" group)
 184           (nnheader-insert
 185            "211 %d %d %d %s\n" (length dir) (car dir)
 186            (car (last dir)) group))
 187          (t
 188           (nnheader-report 'nnmh "Empty group %s" group)
 189           (nnheader-insert (format "211 0 1 0 %s\n" group))))))))))
 190
 191 (deffoo nnmh-request-scan (&optional group server)
 192   (nnmail-get-new-mail 'nnmh nil nnmh-directory group))
 193
 194 (deffoo nnmh-request-list (&optional server dir)
 195   (nnheader-insert "")
 196   (nnmh-possibly-change-directory nil server)
 197   (let ((file-name-coding-system nnmail-pathname-coding-system)
 198         (nnmh-toplev
 199          (file-truename (or dir (file-name-as-directory nnmh-directory)))))
 200     (nnmh-request-list-1 nnmh-toplev))
 201   (setq nnmh-group-alist (nnmail-get-active))
 202   t)
 203
 204 (defvar nnmh-toplev)
 205 (defun nnmh-request-list-1 (dir)
 206   (setq dir (expand-file-name dir))
 207   ;; Recurse down all directories.
 208   (let ((files (nnheader-directory-files dir t nil t))
 209         (max 0)
 210         min rdir num subdirectoriesp file)
 211     ;; Recurse down directories.
 212     (setq subdirectoriesp
 213           ;; link number always 1 on MS Windows :(
 214           (/= (file-attribute-link-number
 215                (file-attributes (file-truename dir)))
 216               2))
 217     (dolist (rdir files)
 218       (if (or (not subdirectoriesp)
 219               (file-regular-p rdir))
 220           (progn
 221             (setq file (file-name-nondirectory rdir))
 222             (when (string-match "^[0-9]+$" file)
 223               (setq num (string-to-number file))
 224               (setq max (max max num))
 225               (when (or (null min)
 226                         (< num min))
 227                 (setq min num))))
 228         ;; This is a directory.
 229         (when (and (file-readable-p rdir)
 230                    (not (equal (file-truename rdir)
 231                                (file-truename dir))))
 232           (nnmh-request-list-1 rdir))))
 233     ;; For each directory, generate an active file line.
 234     (unless (string= (expand-file-name nnmh-toplev) dir)
 235       (with-current-buffer nntp-server-buffer
 236         (goto-char (point-max))
 237         (insert
 238          (format
 239           "%s %.0f %.0f y\n"
 240           (progn
 241             (string-match
 242              (regexp-quote
 243               (file-truename (file-name-as-directory
 244                               (expand-file-name nnmh-toplev))))
 245              dir)
 246             (encode-coding-string
 247              (nnheader-replace-chars-in-string
 248               (substring dir (match-end 0))
 249               ?/ ?.)
 250              nnmail-pathname-coding-system))
 251           (or max 0)
 252           (or min 1))))))
 253   t)
 254
 255 (deffoo nnmh-request-newgroups (date &optional server)
 256   (nnmh-request-list server))
 257
 258 (deffoo nnmh-request-expire-articles (articles newsgroup
 259                                                &optional server force)
 260   (nnmh-possibly-change-directory newsgroup server)
 261   (let ((is-old t)
 262         (dir nnmh-current-directory)
 263         article rest mod-time)
 264     (nnheader-init-server-buffer)
 265
 266     (while (and articles is-old)
 267       (setq article (concat dir (int-to-string (car articles))))
 268       (when (setq mod-time (file-attribute-modification-time
 269                             (file-attributes article)))
 270         (if (and (nnmh-deletable-article-p newsgroup (car articles))
 271                  (setq is-old
 272                        (nnmail-expired-article-p newsgroup mod-time force)))
 273             (progn
 274               ;; Allow a special target group. -- jcn
 275               (unless (eq nnmail-expiry-target 'delete)
 276                 (with-temp-buffer
 277                   (nnmh-request-article (car articles)
 278                                         newsgroup server (current-buffer))
 279                   (nnmail-expiry-target-group
 280                    nnmail-expiry-target newsgroup)))
 281               (nnheader-message 5 "Deleting article %s in %s..."
 282                                 article newsgroup)
 283               (condition-case ()
 284                   (funcall nnmail-delete-file-function article)
 285                 (file-error
 286                  (nnheader-message 1 "Couldn't delete article %s in %s"
 287                                    article newsgroup)
 288                  (push (car articles) rest))))
 289           (push (car articles) rest)))
 290       (setq articles (cdr articles)))
 291     (nnheader-message 5 "")
 292     (nconc rest articles)))
 293
 294 (deffoo nnmh-close-group (group &optional server)
 295   t)
 296
 297 (deffoo nnmh-request-move-article (article group server accept-form
 298                                            &optional last move-is-internal)
 299   (let ((buf (get-buffer-create " *nnmh move*"))
 300         result)
 301     (and
 302      (nnmh-deletable-article-p group article)
 303      (nnmh-request-article article group server)
 304      (with-current-buffer buf
 305        (erase-buffer)
 306        (insert-buffer-substring nntp-server-buffer)
 307        (setq result (eval accept-form))
 308        (kill-buffer (current-buffer))
 309        result)
 310      (progn
 311        (nnmh-possibly-change-directory group server)
 312        (condition-case ()
 313            (funcall nnmail-delete-file-function
 314                     (concat nnmh-current-directory (int-to-string article)))
 315          (file-error nil))))
 316     result))
 317
 318 (deffoo nnmh-request-accept-article (group &optional server last noinsert)
 319   (nnmh-possibly-change-directory group server)
 320   (nnmail-check-syntax)
 321   (when nnmail-cache-accepted-message-ids
 322     (nnmail-cache-insert (nnmail-fetch-field "message-id")
 323                          group
 324                          (nnmail-fetch-field "subject")
 325                          (nnmail-fetch-field "from")))
 326   (nnheader-init-server-buffer)
 327   (prog1
 328       (if (stringp group)
 329           (if noinsert
 330               (nnmh-active-number group)
 331             (car (nnmh-save-mail
 332                   (list (cons group (nnmh-active-number group)))
 333                   noinsert)))
 334         (let ((res (nnmail-article-group 'nnmh-active-number)))
 335           (if (and (null res)
 336                    (yes-or-no-p "Moved to `junk' group; delete article? "))
 337               'junk
 338             (car (nnmh-save-mail res noinsert)))))
 339     (when (and last nnmail-cache-accepted-message-ids)
 340       (nnmail-cache-close))))
 341
 342 (deffoo nnmh-request-replace-article (article group buffer)
 343   (nnmh-possibly-change-directory group)
 344   (with-current-buffer buffer
 345     (nnmh-possibly-create-directory group)
 346     (ignore-errors
 347       (nnmail-write-region
 348        (point-min) (point-max)
 349        (concat nnmh-current-directory (int-to-string article))
 350        nil (if (nnheader-be-verbose 5) nil 'nomesg))
 351       t)))
 352
 353 (deffoo nnmh-request-create-group (group &optional server args)
 354   (nnheader-init-server-buffer)
 355   (unless (assoc group nnmh-group-alist)
 356     (let (active)
 357       (push (list group (setq active (cons 1 0)))
 358             nnmh-group-alist)
 359       (nnmh-possibly-create-directory group)
 360       (nnmh-possibly-change-directory group server)
 361       (let ((articles (mapcar 'string-to-number
 362                               (directory-files
 363                                nnmh-current-directory nil "^[0-9]+$"))))
 364         (when articles
 365           (setcar active (apply 'min articles))
 366           (setcdr active (apply 'max articles))))))
 367   t)
 368
 369 (deffoo nnmh-request-delete-group (group &optional force server)
 370   (nnmh-possibly-change-directory group server)
 371   ;; Delete all articles in GROUP.
 372   (if (not force)
 373       ()                                ; Don't delete the articles.
 374     (let ((articles (directory-files nnmh-current-directory t "^[0-9]+$")))
 375       (while articles
 376         (when (file-writable-p (car articles))
 377           (nnheader-message 5 "Deleting article %s in %s..."
 378                             (car articles) group)
 379           (funcall nnmail-delete-file-function (car articles)))
 380         (setq articles (cdr articles))))
 381     ;; Try to delete the directory itself.
 382     (ignore-errors
 383       (delete-directory nnmh-current-directory)))
 384   ;; Remove the group from all structures.
 385   (setq nnmh-group-alist
 386         (delq (assoc group nnmh-group-alist) nnmh-group-alist)
 387         nnmh-current-directory nil)
 388   t)
 389
 390 (deffoo nnmh-request-rename-group (group new-name &optional server)
 391   (nnmh-possibly-change-directory group server)
 392   (let ((new-dir (nnmail-group-pathname new-name nnmh-directory))
 393         (old-dir (nnmail-group-pathname group nnmh-directory)))
 394     (when (ignore-errors
 395             (make-directory new-dir t)
 396             t)
 397       ;; We move the articles file by file instead of renaming
 398       ;; the directory -- there may be subgroups in this group.
 399       ;; One might be more clever, I guess.
 400       (let ((files (nnheader-article-to-file-alist old-dir)))
 401         (while files
 402           (rename-file
 403            (concat old-dir (cdar files))
 404            (concat new-dir (cdar files)))
 405           (pop files)))
 406       (when (<= (length (directory-files old-dir)) 2)
 407         (ignore-errors
 408           (delete-directory old-dir)))
 409       ;; That went ok, so we change the internal structures.
 410       (let ((entry (assoc group nnmh-group-alist)))
 411         (when entry
 412           (setcar entry new-name))
 413         (setq nnmh-current-directory nil)
 414         t))))
 415
 416 (nnoo-define-skeleton nnmh)
 417
 418 \f
 419 ;;; Internal functions.
 420
 421 (defun nnmh-possibly-change-directory (newsgroup &optional server)
 422   (when (and server
 423              (not (nnmh-server-opened server)))
 424     (nnmh-open-server server))
 425   (when newsgroup
 426     (let ((pathname (nnmail-group-pathname newsgroup nnmh-directory))
 427           (file-name-coding-system nnmail-pathname-coding-system))
 428       (if (file-directory-p pathname)
 429           (setq nnmh-current-directory pathname)
 430         (nnheader-report 'nnmh "Not a directory: %s" nnmh-directory)))))
 431
 432 (defun nnmh-possibly-create-directory (group)
 433   (let (dir dirs)
 434     (setq dir (nnmail-group-pathname group nnmh-directory))
 435     (while (not (file-directory-p dir))
 436       (push dir dirs)
 437       (setq dir (file-name-directory (directory-file-name dir))))
 438     (while dirs
 439       (when (make-directory (directory-file-name (car dirs)))
 440         (error "Could not create directory %s" (car dirs)))
 441       (nnheader-message 5 "Creating mail directory %s" (car dirs))
 442       (setq dirs (cdr dirs)))))
 443
 444 (defun nnmh-save-mail (group-art &optional noinsert)
 445   "Called narrowed to an article."
 446   (unless noinsert
 447     (nnmail-insert-lines)
 448     (nnmail-insert-xref group-art))
 449   (run-hooks 'nnmail-prepare-save-mail-hook)
 450   (run-hooks 'nnmh-prepare-save-mail-hook)
 451   (goto-char (point-min))
 452   (while (looking-at "From ")
 453     (replace-match "X-From-Line: ")
 454     (forward-line 1))
 455   ;; We save the article in all the newsgroups it belongs in.
 456   (let ((ga group-art)
 457         first)
 458     (while ga
 459       (nnmh-possibly-create-directory (caar ga))
 460       (let ((file (concat (nnmail-group-pathname
 461                            (caar ga) nnmh-directory)
 462                           (int-to-string (cdar ga)))))
 463         (if first
 464             ;; It was already saved, so we just make a hard link.
 465             (funcall nnmail-crosspost-link-function first file t)
 466           ;; Save the article.
 467           (nnmail-write-region (point-min) (point-max) file nil nil)
 468           (setq first file)))
 469       (setq ga (cdr ga))))
 470   group-art)
 471
 472 (defun nnmh-active-number (group)
 473   "Compute the next article number in GROUP."
 474   (let ((active (cadr (assoc group nnmh-group-alist)))
 475         (dir (nnmail-group-pathname group nnmh-directory))
 476         (file-name-coding-system nnmail-pathname-coding-system)
 477         file)
 478     (unless active
 479       ;; The group wasn't known to nnmh, so we just create an active
 480       ;; entry for it.
 481       (setq active (cons 1 0))
 482       (push (list group active) nnmh-group-alist)
 483       (unless (file-exists-p dir)
 484         (gnus-make-directory dir))
 485       ;; Find the highest number in the group.
 486       (let ((files (sort
 487                     (mapcar 'string-to-number
 488                             (directory-files dir nil "^[0-9]+$"))
 489                     '>)))
 490         (when files
 491           (setcdr active (car files)))))
 492     (setcdr active (1+ (cdr active)))
 493     (while (or
 494             ;; See whether the file exists...
 495             (file-exists-p
 496              (setq file (concat (nnmail-group-pathname group nnmh-directory)
 497                                 (int-to-string (cdr active)))))
 498             ;; ... or there is a buffer that will make that file exist
 499             ;; in the future.
 500             (get-file-buffer file))
 501       ;; Skip past that file.
 502       (setcdr active (1+ (cdr active))))
 503     (cdr active)))
 504
 505 (defun nnmh-update-gnus-unreads (group)
 506   ;; Go through the .nnmh-articles file and compare with the actual
 507   ;; articles in this folder.  The articles that are "new" will be
 508   ;; marked as unread by Gnus.
 509   (let* ((dir nnmh-current-directory)
 510          (files (sort (mapcar 'string-to-number
 511                               (directory-files nnmh-current-directory
 512                                                nil "^[0-9]+$" t))
 513                       '<))
 514          (nnmh-file (concat dir ".nnmh-articles"))
 515          new articles)
 516     ;; Load the .nnmh-articles file.
 517     (when (file-exists-p nnmh-file)
 518       (setq articles
 519             (let (nnmh-newsgroup-articles)
 520               (ignore-errors (load nnmh-file nil t t))
 521               nnmh-newsgroup-articles)))
 522     ;; Add all new articles to the `new' list.
 523     (let ((art files))
 524       (while art
 525         (unless (assq (car art) articles)
 526           (push (car art) new))
 527         (setq art (cdr art))))
 528     ;; Remove all deleted articles.
 529     (let ((art articles))
 530       (while art
 531         (unless (memq (caar art) files)
 532           (setq articles (delq (car art) articles)))
 533         (setq art (cdr art))))
 534     ;; Check whether the articles really are the ones that Gnus thinks
 535     ;; they are by looking at the time-stamps.
 536     (let ((arts articles)
 537           art)
 538       (while (setq art (pop arts))
 539         (when (not (equal
 540                     (file-attribute-modification-time
 541                      (file-attributes (concat dir (int-to-string (car art)))))
 542                     (cdr art)))
 543           (setq articles (delq art articles))
 544           (push (car art) new))))
 545     ;; Go through all the new articles and add them, and their
 546     ;; time-stamps, to the list.
 547     (setq articles
 548           (nconc articles
 549                  (mapcar
 550                   (lambda (art)
 551                     (cons art
 552                           (file-attribute-modification-time
 553                            (file-attributes
 554                             (concat dir (int-to-string art))))))
 555                   new)))
 556     ;; Make Gnus mark all new articles as unread.
 557     (when new
 558       (gnus-make-articles-unread
 559        (gnus-group-prefixed-name group (list 'nnmh ""))
 560        (setq new (sort new '<))))
 561     ;; Sort the article list with highest numbers first.
 562     (setq articles (sort articles (lambda (art1 art2)
 563                                     (> (car art1) (car art2)))))
 564     ;; Finally write this list back to the .nnmh-articles file.
 565     (with-temp-file nnmh-file
 566       (insert ";; Gnus article active file for " group "\n\n")
 567       (insert "(setq nnmh-newsgroup-articles '")
 568       (gnus-prin1 articles)
 569       (insert ")\n"))))
 570
 571 (defun nnmh-deletable-article-p (group article)
 572   "Say whether ARTICLE in GROUP can be deleted."
 573   (let ((path (concat nnmh-current-directory (int-to-string article))))
 574     ;; Writable.
 575     (and (file-writable-p path)
 576          (or
 577           ;; We can never delete the last article in the group.
 578           (not (eq (cdr (nth 1 (assoc group nnmh-group-alist)))
 579                    article))
 580           ;; Well, we can.
 581           nnmh-allow-delete-final))))
 582
 583 (provide 'nnmh)
 584
 585 ;;; nnmh.el ends here