lisp/vc-rcs.el

   1 ;;; vc-rcs.el --- support for RCS version-control
   2
   3 ;; Copyright (C) 1992,93,94,95,96,97,98,99,2000,2001  Free Software Foundation, Inc.
   4
   5 ;; Author:     FSF (see vc.el for full credits)
   6 ;; Maintainer: Andre Spiegel <spiegel@gnu.org>
   7
   8 ;; $Id: vc-rcs.el,v 1.36 2003/02/04 12:11:40 lektu Exp $
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; See vc.el
  30
  31 ;;; Code:
  32
  33 ;;;
  34 ;;; Customization options
  35 ;;;
  36
  37 (eval-when-compile
  38   (require 'cl)
  39   (require 'vc))
  40
  41 (defcustom vc-rcs-release nil
  42   "*The release number of your RCS installation, as a string.
  43 If nil, VC itself computes this value when it is first needed."
  44   :type '(choice (const :tag "Auto" nil)
  45                  (string :tag "Specified")
  46                  (const :tag "Unknown" unknown))
  47   :group 'vc)
  48
  49 (defcustom vc-rcs-register-switches nil
  50   "*Extra switches for registering a file in RCS.
  51 A string or list of strings.  These are passed to the checkin program
  52 by \\[vc-rcs-register]."
  53   :type '(choice (const :tag "None" nil)
  54                  (string :tag "Argument String")
  55                  (repeat :tag "Argument List"
  56                          :value ("")
  57                          string))
  58   :version "21.1"
  59   :group 'vc)
  60
  61 (defcustom vc-rcs-diff-switches nil
  62   "*A string or list of strings specifying extra switches for rcsdiff under VC."
  63   :type '(choice (const :tag "None" nil)
  64                  (string :tag "Argument String")
  65                  (repeat :tag "Argument List"
  66                          :value ("")
  67                          string))
  68   :version "21.1"
  69   :group 'vc)
  70
  71 (defcustom vc-rcs-header (or (cdr (assoc 'RCS vc-header-alist)) '("\$Id\$"))
  72   "*Header keywords to be inserted by `vc-insert-headers'."
  73   :type '(repeat string)
  74   :version "21.1"
  75   :group 'vc)
  76
  77 (defcustom vc-rcsdiff-knows-brief nil
  78   "*Indicates whether rcsdiff understands the --brief option.
  79 The value is either `yes', `no', or nil.  If it is nil, VC tries
  80 to use --brief and sets this variable to remember whether it worked."
  81   :type '(choice (const :tag "Work out" nil) (const yes) (const no))
  82   :group 'vc)
  83
  84 ;;;###autoload
  85 (defcustom vc-rcs-master-templates
  86   '("%sRCS/%s,v" "%s%s,v" "%sRCS/%s")
  87   "*Where to look for RCS master files.
  88 For a description of possible values, see `vc-check-master-templates'."
  89   :type '(choice (const :tag "Use standard RCS file names"
  90                         '("%sRCS/%s,v" "%s%s,v" "%sRCS/%s"))
  91                  (repeat :tag "User-specified"
  92                          (choice string
  93                                  function)))
  94   :version "21.1"
  95   :group 'vc)
  96
  97 \f
  98 ;;;
  99 ;;; State-querying functions
 100 ;;;
 101
 102 ;;; The autoload cookie below places vc-rcs-registered directly into
 103 ;;; loaddefs.el, so that vc-rcs.el does not need to be loaded for
 104 ;;; every file that is visited.  The definition is repeated below
 105 ;;; so that Help and etags can find it.
 106
 107 ;;;###autoload (defun vc-rcs-registered (f) (vc-default-registered 'RCS f))
 108 (defun vc-rcs-registered (f) (vc-default-registered 'RCS f))
 109
 110 (defun vc-rcs-state (file)
 111   "Implementation of `vc-state' for RCS."
 112   (or (boundp 'vc-rcs-headers-result)
 113       (and vc-consult-headers
 114            (vc-rcs-consult-headers file)))
 115   (let ((state
 116          ;; vc-workfile-version might not be known; in that case the
 117          ;; property is nil.  vc-rcs-fetch-master-state knows how to
 118          ;; handle that.
 119          (vc-rcs-fetch-master-state file
 120                                     (vc-file-getprop file
 121                                                      'vc-workfile-version))))
 122     (if (not (eq state 'up-to-date))
 123         state
 124       (if (vc-workfile-unchanged-p file)
 125           'up-to-date
 126         (if (eq (vc-checkout-model file) 'locking)
 127             'unlocked-changes
 128           'edited)))))
 129
 130 (defun vc-rcs-state-heuristic (file)
 131   "State heuristic for RCS."
 132   (let (vc-rcs-headers-result)
 133     (if (and vc-consult-headers
 134              (setq vc-rcs-headers-result
 135                    (vc-rcs-consult-headers file))
 136              (eq vc-rcs-headers-result 'rev-and-lock))
 137         (let ((state (vc-file-getprop file 'vc-state)))
 138           ;; If the headers say that the file is not locked, the
 139           ;; permissions can tell us whether locking is used for
 140           ;; the file or not.
 141           (if (and (eq state 'up-to-date)
 142                    (not (vc-mistrust-permissions file)))
 143               (cond
 144                ((string-match ".rw..-..-." (nth 8 (file-attributes file)))
 145                 (vc-file-setprop file 'vc-checkout-model 'implicit)
 146                 (setq state
 147                       (if (vc-rcs-workfile-is-newer file)
 148                           'edited
 149                         'up-to-date)))
 150                ((string-match ".r-..-..-." (nth 8 (file-attributes file)))
 151                 (vc-file-setprop file 'vc-checkout-model 'locking))))
 152           state)
 153       (if (not (vc-mistrust-permissions file))
 154           (let* ((attributes  (file-attributes file))
 155                  (owner-uid   (nth 2 attributes))
 156                  (permissions (nth 8 attributes)))
 157             (cond ((string-match ".r-..-..-." permissions)
 158                    (vc-file-setprop file 'vc-checkout-model 'locking)
 159                    'up-to-date)
 160                   ((string-match ".rw..-..-." permissions)
 161                    (if (eq (vc-checkout-model file) 'locking)
 162                        (if (file-ownership-preserved-p file)
 163                            'edited
 164                          (vc-user-login-name owner-uid))
 165                      (if (vc-rcs-workfile-is-newer file)
 166                          'edited
 167                        'up-to-date)))
 168                   (t
 169                    ;; Strange permissions.  Fall through to
 170                    ;; expensive state computation.
 171                    (vc-rcs-state file))))
 172         (vc-rcs-state file)))))
 173
 174 (defun vc-rcs-workfile-version (file)
 175   "RCS-specific version of `vc-workfile-version'."
 176   (or (and vc-consult-headers
 177            (vc-rcs-consult-headers file)
 178            (vc-file-getprop file 'vc-workfile-version))
 179       (progn
 180         (vc-rcs-fetch-master-state file)
 181         (vc-file-getprop file 'vc-workfile-version))))
 182
 183 (defun vc-rcs-latest-on-branch-p (file &optional version)
 184   "Return non-nil if workfile version of FILE is the latest on its branch.
 185 When VERSION is given, perform check for that version."
 186   (unless version (setq version (vc-workfile-version file)))
 187   (with-temp-buffer
 188     (string= version
 189              (if (vc-trunk-p version)
 190                  (progn
 191                    ;; Compare VERSION to the head version number.
 192                    (vc-insert-file (vc-name file) "^[0-9]")
 193                    (vc-parse-buffer "^head[ \t\n]+\\([^;]+\\);" 1))
 194                ;; If we are not on the trunk, we need to examine the
 195                ;; whole current branch.
 196                (vc-insert-file (vc-name file) "^desc")
 197                (vc-rcs-find-most-recent-rev (vc-branch-part version))))))
 198
 199 (defun vc-rcs-checkout-model (file)
 200   "RCS-specific version of `vc-checkout-model'."
 201   (vc-rcs-consult-headers file)
 202   (or (vc-file-getprop file 'vc-checkout-model)
 203       (progn (vc-rcs-fetch-master-state file)
 204              (vc-file-getprop file 'vc-checkout-model))))
 205
 206 (defun vc-rcs-workfile-unchanged-p (file)
 207   "RCS-specific implementation of vc-workfile-unchanged-p."
 208   ;; Try to use rcsdiff --brief.  If rcsdiff does not understand that,
 209   ;; do a double take and remember the fact for the future
 210   (let* ((version (concat "-r" (vc-workfile-version file)))
 211          (status (if (eq vc-rcsdiff-knows-brief 'no)
 212                      (vc-do-command nil 1 "rcsdiff" file version)
 213                    (vc-do-command nil 2 "rcsdiff" file "--brief" version))))
 214     (if (eq status 2)
 215         (if (not vc-rcsdiff-knows-brief)
 216             (setq vc-rcsdiff-knows-brief 'no
 217                   status (vc-do-command nil 1 "rcsdiff" file version))
 218           (error "rcsdiff failed"))
 219       (if (not vc-rcsdiff-knows-brief) (setq vc-rcsdiff-knows-brief 'yes)))
 220     ;; The workfile is unchanged if rcsdiff found no differences.
 221     (zerop status)))
 222
 223 \f
 224 ;;;
 225 ;;; State-changing functions
 226 ;;;
 227
 228 (defun vc-rcs-register (file &optional rev comment)
 229   "Register FILE into the RCS version-control system.
 230 REV is the optional revision number for the file.  COMMENT can be used
 231 to provide an initial description of FILE.
 232
 233 `vc-register-switches' and `vc-rcs-register-switches' are passed to
 234 the RCS command (in that order).
 235
 236 Automatically retrieve a read-only version of the file with keywords
 237 expanded if `vc-keep-workfiles' is non-nil, otherwise, delete the workfile."
 238     (let ((subdir (expand-file-name "RCS" (file-name-directory file))))
 239       (and (not (file-exists-p subdir))
 240            (not (directory-files (file-name-directory file)
 241                                  nil ".*,v$" t))
 242            (yes-or-no-p "Create RCS subdirectory? ")
 243            (make-directory subdir))
 244       (apply 'vc-do-command nil 0 "ci" file
 245              ;; if available, use the secure registering option
 246              (and (vc-rcs-release-p "5.6.4") "-i")
 247              (concat (if vc-keep-workfiles "-u" "-r") rev)
 248              (and comment (concat "-t-" comment))
 249              (vc-switches 'RCS 'register))
 250       ;; parse output to find master file name and workfile version
 251       (with-current-buffer "*vc*"
 252         (goto-char (point-min))
 253         (let ((name (if (looking-at (concat "^\\(.*\\)  <--  "
 254                                             (file-name-nondirectory file)))
 255                         (match-string 1))))
 256           (if (not name)
 257               ;; if we couldn't find the master name,
 258               ;; run vc-rcs-registered to get it
 259               ;; (will be stored into the vc-name property)
 260               (vc-rcs-registered file)
 261             (vc-file-setprop file 'vc-name
 262                              (if (file-name-absolute-p name)
 263                                  name
 264                                (expand-file-name
 265                                 name
 266                                 (file-name-directory file))))))
 267         (vc-file-setprop file 'vc-workfile-version
 268                          (if (re-search-forward
 269                               "^initial revision: \\([0-9.]+\\).*\n"
 270                               nil t)
 271                              (match-string 1))))))
 272
 273 (defun vc-rcs-responsible-p (file)
 274   "Return non-nil if RCS thinks it would be responsible for registering FILE."
 275   ;; TODO: check for all the patterns in vc-rcs-master-templates
 276   (file-directory-p (expand-file-name "RCS" (file-name-directory file))))
 277
 278 (defun vc-rcs-receive-file (file rev)
 279   "Implementation of receive-file for RCS."
 280   (let ((checkout-model (vc-checkout-model file)))
 281     (vc-rcs-register file rev "")
 282     (when (eq checkout-model 'implicit)
 283       (vc-rcs-set-non-strict-locking file))
 284     (vc-rcs-set-default-branch file (concat rev ".1"))))
 285
 286 (defun vc-rcs-unregister (file)
 287   "Unregister FILE from RCS.
 288 If this leaves the RCS subdirectory empty, ask the user
 289 whether to remove it."
 290   (let* ((master (vc-name file))
 291          (dir (file-name-directory master))
 292          (backup-info (find-backup-file-name master)))
 293     (if (not backup-info)
 294         (delete-file master)
 295       (rename-file master (car backup-info) 'ok-if-already-exists)
 296       (dolist (f (cdr backup-info)) (ignore-errors (delete-file f))))
 297     (and (string= (file-name-nondirectory (directory-file-name dir)) "RCS")
 298          ;; check whether RCS dir is empty, i.e. it does not
 299          ;; contain any files except "." and ".."
 300          (not (directory-files dir nil
 301                                "^\\([^.]\\|\\.[^.]\\|\\.\\.[^.]\\).*"))
 302          (yes-or-no-p (format "Directory %s is empty; remove it? " dir))
 303          (delete-directory dir))))
 304
 305 (defun vc-rcs-checkin (file rev comment)
 306   "RCS-specific version of `vc-backend-checkin'."
 307   (let ((switches (vc-switches 'RCS 'checkin)))
 308     (let ((old-version (vc-workfile-version file)) new-version
 309           (default-branch (vc-file-getprop file 'vc-rcs-default-branch)))
 310       ;; Force branch creation if an appropriate
 311       ;; default branch has been set.
 312       (and (not rev)
 313            default-branch
 314            (string-match (concat "^" (regexp-quote old-version) "\\.")
 315                          default-branch)
 316            (setq rev default-branch)
 317            (setq switches (cons "-f" switches)))
 318       (if (and (not rev) old-version)
 319           (setq rev (vc-branch-part old-version)))
 320       (apply 'vc-do-command nil 0 "ci" (vc-name file)
 321              ;; if available, use the secure check-in option
 322              (and (vc-rcs-release-p "5.6.4") "-j")
 323              (concat (if vc-keep-workfiles "-u" "-r") rev)
 324              (concat "-m" comment)
 325              switches)
 326       (vc-file-setprop file 'vc-workfile-version nil)
 327
 328       ;; determine the new workfile version
 329       (set-buffer "*vc*")
 330       (goto-char (point-min))
 331       (when (or (re-search-forward
 332                  "new revision: \\([0-9.]+\\);" nil t)
 333                 (re-search-forward
 334                  "reverting to previous revision \\([0-9.]+\\)" nil t))
 335         (setq new-version (match-string 1))
 336         (vc-file-setprop file 'vc-workfile-version new-version))
 337
 338       ;; if we got to a different branch, adjust the default
 339       ;; branch accordingly
 340       (cond
 341        ((and old-version new-version
 342              (not (string= (vc-branch-part old-version)
 343                            (vc-branch-part new-version))))
 344         (vc-rcs-set-default-branch file
 345                                    (if (vc-trunk-p new-version) nil
 346                                      (vc-branch-part new-version)))
 347         ;; If this is an old RCS release, we might have
 348         ;; to remove a remaining lock.
 349         (if (not (vc-rcs-release-p "5.6.2"))
 350             ;; exit status of 1 is also accepted.
 351             ;; It means that the lock was removed before.
 352             (vc-do-command nil 1 "rcs" (vc-name file)
 353                            (concat "-u" old-version))))))))
 354
 355 (defun vc-rcs-find-version (file rev buffer)
 356   (apply 'vc-do-command
 357          buffer 0 "co" (vc-name file)
 358          "-q" ;; suppress diagnostic output
 359          (concat "-p" rev)
 360          (vc-switches 'RCS 'checkout)))
 361
 362 (defun vc-rcs-checkout (file &optional editable rev)
 363   "Retrieve a copy of a saved version of FILE."
 364   (let ((file-buffer (get-file-buffer file))
 365         switches)
 366     (message "Checking out %s..." file)
 367     (save-excursion
 368       ;; Change buffers to get local value of vc-checkout-switches.
 369       (if file-buffer (set-buffer file-buffer))
 370       (setq switches (vc-switches 'RCS 'checkout))
 371       ;; Save this buffer's default-directory
 372       ;; and use save-excursion to make sure it is restored
 373       ;; in the same buffer it was saved in.
 374       (let ((default-directory default-directory))
 375         (save-excursion
 376           ;; Adjust the default-directory so that the check-out creates
 377           ;; the file in the right place.
 378           (setq default-directory (file-name-directory file))
 379           (let (new-version)
 380             ;; if we should go to the head of the trunk,
 381             ;; clear the default branch first
 382             (and rev (string= rev "")
 383                  (vc-rcs-set-default-branch file nil))
 384             ;; now do the checkout
 385             (apply 'vc-do-command
 386                    nil 0 "co" (vc-name file)
 387                    ;; If locking is not strict, force to overwrite
 388                    ;; the writable workfile.
 389                    (if (eq (vc-checkout-model file) 'implicit) "-f")
 390                    (if editable "-l")
 391                    (if (stringp rev)
 392                        ;; a literal revision was specified
 393                        (concat "-r" rev)
 394                      (let ((workrev (vc-workfile-version file)))
 395                        (if workrev
 396                            (concat "-r"
 397                                    (if (not rev)
 398                                        ;; no revision specified:
 399                                        ;; use current workfile version
 400                                        workrev
 401                                      ;; REV is t ...
 402                                      (if (not (vc-trunk-p workrev))
 403                                          ;; ... go to head of current branch
 404                                          (vc-branch-part workrev)
 405                                        ;; ... go to head of trunk
 406                                        (vc-rcs-set-default-branch file
 407                                                                   nil)
 408                                        ""))))))
 409                    switches)
 410             ;; determine the new workfile version
 411             (with-current-buffer "*vc*"
 412               (setq new-version
 413                     (vc-parse-buffer "^revision \\([0-9.]+\\).*\n" 1)))
 414             (vc-file-setprop file 'vc-workfile-version new-version)
 415             ;; if necessary, adjust the default branch
 416             (and rev (not (string= rev ""))
 417                  (vc-rcs-set-default-branch
 418                   file
 419                   (if (vc-rcs-latest-on-branch-p file new-version)
 420                       (if (vc-trunk-p new-version) nil
 421                         (vc-branch-part new-version))
 422                     new-version)))))
 423         (message "Checking out %s...done" file)))))
 424
 425 (defun vc-rcs-revert (file &optional contents-done)
 426   "Revert FILE to the version it was based on."
 427   (vc-do-command nil 0 "co" (vc-name file) "-f"
 428                  (concat (if (eq (vc-state file) 'edited) "-u" "-r")
 429                          (vc-workfile-version file))))
 430
 431 (defun vc-rcs-cancel-version (file editable)
 432   "Undo the most recent checkin of FILE.
 433 EDITABLE non-nil means previous version should be locked."
 434   (let* ((target (vc-workfile-version file))
 435          (previous (if (vc-trunk-p target) "" (vc-branch-part target)))
 436          (config (current-window-configuration))
 437          (done nil))
 438     (vc-do-command nil 0 "rcs" (vc-name file) (concat "-o" target))
 439     ;; Check out the most recent remaining version.  If it fails, because
 440     ;; the whole branch got deleted, do a double-take and check out the
 441     ;; version where the branch started.
 442     (while (not done)
 443       (condition-case err
 444           (progn
 445             (vc-do-command nil 0 "co" (vc-name file) "-f"
 446                            (concat (if editable "-l" "-u") previous))
 447             (setq done t))
 448         (error (set-buffer "*vc*")
 449                (goto-char (point-min))
 450                (if (search-forward "no side branches present for" nil t)
 451                    (progn (setq previous (vc-branch-part previous))
 452                           (vc-rcs-set-default-branch file previous)
 453                           ;; vc-do-command popped up a window with
 454                           ;; the error message.  Get rid of it, by
 455                           ;; restoring the old window configuration.
 456                           (set-window-configuration config))
 457                  ;; No, it was some other error: re-signal it.
 458                  (signal (car err) (cdr err))))))))
 459
 460 (defun vc-rcs-merge (file first-version &optional second-version)
 461   "Merge changes into current working copy of FILE.
 462 The changes are between FIRST-VERSION and SECOND-VERSION."
 463   (vc-do-command nil 1 "rcsmerge" (vc-name file)
 464                  "-kk"                  ; ignore keyword conflicts
 465                  (concat "-r" first-version)
 466                  (if second-version (concat "-r" second-version))))
 467
 468 (defun vc-rcs-steal-lock (file &optional rev)
 469   "Steal the lock on the current workfile for FILE and revision REV.
 470 Needs RCS 5.6.2 or later for -M."
 471   (vc-do-command nil 0 "rcs" (vc-name file) "-M" (concat "-u" rev))
 472   ;; Do a real checkout after stealing the lock, so that we see
 473   ;; expanded headers.
 474   (vc-do-command nil 0 "co" (vc-name file) "-f" (concat "-l" rev)))
 475
 476
 477 \f
 478 ;;;
 479 ;;; History functions
 480 ;;;
 481
 482 (defun vc-rcs-print-log (file)
 483   "Get change log associated with FILE."
 484   (vc-do-command nil 0 "rlog" (vc-name file)))
 485
 486 (defun vc-rcs-diff (file &optional oldvers newvers)
 487   "Get a difference report using RCS between two versions of FILE."
 488   (if (not oldvers) (setq oldvers (vc-workfile-version file)))
 489   (apply 'vc-do-command "*vc-diff*" 1 "rcsdiff" file
 490          (append (list "-q"
 491                        (concat "-r" oldvers)
 492                        (and newvers (concat "-r" newvers)))
 493                  (vc-switches 'RCS 'diff))))
 494
 495 \f
 496 ;;;
 497 ;;; Snapshot system
 498 ;;;
 499
 500 (defun vc-rcs-assign-name (file name)
 501   "Assign to FILE's latest version a given NAME."
 502   (vc-do-command nil 0 "rcs" (vc-name file) (concat "-n" name ":")))
 503
 504 \f
 505 ;;;
 506 ;;; Miscellaneous
 507 ;;;
 508
 509 (defun vc-rcs-check-headers ()
 510   "Check if the current file has any headers in it."
 511   (save-excursion
 512     (goto-char (point-min))
 513          (re-search-forward "\\$[A-Za-z\300-\326\330-\366\370-\377]+\
 514 \\(: [\t -#%-\176\240-\377]*\\)?\\$" nil t)))
 515
 516 (defun vc-rcs-clear-headers ()
 517   "Implementation of vc-clear-headers for RCS."
 518   (let ((case-fold-search nil))
 519     (goto-char (point-min))
 520     (while (re-search-forward
 521             (concat "\\$\\(Author\\|Date\\|Header\\|Id\\|Locker\\|Name\\|"
 522                     "RCSfile\\|Revision\\|Source\\|State\\): [^$\n]+\\$")
 523             nil t)
 524       (replace-match "$\\1$"))))
 525
 526 (defun vc-rcs-rename-file (old new)
 527   ;; Just move the master file (using vc-rcs-master-templates).
 528   (vc-rename-master (vc-name old) new vc-rcs-master-templates))
 529
 530 \f
 531 ;;;
 532 ;;; Internal functions
 533 ;;;
 534
 535 (defun vc-rcs-workfile-is-newer (file)
 536   "Return non-nil if FILE is newer than its RCS master.
 537 This likely means that FILE has been changed with respect
 538 to its master version."
 539   (let ((file-time (nth 5 (file-attributes file)))
 540         (master-time (nth 5 (file-attributes (vc-name file)))))
 541     (or (> (nth 0 file-time) (nth 0 master-time))
 542         (and (= (nth 0 file-time) (nth 0 master-time))
 543              (> (nth 1 file-time) (nth 1 master-time))))))
 544
 545 (defun vc-rcs-find-most-recent-rev (branch)
 546   "Find most recent revision on BRANCH."
 547   (goto-char (point-min))
 548   (let ((latest-rev -1) value)
 549     (while (re-search-forward (concat "^\\(" (regexp-quote branch)
 550                                       "\\.\\([0-9]+\\)\\)\ndate[ \t]+[0-9.]+;")
 551                               nil t)
 552       (let ((rev (string-to-number (match-string 2))))
 553         (when (< latest-rev rev)
 554           (setq latest-rev rev)
 555           (setq value (match-string 1)))))
 556     (or value
 557         (vc-branch-part branch))))
 558
 559 (defun vc-rcs-fetch-master-state (file &optional workfile-version)
 560   "Compute the master file's idea of the state of FILE.
 561 If a WORKFILE-VERSION is given, compute the state of that version,
 562 otherwise determine the workfile version based on the master file.
 563 This function sets the properties `vc-workfile-version' and
 564 `vc-checkout-model' to their correct values, based on the master
 565 file."
 566   (with-temp-buffer
 567     (if (or (not (vc-insert-file (vc-name file) "^[0-9]"))
 568             (progn (goto-char (point-min))
 569                    (not (looking-at "^head[ \t\n]+[^;]+;$"))))
 570         (error "File %s is not an RCS master file" (vc-name file)))
 571     (let ((workfile-is-latest nil)
 572           (default-branch (vc-parse-buffer "^branch[ \t\n]+\\([^;]*\\);" 1)))
 573       (vc-file-setprop file 'vc-rcs-default-branch default-branch)
 574       (unless workfile-version
 575         ;; Workfile version not known yet.  Determine that first.  It
 576         ;; is either the head of the trunk, the head of the default
 577         ;; branch, or the "default branch" itself, if that is a full
 578         ;; revision number.
 579         (cond
 580          ;; no default branch
 581          ((or (not default-branch) (string= "" default-branch))
 582           (setq workfile-version
 583                 (vc-parse-buffer "^head[ \t\n]+\\([^;]+\\);" 1))
 584           (setq workfile-is-latest t))
 585          ;; default branch is actually a revision
 586          ((string-match "^[0-9]+\\.[0-9]+\\(\\.[0-9]+\\.[0-9]+\\)*$"
 587                         default-branch)
 588           (setq workfile-version default-branch))
 589          ;; else, search for the head of the default branch
 590          (t (vc-insert-file (vc-name file) "^desc")
 591             (setq workfile-version
 592                   (vc-rcs-find-most-recent-rev default-branch))
 593             (setq workfile-is-latest t)))
 594         (vc-file-setprop file 'vc-workfile-version workfile-version))
 595       ;; Check strict locking
 596       (goto-char (point-min))
 597       (vc-file-setprop file 'vc-checkout-model
 598                        (if (re-search-forward ";[ \t\n]*strict;" nil t)
 599                            'locking 'implicit))
 600       ;; Compute state of workfile version
 601       (goto-char (point-min))
 602       (let ((locking-user
 603              (vc-parse-buffer (concat "^locks[ \t\n]+[^;]*[ \t\n]+\\([^:]+\\):"
 604                                       (regexp-quote workfile-version)
 605                                       "[^0-9.]")
 606                               1)))
 607         (cond
 608          ;; not locked
 609          ((not locking-user)
 610           (if (or workfile-is-latest
 611                   (vc-rcs-latest-on-branch-p file workfile-version))
 612               ;; workfile version is latest on branch
 613               'up-to-date
 614             ;; workfile version is not latest on branch
 615             'needs-patch))
 616          ;; locked by the calling user
 617          ((and (stringp locking-user)
 618                (string= locking-user (vc-user-login-name)))
 619           (if (or (eq (vc-checkout-model file) 'locking)
 620                   workfile-is-latest
 621                   (vc-rcs-latest-on-branch-p file workfile-version))
 622               'edited
 623             ;; Locking is not used for the file, but the owner does
 624             ;; have a lock, and there is a higher version on the current
 625             ;; branch.  Not sure if this can occur, and if it is right
 626             ;; to use `needs-merge' in this case.
 627             'needs-merge))
 628          ;; locked by somebody else
 629          ((stringp locking-user)
 630           locking-user)
 631          (t
 632           (error "Error getting state of RCS file")))))))
 633
 634 (defun vc-rcs-consult-headers (file)
 635   "Search for RCS headers in FILE, and set properties accordingly.
 636
 637 Returns: nil            if no headers were found
 638          'rev           if a workfile revision was found
 639          'rev-and-lock  if revision and lock info was found"
 640   (cond
 641    ((not (get-file-buffer file)) nil)
 642    ((let (status version locking-user)
 643      (save-excursion
 644       (set-buffer (get-file-buffer file))
 645       (goto-char (point-min))
 646       (cond
 647        ;; search for $Id or $Header
 648        ;; -------------------------
 649        ;; The `\ 's below avoid an RCS 5.7 bug when checking in this file.
 650        ((or (and (search-forward "$Id\ : " nil t)
 651                  (looking-at "[^ ]+ \\([0-9.]+\\) "))
 652             (and (progn (goto-char (point-min))
 653                         (search-forward "$Header\ : " nil t))
 654                  (looking-at "[^ ]+ \\([0-9.]+\\) ")))
 655         (goto-char (match-end 0))
 656         ;; if found, store the revision number ...
 657         (setq version (match-string-no-properties 1))
 658         ;; ... and check for the locking state
 659         (cond
 660          ((looking-at
 661            (concat "[0-9]+[/-][01][0-9][/-][0-3][0-9] "             ; date
 662             "[0-2][0-9]:[0-5][0-9]+:[0-6][0-9]+\\([+-][0-9:]+\\)? " ; time
 663                    "[^ ]+ [^ ]+ "))                       ; author & state
 664           (goto-char (match-end 0)) ; [0-6] in regexp handles leap seconds
 665           (cond
 666            ;; unlocked revision
 667            ((looking-at "\\$")
 668             (setq locking-user 'none)
 669             (setq status 'rev-and-lock))
 670            ;; revision is locked by some user
 671            ((looking-at "\\([^ ]+\\) \\$")
 672             (setq locking-user (match-string-no-properties 1))
 673             (setq status 'rev-and-lock))
 674            ;; everything else: false
 675            (nil)))
 676          ;; unexpected information in
 677          ;; keyword string --> quit
 678          (nil)))
 679        ;; search for $Revision
 680        ;; --------------------
 681        ((re-search-forward (concat "\\$"
 682                                    "Revision: \\([0-9.]+\\) \\$")
 683                            nil t)
 684         ;; if found, store the revision number ...
 685         (setq version (match-string-no-properties 1))
 686         ;; and see if there's any lock information
 687         (goto-char (point-min))
 688         (if (re-search-forward (concat "\\$" "Locker:") nil t)
 689             (cond ((looking-at " \\([^ ]+\\) \\$")
 690                    (setq locking-user (match-string-no-properties 1))
 691                    (setq status 'rev-and-lock))
 692                   ((looking-at " *\\$")
 693                    (setq locking-user 'none)
 694                    (setq status 'rev-and-lock))
 695                   (t
 696                    (setq locking-user 'none)
 697                    (setq status 'rev-and-lock)))
 698           (setq status 'rev)))
 699        ;; else: nothing found
 700        ;; -------------------
 701        (t nil)))
 702      (if status (vc-file-setprop file 'vc-workfile-version version))
 703      (and (eq status 'rev-and-lock)
 704           (vc-file-setprop file 'vc-state
 705                            (cond
 706                             ((eq locking-user 'none) 'up-to-date)
 707                             ((string= locking-user (vc-user-login-name)) 'edited)
 708                             (t locking-user)))
 709           ;; If the file has headers, we don't want to query the
 710           ;; master file, because that would eliminate all the
 711           ;; performance gain the headers brought us.  We therefore
 712           ;; use a heuristic now to find out whether locking is used
 713           ;; for this file.  If we trust the file permissions, and the
 714           ;; file is not locked, then if the file is read-only we
 715           ;; assume that locking is used for the file, otherwise
 716           ;; locking is not used.
 717           (not (vc-mistrust-permissions file))
 718           (vc-up-to-date-p file)
 719           (if (string-match ".r-..-..-." (nth 8 (file-attributes file)))
 720               (vc-file-setprop file 'vc-checkout-model 'locking)
 721             (vc-file-setprop file 'vc-checkout-model 'implicit)))
 722      status))))
 723
 724 (defun vc-release-greater-or-equal (r1 r2)
 725   "Compare release numbers, represented as strings.
 726 Release components are assumed cardinal numbers, not decimal fractions
 727 \(5.10 is a higher release than 5.9\).  Omitted fields are considered
 728 lower \(5.6.7 is earlier than 5.6.7.1\).  Comparison runs till the end
 729 of the string is found, or a non-numeric component shows up \(5.6.7 is
 730 earlier than \"5.6.7 beta\", which is probably not what you want in
 731 some cases\).  This code is suitable for existing RCS release numbers.
 732 CVS releases are handled reasonably, too \(1.3 < 1.4* < 1.5\)."
 733   (let (v1 v2 i1 i2)
 734     (catch 'done
 735       (or (and (string-match "^\\.?\\([0-9]+\\)" r1)
 736                (setq i1 (match-end 0))
 737                (setq v1 (string-to-number (match-string 1 r1)))
 738                (or (and (string-match "^\\.?\\([0-9]+\\)" r2)
 739                         (setq i2 (match-end 0))
 740                         (setq v2 (string-to-number (match-string 1 r2)))
 741                         (if (> v1 v2) (throw 'done t)
 742                           (if (< v1 v2) (throw 'done nil)
 743                             (throw 'done
 744                                    (vc-release-greater-or-equal
 745                                     (substring r1 i1)
 746                                     (substring r2 i2)))))))
 747                    (throw 'done t)))
 748           (or (and (string-match "^\\.?\\([0-9]+\\)" r2)
 749                    (throw 'done nil))
 750               (throw 'done t)))))
 751
 752 (defun vc-rcs-release-p (release)
 753   "Return t if we have RELEASE or better."
 754   (let ((installation (vc-rcs-system-release)))
 755     (if (and installation
 756              (not (eq installation 'unknown)))
 757         (vc-release-greater-or-equal installation release))))
 758
 759
 760 (defun vc-rcs-system-release ()
 761   "Return the RCS release installed on this system, as a string.
 762 Return symbol UNKNOWN if the release cannot be deducted.  The user can
 763 override this using variable `vc-rcs-release'.
 764
 765 If the user has not set variable `vc-rcs-release' and it is nil,
 766 variable `vc-rcs-release' is set to the returned value."
 767   (or vc-rcs-release
 768       (setq vc-rcs-release
 769             (or (and (zerop (vc-do-command nil nil "rcs" nil "-V"))
 770                      (with-current-buffer (get-buffer "*vc*")
 771                        (vc-parse-buffer "^RCS version \\([0-9.]+ *.*\\)" 1)))
 772                 'unknown))))
 773
 774 (defun vc-rcs-set-non-strict-locking (file)
 775   (vc-do-command nil 0 "rcs" file "-U")
 776   (vc-file-setprop file 'vc-checkout-model 'implicit)
 777   (set-file-modes file (logior (file-modes file) 128)))
 778
 779 (defun vc-rcs-set-default-branch (file branch)
 780   (vc-do-command nil 0 "rcs" (vc-name file) (concat "-b" branch))
 781   (vc-file-setprop file 'vc-rcs-default-branch branch))
 782
 783 (provide 'vc-rcs)
 784
 785 ;;; vc-rcs.el ends here