lisp/gnus/nneething.el

   1 ;;; nneething.el --- arbitrary file access for Gnus
   2
   3 ;; Copyright (C) 1995-2018 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;;      Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   7 ;; Keywords: news, mail
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile (require 'cl-lib))
  29
  30 (require 'mailcap)
  31 (require 'nnheader)
  32 (require 'nnmail)
  33 (require 'nnoo)
  34 (require 'gnus-util)
  35
  36 (nnoo-declare nneething)
  37
  38 (defvoo nneething-map-file-directory
  39   (nnheader-concat gnus-directory ".nneething/")
  40   "Where nneething stores the map files.")
  41
  42 (defvoo nneething-map-file ".nneething"
  43   "Name of the map files.")
  44
  45 (defvoo nneething-exclude-files nil
  46   "Regexp saying what files to exclude from the group.
  47 If this variable is nil, no files will be excluded.")
  48
  49 (defvoo nneething-include-files nil
  50   "Regexp saying what files to include in the group.
  51 If this variable is non-nil, only files matching this regexp will be
  52 included.")
  53
  54 \f
  55
  56 ;;; Internal variables.
  57
  58 (defconst nneething-version "nneething 1.0"
  59   "nneething version.")
  60
  61 (defvoo nneething-current-directory nil
  62   "Current news group directory.")
  63
  64 (defvoo nneething-status-string "")
  65
  66 (defvoo nneething-work-buffer " *nneething work*")
  67
  68 (defvoo nneething-group nil)
  69 (defvoo nneething-map nil)
  70 (defvoo nneething-read-only nil)
  71 (defvoo nneething-active nil)
  72 (defvoo nneething-address nil)
  73
  74 \f
  75
  76 ;;; Interface functions.
  77
  78 (nnoo-define-basics nneething)
  79
  80 (deffoo nneething-retrieve-headers (articles &optional group server fetch-old)
  81   (nneething-possibly-change-directory group)
  82
  83   (with-current-buffer nntp-server-buffer
  84     (erase-buffer)
  85     (let* ((number (length articles))
  86            (count 0)
  87            (large (and (numberp nnmail-large-newsgroup)
  88                        (> number nnmail-large-newsgroup)))
  89            article file)
  90
  91       (if (stringp (car articles))
  92           'headers
  93
  94         (while (setq article (pop articles))
  95           (setq file (nneething-file-name article))
  96
  97           (when (and (file-exists-p file)
  98                      (or (file-directory-p file)
  99                          (not (zerop (nnheader-file-size file)))))
 100             (insert (format "221 %d Article retrieved.\n" article))
 101             (nneething-insert-head file)
 102             (insert ".\n"))
 103
 104           (cl-incf count)
 105
 106           (and large
 107                (zerop (% count 20))
 108                (nnheader-message 5 "nneething: Receiving headers... %d%%"
 109                                  (floor (* count 100.0) number))))
 110
 111         (when large
 112           (nnheader-message 5 "nneething: Receiving headers...done"))
 113
 114         (nnheader-fold-continuation-lines)
 115         'headers))))
 116
 117 (deffoo nneething-request-article (id &optional group server buffer)
 118   (nneething-possibly-change-directory group)
 119   (let ((file (unless (stringp id)
 120                 (nneething-file-name id)))
 121         (nntp-server-buffer (or buffer nntp-server-buffer)))
 122     (and (stringp file)            ; We did not request by Message-ID.
 123          (file-exists-p file)           ; The file exists.
 124          (not (file-directory-p file))  ; It's not a dir.
 125          (save-excursion
 126            (let ((nnmail-file-coding-system 'binary))
 127              (nnmail-find-file file))   ; Insert the file in the nntp buf.
 128            (unless (nnheader-article-p) ; Either it's a real article...
 129              (let ((type
 130                     (unless (file-directory-p file)
 131                       (or (cdr (assoc (concat "." (file-name-extension file))
 132                                       mailcap-mime-extensions))
 133                           "text/plain")))
 134                    (charset
 135                     (mm-detect-mime-charset-region (point-min) (point-max)))
 136                    (encoding))
 137                (unless (string-match "\\`text/" type)
 138                  (base64-encode-region (point-min) (point-max))
 139                  (setq encoding "base64"))
 140                (goto-char (point-min))
 141                (nneething-make-head file (current-buffer)
 142                                     nil type charset encoding))
 143              (insert "\n"))
 144            t))))
 145
 146 (deffoo nneething-request-group (group &optional server dont-check info)
 147   (nneething-possibly-change-directory group server)
 148   (unless dont-check
 149     (nneething-create-mapping)
 150     (if (> (car nneething-active) (cdr nneething-active))
 151         (nnheader-insert "211 0 1 0 %s\n" group)
 152       (nnheader-insert
 153        "211 %d %d %d %s\n"
 154        (- (1+ (cdr nneething-active)) (car nneething-active))
 155        (car nneething-active) (cdr nneething-active)
 156        group)))
 157   t)
 158
 159 (deffoo nneething-request-list (&optional server dir)
 160   (nnheader-report 'nneething "LIST is not implemented."))
 161
 162 (deffoo nneething-request-newgroups (date &optional server)
 163   (nnheader-report 'nneething "NEWSGROUPS is not implemented."))
 164
 165 (deffoo nneething-request-type (group &optional article)
 166   'unknown)
 167
 168 (deffoo nneething-close-group (group &optional server)
 169   (setq nneething-current-directory nil)
 170   t)
 171
 172 (deffoo nneething-open-server (server &optional defs)
 173   (nnheader-init-server-buffer)
 174   (if (nneething-server-opened server)
 175       t
 176     (unless (assq 'nneething-address defs)
 177       (setq defs (append defs (list (list 'nneething-address server)))))
 178     (nnoo-change-server 'nneething server defs)))
 179
 180 \f
 181 ;;; Internal functions.
 182
 183 (defun nneething-possibly-change-directory (group &optional server)
 184   (when (and server
 185              (not (nneething-server-opened server)))
 186     (nneething-open-server server))
 187   (when (and group
 188              (not (equal nneething-group group)))
 189     (setq nneething-group group)
 190     (setq nneething-map nil)
 191     (setq nneething-active (cons 1 0))
 192     (nneething-create-mapping)))
 193
 194 (defun nneething-map-file ()
 195   ;; We make sure that the .nneething directory exists.
 196   (gnus-make-directory nneething-map-file-directory)
 197   ;; We store it in a special directory under the user's home dir.
 198   (concat (file-name-as-directory nneething-map-file-directory)
 199           nneething-group nneething-map-file))
 200
 201 (defun nneething-create-mapping ()
 202   ;; Read nneething-active and nneething-map.
 203   (when (file-exists-p nneething-address)
 204     (let ((map-file (nneething-map-file))
 205           (files (directory-files nneething-address))
 206           touched map-files)
 207       (when (file-exists-p map-file)
 208         (ignore-errors
 209           (load map-file nil t t)))
 210       (unless nneething-active
 211         (setq nneething-active (cons 1 0)))
 212       ;; Old nneething had a different map format.
 213       (when (and (cdar nneething-map)
 214                  (atom (cdar nneething-map)))
 215         (setq nneething-map
 216               (mapcar (lambda (n)
 217                         (list (cdr n) (car n)
 218                               (file-attribute-modification-time
 219                                (file-attributes
 220                                 (nneething-file-name (car n))))))
 221                       nneething-map)))
 222       ;; Remove files matching the exclusion regexp.
 223       (when nneething-exclude-files
 224         (let ((f files)
 225               prev)
 226           (while f
 227             (if (string-match nneething-exclude-files (car f))
 228                 (if prev (setcdr prev (cdr f))
 229                   (setq files (cdr files)))
 230               (setq prev f))
 231             (setq f (cdr f)))))
 232       ;; Remove files not matching the inclusion regexp.
 233       (when nneething-include-files
 234         (let ((f files)
 235               prev)
 236           (while f
 237             (if (not (string-match nneething-include-files (car f)))
 238                 (if prev (setcdr prev (cdr f))
 239                   (setq files (cdr files)))
 240               (setq prev f))
 241             (setq f (cdr f)))))
 242       ;; Remove deleted files from the map.
 243       (let ((map nneething-map)
 244             prev)
 245         (while map
 246           (if (and (member (cadr (car map)) files)
 247                   ;; We also remove files that have changed mod times.
 248                    (equal (file-attribute-modification-time (file-attributes
 249                                   (nneething-file-name (cadr (car map)))))
 250                           (cadr (cdar map))))
 251               (progn
 252                 (push (cadr (car map)) map-files)
 253                 (setq prev map))
 254             (setq touched t)
 255             (if prev
 256                 (setcdr prev (cdr map))
 257               (setq nneething-map (cdr nneething-map))))
 258           (setq map (cdr map))))
 259       ;; Find all new files and enter them into the map.
 260       (while files
 261         (unless (member (car files) map-files)
 262           ;; This file is not in the map, so we enter it.
 263           (setq touched t)
 264           (setcdr nneething-active (1+ (cdr nneething-active)))
 265           (push (list (cdr nneething-active) (car files)
 266                       (file-attribute-modification-time (file-attributes
 267                               (nneething-file-name (car files)))))
 268                 nneething-map))
 269         (setq files (cdr files)))
 270       (when (and touched
 271                  (not nneething-read-only))
 272         (with-temp-file map-file
 273           (insert "(setq nneething-map '")
 274           (gnus-prin1 nneething-map)
 275           (insert ")\n(setq nneething-active '")
 276           (gnus-prin1 nneething-active)
 277           (insert ")\n"))))))
 278
 279 (defun nneething-insert-head (file)
 280   "Insert the head of FILE."
 281   (when (nneething-get-head file)
 282     (insert-buffer-substring nneething-work-buffer)
 283     (goto-char (point-max))))
 284
 285 (defun nneething-encode-file-name (file &optional coding-system)
 286   "Encode the name of the FILE in CODING-SYSTEM."
 287   (let ((pos 0) buf)
 288     (setq file (encode-coding-string
 289                 file (or coding-system nnmail-pathname-coding-system)))
 290     (while (string-match "[^-0-9a-zA-Z_:/.]" file pos)
 291       (setq buf (cons (format "%%%02x" (aref file (match-beginning 0)))
 292                       (cons (substring file pos (match-beginning 0)) buf))
 293             pos (match-end 0)))
 294     (apply (function concat)
 295            (nreverse (cons (substring file pos) buf)))))
 296
 297 (defun nneething-decode-file-name (file &optional coding-system)
 298   "Decode the name of the FILE is encoded in CODING-SYSTEM."
 299   (let ((pos 0) buf)
 300     (while (string-match "%\\([0-9a-fA-F][0-9a-fA-F]\\)" file pos)
 301       (setq buf (cons (string (string-to-number (match-string 1 file) 16))
 302                       (cons (substring file pos (match-beginning 0)) buf))
 303             pos (match-end 0)))
 304     (decode-coding-string
 305      (apply (function concat)
 306             (nreverse (cons (substring file pos) buf)))
 307      (or coding-system nnmail-pathname-coding-system))))
 308
 309 (defun nneething-get-file-name (id)
 310   "Extract the file name from the message ID string."
 311   (when (string-match "\\`<nneething-\\([^@]+\\)@.*>\\'" id)
 312     (nneething-decode-file-name (match-string 1 id))))
 313
 314 (defun nneething-make-head (file &optional buffer extra-msg
 315                                  mime-type mime-charset mime-encoding)
 316   "Create a head by looking at the file attributes of FILE."
 317   (let ((atts (file-attributes file)))
 318     (insert
 319      "Subject: " (file-name-nondirectory file) (or extra-msg "") "\n"
 320      "Message-ID: <nneething-" (nneething-encode-file-name file)
 321      "@" (system-name) ">\n"
 322      (if (zerop (float-time (file-attribute-modification-time atts))) ""
 323        (concat "Date: "
 324                (current-time-string (file-attribute-modification-time atts))
 325                "\n"))
 326      (or (when buffer
 327            (with-current-buffer buffer
 328              (when (re-search-forward "<[a-zA-Z0-9_]@[-a-zA-Z0-9_]>" 1000 t)
 329                (concat "From: " (match-string 0) "\n"))))
 330          (nneething-from-line (file-attribute-user-id atts) file))
 331      (if (> (file-attribute-size atts) 0)
 332          (concat "Chars: " (int-to-string (file-attribute-size atts)) "\n")
 333        "")
 334      (if buffer
 335          (with-current-buffer buffer
 336            (concat "Lines: " (int-to-string
 337                               (count-lines (point-min) (point-max)))
 338                    "\n"))
 339        "")
 340      (if mime-type
 341          (concat "Content-Type: " mime-type
 342                  (if mime-charset
 343                      (concat "; charset="
 344                              (if (stringp mime-charset)
 345                                  mime-charset
 346                                (symbol-name mime-charset)))
 347                    "")
 348                  (if mime-encoding
 349                      (concat "\nContent-Transfer-Encoding: " mime-encoding)
 350                    "")
 351                  "\nMIME-Version: 1.0\n")
 352        ""))))
 353
 354 (defun nneething-from-line (uid &optional file)
 355   "Return a From header based of UID."
 356   (let* ((login (condition-case nil
 357                     (user-login-name uid)
 358                   (error
 359                    (cond ((= uid (user-uid)) (user-login-name))
 360                          ((zerop uid) "root")
 361                          (t (int-to-string uid))))))
 362          (name (condition-case nil
 363                    (user-full-name uid)
 364                  (error
 365                   (cond ((= uid (user-uid)) (user-full-name))
 366                         ((zerop uid) "Ms. Root")))))
 367          (host (if  (string-match "\\`/[^/@]*@\\([^:/]+\\):" file)
 368                    (prog1
 369                        (substring file
 370                                   (match-beginning 1)
 371                                   (match-end 1))
 372                      (when (string-match
 373                             "/\\(users\\|home\\)/\\([^/]+\\)/" file)
 374                        (setq login (substring file
 375                                               (match-beginning 2)
 376                                               (match-end 2))
 377                              name nil)))
 378                  (system-name))))
 379     (concat "From: " login "@" host
 380             (if name (concat " (" name ")") "") "\n")))
 381
 382 (defun nneething-get-head (file)
 383   "Either find the head in FILE or make a head for FILE."
 384   (with-current-buffer (get-buffer-create nneething-work-buffer)
 385     (setq case-fold-search nil)
 386     (buffer-disable-undo)
 387     (erase-buffer)
 388     (cond
 389      ((not (file-exists-p file))
 390       ;; The file do not exist.
 391       nil)
 392      ((or (file-directory-p file)
 393           (file-symlink-p file))
 394       ;; It's a dir, so we fudge a head.
 395       (nneething-make-head file) t)
 396      (t
 397       ;; We examine the file.
 398       (condition-case ()
 399           (progn
 400             (nnheader-insert-head file)
 401             (if (nnheader-article-p)
 402                 (delete-region
 403                  (progn
 404                    (goto-char (point-min))
 405                    (or (and (search-forward "\n\n" nil t)
 406                             (1- (point)))
 407                        (point-max)))
 408                  (point-max))
 409               (goto-char (point-min))
 410               (nneething-make-head file (current-buffer))
 411               (delete-region (point) (point-max))))
 412         (file-error
 413          (nneething-make-head file (current-buffer) " (unreadable)")))
 414       t))))
 415
 416 (defun nneething-file-name (article)
 417   "Return the file name of ARTICLE."
 418   (let ((dir (file-name-as-directory nneething-address))
 419         fname)
 420     (if (numberp article)
 421         (if (setq fname (cadr (assq article nneething-map)))
 422             (expand-file-name fname dir)
 423           (make-temp-name (expand-file-name "nneething" dir)))
 424       (expand-file-name article dir))))
 425
 426 (provide 'nneething)
 427
 428 ;;; nneething.el ends here