lisp/cus-start.el

   1 ;;; cus-start.el --- define customization properties of builtins  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 1997, 1999-2018 Free Software Foundation, Inc.
   4
   5 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   6 ;; Keywords: internal
   7 ;; Package: emacs
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This file adds customize support for built-in variables.
  27
  28 ;; While dumping Emacs, this file is loaded, but it only records
  29 ;; the standard values; it does not do the rest of the job.
  30 ;; Later on, if the user makes a customization buffer,
  31 ;; this file is loaded again with (require 'cus-start);
  32 ;; then it does the whole job.
  33
  34 ;;; Code:
  35
  36 (defun minibuffer-prompt-properties--setter (symbol value)
  37   (set-default symbol value)
  38   (if (memq 'cursor-intangible value)
  39       (add-hook 'minibuffer-setup-hook 'cursor-intangible-mode)
  40     ;; Removing it is a bit trickier since it could have been added by someone
  41     ;; else as well, so let's just not bother.
  42     ))
  43
  44 ;; Elements of this list have the form:
  45 ;; SYMBOL GROUP TYPE VERSION REST...
  46 ;; SYMBOL is the name of the variable.
  47 ;; GROUP is the custom group to which it belongs (may also be a list
  48 ;; of groups)
  49 ;; TYPE is the defcustom :type.
  50 ;; VERSION is the defcustom :version (or nil).
  51 ;; REST is a set of :KEYWORD VALUE pairs.  Accepted :KEYWORDs are:
  52 ;; :standard - standard value for SYMBOL (else use current value)
  53 ;; :set - custom-set property
  54 ;; :risky - risky-local-variable property
  55 ;; :safe - safe-local-variable property
  56 ;; :tag - custom-tag property
  57 (let (standard
  58       native-p prop propval
  59       ;; This function turns a value
  60       ;; into an expression which produces that value.
  61       (quoter (lambda (sexp)
  62                 ;; FIXME: We'd like to use macroexp-quote here, but cus-start
  63                 ;; is loaded too early in loadup.el for that.
  64                 (if (or (memq sexp '(t nil))
  65                         (keywordp sexp)
  66                         (and (listp sexp)
  67                              (memq (car sexp) '(lambda)))
  68                         (stringp sexp)
  69                         (numberp sexp))
  70                     sexp
  71                   (list 'quote sexp))))
  72       (cursor-type-types
  73        '(choice
  74          (const :tag "Frame default" t)
  75          (const :tag "Filled box" box)
  76          (const :tag "Hollow cursor" hollow)
  77          (const :tag "Vertical bar" bar)
  78          (cons  :tag "Vertical bar with specified width"
  79                 (const bar) integer)
  80          (const :tag "Horizontal bar" hbar)
  81          (cons  :tag "Horizontal bar with specified width"
  82                 (const hbar) integer)
  83          (const :tag "None "nil))))
  84   (pcase-dolist
  85       (`(,symbol ,group ,type ,version . ,rest)
  86            `(;; alloc.c
  87              (gc-cons-threshold alloc integer)
  88              (gc-cons-percentage alloc float)
  89              (garbage-collection-messages alloc boolean)
  90              ;; buffer.c
  91              (cursor-type display ,cursor-type-types)
  92              (mode-line-format mode-line sexp) ;Hard to do right.
  93              (major-mode internal function)
  94              (case-fold-search matching boolean)
  95              (fill-column fill integer)
  96              (left-margin fill integer)
  97              (tab-width editing-basics integer)
  98              (ctl-arrow display boolean)
  99              (truncate-lines display boolean)
 100              (word-wrap display boolean)
 101              (selective-display-ellipses display boolean)
 102              (indicate-empty-lines fringe boolean)
 103              (indicate-buffer-boundaries
 104               fringe
 105               (choice
 106                (const :tag "No indicators" nil)
 107                (const :tag "On left, with arrows" left)
 108                (const :tag "On right, with arrows" right)
 109                (set :tag "Pick your own design"
 110                     :value ((t . nil))
 111                     :format "%{%t%}:\n%v\n%d"
 112                     :doc "You can specify a default and then override it \
 113 for individual indicators.
 114 Leaving \"Default\" unchecked is equivalent with specifying a default of
 115 \"Do not show\"."
 116                     (choice :tag "Default"
 117                             :value (t . nil)
 118                             (const :tag "Do not show" (t . nil))
 119                             (const :tag "On the left" (t . left))
 120                             (const :tag "On the right" (t . right)))
 121                     (choice :tag "Top"
 122                             :value (top . left)
 123                             (const :tag "Do not show" (top . nil))
 124                             (const :tag "On the left" (top . left))
 125                             (const :tag "On the right" (top . right)))
 126                     (choice :tag "Bottom"
 127                             :value (bottom . left)
 128                             (const :tag "Do not show" (bottom . nil))
 129                             (const :tag "On the left" (bottom . left))
 130                             (const :tag "On the right" (bottom . right)))
 131                     (choice :tag "Up arrow"
 132                             :value (up . left)
 133                             (const :tag "Do not show" (up . nil))
 134                             (const :tag "On the left" (up . left))
 135                             (const :tag "On the right" (up . right)))
 136                     (choice :tag "Down arrow"
 137                             :value (down . left)
 138                             (const :tag "Do not show" (down . nil))
 139                             (const :tag "On the left" (down . left))
 140                             (const :tag "On the right" (down . right))))
 141                (other :tag "On left, no arrows" t)))
 142              (scroll-up-aggressively windows
 143                                      (choice (const :tag "off" nil) float)
 144                                      "21.1")
 145              (scroll-down-aggressively windows
 146                                        (choice (const :tag "off" nil) float)
 147                                        "21.1")
 148              (line-spacing display (choice (const :tag "none" nil) number)
 149                            "22.1")
 150              (cursor-in-non-selected-windows
 151               cursor ,cursor-type-types nil
 152               :tag "Cursor In Non-selected Windows"
 153               :set (lambda (symbol value)
 154                      (set-default symbol value)
 155                      (force-mode-line-update t)))
 156              (transient-mark-mode editing-basics boolean nil
 157                                   :standard (not noninteractive)
 158                                   :initialize custom-initialize-delay
 159                                   :set custom-set-minor-mode)
 160              (bidi-paragraph-direction
 161               paragraphs
 162               (choice
 163                (const :tag "Left to Right" left-to-right)
 164                (const :tag "Right to Left" right-to-left)
 165                (const :tag "Dynamic, according to paragraph text" nil))
 166               "24.1")
 167              ;; callint.c
 168              (mark-even-if-inactive editing-basics boolean)
 169              ;; callproc.c
 170              (shell-file-name execute file)
 171              (exec-path execute
 172                         (repeat (choice (const :tag "default directory" nil)
 173                                         (directory :format "%v")))
 174                         nil
 175                         :standard
 176                         (mapcar (lambda (f)
 177                                   (if f (directory-file-name f)
 178                                     "."))
 179                                 (append (parse-colon-path (getenv "PATH"))
 180                                         (list exec-directory))))
 181              (exec-suffixes execute (repeat string))
 182              ;; charset.c
 183              (charset-map-path installation
 184                                (repeat (directory :format "%v")))
 185              ;; coding.c
 186              (inhibit-eol-conversion mule boolean)
 187              (enable-character-translation mule boolean)
 188              (eol-mnemonic-undecided mule string)
 189              ;; startup.el fiddles with the values.  IMO, would be
 190              ;; simpler to just use #ifdefs in coding.c.
 191              (eol-mnemonic-unix mule string nil
 192                                 :standard
 193                                 (if (memq system-type '(ms-dos windows-nt))
 194                                     "(Unix)" ":"))
 195              (eol-mnemonic-dos mule string nil
 196                                :standard
 197                                (if (memq system-type '(ms-dos windows-nt))
 198                                    "\\" "(DOS)"))
 199              (eol-mnemonic-mac mule string nil
 200                                :standard "(Mac)")
 201              (file-coding-system-alist
 202               mule
 203               (alist
 204                :key-type (regexp :tag "File regexp")
 205                :value-type (choice
 206                             :value (undecided . undecided)
 207                             (cons :tag "Encoding/decoding pair"
 208                                   :value (undecided . undecided)
 209                                   (coding-system :tag "Decoding")
 210                                   (coding-system :tag "Encoding"))
 211                             (coding-system
 212                              :tag "Single coding system"
 213                              :value undecided
 214                              :match (lambda (widget value)
 215                                       (and value (not (functionp value)))))
 216                             (function :value ignore))))
 217              ;; dired.c
 218              (completion-ignored-extensions dired
 219                                             (repeat (string :format "%v")))
 220              ;; dispnew.c
 221              (baud-rate display integer)
 222              (inverse-video display boolean)
 223              (visible-bell display boolean)
 224              (no-redraw-on-reenter display boolean)
 225
 226              ;; doc.c
 227              (text-quoting-style display
 228                                  (choice
 229                                   (const :tag "Prefer \\=‘curved\\=’ quotes, if possible" nil)
 230                                   (const :tag "\\=‘Curved\\=’ quotes" curved)
 231                                   (const :tag "\\='Straight\\=' quotes" straight)
 232                                   (const :tag "\\=`Grave\\=' quotes (no translation)" grave)))
 233
 234              ;; dosfns.c
 235              (dos-display-scancodes display boolean)
 236              (dos-hyper-key keyboard integer)
 237              (dos-super-key keyboard integer)
 238              (dos-keypad-mode keyboard integer)
 239
 240              ;; editfns.c
 241              (user-full-name mail string)
 242              ;; emacs.c
 243              (report-emacs-bug-address emacsbug string)
 244              ;; eval.c
 245              (max-specpdl-size limits integer)
 246              (max-lisp-eval-depth limits integer)
 247              (max-mini-window-height limits
 248                                      (choice (const :tag "quarter screen" nil)
 249                                              number) "23.1")
 250              (debug-on-error debug
 251                              (choice (const :tag "off")
 252                                      (repeat :menu-tag "When"
 253                                              :value (nil)
 254                                              (symbol :format "%v"))
 255                                      (const :tag "always" t)))
 256              (debug-ignored-errors debug (repeat (choice symbol regexp)))
 257              (debug-on-quit debug boolean)
 258              (debug-on-signal debug boolean)
 259              (debugger-stack-frame-as-list debugger boolean "26.1")
 260              ;; fileio.c
 261              (delete-by-moving-to-trash auto-save boolean "23.1")
 262              (auto-save-visited-file-name auto-save boolean)
 263              ;; filelock.c
 264              (create-lockfiles files boolean "24.3")
 265              (temporary-file-directory
 266               ;; Darwin section added 24.1, does not seem worth :version bump.
 267               files directory nil
 268               :standard
 269               (file-name-as-directory
 270                ;; FIXME ? Should there be Ftemporary_file_directory to do this
 271                ;; more robustly (cf set_local_socket in emacsclient.c).
 272                ;; It could be used elsewhere, eg Fcall_process_region,
 273                ;; server-socket-dir.  See bug#7135.
 274                (cond ((memq system-type '(ms-dos windows-nt))
 275                       (or (getenv "TEMP") (getenv "TMPDIR") (getenv "TMP")
 276                           "c:/temp"))
 277                      ((eq system-type 'darwin)
 278                       (or (getenv "TMPDIR") (getenv "TMP") (getenv "TEMP")
 279                           ;; See bug#7135.
 280                           (let* (file-name-handler-alist
 281                                  (tmp (ignore-errors
 282                                         (shell-command-to-string
 283                                          "getconf DARWIN_USER_TEMP_DIR"))))
 284                             (and (stringp tmp)
 285                                  (setq tmp (replace-regexp-in-string
 286                                             "\n\\'" "" tmp))
 287                                  ;; Handles "getconf: Unrecognized variable..."
 288                                  (file-directory-p tmp)
 289                                  tmp))
 290                           "/tmp"))
 291                      (t
 292                       (or (getenv "TMPDIR") (getenv "TMP") (getenv "TEMP")
 293                           "/tmp"))))
 294               :initialize custom-initialize-delay)
 295              ;; fns.c
 296              (use-dialog-box menu boolean "21.1")
 297              (use-file-dialog menu boolean "22.1")
 298              (focus-follows-mouse
 299               frames (choice
 300                       (const :tag "Off (nil)" :value nil)
 301                       (const :tag "On (t)" :value t)
 302                       (const :tag "Auto-raise" :value auto-raise)) "26.1")
 303              ;; fontset.c
 304              ;; FIXME nil is the initial value, fontset.el setqs it.
 305              (vertical-centering-font-regexp display
 306                                              (choice (const nil) regexp))
 307              ;; frame.c
 308              (default-frame-alist frames
 309                (repeat (cons :format "%v"
 310                              (symbol :tag "Parameter")
 311                              (sexp :tag "Value"))))
 312              (mouse-highlight mouse (choice (const :tag "disabled" nil)
 313                                             (const :tag "always shown" t)
 314                                             (other :tag "hidden by keypress" 1))
 315                               "22.1")
 316              (make-pointer-invisible mouse boolean "23.2")
 317              (menu-bar-mode frames boolean nil
 318                             ;; FIXME?
 319                             ;; :initialize custom-initialize-default
 320                             :set custom-set-minor-mode)
 321              (tool-bar-mode (frames mouse) boolean nil
 322                             ;; :initialize custom-initialize-default
 323                             :set custom-set-minor-mode)
 324              (frame-resize-pixelwise frames boolean "24.4")
 325              (frame-inhibit-implied-resize frames
 326                                            (choice
 327                                             (const :tag "Never" nil)
 328                                             (const :tag "Always" t)
 329                                             (repeat (symbol :tag "Parameter")))
 330                                            "25.1")
 331              (iconify-child-frame frames
 332                                   (choice
 333                                    (const :tag "Do nothing" nil)
 334                                    (const :tag "Iconify top level frame instead" iconify-top-level)
 335                                    (const :tag "Make frame invisible instead" make-invisible)
 336                                    (const :tag "Iconify" t))
 337                                   "26.1")
 338              (tooltip-reuse-hidden-frame tooltip boolean "26.1")
 339              ;; fringe.c
 340              (overflow-newline-into-fringe fringe boolean)
 341              ;; image.c
 342              (imagemagick-render-type image integer "24.1")
 343              ;; indent.c
 344              (indent-tabs-mode indent boolean)
 345              ;; keyboard.c
 346              (meta-prefix-char keyboard character)
 347              (auto-save-interval auto-save integer)
 348              (auto-save-no-message auto-save boolean "27.1")
 349              (auto-save-timeout auto-save (choice (const :tag "off" nil)
 350                                                   (integer :format "%v")))
 351              (echo-keystrokes minibuffer number)
 352              (polling-period keyboard integer)
 353              (double-click-time mouse (restricted-sexp
 354                                        :match-alternatives (integerp 'nil 't)))
 355              (double-click-fuzz mouse integer "22.1")
 356              (help-char keyboard character)
 357              (help-event-list keyboard (repeat (sexp :format "%v")))
 358              (menu-prompting menu boolean)
 359              (select-active-regions killing
 360                                     (choice (const :tag "always" t)
 361                                             (const :tag "only shift-selection or mouse-drag" only)
 362                                             (const :tag "off" nil))
 363                                     "24.1")
 364              (debug-on-event debug
 365                              (choice (const :tag "None" nil)
 366                                      (const :tag "When sent SIGUSR1" sigusr1)
 367                                      (const :tag "When sent SIGUSR2" sigusr2))
 368                              "24.1")
 369
 370              ;; This is not good news because it will use the wrong
 371              ;; version-specific directories when you upgrade.  We need
 372              ;; customization of the front of the list, maintaining the
 373              ;; standard value intact at the back.
 374              ;;(load-path environment
 375              ;;         (repeat (choice :tag "[Current dir?]"
 376              ;;                         :format "%[Current dir?%] %v"
 377              ;;                         (const :tag " current dir" nil)
 378              ;;                         (directory :format "%v"))))
 379              (load-prefer-newer lisp boolean "24.4")
 380              ;; minibuf.c
 381              (enable-recursive-minibuffers minibuffer boolean)
 382              (history-length minibuffer
 383                              (choice (const :tag "Infinite" t) integer)
 384                              "24.5")    ; 30 -> 100
 385              (history-delete-duplicates minibuffer boolean "22.1")
 386              (read-buffer-completion-ignore-case minibuffer boolean "23.1")
 387
 388              (minibuffer-prompt-properties
 389               minibuffer
 390               (list
 391                (checklist :inline t
 392                           (const :tag "Read-Only"
 393                                  :doc "Prevent prompt from being modified"
 394                                  :format "%t%n%h"
 395                                  :inline t
 396                                  (read-only t))
 397                           (const :tag "Don't Enter"
 398                                  :doc "Prevent point from ever entering prompt"
 399                                  :format "%t%n%h"
 400                                  :inline t
 401                                  (cursor-intangible t)))
 402                (repeat :inline t
 403                        :tag "Other Properties"
 404                        (list :inline t
 405                              :format "%v"
 406                              (symbol :tag "Property")
 407                              (sexp :tag "Value"))))
 408               "21.1"
 409               :set minibuffer-prompt-properties--setter)
 410              (minibuffer-auto-raise minibuffer boolean)
 411              ;; options property set at end
 412              (read-buffer-function minibuffer
 413                                    (choice (const nil)
 414                                            function))
 415              ;; msdos.c
 416              (dos-unsupported-char-glyph display integer)
 417              ;; nsterm.m
 418              ;;
 419              ;; FIXME: Why does ⌃ use nil instead of none?  Also the
 420              ;; description is confusing; setting it to nil disables ⌃
 421              ;; entirely.
 422              (ns-control-modifier
 423               ns
 424               (choice (const :tag "No modifier" nil)
 425                       (const control) (const meta)
 426                       (const alt) (const hyper)
 427                       (const super)) "23.1")
 428              (ns-right-control-modifier
 429               ns
 430               (choice (const :tag "No modifier (work as control)" none)
 431                       (const :tag "Use the value of ns-control-modifier"
 432                              left)
 433                       (const control) (const meta)
 434                       (const alt) (const hyper)
 435                       (const super)) "24.1")
 436              (ns-command-modifier
 437               ns
 438               (choice (const :tag "No modifier (work as layout switch)" none)
 439                       (const control) (const meta)
 440                       (const alt) (const hyper)
 441                       (const super)) "23.1")
 442              (ns-right-command-modifier
 443               ns
 444               (choice (const :tag "No modifier (work as layout switch)" none)
 445                       (const :tag "Use the value of ns-command-modifier"
 446                              left)
 447                       (const control) (const meta)
 448                       (const alt) (const hyper)
 449                       (const super)) "24.1")
 450              (ns-alternate-modifier
 451               ns
 452               (choice (const :tag "No modifier (work as alternate/option)" none)
 453                       (const control) (const meta)
 454                       (const alt) (const hyper)
 455                       (const super)) "23.1")
 456              (ns-right-alternate-modifier
 457               ns
 458               (choice (const :tag "No modifier (work as alternate/option)" none)
 459                       (const :tag "Use the value of ns-alternate-modifier"
 460                              left)
 461                       (const control) (const meta)
 462                       (const alt) (const hyper)
 463                       (const super)) "23.3")
 464              (ns-function-modifier
 465               ns
 466               (choice (const :tag "No modifier (work as function)" none)
 467                       (const control) (const meta)
 468                       (const alt) (const hyper)
 469                       (const super)) "23.1")
 470              (ns-antialias-text ns boolean "23.1")
 471              (ns-auto-hide-menu-bar ns boolean "24.1")
 472              (ns-confirm-quit ns boolean "25.1")
 473              (ns-use-native-fullscreen ns boolean "24.4")
 474              (ns-use-fullscreen-animation ns boolean "25.1")
 475              (ns-use-srgb-colorspace ns boolean "24.4")
 476              ;; process.c
 477              (delete-exited-processes processes-basics boolean)
 478              ;; syntax.c
 479              (parse-sexp-ignore-comments editing-basics boolean)
 480              (words-include-escapes editing-basics boolean)
 481              (open-paren-in-column-0-is-defun-start editing-basics boolean
 482                                                     "21.1")
 483              ;; term.c
 484              (visible-cursor cursor boolean "22.1")
 485              ;; terminal.c
 486              (ring-bell-function display
 487               (choice
 488                (const :tag "Default" nil)
 489                (const :tag "Silent" ignore)
 490                function))
 491              ;; undo.c
 492              (undo-limit undo integer)
 493              (undo-strong-limit undo integer)
 494              (undo-outer-limit undo
 495                                (choice integer
 496                                        (const :tag "No limit"
 497                                               :format "%t\n%d"
 498                                               :doc
 499                                               "With this choice, \
 500 the undo info for the current command never gets discarded.
 501 This should only be chosen under exceptional circumstances,
 502 since it could result in memory overflow and make Emacs crash."
 503                                               nil))
 504                                "22.1")
 505              ;; window.c
 506              (temp-buffer-show-function windows (choice (const nil) function))
 507              (next-screen-context-lines windows integer)
 508              (scroll-preserve-screen-position
 509               windows (choice
 510                        (const :tag "Off (nil)" :value nil)
 511                        (const :tag "Full screen (t)" :value t)
 512                        (other :tag "Always" 1)) "22.1")
 513              (recenter-redisplay
 514               windows (choice
 515                        (const :tag "Never (nil)" :value nil)
 516                        (const :tag "Only on ttys" :value tty)
 517                        (other :tag "Always" t)) "23.1")
 518              (window-combination-resize windows boolean "24.1")
 519              (window-combination-limit
 520               windows (choice
 521                        (const :tag "Never (nil)" :value nil)
 522                        (const :tag "If requested via buffer display alist (window-size)"
 523                               :value window-size)
 524                        (const :tag "With Temp Buffer Resize mode (temp-buffer-resize)"
 525                               :value temp-buffer-resize)
 526                        (const :tag "For temporary buffers (temp-buffer)"
 527                               :value temp-buffer)
 528                        (const :tag "For buffer display (display-buffer)"
 529                               :value display-buffer)
 530                        (other :tag "Always (t)" :value t))
 531               "26.1")
 532              (fast-but-imprecise-scrolling scrolling boolean "25.1")
 533              (window-resize-pixelwise windows boolean "24.4")
 534              ;; xdisp.c
 535              ;; The whitespace group is for whitespace.el.
 536              (show-trailing-whitespace editing-basics boolean nil
 537                                        :safe booleanp)
 538              (scroll-step windows integer)
 539              (scroll-conservatively windows integer)
 540              (scroll-margin windows integer)
 541              (maximum-scroll-margin windows float "26.1")
 542              (hscroll-margin windows integer "22.1")
 543              (hscroll-step windows number "22.1")
 544              (truncate-partial-width-windows
 545               display
 546               (choice (integer :tag "Truncate if narrower than")
 547                       (const :tag "Respect `truncate-lines'" nil)
 548                       (other :tag "Truncate if not full-width" t))
 549               "23.1")
 550              (make-cursor-line-fully-visible windows boolean)
 551              (mode-line-in-non-selected-windows mode-line boolean "22.1")
 552              (line-number-display-limit display
 553                                         (choice integer
 554                                                 (const :tag "No limit" nil)))
 555              (line-number-display-limit-width display integer "22.1")
 556              (highlight-nonselected-windows display boolean)
 557              (message-log-max debug (choice (const :tag "Disable" nil)
 558                                             (integer :menu-tag "lines"
 559                                                      :format "%v")
 560                                             (other :tag "Unlimited" t))
 561                               "24.3")
 562              (unibyte-display-via-language-environment mule boolean)
 563              (blink-cursor-alist cursor alist "22.1")
 564              (overline-margin display integer "22.1")
 565              (underline-minimum-offset display integer "23.1")
 566              (mouse-autoselect-window
 567               display (choice
 568                        (const :tag "Off (nil)" :value nil)
 569                        (const :tag "Immediate" :value t)
 570                        (number :tag "Delay by secs" :value 0.5)) "22.1")
 571              (tool-bar-style
 572               frames (choice
 573                       (const :tag "Images" :value image)
 574                       (const :tag "Text" :value text)
 575                       (const :tag "Both" :value both)
 576                       (const :tag "Both-horiz" :value both-horiz)
 577                       (const :tag "Text-image-horiz" :value text-image-horiz)
 578                       (const :tag "System default" :value nil)) "24.1")
 579              (tool-bar-max-label-size frames integer "24.1")
 580              (auto-hscroll-mode scrolling
 581                                 (choice
 582                                  (const :tag "Don't scroll automatically"
 583                                         :value nil)
 584                                  (const :tag "Scroll the entire window"
 585                                         :value t)
 586                                  (const :tag "Scroll only the current line"
 587                                         :value current-line))
 588                                 "26.1")
 589              (void-text-area-pointer cursor
 590                                      (choice
 591                                       (const :tag "Standard (text pointer)" :value nil)
 592                                       (const :tag "Arrow" :value arrow)
 593                                       (const :tag "Text pointer" :value text)
 594                                       (const :tag "Hand" :value hand)
 595                                       (const :tag "Vertical dragger" :value vdrag)
 596                                       (const :tag "Horizontal dragger" :value hdrag)
 597                                       (const :tag "Same as mode line" :value modeline)
 598                                       (const :tag "Hourglass" :value hourglass)))
 599              (display-hourglass cursor boolean)
 600              (hourglass-delay cursor number)
 601              (resize-mini-windows
 602               windows (choice
 603                        (const :tag "Off (nil)" :value nil)
 604                        (const :tag "Fit (t)" :value t)
 605                        (const :tag "Grow only" :value grow-only))
 606               "25.1")
 607              (display-raw-bytes-as-hex display boolean "26.1")
 608              (display-line-numbers display-line-numbers
 609                                    (choice
 610                                     (const :tag "Off (nil)" :value nil)
 611                                     (const :tag "Absolute line numbers"
 612                                            :value t)
 613                                     (const :tag "Relative line numbers"
 614                                            :value relative)
 615                                     (const :tag "Visually relative line numbers"
 616                                            :value visual))
 617                                    "26.1")
 618              (display-line-numbers-width display-line-numbers
 619                                  (choice
 620                                   (const :tag "Dynamically computed"
 621                                          :value nil)
 622                                   (integer :menu-tag "Fixed number of columns"
 623                                            :value 2
 624                                            :format "%v"))
 625                                  "26.1")
 626              (display-line-numbers-current-absolute display-line-numbers
 627                                  (choice
 628                                   (const :tag "Display actual number of current line"
 629                                          :value t)
 630                                   (const :tag "Display zero as number of current line"
 631                                          :value nil))
 632                                  "26.1")
 633              (display-line-numbers-widen display-line-numbers
 634                                  (choice
 635                                   (const :tag "Disregard narrowing when calculating line numbers"
 636                                          :value t)
 637                                   (const :tag "Count lines from beginning of narrowed region"
 638                                          :value nil))
 639                                  "26.1")
 640              ;; xfaces.c
 641              (scalable-fonts-allowed display boolean "22.1")
 642              ;; xfns.c
 643              (x-bitmap-file-path installation
 644                                  (repeat (directory :format "%v")))
 645              (x-gtk-use-old-file-dialog menu boolean "22.1")
 646              (x-gtk-show-hidden-files menu boolean "22.1")
 647              (x-gtk-file-dialog-help-text menu boolean "22.1")
 648              (x-gtk-use-system-tooltips tooltip boolean "23.3")
 649              ;; xterm.c
 650              (x-use-underline-position-properties display boolean "22.1")
 651              (x-underline-at-descent-line display boolean "22.1")
 652              (x-stretch-cursor display boolean "21.1")
 653              (scroll-bar-adjust-thumb-portion windows boolean "24.4")
 654              ;; xselect.c
 655              (x-select-enable-clipboard-manager killing boolean "24.1")
 656              ;; xsettings.c
 657              (font-use-system-font font-selection boolean "23.2")))
 658     (setq ;; If we did not specify any standard value expression above,
 659           ;; use the current value as the standard value.
 660           standard (if (setq prop (memq :standard rest))
 661                        (cadr prop)
 662                      (if (default-boundp symbol)
 663                          (funcall quoter (default-value symbol))))
 664           ;; Don't complain about missing variables which are
 665           ;; irrelevant to this platform.
 666           native-p (save-match-data
 667                      (cond
 668                       ((string-match "\\`dos-" (symbol-name symbol))
 669                        (eq system-type 'ms-dos))
 670                       ((string-match "\\`w32-" (symbol-name symbol))
 671                        (eq system-type 'windows-nt))
 672                       ((string-match "\\`ns-" (symbol-name symbol))
 673                        (featurep 'ns))
 674                       ((string-match "\\`x-.*gtk" (symbol-name symbol))
 675                        (featurep 'gtk))
 676                       ((string-match "clipboard-manager" (symbol-name symbol))
 677                        (boundp 'x-select-enable-clipboard-manager))
 678                       ((string-match "\\`x-" (symbol-name symbol))
 679                        (fboundp 'x-create-frame))
 680                       ((string-match "selection" (symbol-name symbol))
 681                        (fboundp 'x-selection-exists-p))
 682                       ((string-match "fringe" (symbol-name symbol))
 683                        (fboundp 'define-fringe-bitmap))
 684                       ((string-match "\\`imagemagick" (symbol-name symbol))
 685                        (fboundp 'imagemagick-types))
 686                       ((equal "font-use-system-font" (symbol-name symbol))
 687                        (featurep 'system-font-setting))
 688                       ;; Conditioned on x-create-frame, because that's
 689                       ;; the condition for loadup.el to preload tool-bar.el.
 690                       ((string-match "tool-bar-" (symbol-name symbol))
 691                        (fboundp 'x-create-frame))
 692                       ((equal "vertical-centering-font-regexp"
 693                               (symbol-name symbol))
 694                        ;; Any function from fontset.c will do.
 695                        (fboundp 'new-fontset))
 696                       ((equal "scroll-bar-adjust-thumb-portion"
 697                               (symbol-name symbol))
 698                        (featurep 'x))
 699                       (t t))))
 700     (if (not (boundp symbol))
 701         ;; If variables are removed from C code, give an error here!
 702         (and native-p
 703              (message "Note, built-in variable `%S' not bound" symbol))
 704       ;; Save the standard value, unless we already did.
 705       (or (get symbol 'standard-value)
 706           (put symbol 'standard-value (list standard)))
 707       ;; We need these properties independent of whether cus-start is loaded.
 708       (if (setq prop (memq :safe rest))
 709           (put symbol 'safe-local-variable (cadr prop)))
 710       (if (setq prop (memq :risky rest))
 711           (put symbol 'risky-local-variable (cadr prop)))
 712       (if (setq prop (memq :set rest))
 713           (put symbol 'custom-set (cadr prop)))
 714       ;; This is used by describe-variable.
 715       (if version (put symbol 'custom-version version))
 716       ;; Don't re-add to custom-delayed-init-variables post-startup.
 717       (unless after-init-time
 718         ;; Note this is the _only_ initialize property we handle.
 719         (if (eq (cadr (memq :initialize rest)) 'custom-initialize-delay)
 720             ;; These vars are defined early and should hence be initialized
 721             ;; early, even if this file happens to be loaded late.  so add them
 722             ;; to the end of custom-delayed-init-variables.  Otherwise,
 723             ;; auto-save-file-name-transforms will appear in customize-rogue.
 724             (add-to-list 'custom-delayed-init-variables symbol 'append)))
 725       ;; If this is NOT while dumping Emacs, set up the rest of the
 726       ;; customization info.  This is the stuff that is not needed
 727       ;; until someone does M-x customize etc.
 728       (unless purify-flag
 729         ;; Add it to the right group(s).
 730         (if (listp group)
 731             (dolist (g group)
 732               (custom-add-to-group g symbol 'custom-variable))
 733           (custom-add-to-group group symbol 'custom-variable))
 734         ;; Set the type.
 735         (put symbol 'custom-type type)
 736         (while rest
 737           (setq prop (car rest)
 738                 propval (cadr rest)
 739                 rest (nthcdr 2 rest))
 740           (cond ((memq prop '(:standard :risky :safe :set))) ; handled above
 741                 ((eq prop :tag)
 742                  (put symbol 'custom-tag propval))))))))
 743
 744 (custom-add-to-group 'font-lock 'open-paren-in-column-0-is-defun-start
 745                      'custom-variable)
 746
 747 ;; Record cus-start as loaded if we have set up all the info that we can.
 748 ;; Don't record it as loaded if we have only set up the standard values
 749 ;; and safe/risky properties.
 750 (unless purify-flag
 751   (provide 'cus-start))
 752
 753 ;;; cus-start.el ends here