lisp/gnus/gnus-range.el

   1 ;;; gnus-range.el --- range and sequence functions for Gnus
   2
   3 ;; Copyright (C) 1996-2018 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 ;;; List and range functions
  28
  29 (defsubst gnus-range-normalize (range)
  30   "Normalize RANGE.
  31 If RANGE is a single range, return (RANGE). Otherwise, return RANGE."
  32   (if (listp (cdr-safe range)) range (list range)))
  33
  34 (defun gnus-last-element (list)
  35   "Return last element of LIST."
  36   (while (cdr list)
  37     (setq list (cdr list)))
  38   (car list))
  39 (make-obsolete 'gnus-last-element "use `car' of `last' instead." "27.1")
  40
  41 (define-obsolete-function-alias 'gnus-copy-sequence 'copy-tree "27.1")
  42
  43 (defun gnus-set-difference (list1 list2)
  44   "Return a list of elements of LIST1 that do not appear in LIST2."
  45   (let ((hash2 (make-hash-table :test 'eq))
  46         (result nil))
  47     (dolist (elt list2) (puthash elt t hash2))
  48     (dolist (elt list1)
  49       (unless (gethash elt hash2)
  50         (setq result (cons elt result))))
  51     (nreverse result)))
  52
  53 (defun gnus-range-nconcat (&rest ranges)
  54   "Return a range comprising all the RANGES, which are pre-sorted.
  55 RANGES will be destructively altered."
  56   (setq ranges (delete nil ranges))
  57   (let* ((result (gnus-range-normalize (pop ranges)))
  58          (last (last result)))
  59     (dolist (range ranges)
  60       (setq range (gnus-range-normalize range))
  61       ;; Normalize the single-number case, so that we don't need to
  62       ;; special-case that so much.
  63       (when (numberp (car last))
  64         (setcar last (cons (car last) (car last))))
  65       (when (numberp (car range))
  66         (setcar range (cons (car range) (car range))))
  67       (if (= (1+ (cdar last)) (caar range))
  68           (progn
  69             (setcdr (car last) (cdar range))
  70             (setcdr last (cdr range)))
  71         (setcdr last range)
  72         ;; Denormalize back, since we couldn't join the ranges up.
  73         (when (= (caar range) (cdar range))
  74           (setcar range (caar range)))
  75         (when (= (caar last) (cdar last))
  76           (setcar last (caar last))))
  77       (setq last (last last)))
  78     (if (and (consp (car result))
  79              (= (length result) 1))
  80         (car result)
  81       result)))
  82
  83 (defun gnus-range-difference (range1 range2)
  84   "Return the range of elements in RANGE1 that do not appear in RANGE2.
  85 Both ranges must be in ascending order."
  86   (setq range1 (gnus-range-normalize range1))
  87   (setq range2 (gnus-range-normalize range2))
  88   (let* ((new-range (cons nil (copy-sequence range1)))
  89          (r new-range)
  90          (safe t))
  91     (while (cdr r)
  92       (let* ((r1 (cadr r))
  93              (r2 (car range2))
  94              (min1 (if (numberp r1) r1 (car r1)))
  95              (max1 (if (numberp r1) r1 (cdr r1)))
  96              (min2 (if (numberp r2) r2 (car r2)))
  97              (max2 (if (numberp r2) r2 (cdr r2))))
  98
  99         (cond ((> min1 max1)
 100                ;; Invalid range: may result from overlap condition (below)
 101                ;; remove Invalid range
 102                (setcdr r (cddr r)))
 103               ((and (= min1 max1)
 104                     (listp r1))
 105                ;; Inefficient representation: may result from overlap condition (below)
 106                (setcar (cdr r) min1))
 107               ((not min2)
 108                ;; All done with range2
 109                (setq r nil))
 110               ((< max1 min2)
 111                ;; No overlap: range1 precedes range2
 112                (pop r))
 113               ((< max2 min1)
 114                ;; No overlap: range2 precedes range1
 115                (pop range2))
 116               ((and (<= min2 min1) (<= max1 max2))
 117                ;; Complete overlap: range1 removed
 118                (setcdr r (cddr r)))
 119               (t
 120                (setcdr r (nconc (list (cons min1 (1- min2)) (cons (1+ max2) max1)) (cddr r)))))))
 121     (cdr new-range)))
 122
 123
 124
 125 ;;;###autoload
 126 (defun gnus-sorted-difference (list1 list2)
 127   "Return a list of elements of LIST1 that do not appear in LIST2.
 128 Both lists have to be sorted over <.
 129 The tail of LIST1 is not copied."
 130   (let (out)
 131     (while (and list1 list2)
 132       (cond ((= (car list1) (car list2))
 133              (setq list1 (cdr list1)
 134                    list2 (cdr list2)))
 135             ((< (car list1) (car list2))
 136              (setq out (cons (car list1) out))
 137              (setq list1 (cdr list1)))
 138             (t
 139              (setq list2 (cdr list2)))))
 140     (nconc (nreverse out) list1)))
 141
 142 ;;;###autoload
 143 (defun gnus-sorted-ndifference (list1 list2)
 144   "Return a list of elements of LIST1 that do not appear in LIST2.
 145 Both lists have to be sorted over <.
 146 LIST1 is modified."
 147   (let* ((top (cons nil list1))
 148          (prev top))
 149     (while (and list1 list2)
 150       (cond ((= (car list1) (car list2))
 151              (setcdr prev (cdr list1))
 152              (setq list1 (cdr list1)
 153                    list2 (cdr list2)))
 154             ((< (car list1) (car list2))
 155              (setq prev list1
 156                    list1 (cdr list1)))
 157             (t
 158              (setq list2 (cdr list2)))))
 159     (cdr top)))
 160
 161 ;;;###autoload
 162 (defun gnus-sorted-complement (list1 list2)
 163   "Return a list of elements that are in LIST1 or LIST2 but not both.
 164 Both lists have to be sorted over <."
 165   (let (out)
 166     (if (or (null list1) (null list2))
 167         (or list1 list2)
 168       (while (and list1 list2)
 169         (cond ((= (car list1) (car list2))
 170                (setq list1 (cdr list1)
 171                      list2 (cdr list2)))
 172               ((< (car list1) (car list2))
 173                (setq out (cons (car list1) out))
 174                (setq list1 (cdr list1)))
 175               (t
 176                (setq out (cons (car list2) out))
 177                (setq list2 (cdr list2)))))
 178       (nconc (nreverse out) (or list1 list2)))))
 179
 180 ;;;###autoload
 181 (defun gnus-intersection (list1 list2)
 182   (let ((result nil))
 183     (while list2
 184       (when (memq (car list2) list1)
 185         (setq result (cons (car list2) result)))
 186       (setq list2 (cdr list2)))
 187     result))
 188
 189 ;;;###autoload
 190 (defun gnus-sorted-intersection (list1 list2)
 191   "Return intersection of LIST1 and LIST2.
 192 LIST1 and LIST2 have to be sorted over <."
 193   (let (out)
 194     (while (and list1 list2)
 195       (cond ((= (car list1) (car list2))
 196              (setq out (cons (car list1) out)
 197                    list1 (cdr list1)
 198                    list2 (cdr list2)))
 199             ((< (car list1) (car list2))
 200              (setq list1 (cdr list1)))
 201             (t
 202              (setq list2 (cdr list2)))))
 203     (nreverse out)))
 204
 205 ;;;###autoload
 206 (defun gnus-sorted-range-intersection (range1 range2)
 207   "Return intersection of RANGE1 and RANGE2.
 208 RANGE1 and RANGE2 have to be sorted over <."
 209   (let* (out
 210          (min1 (car range1))
 211          (max1 (if (numberp min1)
 212                    (if (numberp (cdr range1))
 213                        (prog1 (cdr range1)
 214                          (setq range1 nil)) min1)
 215                  (prog1 (cdr min1)
 216                    (setq min1 (car min1)))))
 217          (min2 (car range2))
 218          (max2 (if (numberp min2)
 219                    (if (numberp (cdr range2))
 220                        (prog1 (cdr range2)
 221                          (setq range2 nil)) min2)
 222                  (prog1 (cdr min2)
 223                    (setq min2 (car min2))))))
 224     (setq range1 (cdr range1)
 225           range2 (cdr range2))
 226     (while (and min1 min2)
 227       (cond ((< max1 min2)              ; range1 precedes range2
 228              (setq range1 (cdr range1)
 229                    min1 nil))
 230             ((< max2 min1)              ; range2 precedes range1
 231              (setq range2 (cdr range2)
 232                    min2 nil))
 233             (t                     ; some sort of overlap is occurring
 234              (let ((min (max min1 min2))
 235                    (max (min max1 max2)))
 236                (setq out (if (= min max)
 237                              (cons min out)
 238                            (cons (cons min max) out))))
 239              (if (< max1 max2)          ; range1 ends before range2
 240                  (setq min1 nil)        ; incr range1
 241                (setq min2 nil))))       ; incr range2
 242       (unless min1
 243         (setq min1 (car range1)
 244               max1 (if (numberp min1) min1 (prog1 (cdr min1) (setq min1 (car min1))))
 245               range1 (cdr range1)))
 246       (unless min2
 247         (setq min2 (car range2)
 248               max2 (if (numberp min2) min2 (prog1 (cdr min2) (setq min2 (car min2))))
 249               range2 (cdr range2))))
 250     (cond ((cdr out)
 251         (nreverse out))
 252           ((numberp (car out))
 253            out)
 254           (t
 255            (car out)))))
 256
 257 ;;;###autoload
 258 (defalias 'gnus-set-sorted-intersection 'gnus-sorted-nintersection)
 259
 260 ;;;###autoload
 261 (defun gnus-sorted-nintersection (list1 list2)
 262   "Return intersection of LIST1 and LIST2 by modifying cdr pointers of LIST1.
 263 LIST1 and LIST2 have to be sorted over <."
 264   (let* ((top (cons nil list1))
 265          (prev top))
 266     (while (and list1 list2)
 267       (cond ((= (car list1) (car list2))
 268              (setq prev list1
 269                    list1 (cdr list1)
 270                    list2 (cdr list2)))
 271             ((< (car list1) (car list2))
 272              (setcdr prev (cdr list1))
 273              (setq list1 (cdr list1)))
 274             (t
 275              (setq list2 (cdr list2)))))
 276     (setcdr prev nil)
 277     (cdr top)))
 278
 279 ;;;###autoload
 280 (defun gnus-sorted-union (list1 list2)
 281   "Return union of LIST1 and LIST2.
 282 LIST1 and LIST2 have to be sorted over <."
 283   (let (out)
 284     (while (and list1 list2)
 285       (cond ((= (car list1) (car list2))
 286              (setq out (cons (car list1) out)
 287                    list1 (cdr list1)
 288                    list2 (cdr list2)))
 289             ((< (car list1) (car list2))
 290              (setq out (cons (car list1) out)
 291                    list1 (cdr list1)))
 292             (t
 293              (setq out (cons (car list2) out)
 294                    list2 (cdr list2)))))
 295     (while list1
 296       (setq out (cons (car list1) out)
 297             list1 (cdr list1)))
 298     (while list2
 299       (setq out (cons (car list2) out)
 300             list2 (cdr list2)))
 301     (nreverse out)))
 302
 303 ;;;###autoload
 304 (defun gnus-sorted-nunion (list1 list2)
 305   "Return union of LIST1 and LIST2 by modifying cdr pointers of LIST1.
 306 LIST1 and LIST2 have to be sorted over <."
 307   (let* ((top (cons nil list1))
 308          (prev top))
 309     (while (and list1 list2)
 310       (cond ((= (car list1) (car list2))
 311              (setq prev list1
 312                    list1 (cdr list1)
 313                    list2 (cdr list2)))
 314             ((< (car list1) (car list2))
 315              (setq prev list1
 316                    list1 (cdr list1)))
 317             (t
 318              (setcdr prev (list (car list2)))
 319              (setq prev (cdr prev)
 320                    list2 (cdr list2))
 321              (setcdr prev list1))))
 322     (while list2
 323       (setcdr prev (list (car list2)))
 324       (setq prev (cdr prev)
 325             list2 (cdr list2)))
 326     (cdr top)))
 327
 328 (defun gnus-compress-sequence (numbers &optional always-list)
 329   "Convert sorted list of numbers to a list of ranges or a single range.
 330 If ALWAYS-LIST is non-nil, this function will always release a list of
 331 ranges."
 332   (let* ((first (car numbers))
 333          (last (car numbers))
 334          result)
 335     (if (null numbers)
 336         nil
 337       (if (not (listp (cdr numbers)))
 338           numbers
 339         (while numbers
 340           (cond ((= last (car numbers)) nil) ;Omit duplicated number
 341                 ((= (1+ last) (car numbers)) ;Still in sequence
 342                  (setq last (car numbers)))
 343                 (t                      ;End of one sequence
 344                  (setq result
 345                        (cons (if (= first last) first
 346                                (cons first last))
 347                              result))
 348                  (setq first (car numbers))
 349                  (setq last  (car numbers))))
 350           (setq numbers (cdr numbers)))
 351         (if (and (not always-list) (null result))
 352             (if (= first last) (list first) (cons first last))
 353           (nreverse (cons (if (= first last) first (cons first last))
 354                           result)))))))
 355
 356 (defalias 'gnus-uncompress-sequence 'gnus-uncompress-range)
 357 (defun gnus-uncompress-range (ranges)
 358   "Expand a list of ranges into a list of numbers.
 359 RANGES is either a single range on the form `(num . num)' or a list of
 360 these ranges."
 361   (let (first last result)
 362     (cond
 363      ((null ranges)
 364       nil)
 365      ((not (listp (cdr ranges)))
 366       (setq first (car ranges))
 367       (setq last (cdr ranges))
 368       (while (<= first last)
 369         (setq result (cons first result))
 370         (setq first (1+ first)))
 371       (nreverse result))
 372      (t
 373       (while ranges
 374         (if (atom (car ranges))
 375             (when (numberp (car ranges))
 376               (setq result (cons (car ranges) result)))
 377           (setq first (caar ranges))
 378           (setq last  (cdar ranges))
 379           (while (<= first last)
 380             (setq result (cons first result))
 381             (setq first (1+ first))))
 382         (setq ranges (cdr ranges)))
 383       (nreverse result)))))
 384
 385 (defun gnus-add-to-range (ranges list)
 386   "Return a list of ranges that has all articles from both RANGES and LIST.
 387 Note: LIST has to be sorted over `<'."
 388   (if (not ranges)
 389       (gnus-compress-sequence list t)
 390     (setq list (copy-sequence list))
 391     (unless (listp (cdr ranges))
 392       (setq ranges (list ranges)))
 393     (let ((out ranges)
 394           ilist lowest highest temp)
 395       (while (and ranges list)
 396         (setq ilist list)
 397         (setq lowest (or (and (atom (car ranges)) (car ranges))
 398                          (caar ranges)))
 399         (while (and list (cdr list) (< (cadr list) lowest))
 400           (setq list (cdr list)))
 401         (when (< (car ilist) lowest)
 402           (setq temp list)
 403           (setq list (cdr list))
 404           (setcdr temp nil)
 405           (setq out (nconc (gnus-compress-sequence ilist t) out)))
 406         (setq highest (or (and (atom (car ranges)) (car ranges))
 407                           (cdar ranges)))
 408         (while (and list (<= (car list) highest))
 409           (setq list (cdr list)))
 410         (setq ranges (cdr ranges)))
 411       (when list
 412         (setq out (nconc (gnus-compress-sequence list t) out)))
 413       (setq out (sort out (lambda (r1 r2)
 414                             (< (or (and (atom r1) r1) (car r1))
 415                                (or (and (atom r2) r2) (car r2))))))
 416       (setq ranges out)
 417       (while ranges
 418         (if (atom (car ranges))
 419             (when (cdr ranges)
 420               (if (atom (cadr ranges))
 421                   (when (= (1+ (car ranges)) (cadr ranges))
 422                     (setcar ranges (cons (car ranges)
 423                                          (cadr ranges)))
 424                     (setcdr ranges (cddr ranges)))
 425                 (when (= (1+ (car ranges)) (caadr ranges))
 426                   (setcar (cadr ranges) (car ranges))
 427                   (setcar ranges (cadr ranges))
 428                   (setcdr ranges (cddr ranges)))))
 429           (when (cdr ranges)
 430             (if (atom (cadr ranges))
 431                 (when (= (1+ (cdar ranges)) (cadr ranges))
 432                   (setcdr (car ranges) (cadr ranges))
 433                   (setcdr ranges (cddr ranges)))
 434               (when (= (1+ (cdar ranges)) (caadr ranges))
 435                 (setcdr (car ranges) (cdadr ranges))
 436                 (setcdr ranges (cddr ranges))))))
 437         (setq ranges (cdr ranges)))
 438       out)))
 439
 440 (defun gnus-remove-from-range (range1 range2)
 441   "Return a range that has all articles from RANGE2 removed from RANGE1.
 442 The returned range is always a list.  RANGE2 can also be a unsorted
 443 list of articles.  RANGE1 is modified by side effects, RANGE2 is not
 444 modified."
 445   (if (or (null range1) (null range2))
 446       range1
 447     (let (out r1 r2 r1_min r1_max r2_min r2_max
 448               (range2 (copy-tree range2)))
 449       (setq range1 (if (listp (cdr range1)) range1 (list range1))
 450             range2 (sort (if (listp (cdr range2)) range2 (list range2))
 451                          (lambda (e1 e2)
 452                            (< (if (consp e1) (car e1) e1)
 453                               (if (consp e2) (car e2) e2))))
 454             r1 (car range1)
 455             r2 (car range2)
 456             r1_min (if (consp r1) (car r1) r1)
 457             r1_max (if (consp r1) (cdr r1) r1)
 458             r2_min (if (consp r2) (car r2) r2)
 459             r2_max (if (consp r2) (cdr r2) r2))
 460       (while (and range1 range2)
 461         (cond ((< r2_max r1_min)        ; r2 < r1
 462                (pop range2)
 463                (setq r2 (car range2)
 464                      r2_min (if (consp r2) (car r2) r2)
 465                      r2_max (if (consp r2) (cdr r2) r2)))
 466               ((and (<= r2_min r1_min) (<= r1_max r2_max)) ; r2 overlap r1
 467                (pop range1)
 468                (setq r1 (car range1)
 469                      r1_min (if (consp r1) (car r1) r1)
 470                      r1_max (if (consp r1) (cdr r1) r1)))
 471               ((and (<= r2_min r1_min) (<= r2_max r1_max)) ; r2 overlap min r1
 472                (pop range2)
 473                (setq r1_min (1+ r2_max)
 474                      r2 (car range2)
 475                      r2_min (if (consp r2) (car r2) r2)
 476                      r2_max (if (consp r2) (cdr r2) r2)))
 477               ((and (<= r1_min r2_min) (<= r2_max r1_max)) ; r2 contained in r1
 478                (if (eq r1_min (1- r2_min))
 479                    (push r1_min out)
 480                  (push (cons r1_min (1- r2_min)) out))
 481                (pop range2)
 482                (if (< r2_max r1_max)    ; finished with r1?
 483                    (setq r1_min (1+ r2_max))
 484                  (pop range1)
 485                  (setq r1 (car range1)
 486                        r1_min (if (consp r1) (car r1) r1)
 487                        r1_max (if (consp r1) (cdr r1) r1)))
 488                (setq r2 (car range2)
 489                      r2_min (if (consp r2) (car r2) r2)
 490                      r2_max (if (consp r2) (cdr r2) r2)))
 491               ((and (<= r2_min r1_max) (<= r1_max r2_max)) ; r2 overlap max r1
 492                (if (eq r1_min (1- r2_min))
 493                    (push r1_min out)
 494                  (push (cons r1_min (1- r2_min)) out))
 495                (pop range1)
 496                (setq r1 (car range1)
 497                      r1_min (if (consp r1) (car r1) r1)
 498                      r1_max (if (consp r1) (cdr r1) r1)))
 499               ((< r1_max r2_min)        ; r2 > r1
 500                (pop range1)
 501                (if (eq r1_min r1_max)
 502                    (push r1_min out)
 503                  (push (cons r1_min r1_max) out))
 504                (setq r1 (car range1)
 505                      r1_min (if (consp r1) (car r1) r1)
 506                      r1_max (if (consp r1) (cdr r1) r1)))))
 507       (when r1
 508         (if (eq r1_min r1_max)
 509             (push r1_min out)
 510           (push (cons r1_min r1_max) out))
 511         (pop range1))
 512       (while range1
 513         (push (pop range1) out))
 514       (nreverse out))))
 515
 516 (defun gnus-member-of-range (number ranges)
 517   (if (not (listp (cdr ranges)))
 518       (and (>= number (car ranges))
 519            (<= number (cdr ranges)))
 520     (let ((not-stop t))
 521       (while (and ranges
 522                   (if (numberp (car ranges))
 523                       (>= number (car ranges))
 524                     (>= number (caar ranges)))
 525                   not-stop)
 526         (when (if (numberp (car ranges))
 527                   (= number (car ranges))
 528                 (and (>= number (caar ranges))
 529                      (<= number (cdar ranges))))
 530           (setq not-stop nil))
 531         (setq ranges (cdr ranges)))
 532       (not not-stop))))
 533
 534 (defun gnus-list-range-intersection (list ranges)
 535   "Return a list of numbers in LIST that are members of RANGES.
 536 LIST is a sorted list."
 537   (setq ranges (gnus-range-normalize ranges))
 538   (let (number result)
 539     (while (setq number (pop list))
 540       (while (and ranges
 541                   (if (numberp (car ranges))
 542                       (< (car ranges) number)
 543                     (< (cdar ranges) number)))
 544         (setq ranges (cdr ranges)))
 545       (when (and ranges
 546                  (if (numberp (car ranges))
 547                       (= (car ranges) number)
 548                    ;; (caar ranges) <= number <= (cdar ranges)
 549                    (>= number (caar ranges))))
 550         (push number result)))
 551     (nreverse result)))
 552
 553 (defalias 'gnus-inverse-list-range-intersection 'gnus-list-range-difference)
 554
 555 (defun gnus-list-range-difference (list ranges)
 556   "Return a list of numbers in LIST that are not members of RANGES.
 557 LIST is a sorted list."
 558   (setq ranges (gnus-range-normalize ranges))
 559   (let (number result)
 560     (while (setq number (pop list))
 561       (while (and ranges
 562                   (if (numberp (car ranges))
 563                       (< (car ranges) number)
 564                     (< (cdar ranges) number)))
 565         (setq ranges (cdr ranges)))
 566       (when (or (not ranges)
 567                 (if (numberp (car ranges))
 568                     (not (= (car ranges) number))
 569                   ;; not ((caar ranges) <= number <= (cdar ranges))
 570                   (< number (caar ranges))))
 571         (push number result)))
 572     (nreverse result)))
 573
 574 (defun gnus-range-length (range)
 575   "Return the length RANGE would have if uncompressed."
 576   (cond
 577    ((null range)
 578     0)
 579    ((not (listp (cdr range)))
 580     (- (cdr range) (car range) -1))
 581    (t
 582     (let ((sum 0))
 583       (dolist (x range sum)
 584         (setq sum
 585               (+ sum (if (consp x) (- (cdr x) (car x) -1) 1))))))))
 586
 587 (defun gnus-range-add (range1 range2)
 588   "Add RANGE2 to RANGE1 (nondestructively)."
 589   (unless (listp (cdr range1))
 590     (setq range1 (list range1)))
 591   (unless (listp (cdr range2))
 592     (setq range2 (list range2)))
 593   (let ((item1 (pop range1))
 594         (item2 (pop range2))
 595         range item selector)
 596     (while (or item1 item2)
 597       (setq selector
 598             (cond
 599              ((null item1) nil)
 600              ((null item2) t)
 601              ((and (numberp item1) (numberp item2)) (< item1 item2))
 602              ((numberp item1) (< item1 (car item2)))
 603              ((numberp item2) (< (car item1) item2))
 604              (t (< (car item1) (car item2)))))
 605       (setq item
 606             (or
 607              (let ((tmp1 item) (tmp2 (if selector item1 item2)))
 608                (cond
 609                 ((null tmp1) tmp2)
 610                 ((null tmp2) tmp1)
 611                 ((and (numberp tmp1) (numberp tmp2))
 612                  (cond
 613                   ((eq tmp1 tmp2) tmp1)
 614                   ((eq (1+ tmp1) tmp2) (cons tmp1 tmp2))
 615                   ((eq (1+ tmp2) tmp1) (cons tmp2 tmp1))
 616                   (t nil)))
 617                 ((numberp tmp1)
 618                  (cond
 619                   ((and (>= tmp1 (car tmp2)) (<= tmp1 (cdr tmp2))) tmp2)
 620                   ((eq (1+ tmp1) (car tmp2)) (cons tmp1 (cdr tmp2)))
 621                   ((eq (1- tmp1) (cdr tmp2)) (cons (car tmp2) tmp1))
 622                   (t nil)))
 623                 ((numberp tmp2)
 624                  (cond
 625                   ((and (>= tmp2 (car tmp1)) (<= tmp2 (cdr tmp1))) tmp1)
 626                   ((eq (1+ tmp2) (car tmp1)) (cons tmp2 (cdr tmp1)))
 627                   ((eq (1- tmp2) (cdr tmp1)) (cons (car tmp1) tmp2))
 628                   (t nil)))
 629                 ((< (1+ (cdr tmp1)) (car tmp2)) nil)
 630                 ((< (1+ (cdr tmp2)) (car tmp1)) nil)
 631                 (t (cons (min (car tmp1) (car tmp2))
 632                          (max (cdr tmp1) (cdr tmp2))))))
 633              (progn
 634                (if item (push item range))
 635                (if selector item1 item2))))
 636       (if selector
 637           (setq item1 (pop range1))
 638         (setq item2 (pop range2))))
 639     (if item (push item range))
 640     (reverse range)))
 641
 642 ;;;###autoload
 643 (defun gnus-add-to-sorted-list (list num)
 644   "Add NUM into sorted LIST by side effect."
 645   (let* ((top (cons nil list))
 646          (prev top))
 647     (while (and list (< (car list) num))
 648       (setq prev list
 649             list (cdr list)))
 650     (unless (eq (car list) num)
 651       (setcdr prev (cons num list)))
 652     (cdr top)))
 653
 654 (defun gnus-range-map (func range)
 655   "Apply FUNC to each value contained by RANGE."
 656   (setq range (gnus-range-normalize range))
 657   (while range
 658     (let ((span (pop range)))
 659       (if (numberp span)
 660           (funcall func span)
 661         (let ((first (car span))
 662               (last (cdr span)))
 663           (while (<= first last)
 664             (funcall func first)
 665             (setq first (1+ first))))))))
 666
 667 (provide 'gnus-range)
 668
 669 ;;; gnus-range.el ends here